| blob | 37aeb2ec2166b132c494f33e705bd38ae5492c85 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION)
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 dnl Library type .so or .a
16 AC_SUBST(LIBEXT,"so")
18 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
19 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
20 AC_ARG_ENABLE(opengl,AC_HELP_STRING([--enable-opengl],[force usage of OpenGL even if the latter is thread-safe via pthread]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(OPTIONS)
25 if test "x$enable_debug" = "xno"
26 then
27 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
32 fi
34 dnl **** Check for some programs ****
36 AC_CANONICAL_HOST
37 AC_PROG_MAKE_SET
38 AC_PROG_CC
39 AC_PROG_CPP
41 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
42 [if test -z "$with_wine_tools"; then
43 if test "$cross_compiling" = "yes"; then
44 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
45 else
46 wine_cv_toolsdir="\$(TOPOBJDIR)"
47 fi
48 elif test -d "$with_wine_tools/tools/winebuild"; then
49 case $with_wine_tools in
50 /*) wine_cv_toolsdir="$with_wine_tools" ;;
51 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
52 esac
53 else
54 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
55 fi])
56 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
58 AC_PATH_XTRA
59 AC_PROG_YACC
60 AC_PROG_LEX
62 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
63 dnl **** without one present.
64 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
65 if test "$XYACC" = "none"
66 then
67 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
68 fi
69 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
70 if test "$XLEX" = "none"
71 then
72 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
73 fi
75 AC_CHECK_TOOL(LD,ld,ld)
76 AC_CHECK_TOOL(AR,ar,ar)
77 AC_PROG_RANLIB
78 AC_CHECK_TOOL(STRIP,strip,strip)
79 AC_CHECK_TOOL(WINDRES,windres,false)
80 AC_PROG_INSTALL
81 AC_PROG_LN_S
82 WINE_PROG_LN
83 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
84 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
86 dnl Check for lint
87 AC_CHECK_PROGS(LINT, lclint lint)
88 if test "$LINT" = "lint"
89 then
90 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
91 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
92 fi
93 AC_SUBST(LINT)
94 AC_SUBST(LINTFLAGS)
96 dnl **** Check for some libraries ****
98 dnl Check for -lm
99 AC_CHECK_LIB(m,sqrt)
100 dnl Check for -li386 for NetBSD and OpenBSD
101 AC_CHECK_LIB(i386,i386_set_ldt)
102 dnl Check for -lossaudio for NetBSD
103 AC_CHECK_LIB(ossaudio,_oss_ioctl)
104 dnl Check for -lw for Solaris
105 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
106 dnl Check for -lnsl for Solaris
107 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
108 dnl Check for -lsocket for Solaris
109 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
110 dnl Check for -lresolv for Solaris
111 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
112 dnl Check for -lxpg4 for FreeBSD
113 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
114 dnl Check for -lmmap for OS/2
115 AC_CHECK_LIB(mmap,mmap)
117 JPEGLIB=""
118 AC_SUBST(JPEGLIB)
119 AC_CHECK_HEADERS(jpeglib.h,
120 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
121 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
122 JPEGLIB="-ljpeg"
123 )
124 )
127 AC_SUBST(XLIB)
128 AC_SUBST(XFILES)
129 XFILES=""
130 AC_SUBST(OPENGLFILES)
131 OPENGLFILES=""
132 AC_SUBST(GLU32FILES)
133 GLU32FILES=""
134 if test "$have_x" = "yes"
135 then
136 XLIB="-lXext -lX11"
137 ac_save_CPPFLAGS="$CPPFLAGS"
138 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
140 dnl *** All of the following tests require X11/Xlib.h
141 AC_CHECK_HEADERS(X11/Xlib.h,
142 [
143 dnl *** Check for X keyboard extension
144 AC_CHECK_HEADERS(X11/XKBlib.h,
145 [ dnl *** If X11/XKBlib.h exists...
146 AC_CHECK_LIB(X11, XkbQueryExtension,
147 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
148 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
149 ],
150 AC_MSG_WARN([[Xkb extension not found, Wine will be built without it]]),
151 [#include <X11/Xlib.h>])
153 dnl *** Check for X Shm extension
154 AC_CHECK_HEADERS(X11/extensions/XShm.h,
155 [ dnl *** If X11/extensions/XShm.h exists...
156 AC_CHECK_LIB(Xext, XShmQueryExtension,
157 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
158 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
159 ],
160 AC_MSG_WARN([[XShm extension not found, Wine will be built without it]]),
161 [#include <X11/Xlib.h>])
163 dnl *** Check for Xutil
164 AC_CHECK_HEADERS(X11/Xutil.h,,,
165 [#include <X11/Xlib.h>])
167 dnl *** Check for X shape extension
168 AC_CHECK_HEADERS(X11/extensions/shape.h,
169 [ dnl *** If X11/extensions/shape.h exists...
170 AC_CHECK_LIB(Xext,XShapeQueryExtension,
171 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
172 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
173 ],
174 AC_MSG_WARN([[XShape extension not found, Wine will be built without it]]),
175 [#include <X11/Xlib.h>
176 #ifdef HAVE_X11_XUTIL_H
177 # include <X11/Xutil.h>
178 #endif])
180 dnl *** Check for XFree86 DGA / DGA 2.0 extension
181 AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
182 [ dnl *** If X11/extensions/xf86dga.h exists, check
183 dnl *** for XDGAQueryExtension()...
184 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
185 [ dnl *** If found...
186 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
187 [Define if you have the Xxf86dga library version 2])
188 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
189 ],
190 [ dnl *** If not found, look for XF86DGAQueryExtension()
191 dnl *** instead (DGA 2.0 not found)...
192 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
193 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
194 [Define if you have the Xxf86dga library version 1])
195 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
196 ],,
197 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
198 )
199 ],
200 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
201 )
202 ],
203 AC_MSG_WARN([[DGA extension not found, Wine will be built without it]]),
204 [#include <X11/Xlib.h>])
206 dnl *** Check for XFree86 VMODE extension
207 AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
208 [ dnl *** If X11/extensions/xf86vmode.h exists...
209 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
210 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
211 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
212 ],,
213 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
214 )
215 ],
216 AC_MSG_WARN([[XFree86 VMODE extension not found, Wine will be built without it]]),
217 [#include <X11/Xlib.h>])
219 dnl *** Check for XVideo extension supporting XvImages
220 AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
221 [ dnl *** If X11/extensions/Xvlib.h exists...
222 AC_CHECK_LIB(Xv, XvShmCreateImage,
223 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
224 X_PRE_LIBS="$X_PRE_LIBS -lXv"
225 ],,
226 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
227 )
228 ],
229 AC_MSG_WARN([[XVideo extension not found, Wine will be built without it]]),
230 [#include <X11/Xlib.h>])
232 dnl *** Check for XRender include file
233 AC_CHECK_HEADERS(X11/extensions/Xrender.h,,,[#include <X11/Xlib.h>])
234 ]
235 ) dnl *** End of X11/Xlib.h check
237 dnl Check for the presence of OpenGL
238 if test "x$enable_opengl" != "xno"
239 then
240 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
241 then
242 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
243 This prevents linking to OpenGL. Delete the file and restart configure.])
244 fi
246 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
247 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
248 then
249 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
250 dnl Check for some problems due to old Mesa versions
251 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
252 AC_TRY_COMPILE(
253 [#include <GL/gl.h>],
254 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
255 [wine_cv_opengl_version_OK="yes"],
256 [wine_cv_opengl_version_OK="no"]
257 )
258 )
260 dnl Check for the thread-safety of the OpenGL library
261 AC_CACHE_CHECK([for thread-safe OpenGL version],
262 wine_cv_opengl_version_threadsafe,
263 [saved_libs=$LIBS
264 LIBS="$X_LIBS -lGL"
265 AC_TRY_LINK([],[pthread_getspecific();],
266 [wine_cv_opengl_version_threadsafe="yes"],
267 [wine_cv_opengl_version_threadsafe="no"])
268 LIBS=$saved_libs]
269 )
271 if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o "x$enable_opengl" = "xyes" \)
272 then
273 dnl Check for the presence of the library
274 AC_CHECK_LIB(GL,glXCreateContext,
275 X_PRE_LIBS="$X_PRE_LIBS -lGL"
276 ,,
277 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
279 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
280 then
281 OPENGLFILES='$(OPENGLFILES)'
282 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
284 AC_CHECK_LIB(GL,glXGetProcAddressARB,
285 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
286 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
287 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
289 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
290 then
291 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
292 [AC_TRY_COMPILE([#include <GL/gl.h>
293 #ifdef HAVE_GL_GLEXT_H
294 # include <GL/glext.h>
295 #endif
296 ],
297 [PFNGLCOLORTABLEEXTPROC test_proc;],
298 [wine_cv_extension_prototypes="yes"],
299 [wine_cv_extension_prototypes="no"]
300 )]
301 )
302 if test "$wine_cv_extension_prototypes" = "yes"
303 then
304 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
305 [Define if the OpenGL headers define extension typedefs])
306 fi
307 fi
309 fi
310 dnl Check for GLU32 library.
311 AC_CHECK_LIB(GLU,gluLookAt,
312 [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
313 GLU32FILES='$(GLU32FILES)']
314 ,,
315 $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
316 )
317 fi
318 fi
319 fi
321 CPPFLAGS="$ac_save_CPPFLAGS"
322 XFILES='$(XFILES)'
323 else
324 XLIB=""
325 X_CFLAGS=""
326 X_LIBS=""
327 fi
329 dnl **** Check which curses lib to use ***
330 CURSESLIBS=""
331 if test "x$with_curses" != "xno"
332 then
333 AC_CHECK_HEADERS(ncurses.h,
334 [AC_CHECK_LIB(ncurses,waddch,
335 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
336 CURSESLIBS="-lncurses"],
337 [AC_CHECK_HEADERS(curses.h,
338 [AC_CHECK_LIB(curses,waddch,
339 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
340 CURSESLIBS="-lcurses"])])])])
341 saved_libs="$LIBS"
342 LIBS="$CURSESLIBS $LIBS"
343 AC_CHECK_FUNCS(getbkgd resizeterm)
344 LIBS="$saved_libs"
345 fi
346 AC_SUBST(CURSESLIBS)
348 CUPSLIBS=""
349 dnl **** Check for CUPS ****
350 wine_cv_warn_cups_h=no
351 AC_CHECK_LIB(cups,cupsGetPPD,
352 [AC_CHECK_HEADER(cups/cups.h,
353 [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
354 CUPSLIBS="-lcups"],
355 wine_cv_warn_cups_h=yes)]
356 )
357 AC_SUBST(CUPSLIBS)
359 dnl **** Check for SANE ****
360 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
361 if test "$sane_devel" = "no"
362 then
363 SANELIBS=""
364 SANEINCL=""
365 else
366 SANELIBS="`$sane_devel --libs`"
367 SANEINCL="`$sane_devel --cflags`"
368 ac_save_CPPFLAGS="$CPPFLAGS"
369 ac_save_LIBS="$LIBS"
370 CPPFLAGS="$CPPFLAGS $SANEINCL"
371 LIBS="$LIBS $SANELIBS"
372 AC_CHECK_HEADER(sane/sane.h,
373 [AC_CHECK_LIB(sane,sane_open,
374 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
375 [SANELIBS=""
376 SANEINCL=""])],
377 [SANELIBS=""
378 SANEINCL=""])
379 LIBS="$ac_save_LIBS"
380 CPPFLAGS="$ac_save_CPPFLAGS"
381 fi
382 AC_SUBST(SANELIBS)
383 AC_SUBST(SANEINCL)
385 dnl **** Check for FreeType 2 ****
386 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
387 if test "$ft_lib" = "no"
388 then
389 FREETYPEINCL=""
390 wine_cv_msg_freetype=no
391 else
392 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
393 if test "$ft_devel" = "no"
394 then
395 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
396 if test "$ft_devel2" = "freetype2-config"
397 then
398 ft_devel=$ft_devel2
399 fi
400 fi
401 if test "$ft_devel" = "no"
402 then
403 FREETYPEINCL=""
404 wine_cv_msg_freetype=yes
405 else
406 FREETYPEINCL=`$ft_devel --cflags`
407 ac_save_CPPFLAGS="$CPPFLAGS"
408 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
409 AC_CHECK_HEADERS(freetype/freetype.h \
410 freetype/ftglyph.h \
411 freetype/tttables.h \
412 freetype/ftnames.h \
413 freetype/ftsnames.h \
414 freetype/ttnameid.h \
415 freetype/ftoutln.h \
416 freetype/internal/sfnt.h)
417 AC_TRY_CPP([#include <ft2build.h>
418 #include <freetype/fttrigon.h>],
419 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
420 [Define if you have the <freetype/fttrigon.h> header file.])
421 wine_cv_fttrigon=yes],
422 wine_cv_fttrigon=no)
423 CPPFLAGS="$ac_save_CPPFLAGS"
424 dnl Check that we have at least freetype/freetype.h
425 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
426 then
427 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
428 wine_cv_msg_freetype=no
429 else
430 FREETYPEINCL=""
431 wine_cv_msg_freetype=yes
432 fi
433 fi
434 fi
435 AC_SUBST(FREETYPEINCL)
437 dnl **** Check for parport (currently Linux only) ****
438 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
439 AC_TRY_COMPILE(
440 [#include <linux/ppdev.h>],
441 [ioctl (1,PPCLAIM,0)],
442 [ac_cv_c_ppdev="yes"],
443 [ac_cv_c_ppdev="no"])
444 )
445 if test "$ac_cv_c_ppdev" = "yes"
446 then
447 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
448 fi
450 dnl **** Check for va_copy ****
451 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
452 AC_TRY_LINK(
453 [#include <stdarg.h>],
454 [va_list ap1, ap2;
455 va_copy(ap1,ap2);
456 ],
457 [ac_cv_c_va_copy="yes"],
458 [ac_cv_c_va_copy="no"])
459 )
460 if test "$ac_cv_c_va_copy" = "yes"
461 then
462 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
463 fi
464 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
465 AC_TRY_LINK(
466 [#include <stdarg.h>],
467 [va_list ap1, ap2;
468 __va_copy(ap1,ap2);
469 ],
470 [ac_cv_c___va_copy="yes"],
471 [ac_cv_c___va_copy="no"])
472 )
473 if test "$ac_cv_c___va_copy" = "yes"
474 then
475 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
476 fi
478 dnl **** Check for IPX (currently Linux only) ****
479 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
480 AC_TRY_COMPILE(
481 [#include <sys/socket.h>
482 #include <netipx/ipx.h>],
483 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
484 [ac_cv_c_ipx_gnu="yes"],
485 [ac_cv_c_ipx_gnu="no"])
486 )
487 if test "$ac_cv_c_ipx_gnu" = "yes"
488 then
489 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
490 fi
492 if test "$ac_cv_c_ipx_gnu" = "no"
493 then
494 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
495 AC_TRY_COMPILE(
496 [#include <sys/socket.h>
497 #include <asm/types.h>
498 #include <linux/ipx.h>],
499 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
500 [ac_cv_c_ipx_linux="yes"],
501 [ac_cv_c_ipx_linux="no"])
502 )
503 if test "$ac_cv_c_ipx_linux" = "yes"
504 then
505 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
506 fi
507 fi
509 dnl **** Check for Open Sound System ****
510 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
512 AC_CACHE_CHECK([for Open Sound System],
513 ac_cv_c_opensoundsystem,
514 AC_TRY_COMPILE([
515 #if defined(HAVE_SYS_SOUNDCARD_H)
516 #include <sys/soundcard.h>
517 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
518 #include <machine/soundcard.h>
519 #elif defined(HAVE_SOUNDCARD_H)
520 #include <soundcard.h>
521 #endif
522 ],[
524 /* check for one of the Open Sound System specific SNDCTL_ defines */
525 #if !defined(SNDCTL_DSP_STEREO)
526 #error No open sound system
527 #endif
528 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
530 if test "$ac_cv_c_opensoundsystem" = "yes"
531 then
532 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
533 fi
535 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
536 ac_cv_c_opensoundsystem_midi,
537 AC_TRY_COMPILE([
538 #if defined(HAVE_SYS_SOUNDCARD_H)
539 #include <sys/soundcard.h>
540 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
541 #include <machine/soundcard.h>
542 #elif defined(HAVE_SOUNDCARD_H)
543 #include <soundcard.h>
544 #endif
545 ],[
547 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
548 #if !defined(SNDCTL_SEQ_SYNC)
549 #error No open sound system MIDI interface
550 #endif
551 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
553 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
554 then
555 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
556 fi
558 dnl **** Check for aRts Sound Server ****
559 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
560 AC_CACHE_CHECK([for aRts Sound server],
561 ac_cv_c_artsserver,
562 if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
563 then
564 ac_cv_c_artsserver=no
565 else
566 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
567 ARTSC_LIBS=`$ARTSCCONFIG --libs`
568 ac_cv_c_artsserver=no
569 save_CFLAGS="$CFLAGS"
570 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
571 AC_TRY_COMPILE([
572 #include <artsc.h>
573 ],[
574 arts_stream_t stream;
575 ],[
576 ac_cv_c_artsserver=yes
577 ])
578 CFLAGS="$save_CFLAGS"
579 fi)
581 if test "$ac_cv_c_artsserver" = "yes"
582 then
583 AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
584 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
586 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
587 fi
589 dnl **** Check for ALSA ****
590 AC_SUBST(ALSALIBS,"")
591 AC_CHECK_HEADERS(sys/asoundlib.h)
592 if test "$ac_cv_header_sys_asoundlib_h" = "yes"
593 then
594 AC_CHECK_LIB(asound,snd_pcm_open,
595 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
596 ALSALIBS="-lasound")
597 fi
599 dnl **** Check for NAS ****
600 AC_SUBST(NASLIBS,"")
601 AC_CHECK_HEADERS(audio/audiolib.h,
602 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
603 AC_CHECK_LIB(audio,AuCreateFlow,
604 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
605 NASLIBS="-laudio -lXt \$(X_LIBS) \$(XLIB)"],,
606 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
608 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
610 AC_SUBST(AUDIOIOLIBS,"")
611 AC_CHECK_HEADERS(libaudioio.h,
612 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
613 [AUDIOIOLIBS="-laudioio"
614 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
616 dnl **** Check for broken glibc mmap64 ****
618 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
619 AC_TRY_RUN([
620 #define _FILE_OFFSET_BITS 64
621 #include <stdio.h>
622 #include <unistd.h>
623 #include <fcntl.h>
624 #include <sys/mman.h>
625 #include <errno.h>
627 int main(int argc,char **argv) {
628 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
629 if (fd == -1) exit(1);
631 unlink("conftest.map");
633 write(fd,"test",4);
635 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
636 (errno == EINVAL)
637 ) {
638 exit(1);
639 }
640 close(fd);
641 fprintf(stderr,"success!\n");
642 exit(0);
643 }
645 ],
646 ac_cv_mmap64_works="yes",
647 ac_cv_mmap64_works="no",
648 ac_cv_mmap64_works="no") )
650 if test "$ac_cv_mmap64_works" = "yes"
651 then
652 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
653 fi
655 dnl **** Check for gcc strength-reduce bug ****
657 if test "x${GCC}" = "xyes"
658 then
659 CFLAGS="$CFLAGS -Wall"
660 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
661 AC_TRY_RUN([
662 int L[[4]] = {0,1,2,3};
663 int main(void) {
664 static int Array[[3]];
665 unsigned int B = 3;
666 int i;
667 for(i=0; i<B; i++) Array[[i]] = i - 3;
668 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
669 L[[i]] = 4;
671 exit( Array[[1]] != -2 || L[[2]] != 3);
672 }],
673 ac_cv_c_gcc_strength_bug="no",
674 ac_cv_c_gcc_strength_bug="yes",
675 ac_cv_c_gcc_strength_bug="yes") )
676 if test "$ac_cv_c_gcc_strength_bug" = "yes"
677 then
678 CFLAGS="$CFLAGS -fno-strength-reduce"
679 fi
681 dnl Check for -mpreferred-stack-boundary
682 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
683 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
684 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
685 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
686 then
687 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
688 fi
689 fi
691 dnl **** Check how to define a function in assembly code ****
693 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
694 WINE_TRY_ASM_LINK(
695 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
696 ac_cv_asm_func_def=".def",
697 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
698 ac_cv_asm_func_def=".type @function",
699 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
700 ac_cv_asm_func_def=".type 2",
701 ac_cv_asm_func_def="unknown")])]))
703 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
704 case "$ac_cv_asm_func_def" in
705 ".def")
706 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
707 ".type @function")
708 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
709 ".type 2")
710 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
711 *)
712 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
713 esac
715 dnl **** Check for underscore on external symbols ****
717 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
718 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
719 [extern int ac_test;],
720 [if (ac_test) return 1],
721 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
723 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
724 if test "$ac_cv_c_extern_prefix" = "yes"
725 then
726 AC_DEFINE([__ASM_NAME(name)], ["_" name])
727 else
728 AC_DEFINE([__ASM_NAME(name)], [name])
729 fi
731 dnl **** Check whether stdcall symbols need to be decorated ****
733 AC_CACHE_CHECK([whether stdcall symbols need to be decorated], ac_cv_c_stdcall_decoration,
734 WINE_TRY_ASM_LINK(["\t.globl _ac_test@0\n_ac_test@0:\n\t.globl ac_test@0\nac_test@0:"],
735 [extern void __attribute__((__stdcall__)) ac_test(void);],
736 [ac_test()],
737 ac_cv_c_stdcall_decoration="yes",ac_cv_c_stdcall_decoration="no"))
738 if test "$ac_cv_c_stdcall_decoration" = "yes"
739 then
740 AC_DEFINE(NEED_STDCALL_DECORATION, 1, [Define if stdcall symbols need to be decorated])
741 fi
743 dnl **** Check for .string in assembler ****
745 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
746 WINE_TRY_ASM_LINK([".string \"test\""],,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
747 if test "$ac_cv_c_asm_string" = "yes"
748 then
749 AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
750 fi
752 dnl **** Check for working dll ****
754 AC_SUBST(DLLEXT,"")
755 AC_SUBST(DLLFLAGS,"")
756 AC_SUBST(DLLIBS,"")
757 AC_SUBST(LDDLLFLAGS,"")
758 AC_SUBST(LDSHARED,"")
760 case $host_os in
761 cygwin*|mingw32*)
762 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
763 if test "$DLLWRAP" = "false"; then
764 LIBEXT="a"
765 else
766 dnl FIXME - check whether dllwrap works correctly...
767 LIBEXT="dll"
768 fi
769 ;;
770 *)
771 AC_CHECK_HEADERS(dlfcn.h,
772 [AC_CHECK_FUNCS(dlopen,,
773 [AC_CHECK_LIB(dl,dlopen,
774 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
775 DLLIBS="-ldl"],
776 [LIBEXT="a"])])],
777 [LIBEXT="a"])
779 if test "$LIBEXT" = "so"
780 then
781 DLLFLAGS="-fPIC"
782 DLLEXT=".so"
783 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
784 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
785 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
786 if test "$ac_cv_c_dll_gnuelf" = "yes"
787 then
788 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
789 LDDLLFLAGS="-Wl,-Bsymbolic"
790 else
791 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
792 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
793 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
794 if test "$ac_cv_c_dll_unixware" = "yes"
795 then
796 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
797 LDDLLFLAGS="-Wl,-B,symbolic"
798 fi
799 fi
800 fi
801 ;;
802 esac
804 if test "$LIBEXT" = "a"; then
805 AC_MSG_ERROR(
806 [could not find a way to build shared libraries.
807 It is currently not possible to build Wine without shared library
808 (.so) support to allow transparent switch between .so and .dll files.
809 If you are using Linux, you will need a newer binutils.]
810 )
811 fi
813 case $build_os in
814 cygwin*|mingw32*)
815 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/library:\$(TOOLSDIR)/unicode:\$\$PATH\"") ;;
816 *)
817 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/library:\$(TOOLSDIR)/unicode:\$\$LD_LIBRARY_PATH\"") ;;
818 esac
820 dnl Mingw needs explicit msvcrt for linking libwine
821 AC_SUBST(CRTLIBS,"")
822 case $host_os in
823 mingw32*)
824 CRTLIBS="-lmsvcrt" ;;
825 esac
827 dnl **** Get the soname for libraries that we load dynamically ****
829 if test "$LIBEXT" = "so"
830 then
831 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
832 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
833 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
834 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
835 fi
838 dnl **** Check for reentrant libc ****
840 wine_cv_libc_reentrant=no
841 dnl Linux style errno location
842 WINE_CHECK_ERRNO([__errno_location], [wine_cv_libc_reentrant=__errno_location],
843 dnl FreeBSD style errno location
844 WINE_CHECK_ERRNO([__error], [wine_cv_libc_reentrant=__error],
845 dnl Solaris style errno location
846 WINE_CHECK_ERRNO([___errno], [wine_cv_libc_reentrant=___errno],
847 dnl UnixWare style errno location
848 WINE_CHECK_ERRNO([__thr_errno], [wine_cv_libc_reentrant=__thr_errno],
849 dnl NetBSD style errno location
850 WINE_CHECK_ERRNO([__errno], [wine_cv_libc_reentrant=__errno])
851 ))))
853 if test "$wine_cv_libc_reentrant" != "no"
854 then
855 AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
856 [Define to the name of the function returning errno for reentrant libc])
857 fi
859 dnl **** Check for reentrant X libraries ****
860 dnl
861 dnl This may fail to determine whether X libraries are reentrant if
862 dnl AC_PATH_XTRA does not set x_libraries.
864 if test "$have_x" = "yes"
865 then
866 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
867 [libX11_check=none
868 for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
869 if test -r $dir/libX11.so; then
870 libX11_check="-D $dir/libX11.so"
871 break
872 fi
873 if test -r $dir/libX11.a; then
874 libX11_check="$dir/libX11.a"
875 break
876 fi
877 done
878 if test "$libX11_check" != "none"; then
879 if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
880 then
881 wine_cv_x_reentrant=yes
882 else
883 wine_cv_x_reentrant=no
884 fi
885 else
886 wine_cv_x_reentrant=unknown
887 fi])
888 fi
890 dnl **** Check for functions ****
892 AC_FUNC_ALLOCA()
893 AC_CHECK_FUNCS(\
894 __libc_fork \
895 _lwp_create \
896 _pclose \
897 _popen \
898 _snprintf \
899 _stricmp \
900 _strnicmp \
901 chsize \
902 clone \
903 ecvt \
904 finite \
905 fpclass \
906 ftruncate \
907 ftruncate64 \
908 getnetbyaddr \
909 getnetbyname \
910 getpagesize \
911 getprotobyname \
912 getprotobynumber \
913 getpwuid \
914 getservbyport \
915 getsockopt \
916 inet_network \
917 lseek64 \
918 lstat \
919 memmove \
920 mkstemp \
921 mmap \
922 pclose \
923 popen \
924 pread \
925 pwrite \
926 rfork \
927 select \
928 sendmsg \
929 settimeofday \
930 sigaltstack \
931 snprintf \
932 statfs \
933 strcasecmp \
934 strerror \
935 strncasecmp \
936 tcgetattr \
937 timegm \
938 usleep \
939 vfscanf \
940 wait4 \
941 waitpid \
942 )
944 dnl **** Check for header files ****
946 AC_CHECK_HEADERS(\
947 arpa/inet.h \
948 arpa/nameser.h \
949 direct.h \
950 elf.h \
951 float.h \
952 ieeefp.h \
953 io.h \
954 libaudioio.h \
955 libio.h \
956 libutil.h \
957 link.h \
958 linux/cdrom.h \
959 linux/hdreg.h \
960 linux/input.h \
961 linux/joystick.h \
962 linux/major.h \
963 linux/param.h \
964 linux/serial.h \
965 linux/ucdrom.h \
966 netdb.h \
967 netinet/in.h \
968 netinet/in_systm.h \
969 netinet/tcp.h \
970 pty.h \
971 pwd.h \
972 sched.h \
973 scsi/sg.h \
974 socket.h \
975 stdint.h \
976 strings.h \
977 sys/cdio.h \
978 sys/errno.h \
979 sys/file.h \
980 sys/filio.h \
981 sys/inttypes.h \
982 sys/ioctl.h \
983 sys/ipc.h \
984 sys/link.h \
985 sys/lwp.h \
986 sys/mman.h \
987 sys/modem.h \
988 sys/mount.h \
989 sys/msg.h \
990 sys/param.h \
991 sys/ptrace.h \
992 sys/reg.h \
993 sys/shm.h \
994 sys/signal.h \
995 sys/socket.h \
996 sys/sockio.h \
997 sys/statfs.h \
998 sys/strtio.h \
999 sys/syscall.h \
1000 sys/sysctl.h \
1001 sys/time.h \
1002 sys/user.h \
1003 sys/v86.h \
1004 sys/v86intr.h \
1005 sys/vfs.h \
1006 sys/vm86.h \
1007 sys/wait.h \
1008 syscall.h \
1009 termios.h \
1010 ucontext.h \
1011 unistd.h \
1012 )
1013 AC_HEADER_STAT()
1015 dnl *** Check for net/if.h
1016 AC_CHECK_HEADERS(net/if.h,,,
1017 [#if HAVE_SYS_TYPES_H
1018 # include <sys/types.h>
1019 #endif
1020 #if HAVE_SYS_SOCKET_H
1021 # include <sys/socket.h>
1022 #endif])
1024 dnl *** Check for netinet/ip.h
1025 AC_CHECK_HEADERS(netinet/ip.h,,,
1026 [#if HAVE_SYS_SOCKET_H
1027 # include <sys/socket.h>
1028 #endif
1029 #if HAVE_NETINET_IN_SYSTM_H
1030 # include <netinet/in_systm.h>
1031 #endif])
1033 dnl *** Check for resolv.h
1034 AC_CHECK_HEADERS(resolv.h,,,
1035 [#if HAVE_SYS_SOCKET_H
1036 # include <sys/socket.h>
1037 #endif])
1039 dnl **** Check for types ****
1041 AC_C_CONST
1042 AC_C_INLINE
1043 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1044 AC_CHECK_SIZEOF(long long,0)
1046 AC_CACHE_CHECK([whether linux/input.h is for real],
1047 wine_cv_linux_input_h,
1048 AC_TRY_COMPILE([
1049 #include <linux/input.h>
1050 ] , [
1051 int foo = EVIOCGBIT(EV_ABS,42);
1052 int bar = BTN_PINKIE;
1053 int fortytwo = 42;
1054 ],
1055 wine_cv_linux_input_h=yes,
1056 wine_cv_linux_input_h=no,
1057 no
1058 )
1059 )
1060 if test "$wine_cv_linux_input_h" = "yes"
1061 then
1062 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1063 [Define if we have linux/input.h AND it contains the INPUT event API])
1064 fi
1067 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1068 wine_cv_linux_gethostbyname_r_6,
1069 AC_TRY_COMPILE([
1070 #include <netdb.h>
1071 ], [
1072 char *name=NULL;
1073 struct hostent he;
1074 struct hostent *result;
1075 char *buf=NULL;
1076 int bufsize=0;
1077 int res,errnr;
1078 char *addr=NULL;
1079 int addrlen=0;
1080 int addrtype=0;
1081 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1082 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1083 ],
1084 wine_cv_linux_gethostbyname_r_6=yes,
1085 wine_cv_linux_gethostbyname_r_6=no
1086 )
1087 )
1088 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1089 then
1090 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1091 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1092 fi
1094 if test "$ac_cv_header_linux_joystick_h" = "yes"
1095 then
1096 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1097 wine_cv_linux_joystick_22_api,
1098 AC_TRY_COMPILE([
1099 #include <sys/ioctl.h>
1100 #include <linux/joystick.h>
1102 struct js_event blub;
1103 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1104 #error "no 2.2 header"
1105 #endif
1106 ],/*empty*/,
1107 wine_cv_linux_joystick_22_api=yes,
1108 wine_cv_linux_joystick_22_api=no,
1109 wine_cv_linux_joystick_22_api=no
1110 )
1111 )
1112 if test "$wine_cv_linux_joystick_22_api" = "yes"
1113 then
1114 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1115 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1116 fi
1117 fi
1119 dnl **** statfs checks ****
1121 if test "$ac_cv_header_sys_vfs_h" = "yes"
1122 then
1123 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1124 wine_cv_sys_vfs_has_statfs,
1125 AC_TRY_COMPILE([
1126 #include <sys/types.h>
1127 #ifdef HAVE_SYS_PARAM_H
1128 # include <sys/param.h>
1129 #endif
1130 #include <sys/vfs.h>
1131 ],[
1132 struct statfs stfs;
1134 memset(&stfs,0,sizeof(stfs));
1135 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1136 )
1137 )
1138 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1139 then
1140 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1141 [Define if the struct statfs is defined by <sys/vfs.h>])
1142 fi
1143 fi
1145 if test "$ac_cv_header_sys_statfs_h" = "yes"
1146 then
1147 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1148 wine_cv_sys_statfs_has_statfs,
1149 AC_TRY_COMPILE([
1150 #include <sys/types.h>
1151 #ifdef HAVE_SYS_PARAM_H
1152 # include <sys/param.h>
1153 #endif
1154 #include <sys/statfs.h>
1155 ],[
1156 struct statfs stfs;
1157 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1158 )
1159 )
1160 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1161 then
1162 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1163 [Define if the struct statfs is defined by <sys/statfs.h>])
1164 fi
1165 fi
1167 if test "$ac_cv_header_sys_mount_h" = "yes"
1168 then
1169 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1170 wine_cv_sys_mount_has_statfs,
1171 AC_TRY_COMPILE([
1172 #include <sys/types.h>
1173 #ifdef HAVE_SYS_PARAM_H
1174 # include <sys/param.h>
1175 #endif
1176 #include <sys/mount.h>
1177 ],[
1178 struct statfs stfs;
1179 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1180 )
1181 )
1182 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1183 then
1184 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1185 [Define if the struct statfs is defined by <sys/mount.h>])
1186 fi
1187 fi
1189 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1191 WINE_CHECK_STRUCT_MEMBER(statfs,f_bfree,
1192 [#include <sys/types.h>
1193 #ifdef HAVE_SYS_PARAM_H
1194 # include <sys/param.h>
1195 #endif
1196 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1197 # include <sys/mount.h>
1198 #else
1199 # ifdef STATFS_DEFINED_BY_SYS_VFS
1200 # include <sys/vfs.h>
1201 # else
1202 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1203 # include <sys/statfs.h>
1204 # endif
1205 # endif
1206 #endif],
1207 [AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])])
1209 WINE_CHECK_STRUCT_MEMBER(statfs,f_bavail,
1210 [#include <sys/types.h>
1211 #ifdef HAVE_SYS_PARAM_H
1212 # include <sys/param.h>
1213 #endif
1214 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1215 # include <sys/mount.h>
1216 #else
1217 # ifdef STATFS_DEFINED_BY_SYS_VFS
1218 # include <sys/vfs.h>
1219 # else
1220 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1221 # include <sys/statfs.h>
1222 # endif
1223 # endif
1224 #endif],
1225 [AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])])
1227 dnl Check for file descriptor passing with msg_accrights
1228 WINE_CHECK_STRUCT_MEMBER(msghdr,msg_accrights,
1229 [#include <sys/types.h>
1230 #include <sys/socket.h>],
1231 [AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])])
1233 dnl Check for the sa_len member in struct sockaddr
1234 WINE_CHECK_STRUCT_MEMBER(sockaddr,sa_len,
1235 [#include <sys/types.h>
1236 #include <sys/socket.h>],
1237 [AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])])
1239 dnl Check for the sun_len member in struct sockaddr_un
1240 WINE_CHECK_STRUCT_MEMBER(sockaddr_un,sun_len,
1241 [#include <sys/types.h>
1242 #include <sys/socket.h>
1243 #include <sys/un.h>],
1244 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])])
1246 dnl *** check for the need to define __i386__
1248 case $host_cpu in
1249 *i[3456789]86* )
1250 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1251 AC_EGREP_CPP(yes,[#ifndef __i386__
1252 yes
1253 #endif],
1254 ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1255 ;;
1256 esac
1257 if test "$ac_cv_cpp_def_i386" = "yes"
1258 then
1259 CFLAGS="$CFLAGS -D__i386__"
1260 LINTFLAGS="$LINTFLAGS -D__i386__"
1261 fi
1263 dnl *** check for the need to define __sparc__
1265 case $host_cpu in
1266 *sparc* )
1267 AC_CACHE_CHECK([whether we need to define __sparc__],ac_cv_cpp_def_sparc,
1268 AC_EGREP_CPP(yes,[#ifndef __sparc__
1269 yes
1270 #endif],
1271 ac_cv_cpp_def_sparc="yes", ac_cv_cpp_def_sparc="no"))
1272 ;;
1273 esac
1274 if test "$ac_cv_cpp_def_sparc" = "yes"
1275 then
1276 CFLAGS="$CFLAGS -D__sparc__"
1277 LINTFLAGS="$LINTFLAGS -D__sparc__"
1278 fi
1280 dnl *** check for the need to define __sun__
1282 case $host_vendor in
1283 *sun* )
1284 AC_CACHE_CHECK([whether we need to define __sun__],ac_cv_cpp_def_sun,
1285 AC_EGREP_CPP(yes,[#ifndef __sun__
1286 yes
1287 #endif],
1288 ac_cv_cpp_def_sun="yes", ac_cv_cpp_def_sun="no"))
1289 ;;
1290 esac
1291 if test "$ac_cv_cpp_def_sun" = "yes"
1292 then
1293 CFLAGS="$CFLAGS -D__sun__"
1294 LINTFLAGS="$LINTFLAGS -D__sun__"
1295 fi
1297 dnl **** Generate output files ****
1299 AH_TOP([#define __WINE_CONFIG_H])
1301 WINE_CONFIG_EXTRA_DIR(controls)
1302 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1303 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1304 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1305 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1306 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1307 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1308 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1309 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1310 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1311 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1312 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1313 WINE_CONFIG_EXTRA_DIR(dlls/gdi/win16drv)
1314 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1315 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1316 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1317 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1318 WINE_CONFIG_EXTRA_DIR(files)
1319 WINE_CONFIG_EXTRA_DIR(graphics)
1320 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1321 WINE_CONFIG_EXTRA_DIR(if1632)
1322 WINE_CONFIG_EXTRA_DIR(include/wine)
1323 WINE_CONFIG_EXTRA_DIR(loader)
1324 WINE_CONFIG_EXTRA_DIR(loader/ne)
1325 WINE_CONFIG_EXTRA_DIR(memory)
1326 WINE_CONFIG_EXTRA_DIR(misc)
1327 WINE_CONFIG_EXTRA_DIR(msdos)
1328 WINE_CONFIG_EXTRA_DIR(objects)
1329 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1330 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1331 WINE_CONFIG_EXTRA_DIR(programs/winetest/tests)
1332 WINE_CONFIG_EXTRA_DIR(relay32)
1333 WINE_CONFIG_EXTRA_DIR(scheduler)
1334 WINE_CONFIG_EXTRA_DIR(win32)
1335 WINE_CONFIG_EXTRA_DIR(windows)
1337 MAKE_RULES=Make.rules
1338 AC_SUBST_FILE(MAKE_RULES)
1340 MAKE_DLL_RULES=dlls/Makedll.rules
1341 AC_SUBST_FILE(MAKE_DLL_RULES)
1343 MAKE_TEST_RULES=dlls/Maketest.rules
1344 AC_SUBST_FILE(MAKE_TEST_RULES)
1346 MAKE_PROG_RULES=programs/Makeprog.rules
1347 AC_SUBST_FILE(MAKE_PROG_RULES)
1349 AC_CONFIG_FILES([
1350 Make.rules
1351 dlls/Makedll.rules
1352 dlls/Maketest.rules
1353 programs/Makeprog.rules
1354 Makefile
1355 debugger/Makefile
1356 dlls/Makefile
1357 dlls/advapi32/Makefile
1358 dlls/advapi32/tests/Makefile
1359 dlls/avicap32/Makefile
1360 dlls/avifil32/Makefile
1361 dlls/comcat/Makefile
1362 dlls/comctl32/Makefile
1363 dlls/commdlg/Makefile
1364 dlls/crtdll/Makefile
1365 dlls/crypt32/Makefile
1366 dlls/d3d8/Makefile
1367 dlls/dciman32/Makefile
1368 dlls/ddraw/Makefile
1369 dlls/devenum/Makefile
1370 dlls/dinput/Makefile
1371 dlls/dinput8/Makefile
1372 dlls/dplay/Makefile
1373 dlls/dplayx/Makefile
1374 dlls/dsound/Makefile
1375 dlls/gdi/Makefile
1376 dlls/glu32/Makefile
1377 dlls/icmp/Makefile
1378 dlls/imagehlp/Makefile
1379 dlls/imm32/Makefile
1380 dlls/kernel/Makefile
1381 dlls/kernel/tests/Makefile
1382 dlls/lzexpand/Makefile
1383 dlls/mapi32/Makefile
1384 dlls/mpr/Makefile
1385 dlls/msacm/Makefile
1386 dlls/msacm/imaadp32/Makefile
1387 dlls/msacm/msadp32/Makefile
1388 dlls/msacm/msg711/Makefile
1389 dlls/msacm/winemp3/Makefile
1390 dlls/msdmo/Makefile
1391 dlls/msimg32/Makefile
1392 dlls/msisys/Makefile
1393 dlls/msnet32/Makefile
1394 dlls/msrle32/Makefile
1395 dlls/msvcrt/Makefile
1396 dlls/msvcrt20/Makefile
1397 dlls/msvideo/Makefile
1398 dlls/netapi32/Makefile
1399 dlls/ntdll/Makefile
1400 dlls/odbc32/Makefile
1401 dlls/ole32/Makefile
1402 dlls/oleaut32/Makefile
1403 dlls/oleaut32/tests/Makefile
1404 dlls/olecli/Makefile
1405 dlls/oledlg/Makefile
1406 dlls/olepro32/Makefile
1407 dlls/olesvr/Makefile
1408 dlls/opengl32/Makefile
1409 dlls/psapi/Makefile
1410 dlls/qcap/Makefile
1411 dlls/quartz/Makefile
1412 dlls/rasapi32/Makefile
1413 dlls/richedit/Makefile
1414 dlls/rpcrt4/Makefile
1415 dlls/serialui/Makefile
1416 dlls/setupapi/Makefile
1417 dlls/shdocvw/Makefile
1418 dlls/shell32/Makefile
1419 dlls/shfolder/Makefile
1420 dlls/shlwapi/Makefile
1421 dlls/shlwapi/tests/Makefile
1422 dlls/snmpapi/Makefile
1423 dlls/sti/Makefile
1424 dlls/tapi32/Makefile
1425 dlls/ttydrv/Makefile
1426 dlls/twain/Makefile
1427 dlls/url/Makefile
1428 dlls/urlmon/Makefile
1429 dlls/user/Makefile
1430 dlls/user/tests/Makefile
1431 dlls/version/Makefile
1432 dlls/win32s/Makefile
1433 dlls/winaspi/Makefile
1434 dlls/winedos/Makefile
1435 dlls/wineps/Makefile
1436 dlls/wininet/Makefile
1437 dlls/wininet/tests/Makefile
1438 dlls/winmm/Makefile
1439 dlls/winmm/joystick/Makefile
1440 dlls/winmm/mcianim/Makefile
1441 dlls/winmm/mciavi/Makefile
1442 dlls/winmm/mcicda/Makefile
1443 dlls/winmm/mciseq/Makefile
1444 dlls/winmm/mciwave/Makefile
1445 dlls/winmm/midimap/Makefile
1446 dlls/winmm/wavemap/Makefile
1447 dlls/winmm/winealsa/Makefile
1448 dlls/winmm/winearts/Makefile
1449 dlls/winmm/wineaudioio/Makefile
1450 dlls/winmm/winenas/Makefile
1451 dlls/winmm/wineoss/Makefile
1452 dlls/winnls/Makefile
1453 dlls/winsock/Makefile
1454 dlls/winsock/tests/Makefile
1455 dlls/winspool/Makefile
1456 dlls/wintrust/Makefile
1457 dlls/wow32/Makefile
1458 dlls/wsock32/Makefile
1459 dlls/x11drv/Makefile
1460 documentation/Makefile
1461 include/Makefile
1462 library/Makefile
1463 miscemu/Makefile
1464 ole/Makefile
1465 programs/Makefile
1466 programs/avitools/Makefile
1467 programs/clock/Makefile
1468 programs/cmdlgtst/Makefile
1469 programs/control/Makefile
1470 programs/expand/Makefile
1471 programs/notepad/Makefile
1472 programs/osversioncheck/Makefile
1473 programs/progman/Makefile
1474 programs/regapi/Makefile
1475 programs/regedit/Makefile
1476 programs/regsvr32/Makefile
1477 programs/regtest/Makefile
1478 programs/uninstaller/Makefile
1479 programs/view/Makefile
1480 programs/wcmd/Makefile
1481 programs/wineconsole/Makefile
1482 programs/winefile/Makefile
1483 programs/winemine/Makefile
1484 programs/winepath/Makefile
1485 programs/winetest/Makefile
1486 programs/winhelp/Makefile
1487 programs/winver/Makefile
1488 server/Makefile
1489 tools/Makefile
1490 tools/widl/Makefile
1491 tools/winapi/Makefile
1492 tools/winebuild/Makefile
1493 tools/winedump/Makefile
1494 tools/wmc/Makefile
1495 tools/wpp/Makefile
1496 tools/wrc/Makefile
1497 tsx11/Makefile
1498 unicode/Makefile])
1500 AC_OUTPUT
1502 if test "$have_x" = "no"
1503 then
1504 echo
1505 echo "*** Warning: X development files not found. Wine will be built without"
1506 echo "*** X support, which currently does not work, and would probably not be"
1507 echo "*** what you want anyway. You will need to install devel packages of"
1508 echo "*** Xlib/Xfree86 at the very least."
1509 fi
1511 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1512 then
1513 echo
1514 echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1515 echo "*** terminal resize support. Consider upgrading ncurses."
1516 fi
1518 if test "$wine_cv_libc_reentrant" = "no"
1519 then
1520 echo
1521 echo "*** Warning: non-reentrant libc detected. Wine will be built without"
1522 echo "*** threading support. Consider upgrading libc to a more recent"
1523 echo "*** reentrant version of libc."
1524 fi
1526 if test "$have_x" = "yes" -a "$wine_cv_x_reentrant" != "yes"
1527 then
1528 echo
1529 echo "*** Warning: non-reentrant X11 library detected. Multi-threaded"
1530 echo "*** applications won't work properly. You should upgrade your X11 library."
1531 fi
1533 if test "$wine_cv_opengl_version_OK" = "no"
1534 then
1535 echo
1536 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1537 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1538 fi
1540 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a "x$enable_opengl" = "x"
1541 then
1542 echo
1543 echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1544 echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1545 echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1546 echo "*** start configure with '--enable-opengl' to force OpenGL support."
1547 fi
1549 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a "x$enable_opengl" = "xyes"
1550 then
1551 echo
1552 echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1553 echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1554 echo "*** support before reporting bugs."
1555 fi
1557 if test "$wine_cv_warn_cups_h" = "yes"
1558 then
1559 echo
1560 echo "*** Note: You have cups runtime libraries, but no development"
1561 echo "*** libraries. Install the cups-devel package or whichever package"
1562 echo "*** contains cups.h to enable CUPS support in Wine."
1563 fi
1565 if test "$wine_cv_msg_freetype" = "yes"
1566 then
1567 echo
1568 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1569 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1570 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1571 echo "*** enable Wine to use TrueType fonts."
1572 fi
1574 echo
1575 echo "Configure finished. Do 'make depend && make' to compile Wine."
1576 echo
1578 dnl Local Variables:
1579 dnl comment-start: "dnl "
1580 dnl comment-end: ""
1581 dnl comment-start-skip: "\\bdnl\\b\\s *"
1582 dnl compile-command: "autoconf"
1583 dnl End: