| blob | b3475df89eead5353323536adcbd0c67e4cd7905 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION)
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
25 if test "x$enable_win16" = "xno"
26 then
27 WIN16_FILES=""
28 WIN16_INSTALL=""
29 fi
30 if test "x$enable_debug" = "xno"
31 then
32 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
33 fi
34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
35 then
36 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
37 fi
39 dnl **** Check for some programs ****
41 AC_CANONICAL_HOST
42 AC_PROG_MAKE_SET
43 AC_PROG_CC
44 AC_PROG_CPP
46 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
47 [if test -z "$with_wine_tools"; then
48 if test "$cross_compiling" = "yes"; then
49 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
50 else
51 wine_cv_toolsdir="\$(TOPOBJDIR)"
52 fi
53 elif test -d "$with_wine_tools/tools/winebuild"; then
54 case $with_wine_tools in
55 /*) wine_cv_toolsdir="$with_wine_tools" ;;
56 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
57 esac
58 else
59 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
60 fi])
61 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
63 AC_PATH_XTRA
64 AC_PROG_YACC
65 AC_PROG_LEX
67 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
68 dnl **** without one present.
69 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
70 if test "$XYACC" = "none"
71 then
72 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
73 fi
74 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
75 if test "$XLEX" = "none"
76 then
77 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
78 fi
80 AC_CHECK_TOOLS(AS,[gas as],as)
81 AC_CHECK_TOOL(LD,ld,ld)
82 AC_CHECK_TOOL(AR,ar,ar)
83 AC_PROG_RANLIB
84 AC_CHECK_TOOL(STRIP,strip,strip)
85 AC_CHECK_TOOL(WINDRES,windres,false)
86 AC_PROG_LN_S
87 WINE_PROG_LN
88 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
89 AC_PROG_INSTALL
90 dnl Prepend src dir to install path dir if it's a relative path
91 case "$INSTALL" in
92 [[\\/$]]* | ?:[[\\/]]* ) ;;
93 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
94 esac
96 dnl Check for lint
97 AC_CHECK_PROGS(LINT, lclint lint)
98 if test "$LINT" = "lint"
99 then
100 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
101 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
102 fi
103 AC_SUBST(LINT)
104 AC_SUBST(LINTFLAGS)
106 dnl Check for db2html
107 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
108 AC_SUBST(DB2HTML)
110 dnl Check for db2pdf
111 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
112 AC_SUBST(DB2PDF)
114 dnl Check for db2ps
115 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
116 AC_SUBST(DB2PS)
118 dnl Check for db2txt
119 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
120 AC_SUBST(DB2TXT)
122 dnl **** Check for some libraries ****
124 dnl Check for -lm
125 AC_CHECK_LIB(m,sqrt)
126 dnl Check for -li386 for NetBSD and OpenBSD
127 AC_CHECK_LIB(i386,i386_set_ldt)
128 dnl Check for -lossaudio for NetBSD
129 AC_CHECK_LIB(ossaudio,_oss_ioctl)
130 dnl Check for -lw for Solaris
131 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
132 dnl Check for -lnsl for Solaris
133 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
134 dnl Check for -lsocket for Solaris
135 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
136 dnl Check for -lresolv for Solaris
137 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
138 dnl Check for -lxpg4 for FreeBSD
139 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
140 dnl Check for -lpoll for Mac OS X/Darwin
141 AC_CHECK_LIB(poll,poll)
142 dnl Check for -lpthread
143 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
145 JPEGLIB=""
146 AC_SUBST(JPEGLIB)
147 AC_CHECK_HEADERS(jpeglib.h,
148 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
149 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
150 JPEGLIB="-ljpeg"
151 )
152 )
154 AC_SUBST(GIFLIB,"")
155 AC_CHECK_HEADERS(gif_lib.h,
156 AC_CHECK_LIB(ungif,DGifOpen,
157 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
158 GIFLIB="-lungif"],
159 [AC_CHECK_LIB(gif,DGifOpen,
160 [AC_DEFINE(HAVE_LIBGIF,1)
161 GIFLIB="-lgif"])]))
163 AC_SUBST(XLIB)
164 AC_SUBST(XFILES)
165 XFILES=""
166 AC_SUBST(OPENGLFILES)
167 OPENGLFILES=""
168 AC_SUBST(GLU32FILES)
169 GLU32FILES=""
170 AC_SUBST(OPENGL_LIBS)
171 OPENGL_LIBS=""
172 if test "$have_x" = "yes"
173 then
174 XLIB="-lXext -lX11"
175 ac_save_CPPFLAGS="$CPPFLAGS"
176 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
178 dnl *** All of the following tests require X11/Xlib.h
179 AC_CHECK_HEADERS(X11/Xlib.h,
180 [
181 AC_CHECK_HEADERS([X11/XKBlib.h \
182 X11/Xutil.h \
183 X11/extensions/shape.h \
184 X11/extensions/XShm.h \
185 X11/extensions/Xrandr.h \
186 X11/extensions/Xrender.h \
187 X11/extensions/Xvlib.h \
188 X11/extensions/xf86dga.h \
189 X11/extensions/xf86vmode.h],,,
190 [#include <X11/Xlib.h>
191 #ifdef HAVE_X11_XUTIL_H
192 # include <X11/Xutil.h>
193 #endif])
195 dnl *** Check for X keyboard extension
196 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
197 then
198 AC_CHECK_LIB(X11, XkbQueryExtension,
199 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
200 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
201 fi
203 dnl *** Check for X Shm extension
204 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
205 then
206 AC_CHECK_LIB(Xext, XShmQueryExtension,
207 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
208 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
209 fi
211 dnl *** Check for X shape extension
212 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
213 then
214 AC_CHECK_LIB(Xext,XShapeQueryExtension,
215 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
216 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
217 fi
219 dnl *** Check for XFree86 DGA / DGA 2.0 extension
220 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
221 then
222 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
223 [ dnl *** If found...
224 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
225 [Define if you have the Xxf86dga library version 2])
226 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
227 ],
228 [ dnl *** If not found, look for XF86DGAQueryExtension()
229 dnl *** instead (DGA 2.0 not found)...
230 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
231 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
232 [Define if you have the Xxf86dga library version 1])
233 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
234 ],,
235 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
236 )
237 ],
238 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
239 fi
241 dnl *** Check for XFree86 VMODE extension
242 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
243 then
244 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
245 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
246 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
247 ],,
248 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
249 fi
251 dnl *** Check for X RandR extension
252 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
253 then
254 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
255 [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
256 X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
257 ],,
258 $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
259 fi
261 dnl *** Check for XVideo extension supporting XvImages
262 if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
263 then
264 AC_CHECK_LIB(Xv, XvShmCreateImage,
265 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
266 X_PRE_LIBS="$X_PRE_LIBS -lXv"
267 ],,
268 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
269 fi
270 ]
271 ) dnl *** End of X11/Xlib.h check
273 dnl Check for the presence of OpenGL
274 if test "x$with_opengl" != "xno"
275 then
276 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
277 then
278 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
279 This prevents linking to OpenGL. Delete the file and restart configure.])
280 fi
282 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
283 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
284 then
285 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
286 dnl Check for some problems due to old Mesa versions
287 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
288 AC_TRY_COMPILE(
289 [#include <GL/gl.h>],
290 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
291 [wine_cv_opengl_version_OK="yes"],
292 [wine_cv_opengl_version_OK="no"]
293 )
294 )
296 if test "$wine_cv_opengl_version_OK" = "yes"
297 then
298 dnl Check for the presence of the library
299 AC_CHECK_LIB(GL,glXCreateContext,
300 OPENGL_LIBS="-lGL"
301 ,,
302 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
304 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
305 then
306 OPENGLFILES='$(OPENGLFILES)'
307 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
309 AC_CHECK_LIB(GL,glXGetProcAddressARB,
310 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
311 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
312 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
314 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
315 then
316 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
317 [AC_TRY_COMPILE([#include <GL/gl.h>
318 #ifdef HAVE_GL_GLEXT_H
319 # include <GL/glext.h>
320 #endif
321 ],
322 [PFNGLCOLORTABLEEXTPROC test_proc;],
323 [wine_cv_extension_prototypes="yes"],
324 [wine_cv_extension_prototypes="no"]
325 )]
326 )
327 if test "$wine_cv_extension_prototypes" = "yes"
328 then
329 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
330 [Define if the OpenGL headers define extension typedefs])
331 fi
332 fi
334 fi
335 dnl Check for GLU32 library.
336 AC_CHECK_LIB(GLU,gluLookAt,
337 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
338 GLU32FILES='$(GLU32FILES)']
339 ,,
340 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
341 )
342 fi
343 fi
344 fi
346 dnl **** Check for NAS ****
347 AC_SUBST(NASLIBS,"")
348 AC_CHECK_HEADERS(audio/audiolib.h,
349 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
350 AC_CHECK_LIB(audio,AuCreateFlow,
351 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
352 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
353 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
355 CPPFLAGS="$ac_save_CPPFLAGS"
356 XFILES='$(XFILES)'
357 else
358 XLIB=""
359 X_CFLAGS=""
360 X_LIBS=""
361 fi
363 dnl **** Check which curses lib to use ***
364 CURSESLIBS=""
365 if test "x$with_curses" != "xno"
366 then
367 AC_CHECK_HEADERS(ncurses.h,
368 [AC_CHECK_LIB(ncurses,waddch,
369 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
370 CURSESLIBS="-lncurses"],
371 [AC_CHECK_HEADERS(curses.h,
372 [AC_CHECK_LIB(curses,waddch,
373 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
374 CURSESLIBS="-lcurses"])])])])
375 saved_libs="$LIBS"
376 LIBS="$CURSESLIBS $LIBS"
377 AC_CHECK_FUNCS(getbkgd resizeterm)
378 LIBS="$saved_libs"
379 fi
380 AC_SUBST(CURSESLIBS)
382 dnl **** Check for SANE ****
383 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
384 if test "$sane_devel" = "no"
385 then
386 SANELIBS=""
387 SANEINCL=""
388 else
389 SANELIBS="`$sane_devel --libs`"
390 SANEINCL="`$sane_devel --cflags`"
391 ac_save_CPPFLAGS="$CPPFLAGS"
392 ac_save_LIBS="$LIBS"
393 CPPFLAGS="$CPPFLAGS $SANEINCL"
394 LIBS="$LIBS $SANELIBS"
395 AC_CHECK_HEADER(sane/sane.h,
396 [AC_CHECK_LIB(sane,sane_open,
397 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
398 [SANELIBS=""
399 SANEINCL=""])],
400 [SANELIBS=""
401 SANEINCL=""])
402 LIBS="$ac_save_LIBS"
403 CPPFLAGS="$ac_save_CPPFLAGS"
404 fi
405 AC_SUBST(SANELIBS)
406 AC_SUBST(SANEINCL)
408 dnl **** Check for the ICU library ****
409 AC_CHECK_HEADERS(unicode/ubidi.h)
410 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
411 then
412 AC_CACHE_CHECK([whether we can statically link the ICU libraries], ac_cv_lib_icu,
413 [saved_libs="$LIBS"
414 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
415 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
416 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
417 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
418 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
419 [ac_cv_lib_icu="yes"],[ac_cv_lib_icu="no"])
420 LIBS="$saved_libs"])
421 if test "$ac_cv_lib_icu" = "yes"
422 then
423 AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
424 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
425 fi
426 fi
428 dnl **** Check for FreeType 2 ****
429 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
430 if test "$ft_lib" = "no"
431 then
432 FREETYPEINCL=""
433 wine_cv_msg_freetype=no
434 else
435 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
436 if test "$ft_devel" = "no"
437 then
438 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
439 if test "$ft_devel2" = "freetype2-config"
440 then
441 ft_devel=$ft_devel2
442 fi
443 fi
444 if test "$ft_devel" = "no"
445 then
446 FREETYPEINCL=""
447 wine_cv_msg_freetype=yes
448 else
449 FREETYPEINCL=`$ft_devel --cflags`
450 ac_save_CPPFLAGS="$CPPFLAGS"
451 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
452 AC_CHECK_HEADERS(ft2build.h \
453 freetype/freetype.h \
454 freetype/ftglyph.h \
455 freetype/tttables.h \
456 freetype/ftnames.h \
457 freetype/ftsnames.h \
458 freetype/ttnameid.h \
459 freetype/ftoutln.h \
460 freetype/internal/sfnt.h,,,
461 [#if HAVE_FT2BUILD_H
462 #include <ft2build.h>
463 #endif])
464 AC_TRY_CPP([#include <ft2build.h>
465 #include <freetype/fttrigon.h>],
466 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
467 [Define if you have the <freetype/fttrigon.h> header file.])
468 wine_cv_fttrigon=yes],
469 wine_cv_fttrigon=no)
470 CPPFLAGS="$ac_save_CPPFLAGS"
471 dnl Check that we have at least freetype/freetype.h
472 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
473 then
474 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
475 wine_cv_msg_freetype=no
476 else
477 FREETYPEINCL=""
478 wine_cv_msg_freetype=yes
479 fi
480 fi
481 fi
482 AC_SUBST(FREETYPEINCL)
484 dnl **** Check for parport (currently Linux only) ****
485 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
486 AC_TRY_COMPILE(
487 [#include <linux/ppdev.h>],
488 [ioctl (1,PPCLAIM,0)],
489 [ac_cv_c_ppdev="yes"],
490 [ac_cv_c_ppdev="no"])
491 )
492 if test "$ac_cv_c_ppdev" = "yes"
493 then
494 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
495 fi
497 dnl **** Check for va_copy ****
498 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
499 AC_TRY_LINK(
500 [#include <stdarg.h>],
501 [va_list ap1, ap2;
502 va_copy(ap1,ap2);
503 ],
504 [ac_cv_c_va_copy="yes"],
505 [ac_cv_c_va_copy="no"])
506 )
507 if test "$ac_cv_c_va_copy" = "yes"
508 then
509 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
510 fi
511 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
512 AC_TRY_LINK(
513 [#include <stdarg.h>],
514 [va_list ap1, ap2;
515 __va_copy(ap1,ap2);
516 ],
517 [ac_cv_c___va_copy="yes"],
518 [ac_cv_c___va_copy="no"])
519 )
520 if test "$ac_cv_c___va_copy" = "yes"
521 then
522 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
523 fi
525 dnl **** Check for sigsetjmp ****
526 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
527 AC_TRY_LINK(
528 [#include <setjmp.h>],
529 [sigjmp_buf buf;
530 sigsetjmp( buf, 1 );
531 siglongjmp( buf, 1 );],
532 [ac_cv_c_sigsetjmp="yes"],
533 [ac_cv_c_sigsetjmp="no"])
534 )
535 if test "$ac_cv_c_sigsetjmp" = "yes"
536 then
537 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
538 fi
540 dnl **** Check for pthread_rwlock_t ****
541 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
542 #include <pthread.h>])
544 dnl **** Check for pthread_getattr_np ****
545 ac_save_LIBS="$LIBS"
546 LIBS="$LIBS $LIBPTHREAD"
547 AC_CHECK_FUNCS(pthread_getattr_np)
548 LIBS="$ac_save_LIBS"
550 dnl **** Check for Open Sound System ****
551 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
553 AC_CACHE_CHECK([for Open Sound System],
554 ac_cv_c_opensoundsystem,
555 AC_TRY_COMPILE([
556 #if defined(HAVE_SYS_SOUNDCARD_H)
557 #include <sys/soundcard.h>
558 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
559 #include <machine/soundcard.h>
560 #elif defined(HAVE_SOUNDCARD_H)
561 #include <soundcard.h>
562 #endif
563 ],[
565 /* check for one of the Open Sound System specific SNDCTL_ defines */
566 #if !defined(SNDCTL_DSP_STEREO)
567 #error No open sound system
568 #endif
569 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
571 if test "$ac_cv_c_opensoundsystem" = "yes"
572 then
573 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
574 fi
576 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
577 ac_cv_c_opensoundsystem_midi,
578 AC_TRY_COMPILE([
579 #if defined(HAVE_SYS_SOUNDCARD_H)
580 #include <sys/soundcard.h>
581 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
582 #include <machine/soundcard.h>
583 #elif defined(HAVE_SOUNDCARD_H)
584 #include <soundcard.h>
585 #endif
586 ],[
588 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
589 #if !defined(SNDCTL_SEQ_SYNC)
590 #error No open sound system MIDI interface
591 #endif
592 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
594 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
595 then
596 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
597 fi
599 dnl **** Check for aRts Sound Server ****
600 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
601 AC_CACHE_CHECK([for aRts Sound server],
602 ac_cv_c_artsserver,
603 if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
604 then
605 ac_cv_c_artsserver=no
606 else
607 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
608 ARTSC_LIBS=`$ARTSCCONFIG --libs`
609 ac_cv_c_artsserver=no
610 save_CFLAGS="$CFLAGS"
611 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
612 AC_TRY_COMPILE([
613 #include <artsc.h>
614 ],[
615 arts_stream_t stream;
616 ],[
617 ac_cv_c_artsserver=yes
618 ])
619 CFLAGS="$save_CFLAGS"
620 fi)
622 if test "$ac_cv_c_artsserver" = "yes"
623 then
624 AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
625 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
627 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
628 fi
630 dnl **** Check for ALSA ****
631 AC_SUBST(ALSALIBS,"")
632 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
633 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
634 then
635 AC_CHECK_LIB(asound,snd_pcm_open,
636 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
637 ALSALIBS="-lasound")
638 fi
640 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
642 AC_SUBST(AUDIOIOLIBS,"")
643 AC_CHECK_HEADERS(libaudioio.h,
644 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
645 [AUDIOIOLIBS="-laudioio"
646 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
648 dnl **** Check for capi4linux ****
650 AC_CHECK_HEADERS(capi20.h,[
651 AC_CHECK_HEADERS(linux/capi.h,[
652 AC_CHECK_LIB(capi20,capi20_register,[
653 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
654 AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
655 ])
656 ])
657 ])
659 dnl **** Check for broken glibc mmap64 ****
661 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
662 AC_TRY_RUN([
663 #define _FILE_OFFSET_BITS 64
664 #include <stdio.h>
665 #include <unistd.h>
666 #include <fcntl.h>
667 #include <sys/mman.h>
668 #include <errno.h>
670 int main(int argc,char **argv) {
671 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
672 if (fd == -1) exit(1);
674 unlink("conftest.map");
676 write(fd,"test",4);
678 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
679 (errno == EINVAL)
680 ) {
681 exit(1);
682 }
683 close(fd);
684 fprintf(stderr,"success!\n");
685 exit(0);
686 }
688 ],
689 ac_cv_mmap64_works="yes",
690 ac_cv_mmap64_works="no",
691 ac_cv_mmap64_works="no") )
693 if test "$ac_cv_mmap64_works" = "yes"
694 then
695 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
696 fi
698 dnl **** Check for gcc specific options ****
700 AC_SUBST(EXTRACFLAGS,"")
701 if test "x${GCC}" = "xyes"
702 then
703 EXTRACFLAGS=-Wall
705 dnl Check for strength-reduce bug
706 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
707 AC_TRY_RUN([
708 int L[[4]] = {0,1,2,3};
709 int main(void) {
710 static int Array[[3]];
711 unsigned int B = 3;
712 int i;
713 for(i=0; i<B; i++) Array[[i]] = i - 3;
714 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
715 L[[i]] = 4;
717 exit( Array[[1]] != -2 || L[[2]] != 3);
718 }],
719 ac_cv_c_gcc_strength_bug="no",
720 ac_cv_c_gcc_strength_bug="yes",
721 ac_cv_c_gcc_strength_bug="yes") )
722 if test "$ac_cv_c_gcc_strength_bug" = "yes"
723 then
724 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
725 fi
727 dnl Check for -mpreferred-stack-boundary
728 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
729 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
730 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
731 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
732 then
733 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
734 fi
736 dnl Check for -fno-strict-aliasing
737 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
738 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
739 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
740 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
741 then
742 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
743 fi
745 dnl Check for -gstabs+ option
746 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
747 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
748 if test "$ac_cv_c_gcc_gstabs" = "yes"
749 then
750 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
751 fi
753 dnl Check for noisy string.h
754 saved_CFLAGS="$CFLAGS"
755 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
756 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
757 AC_TRY_COMPILE([#include <string.h>],[],
758 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
759 CFLAGS="$saved_CFLAGS"
760 if test "$ac_cv_c_string_h_warnings" = "no"
761 then
762 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
763 fi
764 fi
766 dnl **** Check how to define a function in assembly code ****
768 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
769 WINE_TRY_ASM_LINK(
770 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
771 ac_cv_asm_func_def=".def",
772 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
773 ac_cv_asm_func_def=".type @function",
774 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
775 ac_cv_asm_func_def=".type 2",
776 ac_cv_asm_func_def="unknown")])]))
778 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
779 case "$ac_cv_asm_func_def" in
780 ".def")
781 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
782 ".type @function")
783 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
784 ".type 2")
785 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
786 *)
787 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
788 esac
790 dnl **** Check for underscore on external symbols ****
792 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
793 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
794 [extern int ac_test;],
795 [if (ac_test) return 1],
796 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
798 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
799 if test "$ac_cv_c_extern_prefix" = "yes"
800 then
801 AC_DEFINE([__ASM_NAME(name)], ["_" name])
802 else
803 AC_DEFINE([__ASM_NAME(name)], [name])
804 fi
806 dnl **** Check how to do strings in assembler ****
808 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
809 WINE_TRY_ASM_LINK([".data\n\t.string \"test\"\n\t.text"],,,
810 ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
811 if test "$ac_cv_c_asm_string" = "yes"
812 then
813 AC_DEFINE(__ASM_STRING, [".string"], [Define to the assembler keyword used to specify an ASCII string])
814 else
815 AC_CACHE_CHECK([whether assembler accepts .asciz], ac_cv_c_asm_asciz,
816 WINE_TRY_ASM_LINK([".data\n\t.asciz \"test\"\n\t.text"],,,
817 ac_cv_c_asm_asciz="yes",ac_cv_c_asm_asciz="no"))
818 if test "$ac_cv_c_asm_asciz" = "yes"
819 then
820 AC_DEFINE(__ASM_STRING, [".asciz"])
821 else
822 AC_DEFINE(__ASM_STRING, [".ascii"])
823 fi
824 fi
826 dnl **** Check for .short in assembler ****
828 AC_CACHE_CHECK([whether assembler accepts .short], ac_cv_c_asm_short,
829 WINE_TRY_ASM_LINK([".data\n\t.short 1\n\t.text"],,,
830 ac_cv_c_asm_short="yes",ac_cv_c_asm_short="no"))
831 if test "$ac_cv_c_asm_short" = "yes"
832 then
833 AC_DEFINE(__ASM_SHORT, [".short"], [Define to the assembler keyword used to specify a word value])
834 else
835 AC_DEFINE(__ASM_SHORT, [".half"])
836 fi
838 dnl **** Check for working dll ****
840 AC_SUBST(DLLEXT,"")
841 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
842 AC_SUBST(DLLIBS,"")
843 AC_SUBST(LDSHARED,"")
844 AC_SUBST(LDDLL,"")
845 AC_SUBST(LIBEXT,"so")
846 AC_SUBST(IMPLIBEXT,"def")
848 case $host_os in
849 cygwin*|mingw32*)
850 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
851 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
852 if test "$DLLWRAP" = "false"; then
853 LIBEXT="a"
854 else
855 dnl FIXME - check whether dllwrap works correctly...
856 LIBEXT="dll"
857 fi
858 IMPLIBEXT="a"
859 ;;
860 *)
861 AC_CHECK_HEADERS(dlfcn.h,
862 [AC_CHECK_FUNCS(dlopen,,
863 [AC_CHECK_LIB(dl,dlopen,
864 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
865 DLLIBS="-ldl"],
866 [LIBEXT="a"])])],
867 [LIBEXT="a"])
869 if test "$LIBEXT" = "so"
870 then
871 DLLFLAGS="$DLLFLAGS -fPIC"
872 DLLEXT=".so"
873 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
874 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
875 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
876 if test "$ac_cv_c_dll_gnuelf" = "yes"
877 then
878 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
879 LDDLL="\$(CC) -shared -Wl,-Bsymbolic"
880 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
881 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
882 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
883 if test "$ac_cv_c_dll_zdefs" = "yes"
884 then
885 LDDLL="$LDDLL,-z,defs"
886 fi
888 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
889 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
890 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
891 if test "$ac_cv_c_export_dynamic" = "yes"
892 then
893 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
894 fi
896 case $host_cpu in
897 *i[[3456789]]86*)
898 AC_CACHE_CHECK([whether we can relocate the executable to 0x00110000], ac_cv_ld_reloc_exec,
899 [saved_CFLAGS="$CFLAGS"
900 CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x00110400"
901 AC_TRY_RUN([#include <unistd.h>
902 int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
903 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no", ac_cv_ld_reloc_exec="no")
904 CFLAGS="$saved_CFLAGS"])
905 if test "$ac_cv_ld_reloc_exec" = "yes"
906 then
907 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x00110400"
908 fi
909 ;;
910 esac
912 else
913 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
914 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
915 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
916 if test "$ac_cv_c_dll_unixware" = "yes"
917 then
918 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
919 LDDLL="\$(CC) -Wl,-G,-B,symbolic"
921 else
922 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
923 [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
924 if test "$ac_cv_c_dll_macho" = "yes"
925 then
926 LIBEXT="dylib"
927 LDDLL="\$(CC) -bundle -flat_namespace -undefined suppress"
928 LDSHARED="\$(CC) -dynamiclib"
929 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
930 fi
931 fi
932 fi
933 fi
935 dnl Check for cross compiler to build test programs
936 AC_SUBST(CROSSTEST,"")
937 if test "$cross_compiling" = "no"
938 then
939 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc,false)
940 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool,false)
941 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres,false)
942 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
943 fi
944 ;;
945 esac
947 if test "$LIBEXT" = "a"; then
948 AC_MSG_ERROR(
949 [could not find a way to build shared libraries.
950 It is currently not possible to build Wine without shared library
951 (.so) support to allow transparent switch between .so and .dll files.
952 If you are using Linux, you will need a newer binutils.]
953 )
954 fi
956 case $build_os in
957 cygwin*|mingw32*)
958 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
959 darwin*|macosx*)
960 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
961 *)
962 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
963 esac
965 dnl Mingw needs explicit msvcrt for linking libwine
966 case $host_os in
967 mingw32*)
968 AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
969 esac
971 case $host_os in
972 linux*)
973 AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
974 AC_SUBST(MAIN_BINARY,"wine-glibc")
975 ;;
976 *)
977 AC_SUBST(WINE_BINARIES,"wine-kthread")
978 AC_SUBST(MAIN_BINARY,"wine-kthread")
979 ;;
980 esac
982 dnl **** Get the soname for libraries that we load dynamically ****
984 if test "$LIBEXT" = "so"
985 then
986 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
987 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
988 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
989 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
990 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
991 WINE_GET_SONAME(cups,cupsGetDefault)
992 WINE_GET_SONAME(jack,jack_client_new)
993 WINE_GET_SONAME(fontconfig,FcInit)
994 WINE_GET_SONAME(ssl,SSL_library_init)
995 WINE_GET_SONAME(crypto,BIO_new_socket)
996 WINE_GET_SONAME(ncurses,waddch)
997 WINE_GET_SONAME(curses,waddch)
998 fi
1001 dnl **** Check for functions ****
1003 AC_FUNC_ALLOCA()
1004 AC_CHECK_FUNCS(\
1005 _lwp_create \
1006 _lwp_self \
1007 _pclose \
1008 _popen \
1009 _snprintf \
1010 _spawnvp \
1011 _stricmp \
1012 _strnicmp \
1013 _vsnprintf \
1014 chsize \
1015 clone \
1016 finite \
1017 fpclass \
1018 ftruncate \
1019 ftruncate64 \
1020 getnetbyaddr \
1021 getnetbyname \
1022 getopt_long \
1023 getpagesize \
1024 getprotobyname \
1025 getprotobynumber \
1026 getpwuid \
1027 getservbyport \
1028 gettid \
1029 gettimeofday \
1030 inet_network \
1031 lseek64 \
1032 lstat \
1033 memmove \
1034 mmap \
1035 pclose \
1036 popen \
1037 pread \
1038 pwrite \
1039 rfork \
1040 select \
1041 sendmsg \
1042 settimeofday \
1043 sigaltstack \
1044 snprintf \
1045 spawnvp \
1046 statfs \
1047 strcasecmp \
1048 strerror \
1049 strncasecmp \
1050 tcgetattr \
1051 timegm \
1052 usleep \
1053 vfscanf \
1054 vsnprintf \
1055 wait4 \
1056 waitpid \
1057 )
1059 dnl **** Check for header files ****
1061 AC_CHECK_HEADERS(\
1062 arpa/inet.h \
1063 arpa/nameser.h \
1064 cups/cups.h \
1065 direct.h \
1066 elf.h \
1067 float.h \
1068 fontconfig/fontconfig.h \
1069 getopt.h \
1070 ieeefp.h \
1071 io.h \
1072 jack/jack.h \
1073 libio.h \
1074 libutil.h \
1075 link.h \
1076 linux/cdrom.h \
1077 linux/hdreg.h \
1078 linux/input.h \
1079 linux/joystick.h \
1080 linux/major.h \
1081 linux/param.h \
1082 linux/serial.h \
1083 linux/ucdrom.h \
1084 machine/cpu.h \
1085 netdb.h \
1086 netinet/in.h \
1087 netinet/in_systm.h \
1088 netinet/tcp.h \
1089 netinet/tcp_fsm.h \
1090 openssl/ssl.h \
1091 process.h \
1092 pthread.h \
1093 pty.h \
1094 pwd.h \
1095 regex.h \
1096 sched.h \
1097 scsi/sg.h \
1098 scsi/scsi.h \
1099 scsi/scsi_ioctl.h \
1100 socket.h \
1101 stdint.h \
1102 strings.h \
1103 sys/cdio.h \
1104 sys/errno.h \
1105 sys/file.h \
1106 sys/filio.h \
1107 sys/inttypes.h \
1108 sys/ioctl.h \
1109 sys/ipc.h \
1110 sys/link.h \
1111 sys/lwp.h \
1112 sys/mman.h \
1113 sys/modem.h \
1114 sys/msg.h \
1115 sys/param.h \
1116 sys/poll.h \
1117 sys/ptrace.h \
1118 sys/reg.h \
1119 sys/scsiio.h \
1120 sys/shm.h \
1121 sys/signal.h \
1122 sys/socket.h \
1123 sys/sockio.h \
1124 sys/statfs.h \
1125 sys/strtio.h \
1126 sys/syscall.h \
1127 sys/sysctl.h \
1128 sys/time.h \
1129 sys/times.h \
1130 sys/uio.h \
1131 sys/un.h \
1132 sys/v86.h \
1133 sys/v86intr.h \
1134 sys/vfs.h \
1135 sys/vm86.h \
1136 sys/wait.h \
1137 syscall.h \
1138 termios.h \
1139 unistd.h \
1140 utime.h \
1141 valgrind/memcheck.h
1142 )
1143 AC_HEADER_STAT()
1145 dnl **** Checks for headers that depend on other ones ****
1147 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1148 [#include <sys/types.h>
1149 #if HAVE_SYS_PARAM_H
1150 # include <sys/param.h>
1151 #endif])
1153 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1154 [#include <sys/types.h>
1155 #if HAVE_SYS_SOCKET_H
1156 # include <sys/socket.h>
1157 #endif])
1159 AC_CHECK_HEADERS([resolv.h],,,
1160 [#include <sys/types.h>
1161 #if HAVE_SYS_SOCKET_H
1162 # include <sys/socket.h>
1163 #endif
1164 #if HAVE_NETINET_IN_H
1165 # include <netinet/in.h>
1166 #endif
1167 #if HAVE_ARPA_NAMESER_H
1168 # include <arpa/nameser.h>
1169 #endif])
1171 AC_CHECK_HEADERS(netinet/ip.h,,,
1172 [#include <sys/types.h>
1173 #if HAVE_SYS_SOCKET_H
1174 # include <sys/socket.h>
1175 #endif
1176 #if HAVE_NETINET_IN_SYSTM_H
1177 # include <netinet/in_systm.h>
1178 #endif])
1180 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1182 dnl **** Check for IPX headers (currently Linux only) ****
1184 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1185 AC_TRY_COMPILE(
1186 [#include <sys/types.h>
1187 #ifdef HAVE_SYS_SOCKET_H
1188 # include <sys/socket.h>
1189 #endif
1190 #include <netipx/ipx.h>],
1191 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1192 [ac_cv_c_ipx_gnu="yes"],
1193 [ac_cv_c_ipx_gnu="no"])
1194 )
1195 if test "$ac_cv_c_ipx_gnu" = "yes"
1196 then
1197 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1198 fi
1200 if test "$ac_cv_c_ipx_gnu" = "no"
1201 then
1202 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1203 AC_TRY_COMPILE(
1204 [#include <sys/types.h>
1205 #ifdef HAVE_SYS_SOCKET_H
1206 # include <sys/socket.h>
1207 #endif
1208 #include <asm/types.h>
1209 #include <linux/ipx.h>],
1210 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1211 [ac_cv_c_ipx_linux="yes"],
1212 [ac_cv_c_ipx_linux="no"])
1213 )
1214 if test "$ac_cv_c_ipx_linux" = "yes"
1215 then
1216 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1217 fi
1218 fi
1220 dnl **** Check for types ****
1222 AC_C_CONST
1223 AC_C_INLINE
1224 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1225 AC_CHECK_SIZEOF(long long,0)
1227 AC_CACHE_CHECK([whether linux/input.h is for real],
1228 wine_cv_linux_input_h,
1229 AC_TRY_COMPILE([
1230 #include <linux/input.h>
1231 ] , [
1232 int foo = EVIOCGBIT(EV_ABS,42);
1233 int bar = BTN_PINKIE;
1234 int fortytwo = 42;
1235 ],
1236 wine_cv_linux_input_h=yes,
1237 wine_cv_linux_input_h=no,
1238 no
1239 )
1240 )
1241 if test "$wine_cv_linux_input_h" = "yes"
1242 then
1243 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1244 [Define if we have linux/input.h AND it contains the INPUT event API])
1245 fi
1248 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1249 wine_cv_linux_gethostbyname_r_6,
1250 AC_TRY_COMPILE([
1251 #include <netdb.h>
1252 ], [
1253 char *name=NULL;
1254 struct hostent he;
1255 struct hostent *result;
1256 char *buf=NULL;
1257 int bufsize=0;
1258 int res,errnr;
1259 char *addr=NULL;
1260 int addrlen=0;
1261 int addrtype=0;
1262 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1263 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1264 ],
1265 wine_cv_linux_gethostbyname_r_6=yes,
1266 wine_cv_linux_gethostbyname_r_6=no
1267 )
1268 )
1269 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1270 then
1271 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1272 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1273 fi
1275 if test "$ac_cv_header_linux_joystick_h" = "yes"
1276 then
1277 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1278 wine_cv_linux_joystick_22_api,
1279 AC_TRY_COMPILE([
1280 #include <sys/ioctl.h>
1281 #include <linux/joystick.h>
1283 struct js_event blub;
1284 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1285 #error "no 2.2 header"
1286 #endif
1287 ],/*empty*/,
1288 wine_cv_linux_joystick_22_api=yes,
1289 wine_cv_linux_joystick_22_api=no,
1290 wine_cv_linux_joystick_22_api=no
1291 )
1292 )
1293 if test "$wine_cv_linux_joystick_22_api" = "yes"
1294 then
1295 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1296 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1297 fi
1298 fi
1300 dnl **** statfs checks ****
1302 if test "$ac_cv_header_sys_vfs_h" = "yes"
1303 then
1304 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1305 wine_cv_sys_vfs_has_statfs,
1306 AC_TRY_COMPILE([
1307 #include <sys/types.h>
1308 #ifdef HAVE_SYS_PARAM_H
1309 # include <sys/param.h>
1310 #endif
1311 #include <sys/vfs.h>
1312 ],[
1313 struct statfs stfs;
1315 memset(&stfs,0,sizeof(stfs));
1316 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1317 )
1318 )
1319 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1320 then
1321 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1322 [Define if the struct statfs is defined by <sys/vfs.h>])
1323 fi
1324 fi
1326 if test "$ac_cv_header_sys_statfs_h" = "yes"
1327 then
1328 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1329 wine_cv_sys_statfs_has_statfs,
1330 AC_TRY_COMPILE([
1331 #include <sys/types.h>
1332 #ifdef HAVE_SYS_PARAM_H
1333 # include <sys/param.h>
1334 #endif
1335 #include <sys/statfs.h>
1336 ],[
1337 struct statfs stfs;
1338 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1339 )
1340 )
1341 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1342 then
1343 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1344 [Define if the struct statfs is defined by <sys/statfs.h>])
1345 fi
1346 fi
1348 if test "$ac_cv_header_sys_mount_h" = "yes"
1349 then
1350 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1351 wine_cv_sys_mount_has_statfs,
1352 AC_TRY_COMPILE([
1353 #include <sys/types.h>
1354 #ifdef HAVE_SYS_PARAM_H
1355 # include <sys/param.h>
1356 #endif
1357 #include <sys/mount.h>
1358 ],[
1359 struct statfs stfs;
1360 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1361 )
1362 )
1363 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1364 then
1365 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1366 [Define if the struct statfs is defined by <sys/mount.h>])
1367 fi
1368 fi
1370 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1372 dnl Check for statfs members
1373 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail],,,
1374 [#include <sys/types.h>
1375 #ifdef HAVE_SYS_PARAM_H
1376 # include <sys/param.h>
1377 #endif
1378 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1379 # include <sys/mount.h>
1380 #else
1381 # ifdef STATFS_DEFINED_BY_SYS_VFS
1382 # include <sys/vfs.h>
1383 # else
1384 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1385 # include <sys/statfs.h>
1386 # endif
1387 # endif
1388 #endif])
1390 dnl Check for socket structure members
1391 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1392 [#include <sys/types.h>
1393 #ifdef HAVE_SYS_SOCKET_H
1394 # include <sys/socket.h>
1395 #endif
1396 #ifdef HAVE_SYS_UN_H
1397 # include <sys/un.h>
1398 #endif])
1400 dnl Check for siginfo_t members
1401 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1403 dnl Check for struct option
1404 AC_CHECK_MEMBERS([struct option.name],,,
1405 [#ifdef HAVE_GETOPT_H
1406 #include <getopt.h>
1407 #endif])
1409 dnl Check for stat.st_blocks
1410 AC_CHECK_MEMBERS([struct stat.st_blocks])
1412 dnl *** check for the need to define platform-specific symbols
1414 case $host_cpu in
1415 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1416 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1417 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1418 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1419 esac
1421 case $host_vendor in
1422 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1423 esac
1425 dnl **** Generate output files ****
1427 AH_TOP([#define __WINE_CONFIG_H])
1429 WINE_CONFIG_EXTRA_DIR(controls)
1430 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1431 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1432 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1433 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1434 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1435 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1436 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1437 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1438 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1439 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1440 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1441 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1442 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1443 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1444 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1445 WINE_CONFIG_EXTRA_DIR(files)
1446 WINE_CONFIG_EXTRA_DIR(graphics)
1447 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1448 WINE_CONFIG_EXTRA_DIR(include/wine)
1449 WINE_CONFIG_EXTRA_DIR(misc)
1450 WINE_CONFIG_EXTRA_DIR(objects)
1451 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1452 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1453 WINE_CONFIG_EXTRA_DIR(windows)
1455 MAKE_RULES=Make.rules
1456 AC_SUBST_FILE(MAKE_RULES)
1458 MAKE_DLL_RULES=dlls/Makedll.rules
1459 AC_SUBST_FILE(MAKE_DLL_RULES)
1461 MAKE_TEST_RULES=dlls/Maketest.rules
1462 AC_SUBST_FILE(MAKE_TEST_RULES)
1464 MAKE_LIB_RULES=libs/Makelib.rules
1465 AC_SUBST_FILE(MAKE_LIB_RULES)
1467 MAKE_PROG_RULES=programs/Makeprog.rules
1468 AC_SUBST_FILE(MAKE_PROG_RULES)
1470 AC_CONFIG_FILES([
1471 Make.rules
1472 dlls/Makedll.rules
1473 dlls/Maketest.rules
1474 libs/Makelib.rules
1475 programs/Makeprog.rules
1476 Makefile
1477 dlls/Makefile
1478 dlls/advapi32/Makefile
1479 dlls/advapi32/tests/Makefile
1480 dlls/avicap32/Makefile
1481 dlls/avifil32/Makefile
1482 dlls/cabinet/Makefile
1483 dlls/capi2032/Makefile
1484 dlls/cfgmgr32/Makefile
1485 dlls/comcat/Makefile
1486 dlls/comctl32/Makefile
1487 dlls/comctl32/tests/Makefile
1488 dlls/commdlg/Makefile
1489 dlls/crtdll/Makefile
1490 dlls/crypt32/Makefile
1491 dlls/ctl3d/Makefile
1492 dlls/wined3d/Makefile
1493 dlls/d3d8/Makefile
1494 dlls/d3d9/Makefile
1495 dlls/d3dim/Makefile
1496 dlls/d3dx8/Makefile
1497 dlls/dciman32/Makefile
1498 dlls/ddraw/Makefile
1499 dlls/ddraw/tests/Makefile
1500 dlls/devenum/Makefile
1501 dlls/dinput/Makefile
1502 dlls/dinput8/Makefile
1503 dlls/dmband/Makefile
1504 dlls/dmcompos/Makefile
1505 dlls/dmime/Makefile
1506 dlls/dmloader/Makefile
1507 dlls/dmscript/Makefile
1508 dlls/dmstyle/Makefile
1509 dlls/dmsynth/Makefile
1510 dlls/dmusic/Makefile
1511 dlls/dmusic32/Makefile
1512 dlls/dplay/Makefile
1513 dlls/dplayx/Makefile
1514 dlls/dpnhpast/Makefile
1515 dlls/dsound/Makefile
1516 dlls/dsound/tests/Makefile
1517 dlls/gdi/Makefile
1518 dlls/gdi/tests/Makefile
1519 dlls/glu32/Makefile
1520 dlls/icmp/Makefile
1521 dlls/imagehlp/Makefile
1522 dlls/imm32/Makefile
1523 dlls/iphlpapi/Makefile
1524 dlls/kernel/Makefile
1525 dlls/kernel/tests/Makefile
1526 dlls/lzexpand/Makefile
1527 dlls/mapi32/Makefile
1528 dlls/mpr/Makefile
1529 dlls/msacm/Makefile
1530 dlls/msacm/imaadp32/Makefile
1531 dlls/msacm/msadp32/Makefile
1532 dlls/msacm/msg711/Makefile
1533 dlls/msacm/winemp3/Makefile
1534 dlls/msdmo/Makefile
1535 dlls/mshtml/Makefile
1536 dlls/msi/Makefile
1537 dlls/msimg32/Makefile
1538 dlls/msisys/Makefile
1539 dlls/msnet32/Makefile
1540 dlls/msvcrt/Makefile
1541 dlls/msvcrt/tests/Makefile
1542 dlls/msvcrt20/Makefile
1543 dlls/msvcrtd/Makefile
1544 dlls/msvideo/Makefile
1545 dlls/msvideo/msrle32/Makefile
1546 dlls/mswsock/Makefile
1547 dlls/netapi32/Makefile
1548 dlls/netapi32/tests/Makefile
1549 dlls/ntdll/Makefile
1550 dlls/ntdll/tests/Makefile
1551 dlls/odbc32/Makefile
1552 dlls/ole32/Makefile
1553 dlls/oleacc/Makefile
1554 dlls/oleaut32/Makefile
1555 dlls/oleaut32/tests/Makefile
1556 dlls/olecli/Makefile
1557 dlls/oledlg/Makefile
1558 dlls/olepro32/Makefile
1559 dlls/olesvr/Makefile
1560 dlls/opengl32/Makefile
1561 dlls/psapi/Makefile
1562 dlls/qcap/Makefile
1563 dlls/quartz/Makefile
1564 dlls/rasapi32/Makefile
1565 dlls/richedit/Makefile
1566 dlls/rpcrt4/Makefile
1567 dlls/rpcrt4/tests/Makefile
1568 dlls/serialui/Makefile
1569 dlls/setupapi/Makefile
1570 dlls/shdocvw/Makefile
1571 dlls/shell32/Makefile
1572 dlls/shell32/tests/Makefile
1573 dlls/shfolder/Makefile
1574 dlls/shlwapi/Makefile
1575 dlls/shlwapi/tests/Makefile
1576 dlls/snmpapi/Makefile
1577 dlls/sti/Makefile
1578 dlls/tapi32/Makefile
1579 dlls/ttydrv/Makefile
1580 dlls/twain/Makefile
1581 dlls/url/Makefile
1582 dlls/urlmon/Makefile
1583 dlls/urlmon/tests/Makefile
1584 dlls/user/Makefile
1585 dlls/user/tests/Makefile
1586 dlls/uxtheme/Makefile
1587 dlls/version/Makefile
1588 dlls/win32s/Makefile
1589 dlls/winaspi/Makefile
1590 dlls/winedos/Makefile
1591 dlls/wineps/Makefile
1592 dlls/wininet/Makefile
1593 dlls/wininet/tests/Makefile
1594 dlls/winmm/Makefile
1595 dlls/winmm/joystick/Makefile
1596 dlls/winmm/mcianim/Makefile
1597 dlls/winmm/mciavi/Makefile
1598 dlls/winmm/mcicda/Makefile
1599 dlls/winmm/mciseq/Makefile
1600 dlls/winmm/mciwave/Makefile
1601 dlls/winmm/midimap/Makefile
1602 dlls/winmm/tests/Makefile
1603 dlls/winmm/wavemap/Makefile
1604 dlls/winmm/winealsa/Makefile
1605 dlls/winmm/winearts/Makefile
1606 dlls/winmm/wineaudioio/Makefile
1607 dlls/winmm/winenas/Makefile
1608 dlls/winmm/winejack/Makefile
1609 dlls/winmm/wineoss/Makefile
1610 dlls/winnls/Makefile
1611 dlls/winsock/Makefile
1612 dlls/winsock/tests/Makefile
1613 dlls/winspool/Makefile
1614 dlls/winspool/tests/Makefile
1615 dlls/wintab32/Makefile
1616 dlls/wintrust/Makefile
1617 dlls/wow32/Makefile
1618 dlls/wsock32/Makefile
1619 dlls/x11drv/Makefile
1620 documentation/Makefile
1621 include/Makefile
1622 libs/Makefile
1623 libs/port/Makefile
1624 libs/unicode/Makefile
1625 libs/uuid/Makefile
1626 libs/wine/Makefile
1627 libs/wpp/Makefile
1628 loader/Makefile
1629 programs/Makefile
1630 programs/avitools/Makefile
1631 programs/clock/Makefile
1632 programs/cmdlgtst/Makefile
1633 programs/control/Makefile
1634 programs/expand/Makefile
1635 programs/notepad/Makefile
1636 programs/osversioncheck/Makefile
1637 programs/progman/Makefile
1638 programs/regapi/Makefile
1639 programs/regedit/Makefile
1640 programs/regsvr32/Makefile
1641 programs/regtest/Makefile
1642 programs/rpcss/Makefile
1643 programs/rundll32/Makefile
1644 programs/start/Makefile
1645 programs/uninstaller/Makefile
1646 programs/view/Makefile
1647 programs/wcmd/Makefile
1648 programs/wineboot/Makefile
1649 programs/winecfg/Makefile
1650 programs/wineconsole/Makefile
1651 programs/winedbg/Makefile
1652 programs/winefile/Makefile
1653 programs/winemenubuilder/Makefile
1654 programs/winemine/Makefile
1655 programs/winepath/Makefile
1656 programs/winevdm/Makefile
1657 programs/winhelp/Makefile
1658 programs/winver/Makefile
1659 server/Makefile
1660 tools/Makefile
1661 tools/widl/Makefile
1662 tools/winapi/Makefile
1663 tools/winebuild/Makefile
1664 tools/winedump/Makefile
1665 tools/winegcc/Makefile
1666 tools/wmc/Makefile
1667 tools/wrc/Makefile])
1669 AC_OUTPUT
1671 if test "$have_x" = "no"
1672 then
1673 echo
1674 echo "*** Warning: X development files not found. Wine will be built without"
1675 echo "*** X support, which currently does not work, and would probably not be"
1676 echo "*** what you want anyway. You will need to install devel packages of"
1677 echo "*** Xlib/Xfree86 at the very least."
1678 fi
1680 if test "$wine_cv_opengl_version_OK" = "no"
1681 then
1682 echo
1683 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1684 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1685 fi
1687 if test "$wine_cv_msg_freetype" = "yes"
1688 then
1689 echo
1690 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1691 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1692 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1693 echo "*** enable Wine to use TrueType fonts."
1694 fi
1696 echo
1697 echo "Configure finished. Do 'make depend && make' to compile Wine."
1698 echo
1700 dnl Local Variables:
1701 dnl comment-start: "dnl "
1702 dnl comment-end: ""
1703 dnl comment-start-skip: "\\bdnl\\b\\s *"
1704 dnl compile-command: "autoconf"
1705 dnl End: