| blob | f9735791c592ceb01457dec66e90ea87d1f5b8ed |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
25 if test "x$enable_win16" = "xno"
26 then
27 WIN16_FILES=""
28 WIN16_INSTALL=""
29 fi
30 if test "x$enable_debug" = "xno"
31 then
32 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
33 fi
34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
35 then
36 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
37 fi
39 dnl **** Check for some programs ****
41 AC_CANONICAL_HOST
42 AC_PROG_MAKE_SET
43 AC_PROG_CC
44 AC_PROG_CPP
46 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
47 [if test -z "$with_wine_tools"; then
48 if test "$cross_compiling" = "yes"; then
49 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
50 else
51 wine_cv_toolsdir="\$(TOPOBJDIR)"
52 fi
53 elif test -d "$with_wine_tools/tools/winebuild"; then
54 case $with_wine_tools in
55 /*) wine_cv_toolsdir="$with_wine_tools" ;;
56 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
57 esac
58 else
59 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
60 fi])
61 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
63 AC_PATH_XTRA
64 AC_PROG_YACC
65 AC_PROG_LEX
67 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
68 dnl **** without one present.
69 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
70 if test "$XYACC" = "none"
71 then
72 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
73 fi
74 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
75 if test "$XLEX" = "none"
76 then
77 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
78 fi
80 AC_CHECK_TOOLS(AS,[gas as],as)
81 AC_CHECK_TOOL(LD,ld,ld)
82 AC_CHECK_TOOL(AR,ar,ar)
83 AC_PROG_RANLIB
84 AC_CHECK_TOOL(STRIP,strip,strip)
85 AC_CHECK_TOOL(WINDRES,windres,false)
86 AC_PROG_LN_S
87 WINE_PROG_LN
88 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
89 AC_PROG_INSTALL
90 dnl Prepend src dir to install path dir if it's a relative path
91 case "$INSTALL" in
92 [[\\/$]]* | ?:[[\\/]]* ) ;;
93 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
94 esac
96 dnl Check for lint
97 AC_CHECK_PROGS(LINT, lclint lint)
98 if test "$LINT" = "lint"
99 then
100 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
101 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
102 fi
103 AC_SUBST(LINT)
104 AC_SUBST(LINTFLAGS)
106 dnl Check for db2html
107 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
108 AC_SUBST(DB2HTML)
110 dnl Check for db2pdf
111 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
112 AC_SUBST(DB2PDF)
114 dnl Check for db2ps
115 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
116 AC_SUBST(DB2PS)
118 dnl Check for db2txt
119 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
120 AC_SUBST(DB2TXT)
122 dnl **** Check for some libraries ****
124 dnl Check for -lm
125 AC_CHECK_LIB(m,sqrt)
126 dnl Check for -li386 for NetBSD and OpenBSD
127 AC_CHECK_LIB(i386,i386_set_ldt)
128 dnl Check for -lossaudio for NetBSD
129 AC_CHECK_LIB(ossaudio,_oss_ioctl)
130 dnl Check for -lw for Solaris
131 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
132 dnl Check for -lnsl for Solaris
133 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
134 dnl Check for -lsocket for Solaris
135 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
136 dnl Check for -lresolv for Solaris
137 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
138 dnl Check for -lxpg4 for FreeBSD
139 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
140 dnl Check for -lpoll for Mac OS X/Darwin
141 AC_CHECK_LIB(poll,poll)
142 dnl Check for -lpthread
143 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
145 JPEGLIB=""
146 AC_SUBST(JPEGLIB)
147 AC_CHECK_HEADERS(jpeglib.h,
148 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
149 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
150 JPEGLIB="-ljpeg"
151 )
152 )
154 AC_SUBST(GIFLIB,"")
155 AC_CHECK_HEADERS(gif_lib.h,
156 AC_CHECK_LIB(ungif,DGifOpen,
157 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
158 GIFLIB="-lungif"],
159 [AC_CHECK_LIB(gif,DGifOpen,
160 [AC_DEFINE(HAVE_LIBGIF,1)
161 GIFLIB="-lgif"])]))
163 AC_SUBST(XLIB)
164 AC_SUBST(XFILES)
165 XFILES=""
166 AC_SUBST(OPENGLFILES)
167 OPENGLFILES=""
168 AC_SUBST(GLU32FILES)
169 GLU32FILES=""
170 AC_SUBST(OPENGL_LIBS)
171 OPENGL_LIBS=""
172 if test "$have_x" = "yes"
173 then
174 XLIB="-lXext -lX11"
175 ac_save_CPPFLAGS="$CPPFLAGS"
176 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
178 dnl *** All of the following tests require X11/Xlib.h
179 AC_CHECK_HEADERS(X11/Xlib.h,
180 [
181 AC_CHECK_HEADERS([X11/XKBlib.h \
182 X11/Xutil.h \
183 X11/extensions/shape.h \
184 X11/extensions/XInput.h \
185 X11/extensions/XShm.h \
186 X11/extensions/Xrandr.h \
187 X11/extensions/Xrender.h \
188 X11/extensions/Xvlib.h \
189 X11/extensions/xf86dga.h \
190 X11/extensions/xf86vmode.h],,,
191 [#include <X11/Xlib.h>
192 #ifdef HAVE_X11_XUTIL_H
193 # include <X11/Xutil.h>
194 #endif])
196 dnl *** Check for X keyboard extension
197 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
198 then
199 AC_CHECK_LIB(X11, XkbQueryExtension,
200 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
201 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
202 fi
204 dnl *** Check for X Shm extension
205 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
206 then
207 AC_CHECK_LIB(Xext, XShmQueryExtension,
208 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
209 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
210 fi
212 dnl *** Check for X shape extension
213 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
214 then
215 AC_CHECK_LIB(Xext,XShapeQueryExtension,
216 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
217 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
218 fi
220 dnl *** Check for XFree86 DGA / DGA 2.0 extension
221 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
222 then
223 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
224 [ dnl *** If found...
225 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
226 [Define if you have the Xxf86dga library version 2])
227 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
228 ],
229 [ dnl *** If not found, look for XF86DGAQueryExtension()
230 dnl *** instead (DGA 2.0 not found)...
231 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
232 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
233 [Define if you have the Xxf86dga library version 1])
234 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
235 ],,
236 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
237 )
238 ],
239 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
240 fi
242 dnl *** Check for XFree86 VMODE extension
243 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
244 then
245 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
246 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
247 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
248 ],,
249 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
250 fi
252 dnl *** Check for X RandR extension
253 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
254 then
255 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
256 [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
257 X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
258 ],,
259 $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
260 fi
262 dnl *** Check for XVideo extension supporting XvImages
263 if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
264 then
265 AC_CHECK_LIB(Xv, XvShmCreateImage,
266 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
267 X_PRE_LIBS="$X_PRE_LIBS -lXv"
268 ],,
269 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
270 fi
271 ]
272 ) dnl *** End of X11/Xlib.h check
274 dnl Check for the presence of OpenGL
275 if test "x$with_opengl" != "xno"
276 then
277 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
278 then
279 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
280 This prevents linking to OpenGL. Delete the file and restart configure.])
281 fi
283 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
284 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
285 then
286 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
287 dnl Check for some problems due to old Mesa versions
288 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
289 AC_TRY_COMPILE(
290 [#include <GL/gl.h>],
291 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
292 [wine_cv_opengl_version_OK="yes"],
293 [wine_cv_opengl_version_OK="no"]
294 )
295 )
297 if test "$wine_cv_opengl_version_OK" = "yes"
298 then
299 dnl Check for the presence of the library
300 AC_CHECK_LIB(GL,glXCreateContext,
301 OPENGL_LIBS="-lGL"
302 ,,
303 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
305 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
306 then
307 OPENGLFILES='$(OPENGLFILES)'
308 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
310 AC_CHECK_LIB(GL,glXGetProcAddressARB,
311 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
312 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
313 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
315 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
316 then
317 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
318 [AC_TRY_COMPILE([#include <GL/gl.h>
319 #ifdef HAVE_GL_GLEXT_H
320 # include <GL/glext.h>
321 #endif
322 ],
323 [PFNGLCOLORTABLEEXTPROC test_proc;],
324 [wine_cv_extension_prototypes="yes"],
325 [wine_cv_extension_prototypes="no"]
326 )]
327 )
328 if test "$wine_cv_extension_prototypes" = "yes"
329 then
330 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
331 [Define if the OpenGL headers define extension typedefs])
332 fi
333 fi
335 fi
336 dnl Check for GLU32 library.
337 AC_CHECK_LIB(GLU,gluLookAt,
338 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
339 GLU32FILES='$(GLU32FILES)']
340 ,,
341 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
342 )
343 fi
345 dnl Check for glut32 library.
346 AC_CHECK_LIB(glut,glutMainLoop,
347 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
348 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
349 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
350 fi
351 fi
353 dnl **** Check for NAS ****
354 AC_SUBST(NASLIBS,"")
355 AC_CHECK_HEADERS(audio/audiolib.h,
356 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
357 AC_CHECK_LIB(audio,AuCreateFlow,
358 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
359 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
360 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
362 CPPFLAGS="$ac_save_CPPFLAGS"
363 XFILES='$(XFILES)'
364 else
365 XLIB=""
366 X_CFLAGS=""
367 X_LIBS=""
368 fi
370 dnl **** Check which curses lib to use ***
371 CURSESLIBS=""
372 if test "x$with_curses" != "xno"
373 then
374 AC_CHECK_HEADERS(ncurses.h,
375 [AC_CHECK_LIB(ncurses,waddch,
376 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
377 CURSESLIBS="-lncurses"],
378 [AC_CHECK_HEADERS(curses.h,
379 [AC_CHECK_LIB(curses,waddch,
380 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
381 CURSESLIBS="-lcurses"])])])])
382 saved_libs="$LIBS"
383 LIBS="$CURSESLIBS $LIBS"
384 AC_CHECK_FUNCS(getbkgd resizeterm)
385 LIBS="$saved_libs"
386 fi
387 AC_SUBST(CURSESLIBS)
389 dnl **** Check for SANE ****
390 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
391 if test "$sane_devel" = "no"
392 then
393 SANELIBS=""
394 SANEINCL=""
395 else
396 SANELIBS="`$sane_devel --libs`"
397 SANEINCL="`$sane_devel --cflags`"
398 ac_save_CPPFLAGS="$CPPFLAGS"
399 ac_save_LIBS="$LIBS"
400 CPPFLAGS="$CPPFLAGS $SANEINCL"
401 LIBS="$LIBS $SANELIBS"
402 AC_CHECK_HEADER(sane/sane.h,
403 [AC_CHECK_LIB(sane,sane_open,
404 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
405 [SANELIBS=""
406 SANEINCL=""])],
407 [SANELIBS=""
408 SANEINCL=""])
409 LIBS="$ac_save_LIBS"
410 CPPFLAGS="$ac_save_CPPFLAGS"
411 fi
412 AC_SUBST(SANELIBS)
413 AC_SUBST(SANEINCL)
415 dnl **** Check for the ICU library ****
416 AC_CHECK_HEADERS(unicode/ubidi.h)
417 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
418 then
419 saved_libs="$LIBS"
420 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
421 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
422 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
423 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
424 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
425 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
426 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")])
427 LIBS="$saved_libs"
428 fi
430 dnl **** Check for FreeType 2 ****
431 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
432 if test "$ft_lib" = "no"
433 then
434 FREETYPEINCL=""
435 wine_cv_msg_freetype=no
436 else
437 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
438 if test "$ft_devel" = "no"
439 then
440 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
441 if test "$ft_devel2" = "freetype2-config"
442 then
443 ft_devel=$ft_devel2
444 fi
445 fi
446 if test "$ft_devel" = "no"
447 then
448 FREETYPEINCL=""
449 wine_cv_msg_freetype=yes
450 else
451 FREETYPEINCL=`$ft_devel --cflags`
452 ac_save_CPPFLAGS="$CPPFLAGS"
453 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
454 AC_CHECK_HEADERS(ft2build.h \
455 freetype/freetype.h \
456 freetype/ftglyph.h \
457 freetype/tttables.h \
458 freetype/ftnames.h \
459 freetype/ftsnames.h \
460 freetype/ttnameid.h \
461 freetype/ftoutln.h \
462 freetype/internal/sfnt.h,,,
463 [#if HAVE_FT2BUILD_H
464 #include <ft2build.h>
465 #endif])
466 AC_TRY_CPP([#include <ft2build.h>
467 #include <freetype/fttrigon.h>],
468 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
469 [Define if you have the <freetype/fttrigon.h> header file.])
470 wine_cv_fttrigon=yes],
471 wine_cv_fttrigon=no)
472 CPPFLAGS="$ac_save_CPPFLAGS"
473 dnl Check that we have at least freetype/freetype.h
474 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
475 then
476 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
477 wine_cv_msg_freetype=no
478 else
479 FREETYPEINCL=""
480 wine_cv_msg_freetype=yes
481 fi
482 fi
483 fi
484 AC_SUBST(FREETYPEINCL)
486 dnl **** Check for parport (currently Linux only) ****
487 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
488 AC_TRY_COMPILE(
489 [#include <linux/ppdev.h>],
490 [ioctl (1,PPCLAIM,0)],
491 [ac_cv_c_ppdev="yes"],
492 [ac_cv_c_ppdev="no"])
493 )
494 if test "$ac_cv_c_ppdev" = "yes"
495 then
496 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
497 fi
499 dnl **** Check for va_copy ****
500 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
501 AC_TRY_LINK(
502 [#include <stdarg.h>],
503 [va_list ap1, ap2;
504 va_copy(ap1,ap2);
505 ],
506 [ac_cv_c_va_copy="yes"],
507 [ac_cv_c_va_copy="no"])
508 )
509 if test "$ac_cv_c_va_copy" = "yes"
510 then
511 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
512 fi
513 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
514 AC_TRY_LINK(
515 [#include <stdarg.h>],
516 [va_list ap1, ap2;
517 __va_copy(ap1,ap2);
518 ],
519 [ac_cv_c___va_copy="yes"],
520 [ac_cv_c___va_copy="no"])
521 )
522 if test "$ac_cv_c___va_copy" = "yes"
523 then
524 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
525 fi
527 dnl **** Check for sigsetjmp ****
528 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
529 AC_TRY_LINK(
530 [#include <setjmp.h>],
531 [sigjmp_buf buf;
532 sigsetjmp( buf, 1 );
533 siglongjmp( buf, 1 );],
534 [ac_cv_c_sigsetjmp="yes"],
535 [ac_cv_c_sigsetjmp="no"])
536 )
537 if test "$ac_cv_c_sigsetjmp" = "yes"
538 then
539 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
540 fi
542 dnl **** Check for pthread_rwlock_t ****
543 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
544 #include <pthread.h>])
546 dnl **** Check for pthread_getattr_np ****
547 ac_save_LIBS="$LIBS"
548 LIBS="$LIBS $LIBPTHREAD"
549 AC_CHECK_FUNCS(pthread_getattr_np)
550 LIBS="$ac_save_LIBS"
552 dnl **** Check for Open Sound System ****
553 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
555 AC_CACHE_CHECK([for Open Sound System],
556 ac_cv_c_opensoundsystem,
557 AC_TRY_COMPILE([
558 #if defined(HAVE_SYS_SOUNDCARD_H)
559 #include <sys/soundcard.h>
560 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
561 #include <machine/soundcard.h>
562 #elif defined(HAVE_SOUNDCARD_H)
563 #include <soundcard.h>
564 #endif
565 ],[
567 /* check for one of the Open Sound System specific SNDCTL_ defines */
568 #if !defined(SNDCTL_DSP_STEREO)
569 #error No open sound system
570 #endif
571 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
573 if test "$ac_cv_c_opensoundsystem" = "yes"
574 then
575 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
576 fi
578 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
579 ac_cv_c_opensoundsystem_midi,
580 AC_TRY_COMPILE([
581 #if defined(HAVE_SYS_SOUNDCARD_H)
582 #include <sys/soundcard.h>
583 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
584 #include <machine/soundcard.h>
585 #elif defined(HAVE_SOUNDCARD_H)
586 #include <soundcard.h>
587 #endif
588 ],[
590 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
591 #if !defined(SNDCTL_SEQ_SYNC)
592 #error No open sound system MIDI interface
593 #endif
594 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
596 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
597 then
598 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
599 fi
601 dnl **** Check for aRts Sound Server ****
602 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
603 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
604 then
605 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
606 ARTSC_LIBS=`$ARTSCCONFIG --libs`
607 save_CFLAGS="$CFLAGS"
608 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
609 AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
610 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
611 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
612 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
613 CFLAGS="$save_CFLAGS"
614 fi
616 dnl **** Check for ALSA ****
617 AC_SUBST(ALSALIBS,"")
618 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
619 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
620 then
621 AC_CHECK_LIB(asound,snd_pcm_open,
622 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
623 ALSALIBS="-lasound")
624 fi
626 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
628 AC_SUBST(AUDIOIOLIBS,"")
629 AC_CHECK_HEADERS(libaudioio.h,
630 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
631 [AUDIOIOLIBS="-laudioio"
632 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
634 dnl **** Check for capi4linux ****
636 AC_CHECK_HEADERS(capi20.h,[
637 AC_CHECK_HEADERS(linux/capi.h,[
638 AC_CHECK_LIB(capi20,capi20_register,[
639 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
640 AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
641 ])
642 ])
643 ])
645 dnl **** Check for broken glibc mmap64 ****
647 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
648 AC_TRY_RUN([
649 #define _FILE_OFFSET_BITS 64
650 #include <stdio.h>
651 #include <unistd.h>
652 #include <fcntl.h>
653 #include <sys/mman.h>
654 #include <errno.h>
656 int main(int argc,char **argv) {
657 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
658 if (fd == -1) exit(1);
660 unlink("conftest.map");
662 write(fd,"test",4);
664 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
665 (errno == EINVAL)
666 ) {
667 exit(1);
668 }
669 close(fd);
670 fprintf(stderr,"success!\n");
671 exit(0);
672 }
674 ],
675 ac_cv_mmap64_works="yes",
676 ac_cv_mmap64_works="no",
677 ac_cv_mmap64_works="no") )
679 if test "$ac_cv_mmap64_works" = "yes"
680 then
681 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
682 fi
684 dnl **** Check for gcc specific options ****
686 AC_SUBST(EXTRACFLAGS,"")
687 if test "x${GCC}" = "xyes"
688 then
689 EXTRACFLAGS="-Wall -pipe"
691 dnl Check for strength-reduce bug
692 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
693 AC_TRY_RUN([
694 int L[[4]] = {0,1,2,3};
695 int main(void) {
696 static int Array[[3]];
697 unsigned int B = 3;
698 int i;
699 for(i=0; i<B; i++) Array[[i]] = i - 3;
700 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
701 L[[i]] = 4;
703 exit( Array[[1]] != -2 || L[[2]] != 3);
704 }],
705 ac_cv_c_gcc_strength_bug="no",
706 ac_cv_c_gcc_strength_bug="yes",
707 ac_cv_c_gcc_strength_bug="yes") )
708 if test "$ac_cv_c_gcc_strength_bug" = "yes"
709 then
710 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
711 fi
713 dnl Check for -mpreferred-stack-boundary
714 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
715 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
716 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
717 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
718 then
719 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
720 fi
722 dnl Check for -fno-strict-aliasing
723 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
724 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
725 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
726 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
727 then
728 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
729 fi
731 dnl Check for -gstabs+ option
732 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
733 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
734 if test "$ac_cv_c_gcc_gstabs" = "yes"
735 then
736 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
737 fi
739 dnl Check for noisy string.h
740 saved_CFLAGS="$CFLAGS"
741 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
742 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
743 AC_TRY_COMPILE([#include <string.h>],[],
744 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
745 CFLAGS="$saved_CFLAGS"
746 if test "$ac_cv_c_string_h_warnings" = "no"
747 then
748 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
749 fi
750 fi
752 dnl **** Check how to define a function in assembly code ****
754 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
755 WINE_TRY_ASM_LINK(
756 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
757 ac_cv_asm_func_def=".def",
758 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
759 ac_cv_asm_func_def=".type @function",
760 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
761 ac_cv_asm_func_def=".type 2",
762 ac_cv_asm_func_def="unknown")])]))
764 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
765 case "$ac_cv_asm_func_def" in
766 ".def")
767 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
768 ".type @function")
769 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
770 ".type 2")
771 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
772 *)
773 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
774 esac
776 dnl **** Check for underscore on external symbols ****
778 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
779 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
780 [extern int ac_test;],
781 [if (ac_test) return 1],
782 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
784 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
785 if test "$ac_cv_c_extern_prefix" = "yes"
786 then
787 AC_DEFINE([__ASM_NAME(name)], ["_" name])
788 else
789 AC_DEFINE([__ASM_NAME(name)], [name])
790 fi
792 dnl **** Check how to do strings in assembler ****
794 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
795 WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
796 WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
797 WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
798 AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
800 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
801 [Define to the assembler keyword used to specify an ASCII string])
803 dnl **** Check for .short in assembler ****
805 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
806 WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
807 WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
808 AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
810 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
811 [Define to the assembler keyword used to specify a word value])
813 dnl **** Check for working dll ****
815 AC_SUBST(DLLEXT,"")
816 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
817 AC_SUBST(DLLIBS,"")
818 AC_SUBST(LDSHARED,"")
819 AC_SUBST(LDDLL,"")
820 AC_SUBST(LIBEXT,"so")
821 AC_SUBST(IMPLIBEXT,"def")
823 case $host_os in
824 cygwin*|mingw32*)
825 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
826 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
827 if test "$DLLWRAP" = "false"; then
828 LIBEXT="a"
829 else
830 dnl FIXME - check whether dllwrap works correctly...
831 LIBEXT="dll"
832 fi
833 IMPLIBEXT="a"
834 ;;
835 *)
836 AC_CHECK_HEADERS(dlfcn.h,
837 [AC_CHECK_FUNCS(dlopen,,
838 [AC_CHECK_LIB(dl,dlopen,
839 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
840 DLLIBS="-ldl"],
841 [LIBEXT="a"])])],
842 [LIBEXT="a"])
844 if test "$LIBEXT" = "so"
845 then
846 DLLFLAGS="$DLLFLAGS -fPIC"
847 DLLEXT=".so"
848 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
849 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
850 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
851 if test "$ac_cv_c_dll_gnuelf" = "yes"
852 then
853 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
854 LDDLL="\$(CC) -shared -Wl,-Bsymbolic"
855 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
856 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
857 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
858 if test "$ac_cv_c_dll_zdefs" = "yes"
859 then
860 LDDLL="$LDDLL,-z,defs"
861 fi
863 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
864 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
865 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
866 if test "$ac_cv_c_dll_init_fini" = "yes"
867 then
868 AC_DEFINE(HAVE_LINKER_INIT_FINI,1,[Define if the linker supports renaming the init and fini functions])
869 LDDLL="$LDDLL,-init,__wine_spec_init,-fini,__wine_spec_fini"
870 fi
872 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
873 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
874 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
875 if test "$ac_cv_c_export_dynamic" = "yes"
876 then
877 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
878 fi
880 case $host_cpu in
881 *i[[3456789]]86*)
882 AC_CACHE_CHECK([whether we can relocate the executable to 0x00110000], ac_cv_ld_reloc_exec,
883 [saved_CFLAGS="$CFLAGS"
884 CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x00110400"
885 AC_TRY_RUN([#include <unistd.h>
886 int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
887 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no", ac_cv_ld_reloc_exec="no")
888 CFLAGS="$saved_CFLAGS"])
889 if test "$ac_cv_ld_reloc_exec" = "yes"
890 then
891 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x00110400"
892 fi
893 ;;
894 esac
896 else
897 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
898 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
899 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
900 if test "$ac_cv_c_dll_unixware" = "yes"
901 then
902 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
903 LDDLL="\$(CC) -Wl,-G,-B,symbolic"
905 else
906 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
907 [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
908 if test "$ac_cv_c_dll_macho" = "yes"
909 then
910 LIBEXT="dylib"
911 LDDLL="\$(CC) -bundle -flat_namespace -undefined suppress"
912 LDSHARED="\$(CC) -dynamiclib"
913 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
914 fi
915 fi
916 fi
917 fi
919 dnl Check for cross compiler to build test programs
920 AC_SUBST(CROSSTEST,"")
921 if test "$cross_compiling" = "no"
922 then
923 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
924 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
925 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
926 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
927 fi
928 ;;
929 esac
931 if test "$LIBEXT" = "a"; then
932 AC_MSG_ERROR(
933 [could not find a way to build shared libraries.
934 It is currently not possible to build Wine without shared library
935 (.so) support to allow transparent switch between .so and .dll files.
936 If you are using Linux, you will need a newer binutils.]
937 )
938 fi
940 case $build_os in
941 cygwin*|mingw32*)
942 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
943 darwin*|macosx*)
944 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
945 *)
946 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
947 esac
949 dnl Mingw needs explicit msvcrt for linking libwine
950 case $host_os in
951 mingw32*)
952 AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
953 esac
955 case $host_os in
956 linux*)
957 AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
958 AC_SUBST(MAIN_BINARY,"wine-glibc")
959 ;;
960 *)
961 AC_SUBST(WINE_BINARIES,"wine-kthread")
962 AC_SUBST(MAIN_BINARY,"wine-kthread")
963 ;;
964 esac
966 dnl **** Get the soname for libraries that we load dynamically ****
968 if test "$LIBEXT" = "so"
969 then
970 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
971 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
972 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
973 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
974 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
975 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
976 WINE_GET_SONAME(cups,cupsGetDefault)
977 WINE_GET_SONAME(jack,jack_client_new)
978 WINE_GET_SONAME(fontconfig,FcInit)
979 WINE_GET_SONAME(ssl,SSL_library_init)
980 WINE_GET_SONAME(crypto,BIO_new_socket)
981 WINE_GET_SONAME(ncurses,waddch)
982 WINE_GET_SONAME(curses,waddch)
983 fi
986 dnl **** Check for functions ****
988 AC_FUNC_ALLOCA()
989 AC_CHECK_FUNCS(\
990 _lwp_create \
991 _lwp_self \
992 _pclose \
993 _popen \
994 _snprintf \
995 _spawnvp \
996 _stricmp \
997 _strnicmp \
998 _vsnprintf \
999 chsize \
1000 clone \
1001 finite \
1002 fpclass \
1003 ftruncate \
1004 ftruncate64 \
1005 getnetbyaddr \
1006 getnetbyname \
1007 getopt_long \
1008 getpagesize \
1009 getprotobyname \
1010 getprotobynumber \
1011 getpwuid \
1012 getservbyport \
1013 gettid \
1014 gettimeofday \
1015 inet_network \
1016 lseek64 \
1017 lstat \
1018 memmove \
1019 mmap \
1020 pclose \
1021 popen \
1022 pread \
1023 pwrite \
1024 readlink \
1025 rfork \
1026 select \
1027 sendmsg \
1028 settimeofday \
1029 sigaltstack \
1030 snprintf \
1031 spawnvp \
1032 statfs \
1033 strcasecmp \
1034 strerror \
1035 strncasecmp \
1036 tcgetattr \
1037 timegm \
1038 usleep \
1039 vfscanf \
1040 vsnprintf \
1041 wait4 \
1042 waitpid \
1043 )
1045 dnl **** Check for header files ****
1047 AC_CHECK_HEADERS(\
1048 arpa/inet.h \
1049 arpa/nameser.h \
1050 cups/cups.h \
1051 direct.h \
1052 elf.h \
1053 float.h \
1054 fontconfig/fontconfig.h \
1055 getopt.h \
1056 ieeefp.h \
1057 io.h \
1058 jack/jack.h \
1059 libio.h \
1060 libutil.h \
1061 link.h \
1062 linux/cdrom.h \
1063 linux/hdreg.h \
1064 linux/input.h \
1065 linux/joystick.h \
1066 linux/major.h \
1067 linux/param.h \
1068 linux/serial.h \
1069 linux/ucdrom.h \
1070 machine/cpu.h \
1071 netdb.h \
1072 netinet/in.h \
1073 netinet/in_systm.h \
1074 netinet/tcp.h \
1075 netinet/tcp_fsm.h \
1076 openssl/ssl.h \
1077 process.h \
1078 pthread.h \
1079 pty.h \
1080 pwd.h \
1081 regex.h \
1082 sched.h \
1083 scsi/sg.h \
1084 scsi/scsi.h \
1085 scsi/scsi_ioctl.h \
1086 socket.h \
1087 stdint.h \
1088 strings.h \
1089 sys/cdio.h \
1090 sys/elf32.h \
1091 sys/errno.h \
1092 sys/exec_elf.h \
1093 sys/file.h \
1094 sys/filio.h \
1095 sys/inttypes.h \
1096 sys/ioctl.h \
1097 sys/ipc.h \
1098 sys/link.h \
1099 sys/lwp.h \
1100 sys/mman.h \
1101 sys/modem.h \
1102 sys/msg.h \
1103 sys/param.h \
1104 sys/poll.h \
1105 sys/ptrace.h \
1106 sys/reg.h \
1107 sys/scsiio.h \
1108 sys/shm.h \
1109 sys/signal.h \
1110 sys/socket.h \
1111 sys/sockio.h \
1112 sys/statfs.h \
1113 sys/strtio.h \
1114 sys/syscall.h \
1115 sys/sysctl.h \
1116 sys/time.h \
1117 sys/times.h \
1118 sys/uio.h \
1119 sys/un.h \
1120 sys/v86.h \
1121 sys/v86intr.h \
1122 sys/vfs.h \
1123 sys/vm86.h \
1124 sys/wait.h \
1125 syscall.h \
1126 termios.h \
1127 unistd.h \
1128 utime.h \
1129 valgrind/memcheck.h
1130 )
1131 AC_HEADER_STAT()
1133 dnl **** Checks for headers that depend on other ones ****
1135 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1136 [#include <sys/types.h>
1137 #if HAVE_SYS_PARAM_H
1138 # include <sys/param.h>
1139 #endif])
1141 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1142 [#include <sys/types.h>
1143 #if HAVE_SYS_SOCKET_H
1144 # include <sys/socket.h>
1145 #endif])
1147 AC_CHECK_HEADERS([resolv.h],,,
1148 [#include <sys/types.h>
1149 #if HAVE_SYS_SOCKET_H
1150 # include <sys/socket.h>
1151 #endif
1152 #if HAVE_NETINET_IN_H
1153 # include <netinet/in.h>
1154 #endif
1155 #if HAVE_ARPA_NAMESER_H
1156 # include <arpa/nameser.h>
1157 #endif])
1159 AC_CHECK_HEADERS(netinet/ip.h,,,
1160 [#include <sys/types.h>
1161 #if HAVE_SYS_SOCKET_H
1162 # include <sys/socket.h>
1163 #endif
1164 #if HAVE_NETINET_IN_SYSTM_H
1165 # include <netinet/in_systm.h>
1166 #endif])
1168 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1170 dnl **** Check for IPX headers (currently Linux only) ****
1172 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1173 AC_TRY_COMPILE(
1174 [#include <sys/types.h>
1175 #ifdef HAVE_SYS_SOCKET_H
1176 # include <sys/socket.h>
1177 #endif
1178 #include <netipx/ipx.h>],
1179 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1180 [ac_cv_c_ipx_gnu="yes"],
1181 [ac_cv_c_ipx_gnu="no"])
1182 )
1183 if test "$ac_cv_c_ipx_gnu" = "yes"
1184 then
1185 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1186 fi
1188 if test "$ac_cv_c_ipx_gnu" = "no"
1189 then
1190 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1191 AC_TRY_COMPILE(
1192 [#include <sys/types.h>
1193 #ifdef HAVE_SYS_SOCKET_H
1194 # include <sys/socket.h>
1195 #endif
1196 #include <asm/types.h>
1197 #include <linux/ipx.h>],
1198 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1199 [ac_cv_c_ipx_linux="yes"],
1200 [ac_cv_c_ipx_linux="no"])
1201 )
1202 if test "$ac_cv_c_ipx_linux" = "yes"
1203 then
1204 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1205 fi
1206 fi
1208 dnl **** Check for types ****
1210 AC_C_CONST
1211 AC_C_INLINE
1212 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1213 AC_CHECK_SIZEOF(long long,0)
1215 AC_CACHE_CHECK([whether linux/input.h is for real],
1216 wine_cv_linux_input_h,
1217 AC_TRY_COMPILE([
1218 #include <linux/input.h>
1219 ] , [
1220 int foo = EVIOCGBIT(EV_ABS,42);
1221 int bar = BTN_PINKIE;
1222 int fortytwo = 42;
1223 ],
1224 wine_cv_linux_input_h=yes,
1225 wine_cv_linux_input_h=no,
1226 no
1227 )
1228 )
1229 if test "$wine_cv_linux_input_h" = "yes"
1230 then
1231 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1232 [Define if we have linux/input.h AND it contains the INPUT event API])
1233 fi
1236 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1237 wine_cv_linux_gethostbyname_r_6,
1238 AC_TRY_LINK([
1239 #include <netdb.h>
1240 ], [
1241 char *name=NULL;
1242 struct hostent he;
1243 struct hostent *result;
1244 char *buf=NULL;
1245 int bufsize=0;
1246 int res,errnr;
1247 char *addr=NULL;
1248 int addrlen=0;
1249 int addrtype=0;
1250 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1251 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1252 ],
1253 wine_cv_linux_gethostbyname_r_6=yes,
1254 wine_cv_linux_gethostbyname_r_6=no
1255 )
1256 )
1257 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1258 then
1259 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1260 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1261 fi
1263 if test "$ac_cv_header_linux_joystick_h" = "yes"
1264 then
1265 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1266 wine_cv_linux_joystick_22_api,
1267 AC_TRY_COMPILE([
1268 #include <sys/ioctl.h>
1269 #include <linux/joystick.h>
1271 struct js_event blub;
1272 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1273 #error "no 2.2 header"
1274 #endif
1275 ],/*empty*/,
1276 wine_cv_linux_joystick_22_api=yes,
1277 wine_cv_linux_joystick_22_api=no,
1278 wine_cv_linux_joystick_22_api=no
1279 )
1280 )
1281 if test "$wine_cv_linux_joystick_22_api" = "yes"
1282 then
1283 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1284 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1285 fi
1286 fi
1288 dnl **** statfs checks ****
1290 if test "$ac_cv_header_sys_vfs_h" = "yes"
1291 then
1292 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1293 wine_cv_sys_vfs_has_statfs,
1294 AC_TRY_COMPILE([
1295 #include <sys/types.h>
1296 #ifdef HAVE_SYS_PARAM_H
1297 # include <sys/param.h>
1298 #endif
1299 #include <sys/vfs.h>
1300 ],[
1301 struct statfs stfs;
1303 memset(&stfs,0,sizeof(stfs));
1304 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1305 )
1306 )
1307 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1308 then
1309 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1310 [Define if the struct statfs is defined by <sys/vfs.h>])
1311 fi
1312 fi
1314 if test "$ac_cv_header_sys_statfs_h" = "yes"
1315 then
1316 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1317 wine_cv_sys_statfs_has_statfs,
1318 AC_TRY_COMPILE([
1319 #include <sys/types.h>
1320 #ifdef HAVE_SYS_PARAM_H
1321 # include <sys/param.h>
1322 #endif
1323 #include <sys/statfs.h>
1324 ],[
1325 struct statfs stfs;
1326 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1327 )
1328 )
1329 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1330 then
1331 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1332 [Define if the struct statfs is defined by <sys/statfs.h>])
1333 fi
1334 fi
1336 if test "$ac_cv_header_sys_mount_h" = "yes"
1337 then
1338 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1339 wine_cv_sys_mount_has_statfs,
1340 AC_TRY_COMPILE([
1341 #include <sys/types.h>
1342 #ifdef HAVE_SYS_PARAM_H
1343 # include <sys/param.h>
1344 #endif
1345 #include <sys/mount.h>
1346 ],[
1347 struct statfs stfs;
1348 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1349 )
1350 )
1351 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1352 then
1353 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1354 [Define if the struct statfs is defined by <sys/mount.h>])
1355 fi
1356 fi
1358 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1360 dnl Check for statfs members
1361 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail],,,
1362 [#include <sys/types.h>
1363 #ifdef HAVE_SYS_PARAM_H
1364 # include <sys/param.h>
1365 #endif
1366 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1367 # include <sys/mount.h>
1368 #else
1369 # ifdef STATFS_DEFINED_BY_SYS_VFS
1370 # include <sys/vfs.h>
1371 # else
1372 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1373 # include <sys/statfs.h>
1374 # endif
1375 # endif
1376 #endif])
1378 dnl Check for socket structure members
1379 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1380 [#include <sys/types.h>
1381 #ifdef HAVE_SYS_SOCKET_H
1382 # include <sys/socket.h>
1383 #endif
1384 #ifdef HAVE_SYS_UN_H
1385 # include <sys/un.h>
1386 #endif])
1388 dnl Check for siginfo_t members
1389 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1391 dnl Check for struct option
1392 AC_CHECK_MEMBERS([struct option.name],,,
1393 [#ifdef HAVE_GETOPT_H
1394 #include <getopt.h>
1395 #endif])
1397 dnl Check for stat.st_blocks
1398 AC_CHECK_MEMBERS([struct stat.st_blocks])
1400 dnl *** check for the need to define platform-specific symbols
1402 case $host_cpu in
1403 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1404 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1405 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1406 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1407 esac
1409 case $host_vendor in
1410 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1411 esac
1413 dnl **** Generate output files ****
1415 AH_TOP([#define __WINE_CONFIG_H])
1417 WINE_CONFIG_EXTRA_DIR(controls)
1418 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1419 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1420 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1421 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1422 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1423 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1424 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1425 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1426 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1427 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1428 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1429 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1430 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1431 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1432 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1433 WINE_CONFIG_EXTRA_DIR(files)
1434 WINE_CONFIG_EXTRA_DIR(graphics)
1435 WINE_CONFIG_EXTRA_DIR(include/wine)
1436 WINE_CONFIG_EXTRA_DIR(misc)
1437 WINE_CONFIG_EXTRA_DIR(objects)
1438 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1439 WINE_CONFIG_EXTRA_DIR(windows)
1441 MAKE_RULES=Make.rules
1442 AC_SUBST_FILE(MAKE_RULES)
1444 MAKE_DLL_RULES=dlls/Makedll.rules
1445 AC_SUBST_FILE(MAKE_DLL_RULES)
1447 MAKE_TEST_RULES=dlls/Maketest.rules
1448 AC_SUBST_FILE(MAKE_TEST_RULES)
1450 MAKE_LIB_RULES=libs/Makelib.rules
1451 AC_SUBST_FILE(MAKE_LIB_RULES)
1453 MAKE_PROG_RULES=programs/Makeprog.rules
1454 AC_SUBST_FILE(MAKE_PROG_RULES)
1456 AC_CONFIG_FILES([
1457 Make.rules
1458 dlls/Makedll.rules
1459 dlls/Maketest.rules
1460 libs/Makelib.rules
1461 programs/Makeprog.rules
1462 Makefile
1463 dlls/Makefile
1464 dlls/advapi32/Makefile
1465 dlls/advapi32/tests/Makefile
1466 dlls/avicap32/Makefile
1467 dlls/avifil32/Makefile
1468 dlls/cabinet/Makefile
1469 dlls/capi2032/Makefile
1470 dlls/cfgmgr32/Makefile
1471 dlls/comcat/Makefile
1472 dlls/comctl32/Makefile
1473 dlls/comctl32/tests/Makefile
1474 dlls/commdlg/Makefile
1475 dlls/crtdll/Makefile
1476 dlls/crypt32/Makefile
1477 dlls/ctl3d/Makefile
1478 dlls/d3d8/Makefile
1479 dlls/d3d9/Makefile
1480 dlls/d3dim/Makefile
1481 dlls/d3dx8/Makefile
1482 dlls/dciman32/Makefile
1483 dlls/ddraw/Makefile
1484 dlls/ddraw/tests/Makefile
1485 dlls/devenum/Makefile
1486 dlls/dinput/Makefile
1487 dlls/dinput8/Makefile
1488 dlls/dmband/Makefile
1489 dlls/dmcompos/Makefile
1490 dlls/dmime/Makefile
1491 dlls/dmloader/Makefile
1492 dlls/dmscript/Makefile
1493 dlls/dmstyle/Makefile
1494 dlls/dmsynth/Makefile
1495 dlls/dmusic/Makefile
1496 dlls/dmusic32/Makefile
1497 dlls/dplay/Makefile
1498 dlls/dplayx/Makefile
1499 dlls/dpnhpast/Makefile
1500 dlls/dsound/Makefile
1501 dlls/dsound/tests/Makefile
1502 dlls/dswave/Makefile
1503 dlls/dxguid/Makefile
1504 dlls/gdi/Makefile
1505 dlls/gdi/tests/Makefile
1506 dlls/glu32/Makefile
1507 dlls/glut32/Makefile
1508 dlls/iccvid/Makefile
1509 dlls/icmp/Makefile
1510 dlls/imagehlp/Makefile
1511 dlls/imm32/Makefile
1512 dlls/iphlpapi/Makefile
1513 dlls/iphlpapi/tests/Makefile
1514 dlls/kernel/Makefile
1515 dlls/kernel/tests/Makefile
1516 dlls/lzexpand/Makefile
1517 dlls/mapi32/Makefile
1518 dlls/mpr/Makefile
1519 dlls/msacm/Makefile
1520 dlls/msacm/imaadp32/Makefile
1521 dlls/msacm/msadp32/Makefile
1522 dlls/msacm/msg711/Makefile
1523 dlls/msacm/winemp3/Makefile
1524 dlls/msdmo/Makefile
1525 dlls/mshtml/Makefile
1526 dlls/msi/Makefile
1527 dlls/msimg32/Makefile
1528 dlls/msisys/Makefile
1529 dlls/msnet32/Makefile
1530 dlls/msvcrt/Makefile
1531 dlls/msvcrt/tests/Makefile
1532 dlls/msvcrt20/Makefile
1533 dlls/msvcrt40/Makefile
1534 dlls/msvcrtd/Makefile
1535 dlls/msvidc32/Makefile
1536 dlls/msvideo/Makefile
1537 dlls/msvideo/msrle32/Makefile
1538 dlls/mswsock/Makefile
1539 dlls/netapi32/Makefile
1540 dlls/netapi32/tests/Makefile
1541 dlls/newdev/Makefile
1542 dlls/ntdll/Makefile
1543 dlls/ntdll/tests/Makefile
1544 dlls/odbc32/Makefile
1545 dlls/ole32/Makefile
1546 dlls/oleacc/Makefile
1547 dlls/oleaut32/Makefile
1548 dlls/oleaut32/tests/Makefile
1549 dlls/olecli/Makefile
1550 dlls/oledlg/Makefile
1551 dlls/olepro32/Makefile
1552 dlls/olesvr/Makefile
1553 dlls/opengl32/Makefile
1554 dlls/psapi/Makefile
1555 dlls/qcap/Makefile
1556 dlls/quartz/Makefile
1557 dlls/rasapi32/Makefile
1558 dlls/richedit/Makefile
1559 dlls/rpcrt4/Makefile
1560 dlls/rpcrt4/tests/Makefile
1561 dlls/serialui/Makefile
1562 dlls/setupapi/Makefile
1563 dlls/shdocvw/Makefile
1564 dlls/shell32/Makefile
1565 dlls/shell32/tests/Makefile
1566 dlls/shfolder/Makefile
1567 dlls/shlwapi/Makefile
1568 dlls/shlwapi/tests/Makefile
1569 dlls/snmpapi/Makefile
1570 dlls/sti/Makefile
1571 dlls/tapi32/Makefile
1572 dlls/ttydrv/Makefile
1573 dlls/twain/Makefile
1574 dlls/unicows/Makefile
1575 dlls/url/Makefile
1576 dlls/urlmon/Makefile
1577 dlls/urlmon/tests/Makefile
1578 dlls/user/Makefile
1579 dlls/user/tests/Makefile
1580 dlls/uuid/Makefile
1581 dlls/uxtheme/Makefile
1582 dlls/version/Makefile
1583 dlls/win32s/Makefile
1584 dlls/winaspi/Makefile
1585 dlls/wined3d/Makefile
1586 dlls/winedos/Makefile
1587 dlls/wineps/Makefile
1588 dlls/wininet/Makefile
1589 dlls/wininet/tests/Makefile
1590 dlls/winmm/Makefile
1591 dlls/winmm/joystick/Makefile
1592 dlls/winmm/mcianim/Makefile
1593 dlls/winmm/mciavi/Makefile
1594 dlls/winmm/mcicda/Makefile
1595 dlls/winmm/mciseq/Makefile
1596 dlls/winmm/mciwave/Makefile
1597 dlls/winmm/midimap/Makefile
1598 dlls/winmm/tests/Makefile
1599 dlls/winmm/wavemap/Makefile
1600 dlls/winmm/winealsa/Makefile
1601 dlls/winmm/winearts/Makefile
1602 dlls/winmm/wineaudioio/Makefile
1603 dlls/winmm/winejack/Makefile
1604 dlls/winmm/winenas/Makefile
1605 dlls/winmm/wineoss/Makefile
1606 dlls/winnls/Makefile
1607 dlls/winsock/Makefile
1608 dlls/winsock/tests/Makefile
1609 dlls/winspool/Makefile
1610 dlls/winspool/tests/Makefile
1611 dlls/wintab32/Makefile
1612 dlls/wintrust/Makefile
1613 dlls/wow32/Makefile
1614 dlls/wsock32/Makefile
1615 dlls/x11drv/Makefile
1616 documentation/Makefile
1617 include/Makefile
1618 libs/Makefile
1619 libs/port/Makefile
1620 libs/unicode/Makefile
1621 libs/wine/Makefile
1622 libs/wpp/Makefile
1623 loader/Makefile
1624 programs/Makefile
1625 programs/avitools/Makefile
1626 programs/clock/Makefile
1627 programs/cmdlgtst/Makefile
1628 programs/control/Makefile
1629 programs/expand/Makefile
1630 programs/notepad/Makefile
1631 programs/progman/Makefile
1632 programs/regedit/Makefile
1633 programs/regsvr32/Makefile
1634 programs/rpcss/Makefile
1635 programs/rundll32/Makefile
1636 programs/start/Makefile
1637 programs/uninstaller/Makefile
1638 programs/view/Makefile
1639 programs/wcmd/Makefile
1640 programs/wineboot/Makefile
1641 programs/winebrowser/Makefile
1642 programs/winecfg/Makefile
1643 programs/wineconsole/Makefile
1644 programs/winedbg/Makefile
1645 programs/winefile/Makefile
1646 programs/winemenubuilder/Makefile
1647 programs/winemine/Makefile
1648 programs/winepath/Makefile
1649 programs/winetest/Makefile
1650 programs/winevdm/Makefile
1651 programs/winhelp/Makefile
1652 programs/winver/Makefile
1653 server/Makefile
1654 tools/Makefile
1655 tools/widl/Makefile
1656 tools/winapi/Makefile
1657 tools/winebuild/Makefile
1658 tools/winedump/Makefile
1659 tools/winegcc/Makefile
1660 tools/wmc/Makefile
1661 tools/wrc/Makefile])
1663 AC_OUTPUT
1665 if test "$have_x" = "no"
1666 then
1667 echo
1668 echo "*** Warning: X development files not found. Wine will be built without"
1669 echo "*** X support, which currently does not work, and would probably not be"
1670 echo "*** what you want anyway. You will need to install devel packages of"
1671 echo "*** Xlib/Xfree86 at the very least."
1672 fi
1674 if test "$wine_cv_opengl_version_OK" = "no"
1675 then
1676 echo
1677 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1678 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1679 fi
1681 if test "$wine_cv_msg_freetype" = "yes"
1682 then
1683 echo
1684 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1685 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1686 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1687 echo "*** enable Wine to use TrueType fonts."
1688 fi
1690 echo
1691 echo "Configure finished. Do 'make depend && make' to compile Wine."
1692 echo
1694 dnl Local Variables:
1695 dnl comment-start: "dnl "
1696 dnl comment-end: ""
1697 dnl comment-start-skip: "\\bdnl\\b\\s *"
1698 dnl compile-command: "autoconf"
1699 dnl End: