| blob | 41108dab9c83235fd387236b2f95b9feb6c0b24a |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(DLLDEFS,"")
25 if test "x$enable_debug" = "xno"
26 then
27 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
32 fi
34 AC_CANONICAL_HOST
35 case $host in
36 x86_64*linux*)
37 if test "x$enable_win64" != "xyes"
38 then
39 test -n "$CC" || CC="gcc -m32"
40 test -n "$LD" || LD="ld -m elf_i386"
41 test -n "$AS" || AS="as --32"
42 host_cpu="i386"
43 fi
44 ;;
45 esac
47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
48 case $host_cpu in
49 *i[[3456789]]86*)
50 if test "x$enable_win16" != "xno"
51 then
52 enable_win16="yes"
53 fi
54 ;;
55 esac
57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
59 if test "x$enable_win16" != "xyes"
60 then
61 WIN16_FILES=""
62 WIN16_INSTALL=""
63 fi
65 dnl **** Check for some programs ****
67 AC_PROG_MAKE_SET
68 AC_PROG_CC
69 AC_PROG_CXX
70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
74 [if test -z "$with_wine_tools"; then
75 if test "$cross_compiling" = "yes"; then
76 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
77 else
78 wine_cv_toolsdir="\$(TOPOBJDIR)"
79 fi
80 elif test -d "$with_wine_tools/tools/winebuild"; then
81 case $with_wine_tools in
82 /*) wine_cv_toolsdir="$with_wine_tools" ;;
83 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
84 esac
85 else
86 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
87 fi])
88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
90 AC_PATH_XTRA
91 AC_PROG_LEX
93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
94 dnl **** without one present.
95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
96 if test "$XLEX" = "none"
97 then
98 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
99 fi
101 dnl Check for bison
102 AC_CHECK_PROGS(BISON,bison,none)
103 if test "$BISON" = "none"
104 then
105 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
106 fi
108 AC_CHECK_TOOLS(AS,[gas as],as)
109 AC_CHECK_TOOL(LD,ld,ld)
110 AC_CHECK_TOOL(AR,ar,ar)
111 AC_PROG_RANLIB
112 AC_CHECK_TOOL(STRIP,strip,strip)
113 AC_CHECK_TOOL(WINDRES,windres,false)
114 AC_PROG_LN_S
115 WINE_PROG_LN
116 AC_PROG_EGREP
117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
118 AC_PROG_INSTALL
119 dnl Prepend src dir to install path dir if it's a relative path
120 case "$INSTALL" in
121 [[\\/$]]* | ?:[[\\/]]* ) ;;
122 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
123 esac
125 dnl Check for lint
126 AC_CHECK_PROGS(LINT, lclint lint)
127 if test "$LINT" = "lint"
128 then
129 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
130 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
131 fi
132 AC_SUBST(LINT)
133 AC_SUBST(LINTFLAGS)
135 dnl Check for various programs
136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
138 dnl **** Check for some libraries ****
140 dnl Check for -li386 for NetBSD and OpenBSD
141 AC_CHECK_LIB(i386,i386_set_ldt)
142 dnl Check for -lossaudio for NetBSD
143 AC_CHECK_LIB(ossaudio,_oss_ioctl)
144 dnl Check for -lw for Solaris
145 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
146 dnl Check for -lnsl for Solaris
147 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
148 dnl Check for -lsocket for Solaris
149 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
150 dnl Check for -lresolv for Solaris
151 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
152 dnl Check for -lxpg4 for FreeBSD
153 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
154 dnl Check for -lpoll for Mac OS X/Darwin
155 AC_CHECK_LIB(poll,poll)
156 dnl Check for -lresolv for Mac OS X/Darwin
157 AC_CHECK_LIB(resolv,res_9_init)
158 dnl Check for -lpthread
159 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
161 AC_SUBST(XLIB)
162 AC_SUBST(XFILES)
163 XFILES=""
164 AC_SUBST(OPENGLFILES)
165 OPENGLFILES=""
166 AC_SUBST(GLU32FILES)
167 GLU32FILES=""
168 AC_SUBST(OPENGL_LIBS)
169 OPENGL_LIBS=""
171 dnl **** Check for header files ****
173 AC_CHECK_HEADERS(\
174 IOKit/IOKitLib.h \
175 arpa/inet.h \
176 arpa/nameser.h \
177 asm/types.h \
178 cups/cups.h \
179 direct.h \
180 elf.h \
181 float.h \
182 fontconfig/fontconfig.h \
183 getopt.h \
184 gif_lib.h \
185 ieeefp.h \
186 io.h \
187 jack/jack.h \
188 jpeglib.h \
189 lcms/lcms.h \
190 lcms.h \
191 link.h \
192 linux/cdrom.h \
193 linux/compiler.h \
194 linux/hdreg.h \
195 linux/input.h \
196 linux/ioctl.h \
197 linux/joystick.h \
198 linux/major.h \
199 linux/param.h \
200 linux/serial.h \
201 linux/ucdrom.h \
202 mach/machine.h \
203 machine/cpu.h \
204 machine/limits.h \
205 mntent.h \
206 netdb.h \
207 netinet/in.h \
208 netinet/in_systm.h \
209 netinet/tcp.h \
210 netinet/tcp_fsm.h \
211 openssl/ssl.h \
212 poll.h \
213 process.h \
214 pthread.h \
215 pwd.h \
216 regex.h \
217 sched.h \
218 scsi/sg.h \
219 scsi/scsi.h \
220 scsi/scsi_ioctl.h \
221 stdint.h \
222 strings.h \
223 sys/cdio.h \
224 sys/elf32.h \
225 sys/errno.h \
226 sys/epoll.h \
227 sys/exec_elf.h \
228 sys/filio.h \
229 sys/ioctl.h \
230 sys/ipc.h \
231 sys/link.h \
232 sys/lwp.h \
233 sys/mman.h \
234 sys/modem.h \
235 sys/msg.h \
236 sys/param.h \
237 sys/poll.h \
238 sys/ptrace.h \
239 sys/reg.h \
240 sys/scsiio.h \
241 sys/shm.h \
242 sys/signal.h \
243 sys/socket.h \
244 sys/sockio.h \
245 sys/statfs.h \
246 sys/statvfs.h \
247 sys/strtio.h \
248 sys/syscall.h \
249 sys/sysctl.h \
250 sys/time.h \
251 sys/times.h \
252 sys/uio.h \
253 sys/un.h \
254 sys/vfs.h \
255 sys/vm86.h \
256 sys/wait.h \
257 syscall.h \
258 termios.h \
259 unistd.h \
260 utime.h \
261 valgrind/memcheck.h
262 )
263 AC_HEADER_STAT()
265 dnl **** Check for X11 ****
267 if test "$have_x" = "yes"
268 then
269 XLIB="-lXext -lX11"
270 ac_save_CPPFLAGS="$CPPFLAGS"
271 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
273 dnl *** All of the following tests require X11/Xlib.h
274 AC_CHECK_HEADERS(X11/Xlib.h,
275 [
276 AC_CHECK_HEADERS([X11/XKBlib.h \
277 X11/Xutil.h \
278 X11/extensions/shape.h \
279 X11/extensions/XInput.h \
280 X11/extensions/XShm.h \
281 X11/extensions/Xrandr.h \
282 X11/extensions/Xrender.h \
283 X11/extensions/xf86dga.h \
284 X11/extensions/xf86vmode.h],,,
285 [#include <X11/Xlib.h>
286 #ifdef HAVE_X11_XUTIL_H
287 # include <X11/Xutil.h>
288 #endif])
290 dnl *** Check for X keyboard extension
291 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
292 then
293 AC_CHECK_LIB(X11, XkbQueryExtension,
294 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
295 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
296 fi
298 dnl *** Check for X Shm extension
299 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
300 then
301 AC_CHECK_LIB(Xext, XShmQueryExtension,
302 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
303 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
304 fi
306 dnl *** Check for X shape extension
307 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
308 then
309 AC_CHECK_LIB(Xext,XShapeQueryExtension,
310 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
311 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
312 fi
314 dnl *** Check for XFree86 DGA / DGA 2.0 extension
315 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
316 then
317 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
318 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
319 [Define if you have the Xxf86dga library version 2])
320 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
321 ],,
322 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
323 fi
325 dnl *** Check for XFree86 VMODE extension
326 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
327 then
328 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
329 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
330 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
331 ],,
332 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
333 fi
335 dnl *** Check for X RandR extension
336 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
337 then
338 AC_TRY_COMPILE([#include <X11/Xlib.h>
339 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
340 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
341 fi
343 dnl *** Check for Transform functions in Xrender
344 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
345 then
346 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
347 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
348 [Define if Xrender has the XRenderSetPictureTransform function])],,
349 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
350 fi
351 ]
352 ) dnl *** End of X11/Xlib.h check
354 dnl Check for the presence of OpenGL
355 if test "x$with_opengl" != "xno"
356 then
357 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so -a ! -f /usr/X11R6/lib/libGL.dylib
358 then
359 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
360 This prevents linking to OpenGL. Delete the file and restart configure.])
361 fi
363 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
364 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
365 then
366 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
367 dnl Check for some problems due to old Mesa versions
368 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
369 AC_TRY_COMPILE(
370 [#include <GL/gl.h>],
371 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
372 [wine_cv_opengl_version_OK="yes"],
373 [wine_cv_opengl_version_OK="no"]
374 )
375 )
377 if test "$wine_cv_opengl_version_OK" = "yes"
378 then
379 dnl Check for the presence of the library
380 AC_CHECK_LIB(GL,glXCreateContext,
381 OPENGL_LIBS="-lGL"
382 ,,
383 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
385 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
386 then
387 OPENGLFILES='$(OPENGLFILES)'
388 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
389 fi
390 dnl Check for GLU32 library.
391 AC_CHECK_LIB(GLU,gluLookAt,
392 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
393 GLU32FILES='$(GLU32FILES)']
394 ,,
395 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
396 )
397 fi
399 dnl Check for glut32 library.
400 AC_CHECK_LIB(glut,glutMainLoop,
401 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
402 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
403 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
404 fi
405 fi
407 dnl **** Check for NAS ****
408 AC_SUBST(NASLIBS,"")
409 AC_CHECK_HEADERS(audio/audiolib.h,
410 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
411 AC_CHECK_LIB(audio,AuCreateFlow,
412 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
413 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
414 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
416 CPPFLAGS="$ac_save_CPPFLAGS"
417 XFILES='$(XFILES)'
418 else
419 XLIB=""
420 X_CFLAGS=""
421 X_LIBS=""
422 fi
424 dnl **** Check which curses lib to use ***
425 CURSESLIBS=""
426 if test "x$with_curses" != "xno"
427 then
428 AC_CHECK_HEADERS(ncurses.h,
429 [AC_CHECK_LIB(ncurses,waddch,
430 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
431 CURSESLIBS="-lncurses"],
432 [AC_CHECK_HEADERS(curses.h,
433 [AC_CHECK_LIB(curses,waddch,
434 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
435 CURSESLIBS="-lcurses"])])])])
436 fi
437 AC_SUBST(CURSESLIBS)
439 dnl **** Check for SANE ****
440 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
441 if test "$sane_devel" = "no"
442 then
443 SANELIBS=""
444 SANEINCL=""
445 else
446 SANELIBS="`$sane_devel --libs`"
447 SANEINCL="`$sane_devel --cflags`"
448 ac_save_CPPFLAGS="$CPPFLAGS"
449 ac_save_LIBS="$LIBS"
450 CPPFLAGS="$CPPFLAGS $SANEINCL"
451 LIBS="$LIBS $SANELIBS"
452 AC_CHECK_HEADER(sane/sane.h,
453 [AC_CHECK_LIB(sane,sane_open,
454 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
455 [SANELIBS=""
456 SANEINCL=""])],
457 [SANELIBS=""
458 SANEINCL=""])
459 LIBS="$ac_save_LIBS"
460 CPPFLAGS="$ac_save_CPPFLAGS"
461 fi
462 AC_SUBST(SANELIBS)
463 AC_SUBST(SANEINCL)
465 dnl **** Check for the ICU library ****
466 AC_CHECK_HEADERS(unicode/ubidi.h)
467 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
468 then
469 saved_libs="$LIBS"
470 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
471 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
472 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
473 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
474 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
475 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
476 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
477 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
478 AC_MSG_RESULT(yes)],
479 [AC_MSG_RESULT(no)])
480 LIBS="$saved_libs"
481 fi
483 dnl **** Check for LittleCMS ***
484 AC_SUBST(LCMSLIBS,"")
485 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
486 then
487 AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
488 [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
489 LCMSLIBS="-llcms"])
490 fi
492 dnl **** Check for FreeType 2 ****
493 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
494 if test "$ft_lib" = "no"
495 then
496 FREETYPELIBS=""
497 FREETYPEINCL=""
498 wine_cv_msg_freetype=no
499 else
500 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
501 if test "$ft_devel" = "no"
502 then
503 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
504 if test "$ft_devel2" = "freetype2-config"
505 then
506 ft_devel=$ft_devel2
507 fi
508 fi
509 if test "$ft_devel" = "no"
510 then
511 FREETYPELIBS=""
512 FREETYPEINCL=""
513 wine_cv_msg_freetype=yes
514 else
515 FREETYPELIBS=`$ft_devel --libs`
516 FREETYPEINCL=`$ft_devel --cflags`
517 ac_save_CPPFLAGS="$CPPFLAGS"
518 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
519 AC_CHECK_HEADERS(ft2build.h \
520 freetype/freetype.h \
521 freetype/ftglyph.h \
522 freetype/tttables.h \
523 freetype/ftnames.h \
524 freetype/ftsnames.h \
525 freetype/ttnameid.h \
526 freetype/ftoutln.h \
527 freetype/ftwinfnt.h \
528 freetype/internal/sfnt.h,,,
529 [#if HAVE_FT2BUILD_H
530 #include <ft2build.h>
531 #endif])
532 AC_TRY_CPP([#include <ft2build.h>
533 #include <freetype/fttrigon.h>],
534 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
535 [Define if you have the <freetype/fttrigon.h> header file.])
536 wine_cv_fttrigon=yes],
537 wine_cv_fttrigon=no)
538 CPPFLAGS="$ac_save_CPPFLAGS"
539 dnl Check that we have at least freetype/freetype.h
540 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
541 then
542 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
543 wine_cv_msg_freetype=no
544 else
545 FREETYPELIBS=""
546 FREETYPEINCL=""
547 wine_cv_msg_freetype=yes
548 fi
549 fi
550 fi
551 AC_SUBST(FREETYPELIBS)
552 AC_SUBST(FREETYPEINCL)
554 dnl Only build the fonts dir if we have both freetype and fontforge
555 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
556 then
557 AC_SUBST(FONTSSUBDIRS,"fonts")
558 fi
560 dnl **** Check for parport (currently Linux only) ****
561 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
562 AC_TRY_COMPILE(
563 [#include <linux/ppdev.h>],
564 [ioctl (1,PPCLAIM,0)],
565 [ac_cv_c_ppdev="yes"],
566 [ac_cv_c_ppdev="no"])
567 )
568 if test "$ac_cv_c_ppdev" = "yes"
569 then
570 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
571 fi
573 dnl **** Check for va_copy ****
574 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
575 AC_TRY_LINK(
576 [#include <stdarg.h>],
577 [va_list ap1, ap2;
578 va_copy(ap1,ap2);
579 ],
580 [ac_cv_c_va_copy="yes"],
581 [ac_cv_c_va_copy="no"])
582 )
583 if test "$ac_cv_c_va_copy" = "yes"
584 then
585 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
586 fi
587 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
588 AC_TRY_LINK(
589 [#include <stdarg.h>],
590 [va_list ap1, ap2;
591 __va_copy(ap1,ap2);
592 ],
593 [ac_cv_c___va_copy="yes"],
594 [ac_cv_c___va_copy="no"])
595 )
596 if test "$ac_cv_c___va_copy" = "yes"
597 then
598 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
599 fi
601 dnl **** Check for sigsetjmp ****
602 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
603 AC_TRY_LINK(
604 [#include <setjmp.h>],
605 [sigjmp_buf buf;
606 sigsetjmp( buf, 1 );
607 siglongjmp( buf, 1 );],
608 [ac_cv_c_sigsetjmp="yes"],
609 [ac_cv_c_sigsetjmp="no"])
610 )
611 if test "$ac_cv_c_sigsetjmp" = "yes"
612 then
613 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
614 fi
616 dnl **** Check for pthread_rwlock_t ****
617 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
618 #include <pthread.h>])
620 dnl **** Check for pthread functions ****
621 ac_save_LIBS="$LIBS"
622 LIBS="$LIBS $LIBPTHREAD"
623 AC_CHECK_FUNCS(\
624 pthread_getattr_np \
625 pthread_get_stackaddr_np \
626 pthread_get_stacksize_np \
627 )
628 LIBS="$ac_save_LIBS"
630 dnl **** Check for Open Sound System ****
631 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
633 AC_CACHE_CHECK([for Open Sound System],
634 ac_cv_c_opensoundsystem,
635 AC_TRY_COMPILE([
636 #if defined(HAVE_SYS_SOUNDCARD_H)
637 #include <sys/soundcard.h>
638 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
639 #include <machine/soundcard.h>
640 #elif defined(HAVE_SOUNDCARD_H)
641 #include <soundcard.h>
642 #endif
643 ],[
645 /* check for one of the Open Sound System specific SNDCTL_ defines */
646 #if !defined(SNDCTL_DSP_STEREO)
647 #error No open sound system
648 #endif
649 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
651 if test "$ac_cv_c_opensoundsystem" = "yes"
652 then
653 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
654 fi
656 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
657 ac_cv_c_opensoundsystem_midi,
658 AC_TRY_COMPILE([
659 #if defined(HAVE_SYS_SOUNDCARD_H)
660 #include <sys/soundcard.h>
661 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
662 #include <machine/soundcard.h>
663 #elif defined(HAVE_SOUNDCARD_H)
664 #include <soundcard.h>
665 #endif
666 ],[
668 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
669 #if !defined(SNDCTL_SEQ_SYNC)
670 #error No open sound system MIDI interface
671 #endif
672 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
674 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
675 then
676 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
677 fi
679 dnl **** Check for aRts Sound Server ****
680 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
681 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
682 then
683 ARTSC_CFLAGS=""
684 for i in `$ARTSCCONFIG --cflags`
685 do
686 case "$i" in
687 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
688 esac
689 done
690 ARTSC_LIBS=`$ARTSCCONFIG --libs`
691 save_CFLAGS="$CFLAGS"
692 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
693 AC_CHECK_LIB(artsc,arts_init,
694 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
695 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
696 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
697 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
698 $ARTSC_LIBS)
699 CFLAGS="$save_CFLAGS"
700 fi
702 dnl **** Check for ALSA 1.x ****
703 AC_SUBST(ALSALIBS,"")
704 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
705 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
706 then
707 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
708 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
709 #include <alsa/asoundlib.h>
710 #elif defined(HAVE_SYS_ASOUNDLIB_H)
711 #include <sys/asoundlib.h>
712 #endif],
713 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
714 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
715 ALSALIBS="-lasound"])])
716 fi
718 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
720 AC_SUBST(AUDIOIOLIBS,"")
721 AC_CHECK_HEADERS(libaudioio.h,
722 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
723 [AUDIOIOLIBS="-laudioio"
724 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
726 dnl **** Check for capi4linux ****
728 AC_CHECK_HEADERS(capi20.h,[
729 AC_CHECK_HEADERS(linux/capi.h,[
730 AC_CHECK_LIB(capi20,capi20_register,[
731 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
732 ])
733 ])
734 ])
736 dnl **** Check for broken glibc mmap64 ****
738 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
739 AC_TRY_RUN([
740 #define _FILE_OFFSET_BITS 64
741 #include <stdio.h>
742 #include <unistd.h>
743 #include <fcntl.h>
744 #include <sys/mman.h>
745 #include <errno.h>
747 int main(int argc,char **argv) {
748 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
749 if (fd == -1) exit(1);
751 unlink("conftest.map");
753 write(fd,"test",4);
755 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
756 (errno == EINVAL)
757 ) {
758 exit(1);
759 }
760 close(fd);
761 fprintf(stderr,"success!\n");
762 exit(0);
763 }
765 ],
766 ac_cv_mmap64_works="yes",
767 ac_cv_mmap64_works="no",
768 ac_cv_mmap64_works="no") )
770 if test "$ac_cv_mmap64_works" = "yes"
771 then
772 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
773 fi
775 dnl **** Check for gcc specific options ****
777 AC_SUBST(EXTRACFLAGS,"")
778 if test "x${GCC}" = "xyes"
779 then
780 EXTRACFLAGS="-Wall -pipe"
782 dnl Check for strength-reduce bug
783 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
784 AC_TRY_RUN([
785 int L[[4]] = {0,1,2,3};
786 int main(void) {
787 static int Array[[3]];
788 unsigned int B = 3;
789 int i;
790 for(i=0; i<B; i++) Array[[i]] = i - 3;
791 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
792 L[[i]] = 4;
794 exit( Array[[1]] != -2 || L[[2]] != 3);
795 }],
796 ac_cv_c_gcc_strength_bug="no",
797 ac_cv_c_gcc_strength_bug="yes",
798 ac_cv_c_gcc_strength_bug="yes") )
799 if test "$ac_cv_c_gcc_strength_bug" = "yes"
800 then
801 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
802 fi
804 dnl Check for -fshort-wchar
805 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
806 [WINE_TRY_CFLAGS([-fshort-wchar],
807 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
808 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
809 then
810 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
811 fi
813 dnl Check for -mpreferred-stack-boundary
814 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
815 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
816 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
817 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
818 then
819 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
820 fi
822 dnl Check for -fno-strict-aliasing
823 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
824 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
825 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
826 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
827 then
828 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
829 fi
831 dnl Check for -gstabs+ option
832 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
833 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
834 if test "$ac_cv_c_gcc_gstabs" = "yes"
835 then
836 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
837 fi
839 dnl Check for noisy string.h
840 saved_CFLAGS="$CFLAGS"
841 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
842 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
843 AC_TRY_COMPILE([#include <string.h>],[],
844 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
845 CFLAGS="$saved_CFLAGS"
846 if test "$ac_cv_c_string_h_warnings" = "no"
847 then
848 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
849 fi
850 fi
852 dnl **** Check how to define a function in assembly code ****
854 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
855 WINE_TRY_ASM_LINK(
856 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
857 ac_cv_asm_func_def=".def",
858 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
859 ac_cv_asm_func_def=".type @function",
860 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
861 ac_cv_asm_func_def=".type 2",
862 ac_cv_asm_func_def="unknown")])]))
864 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
865 case "$ac_cv_asm_func_def" in
866 ".def")
867 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
868 ".type @function")
869 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
870 ".type 2")
871 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
872 *)
873 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
874 esac
876 dnl **** Check for underscore on external symbols ****
878 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
879 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
880 [extern int ac_test;],
881 [if (ac_test) return 1],
882 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
884 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
885 if test "$ac_cv_c_extern_prefix" = "yes"
886 then
887 AC_DEFINE([__ASM_NAME(name)], ["_" name])
888 else
889 AC_DEFINE([__ASM_NAME(name)], [name])
890 fi
892 dnl **** Check for working dll ****
894 AC_SUBST(DLLEXT,"")
895 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
896 AC_SUBST(DLLIBS,"")
897 AC_SUBST(LDSHARED,"")
898 AC_SUBST(LDDLLFLAGS,"")
899 AC_SUBST(LIBEXT,"so")
900 AC_SUBST(IMPLIBEXT,"def")
902 case $host_os in
903 cygwin*|mingw32*)
904 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
905 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
906 if test "$DLLWRAP" = "false"; then
907 LIBEXT="a"
908 else
909 dnl FIXME - check whether dllwrap works correctly...
910 LIBEXT="dll"
911 fi
912 IMPLIBEXT="a"
913 dnl We can't build 16-bit NE dlls
914 WIN16_FILES=""
915 WIN16_INSTALL=""
916 ;;
917 *)
918 AC_CHECK_HEADERS(dlfcn.h,
919 [AC_CHECK_FUNCS(dlopen,,
920 [AC_CHECK_LIB(dl,dlopen,
921 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
922 DLLIBS="-ldl"],
923 [LIBEXT="a"])])],
924 [LIBEXT="a"])
926 if test "$LIBEXT" = "so"
927 then
928 DLLFLAGS="$DLLFLAGS -fPIC"
929 DLLEXT=".so"
930 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
931 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
932 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
933 if test "$ac_cv_c_dll_gnuelf" = "yes"
934 then
935 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
936 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
937 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
938 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
939 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
940 if test "$ac_cv_c_dll_zdefs" = "yes"
941 then
942 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
943 fi
945 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
946 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
947 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
948 if test "$ac_cv_c_dll_init_fini" = "yes"
949 then
950 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
951 fi
953 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
954 [echo '{ global: *; };' >conftest.map
955 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
956 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
957 rm -f conftest.map])
958 if test "$ac_cv_c_ld_version_scripts" = "yes"
959 then
960 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
961 fi
963 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
964 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
965 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
966 if test "$ac_cv_c_export_dynamic" = "yes"
967 then
968 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
969 fi
971 case $host_cpu in
972 *i[[3456789]]86*)
973 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
974 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
975 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
976 if test "$ac_cv_ld_reloc_exec" = "yes"
977 then
978 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
979 fi
980 ;;
981 esac
983 else
984 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
985 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
986 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
987 if test "$ac_cv_c_dll_unixware" = "yes"
988 then
989 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
990 LDDLLFLAGS="-Wl,-G,-B,symbolic"
992 else
993 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
994 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
995 if test "$ac_cv_c_dll_macho" = "yes"
996 then
997 LIBEXT="dylib"
998 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
999 LDSHARED="\$(CC) -dynamiclib"
1000 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
1001 STRIP="$STRIP -u -r"
1002 dnl Relocate wine executable
1003 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1004 dnl Relocate libwine.dyld too
1005 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1006 dnl declare needed frameworks
1007 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1008 AC_SUBST(IOKITLIB,"-framework IOKit")
1009 dnl using IOKit imply we use CoreFoundation too
1010 IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1011 else
1012 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1013 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1014 if test "$ac_cv_c_dll_hpux" = "yes"
1015 then
1016 LIBEXT="sl"
1017 DLLEXT=".sl"
1018 LDDLLFLAGS="-shared -fPIC"
1019 LDSHARED="\$(CC) -shared"
1020 fi
1021 fi
1022 fi
1023 fi
1024 fi
1026 dnl Check for cross compiler to build test programs
1027 AC_SUBST(CROSSTEST,"")
1028 if test "$cross_compiling" = "no"
1029 then
1030 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1031 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1032 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1033 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1034 fi
1035 ;;
1036 esac
1038 if test "$LIBEXT" = "a"; then
1039 AC_MSG_ERROR(
1040 [could not find a way to build shared libraries.
1041 It is currently not possible to build Wine without shared library
1042 (.so) support to allow transparent switch between .so and .dll files.
1043 If you are using Linux, you will need a newer binutils.]
1044 )
1045 fi
1047 case $build_os in
1048 cygwin*|mingw32*)
1049 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1050 darwin*|macosx*)
1051 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1052 *)
1053 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1054 esac
1056 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1057 case $host_os in
1058 mingw32*)
1059 AC_SUBST(CRTLIBS,"-lmsvcrt")
1060 AC_SUBST(SOCKETLIBS,"-lws2_32")
1061 ;;
1062 esac
1064 case $host_os in
1065 linux*)
1066 case $host_cpu in
1067 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1068 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1069 esac
1070 AC_SUBST(MAIN_BINARY,"wine-glibc")
1071 ;;
1072 darwin*)
1073 AC_SUBST(WINE_BINARIES,"wine-pthread")
1074 AC_SUBST(MAIN_BINARY,"wine-pthread")
1075 ;;
1076 *)
1077 AC_SUBST(WINE_BINARIES,"wine-kthread")
1078 AC_SUBST(MAIN_BINARY,"wine-kthread")
1079 ;;
1080 esac
1082 dnl **** Get the soname for libraries that we load dynamically ****
1084 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1085 then
1086 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1087 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1088 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1089 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1090 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1091 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1092 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1093 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1094 WINE_GET_SONAME(cups,cupsGetDefault)
1095 WINE_GET_SONAME(jack,jack_client_new)
1096 WINE_GET_SONAME(fontconfig,FcInit)
1097 WINE_GET_SONAME(ssl,SSL_library_init)
1098 WINE_GET_SONAME(crypto,BIO_new_socket)
1099 WINE_GET_SONAME(ncurses,waddch)
1100 WINE_GET_SONAME(curses,waddch)
1101 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1102 WINE_GET_SONAME(ungif,DGifOpen)
1103 WINE_GET_SONAME(gif,DGifOpen)
1104 WINE_GET_SONAME(capi20,capi20_isinstalled)
1105 fi
1108 dnl **** Check for functions ****
1110 AC_FUNC_ALLOCA()
1111 AC_CHECK_FUNCS(\
1112 _lwp_create \
1113 _lwp_self \
1114 _pclose \
1115 _popen \
1116 _snprintf \
1117 _spawnvp \
1118 _stricmp \
1119 _strnicmp \
1120 _vsnprintf \
1121 chsize \
1122 clone \
1123 epoll_create \
1124 ffs \
1125 finite \
1126 fork \
1127 fpclass \
1128 fstatfs \
1129 fstatvfs \
1130 ftruncate \
1131 futimes \
1132 futimesat \
1133 getnetbyname \
1134 getopt_long \
1135 getpagesize \
1136 getprotobyname \
1137 getprotobynumber \
1138 getpwuid \
1139 getservbyport \
1140 gettid \
1141 gettimeofday \
1142 getuid \
1143 inet_network \
1144 lstat \
1145 memmove \
1146 mmap \
1147 pclose \
1148 popen \
1149 pread \
1150 pwrite \
1151 readlink \
1152 rfork \
1153 sched_yield \
1154 select \
1155 sendmsg \
1156 settimeofday \
1157 sigaltstack \
1158 sigprocmask \
1159 snprintf \
1160 spawnvp \
1161 statfs \
1162 statvfs \
1163 strcasecmp \
1164 strerror \
1165 strncasecmp \
1166 tcgetattr \
1167 timegm \
1168 usleep \
1169 vsnprintf \
1170 wait4 \
1171 waitpid \
1172 )
1174 dnl **** Checks for headers that depend on other ones ****
1176 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1177 [#include <sys/types.h>
1178 #if HAVE_SYS_PARAM_H
1179 # include <sys/param.h>
1180 #endif])
1182 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1183 [#include <sys/types.h>
1184 #if HAVE_SYS_SOCKET_H
1185 # include <sys/socket.h>
1186 #endif])
1188 AC_CHECK_HEADERS([resolv.h],,,
1189 [#include <sys/types.h>
1190 #if HAVE_SYS_SOCKET_H
1191 # include <sys/socket.h>
1192 #endif
1193 #if HAVE_NETINET_IN_H
1194 # include <netinet/in.h>
1195 #endif
1196 #if HAVE_ARPA_NAMESER_H
1197 # include <arpa/nameser.h>
1198 #endif])
1200 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1202 dnl **** Check for v4l(2) headers ****
1204 AC_CHECK_HEADERS(linux/videodev.h,,,
1205 [#ifdef HAVE_SYS_TIME_H
1206 #include <sys/time.h>
1207 #endif
1208 #include <sys/types.h>
1209 #ifdef HAVE_ASM_TYPES_H
1210 #include <asm/types.h>
1211 #endif])
1213 dnl **** Check for IPX headers (currently Linux only) ****
1215 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1216 AC_TRY_COMPILE(
1217 [#include <sys/types.h>
1218 #ifdef HAVE_SYS_SOCKET_H
1219 # include <sys/socket.h>
1220 #endif
1221 #include <netipx/ipx.h>],
1222 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1223 [ac_cv_c_ipx_gnu="yes"],
1224 [ac_cv_c_ipx_gnu="no"])
1225 )
1226 if test "$ac_cv_c_ipx_gnu" = "yes"
1227 then
1228 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1229 fi
1231 if test "$ac_cv_c_ipx_gnu" = "no"
1232 then
1233 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1234 AC_TRY_COMPILE(
1235 [#include <sys/types.h>
1236 #ifdef HAVE_SYS_SOCKET_H
1237 # include <sys/socket.h>
1238 #endif
1239 #include <asm/types.h>
1240 #include <linux/ipx.h>],
1241 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1242 [ac_cv_c_ipx_linux="yes"],
1243 [ac_cv_c_ipx_linux="no"])
1244 )
1245 if test "$ac_cv_c_ipx_linux" = "yes"
1246 then
1247 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1248 fi
1249 fi
1251 dnl **** Check for types ****
1253 AC_C_CONST
1254 AC_C_INLINE
1255 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1256 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1257 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1259 AC_CACHE_CHECK([whether linux/input.h is for real],
1260 wine_cv_linux_input_h,
1261 AC_TRY_COMPILE([
1262 #include <linux/input.h>
1263 ] , [
1264 int foo = EVIOCGBIT(EV_ABS,42);
1265 int bar = BTN_PINKIE;
1266 int fortytwo = 42;
1267 ],
1268 wine_cv_linux_input_h=yes,
1269 wine_cv_linux_input_h=no,
1270 no
1271 )
1272 )
1273 if test "$wine_cv_linux_input_h" = "yes"
1274 then
1275 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1276 [Define if we have linux/input.h AND it contains the INPUT event API])
1277 fi
1279 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1280 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1281 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1282 if test "$wine_cv_have_sigaddset" = "yes"
1283 then
1284 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1285 fi
1288 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1289 wine_cv_linux_gethostbyname_r_6,
1290 AC_TRY_LINK([
1291 #include <netdb.h>
1292 ], [
1293 char *name=NULL;
1294 struct hostent he;
1295 struct hostent *result;
1296 char *buf=NULL;
1297 int bufsize=0;
1298 int res,errnr;
1299 char *addr=NULL;
1300 int addrlen=0;
1301 int addrtype=0;
1302 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1303 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1304 ],
1305 wine_cv_linux_gethostbyname_r_6=yes,
1306 wine_cv_linux_gethostbyname_r_6=no
1307 )
1308 )
1309 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1310 then
1311 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1312 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1313 fi
1315 if test "$ac_cv_header_linux_joystick_h" = "yes"
1316 then
1317 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1318 wine_cv_linux_joystick_22_api,
1319 AC_TRY_COMPILE([
1320 #include <sys/ioctl.h>
1321 #include <linux/joystick.h>
1323 struct js_event blub;
1324 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1325 #error "no 2.2 header"
1326 #endif
1327 ],/*empty*/,
1328 wine_cv_linux_joystick_22_api=yes,
1329 wine_cv_linux_joystick_22_api=no,
1330 wine_cv_linux_joystick_22_api=no
1331 )
1332 )
1333 if test "$wine_cv_linux_joystick_22_api" = "yes"
1334 then
1335 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1336 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1337 fi
1338 fi
1340 dnl **** statfs checks ****
1342 if test "$ac_cv_header_sys_vfs_h" = "yes"
1343 then
1344 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1345 wine_cv_sys_vfs_has_statfs,
1346 AC_TRY_COMPILE([
1347 #include <sys/types.h>
1348 #ifdef HAVE_SYS_PARAM_H
1349 # include <sys/param.h>
1350 #endif
1351 #include <sys/vfs.h>
1352 ],[
1353 struct statfs stfs;
1355 memset(&stfs,0,sizeof(stfs));
1356 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1357 )
1358 )
1359 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1360 then
1361 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1362 [Define if the struct statfs is defined by <sys/vfs.h>])
1363 fi
1364 fi
1366 if test "$ac_cv_header_sys_statfs_h" = "yes"
1367 then
1368 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1369 wine_cv_sys_statfs_has_statfs,
1370 AC_TRY_COMPILE([
1371 #include <sys/types.h>
1372 #ifdef HAVE_SYS_PARAM_H
1373 # include <sys/param.h>
1374 #endif
1375 #include <sys/statfs.h>
1376 ],[
1377 struct statfs stfs;
1378 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1379 )
1380 )
1381 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1382 then
1383 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1384 [Define if the struct statfs is defined by <sys/statfs.h>])
1385 fi
1386 fi
1388 if test "$ac_cv_header_sys_mount_h" = "yes"
1389 then
1390 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1391 wine_cv_sys_mount_has_statfs,
1392 AC_TRY_COMPILE([
1393 #include <sys/types.h>
1394 #ifdef HAVE_SYS_PARAM_H
1395 # include <sys/param.h>
1396 #endif
1397 #include <sys/mount.h>
1398 ],[
1399 struct statfs stfs;
1400 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1401 )
1402 )
1403 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1404 then
1405 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1406 [Define if the struct statfs is defined by <sys/mount.h>])
1407 fi
1408 fi
1410 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1412 dnl Check for statfs members
1413 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1414 [#include <sys/types.h>
1415 #ifdef HAVE_SYS_PARAM_H
1416 # include <sys/param.h>
1417 #endif
1418 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1419 # include <sys/mount.h>
1420 #else
1421 # ifdef STATFS_DEFINED_BY_SYS_VFS
1422 # include <sys/vfs.h>
1423 # else
1424 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1425 # include <sys/statfs.h>
1426 # endif
1427 # endif
1428 #endif])
1430 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1431 [#ifdef HAVE_SYS_STATVFS_H
1432 #include <sys/statvfs.h>
1433 #endif])
1435 dnl Check for socket structure members
1436 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1437 [#include <sys/types.h>
1438 #ifdef HAVE_SYS_SOCKET_H
1439 # include <sys/socket.h>
1440 #endif
1441 #ifdef HAVE_SYS_UN_H
1442 # include <sys/un.h>
1443 #endif])
1445 dnl Check for scsireq_t and sg_io_hdr_t members
1446 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1447 [#include <sys/types.h>
1448 #ifdef HAVE_SCSI_SG_H
1449 #include <scsi/sg.h>
1450 #endif])
1452 dnl Check for siginfo_t members
1453 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1455 dnl Check for struct option
1456 AC_CHECK_MEMBERS([struct option.name],,,
1457 [#ifdef HAVE_GETOPT_H
1458 #include <getopt.h>
1459 #endif])
1461 dnl Check for stat.st_blocks
1462 AC_CHECK_MEMBERS([struct stat.st_blocks])
1464 dnl Check for the external timezone variables timezone and daylight
1465 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1466 AC_TRY_LINK([#include <time.h>],[timezone;],
1467 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1468 if test "$ac_cv_have_timezone" = "yes"
1469 then
1470 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1471 fi
1472 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1473 AC_TRY_LINK([#include <time.h>],[daylight;],
1474 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1475 if test "$ac_cv_have_daylight" = "yes"
1476 then
1477 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1478 fi
1480 dnl *** check for the need to define platform-specific symbols
1482 case $host_cpu in
1483 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1484 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1485 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1486 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1487 esac
1489 case $host_vendor in
1490 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1491 esac
1493 dnl **** Generate output files ****
1495 AH_TOP([#define __WINE_CONFIG_H])
1497 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1498 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1499 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1500 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1501 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1502 WINE_CONFIG_EXTRA_DIR(include/wine)
1503 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1505 MAKE_RULES=Make.rules
1506 AC_SUBST_FILE(MAKE_RULES)
1508 MAKE_DLL_RULES=dlls/Makedll.rules
1509 AC_SUBST_FILE(MAKE_DLL_RULES)
1511 MAKE_TEST_RULES=dlls/Maketest.rules
1512 AC_SUBST_FILE(MAKE_TEST_RULES)
1514 MAKE_LIB_RULES=libs/Makelib.rules
1515 AC_SUBST_FILE(MAKE_LIB_RULES)
1517 MAKE_PROG_RULES=programs/Makeprog.rules
1518 AC_SUBST_FILE(MAKE_PROG_RULES)
1520 AC_CONFIG_FILES([
1521 Make.rules
1522 dlls/Makedll.rules
1523 dlls/Maketest.rules
1524 libs/Makelib.rules
1525 programs/Makeprog.rules
1526 Makefile
1527 dlls/Makefile
1528 dlls/activeds/Makefile
1529 dlls/advapi32/Makefile
1530 dlls/advapi32/tests/Makefile
1531 dlls/advpack/Makefile
1532 dlls/advpack/tests/Makefile
1533 dlls/amstream/Makefile
1534 dlls/atl/Makefile
1535 dlls/avicap32/Makefile
1536 dlls/avifil32/Makefile
1537 dlls/cabinet/Makefile
1538 dlls/capi2032/Makefile
1539 dlls/cards/Makefile
1540 dlls/cfgmgr32/Makefile
1541 dlls/comcat/Makefile
1542 dlls/comctl32/Makefile
1543 dlls/comctl32/tests/Makefile
1544 dlls/commdlg/Makefile
1545 dlls/crtdll/Makefile
1546 dlls/crypt32/Makefile
1547 dlls/crypt32/tests/Makefile
1548 dlls/cryptdll/Makefile
1549 dlls/ctl3d/Makefile
1550 dlls/d3d8/Makefile
1551 dlls/d3d9/Makefile
1552 dlls/d3dim/Makefile
1553 dlls/d3drm/Makefile
1554 dlls/d3dx8/Makefile
1555 dlls/d3dxof/Makefile
1556 dlls/dbghelp/Makefile
1557 dlls/dciman32/Makefile
1558 dlls/ddraw/Makefile
1559 dlls/ddraw/tests/Makefile
1560 dlls/devenum/Makefile
1561 dlls/dinput/Makefile
1562 dlls/dinput/tests/Makefile
1563 dlls/dinput8/Makefile
1564 dlls/dmband/Makefile
1565 dlls/dmcompos/Makefile
1566 dlls/dmime/Makefile
1567 dlls/dmloader/Makefile
1568 dlls/dmscript/Makefile
1569 dlls/dmstyle/Makefile
1570 dlls/dmsynth/Makefile
1571 dlls/dmusic/Makefile
1572 dlls/dmusic32/Makefile
1573 dlls/dplay/Makefile
1574 dlls/dplayx/Makefile
1575 dlls/dpnet/Makefile
1576 dlls/dpnhpast/Makefile
1577 dlls/dsound/Makefile
1578 dlls/dsound/tests/Makefile
1579 dlls/dswave/Makefile
1580 dlls/dxdiagn/Makefile
1581 dlls/dxerr8/Makefile
1582 dlls/dxerr9/Makefile
1583 dlls/dxguid/Makefile
1584 dlls/gdi/Makefile
1585 dlls/gdi/tests/Makefile
1586 dlls/glu32/Makefile
1587 dlls/glut32/Makefile
1588 dlls/hhctrl.ocx/Makefile
1589 dlls/iccvid/Makefile
1590 dlls/icmp/Makefile
1591 dlls/ifsmgr.vxd/Makefile
1592 dlls/imagehlp/Makefile
1593 dlls/imm32/Makefile
1594 dlls/iphlpapi/Makefile
1595 dlls/iphlpapi/tests/Makefile
1596 dlls/itss/Makefile
1597 dlls/kernel/Makefile
1598 dlls/kernel/tests/Makefile
1599 dlls/lzexpand/Makefile
1600 dlls/lzexpand/tests/Makefile
1601 dlls/mapi32/Makefile
1602 dlls/mapi32/tests/Makefile
1603 dlls/mlang/Makefile
1604 dlls/mlang/tests/Makefile
1605 dlls/mmdevldr.vxd/Makefile
1606 dlls/monodebg.vxd/Makefile
1607 dlls/mpr/Makefile
1608 dlls/msacm/Makefile
1609 dlls/msacm/imaadp32/Makefile
1610 dlls/msacm/msadp32/Makefile
1611 dlls/msacm/msg711/Makefile
1612 dlls/msacm/winemp3/Makefile
1613 dlls/msacm/tests/Makefile
1614 dlls/mscms/Makefile
1615 dlls/mscms/tests/Makefile
1616 dlls/msdmo/Makefile
1617 dlls/mshtml/Makefile
1618 dlls/mshtml/tests/Makefile
1619 dlls/msi/Makefile
1620 dlls/msi/tests/Makefile
1621 dlls/msimg32/Makefile
1622 dlls/msisys/Makefile
1623 dlls/msnet32/Makefile
1624 dlls/msrle32/Makefile
1625 dlls/msvcrt/Makefile
1626 dlls/msvcrt/tests/Makefile
1627 dlls/msvcrt20/Makefile
1628 dlls/msvcrt40/Makefile
1629 dlls/msvcrtd/Makefile
1630 dlls/msvcrtd/tests/Makefile
1631 dlls/msvidc32/Makefile
1632 dlls/msvideo/Makefile
1633 dlls/mswsock/Makefile
1634 dlls/netapi32/Makefile
1635 dlls/netapi32/tests/Makefile
1636 dlls/newdev/Makefile
1637 dlls/ntdll/Makefile
1638 dlls/ntdll/tests/Makefile
1639 dlls/odbc32/Makefile
1640 dlls/odbccp32/Makefile
1641 dlls/ole32/Makefile
1642 dlls/ole32/tests/Makefile
1643 dlls/oleacc/Makefile
1644 dlls/oleaut32/Makefile
1645 dlls/oleaut32/tests/Makefile
1646 dlls/olecli/Makefile
1647 dlls/oledlg/Makefile
1648 dlls/olepro32/Makefile
1649 dlls/olesvr/Makefile
1650 dlls/opengl32/Makefile
1651 dlls/powrprof/Makefile
1652 dlls/psapi/Makefile
1653 dlls/psapi/tests/Makefile
1654 dlls/qcap/Makefile
1655 dlls/quartz/Makefile
1656 dlls/quartz/tests/Makefile
1657 dlls/rasapi32/Makefile
1658 dlls/riched20/Makefile
1659 dlls/richedit/Makefile
1660 dlls/rpcrt4/Makefile
1661 dlls/rpcrt4/tests/Makefile
1662 dlls/rsabase/Makefile
1663 dlls/rsabase/tests/Makefile
1664 dlls/rsaenh/Makefile
1665 dlls/rsaenh/tests/Makefile
1666 dlls/secur32/Makefile
1667 dlls/sensapi/Makefile
1668 dlls/serialui/Makefile
1669 dlls/setupapi/Makefile
1670 dlls/shdocvw/Makefile
1671 dlls/shell32/Makefile
1672 dlls/shell32/tests/Makefile
1673 dlls/shfolder/Makefile
1674 dlls/shlwapi/Makefile
1675 dlls/shlwapi/tests/Makefile
1676 dlls/snmpapi/Makefile
1677 dlls/stdole32.tlb/Makefile
1678 dlls/sti/Makefile
1679 dlls/strmiids/Makefile
1680 dlls/tapi32/Makefile
1681 dlls/ttydrv/Makefile
1682 dlls/twain/Makefile
1683 dlls/unicows/Makefile
1684 dlls/url/Makefile
1685 dlls/urlmon/Makefile
1686 dlls/urlmon/tests/Makefile
1687 dlls/user/Makefile
1688 dlls/user/tests/Makefile
1689 dlls/uuid/Makefile
1690 dlls/uxtheme/Makefile
1691 dlls/vdhcp.vxd/Makefile
1692 dlls/vdmdbg/Makefile
1693 dlls/version/Makefile
1694 dlls/version/tests/Makefile
1695 dlls/vmm.vxd/Makefile
1696 dlls/vnbt.vxd/Makefile
1697 dlls/vnetbios.vxd/Makefile
1698 dlls/vtdapi.vxd/Makefile
1699 dlls/vwin32.vxd/Makefile
1700 dlls/win32s/Makefile
1701 dlls/winaspi/Makefile
1702 dlls/wined3d/Makefile
1703 dlls/winedos/Makefile
1704 dlls/wineps/Makefile
1705 dlls/wininet/Makefile
1706 dlls/wininet/tests/Makefile
1707 dlls/winmm/Makefile
1708 dlls/winmm/joystick/Makefile
1709 dlls/winmm/mcianim/Makefile
1710 dlls/winmm/mciavi/Makefile
1711 dlls/winmm/mcicda/Makefile
1712 dlls/winmm/mciseq/Makefile
1713 dlls/winmm/mciwave/Makefile
1714 dlls/winmm/midimap/Makefile
1715 dlls/winmm/tests/Makefile
1716 dlls/winmm/wavemap/Makefile
1717 dlls/winmm/winealsa/Makefile
1718 dlls/winmm/winearts/Makefile
1719 dlls/winmm/wineaudioio/Makefile
1720 dlls/winmm/winejack/Makefile
1721 dlls/winmm/winenas/Makefile
1722 dlls/winmm/wineoss/Makefile
1723 dlls/winnls/Makefile
1724 dlls/winsock/Makefile
1725 dlls/winsock/tests/Makefile
1726 dlls/winspool/Makefile
1727 dlls/winspool/tests/Makefile
1728 dlls/wintab32/Makefile
1729 dlls/wintrust/Makefile
1730 dlls/wldap32/Makefile
1731 dlls/wow32/Makefile
1732 dlls/wsock32/Makefile
1733 dlls/wtsapi32/Makefile
1734 dlls/x11drv/Makefile
1735 documentation/Makefile
1736 fonts/Makefile
1737 include/Makefile
1738 libs/Makefile
1739 libs/port/Makefile
1740 libs/unicode/Makefile
1741 libs/wine/Makefile
1742 libs/wpp/Makefile
1743 loader/Makefile
1744 programs/Makefile
1745 programs/avitools/Makefile
1746 programs/clock/Makefile
1747 programs/cmdlgtst/Makefile
1748 programs/control/Makefile
1749 programs/expand/Makefile
1750 programs/hh/Makefile
1751 programs/msiexec/Makefile
1752 programs/notepad/Makefile
1753 programs/progman/Makefile
1754 programs/regedit/Makefile
1755 programs/regsvr32/Makefile
1756 programs/rpcss/Makefile
1757 programs/rundll32/Makefile
1758 programs/start/Makefile
1759 programs/taskmgr/Makefile
1760 programs/uninstaller/Makefile
1761 programs/view/Makefile
1762 programs/wcmd/Makefile
1763 programs/wineboot/Makefile
1764 programs/winebrowser/Makefile
1765 programs/winecfg/Makefile
1766 programs/wineconsole/Makefile
1767 programs/winedbg/Makefile
1768 programs/winefile/Makefile
1769 programs/winemenubuilder/Makefile
1770 programs/winemine/Makefile
1771 programs/winepath/Makefile
1772 programs/winetest/Makefile
1773 programs/winevdm/Makefile
1774 programs/winhelp/Makefile
1775 programs/winver/Makefile
1776 server/Makefile
1777 tools/Makefile
1778 tools/widl/Makefile
1779 tools/winapi/Makefile
1780 tools/winebuild/Makefile
1781 tools/winedump/Makefile
1782 tools/winegcc/Makefile
1783 tools/wmc/Makefile
1784 tools/wrc/Makefile])
1786 AC_OUTPUT
1788 if test "$have_x" = "no"
1789 then
1790 echo
1791 echo "*** Warning: X development files not found. Wine will be built without"
1792 echo "*** X support, which currently does not work, and would probably not be"
1793 echo "*** what you want anyway. You will need to install devel packages of"
1794 echo "*** Xlib/Xfree86 at the very least."
1795 fi
1797 if test "$wine_cv_opengl_version_OK" = "no"
1798 then
1799 echo
1800 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1801 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1802 fi
1804 if test "$wine_cv_msg_freetype" = "yes"
1805 then
1806 echo
1807 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1808 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1809 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1810 echo "*** enable Wine to use TrueType fonts."
1811 fi
1813 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1814 -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1815 "$ac_cv_c_opensoundsystem" = "no"
1816 then
1817 echo "*** No sound system was found. Windows applications will be silent."
1818 echo "*** The currently supported sound systems are:"
1819 echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1820 fi
1822 echo
1823 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1824 echo
1826 dnl Local Variables:
1827 dnl comment-start: "dnl "
1828 dnl comment-end: ""
1829 dnl comment-start-skip: "\\bdnl\\b\\s *"
1830 dnl compile-command: "autoconf"
1831 dnl End: