| blob | f6c2ab87b68bfee95901b3664c50cf8f6a541ac4 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION)
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
23 AC_SUBST(OPTIONS)
24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
26 if test "x$enable_win16" = "xno"
27 then
28 WIN16_FILES=""
29 WIN16_INSTALL=""
30 fi
31 if test "x$enable_debug" = "xno"
32 then
33 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
34 fi
35 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
36 then
37 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
38 fi
40 dnl **** Check for some programs ****
42 AC_CANONICAL_HOST
43 AC_PROG_MAKE_SET
44 AC_PROG_CC
45 AC_PROG_CPP
47 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
48 [if test -z "$with_wine_tools"; then
49 if test "$cross_compiling" = "yes"; then
50 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
51 else
52 wine_cv_toolsdir="\$(TOPOBJDIR)"
53 fi
54 elif test -d "$with_wine_tools/tools/winebuild"; then
55 case $with_wine_tools in
56 /*) wine_cv_toolsdir="$with_wine_tools" ;;
57 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
58 esac
59 else
60 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
61 fi])
62 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
64 AC_PATH_XTRA
65 AC_PROG_YACC
66 AC_PROG_LEX
68 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
69 dnl **** without one present.
70 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
71 if test "$XYACC" = "none"
72 then
73 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
74 fi
75 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
76 if test "$XLEX" = "none"
77 then
78 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
79 fi
81 AC_CHECK_TOOL(AS,as,as)
82 AC_CHECK_TOOL(LD,ld,ld)
83 AC_CHECK_TOOL(AR,ar,ar)
84 AC_PROG_RANLIB
85 AC_CHECK_TOOL(STRIP,strip,strip)
86 AC_CHECK_TOOL(WINDRES,windres,false)
87 AC_PROG_LN_S
88 WINE_PROG_LN
89 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
90 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
91 AC_PROG_INSTALL
92 dnl Prepend src dir to install path dir if it's a relative path
93 case "$INSTALL" in
94 [[\\/$]]* | ?:[[\\/]]* ) ;;
95 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
96 esac
98 dnl Check for lint
99 AC_CHECK_PROGS(LINT, lclint lint)
100 if test "$LINT" = "lint"
101 then
102 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
103 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
104 fi
105 AC_SUBST(LINT)
106 AC_SUBST(LINTFLAGS)
108 dnl Check for db2html
109 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
110 AC_SUBST(DB2HTML)
112 dnl Check for db2pdf
113 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
114 AC_SUBST(DB2PDF)
116 dnl Check for db2ps
117 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
118 AC_SUBST(DB2PS)
120 dnl **** Check for some libraries ****
122 dnl Check for -lm
123 AC_CHECK_LIB(m,sqrt)
124 dnl Check for -li386 for NetBSD and OpenBSD
125 AC_CHECK_LIB(i386,i386_set_ldt)
126 dnl Check for -lossaudio for NetBSD
127 AC_CHECK_LIB(ossaudio,_oss_ioctl)
128 dnl Check for -lw for Solaris
129 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
130 dnl Check for -lnsl for Solaris
131 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
132 dnl Check for -lsocket for Solaris
133 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
134 dnl Check for -lresolv for Solaris
135 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
136 dnl Check for -lxpg4 for FreeBSD
137 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
138 dnl Check for -lmmap for OS/2
139 AC_CHECK_LIB(mmap,mmap)
141 JPEGLIB=""
142 AC_SUBST(JPEGLIB)
143 AC_CHECK_HEADERS(jpeglib.h,
144 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
145 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
146 JPEGLIB="-ljpeg"
147 )
148 )
150 AC_SUBST(GIFLIB,"")
151 AC_CHECK_HEADERS(gif_lib.h,
152 AC_CHECK_LIB(ungif,DGifOpen,
153 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
154 GIFLIB="-lungif"],
155 [AC_CHECK_LIB(gif,DGifOpen,
156 [AC_DEFINE(HAVE_LIBGIF,1)
157 GIFLIB="-lgif"])]))
160 AC_SUBST(XLIB)
161 AC_SUBST(XFILES)
162 XFILES=""
163 AC_SUBST(OPENGLFILES)
164 OPENGLFILES=""
165 AC_SUBST(GLU32FILES)
166 GLU32FILES=""
167 AC_SUBST(OPENGL_LIBS)
168 OPENGL_LIBS=""
169 if test "$have_x" = "yes"
170 then
171 XLIB="-lXext -lX11"
172 ac_save_CPPFLAGS="$CPPFLAGS"
173 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
175 dnl *** All of the following tests require X11/Xlib.h
176 AC_CHECK_HEADERS(X11/Xlib.h,
177 [
178 dnl *** Check for X keyboard extension
179 AC_CHECK_HEADERS(X11/XKBlib.h,
180 [ dnl *** If X11/XKBlib.h exists...
181 AC_CHECK_LIB(X11, XkbQueryExtension,
182 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
183 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
184 ],
185 AC_MSG_WARN([[Xkb extension not found, Wine will be built without it]]),
186 [#include <X11/Xlib.h>])
188 dnl *** Check for X Shm extension
189 AC_CHECK_HEADERS(X11/extensions/XShm.h,
190 [ dnl *** If X11/extensions/XShm.h exists...
191 AC_CHECK_LIB(Xext, XShmQueryExtension,
192 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
193 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
194 ],
195 AC_MSG_WARN([[XShm extension not found, Wine will be built without it]]),
196 [#include <X11/Xlib.h>])
198 dnl *** Check for Xutil
199 AC_CHECK_HEADERS(X11/Xutil.h,,,
200 [#include <X11/Xlib.h>])
202 dnl *** Check for X shape extension
203 AC_CHECK_HEADERS(X11/extensions/shape.h,
204 [ dnl *** If X11/extensions/shape.h exists...
205 AC_CHECK_LIB(Xext,XShapeQueryExtension,
206 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
207 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
208 ],
209 AC_MSG_WARN([[XShape extension not found, Wine will be built without it]]),
210 [#include <X11/Xlib.h>
211 #ifdef HAVE_X11_XUTIL_H
212 # include <X11/Xutil.h>
213 #endif])
215 dnl *** Check for XFree86 DGA / DGA 2.0 extension
216 AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
217 [ dnl *** If X11/extensions/xf86dga.h exists, check
218 dnl *** for XDGAQueryExtension()...
219 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
220 [ dnl *** If found...
221 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
222 [Define if you have the Xxf86dga library version 2])
223 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
224 ],
225 [ dnl *** If not found, look for XF86DGAQueryExtension()
226 dnl *** instead (DGA 2.0 not found)...
227 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
228 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
229 [Define if you have the Xxf86dga library version 1])
230 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
231 ],,
232 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
233 )
234 ],
235 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
236 )
237 ],
238 AC_MSG_WARN([[DGA extension not found, Wine will be built without it]]),
239 [#include <X11/Xlib.h>])
241 dnl *** Check for XFree86 VMODE extension
242 AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
243 [ dnl *** If X11/extensions/xf86vmode.h exists...
244 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
245 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
246 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
247 ],,
248 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
249 )
250 ],
251 AC_MSG_WARN([[XFree86 VMODE extension not found, Wine will be built without it]]),
252 [#include <X11/Xlib.h>])
254 dnl *** Check for XVideo extension supporting XvImages
255 AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
256 [ dnl *** If X11/extensions/Xvlib.h exists...
257 AC_CHECK_LIB(Xv, XvShmCreateImage,
258 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
259 X_PRE_LIBS="$X_PRE_LIBS -lXv"
260 ],,
261 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
262 )
263 ],
264 AC_MSG_WARN([[XVideo extension not found, Wine will be built without it]]),
265 [#include <X11/Xlib.h>])
267 dnl *** Check for XRender include file
268 AC_CHECK_HEADERS(X11/extensions/Xrender.h,,,[#include <X11/Xlib.h>])
269 ]
270 ) dnl *** End of X11/Xlib.h check
272 dnl Check for the presence of OpenGL
273 if test "x$with_opengl" != "xno"
274 then
275 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
276 then
277 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
278 This prevents linking to OpenGL. Delete the file and restart configure.])
279 fi
281 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
282 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
283 then
284 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
285 dnl Check for some problems due to old Mesa versions
286 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
287 AC_TRY_COMPILE(
288 [#include <GL/gl.h>],
289 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
290 [wine_cv_opengl_version_OK="yes"],
291 [wine_cv_opengl_version_OK="no"]
292 )
293 )
295 if test "$wine_cv_opengl_version_OK" = "yes"
296 then
297 dnl Check for the presence of the library
298 AC_CHECK_LIB(GL,glXCreateContext,
299 OPENGL_LIBS="-lGL"
300 ,,
301 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
303 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
304 then
305 OPENGLFILES='$(OPENGLFILES)'
306 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
308 AC_CHECK_LIB(GL,glXGetProcAddressARB,
309 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
310 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
311 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
313 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
314 then
315 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
316 [AC_TRY_COMPILE([#include <GL/gl.h>
317 #ifdef HAVE_GL_GLEXT_H
318 # include <GL/glext.h>
319 #endif
320 ],
321 [PFNGLCOLORTABLEEXTPROC test_proc;],
322 [wine_cv_extension_prototypes="yes"],
323 [wine_cv_extension_prototypes="no"]
324 )]
325 )
326 if test "$wine_cv_extension_prototypes" = "yes"
327 then
328 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
329 [Define if the OpenGL headers define extension typedefs])
330 fi
331 fi
333 fi
334 dnl Check for GLU32 library.
335 AC_CHECK_LIB(GLU,gluLookAt,
336 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
337 GLU32FILES='$(GLU32FILES)']
338 ,,
339 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
340 )
341 fi
342 fi
343 fi
345 dnl **** Check for NAS ****
346 AC_SUBST(NASLIBS,"")
347 AC_CHECK_HEADERS(audio/audiolib.h,
348 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
349 AC_CHECK_LIB(audio,AuCreateFlow,
350 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
351 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
352 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
354 CPPFLAGS="$ac_save_CPPFLAGS"
355 XFILES='$(XFILES)'
356 else
357 XLIB=""
358 X_CFLAGS=""
359 X_LIBS=""
360 fi
362 dnl **** Check which curses lib to use ***
363 CURSESLIBS=""
364 if test "x$with_curses" != "xno"
365 then
366 AC_CHECK_HEADERS(ncurses.h,
367 [AC_CHECK_LIB(ncurses,waddch,
368 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
369 CURSESLIBS="-lncurses"],
370 [AC_CHECK_HEADERS(curses.h,
371 [AC_CHECK_LIB(curses,waddch,
372 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
373 CURSESLIBS="-lcurses"])])])])
374 saved_libs="$LIBS"
375 LIBS="$CURSESLIBS $LIBS"
376 AC_CHECK_FUNCS(getbkgd resizeterm)
377 LIBS="$saved_libs"
378 fi
379 AC_SUBST(CURSESLIBS)
381 dnl **** Check for SANE ****
382 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
383 if test "$sane_devel" = "no"
384 then
385 SANELIBS=""
386 SANEINCL=""
387 else
388 SANELIBS="`$sane_devel --libs`"
389 SANEINCL="`$sane_devel --cflags`"
390 ac_save_CPPFLAGS="$CPPFLAGS"
391 ac_save_LIBS="$LIBS"
392 CPPFLAGS="$CPPFLAGS $SANEINCL"
393 LIBS="$LIBS $SANELIBS"
394 AC_CHECK_HEADER(sane/sane.h,
395 [AC_CHECK_LIB(sane,sane_open,
396 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
397 [SANELIBS=""
398 SANEINCL=""])],
399 [SANELIBS=""
400 SANEINCL=""])
401 LIBS="$ac_save_LIBS"
402 CPPFLAGS="$ac_save_CPPFLAGS"
403 fi
404 AC_SUBST(SANELIBS)
405 AC_SUBST(SANEINCL)
407 dnl **** Check for FreeType 2 ****
408 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
409 if test "$ft_lib" = "no"
410 then
411 FREETYPEINCL=""
412 wine_cv_msg_freetype=no
413 else
414 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
415 if test "$ft_devel" = "no"
416 then
417 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
418 if test "$ft_devel2" = "freetype2-config"
419 then
420 ft_devel=$ft_devel2
421 fi
422 fi
423 if test "$ft_devel" = "no"
424 then
425 FREETYPEINCL=""
426 wine_cv_msg_freetype=yes
427 else
428 FREETYPEINCL=`$ft_devel --cflags`
429 ac_save_CPPFLAGS="$CPPFLAGS"
430 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
431 AC_CHECK_HEADERS(freetype/freetype.h \
432 freetype/ftglyph.h \
433 freetype/tttables.h \
434 freetype/ftnames.h \
435 freetype/ftsnames.h \
436 freetype/ttnameid.h \
437 freetype/ftoutln.h \
438 freetype/internal/sfnt.h)
439 AC_TRY_CPP([#include <ft2build.h>
440 #include <freetype/fttrigon.h>],
441 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
442 [Define if you have the <freetype/fttrigon.h> header file.])
443 wine_cv_fttrigon=yes],
444 wine_cv_fttrigon=no)
445 CPPFLAGS="$ac_save_CPPFLAGS"
446 dnl Check that we have at least freetype/freetype.h
447 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
448 then
449 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
450 wine_cv_msg_freetype=no
451 else
452 FREETYPEINCL=""
453 wine_cv_msg_freetype=yes
454 fi
455 fi
456 fi
457 AC_SUBST(FREETYPEINCL)
459 dnl **** Check for parport (currently Linux only) ****
460 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
461 AC_TRY_COMPILE(
462 [#include <linux/ppdev.h>],
463 [ioctl (1,PPCLAIM,0)],
464 [ac_cv_c_ppdev="yes"],
465 [ac_cv_c_ppdev="no"])
466 )
467 if test "$ac_cv_c_ppdev" = "yes"
468 then
469 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
470 fi
472 dnl **** Check for va_copy ****
473 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
474 AC_TRY_LINK(
475 [#include <stdarg.h>],
476 [va_list ap1, ap2;
477 va_copy(ap1,ap2);
478 ],
479 [ac_cv_c_va_copy="yes"],
480 [ac_cv_c_va_copy="no"])
481 )
482 if test "$ac_cv_c_va_copy" = "yes"
483 then
484 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
485 fi
486 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
487 AC_TRY_LINK(
488 [#include <stdarg.h>],
489 [va_list ap1, ap2;
490 __va_copy(ap1,ap2);
491 ],
492 [ac_cv_c___va_copy="yes"],
493 [ac_cv_c___va_copy="no"])
494 )
495 if test "$ac_cv_c___va_copy" = "yes"
496 then
497 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
498 fi
500 dnl **** Check for Open Sound System ****
501 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
503 AC_CACHE_CHECK([for Open Sound System],
504 ac_cv_c_opensoundsystem,
505 AC_TRY_COMPILE([
506 #if defined(HAVE_SYS_SOUNDCARD_H)
507 #include <sys/soundcard.h>
508 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
509 #include <machine/soundcard.h>
510 #elif defined(HAVE_SOUNDCARD_H)
511 #include <soundcard.h>
512 #endif
513 ],[
515 /* check for one of the Open Sound System specific SNDCTL_ defines */
516 #if !defined(SNDCTL_DSP_STEREO)
517 #error No open sound system
518 #endif
519 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
521 if test "$ac_cv_c_opensoundsystem" = "yes"
522 then
523 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
524 fi
526 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
527 ac_cv_c_opensoundsystem_midi,
528 AC_TRY_COMPILE([
529 #if defined(HAVE_SYS_SOUNDCARD_H)
530 #include <sys/soundcard.h>
531 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
532 #include <machine/soundcard.h>
533 #elif defined(HAVE_SOUNDCARD_H)
534 #include <soundcard.h>
535 #endif
536 ],[
538 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
539 #if !defined(SNDCTL_SEQ_SYNC)
540 #error No open sound system MIDI interface
541 #endif
542 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
544 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
545 then
546 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
547 fi
549 dnl **** Check for aRts Sound Server ****
550 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
551 AC_CACHE_CHECK([for aRts Sound server],
552 ac_cv_c_artsserver,
553 if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
554 then
555 ac_cv_c_artsserver=no
556 else
557 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
558 ARTSC_LIBS=`$ARTSCCONFIG --libs`
559 ac_cv_c_artsserver=no
560 save_CFLAGS="$CFLAGS"
561 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
562 AC_TRY_COMPILE([
563 #include <artsc.h>
564 ],[
565 arts_stream_t stream;
566 ],[
567 ac_cv_c_artsserver=yes
568 ])
569 CFLAGS="$save_CFLAGS"
570 fi)
572 if test "$ac_cv_c_artsserver" = "yes"
573 then
574 AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
575 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
577 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
578 fi
580 dnl **** Check for ALSA ****
581 AC_SUBST(ALSALIBS,"")
582 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
583 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
584 then
585 AC_CHECK_LIB(asound,snd_pcm_open,
586 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
587 ALSALIBS="-lasound")
588 fi
590 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
592 AC_SUBST(AUDIOIOLIBS,"")
593 AC_CHECK_HEADERS(libaudioio.h,
594 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
595 [AUDIOIOLIBS="-laudioio"
596 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
598 dnl **** Check for broken glibc mmap64 ****
600 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
601 AC_TRY_RUN([
602 #define _FILE_OFFSET_BITS 64
603 #include <stdio.h>
604 #include <unistd.h>
605 #include <fcntl.h>
606 #include <sys/mman.h>
607 #include <errno.h>
609 int main(int argc,char **argv) {
610 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
611 if (fd == -1) exit(1);
613 unlink("conftest.map");
615 write(fd,"test",4);
617 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
618 (errno == EINVAL)
619 ) {
620 exit(1);
621 }
622 close(fd);
623 fprintf(stderr,"success!\n");
624 exit(0);
625 }
627 ],
628 ac_cv_mmap64_works="yes",
629 ac_cv_mmap64_works="no",
630 ac_cv_mmap64_works="no") )
632 if test "$ac_cv_mmap64_works" = "yes"
633 then
634 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
635 fi
637 dnl **** Check for gcc specific options ****
639 if test "x${GCC}" = "xyes"
640 then
641 CFLAGS="$CFLAGS -Wall"
643 dnl Check for strength-reduce bug
644 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
645 AC_TRY_RUN([
646 int L[[4]] = {0,1,2,3};
647 int main(void) {
648 static int Array[[3]];
649 unsigned int B = 3;
650 int i;
651 for(i=0; i<B; i++) Array[[i]] = i - 3;
652 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
653 L[[i]] = 4;
655 exit( Array[[1]] != -2 || L[[2]] != 3);
656 }],
657 ac_cv_c_gcc_strength_bug="no",
658 ac_cv_c_gcc_strength_bug="yes",
659 ac_cv_c_gcc_strength_bug="yes") )
660 if test "$ac_cv_c_gcc_strength_bug" = "yes"
661 then
662 CFLAGS="$CFLAGS -fno-strength-reduce"
663 fi
665 dnl Check for -mpreferred-stack-boundary
666 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
667 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
668 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
669 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
670 then
671 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
672 fi
674 dnl Check for -gstabs+ option
675 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
676 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
677 if test "$ac_cv_c_gcc_gstabs" = "yes"
678 then
679 CFLAGS="$CFLAGS -gstabs+"
680 fi
682 dnl Check for noisy string.h
683 saved_CFLAGS="$CFLAGS"
684 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
685 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
686 AC_TRY_COMPILE([#include <string.h>],[],
687 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
688 CFLAGS="$saved_CFLAGS"
689 if test "$ac_cv_c_string_h_warnings" = "no"
690 then
691 CFLAGS="$CFLAGS -Wpointer-arith"
692 fi
693 fi
695 dnl **** Check how to define a function in assembly code ****
697 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
698 WINE_TRY_ASM_LINK(
699 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
700 ac_cv_asm_func_def=".def",
701 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
702 ac_cv_asm_func_def=".type @function",
703 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
704 ac_cv_asm_func_def=".type 2",
705 ac_cv_asm_func_def="unknown")])]))
707 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
708 case "$ac_cv_asm_func_def" in
709 ".def")
710 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
711 ".type @function")
712 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
713 ".type 2")
714 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
715 *)
716 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
717 esac
719 dnl **** Check for underscore on external symbols ****
721 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
722 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
723 [extern int ac_test;],
724 [if (ac_test) return 1],
725 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
727 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
728 if test "$ac_cv_c_extern_prefix" = "yes"
729 then
730 AC_DEFINE([__ASM_NAME(name)], ["_" name])
731 else
732 AC_DEFINE([__ASM_NAME(name)], [name])
733 fi
735 dnl **** Check how to do strings in assembler ****
737 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
738 WINE_TRY_ASM_LINK([".data\n\t.string \"test\"\n\t.text"],,,
739 ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
740 if test "$ac_cv_c_asm_string" = "yes"
741 then
742 AC_DEFINE(__ASM_STRING, [".string"], [Define to the assembler keyword used to specify an ASCII string])
743 else
744 AC_CACHE_CHECK([whether assembler accepts .asciz], ac_cv_c_asm_asciz,
745 WINE_TRY_ASM_LINK([".data\n\t.asciz \"test\"\n\t.text"],,,
746 ac_cv_c_asm_asciz="yes",ac_cv_c_asm_asciz="no"))
747 if test "$ac_cv_c_asm_asciz" = "yes"
748 then
749 AC_DEFINE(__ASM_STRING, [".asciz"])
750 else
751 AC_DEFINE(__ASM_STRING, [".ascii"])
752 fi
753 fi
755 dnl **** Check for .short in assembler ****
757 AC_CACHE_CHECK([whether assembler accepts .short], ac_cv_c_asm_short,
758 WINE_TRY_ASM_LINK([".data\n\t.short 1\n\t.text"],,,
759 ac_cv_c_asm_short="yes",ac_cv_c_asm_short="no"))
760 if test "$ac_cv_c_asm_short" = "yes"
761 then
762 AC_DEFINE(__ASM_SHORT, [".short"], [Define to the assembler keyword used to specify a word value])
763 else
764 AC_DEFINE(__ASM_SHORT, [".half"])
765 fi
767 dnl **** Check for working dll ****
769 AC_SUBST(DLLEXT,"")
770 AC_SUBST(DLLFLAGS,"")
771 AC_SUBST(DLLIBS,"")
772 AC_SUBST(LDDLLFLAGS,"")
773 AC_SUBST(LDSHARED,"")
774 AC_SUBST(LIBEXT,"so")
775 AC_SUBST(IMPLIBEXT,"def")
777 case $host_os in
778 cygwin*|mingw32*)
779 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
780 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
781 if test "$DLLWRAP" = "false"; then
782 LIBEXT="a"
783 else
784 dnl FIXME - check whether dllwrap works correctly...
785 LIBEXT="dll"
786 fi
787 IMPLIBEXT="a"
788 ;;
789 *)
790 AC_CHECK_HEADERS(dlfcn.h,
791 [AC_CHECK_FUNCS(dlopen,,
792 [AC_CHECK_LIB(dl,dlopen,
793 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
794 DLLIBS="-ldl"],
795 [LIBEXT="a"])])],
796 [LIBEXT="a"])
798 if test "$LIBEXT" = "so"
799 then
800 DLLFLAGS="-fPIC"
801 DLLEXT=".so"
802 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
803 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
804 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
805 if test "$ac_cv_c_dll_gnuelf" = "yes"
806 then
807 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
808 LDDLLFLAGS="-Wl,-Bsymbolic"
809 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
810 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
811 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
812 if test "$ac_cv_c_dll_zdefs" = "yes"
813 then
814 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
815 fi
816 AC_CACHE_CHECK([whether we can relocate the executable to 0x3c000000], ac_cv_ld_reloc_exec,
817 [saved_CFLAGS="$CFLAGS"
818 CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x3c000100"
819 AC_TRY_RUN([#include <unistd.h>
820 int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
821 ac_cv_ld_reloc_exec="yes",
822 ac_cv_ld_reloc_exec="no",
823 ac_cv_ld_reloc_exec="no")
824 CFLAGS="$saved_CFLAGS"])
825 if test "$ac_cv_ld_reloc_exec" = "yes"
826 then
827 AC_SUBST(LDEXECFLAGS,["-Wl,--section-start,.interp=0x3c000100"])
828 fi
829 else
830 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
831 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
832 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
833 if test "$ac_cv_c_dll_unixware" = "yes"
834 then
835 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
836 LDDLLFLAGS="-Wl,-B,symbolic"
837 fi
838 fi
839 fi
841 dnl Check for cross compiler to build test programs
842 AC_SUBST(CROSSTEST,"")
843 if test "$cross_compiling" = "no"
844 then
845 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc,false)
846 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool,false)
847 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
848 fi
849 ;;
850 esac
852 if test "$LIBEXT" = "a"; then
853 AC_MSG_ERROR(
854 [could not find a way to build shared libraries.
855 It is currently not possible to build Wine without shared library
856 (.so) support to allow transparent switch between .so and .dll files.
857 If you are using Linux, you will need a newer binutils.]
858 )
859 fi
861 case $build_os in
862 cygwin*|mingw32*)
863 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
864 *)
865 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
866 esac
868 dnl Mingw needs explicit msvcrt for linking libwine
869 AC_SUBST(CRTLIBS,"")
870 case $host_os in
871 mingw32*)
872 CRTLIBS="-lmsvcrt" ;;
873 esac
875 dnl **** Get the soname for libraries that we load dynamically ****
877 if test "$LIBEXT" = "so"
878 then
879 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
880 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
881 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
882 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
883 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
884 WINE_GET_SONAME(cups,cupsGetDefault)
885 WINE_GET_SONAME(jack,jack_client_new)
886 fi
889 dnl **** Check for reentrant libc ****
891 wine_cv_libc_reentrant=no
892 dnl Linux style errno location
893 WINE_CHECK_ERRNO([__errno_location], [wine_cv_libc_reentrant=__errno_location],
894 dnl FreeBSD style errno location
895 WINE_CHECK_ERRNO([__error], [wine_cv_libc_reentrant=__error],
896 dnl Solaris style errno location
897 WINE_CHECK_ERRNO([___errno], [wine_cv_libc_reentrant=___errno],
898 dnl UnixWare style errno location
899 WINE_CHECK_ERRNO([__thr_errno], [wine_cv_libc_reentrant=__thr_errno],
900 dnl NetBSD style errno location
901 WINE_CHECK_ERRNO([__errno], [wine_cv_libc_reentrant=__errno])
902 ))))
904 if test "$wine_cv_libc_reentrant" != "no"
905 then
906 AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
907 [Define to the name of the function returning errno for reentrant libc])
908 fi
910 dnl **** Check for reentrant X libraries ****
911 dnl
912 dnl This may fail to determine whether X libraries are reentrant if
913 dnl AC_PATH_XTRA does not set x_libraries.
915 if test "$have_x" = "yes"
916 then
917 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
918 [libX11_check=none
919 for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
920 if test -r $dir/libX11.so; then
921 libX11_check="-D $dir/libX11.so"
922 break
923 fi
924 if test -r $dir/libX11.a; then
925 libX11_check="$dir/libX11.a"
926 break
927 fi
928 done
929 if test "$libX11_check" != "none"; then
930 if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
931 then
932 wine_cv_x_reentrant=yes
933 else
934 wine_cv_x_reentrant=no
935 fi
936 else
937 wine_cv_x_reentrant=unknown
938 fi])
939 fi
941 dnl **** Check for functions ****
943 AC_FUNC_ALLOCA()
944 AC_CHECK_FUNCS(\
945 _lwp_create \
946 _lwp_self \
947 _pclose \
948 _popen \
949 _snprintf \
950 _spawnvp \
951 _stricmp \
952 _strnicmp \
953 _vsnprintf \
954 chsize \
955 clone \
956 finite \
957 fpclass \
958 ftruncate \
959 ftruncate64 \
960 getnetbyaddr \
961 getnetbyname \
962 getopt_long \
963 getpagesize \
964 getprotobyname \
965 getprotobynumber \
966 getpwuid \
967 getservbyport \
968 gettimeofday \
969 inet_network \
970 lseek64 \
971 lstat \
972 memmove \
973 mmap \
974 pclose \
975 popen \
976 pread \
977 pthread_getspecific \
978 pthread_key_create \
979 pthread_mutex_lock \
980 pthread_mutex_unlock \
981 pthread_setspecific \
982 pwrite \
983 rfork \
984 select \
985 sendmsg \
986 settimeofday \
987 sigaltstack \
988 snprintf \
989 statfs \
990 strcasecmp \
991 strerror \
992 strncasecmp \
993 tcgetattr \
994 timegm \
995 usleep \
996 vfscanf \
997 vsnprintf \
998 wait4 \
999 waitpid \
1000 )
1002 dnl **** Check for header files ****
1004 AC_CHECK_HEADERS(\
1005 arpa/inet.h \
1006 arpa/nameser.h \
1007 cups/cups.h \
1008 direct.h \
1009 elf.h \
1010 float.h \
1011 getopt.h \
1012 ieeefp.h \
1013 io.h \
1014 jack/jack.h \
1015 libio.h \
1016 libutil.h \
1017 link.h \
1018 linux/cdrom.h \
1019 linux/hdreg.h \
1020 linux/input.h \
1021 linux/joystick.h \
1022 linux/major.h \
1023 linux/param.h \
1024 linux/serial.h \
1025 linux/ucdrom.h \
1026 netdb.h \
1027 netinet/in.h \
1028 netinet/in_systm.h \
1029 netinet/tcp.h \
1030 pty.h \
1031 pwd.h \
1032 regex.h \
1033 sched.h \
1034 scsi/sg.h \
1035 socket.h \
1036 stdint.h \
1037 strings.h \
1038 sys/cdio.h \
1039 sys/errno.h \
1040 sys/file.h \
1041 sys/filio.h \
1042 sys/inttypes.h \
1043 sys/ioctl.h \
1044 sys/ipc.h \
1045 sys/link.h \
1046 sys/lwp.h \
1047 sys/mman.h \
1048 sys/modem.h \
1049 sys/msg.h \
1050 sys/param.h \
1051 sys/poll.h \
1052 sys/ptrace.h \
1053 sys/reg.h \
1054 sys/shm.h \
1055 sys/signal.h \
1056 sys/socket.h \
1057 sys/sockio.h \
1058 sys/statfs.h \
1059 sys/strtio.h \
1060 sys/syscall.h \
1061 sys/sysctl.h \
1062 sys/time.h \
1063 sys/times.h \
1064 sys/uio.h \
1065 sys/un.h \
1066 sys/v86.h \
1067 sys/v86intr.h \
1068 sys/vfs.h \
1069 sys/vm86.h \
1070 sys/wait.h \
1071 syscall.h \
1072 termios.h \
1073 unistd.h \
1074 utime.h \
1075 valgrind/memcheck.h
1076 )
1077 AC_HEADER_STAT()
1079 dnl **** Checks for headers that depend on other ones ****
1081 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1082 [#include <sys/types.h>
1083 #if HAVE_SYS_PARAM_H
1084 # include <sys/param.h>
1085 #endif])
1087 AC_CHECK_HEADERS(net/if.h,,,
1088 [#include <sys/types.h>
1089 #if HAVE_SYS_SOCKET_H
1090 # include <sys/socket.h>
1091 #endif])
1093 AC_CHECK_HEADERS(netinet/ip.h,,,
1094 [#include <sys/types.h>
1095 #if HAVE_SYS_SOCKET_H
1096 # include <sys/socket.h>
1097 #endif
1098 #if HAVE_NETINET_IN_SYSTM_H
1099 # include <netinet/in_systm.h>
1100 #endif])
1102 AC_CHECK_HEADERS(resolv.h,,,
1103 [#include <sys/types.h>
1104 #if HAVE_SYS_SOCKET_H
1105 # include <sys/socket.h>
1106 #endif])
1108 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1110 dnl **** Check for IPX headers (currently Linux only) ****
1112 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1113 AC_TRY_COMPILE(
1114 [#include <sys/types.h>
1115 #ifdef HAVE_SYS_SOCKET_H
1116 # include <sys/socket.h>
1117 #endif
1118 #include <netipx/ipx.h>],
1119 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1120 [ac_cv_c_ipx_gnu="yes"],
1121 [ac_cv_c_ipx_gnu="no"])
1122 )
1123 if test "$ac_cv_c_ipx_gnu" = "yes"
1124 then
1125 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1126 fi
1128 if test "$ac_cv_c_ipx_gnu" = "no"
1129 then
1130 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1131 AC_TRY_COMPILE(
1132 [#include <sys/types.h>
1133 #ifdef HAVE_SYS_SOCKET_H
1134 # include <sys/socket.h>
1135 #endif
1136 #include <asm/types.h>
1137 #include <linux/ipx.h>],
1138 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1139 [ac_cv_c_ipx_linux="yes"],
1140 [ac_cv_c_ipx_linux="no"])
1141 )
1142 if test "$ac_cv_c_ipx_linux" = "yes"
1143 then
1144 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1145 fi
1146 fi
1148 dnl **** Check for types ****
1150 AC_C_CONST
1151 AC_C_INLINE
1152 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1153 AC_CHECK_SIZEOF(long long,0)
1155 AC_CACHE_CHECK([whether linux/input.h is for real],
1156 wine_cv_linux_input_h,
1157 AC_TRY_COMPILE([
1158 #include <linux/input.h>
1159 ] , [
1160 int foo = EVIOCGBIT(EV_ABS,42);
1161 int bar = BTN_PINKIE;
1162 int fortytwo = 42;
1163 ],
1164 wine_cv_linux_input_h=yes,
1165 wine_cv_linux_input_h=no,
1166 no
1167 )
1168 )
1169 if test "$wine_cv_linux_input_h" = "yes"
1170 then
1171 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1172 [Define if we have linux/input.h AND it contains the INPUT event API])
1173 fi
1176 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1177 wine_cv_linux_gethostbyname_r_6,
1178 AC_TRY_COMPILE([
1179 #include <netdb.h>
1180 ], [
1181 char *name=NULL;
1182 struct hostent he;
1183 struct hostent *result;
1184 char *buf=NULL;
1185 int bufsize=0;
1186 int res,errnr;
1187 char *addr=NULL;
1188 int addrlen=0;
1189 int addrtype=0;
1190 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1191 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1192 ],
1193 wine_cv_linux_gethostbyname_r_6=yes,
1194 wine_cv_linux_gethostbyname_r_6=no
1195 )
1196 )
1197 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1198 then
1199 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1200 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1201 fi
1203 if test "$ac_cv_header_linux_joystick_h" = "yes"
1204 then
1205 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1206 wine_cv_linux_joystick_22_api,
1207 AC_TRY_COMPILE([
1208 #include <sys/ioctl.h>
1209 #include <linux/joystick.h>
1211 struct js_event blub;
1212 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1213 #error "no 2.2 header"
1214 #endif
1215 ],/*empty*/,
1216 wine_cv_linux_joystick_22_api=yes,
1217 wine_cv_linux_joystick_22_api=no,
1218 wine_cv_linux_joystick_22_api=no
1219 )
1220 )
1221 if test "$wine_cv_linux_joystick_22_api" = "yes"
1222 then
1223 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1224 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1225 fi
1226 fi
1228 dnl **** statfs checks ****
1230 if test "$ac_cv_header_sys_vfs_h" = "yes"
1231 then
1232 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1233 wine_cv_sys_vfs_has_statfs,
1234 AC_TRY_COMPILE([
1235 #include <sys/types.h>
1236 #ifdef HAVE_SYS_PARAM_H
1237 # include <sys/param.h>
1238 #endif
1239 #include <sys/vfs.h>
1240 ],[
1241 struct statfs stfs;
1243 memset(&stfs,0,sizeof(stfs));
1244 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1245 )
1246 )
1247 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1248 then
1249 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1250 [Define if the struct statfs is defined by <sys/vfs.h>])
1251 fi
1252 fi
1254 if test "$ac_cv_header_sys_statfs_h" = "yes"
1255 then
1256 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1257 wine_cv_sys_statfs_has_statfs,
1258 AC_TRY_COMPILE([
1259 #include <sys/types.h>
1260 #ifdef HAVE_SYS_PARAM_H
1261 # include <sys/param.h>
1262 #endif
1263 #include <sys/statfs.h>
1264 ],[
1265 struct statfs stfs;
1266 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1267 )
1268 )
1269 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1270 then
1271 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1272 [Define if the struct statfs is defined by <sys/statfs.h>])
1273 fi
1274 fi
1276 if test "$ac_cv_header_sys_mount_h" = "yes"
1277 then
1278 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1279 wine_cv_sys_mount_has_statfs,
1280 AC_TRY_COMPILE([
1281 #include <sys/types.h>
1282 #ifdef HAVE_SYS_PARAM_H
1283 # include <sys/param.h>
1284 #endif
1285 #include <sys/mount.h>
1286 ],[
1287 struct statfs stfs;
1288 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1289 )
1290 )
1291 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1292 then
1293 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1294 [Define if the struct statfs is defined by <sys/mount.h>])
1295 fi
1296 fi
1298 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1300 dnl Check for statfs members
1301 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail],,,
1302 [#include <sys/types.h>
1303 #ifdef HAVE_SYS_PARAM_H
1304 # include <sys/param.h>
1305 #endif
1306 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1307 # include <sys/mount.h>
1308 #else
1309 # ifdef STATFS_DEFINED_BY_SYS_VFS
1310 # include <sys/vfs.h>
1311 # else
1312 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1313 # include <sys/statfs.h>
1314 # endif
1315 # endif
1316 #endif])
1318 dnl Check for socket structure members
1319 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1320 [#include <sys/types.h>
1321 #ifdef HAVE_SYS_SOCKET_H
1322 # include <sys/socket.h>
1323 #endif
1324 #ifdef HAVE_SYS_UN_H
1325 # include <sys/un.h>
1326 #endif])
1328 dnl Check for siginfo_t members
1329 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1331 dnl *** check for the need to define platform-specific symbols
1333 case $host_cpu in
1334 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1335 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1336 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1337 esac
1339 case $host_vendor in
1340 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1341 esac
1343 dnl **** Generate output files ****
1345 AH_TOP([#define __WINE_CONFIG_H])
1347 WINE_CONFIG_EXTRA_DIR(controls)
1348 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1349 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1350 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1351 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1352 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1353 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1354 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1355 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1356 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1357 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1358 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1359 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1360 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1361 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1362 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1363 WINE_CONFIG_EXTRA_DIR(files)
1364 WINE_CONFIG_EXTRA_DIR(graphics)
1365 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1366 WINE_CONFIG_EXTRA_DIR(if1632)
1367 WINE_CONFIG_EXTRA_DIR(include/wine)
1368 WINE_CONFIG_EXTRA_DIR(loader)
1369 WINE_CONFIG_EXTRA_DIR(loader/ne)
1370 WINE_CONFIG_EXTRA_DIR(memory)
1371 WINE_CONFIG_EXTRA_DIR(misc)
1372 WINE_CONFIG_EXTRA_DIR(msdos)
1373 WINE_CONFIG_EXTRA_DIR(objects)
1374 WINE_CONFIG_EXTRA_DIR(ole)
1375 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1376 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1377 WINE_CONFIG_EXTRA_DIR(relay32)
1378 WINE_CONFIG_EXTRA_DIR(scheduler)
1379 WINE_CONFIG_EXTRA_DIR(win32)
1380 WINE_CONFIG_EXTRA_DIR(windows)
1382 MAKE_RULES=Make.rules
1383 AC_SUBST_FILE(MAKE_RULES)
1385 MAKE_DLL_RULES=dlls/Makedll.rules
1386 AC_SUBST_FILE(MAKE_DLL_RULES)
1388 MAKE_TEST_RULES=dlls/Maketest.rules
1389 AC_SUBST_FILE(MAKE_TEST_RULES)
1391 MAKE_PROG_RULES=programs/Makeprog.rules
1392 AC_SUBST_FILE(MAKE_PROG_RULES)
1394 AC_CONFIG_FILES([
1395 Make.rules
1396 dlls/Makedll.rules
1397 dlls/Maketest.rules
1398 programs/Makeprog.rules
1399 Makefile
1400 dlls/Makefile
1401 dlls/advapi32/Makefile
1402 dlls/advapi32/tests/Makefile
1403 dlls/avicap32/Makefile
1404 dlls/avifil32/Makefile
1405 dlls/cabinet/Makefile
1406 dlls/comcat/Makefile
1407 dlls/comctl32/Makefile
1408 dlls/commdlg/Makefile
1409 dlls/crtdll/Makefile
1410 dlls/crypt32/Makefile
1411 dlls/ctl3d/Makefile
1412 dlls/d3d8/Makefile
1413 dlls/d3dim/Makefile
1414 dlls/d3dx8/Makefile
1415 dlls/dciman32/Makefile
1416 dlls/ddraw/Makefile
1417 dlls/devenum/Makefile
1418 dlls/dinput/Makefile
1419 dlls/dinput8/Makefile
1420 dlls/dmusic/Makefile
1421 dlls/dplay/Makefile
1422 dlls/dplayx/Makefile
1423 dlls/dsound/Makefile
1424 dlls/dsound/tests/Makefile
1425 dlls/gdi/Makefile
1426 dlls/gdi/tests/Makefile
1427 dlls/glu32/Makefile
1428 dlls/icmp/Makefile
1429 dlls/imagehlp/Makefile
1430 dlls/imm32/Makefile
1431 dlls/kernel/Makefile
1432 dlls/kernel/tests/Makefile
1433 dlls/lzexpand/Makefile
1434 dlls/mapi32/Makefile
1435 dlls/mpr/Makefile
1436 dlls/msacm/Makefile
1437 dlls/msacm/imaadp32/Makefile
1438 dlls/msacm/msadp32/Makefile
1439 dlls/msacm/msg711/Makefile
1440 dlls/msacm/winemp3/Makefile
1441 dlls/msdmo/Makefile
1442 dlls/msimg32/Makefile
1443 dlls/msisys/Makefile
1444 dlls/msnet32/Makefile
1445 dlls/msvcrt/Makefile
1446 dlls/msvcrt/tests/Makefile
1447 dlls/msvcrt20/Makefile
1448 dlls/msvideo/Makefile
1449 dlls/msvideo/msrle32/Makefile
1450 dlls/netapi32/Makefile
1451 dlls/netapi32/tests/Makefile
1452 dlls/ntdll/Makefile
1453 dlls/ntdll/tests/Makefile
1454 dlls/odbc32/Makefile
1455 dlls/ole32/Makefile
1456 dlls/oleaut32/Makefile
1457 dlls/oleaut32/tests/Makefile
1458 dlls/olecli/Makefile
1459 dlls/oledlg/Makefile
1460 dlls/olepro32/Makefile
1461 dlls/olesvr/Makefile
1462 dlls/opengl32/Makefile
1463 dlls/psapi/Makefile
1464 dlls/qcap/Makefile
1465 dlls/quartz/Makefile
1466 dlls/rasapi32/Makefile
1467 dlls/richedit/Makefile
1468 dlls/rpcrt4/Makefile
1469 dlls/rpcrt4/tests/Makefile
1470 dlls/serialui/Makefile
1471 dlls/setupapi/Makefile
1472 dlls/shdocvw/Makefile
1473 dlls/shell32/Makefile
1474 dlls/shell32/tests/Makefile
1475 dlls/shfolder/Makefile
1476 dlls/shlwapi/Makefile
1477 dlls/shlwapi/tests/Makefile
1478 dlls/snmpapi/Makefile
1479 dlls/sti/Makefile
1480 dlls/tapi32/Makefile
1481 dlls/ttydrv/Makefile
1482 dlls/twain/Makefile
1483 dlls/url/Makefile
1484 dlls/urlmon/Makefile
1485 dlls/urlmon/tests/Makefile
1486 dlls/user/Makefile
1487 dlls/user/tests/Makefile
1488 dlls/version/Makefile
1489 dlls/win32s/Makefile
1490 dlls/winaspi/Makefile
1491 dlls/winedos/Makefile
1492 dlls/wineps/Makefile
1493 dlls/wininet/Makefile
1494 dlls/wininet/tests/Makefile
1495 dlls/winmm/Makefile
1496 dlls/winmm/joystick/Makefile
1497 dlls/winmm/mcianim/Makefile
1498 dlls/winmm/mciavi/Makefile
1499 dlls/winmm/mcicda/Makefile
1500 dlls/winmm/mciseq/Makefile
1501 dlls/winmm/mciwave/Makefile
1502 dlls/winmm/midimap/Makefile
1503 dlls/winmm/tests/Makefile
1504 dlls/winmm/wavemap/Makefile
1505 dlls/winmm/winealsa/Makefile
1506 dlls/winmm/winearts/Makefile
1507 dlls/winmm/wineaudioio/Makefile
1508 dlls/winmm/winenas/Makefile
1509 dlls/winmm/winejack/Makefile
1510 dlls/winmm/wineoss/Makefile
1511 dlls/winnls/Makefile
1512 dlls/winsock/Makefile
1513 dlls/winsock/tests/Makefile
1514 dlls/winspool/Makefile
1515 dlls/winspool/tests/Makefile
1516 dlls/wintab32/Makefile
1517 dlls/wintrust/Makefile
1518 dlls/wow32/Makefile
1519 dlls/wsock32/Makefile
1520 dlls/x11drv/Makefile
1521 documentation/Makefile
1522 include/Makefile
1523 libs/Makefile
1524 libs/port/Makefile
1525 libs/unicode/Makefile
1526 libs/uuid/Makefile
1527 libs/wine/Makefile
1528 miscemu/Makefile
1529 programs/Makefile
1530 programs/avitools/Makefile
1531 programs/clock/Makefile
1532 programs/cmdlgtst/Makefile
1533 programs/control/Makefile
1534 programs/expand/Makefile
1535 programs/notepad/Makefile
1536 programs/osversioncheck/Makefile
1537 programs/progman/Makefile
1538 programs/regapi/Makefile
1539 programs/regedit/Makefile
1540 programs/regsvr32/Makefile
1541 programs/regtest/Makefile
1542 programs/rpcss/Makefile
1543 programs/rundll32/Makefile
1544 programs/start/Makefile
1545 programs/uninstaller/Makefile
1546 programs/view/Makefile
1547 programs/wcmd/Makefile
1548 programs/wineboot/Makefile
1549 programs/winecfg/Makefile
1550 programs/wineconsole/Makefile
1551 programs/winedbg/Makefile
1552 programs/winefile/Makefile
1553 programs/winemine/Makefile
1554 programs/winepath/Makefile
1555 programs/winhelp/Makefile
1556 programs/winver/Makefile
1557 server/Makefile
1558 tools/Makefile
1559 tools/widl/Makefile
1560 tools/winapi/Makefile
1561 tools/winebuild/Makefile
1562 tools/winedump/Makefile
1563 tools/wmc/Makefile
1564 tools/wpp/Makefile
1565 tools/wrc/Makefile])
1567 AC_OUTPUT
1569 if test "$have_x" = "no"
1570 then
1571 echo
1572 echo "*** Warning: X development files not found. Wine will be built without"
1573 echo "*** X support, which currently does not work, and would probably not be"
1574 echo "*** what you want anyway. You will need to install devel packages of"
1575 echo "*** Xlib/Xfree86 at the very least."
1576 fi
1578 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1579 then
1580 echo
1581 echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1582 echo "*** terminal resize support. Consider upgrading ncurses."
1583 fi
1585 if test "$wine_cv_libc_reentrant" = "no"
1586 then
1587 echo
1588 echo "*** Warning: non-reentrant libc detected. Wine will be built without"
1589 echo "*** threading support. Consider upgrading libc to a more recent"
1590 echo "*** reentrant version of libc."
1591 fi
1593 if test "$have_x" = "yes" -a "$wine_cv_x_reentrant" != "yes"
1594 then
1595 echo
1596 echo "*** Warning: non-reentrant X11 library detected. Multi-threaded"
1597 echo "*** applications won't work properly. You should upgrade your X11 library."
1598 fi
1600 if test "$wine_cv_opengl_version_OK" = "no"
1601 then
1602 echo
1603 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1604 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1605 fi
1607 if test "$wine_cv_msg_freetype" = "yes"
1608 then
1609 echo
1610 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1611 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1612 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1613 echo "*** enable Wine to use TrueType fonts."
1614 fi
1616 echo
1617 echo "Configure finished. Do 'make depend && make' to compile Wine."
1618 echo
1620 dnl Local Variables:
1621 dnl comment-start: "dnl "
1622 dnl comment-end: ""
1623 dnl comment-start-skip: "\\bdnl\\b\\s *"
1624 dnl compile-command: "autoconf"
1625 dnl End: