configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(debug,
  19 [  --disable-debug         compile out all debugging messages],
  20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  21
  22 AC_ARG_ENABLE(opengl,
  23 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe],
  24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  25
  26 AC_ARG_ENABLE(trace,
  27 [  --disable-trace         compile out TRACE messages],
  28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  29
  30 AC_ARG_WITH(curses,
  31 [  --without-curses        do not use curses],
  32 [if test "$withval" = "no"; then CURSES="no"; fi])
  33
  34 AC_ARG_WITH(reentrant-x,
  35 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  36
  37 AC_SUBST(OPTIONS)
  38
  39 if test "$DEBUG_MSGS" = "no"
  40 then
  41     AC_DEFINE(NO_DEBUG_MSGS)
  42     AC_DEFINE(NO_TRACE_MSGS)
  43 else
  44     if test "$TRACE_MSGS" = "no"
  45     then
  46         AC_DEFINE(NO_TRACE_MSGS)
  47     fi
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_DECL_YYTEXT
  66 AC_PROG_RANLIB
  67 AC_PROG_INSTALL
  68 AC_PROG_LN_S
  69 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  70 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  71 AC_CYGWIN
  72
  73 dnl Check for lint
  74 AC_CHECK_PROGS(LINT, lclint lint)
  75 if test "$LINT" = "lint"
  76 then
  77   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  78   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  79 fi
  80 AC_SUBST(LINT)
  81 AC_SUBST(LINTFLAGS)
  82
  83 if test "$CYGWIN" = "yes"
  84 then
  85     LDCOMBINE="ld -r --enable-stdcall-fixup"
  86 else
  87     LDCOMBINE="ld -r"
  88 fi
  89 AC_SUBST(LDCOMBINE)
  90
  91 dnl **** Check for some libraries ****
  92
  93 dnl Check for -lm for BeOS
  94 AC_CHECK_LIB(m,sqrt)
  95 dnl Check for -li386 for NetBSD and OpenBSD
  96 AC_CHECK_LIB(i386,i386_set_ldt)
  97 dnl Check for -lossaudio for NetBSD
  98 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  99 dnl Check for -lw for Solaris
 100 AC_CHECK_LIB(w,iswalnum)
 101 dnl Check for -lnsl for Solaris
 102 AC_CHECK_FUNCS(gethostbyname,, AC_CHECK_LIB(nsl, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", AC_CHECK_LIB(socket, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", , -lnsl), -lsocket))
 103 dnl Check for -lsocket for Solaris
 104 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 105 dnl Check for -lxpg4 for FreeBSD
 106 AC_CHECK_LIB(xpg4,setrunelocale)
 107 dnl Check for -lmmap for OS/2
 108 AC_CHECK_LIB(mmap,mmap)
 109 dnl Check for openpty
 110 AC_CHECK_FUNCS(openpty,,
 111         AC_CHECK_LIB(util,openpty,
 112                 AC_DEFINE(HAVE_OPENPTY)
 113                 LIBS="$LIBS -lutil"
 114         ))
 115
 116 AC_CHECK_HEADERS(dlfcn.h,
 117         AC_CHECK_FUNCS(dlopen,
 118                 AC_DEFINE(HAVE_DL_API),
 119                 AC_CHECK_LIB(dl,dlopen,
 120                         AC_DEFINE(HAVE_DL_API)
 121                         LIBS="$LIBS -ldl",
 122                         LIBEXT="a"
 123                 )
 124         ),
 125         LIBEXT="a"
 126 )
 127 AC_SUBST(XLIB)
 128 AC_SUBST(X_DLLS)
 129 X_DLLS=""
 130 AC_SUBST(XFILES)
 131 XFILES=""
 132 AC_SUBST(OPENGLFILES)
 133 OPENGLFILES=""
 134 AC_SUBST(OPENGL32_DLL)
 135 OPENGL32_DLL=""
 136 AC_SUBST(DGA_SRCS)
 137 DGA_SRCS=""
 138 AC_SUBST(DGA2_SRCS)
 139 DGA2_SRCS=""
 140 AC_SUBST(MESA_SRCS)
 141 MESA_SRCS=""
 142 if test "$have_x" = "yes"
 143 then
 144     XLIB="-lXext -lX11"
 145     ac_save_CPPFLAGS="$CPPFLAGS"
 146     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 147
 148     dnl *** Check for -lXpm
 149     AC_CHECK_HEADERS(X11/xpm.h,
 150       [ dnl *** If X11/xpm.h exists...
 151         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 152           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 153           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 154         )
 155       ],
 156       [ dnl *** If X11/xpm.h does not exist...
 157         dnl NOTE: autoconf does not allow commas inside the third
 158         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 159         dnl       magic it does.
 160         echo "Redhat            :       xpm xpm-devel"
 161         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 162         echo "SuSE              :       xpm"
 163         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 164         echo
 165         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 166         echo "the directory /contrib/libraries."
 167         echo
 168         exit 1
 169       ]
 170     )
 171
 172     dnl *** All three of the following tests require X11/Xlib.h
 173     AC_CHECK_HEADERS(X11/Xlib.h,
 174       [
 175         dnl *** Check for X Shm extension
 176         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 177             [ dnl *** If X11/extensions/XShm.h exists...
 178               AC_CHECK_LIB(Xext, XShmQueryExtension,
 179               AC_DEFINE(HAVE_LIBXXSHM),,
 180               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 181             ],
 182             AC_MSG_WARN([Xshm extension not found!!])
 183         )
 184
 185         dnl *** Check for X shape extension
 186         AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/shape.h,
 187             [ dnl *** If X11/extensions/shape.h exists...
 188               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 189               AC_DEFINE(HAVE_LIBXSHAPE),,
 190               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 191             ],
 192             AC_MSG_WARN([XShape extension found!!])
 193         )
 194
 195         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 196         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 197             [ dnl *** If X11/extensions/xf86dga.h exists, check
 198               dnl *** for XDGAQueryExtension()...
 199               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 200                 [ dnl *** If found...
 201                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 202                   AC_DEFINE(HAVE_LIBXXF86DGA)
 203                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 204                   DGA_SRCS='$(DGA_SRCS)'
 205                   DGA2_SRCS='$(DGA2_SRCS)'
 206                ],
 207                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 208                   dnl *** instead (DGA 2.0 not found)...
 209                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 210                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 211                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 212                       DGA_SRCS='$(DGA_SRCS)'
 213                     ],,
 214                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 215                   )
 216                 ],
 217                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 218               )
 219             ],
 220             AC_MSG_WARN([DGA extension not found!!])
 221         )
 222
 223         dnl *** Check for XFree86 VMODE extension
 224         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 225             [ dnl *** If X11/extensions/xf86vmode.h exists...
 226                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 227                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 228                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 229                   ],,
 230                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 231                 )
 232             ],
 233             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 234         )
 235
 236         dnl *** Check for XVideo extension supporting XvImages
 237         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 238             [ dnl *** If X11/extensions/Xvlib.h exists...
 239                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 240                   [ AC_DEFINE(HAVE_XVIDEO)
 241                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 242                   ],,
 243                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 244                 )
 245             ],
 246             AC_MSG_WARN([XVideo extension not found !!])
 247         )
 248
 249       ]
 250     ) dnl *** End of X11/Xlib.h check
 251
 252     dnl Check for the presence of OpenGL
 253     if test $OPENGL = "yes" -o $OPENGL = "normal"
 254     then
 255         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 256         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 257         then
 258             dnl Check for some problems due to old Mesa versions
 259             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 260               AC_TRY_COMPILE(
 261                 [#include <GL/gl.h>],
 262                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 263                 [wine_cv_opengl_version_OK="yes"],
 264                 [wine_cv_opengl_version_OK="no"]
 265               )
 266             )
 267
 268             dnl Check for the thread-safety of the OpenGL library
 269             AC_CACHE_CHECK("for thread-safe OpenGL version",
 270                            wine_cv_opengl_version_threadsafe,
 271               [saved_libs=$LIBS
 272                LIBS="$X_LIBS -lGL"
 273                AC_TRY_LINK([],[pthread_getspecific();],
 274                               [wine_cv_opengl_version_threadsafe="yes"],
 275                               [wine_cv_opengl_version_threadsafe="no"])
 276                LIBS=$saved_libs]
 277             )
 278
 279             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 280             then
 281                 dnl Check for the presence of the library
 282                 AC_CHECK_LIB(GL,glXCreateContext,
 283                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 284                              MESA_SRCS='$(MESA_SRCS)'
 285                              ,,
 286                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 287
 288                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 289                 then
 290
 291                         OPENGLFILES='$(OPENGLFILES)'
 292                         AC_DEFINE(HAVE_OPENGL)
 293
 294                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 295
 296                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 297                         then
 298                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 299                                   AC_TRY_COMPILE([#include <GL/gl.h>
 300                                                   #ifdef HAVE_GL_GLEXT_H
 301                                                   # include <GL/glext.h>
 302                                                   #endif
 303                                                   ],
 304                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 305                                                  [wine_cv_extension_prototypes="yes"],
 306                                                  [wine_cv_extension_prototypes="no"]
 307                                   )
 308                                 )
 309                                 if test $wine_cv_extension_prototypes = "yes"
 310                                 then
 311                                         AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 312                                 fi
 313
 314                                 OPENGL32_DLL=opengl32
 315                         fi
 316                 fi
 317              fi
 318          fi
 319     fi
 320
 321     CPPFLAGS="$ac_save_CPPFLAGS"
 322     X_DLLS='$(X_DLLS)'
 323     XFILES='$(XFILES)'
 324 else
 325     XLIB=""
 326     X_CFLAGS=""
 327     X_LIBS=""
 328 fi
 329
 330 dnl **** Check which curses lib to use ***
 331 if test "$CURSES" = "yes"
 332 then
 333     AC_CHECK_HEADERS(ncurses.h)
 334     if test "$ac_cv_header_ncurses_h" = "yes"
 335     then
 336         AC_CHECK_LIB(ncurses,waddch)
 337     fi
 338     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 339     then
 340         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 341         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 342     else
 343         AC_CHECK_HEADERS(curses.h)
 344         if test "$ac_cv_header_curses_h" = "yes"
 345         then
 346             AC_CHECK_LIB(curses,waddch)
 347             if test "$ac_cv_lib_curses_waddch" = "yes"
 348             then
 349                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 350                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 351             fi
 352         fi
 353     fi
 354 fi
 355
 356 dnl **** Check for IPX (currently Linux only) ****
 357 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 358  AC_TRY_COMPILE(
 359    [#include <sys/socket.h>
 360     #include <netipx/ipx.h>],
 361    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 362    [ac_cv_c_ipx_gnu="yes"],
 363    [ac_cv_c_ipx_gnu="no"])
 364  )
 365 if test "$ac_cv_c_ipx_gnu" = "yes"
 366 then
 367     AC_DEFINE(HAVE_IPX_GNU)
 368 fi
 369
 370 if test "$ac_cv_c_ipx_gnu" = "no"
 371 then
 372  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 373   AC_TRY_COMPILE(
 374     [#include <sys/socket.h>
 375      #include <asm/types.h>
 376      #include <linux/ipx.h>],
 377     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 378     [ac_cv_c_ipx_linux="yes"],
 379     [ac_cv_c_ipx_linux="no"])
 380   )
 381   if test "$ac_cv_c_ipx_linux" = "yes"
 382   then
 383       AC_DEFINE(HAVE_IPX_LINUX)
 384   fi
 385 fi
 386
 387 dnl **** Check for Open Sound System ****
 388 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 389
 390 AC_CACHE_CHECK("for Open Sound System",
 391         ac_cv_c_opensoundsystem,
 392         AC_TRY_COMPILE([
 393         #if defined(HAVE_SYS_SOUNDCARD_H)
 394                 #include <sys/soundcard.h>
 395         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 396                 #include <machine/soundcard.h>
 397         #elif defined(HAVE_SOUNDCARD_H)
 398                 #include <soundcard.h>
 399         #endif
 400         ],[
 401
 402 /* check for one of the Open Sound System specific SNDCTL_ defines */
 403 #if !defined(SNDCTL_DSP_STEREO)
 404 #error No open sound system
 405 #endif
 406 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 407
 408 if test "$ac_cv_c_opensoundsystem" = "yes"
 409 then
 410     AC_DEFINE(HAVE_OSS)
 411 fi
 412
 413 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 414         ac_cv_c_opensoundsystem_midi,
 415         AC_TRY_COMPILE([
 416         #if defined(HAVE_SYS_SOUNDCARD_H)
 417                 #include <sys/soundcard.h>
 418         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 419                 #include <machine/soundcard.h>
 420         #elif defined(HAVE_SOUNDCARD_H)
 421                 #include <soundcard.h>
 422         #endif
 423         ],[
 424
 425 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 426 #if !defined(SNDCTL_SEQ_SYNC)
 427 #error No open sound system MIDI interface
 428 #endif
 429 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 430
 431 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 432 then
 433     AC_DEFINE(HAVE_OSS_MIDI)
 434 fi
 435
 436 dnl **** If ln -s doesn't work, use cp instead ****
 437 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 438
 439 dnl **** Check for gcc strength-reduce bug ****
 440
 441 if test "x${GCC}" = "xyes"
 442 then
 443   CFLAGS="$CFLAGS -Wall"
 444   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 445                   AC_TRY_RUN([
 446 int     L[[4]] = {0,1,2,3};
 447 int main(void) {
 448   static int Array[[3]];
 449   unsigned int B = 3;
 450   int i;
 451   for(i=0; i<B; i++) Array[[i]] = i - 3;
 452   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 453   L[[i]] = 4;
 454
 455   exit( Array[[1]] != -2 || L[[2]] != 3);
 456 }],
 457     ac_cv_c_gcc_strength_bug="no",
 458     ac_cv_c_gcc_strength_bug="yes",
 459     ac_cv_c_gcc_strength_bug="yes") )
 460   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 461   then
 462     CFLAGS="$CFLAGS -fno-strength-reduce"
 463   fi
 464
 465   dnl Check for -mpreferred-stack-boundary
 466   AC_CACHE_CHECK("for gcc -mpreferred-stack-boundary=2 support",
 467                  ac_cv_c_gcc_stack_boundary,
 468   [saved_cflags=$CFLAGS
 469   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 470   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 471   CFLAGS=$saved_cflags
 472   ])
 473   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 474   then
 475     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 476   fi
 477 fi
 478
 479 dnl **** Check if we need to place .type inside a .def directive ****
 480
 481 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
 482                ac_cv_c_type_in_def,
 483 [saved_libs=$LIBS
 484 LIBS="conftest_asm.s $LIBS"
 485 cat > conftest_asm.s <<EOF
 486         .globl _ac_test
 487         .def _ac_test; .scl 2; .type 32; .endef
 488 _ac_test:
 489         .long 0
 490 EOF
 491 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 492 LIBS=$saved_libs])
 493 if test "$ac_cv_c_type_in_def" = "yes"
 494 then
 495   AC_DEFINE(NEED_TYPE_IN_DEF)
 496 fi
 497
 498 dnl **** Check for underscore on external symbols ****
 499
 500 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 501                ac_cv_c_extern_prefix,
 502 [saved_libs=$LIBS
 503 LIBS="conftest_asm.s $LIBS"
 504 cat > conftest_asm.s <<EOF
 505         .globl _ac_test
 506 _ac_test:
 507         .long 0
 508 EOF
 509 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 510             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 511 LIBS=$saved_libs])
 512 if test "$ac_cv_c_extern_prefix" = "yes"
 513 then
 514   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 515 fi
 516
 517 dnl **** Check for .string in assembler ****
 518
 519 AC_CACHE_CHECK("whether assembler accepts .string",
 520                ac_cv_c_asm_string,
 521 [saved_libs=$LIBS
 522 LIBS="conftest_asm.s $LIBS"
 523 cat > conftest_asm.s <<EOF
 524         .string "test"
 525 EOF
 526 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 527 LIBS=$saved_libs])
 528 if test "$ac_cv_c_asm_string" = "yes"
 529 then
 530   AC_DEFINE(HAVE_ASM_STRING)
 531 fi
 532
 533 dnl **** Check for working dll ****
 534
 535 LDSHARED=""
 536 LDDLLFLAGS=""
 537 if test "$LIBEXT" = "so"
 538 then
 539   AC_CACHE_CHECK("whether we can build a Linux dll",
 540                  ac_cv_c_dll_linux,
 541   [saved_cflags=$CFLAGS
 542   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 543   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 544   CFLAGS=$saved_cflags
 545   ])
 546   if test "$ac_cv_c_dll_linux" = "yes"
 547   then
 548     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%) -Wl,-rpath,\$(libdir)"
 549     LDDLLFLAGS="-Wl,-Bsymbolic"
 550   else
 551     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 552                  ac_cv_c_dll_unixware,
 553     [saved_cflags=$CFLAGS
 554     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 555     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 556     CFLAGS=$saved_cflags
 557     ])
 558     if test "$ac_cv_c_dll_unixware" = "yes"
 559     then
 560       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,h,\$(libdir)/%)"
 561       LDDLLFLAGS="-Wl,-B,symbolic"
 562     else
 563       AC_CACHE_CHECK("whether we can build a NetBSD dll",
 564                    ac_cv_c_dll_netbsd,
 565       [saved_cflags=$CFLAGS
 566       CFLAGS="$CFLAGS -fPIC -Wl,-Bshareable,-Bforcearchive"
 567       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 568       CFLAGS=$saved_cflags
 569       ])
 570       if test "$ac_cv_c_dll_netbsd" = "yes"
 571       then
 572         LDSHARED="\$(CC) -Wl,-Bshareable,-Bforcearchive"
 573         LDDLLFLAGS="" #FIXME
 574       fi
 575     fi
 576   fi
 577   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 578   then
 579     echo "*** It is currently not possible to build WINE without shared"
 580     echo "*** library (.so) support to allow transparent switch between .so"
 581     echo "*** and .dll files."
 582     echo "*** If you are using Linux, you will need a newer binutils."
 583     exit 1
 584   fi
 585 fi
 586
 587 DLLFLAGS=""
 588
 589 if test "$LIBEXT" = "so"; then
 590     DLLFLAGS="-fPIC"
 591     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 592 else
 593     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) \$(LIBWINE) \$(LIBUNICODE) \$(X_LIBS) \$(XLIB)"
 594     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 595                    ac_cv_c_whole_archive,
 596             [saved_cflags=$CFLAGS
 597             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 598             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 599             CFLAGS=$saved_cflags
 600             ])
 601     if test "$ac_cv_c_whole_archive" = "yes"
 602     then
 603         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 604     else
 605         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 606                        ac_cv_c_allextract,
 607                 [saved_cflags=$CFLAGS
 608                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 609                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 610                 CFLAGS=$saved_cflags
 611                 ])
 612         if test "$ac_cv_c_allextract" = "yes"
 613         then
 614             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 615         fi
 616     fi
 617 fi
 618
 619 AC_SUBST(DLL_LINK)
 620 AC_SUBST(DLLFLAGS)
 621 AC_SUBST(LDSHARED)
 622 AC_SUBST(LDDLLFLAGS)
 623 AC_SUBST(LIBEXT)
 624
 625 dnl **** Check for reentrant libc ****
 626 dnl
 627 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 628 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 629
 630 wine_cv_libc_reentrant=no
 631 dnl
 632 dnl Linux style errno location
 633 dnl
 634 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 635   [AC_TRY_RUN([int myerrno = 0;
 636 char buf[256];
 637 int *__errno_location(){return &myerrno;}
 638 main(){connect(0,buf,255); exit(!myerrno);}],
 639   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 640   wine_cv_libc_r__errno_location=yes )
 641 ])
 642 if test "$wine_cv_libc_r__errno_location" = "yes"
 643 then
 644     AC_DEFINE(HAVE__ERRNO_LOCATION)
 645     wine_cv_libc_reentrant=__errno_location
 646 fi
 647 dnl
 648 dnl FreeBSD style errno location
 649 dnl
 650 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 651   [AC_TRY_RUN([int myerrno = 0;
 652 char buf[256];
 653 int *__error(){return &myerrno;}
 654 main(){connect(0,buf,255); exit(!myerrno);}],
 655     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 656     wine_cv_libc_r__error=yes )
 657 ])
 658 if test "$wine_cv_libc_r__error" = "yes"
 659 then
 660     AC_DEFINE(HAVE__ERROR)
 661     wine_cv_libc_reentrant=__error
 662 fi
 663 dnl
 664 dnl Solaris style errno location
 665 dnl
 666 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 667   [AC_TRY_RUN([int myerrno = 0;
 668 char buf[256];
 669 int *___errno(){return &myerrno;}
 670 main(){connect(0,buf,255); exit(!myerrno);}],
 671     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 672     wine_cv_libc_r___errno=yes )
 673 ])
 674 if test "$wine_cv_libc_r___errno" = "yes"
 675 then
 676     AC_DEFINE(HAVE___ERRNO)
 677     wine_cv_libc_reentrant=___errno
 678 fi
 679 dnl
 680 dnl UnixWare style errno location
 681 dnl
 682 AC_CACHE_CHECK("for reentrant libc: __thr_errno", wine_cv_libc_r__thr_errno,
 683   [AC_TRY_RUN([int myerrno = 0;
 684 char buf[256];
 685 int *__thr_errno(){return &myerrno;}
 686 main(){connect(0,buf,255); exit(!myerrno);}],
 687     wine_cv_libc_r__thr_errno=yes, wine_cv_libc_r__thr_errno=no,
 688     wine_cv_libc_r__thr_errno=yes )
 689 ])
 690 if test "$wine_cv_libc_r__thr_errno" = "yes"
 691 then
 692     AC_DEFINE(HAVE__THR_ERRNO)
 693     wine_cv_libc_reentrant=__thr_errno
 694 fi
 695 if test "$wine_cv_libc_reentrant" = "no"
 696 then
 697   AC_DEFINE(NO_REENTRANT_LIBC)
 698 fi
 699
 700 dnl **** Check for reentrant X libraries ****
 701 dnl
 702 dnl This may fail to determine whether X libraries are reentrant if
 703 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 704 dnl is possible with the --without-reentrant-x option.
 705
 706 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 707 then
 708 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 709   [ if test "x$with_reentrant_x" = "xno"
 710     then
 711         wine_cv_x_reentrant=no
 712     else
 713         libX11_check=none
 714         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 715             if test -r $dir/libX11.so; then
 716                 libX11_check="-D $dir/libX11.so"
 717                 break 1
 718             fi
 719             if test -r $dir/libX11.a; then
 720                 libX11_check="$dir/libX11.a"
 721                 break 1
 722             fi
 723         done
 724         if test "$libX11_check" != "none"; then
 725             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 726             then
 727                 wine_cv_x_reentrant=yes
 728             else
 729                 wine_cv_x_reentrant=no
 730             fi
 731         else
 732             wine_cv_x_reentrant=unknown
 733         fi
 734     fi ] )
 735 else
 736     wine_cv_x_reentrant=no
 737 fi
 738 if test "$wine_cv_x_reentrant" = "no"
 739 then
 740   AC_DEFINE(NO_REENTRANT_X11)
 741 fi
 742
 743 dnl **** Check for endianness ****
 744
 745 AC_C_BIGENDIAN
 746
 747 dnl **** Check for functions ****
 748
 749 AC_FUNC_ALLOCA()
 750 AC_CHECK_FUNCS(\
 751         __libc_fork \
 752         _lwp_create \
 753         clone \
 754         finite \
 755         fpclass \
 756         getnetbyaddr \
 757         getnetbyname \
 758         getpagesize \
 759         getprotobyname \
 760         getprotobynumber \
 761         getrlimit \
 762         getservbyport \
 763         getsockopt \
 764         inet_network \
 765         lstat \
 766         memmove \
 767         mmap \
 768         rfork \
 769         select \
 770         sendmsg \
 771         settimeofday \
 772         sigaltstack \
 773         statfs \
 774         strcasecmp \
 775         strerror \
 776         strncasecmp \
 777         tcgetattr \
 778         timegm \
 779         usleep \
 780         vfscanf \
 781         wait4 \
 782         waitpid \
 783 )
 784
 785 dnl **** Check for header files ****
 786
 787 AC_CHECK_HEADERS(\
 788         arpa/inet.h \
 789         arpa/nameser.h \
 790         elf.h \
 791         float.h \
 792         libio.h \
 793         libutil.h \
 794         link.h \
 795         linux/cdrom.h \
 796         linux/joystick.h \
 797         linux/ucdrom.h \
 798         net/if.h \
 799         netdb.h \
 800         netinet/in.h \
 801         netinet/in_systm.h \
 802         netinet/ip.h \
 803         netinet/tcp.h \
 804         pty.h \
 805         resolv.h \
 806         sched.h \
 807         socket.h \
 808         strings.h \
 809         sys/cdio.h \
 810         sys/errno.h \
 811         sys/file.h \
 812         sys/filio.h \
 813         sys/ipc.h \
 814         sys/lwp.h \
 815         sys/mman.h \
 816         sys/modem.h \
 817         sys/mount.h \
 818         sys/msg.h \
 819         sys/param.h \
 820         sys/ptrace.h \
 821         sys/reg.h \
 822         sys/signal.h \
 823         sys/shm.h \
 824         sys/socket.h \
 825         sys/sockio.h \
 826         sys/statfs.h \
 827         sys/strtio.h \
 828         sys/syscall.h \
 829         sys/user.h \
 830         sys/wait.h \
 831         sys/v86.h \
 832         sys/v86intr.h \
 833         sys/vfs.h \
 834         sys/vm86.h \
 835         syscall.h \
 836         ucontext.h \
 837 )
 838 AC_HEADER_STAT()
 839
 840 dnl **** Check for types ****
 841
 842 AC_C_CONST()
 843 AC_C_INLINE()
 844 AC_TYPE_SIZE_T()
 845 AC_CHECK_SIZEOF(long long,0)
 846
 847
 848 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
 849         wine_cv_linux_gethostbyname_r_6,
 850         AC_TRY_COMPILE([
 851 #include <netdb.h>
 852         ], [
 853     char *name=NULL;
 854     struct hostent he;
 855     struct hostent *result;
 856     char *buf=NULL;
 857     int bufsize=0;
 858     int res,errnr;
 859     char *addr=NULL;
 860     int addrlen=0;
 861     int addrtype=0;
 862     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 863     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 864     ],
 865         wine_cv_linux_gethostbyname_r_6=yes,
 866         wine_cv_linux_gethostbyname_r_6=no
 867         )
 868    )
 869    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 870    then
 871       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6)
 872    fi
 873
 874 if test "$ac_cv_header_linux_joystick_h" = "yes"
 875 then
 876    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 877         wine_cv_linux_joystick_22_api,
 878         AC_TRY_COMPILE([
 879         #include <sys/ioctl.h>
 880         #include <linux/joystick.h>
 881
 882         struct js_event blub;
 883         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 884         #error "no 2.2 header"
 885         #endif
 886         ],/*empty*/,
 887         wine_cv_linux_joystick_22_api=yes,
 888         wine_cv_linux_joystick_22_api=no,
 889         wine_cv_linux_joystick_22_api=no
 890         )
 891    )
 892    if test "$wine_cv_linux_joystick_22_api" = "yes"
 893    then
 894       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 895    fi
 896 fi
 897
 898 dnl **** statfs checks ****
 899
 900 if test "$ac_cv_header_sys_vfs_h" = "yes"
 901 then
 902     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 903                     wine_cv_sys_vfs_has_statfs,
 904         AC_TRY_COMPILE([
 905         #include <sys/types.h>
 906         #ifdef HAVE_SYS_PARAM_H
 907         # include <sys/param.h>
 908         #endif
 909         #include <sys/vfs.h>
 910         ],[
 911                 struct statfs stfs;
 912
 913                 memset(&stfs,0,sizeof(stfs));
 914         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 915         )
 916     )
 917     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 918     then
 919       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 920     fi
 921 fi
 922
 923 if test "$ac_cv_header_sys_statfs_h" = "yes"
 924 then
 925     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 926                     wine_cv_sys_statfs_has_statfs,
 927         AC_TRY_COMPILE([
 928         #include <sys/types.h>
 929         #ifdef HAVE_SYS_PARAM_H
 930         # include <sys/param.h>
 931         #endif
 932         #include <sys/statfs.h>
 933         ],[
 934                 struct statfs stfs;
 935         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 936         )
 937     )
 938     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 939     then
 940       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 941     fi
 942 fi
 943
 944 if test "$ac_cv_header_sys_mount_h" = "yes"
 945 then
 946     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 947                     wine_cv_sys_mount_has_statfs,
 948         AC_TRY_COMPILE([
 949         #include <sys/types.h>
 950         #ifdef HAVE_SYS_PARAM_H
 951         # include <sys/param.h>
 952         #endif
 953         #include <sys/mount.h>
 954         ],[
 955                 struct statfs stfs;
 956         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 957         )
 958     )
 959     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 960     then
 961       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 962     fi
 963 fi
 964
 965 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 966
 967 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 968   [ if test "x$statfs_bfree" = "xno"
 969     then
 970         wine_cv_statfs_bfree=no
 971     else
 972         AC_TRY_COMPILE([
 973         #include <sys/types.h>
 974         #ifdef HAVE_SYS_PARAM_H
 975         # include <sys/param.h>
 976         #endif
 977         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 978         # include <sys/mount.h>
 979         #else
 980         # ifdef STATFS_DEFINED_BY_SYS_VFS
 981         #  include <sys/vfs.h>
 982         # else
 983         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 984         #   include <sys/statfs.h>
 985         #  endif
 986         # endif
 987         #endif
 988         ],[
 989                 struct statfs stfs;
 990
 991                 stfs.f_bfree++;
 992         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 993         )
 994     fi ] )
 995 if test "$wine_cv_statfs_bfree" = "yes"
 996 then
 997   AC_DEFINE(STATFS_HAS_BFREE)
 998 fi
 999
1000 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
1001   [ if test "x$statfs_bavail" = "xno"
1002     then
1003         wine_cv_statfs_bavail=no
1004     else
1005         AC_TRY_COMPILE([
1006         #include <sys/types.h>
1007         #ifdef HAVE_SYS_PARAM_H
1008         # include <sys/param.h>
1009         #endif
1010         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1011         # include <sys/mount.h>
1012         #else
1013         # ifdef STATFS_DEFINED_BY_SYS_VFS
1014         #  include <sys/vfs.h>
1015         # else
1016         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1017         #   include <sys/statfs.h>
1018         #  endif
1019         # endif
1020         #endif
1021         ],[
1022                 struct statfs stfs;
1023
1024                 stfs.f_bavail++;
1025         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1026         )
1027     fi ] )
1028 if test "$wine_cv_statfs_bavail" = "yes"
1029 then
1030   AC_DEFINE(STATFS_HAS_BAVAIL)
1031 fi
1032
1033 dnl *** check for file descriptor passing with msg_accrights
1034
1035 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1036  AC_TRY_COMPILE([#include <sys/types.h>
1037 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1038                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1039 if test "$ac_cv_c_msg_accrights" = "yes"
1040 then
1041     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
1042 fi
1043
1044 dnl *** Check for the sun_len member in struct sockaddr_un
1045
1046 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
1047  AC_TRY_COMPILE([#include <sys/types.h>
1048 #include <sys/socket.h>
1049 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1050                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
1051 if test "$ac_cv_c_sun_len" = "yes"
1052 then
1053     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
1054 fi
1055
1056 dnl *** check for the need to define __i386__
1057
1058 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1059  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1060 yes
1061 #endif],
1062  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1063 if test "$ac_cv_cpp_def_i386" = "yes"
1064 then
1065     CFLAGS="$CFLAGS -D__i386__"
1066     LINTFLAGS="$LINTFLAGS -D__i386__"
1067 fi
1068
1069 dnl $GCC is set by autoconf
1070 GCC_NO_BUILTIN=""
1071 if test "$GCC" = "yes"
1072 then
1073     GCC_NO_BUILTIN="-fno-builtin"
1074 fi
1075 AC_SUBST(GCC_NO_BUILTIN)
1076
1077 dnl **** Generate output files ****
1078
1079 AC_OUTPUT_COMMANDS([
1080 extra_subdirs="\
1081 dlls/ddraw/d3ddevice \
1082 dlls/ddraw/dclipper \
1083 dlls/ddraw/ddraw \
1084 dlls/ddraw/direct3d \
1085 dlls/ddraw/dpalette \
1086 dlls/ddraw/dsurface \
1087 dlls/dinput/joystick \
1088 dlls/dinput/keyboard \
1089 dlls/dinput/mouse \
1090 dlls/kernel/messages \
1091 dlls/user/resources \
1092 "
1093 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1094
1095 MAKE_RULES=Make.rules
1096 AC_SUBST_FILE(MAKE_RULES)
1097
1098 MAKE_DLL_RULES=dlls/Makedll.rules
1099 AC_SUBST_FILE(MAKE_DLL_RULES)
1100
1101 MAKE_PROG_RULES=programs/Makeprog.rules
1102 AC_SUBST_FILE(MAKE_PROG_RULES)
1103
1104 AC_OUTPUT([
1105 Make.rules
1106 dlls/Makedll.rules
1107 programs/Makeprog.rules
1108 Makefile
1109 console/Makefile
1110 controls/Makefile
1111 debugger/Makefile
1112 dlls/Makefile
1113 dlls/advapi32/Makefile
1114 dlls/avifil32/Makefile
1115 dlls/comctl32/Makefile
1116 dlls/commdlg/Makefile
1117 dlls/crtdll/Makefile
1118 dlls/dciman32/Makefile
1119 dlls/ddraw/Makefile
1120 dlls/dinput/Makefile
1121 dlls/dplay/Makefile
1122 dlls/dplayx/Makefile
1123 dlls/dsound/Makefile
1124 dlls/gdi/Makefile
1125 dlls/icmp/Makefile
1126 dlls/imagehlp/Makefile
1127 dlls/imm32/Makefile
1128 dlls/kernel/Makefile
1129 dlls/lzexpand/Makefile
1130 dlls/mpr/Makefile
1131 dlls/msacm/Makefile
1132 dlls/msnet32/Makefile
1133 dlls/msvideo/Makefile
1134 dlls/ntdll/Makefile
1135 dlls/odbc32/Makefile
1136 dlls/ole32/Makefile
1137 dlls/oleaut32/Makefile
1138 dlls/olecli/Makefile
1139 dlls/oledlg/Makefile
1140 dlls/olepro32/Makefile
1141 dlls/olesvr/Makefile
1142 dlls/opengl32/Makefile
1143 dlls/psapi/Makefile
1144 dlls/rasapi32/Makefile
1145 dlls/richedit/Makefile
1146 dlls/rpcrt4/Makefile
1147 dlls/serialui/Makefile
1148 dlls/setupapi/Makefile
1149 dlls/shell32/Makefile
1150 dlls/shfolder/Makefile
1151 dlls/shlwapi/Makefile
1152 dlls/tapi32/Makefile
1153 dlls/ttydrv/Makefile
1154 dlls/urlmon/Makefile
1155 dlls/user/Makefile
1156 dlls/version/Makefile
1157 dlls/win32s/Makefile
1158 dlls/winaspi/Makefile
1159 dlls/wineps/Makefile
1160 dlls/wininet/Makefile
1161 dlls/winmm/Makefile
1162 dlls/winmm/joystick/Makefile
1163 dlls/winmm/mcianim/Makefile
1164 dlls/winmm/mciavi/Makefile
1165 dlls/winmm/mcicda/Makefile
1166 dlls/winmm/mciseq/Makefile
1167 dlls/winmm/mciwave/Makefile
1168 dlls/winmm/midimap/Makefile
1169 dlls/winmm/wavemap/Makefile
1170 dlls/winmm/wineoss/Makefile
1171 dlls/winsock/Makefile
1172 dlls/winspool/Makefile
1173 dlls/wow32/Makefile
1174 dlls/wsock32/Makefile
1175 dlls/x11drv/Makefile
1176 documentation/Makefile
1177 documentation/wine.conf.man
1178 documentation/wine.man
1179 files/Makefile
1180 graphics/Makefile
1181 graphics/enhmetafiledrv/Makefile
1182 graphics/metafiledrv/Makefile
1183 graphics/win16drv/Makefile
1184 graphics/x11drv/Makefile
1185 if1632/Makefile
1186 include/Makefile
1187 library/Makefile
1188 libtest/Makefile
1189 loader/Makefile
1190 loader/dos/Makefile
1191 loader/ne/Makefile
1192 memory/Makefile
1193 misc/Makefile
1194 miscemu/Makefile
1195 msdos/Makefile
1196 objects/Makefile
1197 ole/Makefile
1198 programs/Makefile
1199 programs/avitools/Makefile
1200 programs/clock/Makefile
1201 programs/cmdlgtst/Makefile
1202 programs/control/Makefile
1203 programs/notepad/Makefile
1204 programs/osversioncheck/Makefile
1205 programs/progman/Makefile
1206 programs/regapi/Makefile
1207 programs/regtest/Makefile
1208 programs/uninstaller/Makefile
1209 programs/view/Makefile
1210 programs/wcmd/Makefile
1211 programs/winemine/Makefile
1212 programs/winhelp/Makefile
1213 programs/winver/Makefile
1214 relay32/Makefile
1215 scheduler/Makefile
1216 server/Makefile
1217 tools/Makefile
1218 tools/cvdump/Makefile
1219 tools/winebuild/Makefile
1220 tools/winelauncher
1221 tools/wmc/Makefile
1222 tools/wrc/Makefile
1223 tsx11/Makefile
1224 unicode/Makefile
1225 win32/Makefile
1226 windows/Makefile
1227 windows/x11drv/Makefile ])
1228
1229 if test "$have_x" = "no"
1230 then
1231   echo
1232   echo "*** Warning: X development files not found. Wine will be built without"
1233   echo "*** X support, which currently does not work, and would probably not be"
1234   echo "*** what you want anyway. You will need to install devel packages of"
1235   echo "*** Xlib/Xfree86 and Xpm at the very least."
1236 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1237 then
1238   echo
1239   echo "*** Warning: Xpm development files not found. Wine will be built without"
1240   echo "*** Xpm support, which currently does not work. You will need to install"
1241   echo "*** devel packages of Xpm."
1242 fi
1243
1244 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1245 then
1246   echo
1247   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1248   echo "*** terminal resize support. Consider upgrading ncurses."
1249 fi
1250
1251 if test "$wine_cv_libc_reentrant" = "no"
1252 then
1253   echo
1254   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1255   echo "*** thread support. Consider upgrading libc to a more recent"
1256   echo "*** reentrant version of libc."
1257 fi
1258
1259 if test "$wine_cv_opengl_version_OK" = "no"
1260 then
1261   echo
1262   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1263   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1264 fi
1265
1266 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1267 then
1268   echo
1269   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1270   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1271   echo "*** A fix for glibc 2.1.3 that seem to work is included in this version of Wine,"
1272   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1273 fi
1274
1275 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1276 then
1277   echo
1278   echo "*** Warning: you explicitely linked in a thread-safe OpenGL version. If you"
1279   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1280   echo "*** support before reporting bugs."
1281 fi
1282
1283
1284 echo
1285 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1286 echo
1287
1288 dnl Local Variables:
1289 dnl comment-start: "dnl "
1290 dnl comment-end: ""
1291 dnl comment-start-skip: "\\bdnl\\b\\s *"
1292 dnl compile-command: "autoconf"
1293 dnl End: