aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]]),
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32,w64-mingw32],[x86_64-ac_wine_prefix-$2 ])" ;;
 132   *)
 133     ac_prefix_list="" ;;
 134 esac
 135 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 136
 137
 138 dnl **** Define helper functions for creating config.status files ****
 139 dnl
 140 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 141 dnl
 142 AC_DEFUN([WINE_CONFIG_HELPERS],
 143 [AC_SUBST(ALL_MAKEFILE_DEPENDS,["# Makefile dependencies"])
 144 AC_SUBST(ALL_WINETEST_DEPENDS,["# Test binaries"])
 145
 146 AC_SUBST(ALL_MAKERULES,"")
 147 AC_SUBST(ALL_SYMLINKS,"")
 148 AC_SUBST(ALL_DIRS,"")
 149 AC_SUBST(ALL_TOP_DIRS,"")
 150 AC_SUBST(ALL_DLL_DIRS,"")
 151 AC_SUBST(ALL_TOOL_DIRS,"")
 152 AC_SUBST(ALL_STATICLIB_DIRS,"")
 153 AC_SUBST(ALL_STATIC_LIBS,"")
 154 AC_SUBST(ALL_IMPORT_LIBS,"")
 155 AC_SUBST(ALL_INSTALL_DIRS,"")
 156 AC_SUBST(ALL_TEST_DIRS,"")
 157 AC_SUBST(ALL_TEST_BINARIES,"")
 158 AC_SUBST(ALL_PROGRAM_DIRS,"")
 159 AC_SUBST(ALL_PROGRAM_BIN_INSTALL_DIRS,"")
 160
 161 wine_fn_append_file ()
 162 {
 163     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 164 }
 165
 166 wine_fn_append_rule ()
 167 {
 168     AS_VAR_APPEND($[1],"$as_nl$[2]")
 169 }
 170
 171 wine_fn_config_makefile ()
 172 {
 173     ac_dir=$[1]
 174     ac_deps=$[2]
 175     wine_fn_append_file ALL_DIRS $ac_dir
 176     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 177 "$ac_dir/__clean__ $ac_dir/__install__ $ac_dir/__install-dev__ $ac_dir/__install-lib__ $ac_dir/__uninstall__ $ac_dir: $ac_dir/Makefile
 178 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status $ac_deps
 179         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 180 }
 181
 182 wine_fn_config_lib ()
 183 {
 184     ac_name=$[1]
 185     ac_dir=dlls/$ac_name
 186     wine_fn_append_file ALL_DIRS $ac_dir
 187     wine_fn_append_file ALL_STATICLIB_DIRS $ac_dir
 188     wine_fn_append_file ALL_STATIC_LIBS $ac_dir/lib$ac_name.a
 189     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 190 "$ac_dir/__install__ $ac_dir/__install-dev__: $ac_dir
 191 $ac_dir $ac_dir/lib$ac_name.cross.a: tools/widl tools/winebuild tools/winegcc include
 192 $ac_dir/lib$ac_name.cross.a: $ac_dir/Makefile dummy
 193         @cd $ac_dir && \$(MAKE) lib$ac_name.cross.a
 194 $ac_dir/__clean__ $ac_dir/__install-lib__ $ac_dir/__uninstall__ $ac_dir: $ac_dir/Makefile
 195 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status dlls/Makeimplib.rules \$(MAKEDEP)
 196         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 197 }
 198
 199 wine_fn_config_dll ()
 200 {
 201     ac_dir=$[1]
 202     ac_enable=$[2]
 203     ac_implib=$[3]
 204     ac_implibsrc=$[4]
 205     ac_file="dlls/$ac_dir/lib$ac_implib"
 206     ac_deps="tools/widl tools/winebuild tools/winegcc include"
 207
 208     wine_fn_append_file ALL_DIRS dlls/$ac_dir
 209     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 210 "dlls/$ac_dir dlls/$ac_dir/__install__ dlls/$ac_dir/__install-lib__ dlls/$ac_dir/__install-dev__: __builddeps__ dlls/$ac_dir/Makefile
 211 dlls/$ac_dir/__clean__ dlls/$ac_dir/__uninstall__ dlls/$ac_dir: dlls/$ac_dir/Makefile
 212 dlls/$ac_dir/Makefile dlls/$ac_dir/__depend__: dlls/$ac_dir/Makefile.in config.status dlls/Makedll.rules \$(MAKEDEP)
 213         @./config.status --file dlls/$ac_dir/Makefile && cd dlls/$ac_dir && \$(MAKE) depend"
 214     AS_VAR_IF([$ac_enable],[no],
 215               dnl enable_win16 is special in that it disables import libs too
 216               [test "$ac_enable" != enable_win16 || return 0],
 217               [wine_fn_append_file ALL_DLL_DIRS dlls/$ac_dir])
 218
 219     if test -n "$ac_implibsrc"
 220     then
 221         wine_fn_append_file ALL_IMPORT_LIBS $ac_file.$IMPLIBEXT
 222         wine_fn_append_file ALL_IMPORT_LIBS $ac_file.$STATIC_IMPLIBEXT
 223         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 224 "$ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 225 $ac_file.def: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 226         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 227 $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/Makefile dummy
 228         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`"
 229     elif test -n "$ac_implib"
 230     then
 231         wine_fn_append_file ALL_IMPORT_LIBS $ac_file.$IMPLIBEXT
 232         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 233 "$ac_file.$IMPLIBEXT $ac_file.cross.a: $ac_deps
 234 $ac_file.$IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 235         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`"
 236
 237         if test "$ac_dir" != "$ac_implib"
 238         then
 239             wine_fn_append_file ALL_IMPORT_LIBS dlls/lib$ac_implib.$IMPLIBEXT
 240             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 241 "dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 242         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.$IMPLIBEXT \$[@]
 243 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 244         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.cross.a \$[@]
 245 clean::
 246         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 247         fi
 248     fi
 249 }
 250
 251 wine_fn_config_program ()
 252 {
 253     ac_dir=$[1]
 254     ac_enable=$[2]
 255     ac_install=$[3]
 256     wine_fn_append_file ALL_DIRS programs/$ac_dir
 257     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 258 "programs/$ac_dir programs/$ac_dir/__install__ programs/$ac_dir/__install-lib__: __builddeps__ programs/$ac_dir/Makefile
 259 programs/$ac_dir/__clean__ programs/$ac_dir/__install-dev__ programs/$ac_dir/__uninstall__ programs/$ac_dir: programs/$ac_dir/Makefile
 260 programs/$ac_dir/Makefile programs/$ac_dir/__depend__: programs/$ac_dir/Makefile.in config.status programs/Makeprog.rules \$(MAKEDEP)
 261         @./config.status --file programs/$ac_dir/Makefile && cd programs/$ac_dir && \$(MAKE) depend"
 262     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_file ALL_PROGRAM_DIRS programs/$ac_dir
 263               case $ac_install in
 264                installbin) wine_fn_append_file ALL_INSTALL_DIRS programs/$ac_dir
 265                            wine_fn_append_file ALL_PROGRAM_BIN_INSTALL_DIRS programs/$ac_dir ;;
 266                install) wine_fn_append_file ALL_INSTALL_DIRS programs/$ac_dir ;;
 267               esac])
 268 }
 269
 270 wine_fn_config_test ()
 271 {
 272     ac_dir=$[1]
 273     ac_name=$[2]
 274     wine_fn_append_file ALL_TEST_BINARIES $ac_name.exe
 275     wine_fn_append_rule ALL_WINETEST_DEPENDS \
 276 "$ac_name.exe: \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT
 277         cp \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT \$[@] && \$(STRIP) \$[@]
 278 $ac_name.rc:
 279         echo \"$ac_name.exe TESTRES \\\"$ac_name.exe\\\"\" >\$[@] || (\$(RM) \$[@] && false)
 280 $ac_name.res: $ac_name.rc $ac_name.exe"
 281     wine_fn_append_file ALL_DIRS $ac_dir
 282     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 283 "$ac_dir: __builddeps__
 284 $ac_dir/__crosstest__: __buildcrossdeps__
 285 $ac_dir/__clean__ $ac_dir/__crosstest__ $ac_dir: $ac_dir/Makefile
 286 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status Maketest.rules \$(MAKEDEP)
 287         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 288     AS_VAR_IF([enable_tests],[no],,[wine_fn_append_file ALL_TEST_DIRS $ac_dir])
 289 }
 290
 291 wine_fn_config_tool ()
 292 {
 293     ac_dir=$[1]
 294     ac_deps="Make.rules"
 295     if test "$ac_dir" != tools
 296     then
 297         dnl makedep is in tools so tools makefile cannot depend on it
 298         ac_deps="$ac_deps \$(MAKEDEP)"
 299     fi
 300     wine_fn_append_file ALL_DIRS $ac_dir
 301     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 302 "$ac_dir/__clean__ $ac_dir/__install__ $ac_dir/__install-dev__ $ac_dir/__install-lib__ $ac_dir/__uninstall__ $ac_dir: $ac_dir/Makefile
 303 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status $ac_deps
 304         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 305     AS_VAR_IF([enable_tools],[no],,[wine_fn_append_file ALL_TOOL_DIRS $ac_dir])
 306 }])
 307
 308 dnl **** Define helper function to append a file to a makefile file list ****
 309 dnl
 310 dnl Usage: WINE_APPEND_FILE(var,file)
 311 dnl
 312 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 313
 314 dnl **** Define helper function to append a rule to a makefile command list ****
 315 dnl
 316 dnl Usage: WINE_APPEND_RULE(var,rule)
 317 dnl
 318 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 319
 320 dnl **** Create nonexistent directories from config.status ****
 321 dnl
 322 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 323 dnl
 324 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 325 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 326
 327 dnl **** Create symlinks from config.status ****
 328 dnl
 329 dnl Usage: WINE_CONFIG_SYMLINK(name,target)
 330 dnl
 331 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 332 AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 333 m4_if([$2],,[test "$srcdir" = "." || ])WINE_APPEND_FILE(ALL_SYMLINKS,[$1])])
 334
 335 dnl **** Create a make rules file from config.status ****
 336 dnl
 337 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 338 dnl
 339 AC_DEFUN([WINE_CONFIG_MAKERULES],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 340 WINE_APPEND_FILE(ALL_MAKERULES,[$1])
 341 WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[$1: m4_ifval([$3],[$1.in $3],[$1.in]) config.status])
 342 $2=$1
 343 AC_SUBST_FILE([$2])dnl
 344 AC_CONFIG_FILES([$1])])
 345
 346 dnl **** Create a makefile from config.status ****
 347 dnl
 348 dnl Usage: WINE_CONFIG_MAKEFILE(file,deps,var,enable)
 349 dnl
 350 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 351 m4_pushdef([ac_dir],m4_bpatsubst([$1],[^\(\(.*\)/\)?Makefile$],[\2]))dnl
 352 m4_pushdef([ac_name],m4_bpatsubst(ac_dir,[.*/\(.*\)$],[\1]))dnl
 353 m4_if(ac_dir,,WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[$1: $1.in $2 config.status])
 354 AC_CONFIG_FILES([$1]),
 355 [wine_fn_config_makefile ac_dir m4_if(ac_dir,tools,[$2],["$2 \$(MAKEDEP)"])
 356 AS_VAR_PUSHDEF([ac_enable],m4_default([$4],[enable_]ac_name))dnl
 357 m4_ifval([$3],[test "x$ac_enable" != xno]m4_foreach([ac_var],[$3],[ && WINE_APPEND_FILE(ac_var,ac_dir)]))
 358 AS_VAR_POPDEF([ac_enable])])dnl
 359 m4_popdef([ac_dir])dnl
 360 m4_popdef([ac_name])])
 361
 362 dnl **** Create a dll makefile from config.status ****
 363 dnl
 364 dnl Usage: WINE_CONFIG_DLL(name,enable,implib,implibsrc)
 365 dnl
 366 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 367 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 368 wine_fn_config_dll [$1] ac_enable [$3] m4_ifval([$4],["$4"])dnl
 369 AS_VAR_POPDEF([ac_enable])])
 370
 371 dnl **** Create a program makefile from config.status ****
 372 dnl
 373 dnl Usage: WINE_CONFIG_PROGRAM(name,install,enable)
 374 dnl
 375 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 376 AS_VAR_PUSHDEF([ac_enable],m4_default([$3],[enable_]$1))dnl
 377 wine_fn_config_program [$1] ac_enable [$2]dnl
 378 AS_VAR_POPDEF([ac_enable])])
 379
 380 dnl **** Create a test makefile from config.status ****
 381 dnl
 382 dnl Usage: WINE_CONFIG_TEST(dir)
 383 dnl
 384 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 385 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 386 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 387 wine_fn_config_test $1 ac_name[]ac_suffix[]dnl
 388 m4_popdef([ac_suffix])dnl
 389 m4_popdef([ac_name])])
 390
 391 dnl **** Create a static lib makefile from config.status ****
 392 dnl
 393 dnl Usage: WINE_CONFIG_LIB(name)
 394 dnl
 395 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 396 wine_fn_config_lib $1])
 397
 398 dnl **** Create a tool makefile from config.status ****
 399 dnl
 400 dnl Usage: WINE_CONFIG_TOOL(name)
 401 dnl
 402 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 403 wine_fn_config_tool $1])
 404
 405 dnl **** Add a message to the list displayed at the end ****
 406 dnl
 407 dnl Usage: WINE_NOTICE(notice)
 408 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 409 dnl Usage: WINE_WARNING(warning)
 410 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 411 dnl Usage: WINE_PRINT_MESSAGES
 412 dnl
 413 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 414 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 415
 416 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 417   x)   WINE_NOTICE([$3]) ;;
 418   xno) ;;
 419   *)   AC_MSG_ERROR([$3
 420 This is an error since --with-$1 was requested.]) ;;
 421 esac])])
 422
 423 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 424   x)   WINE_WARNING([$3]) ;;
 425   xno) ;;
 426   *)   AC_MSG_ERROR([$3
 427 This is an error since --with-$1 was requested.]) ;;
 428 esac])])
 429
 430 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 431   xno) ;;
 432   *)   AC_MSG_ERROR([$3
 433 Use the --without-$1 option if you really want this.]) ;;
 434 esac])])
 435
 436 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 437 if test "x$wine_notices != "x; then
 438     echo >&AS_MESSAGE_FD
 439     IFS="|"
 440     for msg in $wine_notices; do
 441         IFS="$ac_save_IFS"
 442         if test -n "$msg"; then
 443             AC_MSG_NOTICE([$msg])
 444         fi
 445     done
 446 fi
 447 IFS="|"
 448 for msg in $wine_warnings; do
 449     IFS="$ac_save_IFS"
 450     if test -n "$msg"; then
 451         echo >&2
 452         AC_MSG_WARN([$msg])
 453     fi
 454 done
 455 IFS="$ac_save_IFS"])
 456
 457 dnl Local Variables:
 458 dnl compile-command: "autoreconf --warnings=all"
 459 dnl End: