configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 dnl Ported to autoconf 2.5x by bero@redhat.com
   5 AC_REVISION([configure.in 1.00])
   6 AC_INIT(controls/edit.c)
   7 AC_CONFIG_HEADER(include/config.h)
   8 AC_CONFIG_AUX_DIR(tools)
   9
  10 dnl **** Command-line arguments ****
  11
  12 dnl Default values
  13 LIBEXT=so       # library type .so or .a
  14 TRACE_MSGS=yes  # the TRACE() macro
  15 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  16 CURSES=yes
  17 OPENGL=normal
  18
  19 AC_ARG_ENABLE(debug,
  20 [  --disable-debug         compile out all debugging messages],
  21 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  22
  23 AC_ARG_ENABLE(opengl,
  24 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe via pthread],
  25 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  26
  27 AC_ARG_ENABLE(trace,
  28 [  --disable-trace         compile out TRACE messages],
  29 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  30
  31 AC_ARG_WITH(curses,
  32 [  --without-curses        do not use curses],
  33 [if test "$withval" = "no"; then CURSES="no"; fi])
  34
  35 AC_ARG_WITH(reentrant-x,
  36 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  37
  38 AC_SUBST(OPTIONS)
  39
  40 if test "$DEBUG_MSGS" = "no"
  41 then
  42     OPTIONS="$OPTIONS -DNO_DEBUG_MSGS"
  43 fi
  44
  45 if test "$TRACE_MSGS" = "no" -o "$DEBUG_MSGS" = "no"
  46 then
  47     OPTIONS="$OPTIONS -DNO_TRACE_MSGS"
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58
  59 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
  60 dnl **** without one present.
  61 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
  62 if test "$XYACC" = "none"
  63 then
  64         echo "*** Error: No suitable bison/yacc found. ***"
  65         echo "    Please install the 'bison' package."
  66         exit 1
  67 fi
  68 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  69 if test "$XLEX" = "none"
  70 then
  71         echo "*** Error: No suitable lex found. ***"
  72         echo "    Please install the 'flex' package."
  73         exit 1
  74 fi
  75 AC_PROG_RANLIB
  76 AC_PROG_INSTALL
  77 AC_PROG_LN_S
  78 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  79 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  80 AC_CYGWIN
  81 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  82
  83 dnl Check for lint
  84 AC_CHECK_PROGS(LINT, lclint lint)
  85 if test "$LINT" = "lint"
  86 then
  87   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  88   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  89 fi
  90 AC_SUBST(LINT)
  91 AC_SUBST(LINTFLAGS)
  92
  93 if test "$CYGWIN" = "yes"
  94 then
  95     LDCOMBINE="ld -r --enable-stdcall-fixup"
  96 else
  97     LDCOMBINE="ld -r"
  98 fi
  99 AC_SUBST(LDCOMBINE)
 100
 101 dnl **** Check for some libraries ****
 102
 103 dnl Check for -lm
 104 AC_CHECK_LIB(m,sqrt)
 105 dnl Check for -li386 for NetBSD and OpenBSD
 106 AC_CHECK_LIB(i386,i386_set_ldt)
 107 dnl Check for -lossaudio for NetBSD
 108 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 109 dnl Check for -lw for Solaris
 110 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 111 dnl Check for -lnsl for Solaris
 112 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 113 dnl Check for -lsocket for Solaris
 114 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 115 dnl Check for -lxpg4 for FreeBSD
 116 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 117 dnl Check for -lmmap for OS/2
 118 AC_CHECK_LIB(mmap,mmap)
 119
 120 dnl Check for openpty
 121 UTILLIBS=""
 122 AC_SUBST(UTILLIBS)
 123 AC_CHECK_FUNCS(openpty,,
 124         [AC_CHECK_LIB(util,openpty,
 125                 [AC_DEFINE(HAVE_OPENPTY)
 126                 UTILLIBS="-lutil"]
 127         )])
 128
 129 DLLIBS=""
 130 AC_SUBST(DLLIBS)
 131 AC_CHECK_HEADERS(dlfcn.h,
 132     [AC_CHECK_FUNCS(dlopen,,
 133         [AC_CHECK_LIB(dl,dlopen,
 134                      [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 135                      DLLIBS="-ldl"],
 136                      LIBEXT="a")]
 137         )],
 138         LIBEXT="a"
 139     )
 140
 141 JPEGLIB=""
 142 AC_SUBST(JPEGLIB)
 143 AC_CHECK_HEADERS(jpeglib.h,
 144     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 145         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 146         JPEGLIB="-ljpeg"
 147     )
 148 )
 149
 150
 151 AC_SUBST(XLIB)
 152 AC_SUBST(XFILES)
 153 XFILES=""
 154 AC_SUBST(OPENGLFILES)
 155 OPENGLFILES=""
 156 AC_SUBST(GLU32FILES)
 157 GLU32FILES=""
 158 if test "$have_x" = "yes"
 159 then
 160     XLIB="-lXext -lX11"
 161     ac_save_CPPFLAGS="$CPPFLAGS"
 162     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 163
 164     dnl *** All of the following tests require X11/Xlib.h
 165     AC_CHECK_HEADERS(X11/Xlib.h,
 166       [
 167         dnl *** Check for X keyboard extension
 168         AC_CHECK_HEADERS(X11/XKBlib.h,
 169             [ dnl *** If X11/XKBlib.h exists...
 170               AC_CHECK_LIB(X11, XkbQueryExtension,
 171               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 172               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 173             ],
 174             AC_MSG_WARN([XKB extension not found!!])
 175         )
 176
 177         dnl *** Check for X Shm extension
 178         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 179             [ dnl *** If X11/extensions/XShm.h exists...
 180               AC_CHECK_LIB(Xext, XShmQueryExtension,
 181               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 182               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 183             ],
 184             AC_MSG_WARN([Xshm extension not found!!])
 185         )
 186
 187         dnl *** Check for X shape extension
 188         AC_CHECK_HEADERS(X11/extensions/shape.h,
 189             [ dnl *** If X11/extensions/shape.h exists...
 190               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 191               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 192               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 193             ],
 194             AC_MSG_WARN([XShape extension not found!!])
 195         )
 196
 197         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 198         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 199             [ dnl *** If X11/extensions/xf86dga.h exists, check
 200               dnl *** for XDGAQueryExtension()...
 201               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 202                 [ dnl *** If found...
 203                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 204                             [Define if you have the Xxf86dga library version 2])
 205                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 206                ],
 207                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 208                   dnl *** instead (DGA 2.0 not found)...
 209                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 210                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 211                                 [Define if you have the Xxf86dga library version 1])
 212                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 213                     ],,
 214                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 215                   )
 216                 ],
 217                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 218               )
 219             ],
 220             AC_MSG_WARN([DGA extension not found!!])
 221         )
 222
 223         dnl *** Check for XFree86 VMODE extension
 224         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 225             [ dnl *** If X11/extensions/xf86vmode.h exists...
 226                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 227                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 228                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 229                   ],,
 230                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 231                 )
 232             ],
 233             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 234         )
 235
 236         dnl *** Check for XVideo extension supporting XvImages
 237         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 238             [ dnl *** If X11/extensions/Xvlib.h exists...
 239                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 240                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 241                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 242                   ],,
 243                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 244                 )
 245             ],
 246             AC_MSG_WARN([XVideo extension not found !!])
 247         )
 248
 249         dnl *** Check for XRender extension
 250         AC_CHECK_HEADERS(X11/extensions/Xrender.h,
 251             [ dnl *** If X11/extensions/Xrender.h exists...
 252                 AC_CHECK_LIB(Xrender, XRenderQueryExtension,
 253                   [ AC_DEFINE(HAVE_LIBXRENDER, 1, [Define if you have the XRender extension library])
 254                      X_PRE_LIBS="$X_PRE_LIBS -lXrender"
 255                   ],,
 256                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 257                 )
 258             ],
 259             AC_MSG_WARN([XRender extension not found !!])
 260         )
 261
 262       ]
 263     ) dnl *** End of X11/Xlib.h check
 264
 265     dnl Check for the presence of OpenGL
 266     if test $OPENGL = "yes" -o $OPENGL = "normal"
 267     then
 268         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 269         then
 270             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 271 This prevents linking to OpenGL. Delete the file and restart configure.])
 272         fi
 273
 274         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 275         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 276         then
 277             dnl Check for some problems due to old Mesa versions
 278             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 279               AC_TRY_COMPILE(
 280                 [#include <GL/gl.h>],
 281                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 282                 [wine_cv_opengl_version_OK="yes"],
 283                 [wine_cv_opengl_version_OK="no"]
 284               )
 285             )
 286
 287             dnl Check for the thread-safety of the OpenGL library
 288             AC_CACHE_CHECK([for thread-safe OpenGL version],
 289                            wine_cv_opengl_version_threadsafe,
 290               [saved_libs=$LIBS
 291                LIBS="$X_LIBS -lGL"
 292                AC_TRY_LINK([],[pthread_getspecific();],
 293                               [wine_cv_opengl_version_threadsafe="yes"],
 294                               [wine_cv_opengl_version_threadsafe="no"])
 295                LIBS=$saved_libs]
 296             )
 297
 298             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 299             then
 300                 dnl Check for the presence of the library
 301                 AC_CHECK_LIB(GL,glXCreateContext,
 302                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 303                              ,,
 304                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 305
 306                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 307                 then
 308                         OPENGLFILES='$(OPENGLFILES)'
 309                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 310
 311                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 312                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 313                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 314                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 315
 316                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 317                         then
 318                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 319                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 320                                                   #ifdef HAVE_GL_GLEXT_H
 321                                                   # include <GL/glext.h>
 322                                                   #endif
 323                                                   ],
 324                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 325                                                  [wine_cv_extension_prototypes="yes"],
 326                                                  [wine_cv_extension_prototypes="no"]
 327                                   )]
 328                                 )
 329                                 if test "$wine_cv_extension_prototypes" = "yes"
 330                                 then
 331                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 332                                               [Define if the OpenGL headers define extension typedefs])
 333                                 fi
 334                         fi
 335
 336                 fi
 337                 dnl Check for GLU32 library.
 338                 AC_CHECK_LIB(GLU,gluLookAt,
 339                              [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
 340                              GLU32FILES='$(GLU32FILES)']
 341                              ,,
 342                              $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 343                 )
 344              fi
 345          fi
 346     fi
 347
 348     CPPFLAGS="$ac_save_CPPFLAGS"
 349     XFILES='$(XFILES)'
 350 else
 351     XLIB=""
 352     X_CFLAGS=""
 353     X_LIBS=""
 354 fi
 355
 356 dnl **** Check which curses lib to use ***
 357 CURSESLIBS=""
 358 if test "$CURSES" = "yes"
 359 then
 360     AC_CHECK_HEADERS(ncurses.h,
 361         [AC_CHECK_LIB(ncurses,waddch,
 362             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 363              CURSESLIBS="-lncurses"],
 364              [AC_CHECK_HEADERS(curses.h,
 365                  [AC_CHECK_LIB(curses,waddch,
 366                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 367                       CURSESLIBS="-lcurses"])])])])
 368     saved_libs="$LIBS"
 369     LIBS="$CURSESLIBS $LIBS"
 370     AC_CHECK_FUNCS(getbkgd resizeterm)
 371     LIBS="$saved_libs"
 372 fi
 373 AC_SUBST(CURSESLIBS)
 374
 375 CUPSLIBS=""
 376 dnl **** Check for CUPS ****
 377 wine_cv_warn_cups_h=no
 378 AC_CHECK_LIB(cups,cupsGetPPD,
 379         [AC_CHECK_HEADER(cups/cups.h,
 380             [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
 381             CUPSLIBS="-lcups"],
 382             wine_cv_warn_cups_h=yes)]
 383 )
 384 AC_SUBST(CUPSLIBS)
 385
 386 dnl **** Check for FreeType 2 ****
 387 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 388 if test "$ft_lib" = "no"
 389 then
 390     FREETYPELIBS=""
 391     FREETYPEINCL=""
 392     wine_cv_msg_freetype=no
 393 else
 394     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 395     if test "$ft_devel" = "no"
 396     then
 397         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 398         if test "$ft_devel2" = "freetype2-config"
 399         then
 400                 ft_devel=$ft_devel2
 401         fi
 402     fi
 403     if test "$ft_devel" = "no"
 404     then
 405         FREETYPELIBS=""
 406         FREETYPEINCL=""
 407         wine_cv_msg_freetype=yes
 408     else
 409         FREETYPELIBS=`$ft_devel --libs`
 410         FREETYPEINCL=`$ft_devel --cflags`
 411         ac_save_CPPFLAGS="$CPPFLAGS"
 412         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 413         AC_CHECK_HEADERS(freetype/freetype.h \
 414                          freetype/ftglyph.h \
 415                          freetype/tttables.h \
 416                          freetype/ftnames.h \
 417                          freetype/ftsnames.h \
 418                          freetype/ttnameid.h \
 419                          freetype/ftoutln.h \
 420                          freetype/internal/sfnt.h)
 421         AC_TRY_CPP([#include <ft2build.h>
 422                     #include <freetype/fttrigon.h>],
 423                     AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 424           [Define if you have the <freetype/fttrigon.h> header file.]))
 425         CPPFLAGS="$ac_save_CPPFLAGS"
 426         dnl Check that we have at least freetype/freetype.h
 427         if test "$ac_cv_header_freetype_freetype_h" = "yes"
 428         then
 429             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 430             wine_cv_msg_freetype=no
 431         else
 432             FREETYPELIBS=""
 433             FREETYPEINCL=""
 434             wine_cv_msg_freetype=yes
 435         fi
 436     fi
 437 fi
 438 AC_SUBST(FREETYPELIBS)
 439 AC_SUBST(FREETYPEINCL)
 440
 441 dnl **** Check for parport (currently Linux only) ****
 442 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 443  AC_TRY_COMPILE(
 444    [#include <linux/ppdev.h>],
 445    [ioctl (1,PPCLAIM,0)],
 446    [ac_cv_c_ppdev="yes"],
 447    [ac_cv_c_ppdev="no"])
 448  )
 449 if test "$ac_cv_c_ppdev" = "yes"
 450 then
 451     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 452 fi
 453
 454 dnl **** Check for IPX (currently Linux only) ****
 455 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
 456  AC_TRY_COMPILE(
 457    [#include <sys/socket.h>
 458     #include <netipx/ipx.h>],
 459    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 460    [ac_cv_c_ipx_gnu="yes"],
 461    [ac_cv_c_ipx_gnu="no"])
 462  )
 463 if test "$ac_cv_c_ipx_gnu" = "yes"
 464 then
 465     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
 466 fi
 467
 468 if test "$ac_cv_c_ipx_gnu" = "no"
 469 then
 470  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
 471   AC_TRY_COMPILE(
 472     [#include <sys/socket.h>
 473      #include <asm/types.h>
 474      #include <linux/ipx.h>],
 475     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 476     [ac_cv_c_ipx_linux="yes"],
 477     [ac_cv_c_ipx_linux="no"])
 478   )
 479   if test "$ac_cv_c_ipx_linux" = "yes"
 480   then
 481       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
 482   fi
 483 fi
 484
 485 dnl **** Check for Open Sound System ****
 486 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 487
 488 AC_CACHE_CHECK([for Open Sound System],
 489         ac_cv_c_opensoundsystem,
 490         AC_TRY_COMPILE([
 491         #if defined(HAVE_SYS_SOUNDCARD_H)
 492                 #include <sys/soundcard.h>
 493         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 494                 #include <machine/soundcard.h>
 495         #elif defined(HAVE_SOUNDCARD_H)
 496                 #include <soundcard.h>
 497         #endif
 498         ],[
 499
 500 /* check for one of the Open Sound System specific SNDCTL_ defines */
 501 #if !defined(SNDCTL_DSP_STEREO)
 502 #error No open sound system
 503 #endif
 504 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 505
 506 if test "$ac_cv_c_opensoundsystem" = "yes"
 507 then
 508     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 509 fi
 510
 511 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 512         ac_cv_c_opensoundsystem_midi,
 513         AC_TRY_COMPILE([
 514         #if defined(HAVE_SYS_SOUNDCARD_H)
 515                 #include <sys/soundcard.h>
 516         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 517                 #include <machine/soundcard.h>
 518         #elif defined(HAVE_SOUNDCARD_H)
 519                 #include <soundcard.h>
 520         #endif
 521         ],[
 522
 523 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 524 #if !defined(SNDCTL_SEQ_SYNC)
 525 #error No open sound system MIDI interface
 526 #endif
 527 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 528
 529 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 530 then
 531     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 532 fi
 533
 534 dnl **** If ln -s doesn't work, use cp instead ****
 535 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 536
 537 dnl **** Check for broken glibc mmap64 ****
 538
 539 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 540         AC_TRY_RUN([
 541                 #define _FILE_OFFSET_BITS 64
 542                 #include <stdio.h>
 543                 #include <unistd.h>
 544                 #include <fcntl.h>
 545                 #include <sys/mman.h>
 546                 #include <errno.h>
 547
 548                 int main(int argc,char **argv) {
 549                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 550                         if (fd == -1) exit(1);
 551
 552                         unlink("conftest.map");
 553
 554                         write(fd,"test",4);
 555
 556                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 557                             (errno == EINVAL)
 558                         ) {
 559                                 exit(1);
 560                         }
 561                         close(fd);
 562                         fprintf(stderr,"success!\n");
 563                         exit(0);
 564                 }
 565
 566         ],
 567     ac_cv_mmap64_works="yes",
 568     ac_cv_mmap64_works="no",
 569     ac_cv_mmap64_works="no") )
 570
 571 if test "$ac_cv_mmap64_works" = "yes"
 572 then
 573     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 574 fi
 575
 576 dnl **** Check for gcc strength-reduce bug ****
 577
 578 if test "x${GCC}" = "xyes"
 579 then
 580   CFLAGS="$CFLAGS -Wall"
 581   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 582                   AC_TRY_RUN([
 583 int     L[[4]] = {0,1,2,3};
 584 int main(void) {
 585   static int Array[[3]];
 586   unsigned int B = 3;
 587   int i;
 588   for(i=0; i<B; i++) Array[[i]] = i - 3;
 589   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 590   L[[i]] = 4;
 591
 592   exit( Array[[1]] != -2 || L[[2]] != 3);
 593 }],
 594     ac_cv_c_gcc_strength_bug="no",
 595     ac_cv_c_gcc_strength_bug="yes",
 596     ac_cv_c_gcc_strength_bug="yes") )
 597   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 598   then
 599     CFLAGS="$CFLAGS -fno-strength-reduce"
 600   fi
 601
 602   dnl Check for -mpreferred-stack-boundary
 603   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support],
 604                  ac_cv_c_gcc_stack_boundary,
 605   [saved_cflags=$CFLAGS
 606   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 607   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 608   CFLAGS=$saved_cflags
 609   ])
 610   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 611   then
 612     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 613   fi
 614 fi
 615
 616 dnl **** Check if we need to place .type inside a .def directive ****
 617
 618 AC_CACHE_CHECK([whether .type must sit inside a .def directive],
 619                ac_cv_c_type_in_def,
 620 [saved_libs=$LIBS
 621 LIBS="conftest_asm.s $LIBS"
 622 cat > conftest_asm.s <<EOF
 623         .globl _ac_test
 624         .def _ac_test; .scl 2; .type 32; .endef
 625 _ac_test:
 626         .long 0
 627 EOF
 628 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 629 LIBS=$saved_libs])
 630 if test "$ac_cv_c_type_in_def" = "yes"
 631 then
 632   AC_DEFINE(NEED_TYPE_IN_DEF, 1, [Define if .type asm directive must be inside a .def directive])
 633 fi
 634
 635 dnl **** Check for underscore on external symbols ****
 636
 637 AC_CACHE_CHECK([whether external symbols need an underscore prefix],
 638                ac_cv_c_extern_prefix,
 639 [saved_libs=$LIBS
 640 LIBS="conftest_asm.s $LIBS"
 641 cat > conftest_asm.s <<EOF
 642         .globl _ac_test
 643 _ac_test:
 644         .long 0
 645 EOF
 646 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 647             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 648 LIBS=$saved_libs])
 649 if test "$ac_cv_c_extern_prefix" = "yes"
 650 then
 651   AC_DEFINE(NEED_UNDERSCORE_PREFIX, 1,
 652             [Define if symbols declared in assembly code need an underscore prefix])
 653 fi
 654
 655 dnl **** Check for .string in assembler ****
 656
 657 AC_CACHE_CHECK([whether assembler accepts .string],
 658                ac_cv_c_asm_string,
 659 [saved_libs=$LIBS
 660 LIBS="conftest_asm.s $LIBS"
 661 cat > conftest_asm.s <<EOF
 662         .string "test"
 663 EOF
 664 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 665 LIBS=$saved_libs])
 666 if test "$ac_cv_c_asm_string" = "yes"
 667 then
 668   AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
 669 fi
 670
 671 dnl **** Check for working dll ****
 672
 673 LDSHARED=""
 674 LDDLLFLAGS=""
 675 if test "$LIBEXT" = "so"
 676 then
 677   AC_CACHE_CHECK([whether we can build a GNU style ELF dll],
 678                  ac_cv_c_dll_gnuelf,
 679   [saved_cflags=$CFLAGS
 680   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 681   AC_TRY_LINK(,[return 1],ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")
 682   CFLAGS=$saved_cflags
 683   ])
 684   if test "$ac_cv_c_dll_gnuelf" = "yes"
 685   then
 686     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 687     LDDLLFLAGS="-Wl,-Bsymbolic"
 688   else
 689     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 690                  ac_cv_c_dll_unixware,
 691     [saved_cflags=$CFLAGS
 692     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 693     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 694     CFLAGS=$saved_cflags
 695     ])
 696     if test "$ac_cv_c_dll_unixware" = "yes"
 697     then
 698       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 699       LDDLLFLAGS="-Wl,-B,symbolic"
 700     fi
 701   fi
 702   if test "$ac_cv_c_dll_gnuelf" = "no" -a "$ac_cv_c_dll_unixware" = "no"
 703   then
 704     LIBEXT="a"
 705     if test "$DLLWRAP" = "dllwrap"; then
 706       dnl FIXME - check whether dllwrap works correctly...
 707       if test "$CYGWIN" = "yes"; then
 708         echo "*** use dllwrap for building shared library."
 709         LIBEXT="dll"
 710       fi
 711     fi
 712   fi
 713 fi
 714
 715 if test "$LIBEXT" = "a"; then
 716   echo "*** It is currently not possible to build WINE without shared"
 717   echo "*** library (.so) support to allow transparent switch between .so"
 718   echo "*** and .dll files."
 719   echo "*** If you are using Linux, you will need a newer binutils."
 720   exit 1
 721 fi
 722
 723 DLLFLAGS=""
 724 LDPATH=""
 725
 726 if test "$LIBEXT" = "so"; then
 727     DLLFLAGS="-fPIC"
 728     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 729 elif test "$LIBEXT" = "dll"; then
 730     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 731     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 732 fi
 733
 734 AC_SUBST(DLLFLAGS)
 735 AC_SUBST(LDSHARED)
 736 AC_SUBST(LDDLLFLAGS)
 737 AC_SUBST(LIBEXT)
 738 AC_SUBST(LDPATH)
 739
 740 dnl **** Check for reentrant libc ****
 741 dnl
 742 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 743 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 744
 745 AC_DEFUN([WINE_CHECK_ERRNO],
 746 [
 747   AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
 748   [AC_TRY_RUN([int myerrno = 0;
 749 char buf[256];
 750 int *$1(){return &myerrno;}
 751 main(){connect(0,buf,255); exit(!myerrno);}],
 752   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
 753   wine_cv_libc_r_$1=yes )
 754 ])
 755 if test "$wine_cv_libc_r_$1" = "yes"
 756 then
 757     wine_cv_libc_reentrant=$1
 758 fi
 759 ])
 760
 761 wine_cv_libc_reentrant=no
 762 dnl Linux style errno location
 763 WINE_CHECK_ERRNO(__errno_location)
 764 dnl FreeBSD style errno location
 765 WINE_CHECK_ERRNO(__error)
 766 dnl Solaris style errno location
 767 WINE_CHECK_ERRNO(___errno)
 768 dnl UnixWare style errno location
 769 WINE_CHECK_ERRNO(__thr_errno)
 770 dnl NetBSD style errno location
 771 WINE_CHECK_ERRNO(__errno)
 772
 773 if test "$wine_cv_libc_reentrant" != "no"
 774 then
 775   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
 776                      [Define to the name of the function returning errno for reentrant libc])
 777 fi
 778
 779 dnl **** Check for reentrant X libraries ****
 780 dnl
 781 dnl This may fail to determine whether X libraries are reentrant if
 782 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 783 dnl is possible with the --without-reentrant-x option.
 784
 785 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 786 then
 787 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
 788   [ if test "x$with_reentrant_x" = "xno"
 789     then
 790         wine_cv_x_reentrant=no
 791     else
 792         libX11_check=none
 793         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 794             if test -r $dir/libX11.so; then
 795                 libX11_check="-D $dir/libX11.so"
 796                 break 1
 797             fi
 798             if test -r $dir/libX11.a; then
 799                 libX11_check="$dir/libX11.a"
 800                 break 1
 801             fi
 802         done
 803         if test "$libX11_check" != "none"; then
 804             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 805             then
 806                 wine_cv_x_reentrant=yes
 807             else
 808                 wine_cv_x_reentrant=no
 809             fi
 810         else
 811             wine_cv_x_reentrant=unknown
 812         fi
 813     fi ] )
 814 else
 815     wine_cv_x_reentrant=no
 816 fi
 817 if test "$wine_cv_x_reentrant" = "no"
 818 then
 819   AC_DEFINE(NO_REENTRANT_X11, 1,
 820             [Define if X libraries are not reentrant (compiled without -D_REENTRANT)])
 821 fi
 822
 823
 824 dnl **** Check for functions ****
 825
 826 AC_FUNC_ALLOCA()
 827 AC_CHECK_FUNCS(\
 828         __libc_fork \
 829         _lwp_create \
 830         clone \
 831         ecvt \
 832         finite \
 833         fpclass \
 834         ftruncate64 \
 835         getnetbyaddr \
 836         getnetbyname \
 837         getpagesize \
 838         getprotobyname \
 839         getprotobynumber \
 840         getrlimit \
 841         getservbyport \
 842         getsockopt \
 843         inet_network \
 844         lseek64 \
 845         lstat \
 846         memmove \
 847         mmap \
 848         pread \
 849         pwrite \
 850         rfork \
 851         select \
 852         sendmsg \
 853         settimeofday \
 854         sigaltstack \
 855         statfs \
 856         strcasecmp \
 857         strerror \
 858         strncasecmp \
 859         tcgetattr \
 860         timegm \
 861         usleep \
 862         vfscanf \
 863         wait4 \
 864         waitpid \
 865 )
 866
 867 dnl **** Check for header files ****
 868
 869 AC_CHECK_HEADERS(\
 870         arpa/inet.h \
 871         arpa/nameser.h \
 872         elf.h \
 873         float.h \
 874         ieeefp.h \
 875         libio.h \
 876         libutil.h \
 877         link.h \
 878         linux/cdrom.h \
 879         linux/input.h \
 880         linux/joystick.h \
 881         linux/ucdrom.h \
 882         net/if.h \
 883         netdb.h \
 884         netinet/in.h \
 885         netinet/in_systm.h \
 886         netinet/ip.h \
 887         netinet/tcp.h \
 888         pty.h \
 889         resolv.h \
 890         sched.h \
 891         socket.h \
 892         stdint.h \
 893         strings.h \
 894         sys/cdio.h \
 895         sys/errno.h \
 896         sys/file.h \
 897         sys/filio.h \
 898         sys/ipc.h \
 899         sys/link.h \
 900         sys/lwp.h \
 901         sys/mman.h \
 902         sys/modem.h \
 903         sys/mount.h \
 904         sys/msg.h \
 905         sys/param.h \
 906         sys/ptrace.h \
 907         sys/reg.h \
 908         sys/signal.h \
 909         sys/shm.h \
 910         sys/socket.h \
 911         sys/sockio.h \
 912         sys/statfs.h \
 913         sys/strtio.h \
 914         sys/syscall.h \
 915         sys/user.h \
 916         sys/wait.h \
 917         sys/v86.h \
 918         sys/v86intr.h \
 919         sys/vfs.h \
 920         sys/vm86.h \
 921         syscall.h \
 922         ucontext.h \
 923 )
 924 AC_HEADER_STAT()
 925
 926 dnl **** Check for types ****
 927
 928 AC_C_CONST()
 929 AC_C_INLINE()
 930 AC_TYPE_SIZE_T()
 931 AC_CHECK_SIZEOF(long long,0)
 932
 933 AC_CACHE_CHECK([whether linux/input.h is for real],
 934         wine_cv_linux_input_h,
 935         AC_TRY_COMPILE([
 936             #include <linux/input.h>
 937         ] , [
 938             int foo = EVIOCGBIT(EV_ABS,42);
 939             int bar = BTN_PINKIE;
 940             int fortytwo = 42;
 941         ],
 942         wine_cv_linux_input_h=yes,
 943         wine_cv_linux_input_h=no,
 944         no
 945         )
 946     )
 947     if test "$wine_cv_linux_input_h" = "yes"
 948     then
 949         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
 950                   [Define if we have linux/input.h AND it contains the INPUT event API])
 951     fi
 952
 953
 954 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
 955         wine_cv_linux_gethostbyname_r_6,
 956         AC_TRY_COMPILE([
 957 #include <netdb.h>
 958         ], [
 959     char *name=NULL;
 960     struct hostent he;
 961     struct hostent *result;
 962     char *buf=NULL;
 963     int bufsize=0;
 964     int res,errnr;
 965     char *addr=NULL;
 966     int addrlen=0;
 967     int addrtype=0;
 968     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 969     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 970     ],
 971         wine_cv_linux_gethostbyname_r_6=yes,
 972         wine_cv_linux_gethostbyname_r_6=no
 973         )
 974    )
 975    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 976    then
 977       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
 978                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
 979    fi
 980
 981 if test "$ac_cv_header_linux_joystick_h" = "yes"
 982 then
 983    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
 984         wine_cv_linux_joystick_22_api,
 985         AC_TRY_COMPILE([
 986         #include <sys/ioctl.h>
 987         #include <linux/joystick.h>
 988
 989         struct js_event blub;
 990         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 991         #error "no 2.2 header"
 992         #endif
 993         ],/*empty*/,
 994         wine_cv_linux_joystick_22_api=yes,
 995         wine_cv_linux_joystick_22_api=no,
 996         wine_cv_linux_joystick_22_api=no
 997         )
 998    )
 999    if test "$wine_cv_linux_joystick_22_api" = "yes"
1000    then
1001       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1002                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1003    fi
1004 fi
1005
1006 dnl **** statfs checks ****
1007
1008 if test "$ac_cv_header_sys_vfs_h" = "yes"
1009 then
1010     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1011                     wine_cv_sys_vfs_has_statfs,
1012         AC_TRY_COMPILE([
1013         #include <sys/types.h>
1014         #ifdef HAVE_SYS_PARAM_H
1015         # include <sys/param.h>
1016         #endif
1017         #include <sys/vfs.h>
1018         ],[
1019                 struct statfs stfs;
1020
1021                 memset(&stfs,0,sizeof(stfs));
1022         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1023         )
1024     )
1025     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1026     then
1027       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1028                 [Define if the struct statfs is defined by <sys/vfs.h>])
1029     fi
1030 fi
1031
1032 if test "$ac_cv_header_sys_statfs_h" = "yes"
1033 then
1034     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1035                     wine_cv_sys_statfs_has_statfs,
1036         AC_TRY_COMPILE([
1037         #include <sys/types.h>
1038         #ifdef HAVE_SYS_PARAM_H
1039         # include <sys/param.h>
1040         #endif
1041         #include <sys/statfs.h>
1042         ],[
1043                 struct statfs stfs;
1044         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1045         )
1046     )
1047     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1048     then
1049       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1050                 [Define if the struct statfs is defined by <sys/statfs.h>])
1051     fi
1052 fi
1053
1054 if test "$ac_cv_header_sys_mount_h" = "yes"
1055 then
1056     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1057                     wine_cv_sys_mount_has_statfs,
1058         AC_TRY_COMPILE([
1059         #include <sys/types.h>
1060         #ifdef HAVE_SYS_PARAM_H
1061         # include <sys/param.h>
1062         #endif
1063         #include <sys/mount.h>
1064         ],[
1065                 struct statfs stfs;
1066         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1067         )
1068     )
1069     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1070     then
1071       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1072                 [Define if the struct statfs is defined by <sys/mount.h>])
1073     fi
1074 fi
1075
1076 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1077
1078 AC_CACHE_CHECK( [for statfs.f_bfree], wine_cv_statfs_bfree,
1079   [ if test "x$statfs_bfree" = "xno"
1080     then
1081         wine_cv_statfs_bfree=no
1082     else
1083         AC_TRY_COMPILE([
1084         #include <sys/types.h>
1085         #ifdef HAVE_SYS_PARAM_H
1086         # include <sys/param.h>
1087         #endif
1088         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1089         # include <sys/mount.h>
1090         #else
1091         # ifdef STATFS_DEFINED_BY_SYS_VFS
1092         #  include <sys/vfs.h>
1093         # else
1094         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1095         #   include <sys/statfs.h>
1096         #  endif
1097         # endif
1098         #endif
1099         ],[
1100                 struct statfs stfs;
1101
1102                 stfs.f_bfree++;
1103         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1104         )
1105     fi ] )
1106 if test "$wine_cv_statfs_bfree" = "yes"
1107 then
1108   AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])
1109 fi
1110
1111 AC_CACHE_CHECK( [for statfs.f_bavail], wine_cv_statfs_bavail,
1112   [ if test "x$statfs_bavail" = "xno"
1113     then
1114         wine_cv_statfs_bavail=no
1115     else
1116         AC_TRY_COMPILE([
1117         #include <sys/types.h>
1118         #ifdef HAVE_SYS_PARAM_H
1119         # include <sys/param.h>
1120         #endif
1121         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1122         # include <sys/mount.h>
1123         #else
1124         # ifdef STATFS_DEFINED_BY_SYS_VFS
1125         #  include <sys/vfs.h>
1126         # else
1127         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1128         #   include <sys/statfs.h>
1129         #  endif
1130         # endif
1131         #endif
1132         ],[
1133                 struct statfs stfs;
1134
1135                 stfs.f_bavail++;
1136         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1137         )
1138     fi ] )
1139 if test "$wine_cv_statfs_bavail" = "yes"
1140 then
1141   AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])
1142 fi
1143
1144 dnl *** check for file descriptor passing with msg_accrights
1145
1146 AC_CACHE_CHECK([for msg_accrights in struct msghdr], ac_cv_c_msg_accrights,
1147  AC_TRY_COMPILE([#include <sys/types.h>
1148 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1149                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1150 if test "$ac_cv_c_msg_accrights" = "yes"
1151 then
1152     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])
1153 fi
1154
1155 dnl *** Check for the sa_len member in struct sockaddr
1156
1157 AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_c_sockaddr_sa_len,
1158  AC_TRY_COMPILE([#include <sys/types.h>
1159 #include <sys/socket.h>
1160 ], [static struct sockaddr addr; addr.sa_len = 1],
1161                 ac_cv_c_sockaddr_sa_len="yes", ac_cv_c_sockaddr_sa_len="no"))
1162 if test "$ac_cv_c_sockaddr_sa_len" = "yes"
1163 then
1164     AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])
1165 fi
1166
1167 dnl *** Check for the sun_len member in struct sockaddr_un
1168
1169 AC_CACHE_CHECK([for sun_len in struct sockaddr_un], ac_cv_c_sockaddr_sun_len,
1170  AC_TRY_COMPILE([#include <sys/types.h>
1171 #include <sys/socket.h>
1172 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1173                 ac_cv_c_sockaddr_sun_len="yes", ac_cv_c_sockaddr_sun_len="no"))
1174 if test "$ac_cv_c_sockaddr_sun_len" = "yes"
1175 then
1176     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])
1177 fi
1178
1179 dnl *** check for the need to define __i386__
1180
1181 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1182  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1183 yes
1184 #endif],
1185  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1186 if test "$ac_cv_cpp_def_i386" = "yes"
1187 then
1188     CFLAGS="$CFLAGS -D__i386__"
1189     LINTFLAGS="$LINTFLAGS -D__i386__"
1190 fi
1191
1192 dnl $GCC is set by autoconf
1193 GCC_NO_BUILTIN=""
1194 if test "$GCC" = "yes"
1195 then
1196     GCC_NO_BUILTIN="-fno-builtin"
1197 fi
1198 AC_SUBST(GCC_NO_BUILTIN)
1199
1200 dnl **** Generate output files ****
1201
1202 AC_DEFINE(__WINE_CONFIG_H, 1,
1203           [This must always be defined to allow checking for config.h inclusion])
1204
1205 AC_OUTPUT_COMMANDS([
1206 extra_subdirs="\
1207 dlls/ddraw/d3ddevice \
1208 dlls/ddraw/dclipper \
1209 dlls/ddraw/ddraw \
1210 dlls/ddraw/direct3d \
1211 dlls/ddraw/dpalette \
1212 dlls/ddraw/dsurface \
1213 dlls/dinput/joystick \
1214 dlls/dinput/keyboard \
1215 dlls/dinput/mouse \
1216 dlls/kernel/messages \
1217 dlls/user/dde \
1218 dlls/user/resources \
1219 dlls/wineps/data \
1220 "
1221 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1222
1223 MAKE_RULES=Make.rules
1224 AC_SUBST_FILE(MAKE_RULES)
1225
1226 MAKE_DLL_RULES=dlls/Makedll.rules
1227 AC_SUBST_FILE(MAKE_DLL_RULES)
1228
1229 MAKE_PROG_RULES=programs/Makeprog.rules
1230 AC_SUBST_FILE(MAKE_PROG_RULES)
1231
1232 AC_OUTPUT([
1233 Make.rules
1234 dlls/Makedll.rules
1235 programs/Makeprog.rules
1236 Makefile
1237 console/Makefile
1238 controls/Makefile
1239 debugger/Makefile
1240 dlls/Makefile
1241 dlls/advapi32/Makefile
1242 dlls/avicap32/Makefile
1243 dlls/avifil32/Makefile
1244 dlls/comctl32/Makefile
1245 dlls/commdlg/Makefile
1246 dlls/crtdll/Makefile
1247 dlls/crypt32/Makefile
1248 dlls/dciman32/Makefile
1249 dlls/ddraw/Makefile
1250 dlls/devenum/Makefile
1251 dlls/dinput/Makefile
1252 dlls/dplay/Makefile
1253 dlls/dplayx/Makefile
1254 dlls/dsound/Makefile
1255 dlls/gdi/Makefile
1256 dlls/glu32/Makefile
1257 dlls/icmp/Makefile
1258 dlls/imagehlp/Makefile
1259 dlls/imm32/Makefile
1260 dlls/kernel/Makefile
1261 dlls/lzexpand/Makefile
1262 dlls/mapi32/Makefile
1263 dlls/mpr/Makefile
1264 dlls/msacm/Makefile
1265 dlls/msdmo/Makefile
1266 dlls/msimg32/Makefile
1267 dlls/msnet32/Makefile
1268 dlls/msrle32/Makefile
1269 dlls/msvcrt/Makefile
1270 dlls/msvcrt20/Makefile
1271 dlls/msvideo/Makefile
1272 dlls/netapi32/Makefile
1273 dlls/ntdll/Makefile
1274 dlls/odbc32/Makefile
1275 dlls/ole32/Makefile
1276 dlls/oleaut32/Makefile
1277 dlls/olecli/Makefile
1278 dlls/oledlg/Makefile
1279 dlls/olepro32/Makefile
1280 dlls/olesvr/Makefile
1281 dlls/opengl32/Makefile
1282 dlls/psapi/Makefile
1283 dlls/qcap/Makefile
1284 dlls/quartz/Makefile
1285 dlls/rasapi32/Makefile
1286 dlls/richedit/Makefile
1287 dlls/rpcrt4/Makefile
1288 dlls/serialui/Makefile
1289 dlls/setupapi/Makefile
1290 dlls/shdocvw/Makefile
1291 dlls/shell32/Makefile
1292 dlls/shfolder/Makefile
1293 dlls/shlwapi/Makefile
1294 dlls/sti/Makefile
1295 dlls/tapi32/Makefile
1296 dlls/ttydrv/Makefile
1297 dlls/url/Makefile
1298 dlls/urlmon/Makefile
1299 dlls/user/Makefile
1300 dlls/version/Makefile
1301 dlls/win32s/Makefile
1302 dlls/winaspi/Makefile
1303 dlls/winedos/Makefile
1304 dlls/wineps/Makefile
1305 dlls/wininet/Makefile
1306 dlls/winmm/Makefile
1307 dlls/winmm/joystick/Makefile
1308 dlls/winmm/mcianim/Makefile
1309 dlls/winmm/mciavi/Makefile
1310 dlls/winmm/mcicda/Makefile
1311 dlls/winmm/mciseq/Makefile
1312 dlls/winmm/mciwave/Makefile
1313 dlls/winmm/midimap/Makefile
1314 dlls/winmm/wavemap/Makefile
1315 dlls/winmm/wineoss/Makefile
1316 dlls/winnls/Makefile
1317 dlls/winsock/Makefile
1318 dlls/winspool/Makefile
1319 dlls/wintrust/Makefile
1320 dlls/wow32/Makefile
1321 dlls/wsock32/Makefile
1322 dlls/x11drv/Makefile
1323 documentation/Makefile
1324 documentation/wine.conf.man
1325 documentation/wine.man
1326 files/Makefile
1327 graphics/Makefile
1328 graphics/enhmetafiledrv/Makefile
1329 graphics/metafiledrv/Makefile
1330 graphics/win16drv/Makefile
1331 graphics/x11drv/Makefile
1332 if1632/Makefile
1333 include/Makefile
1334 library/Makefile
1335 libtest/Makefile
1336 loader/Makefile
1337 loader/ne/Makefile
1338 memory/Makefile
1339 misc/Makefile
1340 miscemu/Makefile
1341 msdos/Makefile
1342 objects/Makefile
1343 ole/Makefile
1344 programs/Makefile
1345 programs/avitools/Makefile
1346 programs/clock/Makefile
1347 programs/cmdlgtst/Makefile
1348 programs/control/Makefile
1349 programs/notepad/Makefile
1350 programs/osversioncheck/Makefile
1351 programs/progman/Makefile
1352 programs/regapi/Makefile
1353 programs/regtest/Makefile
1354 programs/uninstaller/Makefile
1355 programs/view/Makefile
1356 programs/wcmd/Makefile
1357 programs/wineconsole/Makefile
1358 programs/winemine/Makefile
1359 programs/winetest/Makefile
1360 programs/winhelp/Makefile
1361 programs/winver/Makefile
1362 relay32/Makefile
1363 scheduler/Makefile
1364 server/Makefile
1365 tools/Makefile
1366 tools/winapi/Makefile
1367 tools/winebuild/Makefile
1368 tools/winedump/Makefile
1369 tools/winelauncher
1370 tools/wmc/Makefile
1371 tools/wrc/Makefile
1372 tsx11/Makefile
1373 unicode/Makefile
1374 win32/Makefile
1375 windows/Makefile
1376 windows/x11drv/Makefile ])
1377
1378 if test "$have_x" = "no"
1379 then
1380   echo
1381   echo "*** Warning: X development files not found. Wine will be built without"
1382   echo "*** X support, which currently does not work, and would probably not be"
1383   echo "*** what you want anyway. You will need to install devel packages of"
1384   echo "*** Xlib/Xfree86 at the very least."
1385 fi
1386
1387 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1388 then
1389   echo
1390   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1391   echo "*** terminal resize support. Consider upgrading ncurses."
1392 fi
1393
1394 if test "$wine_cv_libc_reentrant" = "no"
1395 then
1396   echo
1397   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1398   echo "*** thread support. Consider upgrading libc to a more recent"
1399   echo "*** reentrant version of libc."
1400 fi
1401
1402 if test "$wine_cv_opengl_version_OK" = "no"
1403 then
1404   echo
1405   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1406   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1407 fi
1408
1409 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1410 then
1411   echo
1412   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1413   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1414   echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1415   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1416 fi
1417
1418 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1419 then
1420   echo
1421   echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1422   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1423   echo "*** support before reporting bugs."
1424 fi
1425
1426 if test "$wine_cv_warn_cups_h" = "yes"
1427 then
1428   echo
1429   echo "*** Note: You have cups runtime libraries, but no development"
1430   echo "*** libraries. Install the cups-devel package or whichever package"
1431   echo "*** contains cups.h to enable CUPS support in WINE."
1432 fi
1433
1434 if test "$wine_cv_msg_freetype" = "yes"
1435 then
1436   echo
1437   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1438   echo "*** installed, but either 'freetype-config' is not in your PATH or"
1439   echo "*** you do not have the FreeType include files.  Install the"
1440   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1441   echo "*** enable Wine to use TrueType fonts."
1442 fi
1443
1444 echo
1445 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1446 echo
1447
1448 dnl Local Variables:
1449 dnl comment-start: "dnl "
1450 dnl comment-end: ""
1451 dnl comment-start-skip: "\\bdnl\\b\\s *"
1452 dnl compile-command: "autoconf"
1453 dnl End: