debugger/dbg.y

   1 %{
   2 /*
   3  * Parser for command lines in the Wine debugger
   4  *
   5  * Copyright 1993 Eric Youngdale
   6  * Copyright 1995 Morten Welinder
   7  * Copyright 2000 Eric Pouech
   8  *
   9  * This library is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public
  11  * License as published by the Free Software Foundation; either
  12  * version 2.1 of the License, or (at your option) any later version.
  13  *
  14  * This library is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with this library; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24 #include "config.h"
  25
  26 #include <stdio.h>
  27 #include <stdlib.h>
  28 #include <string.h>
  29 #include <signal.h>
  30 #include <unistd.h>
  31
  32 #include "wine/exception.h"
  33 #include "debugger.h"
  34 #include "expr.h"
  35 #include "msvcrt/excpt.h"
  36
  37 extern FILE * yyin;
  38
  39 static void mode_command(int);
  40 int yylex(void);
  41 int yyerror(char *);
  42
  43 %}
  44
  45 %union
  46 {
  47     DBG_VALUE        value;
  48     char *           string;
  49     int              integer;
  50     struct list_id   listing;
  51     struct expr *    expression;
  52     struct datatype* type;
  53 }
  54
  55 %token tCONT tPASS tSTEP tLIST tNEXT tQUIT tHELP tBACKTRACE tINFO tWALK tUP tDOWN
  56 %token tENABLE tDISABLE tBREAK tWATCH tDELETE tSET tMODE tPRINT tEXAM tABORT tVM86
  57 %token tCLASS tMAPS tMODULE tSTACK tSEGMENTS tREGS tWND tQUEUE tLOCAL
  58 %token tPROCESS tTHREAD tMODREF tEOL
  59 %token tFRAME tSHARE tCOND tDISPLAY tUNDISPLAY tDISASSEMBLE
  60 %token tSTEPI tNEXTI tFINISH tSHOW tDIR tWHATIS
  61 %token <string> tPATH
  62 %token <string> tIDENTIFIER tSTRING tDEBUGSTR tINTVAR
  63 %token <integer> tNUM tFORMAT
  64 %token tSYMBOLFILE tRUN tATTACH tDETACH tNOPROCESS
  65
  66 %token tCHAR tSHORT tINT tLONG tFLOAT tDOUBLE tUNSIGNED tSIGNED
  67 %token tSTRUCT tUNION tENUM
  68
  69 /* %left ',' */
  70 /* %left '=' OP_OR_EQUAL OP_XOR_EQUAL OP_AND_EQUAL OP_SHL_EQUAL \
  71          OP_SHR_EQUAL OP_PLUS_EQUAL OP_MINUS_EQUAL \
  72          OP_TIMES_EQUAL OP_DIVIDE_EQUAL OP_MODULO_EQUAL */
  73 /* %left OP_COND */ /* ... ? ... : ... */
  74 %left OP_LOR
  75 %left OP_LAND
  76 %left '|'
  77 %left '^'
  78 %left '&'
  79 %left OP_EQ OP_NE
  80 %left '<' '>' OP_LE OP_GE
  81 %left OP_SHL OP_SHR
  82 %left '+' '-'
  83 %left '*' '/' '%'
  84 %left OP_SIGN '!' '~' OP_DEREF /* OP_INC OP_DEC OP_ADDR */
  85 %left '.' '[' OP_DRF
  86 %nonassoc ':'
  87
  88 %type <expression> expr lval lvalue
  89 %type <type> type_expr
  90 %type <value> expr_addr lval_addr
  91 %type <integer> expr_value
  92 %type <string> pathname identifier
  93
  94 %type <listing> list_arg
  95
  96 %%
  97
  98 input: line
  99     | input line
 100     ;
 101
 102 line: command
 103     | tEOL
 104     | error tEOL                { yyerrok; }
 105     ;
 106
 107 command:
 108       tQUIT tEOL                { DEBUG_ExitMode = EXIT_QUIT; return 1; }
 109     | tHELP tEOL                { DEBUG_Help(); }
 110     | tHELP tINFO tEOL          { DEBUG_HelpInfo(); }
 111     | tCONT tEOL                { DEBUG_CurrThread->exec_count = 1;
 112                                   DEBUG_CurrThread->exec_mode = EXEC_CONT; return 1; }
 113     | tPASS tEOL                { DEBUG_ExitMode = EXIT_PASS; return 1; }
 114     | tCONT tNUM tEOL           { DEBUG_CurrThread->exec_count = $2;
 115                                   DEBUG_CurrThread->exec_mode = EXEC_CONT; return 1; }
 116     | tSTEP tEOL                { DEBUG_CurrThread->exec_count = 1;
 117                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_INSTR; return 1; }
 118     | tNEXT tEOL                { DEBUG_CurrThread->exec_count = 1;
 119                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_OVER; return 1; }
 120     | tSTEP tNUM tEOL           { DEBUG_CurrThread->exec_count = $2;
 121                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_INSTR; return 1; }
 122     | tNEXT tNUM tEOL           { DEBUG_CurrThread->exec_count = $2;
 123                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_OVER; return 1; }
 124     | tSTEPI tEOL               { DEBUG_CurrThread->exec_count = 1;
 125                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_INSTR; return 1; }
 126     | tNEXTI tEOL               { DEBUG_CurrThread->exec_count = 1;
 127                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_OVER; return 1; }
 128     | tSTEPI tNUM tEOL          { DEBUG_CurrThread->exec_count = $2;
 129                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_INSTR; return 1; }
 130     | tNEXTI tNUM tEOL          { DEBUG_CurrThread->exec_count = $2;
 131                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_OVER; return 1; }
 132     | tABORT tEOL               { kill(getpid(), SIGABRT); }
 133     | tMODE tNUM tEOL           { mode_command($2); }
 134     | tMODE tVM86 tEOL          { DEBUG_CurrThread->dbg_mode = MODE_VM86; }
 135     | tENABLE tNUM tEOL         { DEBUG_EnableBreakpoint( $2, TRUE ); }
 136     | tDISABLE tNUM tEOL        { DEBUG_EnableBreakpoint( $2, FALSE ); }
 137     | tDELETE tBREAK tNUM tEOL  { DEBUG_DelBreakpoint( $3 ); }
 138     | tBACKTRACE tEOL           { DEBUG_BackTrace(DEBUG_CurrTid, TRUE); }
 139     | tBACKTRACE tNUM tEOL      { DEBUG_BackTrace($2, TRUE); }
 140     | tUP tEOL                  { DEBUG_SetFrame( curr_frame + 1 );  }
 141     | tUP tNUM tEOL             { DEBUG_SetFrame( curr_frame + $2 ); }
 142     | tDOWN tEOL                { DEBUG_SetFrame( curr_frame - 1 );  }
 143     | tDOWN tNUM tEOL           { DEBUG_SetFrame( curr_frame - $2 ); }
 144     | tFRAME tNUM tEOL          { DEBUG_SetFrame( $2 ); }
 145     | tFINISH tEOL              { DEBUG_CurrThread->exec_count = 0;
 146                                   DEBUG_CurrThread->exec_mode = EXEC_FINISH; return 1; }
 147     | tSHOW tDIR tEOL           { DEBUG_ShowDir(); }
 148     | tDIR pathname tEOL        { DEBUG_AddPath( $2 ); }
 149     | tDIR tEOL                 { DEBUG_NukePath(); }
 150     | tDISPLAY tEOL             { DEBUG_InfoDisplay(); }
 151     | tDISPLAY expr tEOL        { DEBUG_AddDisplay($2, 1, 0); }
 152     | tDISPLAY tFORMAT expr tEOL{ DEBUG_AddDisplay($3, $2 >> 8, $2 & 0xff); }
 153     | tDELETE tDISPLAY tNUM tEOL{ DEBUG_DelDisplay( $3 ); }
 154     | tDELETE tDISPLAY tEOL     { DEBUG_DelDisplay( -1 ); }
 155     | tUNDISPLAY tNUM tEOL      { DEBUG_DelDisplay( $2 ); }
 156     | tUNDISPLAY tEOL           { DEBUG_DelDisplay( -1 ); }
 157     | tCOND tNUM tEOL           { DEBUG_AddBPCondition($2, NULL); }
 158     | tCOND tNUM expr tEOL      { DEBUG_AddBPCondition($2, $3); }
 159     | tSYMBOLFILE pathname tEOL { DEBUG_ReadSymbolTable($2); }
 160     | tWHATIS expr_addr tEOL    { DEBUG_PrintType(&$2); DEBUG_FreeExprMem(); }
 161     | tATTACH tNUM tEOL         { if (DEBUG_Attach($2, FALSE)) return 1; }
 162     | tDETACH tEOL              { DEBUG_ExitMode = EXIT_DETACH; return 1; }
 163     | list_command
 164     | disassemble_command
 165     | set_command
 166     | x_command
 167     | print_command
 168     | break_command
 169     | watch_command
 170     | info_command
 171     | walk_command
 172     | run_command
 173     | noprocess_state
 174     ;
 175
 176 set_command: tSET lval_addr '=' expr_value tEOL { DEBUG_WriteMemory(&$2,$4); DEBUG_FreeExprMem(); }
 177     ;
 178
 179 pathname:
 180       tIDENTIFIER              { $$ = $1; }
 181     | tPATH                    { $$ = $1; }
 182     ;
 183
 184 disassemble_command:
 185       tDISASSEMBLE tEOL              { DEBUG_Disassemble( NULL, NULL, 10 ); }
 186     | tDISASSEMBLE expr_addr tEOL    { DEBUG_Disassemble( & $2, NULL, 10 ); }
 187     | tDISASSEMBLE expr_addr ',' expr_addr tEOL { DEBUG_Disassemble( & $2, & $4, 0 ); }
 188     ;
 189
 190 list_command:
 191       tLIST tEOL               { DEBUG_List( NULL, NULL, 10 ); }
 192     | tLIST '-' tEOL           { DEBUG_List( NULL, NULL, -10 ); }
 193     | tLIST list_arg tEOL      { DEBUG_List( & $2, NULL, 10 ); }
 194     | tLIST ',' list_arg tEOL  { DEBUG_List( NULL, & $3, -10 ); }
 195     | tLIST list_arg ',' list_arg tEOL { DEBUG_List( & $2, & $4, 0 ); }
 196     ;
 197
 198 list_arg:
 199       tNUM                     { $$.sourcefile = NULL; $$.line = $1; }
 200     | pathname ':' tNUM        { $$.sourcefile = $1; $$.line = $3; }
 201     | tIDENTIFIER              { DEBUG_GetFuncInfo( & $$, NULL, $1); }
 202     | pathname ':' tIDENTIFIER { DEBUG_GetFuncInfo( & $$, $1, $3); }
 203     | '*' expr_addr            { DEBUG_FindNearestSymbol( & $2.addr, FALSE, NULL, 0, & $$ );
 204                                  DEBUG_FreeExprMem(); }
 205     ;
 206
 207 x_command:
 208       tEXAM expr_addr tEOL     { DEBUG_ExamineMemory( &$2, 1, 'x'); DEBUG_FreeExprMem(); }
 209     | tEXAM tFORMAT expr_addr tEOL  { DEBUG_ExamineMemory( &$3, $2>>8, $2&0xff );
 210                                       DEBUG_FreeExprMem(); }
 211     ;
 212
 213 print_command:
 214       tPRINT expr_addr tEOL    { DEBUG_Print( &$2, 1, 0, 0 ); DEBUG_FreeExprMem(); }
 215     | tPRINT tFORMAT expr_addr tEOL { DEBUG_Print( &$3, $2 >> 8, $2 & 0xff, 0 );
 216                                       DEBUG_FreeExprMem(); }
 217     ;
 218
 219 break_command:
 220       tBREAK '*' expr_addr tEOL{ DEBUG_AddBreakpoint( &$3, NULL ); DEBUG_FreeExprMem(); }
 221     | tBREAK identifier tEOL   { DEBUG_AddBreakpointFromId($2, -1); }
 222     | tBREAK identifier ':' tNUM tEOL  { DEBUG_AddBreakpointFromId($2, $4); }
 223     | tBREAK tNUM tEOL         { DEBUG_AddBreakpointFromLineno($2); }
 224     | tBREAK tEOL              { DEBUG_AddBreakpointFromLineno(-1); }
 225     ;
 226
 227 watch_command:
 228       tWATCH '*' expr_addr tEOL { DEBUG_AddWatchpoint( &$3, 1 ); DEBUG_FreeExprMem(); }
 229     | tWATCH identifier tEOL    { DEBUG_AddWatchpointFromId($2); }
 230     ;
 231
 232 info_command:
 233       tINFO tBREAK tEOL         { DEBUG_InfoBreakpoints(); }
 234     | tINFO tCLASS tSTRING tEOL { DEBUG_InfoClass( $3 ); }
 235     | tINFO tSHARE tEOL         { DEBUG_InfoShare(); }
 236     | tINFO tMODULE expr_value tEOL   { DEBUG_DumpModule( $3 ); DEBUG_FreeExprMem(); }
 237     | tINFO tQUEUE expr_value tEOL    { DEBUG_DumpQueue( $3 ); DEBUG_FreeExprMem(); }
 238     | tINFO tREGS tEOL          { DEBUG_InfoRegisters(); }
 239     | tINFO tSEGMENTS expr_value tEOL { DEBUG_InfoSegments( $3, 1 ); DEBUG_FreeExprMem(); }
 240     | tINFO tSEGMENTS tEOL      { DEBUG_InfoSegments( 0, -1 ); }
 241     | tINFO tSTACK tEOL         { DEBUG_InfoStack(); }
 242     | tINFO tMAPS tEOL          { DEBUG_InfoVirtual(); }
 243     | tINFO tWND expr_value tEOL{ DEBUG_InfoWindow( (HWND)$3 ); DEBUG_FreeExprMem(); }
 244     | tINFO tLOCAL tEOL         { DEBUG_InfoLocals(); }
 245     | tINFO tDISPLAY tEOL       { DEBUG_InfoDisplay(); }
 246     ;
 247
 248 walk_command:
 249       tWALK tCLASS tEOL         { DEBUG_WalkClasses(); }
 250     | tWALK tMODULE tEOL        { DEBUG_WalkModules(); }
 251     | tWALK tQUEUE tEOL         { DEBUG_WalkQueues(); }
 252     | tWALK tWND tEOL           { DEBUG_WalkWindows( 0, 0 ); }
 253     | tWALK tWND tNUM tEOL      { DEBUG_WalkWindows( (HWND)$3, 0 ); }
 254     | tWALK tPROCESS tEOL       { DEBUG_WalkProcess(); }
 255     | tWALK tTHREAD tEOL        { DEBUG_WalkThreads(); }
 256     | tWALK tMODREF expr_value tEOL   { DEBUG_WalkModref( $3 ); DEBUG_FreeExprMem(); }
 257     ;
 258
 259 run_command:
 260       tRUN tEOL                 { DEBUG_Run(NULL); }
 261     | tRUN tSTRING tEOL         { DEBUG_Run($2); }
 262     ;
 263
 264 noprocess_state:
 265       tNOPROCESS tEOL           {} /* <CR> shall not barf anything */
 266     | tNOPROCESS tSTRING tEOL   { DEBUG_Printf(DBG_CHN_MESG, "No process loaded, cannot execute '%s'\n", $2); }
 267     ;
 268
 269 type_expr:
 270       type_expr '*'             { $$ = $1 ? DEBUG_FindOrMakePointerType($1) : NULL; }
 271     | tINT                      { $$ = DEBUG_GetBasicType(DT_BASIC_INT); }
 272     | tCHAR                     { $$ = DEBUG_GetBasicType(DT_BASIC_CHAR); }
 273     | tLONG tINT                { $$ = DEBUG_GetBasicType(DT_BASIC_LONGINT); }
 274     | tUNSIGNED tINT            { $$ = DEBUG_GetBasicType(DT_BASIC_UINT); }
 275     | tLONG tUNSIGNED tINT      { $$ = DEBUG_GetBasicType(DT_BASIC_ULONGINT); }
 276     | tLONG tLONG tINT          { $$ = DEBUG_GetBasicType(DT_BASIC_LONGLONGINT); }
 277     | tLONG tLONG tUNSIGNED tINT{ $$ = DEBUG_GetBasicType(DT_BASIC_ULONGLONGINT); }
 278     | tSHORT tINT               { $$ = DEBUG_GetBasicType(DT_BASIC_SHORTINT); }
 279     | tSHORT tUNSIGNED tINT     { $$ = DEBUG_GetBasicType(DT_BASIC_USHORTINT); }
 280     | tSIGNED tCHAR             { $$ = DEBUG_GetBasicType(DT_BASIC_SCHAR); }
 281     | tUNSIGNED tCHAR           { $$ = DEBUG_GetBasicType(DT_BASIC_UCHAR); }
 282     | tFLOAT                    { $$ = DEBUG_GetBasicType(DT_BASIC_FLOAT); }
 283     | tDOUBLE                   { $$ = DEBUG_GetBasicType(DT_BASIC_DOUBLE); }
 284     | tLONG tDOUBLE             { $$ = DEBUG_GetBasicType(DT_BASIC_LONGDOUBLE); }
 285     | tSTRUCT tIDENTIFIER       { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 286     | tUNION tIDENTIFIER        { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 287     | tENUM tIDENTIFIER         { $$ = DEBUG_TypeCast(DT_ENUM, $2); }
 288     ;
 289
 290 expr_addr: expr                 { $$ = DEBUG_EvalExpr($1); }
 291     ;
 292
 293 expr_value: expr                { DBG_VALUE value = DEBUG_EvalExpr($1);
 294                                   /* expr_value is typed as an integer */
 295                                   $$ = DEBUG_ReadMemory(&value); }
 296     ;
 297
 298 /*
 299  * The expr rule builds an expression tree.  When we are done, we call
 300  * EvalExpr to evaluate the value of the expression.  The advantage of
 301  * the two-step approach is that it is possible to save expressions for
 302  * use in 'display' commands, and in conditional watchpoints.
 303  */
 304 expr:
 305       tNUM                       { $$ = DEBUG_ConstExpr($1); }
 306     | tSTRING                    { $$ = DEBUG_StringExpr($1); }
 307     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 308     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 309     | expr OP_DRF tIDENTIFIER    { $$ = DEBUG_StructPExpr($1, $3); }
 310     | expr '.' tIDENTIFIER       { $$ = DEBUG_StructExpr($1, $3); }
 311     | tIDENTIFIER '(' ')'        { $$ = DEBUG_CallExpr($1, 0); }
 312     | tIDENTIFIER '(' expr ')'   { $$ = DEBUG_CallExpr($1, 1, $3); }
 313     | tIDENTIFIER '(' expr ',' expr ')'  { $$ = DEBUG_CallExpr($1, 2, $3, $5); }
 314     | tIDENTIFIER '(' expr ',' expr ',' expr ')'         { $$ = DEBUG_CallExpr($1, 3, $3, $5, $7); }
 315     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ')'        { $$ = DEBUG_CallExpr($1, 4, $3, $5, $7, $9); }
 316     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ',' expr ')'       { $$ = DEBUG_CallExpr($1, 5, $3, $5, $7, $9, $11); }
 317     | expr '[' expr ']'          { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 318     | expr ':' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SEG, $1, $3); }
 319     | expr OP_LOR expr           { $$ = DEBUG_BinopExpr(EXP_OP_LOR, $1, $3); }
 320     | expr OP_LAND expr          { $$ = DEBUG_BinopExpr(EXP_OP_LAND, $1, $3); }
 321     | expr '|' expr              { $$ = DEBUG_BinopExpr(EXP_OP_OR, $1, $3); }
 322     | expr '&' expr              { $$ = DEBUG_BinopExpr(EXP_OP_AND, $1, $3); }
 323     | expr '^' expr              { $$ = DEBUG_BinopExpr(EXP_OP_XOR, $1, $3); }
 324     | expr OP_EQ expr            { $$ = DEBUG_BinopExpr(EXP_OP_EQ, $1, $3); }
 325     | expr '>' expr              { $$ = DEBUG_BinopExpr(EXP_OP_GT, $1, $3); }
 326     | expr '<' expr              { $$ = DEBUG_BinopExpr(EXP_OP_LT, $1, $3); }
 327     | expr OP_GE expr            { $$ = DEBUG_BinopExpr(EXP_OP_GE, $1, $3); }
 328     | expr OP_LE expr            { $$ = DEBUG_BinopExpr(EXP_OP_LE, $1, $3); }
 329     | expr OP_NE expr            { $$ = DEBUG_BinopExpr(EXP_OP_NE, $1, $3); }
 330     | expr OP_SHL expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHL, $1, $3); }
 331     | expr OP_SHR expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHR, $1, $3); }
 332     | expr '+' expr              { $$ = DEBUG_BinopExpr(EXP_OP_ADD, $1, $3); }
 333     | expr '-' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SUB, $1, $3); }
 334     | expr '*' expr              { $$ = DEBUG_BinopExpr(EXP_OP_MUL, $1, $3); }
 335     | expr '/' expr              { $$ = DEBUG_BinopExpr(EXP_OP_DIV, $1, $3); }
 336     | expr '%' expr              { $$ = DEBUG_BinopExpr(EXP_OP_REM, $1, $3); }
 337     | '-' expr %prec OP_SIGN     { $$ = DEBUG_UnopExpr(EXP_OP_NEG, $2); }
 338     | '+' expr %prec OP_SIGN     { $$ = $2; }
 339     | '!' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_NOT, $2); }
 340     | '~' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_LNOT, $2); }
 341     | '(' expr ')'               { $$ = $2; }
 342     | '*' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_DEREF, $2); }
 343     | '&' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_ADDR, $2); }
 344     | '(' type_expr ')' expr %prec OP_DEREF { $$ = DEBUG_TypeCastExpr($2, $4); }
 345     ;
 346
 347 /*
 348  * The lvalue rule builds an expression tree.  This is a limited form
 349  * of expression that is suitable to be used as an lvalue.
 350  */
 351 lval_addr: lval                  { $$ = DEBUG_EvalExpr($1); }
 352     ;
 353
 354 lval: lvalue                     { $$ = $1; }
 355     | '*' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_FORCE_DEREF, $2); }
 356     ;
 357
 358 lvalue: tNUM                     { $$ = DEBUG_ConstExpr($1); }
 359     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 360     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 361     | lvalue OP_DRF tIDENTIFIER  { $$ = DEBUG_StructPExpr($1, $3); }
 362     | lvalue '.' tIDENTIFIER     { $$ = DEBUG_StructExpr($1, $3); }
 363     | lvalue '[' expr ']'        { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 364     ;
 365
 366 identifier: tIDENTIFIER          { $$ = $1; }
 367     | identifier '.' tIDENTIFIER { char* ptr = DBG_alloc(strlen($1) + 1 + strlen($3)+ 1);
 368                                    sprintf(ptr, "%s.%s", $1, $3); $$ = DEBUG_MakeSymbol(ptr);
 369                                    DBG_free(ptr); }
 370     | identifier ':' ':' tIDENTIFIER { char* ptr = DBG_alloc(strlen($1) + 2 + strlen($4) + 1);
 371                                    sprintf(ptr, "%s::%s", $1, $4); $$ = DEBUG_MakeSymbol(ptr);
 372                                    DBG_free(ptr); }
 373     ;
 374
 375 %%
 376
 377 static void mode_command(int newmode)
 378 {
 379     switch(newmode)
 380     {
 381     case 16: DEBUG_CurrThread->dbg_mode = MODE_16; break;
 382     case 32: DEBUG_CurrThread->dbg_mode = MODE_32; break;
 383     default: DEBUG_Printf(DBG_CHN_MESG,"Invalid mode (use 16, 32 or vm86)\n");
 384     }
 385 }
 386
 387 void DEBUG_Exit(DWORD ec)
 388 {
 389    ExitProcess(ec);
 390 }
 391
 392 static WINE_EXCEPTION_FILTER(wine_dbg_cmd)
 393 {
 394    DEBUG_Printf(DBG_CHN_MESG, "\nwine_dbg_cmd: ");
 395    switch (GetExceptionCode()) {
 396    case DEBUG_STATUS_INTERNAL_ERROR:
 397       DEBUG_Printf(DBG_CHN_MESG, "WineDbg internal error\n");
 398       break;
 399    case DEBUG_STATUS_NO_SYMBOL:
 400       DEBUG_Printf(DBG_CHN_MESG, "Undefined symbol\n");
 401       break;
 402    case DEBUG_STATUS_DIV_BY_ZERO:
 403       DEBUG_Printf(DBG_CHN_MESG, "Division by zero\n");
 404       break;
 405    case DEBUG_STATUS_BAD_TYPE:
 406       DEBUG_Printf(DBG_CHN_MESG, "No type or type mismatch\n");
 407       break;
 408    case DEBUG_STATUS_NO_FIELD:
 409       DEBUG_Printf(DBG_CHN_MESG, "No such field in structure or union\n");
 410       break;
 411    default:
 412       DEBUG_Printf(DBG_CHN_MESG, "Exception %lx\n", GetExceptionCode());
 413       break;
 414    }
 415
 416    return EXCEPTION_EXECUTE_HANDLER;
 417 }
 418
 419 /***********************************************************************
 420  *           DEBUG_Parser
 421  *
 422  * Debugger editline parser
 423  */
 424 void    DEBUG_Parser(void)
 425 {
 426     BOOL                ret_ok;
 427 #ifdef YYDEBUG
 428     yydebug = 0;
 429 #endif
 430     yyin = stdin;
 431
 432     DEBUG_ExitMode = EXIT_CONTINUE;
 433
 434     ret_ok = FALSE;
 435     do {
 436        __TRY {
 437           ret_ok = TRUE;
 438           yyparse();
 439        } __EXCEPT(wine_dbg_cmd) {
 440           ret_ok = FALSE;
 441        }
 442        __ENDTRY;
 443        DEBUG_FlushSymbols();
 444     } while (!ret_ok);
 445 }
 446
 447 int yyerror(char* s)
 448 {
 449    DEBUG_Printf(DBG_CHN_MESG, "%s\n", s);
 450    return 0;
 451 }