dlls/opengl32/make_opengl

   1 #!/usr/bin/perl -w
   2 use strict;
   3
   4 # This script is called thus :
   5 #
   6 #   make_opengl [opengl_version]
   7 #
   8 #     - It needs the gl.spec and gl.tm files in the current directory.
   9 #       These files are hosted in the OpenGL extension registry at
  10 #       opengl.org:
  11 #
  12 #       http://www.opengl.org/registry/api/gl.spec
  13 #       http://www.opengl.org/registry/api/gl.tm
  14 #
  15 #       If they are not found in the current directory the script will
  16 #       attempt to download them from there.
  17 #
  18 #       The files used to be hosted and maintained by SGI. You can still find
  19 #       find them in the sample implementation CVS tree which is located at
  20 #       CVS_ROOT/projects/ogl-sample/main/doc/registry/specs.
  21 #       You can also find them on the web at the following URL :
  22 #         http://oss.sgi.com/cgi-bin/cvsweb.cgi/projects/ogl-sample/main/doc/registry/specs/
  23 #
  24 #     - opengl_version is the OpenGL version emulated by the library
  25 #       (can be 1.0 to 1.5). The default is 1.2.
  26 #
  27 # This script generates the three following files :
  28 #
  29 #     - opengl32.spec : the spec file giving all the exported functions
  30 #       of the OpenGL32.DLL library. These functions are the one an
  31 #       application can directly link to (and are all the functions
  32 #       defined in the OpenGL core for the version defined by
  33 #       'opengl_version').
  34 #
  35 #     - opengl_norm.c : this file contains the thunks for all OpenGL
  36 #       functions that are defined in 'opengl32.spec'. The corresponding
  37 #       functions NEED to be defined in Linux's libGL or the library
  38 #       won't be able to be linked in.
  39 #
  40 #     - opengl_ext.c : in this file are stored thunks for ALL possible
  41 #       OpenGL extensions (at least, all the extensions that are defined
  42 #       in the OpenGL extension registry). Contrary to 'opengl_norm.c',
  43 #       you do not need to have these extensions in your libGL to have
  44 #       OpenGL work (as they are resolved at run-time using
  45 #       glXGetProcAddressARB).
  46 #
  47 # Copyright 2000 Lionel Ulmer
  48 #
  49 # This library is free software; you can redistribute it and/or
  50 # modify it under the terms of the GNU Lesser General Public
  51 # License as published by the Free Software Foundation; either
  52 # version 2.1 of the License, or (at your option) any later version.
  53 #
  54 # This library is distributed in the hope that it will be useful,
  55 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  56 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  57 # Lesser General Public License for more details.
  58 #
  59 # You should have received a copy of the GNU Lesser General Public
  60 # License along with this library; if not, write to the Free Software
  61 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  62 #
  63
  64 #
  65 # Files to generate
  66 #
  67 my $spec_file = "opengl32.spec";
  68 my $norm_file = "opengl_norm.c";
  69 my $ext_file  = "opengl_ext.c";
  70
  71 # Set to 0 for removing the ENTER / LEAVE GL calls
  72 my $gen_thread_safe = 1;
  73 # Prefix used for the local variables
  74 my $ext_prefix = "func_";
  75 # If set to 1, generate TRACEs for each OpenGL function
  76 my $gen_traces = 1;
  77
  78 #
  79 # List of categories to put in the 'opengl_norm.c' file
  80 #
  81 my %cat_1_0 = ( "display-list" => 1,
  82              "drawing" => 1,
  83              "drawing-control" => 1,
  84              "feedback" => 1,
  85              "framebuf" => 1,
  86              "misc" => 1,
  87              "modeling" => 1,
  88              "pixel-op" => 1,
  89              "pixel-rw" => 1,
  90              "state-req" => 1,
  91              "xform" => 1 );
  92 my %cat_1_1 = ( %cat_1_0,
  93              "1_1" => 1 );
  94 my %cat_1_2 = ( %cat_1_1,
  95              "VERSION_1_2" => 1 );
  96 my %cat_1_3 = ( %cat_1_2,
  97              "VERSION_1_3" => 1 );
  98 my %cat_1_4 = ( %cat_1_3,
  99              "VERSION_1_4" => 1 );
 100 my %cat_1_5 = ( %cat_1_4,
 101              "VERSION_1_5" => 1 );
 102
 103 my %norm_categories = ();
 104
 105 #
 106 # This hash table gives the conversion between OpenGL types and what
 107 # is used by the TRACE printfs
 108 #
 109 my %debug_conv =
 110     ("GLbitfield" => "%d",
 111      "GLboolean" => "%d",
 112      "GLbyte" => "%d",
 113      "GLclampd" => "%f",
 114      "GLclampf" => "%f",
 115      "GLdouble" => "%f",
 116      "GLenum" => "%d",
 117      "GLfloat" => "%f",
 118      "GLint" => "%d",
 119      "GLshort" => "%d",
 120      "GLsizei" => "%d",
 121      "GLstring" => "%s",
 122      "GLubyte" => "%d",
 123      "GLuint" => "%d",
 124      "GLushort" => "%d",
 125      "GLhalfNV" => "%d",
 126      "GLintptrARB" => "%ld",
 127      "GLsizeiptrARB" => "%ld",
 128      "GLintptr" => "%ld",
 129      "GLsizeiptr" => "%ld",
 130      "GLhandleARB" => "%d",
 131      "GLcharARB" => "%c",
 132      "GLvoid" => "(void)",
 133      "_GLfuncptr" => "%p");
 134
 135 #
 136 # This hash table gives the conversion between OpenGL types and what
 137 # is used in the .spec file
 138 #
 139 my %arg_conv =
 140     ("GLbitfield" => [ "long", 4 ],
 141      "GLboolean" => [ "long", 4 ],
 142      "GLbyte" => [ "long", 4 ],
 143      "GLclampd" => [ "double", 8 ],
 144      "GLclampf" => [ "long", 4 ],
 145      "GLdouble" => [ "double", 8 ],
 146      "GLenum" => [ "long", 4 ],
 147      "GLfloat" => [ "long", 4 ],
 148      "GLint" => [ "long", 4 ],
 149      "GLshort" => [ "long", 4 ],
 150      "GLsizei" => [ "long", 4 ],
 151      "GLstring" => [ "str", 4 ],
 152      "GLubyte" => [ "long", 4 ],
 153      "GLuint" => [ "long", 4 ],
 154      "GLushort" => [ "long", 4 ],
 155      "GLhalfNV" => [ "long", 4 ],
 156      "GLintptrARB" => [ "long", 4 ],
 157      "GLsizeiptrARB" => [ "long", 4 ],
 158      "GLhandleARB" => [ "long", 4 ],
 159      "GLcharARB" => [ "long", 4 ],
 160      "GLintptr" => [ "long", 4 ],
 161      "GLsizeiptr" => [ "long", 4 ],
 162      "GLvoid" => [ "void", 4 ],
 163      "_GLfuncptr" => [ "ptr", 4 ]);
 164
 165 #
 166 # Used to convert some types
 167 #
 168 sub ConvertType($)
 169 {
 170     my ($type) = @_;
 171
 172     my %hash = ( "GLstring" => "const GLubyte *",
 173               "GLintptrARB" => "INT_PTR",
 174               "GLsizeiptrARB" => "INT_PTR",
 175               "GLintptr" => "INT_PTR",
 176               "GLsizeiptr" => "INT_PTR",
 177               "GLhandleARB" => "unsigned int",
 178               "GLcharARB" => "char",
 179               "GLchar" => "char",
 180               "GLhalfNV" => "unsigned short" );
 181
 182     foreach my $org (reverse sort keys %hash) {
 183         if ($type =~ /$org/) {
 184             my ($before, $after) = ($type =~ /^(.*)$org(.*)$/);
 185             return "$before$hash{$org}$after";
 186         }
 187     }
 188     return $type;
 189 }
 190
 191 #
 192 # Used to convert some variable names
 193 #
 194 sub ConvertVarName($)
 195 {
 196     my ($type) = @_;
 197
 198     my %hash = ( "near" => "nearParam",
 199                  "far"  => "farParam" );
 200
 201     foreach my $org (keys %hash) {
 202         if ($type =~ /$org/) {
 203             my ($before, $after) = ($type =~ /^(.*)$org(.*)$/);
 204             return "$before$hash{$org}$after";
 205         }
 206     }
 207     return $type;
 208 }
 209
 210 #
 211 # This functions generates the thunk for a given function.
 212 #
 213 sub GenerateThunk($$$$$)
 214 {
 215     my ($func_ref, $comment, $prefix, $thread_safe, $local_var) = @_;
 216     my $ret = "";
 217     my $call_arg = "";
 218     my $trace_arg = "";
 219
 220     return "" if $func_ref->[0] eq "glGetString";
 221     return "" if $func_ref->[0] eq "glGetIntegerv";
 222     return "" if $func_ref->[0] eq "glFinish";
 223     return "" if $func_ref->[0] eq "glFlush";
 224
 225     # If for opengl_norm.c, generate a nice heading otherwise Patrik won't be happy :-)
 226     # Patrik says: Well I would be even happier if a (OPENGL32.@) was added as well. Done. :-)
 227     if ($comment eq 1) {
 228         $ret = "$ret/***********************************************************************\n";
 229         $ret = "$ret *              $func_ref->[0] (OPENGL32.\@)\n";
 230         $ret = "$ret */\n";
 231     }
 232     $ret = $ret . ConvertType($func_ref->[1]) . " WINAPI wine_$func_ref->[0]( ";
 233     for (my $i = 0; $i < @{$func_ref->[2]}; $i++) {
 234         ## Quick debug code :-)
 235         ## print $func_ref->[2]->[$i]->[1] . "\n";
 236         my $type = $func_ref->[2]->[$i]->[0];
 237         my $name = ConvertVarName($func_ref->[2]->[$i]->[1]);
 238         $ret = $ret . ConvertType($type) . " $name";
 239         $call_arg = "$call_arg$name";
 240         if ($type =~ /\*/) {
 241             $trace_arg = "$trace_arg\%p";
 242         } else {
 243             $trace_arg = "$trace_arg$debug_conv{$type}";
 244         }
 245         if ($i+1 < @{$func_ref->[2]}) {
 246             $ret = "$ret, ";
 247             $call_arg = "$call_arg, ";
 248             $trace_arg = "$trace_arg, ";
 249         } else {
 250             $ret = "$ret ";
 251             $call_arg = "$call_arg ";
 252         }
 253     }
 254     $ret .= 'void ' if (!@{$func_ref->[2]});
 255     $ret = "$ret) {\n";
 256     if ($func_ref->[1] ne "void") {
 257         $ret = "$ret  " . ConvertType($func_ref->[1]) . " ret_value;\n";
 258     }
 259     $ret .= $local_var;
 260     if ($gen_traces) {
 261         $ret = "$ret  TRACE(\"($trace_arg)\\n\"";
 262         if ($trace_arg ne "") {
 263             $ret = "$ret, $call_arg";
 264         }
 265         $ret = "$ret);\n";
 266     }
 267     if ($thread_safe) {
 268         $ret = "$ret  ENTER_GL();\n";
 269     }
 270     $ret = "$ret  ";
 271     if ($func_ref->[1] ne "void") {
 272         $ret = $ret . "ret_value = ";
 273     }
 274     $ret = "$ret$prefix$func_ref->[0]( $call_arg);\n";
 275     if ($thread_safe) {
 276         $ret = "$ret  LEAVE_GL();\n";
 277     }
 278     if ($func_ref->[1] ne "void") {
 279         $ret = "$ret  return ret_value;\n"
 280     }
 281     $ret = "$ret}\n";
 282
 283     # Return this string....
 284     return $ret;
 285 }
 286
 287 #
 288 # Extract and checks the number of arguments
 289 #
 290 if (@ARGV > 1) {
 291     my $name0=$0;
 292     $name0=~s%^.*/%%;
 293     die "Usage: $name0 [version]\n";
 294 }
 295 my $version = $ARGV[0] || "1.2";
 296 if ($version eq "1.0") {
 297     %norm_categories = %cat_1_0;
 298 } elsif ($version eq "1.1") {
 299     %norm_categories = %cat_1_1;
 300 } elsif ($version eq "1.2") {
 301     %norm_categories = %cat_1_2;
 302 } elsif ($version eq "1.3") {
 303     %norm_categories = %cat_1_3;
 304 } elsif ($version eq "1.4") {
 305     %norm_categories = %cat_1_4;
 306 } elsif ($version eq "1.5") {
 307     %norm_categories = %cat_1_5;
 308 } else {
 309     die "Incorrect OpenGL version.\n";
 310 }
 311
 312 #
 313 # Fetch the registry files
 314 #
 315 -f "gl.spec" || system "wget http://www.opengl.org/registry/api/gl.spec" || die "cannot download gl.spec";
 316 -f "gl.tm" || system "wget http://www.opengl.org/registry/api/gl.tm" || die "cannot download gl.tm";
 317
 318 #
 319 # Open the registry files
 320 #
 321 open(TYPES,    "gl.tm")   || die "Could not open gl.tm";
 322 open(REGISTRY, "gl.spec") || die "Could not open gl.spec";
 323
 324 #
 325 # First, create a mapping between the pseudo types used in the spec file
 326 # and OpenGL types using the 'gl.tm' file.
 327 #
 328 my %pseudo_to_opengl = ();
 329 while (my $line = <TYPES>) {
 330     if ($line !~ /\w*\#/) {
 331         my ($pseudo, $opengl) = ($line =~ /(\w*),\*,\*,\s*(.*),\*,\*/);
 332         $pseudo_to_opengl{$pseudo} = $opengl;
 333     }
 334 }
 335 # This is to override the 'void' -> '*' bogus conversion
 336 $pseudo_to_opengl{"void"} = "void";
 337 $pseudo_to_opengl{"Int64EXT"} = "INT64";
 338 $pseudo_to_opengl{"UInt64EXT"} = "UINT64";
 339
 340 #
 341 # Then, create the list of all OpenGL functions using the 'gl.spec'
 342 # file. This will create two hash-tables, one with all the function
 343 # whose category matches the one listed in '@norm_categories', the other
 344 # with all other functions.
 345 #
 346 # An element of the hash table is a reference to an array with these
 347 # elements :
 348 #
 349 #  - function name
 350 #
 351 #  - return type
 352 #
 353 #  - reference to an array giving the list of arguments (an empty array
 354 #    for a 'void' function).
 355 #
 356 # The list of arguments is itself an array of reference to arrays. Each
 357 # of these arrays represents the argument type and the argument name.
 358 #
 359 # An example :
 360 #
 361 # void glBitmap( GLsizei width, GLsizei height,
 362 #                GLfloat xorig, GLfloat yorig,
 363 #                GLfloat xmove, GLfloat ymove,
 364 #                const GLubyte *bitmap );
 365 #
 366 # Would give something like that :
 367 #
 368 # [ "glBitmap",
 369 #   "void",
 370 #   [ [ "GLsizei", "width" ],
 371 #     [ "GLsizei", "height" ],
 372 #     [ "GLfloat", "xorig" ],
 373 #     [ "GLfloat", "yorig" ],
 374 #     [ "GLfloat", "xmove" ],
 375 #     [ "GLfloat", "ymove" ],
 376 #     [ "GLubyte *", "bitmap"] ] ];
 377 #
 378 my %norm_functions = ();
 379
 380 #
 381 # This stores various extensions NOT part of the GL extension registry but still
 382 # implemented by most OpenGL libraries out there...
 383 #
 384
 385 my %ext_functions  =
 386     ( "glDeleteBufferRegion" => [ "glDeleteBufferRegion", "void", [ [ "GLenum", "region" ] ], "glDeleteBufferRegion", "GL_KTX_buffer_region" ],
 387       "glReadBufferRegion" => [ "glReadBufferRegion", "void", [ [ "GLenum", "region" ],
 388                                                                 [ "GLint", "x" ],
 389                                                                 [ "GLint", "y" ],
 390                                                                 [ "GLsizei", "width" ],
 391                                                                 [ "GLsizei", "height" ] ], "glReadBufferRegion", "GL_KTX_buffer_region" ],
 392       "glDrawBufferRegion" => [ "glDrawBufferRegion", "void", [ [ "GLenum", "region" ],
 393                                                                 [ "GLint", "x" ],
 394                                                                 [ "GLint", "y" ],
 395                                                                 [ "GLsizei", "width" ],
 396                                                                 [ "GLsizei", "height" ],
 397                                                                 [ "GLint", "xDest" ],
 398                                                                 [ "GLint", "yDest" ] ], "glDrawBufferRegion", "GL_KTX_buffer_region" ],
 399       "glBufferRegionEnabled" => [ "glBufferRegionEnabled", "GLuint", [ ], "glBufferRegionEnabled",  "GL_KTX_buffer_region" ],
 400       "glNewBufferRegion" => [ "glNewBufferRegion", "GLuint", [ [ "GLenum", "type" ] ], "glNewBufferRegion", "GL_KTX_buffer_region" ],
 401       "glMTexCoord2fSGIS" => [ "glMTexCoord2fSGIS", "void", [ [ "GLenum", "target" ],
 402                                                               [ "GLfloat", "s" ],
 403                                                               [ "GLfloat", "t" ] ], "glMTexCoord2fSGIS", "GL_SGIS_multitexture" ],
 404       "glMTexCoord2fvSGIS" => [ "glMTexCoord2fvSGIS", "void", [ [ "GLenum", "target" ],
 405                                                                 [ "GLfloat *", "v" ] ], "glMTexCoord2fvSGIS", "GL_SGIS_multitexture" ],
 406       "glMultiTexCoord1dSGIS" => [ "glMultiTexCoord1dSGIS", "void", [ [ "GLenum", "target" ],
 407                                                                       [ "GLdouble", "s" ] ],  "glMultiTexCoord1dSGIS", "GL_SGIS_multitexture" ],
 408       "glMultiTexCoord1dvSGIS" => [ "glMultiTexCoord1dvSGIS", "void", [ [ "GLenum", "target" ],
 409                                                                         [ "GLdouble *", "v" ] ], "glMultiTexCoord1dvSGIS", "GL_SGIS_multitexture" ],
 410       "glMultiTexCoord1fSGIS" => [ "glMultiTexCoord1fSGIS", "void", [ [ "GLenum", "target" ],
 411                                                                       [ "GLfloat", "s" ] ], "glMultiTexCoord1fSGIS", "GL_SGIS_multitexture" ],
 412       "glMultiTexCoord1fvSGIS" => [ "glMultiTexCoord1fvSGIS", "void", [ [ "GLenum", "target" ],
 413                                                                         [ "const GLfloat *", "v" ] ], "glMultiTexCoord1fvSGIS", "GL_SGIS_multitexture" ],
 414       "glMultiTexCoord1iSGIS" => [ "glMultiTexCoord1iSGIS", "void", [ [ "GLenum", "target" ],
 415                                                                       [ "GLint", "s" ] ], "glMultiTexCoord1iSGIS", "GL_SGIS_multitexture" ],
 416       "glMultiTexCoord1ivSGIS" => [ "glMultiTexCoord1ivSGIS", "void", [ [ "GLenum", "target" ],
 417                                                                         [ "GLint *", "v" ] ], "glMultiTexCoord1ivSGIS", "GL_SGIS_multitexture" ],
 418       "glMultiTexCoord1sSGIS" => [ "glMultiTexCoord1sSGIS", "void", [ [ "GLenum", "target" ],
 419                                                                       [ "GLshort", "s" ] ], "glMultiTexCoord1sSGIS", "GL_SGIS_multitexture" ],
 420       "glMultiTexCoord1svSGIS" => [ "glMultiTexCoord1svSGIS", "void", [ [ "GLenum", "target" ],
 421                                                                         [ "GLshort *", "v" ] ], "glMultiTexCoord1svSGIS", "GL_SGIS_multitexture" ],
 422       "glMultiTexCoord2dSGIS" => [ "glMultiTexCoord2dSGIS", "void", [ [ "GLenum", "target" ],
 423                                                                       [ "GLdouble", "s"],
 424                                                                       [ "GLdouble", "t" ] ], "glMultiTexCoord2dSGIS", "GL_SGIS_multitexture" ],
 425       "glMultiTexCoord2dvSGIS" => [ "glMultiTexCoord2dvSGIS", "void", [ [ "GLenum", "target" ],
 426                                                                         [ "GLdouble *", "v" ] ], "glMultiTexCoord2dvSGIS", "GL_SGIS_multitexture" ],
 427       "glMultiTexCoord2fSGIS" => [ "glMultiTexCoord2fSGIS", "void", [ [ "GLenum", "target" ],
 428                                                                       [ "GLfloat", "s" ],
 429                                                                       [ "GLfloat", "t" ] ], "glMultiTexCoord2fSGIS", "GL_SGIS_multitexture" ],
 430       "glMultiTexCoord2fvSGIS" => [ "glMultiTexCoord2fvSGIS", "void", [ [ "GLenum", "target" ],
 431                                                                         [ "GLfloat *", "v" ] ], "glMultiTexCoord2fvSGIS", "GL_SGIS_multitexture" ],
 432       "glMultiTexCoord2iSGIS" => [ "glMultiTexCoord2iSGIS", "void", [ [ "GLenum", "target" ],
 433                                                                       [ "GLint", "s" ],
 434                                                                       [ "GLint", "t" ] ], "glMultiTexCoord2iSGIS", "GL_SGIS_multitexture" ],
 435       "glMultiTexCoord2ivSGIS" => [ "glMultiTexCoord2ivSGIS", "void", [ [ "GLenum", "target" ],
 436                                                                         [ "GLint *", "v" ] ], "glMultiTexCoord2ivSGIS", "GL_SGIS_multitexture" ],
 437       "glMultiTexCoord2sSGIS" => [ "glMultiTexCoord2sSGIS", "void", [ [ "GLenum", "target" ],
 438                                                                       [ "GLshort", "s" ],
 439                                                                       [ "GLshort", "t" ] ], "glMultiTexCoord2sSGIS", "GL_SGIS_multitexture" ],
 440       "glMultiTexCoord2svSGIS" => [ "glMultiTexCoord2svSGIS", "void", [ [ "GLenum", "target" ],
 441                                                                         [ "GLshort *", "v" ] ], "glMultiTexCoord2svSGIS", "GL_SGIS_multitexture" ],
 442       "glMultiTexCoord3dSGIS" => [ "glMultiTexCoord3dSGIS", "void", [ [ "GLenum", "target" ],
 443                                                                       [ "GLdouble", "s" ],
 444                                                                       [ "GLdouble", "t" ],
 445                                                                       [ "GLdouble", "r" ] ], "glMultiTexCoord3dSGIS", "GL_SGIS_multitexture" ],
 446       "glMultiTexCoord3dvSGIS" => [ "glMultiTexCoord3dvSGIS", "void", [ [ "GLenum", "target" ],
 447                                                                         [ "GLdouble *", "v" ] ], "glMultiTexCoord3dvSGIS", "GL_SGIS_multitexture" ],
 448       "glMultiTexCoord3fSGIS" => [ "glMultiTexCoord3fSGIS", "void", [ [ "GLenum", "target" ],
 449                                                                       [ "GLfloat", "s" ],
 450                                                                       [ "GLfloat", "t" ],
 451                                                                       [ "GLfloat", "r" ] ], "glMultiTexCoord3fSGIS", "GL_SGIS_multitexture" ],
 452       "glMultiTexCoord3fvSGIS" => [ "glMultiTexCoord3fvSGIS", "void", [ [ "GLenum", "target" ],
 453                                                                         [ "GLfloat *", "v" ] ], "glMultiTexCoord3fvSGIS", "GL_SGIS_multitexture" ],
 454       "glMultiTexCoord3iSGIS" => [ "glMultiTexCoord3iSGIS", "void", [ [ "GLenum", "target" ],
 455                                                                       [ "GLint", "s" ],
 456                                                                       [ "GLint", "t" ],
 457                                                                       [ "GLint", "r" ] ], "glMultiTexCoord3iSGIS", "GL_SGIS_multitexture" ],
 458       "glMultiTexCoord3ivSGIS" => [ "glMultiTexCoord3ivSGIS", "void", [ [ "GLenum", "target" ],
 459                                                                         [ "GLint *", "v" ] ], "glMultiTexCoord3ivSGIS", "GL_SGIS_multitexture" ],
 460       "glMultiTexCoord3sSGIS" => [ "glMultiTexCoord3sSGIS", "void", [ [ "GLenum", "target" ],
 461                                                                       [ "GLshort", "s" ],
 462                                                                       [ "GLshort", "t" ],
 463                                                                       [ "GLshort", "r" ] ], "glMultiTexCoord3sSGIS", "GL_SGIS_multitexture" ],
 464       "glMultiTexCoord3svSGIS" => [ "glMultiTexCoord3svSGIS", "void", [ [ "GLenum", "target" ],
 465                                                                         [ "GLshort *", "v" ] ], "glMultiTexCoord3svSGIS", "GL_SGIS_multitexture" ],
 466       "glMultiTexCoord4dSGIS" => [ "glMultiTexCoord4dSGIS", "void", [ [ "GLenum", "target" ],
 467                                                                       [ "GLdouble", "s" ],
 468                                                                       [ "GLdouble", "t" ],
 469                                                                       [ "GLdouble", "r" ],
 470                                                                       [ "GLdouble", "q" ] ], "glMultiTexCoord4dSGIS", "GL_SGIS_multitexture" ],
 471       "glMultiTexCoord4dvSGIS" => [ "glMultiTexCoord4dvSGIS", "void", [ [ "GLenum", "target" ],
 472                                                                         [ "GLdouble *", "v" ] ], "glMultiTexCoord4dvSGIS", "GL_SGIS_multitexture" ],
 473       "glMultiTexCoord4fSGIS" => [ "glMultiTexCoord4fSGIS", "void", [ [ "GLenum", "target" ],
 474                                                                       [ "GLfloat", "s" ],
 475                                                                       [ "GLfloat", "t" ],
 476                                                                       [ "GLfloat", "r" ],
 477                                                                       [ "GLfloat", "q" ] ], "glMultiTexCoord4fSGIS", "GL_SGIS_multitexture" ],
 478       "glMultiTexCoord4fvSGIS" => [ "glMultiTexCoord4fvSGIS", "void", [ [ "GLenum", "target" ],
 479                                                                         [ "GLfloat *", "v" ] ], "glMultiTexCoord4fvSGIS", "GL_SGIS_multitexture" ],
 480       "glMultiTexCoord4iSGIS" => [ "glMultiTexCoord4iSGIS", "void", [ [ "GLenum", "target" ],
 481                                                                       [ "GLint", "s" ],
 482                                                                       [ "GLint", "t" ],
 483                                                                       [ "GLint", "r" ],
 484                                                                       [ "GLint", "q" ] ], "glMultiTexCoord4iSGIS", "GL_SGIS_multitexture" ],
 485       "glMultiTexCoord4ivSGIS" => [ "glMultiTexCoord4ivSGIS", "void", [ [ "GLenum", "target" ],
 486                                                                         [ "GLint *", "v" ] ], "glMultiTexCoord4ivSGIS", "GL_SGIS_multitexture" ],
 487       "glMultiTexCoord4sSGIS" => [ "glMultiTexCoord4sSGIS", "void", [ [ "GLenum", "target" ],
 488                                                                       [ "GLshort", "s" ],
 489                                                                       [ "GLshort", "t" ],
 490                                                                       [ "GLshort", "r" ],
 491                                                                       [ "GLshort", "q" ] ], "glMultiTexCoord4sSGIS", "GL_SGIS_multitexture" ],
 492       "glMultiTexCoord4svSGIS" => [ "glMultiTexCoord4svSGIS", "void", [ [ "GLenum", "target" ],
 493                                                                         [ "GLshort *", "v" ] ], "glMultiTexCoord4svSGIS", "GL_SGIS_multitexture" ],
 494       "glMultiTexCoordPointerSGIS" => [ "glMultiTexCoordPointerSGIS", "void", [ [ "GLenum", "target" ],
 495                                                                                 [ "GLint", "size" ],
 496                                                                                 [ "GLenum", "type" ],
 497                                                                                 [ "GLsizei", "stride" ],
 498                                                                                 [ "GLvoid *", "pointer" ] ], "glMultiTexCoordPointerSGIS", "GL_SGIS_multitexture" ],
 499       "glSelectTextureSGIS" => [ "glSelectTextureSGIS", "void", [ [ "GLenum", "target" ] ], "glSelectTextureSGIS", "GL_SGIS_multitexture" ],
 500       "glSelectTextureCoordSetSGIS" => [ "glSelectTextureCoordSetSGIS", "void", [ [ "GLenum", "target" ] ], "glSelectTextureCoordSetSGIS", "GL_SGIS_multitexture" ],
 501       "glDeleteObjectBufferATI" => [ "glDeleteObjectBufferATI", "void", [ [ "GLuint", "buffer" ] ], "glDeleteObjectBufferATI", "GL_ATI_vertex_array_object" ]
 502       );
 503
 504 my @arg_names;
 505 my %arg_types;
 506 while (my $line = <REGISTRY>) {
 507     if ($line =~ /^\w*\(.*\)/) {
 508         # Get the function name (NOTE: the 'gl' prefix needs to be added later)
 509         my ($funcname, $args) = ($line =~ /^(\w*)\((.*)\)/);
 510         # and the argument names
 511         @arg_names = split /\s*,\s*/, $args;
 512
 513         # After get :
 514         #  - the return type
 515         #  - category (the extension the function is part of)
 516         #  - the argument types
 517         #  - the category the function belongs
 518         %arg_types = ();
 519         my $category = "";
 520         my $ret_type = "";
 521         while (1) {
 522             $line = <REGISTRY>;
 523             unless (defined($line)) {
 524                 last;
 525             } elsif ($line =~ /^\s*$/) {
 526                 if (($category eq "") || ($ret_type eq "")) {
 527                     die "Missing 'category' line in function $funcname.\n";
 528                 }
 529                 last;
 530             } elsif ($line =~ /\t*return\t*(\w*)/) {
 531                 ($ret_type) = ($line =~ /\t*return\s*(\w*)/);
 532                 $ret_type = $pseudo_to_opengl{$ret_type};
 533                 unless (defined($ret_type)) {
 534                     die "Unsupported return type in function $funcname\n";
 535                 }
 536             } elsif ($line =~ /^\t*category/) {
 537                 ($category) = ($line =~ /^\t*category\s*([\w-]*)/);
 538             } elsif ($line =~ /^\t*param/) {
 539                 my ($name, $base_type, $ext) = ($line =~ /\t*param\s*(\w*)\s*(\w*) (.*)/);
 540                 my $ptr = 0;
 541                 unless (defined($name)) {
 542                     chomp $line;
 543                     die "Broken spec file line $line in function $funcname\n";
 544                 }
 545
 546                 if ($ext =~ /array/) {
 547                     # This is a pointer
 548                     $ptr = 1;
 549                 } elsif ($ext =~ /value/) {
 550                     # And this a 'normal' value
 551                     $ptr = 0;
 552                 } else {
 553                     chomp $line;
 554                     die "Unsupported type : $line in function $funcname\n";
 555                 }
 556                 # Get the 'real' type and append a '*' in case of a pointer
 557                 my $type = $pseudo_to_opengl{$base_type};
 558                 unless (defined($type)) {
 559                     chomp $line;
 560                     die "Unsupported return type in function $funcname for type $base_type (line $line)\n";
 561                 }
 562                 if ($ptr) {
 563                     $type = "$type*";
 564                 }
 565
 566                 $arg_types{$name} = $type;
 567             }
 568         }
 569
 570         # Now, build the argument reference
 571         my $arg_ref = [ ];
 572         for (my $i = 0; $i < @arg_names; $i++) {
 573             unless (defined($arg_types{$arg_names[$i]})) {
 574                 print "@arg_names\n";
 575                 foreach (sort keys %arg_types) {
 576                     print "$_ => $arg_types{$_}\n";
 577                 }
 578                 die "Undefined type for $arg_names[$i] in function $funcname\n";
 579             }
 580
 581             push @$arg_ref, [ $arg_types{$arg_names[$i]}, $arg_names[$i] ];
 582         }
 583         my $func_ref = [ "gl$funcname",
 584                          $ret_type,
 585                          $arg_ref,
 586                          "gl$funcname",
 587                          "GL_$category" ];
 588
 589         # Now, put in one or the other hash table
 590         if ($norm_categories{$category}) {
 591             $norm_functions{"gl$funcname"} = $func_ref;
 592         } else {
 593             $ext_functions{"gl$funcname"} = $func_ref;
 594         }
 595     }
 596 }
 597
 598 #
 599 # Clean up the input files
 600 #
 601 close(TYPES);
 602 close(REGISTRY);
 603
 604 #
 605 # Now, generate the output files. First, the spec file.
 606 #
 607 open(SPEC, ">$spec_file");
 608
 609 foreach (sort keys %norm_functions) {
 610     my $func_name = $norm_functions{$_}->[0];
 611     print SPEC "@  stdcall $func_name( ";
 612     for (my $i = 0; $i < @{$norm_functions{$_}->[2]}; $i++) {
 613         my $type = $norm_functions{$_}->[2]->[$i]->[0];
 614         if ($type =~ /\*/) {
 615             print SPEC "ptr ";
 616         } elsif (defined($arg_conv{$type})) {
 617             print SPEC "$@$arg_conv{$type}[0] ";
 618         } else {
 619             die "No conversion for GL type $type...\n";
 620         }
 621     }
 622     print SPEC ") wine_$func_name\n";
 623 }
 624
 625 print SPEC "@  stub    glGetLevelParameterfv
 626 @  stub    glGetLevelParameteriv
 627 @  stdcall wglChoosePixelFormat(long ptr) gdi32.ChoosePixelFormat
 628 @  stdcall wglCopyContext(long long long) gdi32.wglCopyContext
 629 @  stdcall wglCreateContext(long) gdi32.wglCreateContext
 630 @  stdcall wglCreateLayerContext(long long)
 631 @  stdcall wglDeleteContext(long) gdi32.wglDeleteContext
 632 @  stdcall wglDescribeLayerPlane(long long long long ptr)
 633 @  stdcall wglDescribePixelFormat(long long long ptr) gdi32.DescribePixelFormat
 634 @  stdcall wglGetCurrentContext() gdi32.wglGetCurrentContext
 635 @  stdcall wglGetCurrentDC() gdi32.wglGetCurrentDC
 636 @  stub    wglGetDefaultProcAddress
 637 @  stdcall wglGetLayerPaletteEntries(long long long long ptr)
 638 @  stdcall wglGetPixelFormat(long) gdi32.GetPixelFormat
 639 @  stdcall wglGetProcAddress(str)
 640 @  stdcall wglMakeCurrent(long long) gdi32.wglMakeCurrent
 641 @  stdcall wglRealizeLayerPalette(long long long)
 642 @  stdcall wglSetLayerPaletteEntries(long long long long ptr)
 643 @  stdcall wglSetPixelFormat(long long ptr) gdi32.SetPixelFormat
 644 @  stdcall wglShareLists(long long) gdi32.wglShareLists
 645 @  stdcall wglSwapBuffers(long) gdi32.SwapBuffers
 646 @  stdcall wglSwapLayerBuffers(long long)
 647 @  stdcall wglUseFontBitmapsA(long long long long) gdi32.wglUseFontBitmapsA
 648 @  stdcall wglUseFontBitmapsW(long long long long) gdi32.wglUseFontBitmapsW
 649 @  stdcall wglUseFontOutlinesA(long long long long long long long ptr)
 650 @  stdcall wglUseFontOutlinesW(long long long long long long long ptr)
 651 ";
 652
 653 close(SPEC);
 654
 655 #
 656 # After the spec file, the opengl_norm.c file
 657 #
 658 open(NORM, ">$norm_file");
 659 print NORM "
 660 /* Auto-generated file... Do not edit ! */
 661
 662 #include \"config.h\"
 663 #include \"opengl_ext.h\"
 664 #include \"wine/debug.h\"
 665
 666 WINE_DEFAULT_DEBUG_CHANNEL(opengl);
 667 ";
 668 foreach (sort keys %norm_functions) {
 669     my $string = GenerateThunk($norm_functions{$_}, 1, "", $gen_thread_safe, "");
 670
 671     print NORM "\n$string" if $string;
 672 }
 673 close(NORM);
 674
 675 #
 676 # Finally, more complex, the opengl_ext.c file
 677 #
 678 open(EXT, ">$ext_file");
 679 print EXT "
 680 /* Auto-generated file... Do not edit ! */
 681
 682 #include \"config.h\"
 683 #include \"opengl_ext.h\"
 684 #include \"wine/debug.h\"
 685
 686 WINE_DEFAULT_DEBUG_CHANNEL(opengl);
 687
 688 ";
 689
 690 # The thunks themselves....
 691 my $count = keys %ext_functions;
 692 print EXT "enum extensions\n{\n";
 693 foreach (sort keys %ext_functions) {
 694     my $func_ref = $ext_functions{$_};
 695     print EXT "    EXT_$func_ref->[0],\n";
 696 }
 697 print EXT "    NB_EXTENSIONS\n};\n\n";
 698 print EXT "const int extension_registry_size = NB_EXTENSIONS;\n";
 699 print EXT "void *extension_funcs[NB_EXTENSIONS];\n";
 700 print EXT "\n/* The thunks themselves....*/";
 701 foreach (sort keys %ext_functions) {
 702     my $func_ref = $ext_functions{$_};
 703     my $local_var = "  " . ConvertType($func_ref->[1]) . " (*$ext_prefix$func_ref->[0])( ";
 704     for (my $i = 0; $i < @{$func_ref->[2]}; $i++) {
 705         my $type = ConvertType($func_ref->[2]->[$i]->[0]);
 706         $local_var .= "$type";
 707         if ($i+1 < @{$func_ref->[2]}) {
 708             $local_var .= ", ";
 709         } else {
 710             $local_var .= " ";
 711         }
 712     }
 713     $local_var .= 'void ' if (!@{$func_ref->[2]});
 714     $local_var .= ") = extension_funcs[EXT_$func_ref->[0]];\n";
 715     print EXT "\nstatic ", GenerateThunk($ext_functions{$_}, 0, $ext_prefix, $gen_thread_safe, $local_var);
 716 }
 717
 718 # Then the table giving the string <-> function correspondence */
 719 print EXT "\n\n/* The table giving the correspondence between names and functions */\n";
 720 print EXT "const OpenGL_extension extension_registry[NB_EXTENSIONS] = {\n";
 721 my $i = 0;
 722 foreach (sort keys %ext_functions) {
 723     my $func_ref = $ext_functions{$_};
 724     if ($func_ref->[0] eq $func_ref->[3])
 725     {
 726         print EXT "  { \"$func_ref->[0]\", \"$func_ref->[4]\", wine_$func_ref->[0] }";
 727     }
 728     if ($i != $count-1) {
 729         print EXT ",";
 730     }
 731     $i++;
 732     print EXT "\n";
 733 }
 734 print EXT "};\n";
 735
 736 close(EXT);