aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]]),
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32,w64-mingw32],[x86_64-ac_wine_prefix-$2 ])" ;;
 132   *)
 133     ac_prefix_list="" ;;
 134 esac
 135 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 136
 137
 138 dnl **** Define helper functions for creating config.status files ****
 139 dnl
 140 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 141 dnl
 142 AC_DEFUN([WINE_CONFIG_HELPERS],
 143 [AC_SUBST(ALL_MAKEFILE_DEPENDS,["# Makefile dependencies
 144 Makefile: Makefile.in Make.rules config.status
 145         @./config.status Makefile"])
 146
 147 AC_SUBST(ALL_WINETEST_DEPENDS,["# Test binaries"])
 148 AC_SUBST(ALL_TEST_BINARIES,"")
 149 AC_SUBST(ALL_PROGRAM_BIN_INSTALL_DIRS,"")
 150
 151 wine_fn_append_file ()
 152 {
 153     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 154 }
 155
 156 wine_fn_append_rule ()
 157 {
 158     AS_VAR_APPEND($[1],"$as_nl$[2]")
 159 }
 160
 161 wine_fn_all_dir_rules ()
 162 {
 163     wine_fn_append_file ALL_DIRS $[1]
 164     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 165 "__clean__ .PHONY: $[1]/__clean__
 166 $[1]/__clean__: $[1]/Makefile
 167         @cd $[1] && \$(MAKE) clean
 168         \$(RM) $[1]/Makefile
 169 $[1]/Makefile: $[1]/Makefile.in config.status $[2]
 170         @./config.status --file $[1]/Makefile && cd $[1] && \$(MAKE) depend
 171 depend .PHONY: $[1]/__depend__
 172 $[1]/__depend__: \$(MAKEDEP) dummy
 173         @./config.status --file $[1]/Makefile && cd $[1] && \$(MAKE) depend"
 174 }
 175
 176 wine_fn_config_makefile ()
 177 {
 178     ac_dir=$[1]
 179     ac_enable=$[2]
 180     wine_fn_all_dir_rules $ac_dir "Make.rules \$(MAKEDEP)"
 181
 182     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 183 "all .PHONY: $ac_dir
 184 $ac_dir: $ac_dir/Makefile dummy
 185         @cd $ac_dir && \$(MAKE)
 186 install:: $ac_dir
 187         @cd $ac_dir && \$(MAKE) install
 188 install-lib:: $ac_dir
 189         @cd $ac_dir && \$(MAKE) install-lib
 190 install-dev:: $ac_dir
 191         @cd $ac_dir && \$(MAKE) install-dev
 192 uninstall:: $ac_dir/Makefile
 193         @cd $ac_dir && \$(MAKE) uninstall"])
 194 }
 195
 196 wine_fn_config_lib ()
 197 {
 198     ac_name=$[1]
 199     ac_dir=dlls/$ac_name
 200     wine_fn_all_dir_rules $ac_dir "dlls/Makeimplib.rules \$(MAKEDEP)"
 201     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 202 "all __builddeps__: $ac_dir
 203 __buildcrossdeps__: $ac_dir/lib$ac_name.cross.a
 204 $ac_dir $ac_dir/lib$ac_name.cross.a: $ac_dir/Makefile tools/widl tools/winebuild tools/winegcc include
 205 $ac_dir: dummy
 206         @cd $ac_dir && \$(MAKE)
 207 $ac_dir/lib$ac_name.cross.a: dummy
 208         @cd $ac_dir && \$(MAKE) lib$ac_name.cross.a
 209 install install-dev:: $ac_dir
 210         @cd $ac_dir && \$(MAKE) install
 211 uninstall:: $ac_dir/Makefile
 212         @cd $ac_dir && \$(MAKE) uninstall"
 213 }
 214
 215 wine_fn_config_dll ()
 216 {
 217     ac_dir=$[1]
 218     ac_enable=$[2]
 219     ac_implib=$[3]
 220     ac_implibsrc=$[4]
 221     ac_file="dlls/$ac_dir/lib$ac_implib"
 222     ac_deps="tools/widl tools/winebuild tools/winegcc include"
 223
 224     wine_fn_all_dir_rules dlls/$ac_dir "dlls/Makedll.rules \$(MAKEDEP)"
 225
 226     AS_VAR_IF([$ac_enable],[no],
 227               dnl enable_win16 is special in that it disables import libs too
 228               [test "$ac_enable" != enable_win16 || return 0],
 229               [wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 230 "all .PHONY: dlls/$ac_dir
 231 dlls/$ac_dir: dlls/$ac_dir/Makefile __builddeps__ dummy
 232         @cd dlls/$ac_dir && \$(MAKE)
 233 install:: dlls/$ac_dir/Makefile __builddeps__
 234         @cd dlls/$ac_dir && \$(MAKE) install
 235 install-lib:: dlls/$ac_dir/Makefile __builddeps__
 236         @cd dlls/$ac_dir && \$(MAKE) install-lib
 237 uninstall manpages htmlpages sgmlpages xmlpages:: dlls/$ac_dir/Makefile
 238         @cd dlls/$ac_dir && \$(MAKE) \$[@]"])
 239
 240     if test -n "$ac_implibsrc"
 241     then
 242         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 243 "__builddeps__: $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT
 244 __buildcrossdeps__: $ac_file.cross.a
 245 $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 246 $ac_file.def: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 247         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 248 $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/Makefile dummy
 249         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 250 install-dev:: dlls/$ac_dir/Makefile __builddeps__
 251         @cd dlls/$ac_dir && \$(MAKE) install-dev"
 252     elif test -n "$ac_implib"
 253     then
 254         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 255 "__builddeps__: $ac_file.$IMPLIBEXT
 256 __buildcrossdeps__: $ac_file.cross.a
 257 $ac_file.$IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile $ac_deps
 258         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 259 install-dev:: dlls/$ac_dir/Makefile __builddeps__
 260         @cd dlls/$ac_dir && \$(MAKE) install-dev"
 261
 262         if test "$ac_dir" != "$ac_implib"
 263         then
 264             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 265 "__builddeps__: dlls/lib$ac_implib.$IMPLIBEXT
 266 __buildcrossdeps__: dlls/lib$ac_implib.cross.a
 267 dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 268         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.$IMPLIBEXT \$[@]
 269 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 270         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.cross.a \$[@]
 271 clean::
 272         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 273         fi
 274     fi
 275 }
 276
 277 wine_fn_config_program ()
 278 {
 279     ac_dir=$[1]
 280     ac_enable=$[2]
 281     ac_install=$[3]
 282     wine_fn_all_dir_rules programs/$ac_dir "programs/Makeprog.rules \$(MAKEDEP)"
 283
 284     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 285 "all .PHONY: programs/$ac_dir
 286 programs/$ac_dir: programs/$ac_dir/Makefile __builddeps__ dummy
 287         @cd programs/$ac_dir && \$(MAKE)"
 288
 289     if test -n "$ac_install"
 290     then
 291         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 292 "install install-lib:: programs/$ac_dir/Makefile __builddeps__
 293         @cd programs/$ac_dir && \$(MAKE) install
 294 uninstall:: programs/$ac_dir/Makefile
 295         @cd programs/$ac_dir && \$(MAKE) uninstall"
 296         test "$ac_install" != installbin || wine_fn_append_file ALL_PROGRAM_BIN_INSTALL_DIRS programs/$ac_dir
 297     fi])
 298 }
 299
 300 wine_fn_config_test ()
 301 {
 302     ac_dir=$[1]
 303     ac_name=$[2]
 304     wine_fn_append_file ALL_TEST_BINARIES $ac_name.exe
 305     wine_fn_append_rule ALL_WINETEST_DEPENDS \
 306 "$ac_name.exe: \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT
 307         cp \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT \$[@] && \$(STRIP) \$[@]
 308 $ac_name.rc:
 309         echo \"$ac_name.exe TESTRES \\\"$ac_name.exe\\\"\" >\$[@] || (\$(RM) \$[@] && false)
 310 $ac_name.res: $ac_name.rc $ac_name.exe"
 311     wine_fn_all_dir_rules $ac_dir "Maketest.rules \$(MAKEDEP)"
 312
 313     AS_VAR_IF([enable_tests],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 314 "all programs/winetest .PHONY: $ac_dir
 315 $ac_dir: $ac_dir/Makefile __builddeps__ dummy
 316         @cd $ac_dir && \$(MAKE)
 317 crosstest .PHONY: $ac_dir/__crosstest__
 318 $ac_dir/__crosstest__: $ac_dir/Makefile __buildcrossdeps__ dummy
 319         @cd $ac_dir && \$(MAKE) crosstest
 320 test .PHONY: $ac_dir/__test__
 321 $ac_dir/__test__: dummy
 322         @cd $ac_dir && \$(MAKE) test
 323 testclean::
 324         \$(RM) $ac_dir/*.ok"])
 325 }
 326
 327 wine_fn_config_tool ()
 328 {
 329     ac_dir=$[1]
 330     ac_deps="Make.rules"
 331     if test "$ac_dir" != tools
 332     then
 333         dnl makedep is in tools so tools makefile cannot depend on it
 334         ac_deps="$ac_deps \$(MAKEDEP)"
 335     fi
 336     wine_fn_all_dir_rules $ac_dir "$ac_deps"
 337
 338     AS_VAR_IF([enable_tools],[no],,[case $ac_dir in
 339       dnl tools directory has both install-lib and install-dev
 340       tools) wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 341 "install:: $ac_dir
 342         @cd $ac_dir && \$(MAKE) install
 343 install-lib:: $ac_dir
 344         @cd $ac_dir && \$(MAKE) install-lib
 345 install-dev:: $ac_dir
 346         @cd $ac_dir && \$(MAKE) install-dev" ;;
 347       *)     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 348 "install install-dev:: $ac_dir
 349         @cd $ac_dir && \$(MAKE) install" ;;
 350       esac
 351       wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 352 "uninstall:: $ac_dir/Makefile
 353         @cd $ac_dir && \$(MAKE) uninstall
 354 all __tooldeps__ .PHONY: $ac_dir
 355 $ac_dir: $ac_dir/Makefile libs/port dummy
 356         @cd $ac_dir && \$(MAKE)"])
 357 }
 358
 359 wine_fn_config_makerules ()
 360 {
 361     ac_rules=$[1]
 362     ac_deps=$[2]
 363     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 364 "$ac_rules: $ac_rules.in $ac_deps config.status
 365         @./config.status $ac_rules
 366 distclean::
 367         \$(RM) $ac_rules"
 368 }
 369
 370 wine_fn_config_symlink ()
 371 {
 372     ac_link=$[1]
 373     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 374 "$ac_link:
 375         @./config.status $ac_link
 376 distclean::
 377         \$(RM) $ac_link"
 378 }])
 379
 380 dnl **** Define helper function to append a file to a makefile file list ****
 381 dnl
 382 dnl Usage: WINE_APPEND_FILE(var,file)
 383 dnl
 384 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 385
 386 dnl **** Define helper function to append a rule to a makefile command list ****
 387 dnl
 388 dnl Usage: WINE_APPEND_RULE(var,rule)
 389 dnl
 390 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 391
 392 dnl **** Create nonexistent directories from config.status ****
 393 dnl
 394 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 395 dnl
 396 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 397 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 398
 399 dnl **** Create symlinks from config.status ****
 400 dnl
 401 dnl Usage: WINE_CONFIG_SYMLINK(name,target)
 402 dnl
 403 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 404 AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 405 m4_if([$2],,[test "$srcdir" = "." || ])wine_fn_config_symlink $1])
 406
 407 dnl **** Create a make rules file from config.status ****
 408 dnl
 409 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 410 dnl
 411 AC_DEFUN([WINE_CONFIG_MAKERULES],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 412 wine_fn_config_makerules $1 $3
 413 $2=$1
 414 AC_SUBST_FILE([$2])dnl
 415 AC_CONFIG_FILES([$1])])
 416
 417 dnl **** Create a makefile from config.status ****
 418 dnl
 419 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable)
 420 dnl
 421 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 422 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 423 wine_fn_config_makefile [$1] ac_enable[]dnl
 424 AS_VAR_POPDEF([ac_enable])])
 425
 426 dnl **** Create a dll makefile from config.status ****
 427 dnl
 428 dnl Usage: WINE_CONFIG_DLL(name,enable,implib,implibsrc)
 429 dnl
 430 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 431 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 432 wine_fn_config_dll [$1] ac_enable [$3] m4_ifval([$4],["$4"])dnl
 433 AS_VAR_POPDEF([ac_enable])])
 434
 435 dnl **** Create a program makefile from config.status ****
 436 dnl
 437 dnl Usage: WINE_CONFIG_PROGRAM(name,install,enable)
 438 dnl
 439 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 440 AS_VAR_PUSHDEF([ac_enable],m4_default([$3],[enable_]$1))dnl
 441 wine_fn_config_program [$1] ac_enable [$2]dnl
 442 AS_VAR_POPDEF([ac_enable])])
 443
 444 dnl **** Create a test makefile from config.status ****
 445 dnl
 446 dnl Usage: WINE_CONFIG_TEST(dir)
 447 dnl
 448 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 449 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 450 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 451 wine_fn_config_test $1 ac_name[]ac_suffix[]dnl
 452 m4_popdef([ac_suffix])dnl
 453 m4_popdef([ac_name])])
 454
 455 dnl **** Create a static lib makefile from config.status ****
 456 dnl
 457 dnl Usage: WINE_CONFIG_LIB(name)
 458 dnl
 459 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 460 wine_fn_config_lib $1])
 461
 462 dnl **** Create a tool makefile from config.status ****
 463 dnl
 464 dnl Usage: WINE_CONFIG_TOOL(name)
 465 dnl
 466 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 467 wine_fn_config_tool $1])
 468
 469 dnl **** Add a message to the list displayed at the end ****
 470 dnl
 471 dnl Usage: WINE_NOTICE(notice)
 472 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 473 dnl Usage: WINE_WARNING(warning)
 474 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 475 dnl Usage: WINE_PRINT_MESSAGES
 476 dnl
 477 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 478 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 479
 480 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 481   x)   WINE_NOTICE([$3]) ;;
 482   xno) ;;
 483   *)   AC_MSG_ERROR([$3
 484 This is an error since --with-$1 was requested.]) ;;
 485 esac])])
 486
 487 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 488   x)   WINE_WARNING([$3]) ;;
 489   xno) ;;
 490   *)   AC_MSG_ERROR([$3
 491 This is an error since --with-$1 was requested.]) ;;
 492 esac])])
 493
 494 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 495   xno) ;;
 496   *)   AC_MSG_ERROR([$3
 497 Use the --without-$1 option if you really want this.]) ;;
 498 esac])])
 499
 500 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 501 if test "x$wine_notices != "x; then
 502     echo >&AS_MESSAGE_FD
 503     IFS="|"
 504     for msg in $wine_notices; do
 505         IFS="$ac_save_IFS"
 506         if test -n "$msg"; then
 507             AC_MSG_NOTICE([$msg])
 508         fi
 509     done
 510 fi
 511 IFS="|"
 512 for msg in $wine_warnings; do
 513     IFS="$ac_save_IFS"
 514     if test -n "$msg"; then
 515         echo >&2
 516         AC_MSG_WARN([$msg])
 517     fi
 518 done
 519 IFS="$ac_save_IFS"])
 520
 521 dnl Local Variables:
 522 dnl compile-command: "autoreconf --warnings=all"
 523 dnl End: