| blob | 2f2fcd59d2a41ea9f15868cfe79acb0fdf1df670 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53b)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(DLLDEFS,"")
25 if test "x$enable_debug" = "xno"
26 then
27 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
32 fi
34 AC_CANONICAL_HOST
35 case $host in
36 x86_64*linux*)
37 if test "x$enable_win64" != "xyes"
38 then
39 test -n "$CC" || CC="gcc -m32"
40 test -n "$LD" || LD="ld -m elf_i386"
41 test -n "$AS" || AS="as --32"
42 host_cpu="i386"
43 fi
44 ;;
45 esac
47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
48 case $host_cpu in
49 *i[[3456789]]86*)
50 if test "x$enable_win16" != "xno"
51 then
52 enable_win16="yes"
53 fi
54 ;;
55 esac
57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
59 if test "x$enable_win16" != "xyes"
60 then
61 WIN16_FILES=""
62 WIN16_INSTALL=""
63 fi
65 dnl **** Check for some programs ****
67 AC_PROG_MAKE_SET
68 AC_PROG_CC
69 AC_PROG_CXX
70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
74 [if test -z "$with_wine_tools"; then
75 if test "$cross_compiling" = "yes"; then
76 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
77 else
78 wine_cv_toolsdir="\$(TOPOBJDIR)"
79 fi
80 elif test -d "$with_wine_tools/tools/winebuild"; then
81 case $with_wine_tools in
82 /*) wine_cv_toolsdir="$with_wine_tools" ;;
83 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
84 esac
85 else
86 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
87 fi])
88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
90 AC_PATH_XTRA
91 AC_PROG_LEX
93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
94 dnl **** without one present.
95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
96 if test "$XLEX" = "none"
97 then
98 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
99 fi
101 dnl Check for bison
102 AC_CHECK_PROGS(BISON,bison,none)
103 if test "$BISON" = "none"
104 then
105 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
106 fi
108 AC_CHECK_TOOLS(AS,[gas as],as)
109 AC_CHECK_TOOL(LD,ld,ld)
110 AC_CHECK_TOOL(AR,ar,ar)
111 AC_PROG_RANLIB
112 AC_CHECK_TOOL(STRIP,strip,strip)
113 AC_CHECK_TOOL(WINDRES,windres,false)
114 AC_PROG_LN_S
115 WINE_PROG_LN
116 AC_PROG_EGREP
117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
118 AC_PROG_INSTALL
119 dnl Prepend src dir to install path dir if it's a relative path
120 case "$INSTALL" in
121 [[\\/$]]* | ?:[[\\/]]* ) ;;
122 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
123 esac
125 dnl Check for lint
126 AC_CHECK_PROGS(LINT, lclint lint)
127 if test "$LINT" = "lint"
128 then
129 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
130 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
131 fi
132 AC_SUBST(LINT)
133 AC_SUBST(LINTFLAGS)
135 dnl Check for various programs
136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
137 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
139 case $host_cpu in
140 *i[[3456789]]86*)
141 AC_CHECK_PROGS(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
142 ;;
143 esac
145 dnl **** Check for some libraries ****
147 dnl Check for -li386 for NetBSD and OpenBSD
148 AC_CHECK_LIB(i386,i386_set_ldt)
149 dnl Check for -lossaudio for NetBSD
150 AC_CHECK_LIB(ossaudio,_oss_ioctl)
151 dnl Check for -lnsl for Solaris
152 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
153 dnl Check for -lsocket for Solaris
154 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
155 dnl Check for -lresolv for Solaris
156 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
157 dnl Check for -lxpg4 for FreeBSD
158 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
159 dnl Check for -lpoll for Mac OS X/Darwin
160 AC_CHECK_LIB(poll,poll)
161 dnl Check for -lresolv for Mac OS X/Darwin
162 AC_CHECK_LIB(resolv,res_9_init)
163 dnl Check for -lpthread
164 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
166 AC_SUBST(XLIB,"")
167 AC_SUBST(XFILES,"")
168 AC_SUBST(OPENGLFILES,"")
169 AC_SUBST(GLU32FILES,"")
170 AC_SUBST(OPENGL_LIBS,"")
172 dnl **** Check for header files ****
174 AC_CHECK_HEADERS(\
175 IOKit/IOKitLib.h \
176 alsa/asoundlib.h \
177 arpa/inet.h \
178 arpa/nameser.h \
179 asm/types.h \
180 capi20.h \
181 cups/cups.h \
182 curses.h \
183 direct.h \
184 dlfcn.h \
185 elf.h \
186 float.h \
187 fontconfig/fontconfig.h \
188 getopt.h \
189 gif_lib.h \
190 ieeefp.h \
191 io.h \
192 jack/jack.h \
193 jpeglib.h \
194 lber.h \
195 lcms.h \
196 lcms/lcms.h \
197 ldap.h \
198 libaudioio.h \
199 link.h \
200 linux/capi.h \
201 linux/cdrom.h \
202 linux/compiler.h \
203 linux/hdreg.h \
204 linux/input.h \
205 linux/ioctl.h \
206 linux/joystick.h \
207 linux/major.h \
208 linux/param.h \
209 linux/serial.h \
210 linux/ucdrom.h \
211 mach/machine.h \
212 machine/cpu.h \
213 machine/limits.h \
214 machine/soundcard.h \
215 mntent.h \
216 ncurses.h \
217 netdb.h \
218 netinet/in.h \
219 netinet/in_systm.h \
220 netinet/tcp.h \
221 netinet/tcp_fsm.h \
222 openssl/err.h \
223 openssl/ssl.h \
224 poll.h \
225 process.h \
226 pthread.h \
227 pwd.h \
228 regex.h \
229 sched.h \
230 scsi/scsi.h \
231 scsi/scsi_ioctl.h \
232 scsi/sg.h \
233 soundcard.h \
234 stdint.h \
235 strings.h \
236 sys/asoundlib.h \
237 sys/cdio.h \
238 sys/elf32.h \
239 sys/epoll.h \
240 sys/errno.h \
241 sys/exec_elf.h \
242 sys/filio.h \
243 sys/ioctl.h \
244 sys/ipc.h \
245 sys/limits.h \
246 sys/link.h \
247 sys/lwp.h \
248 sys/mman.h \
249 sys/modem.h \
250 sys/msg.h \
251 sys/mtio.h \
252 sys/param.h \
253 sys/poll.h \
254 sys/ptrace.h \
255 sys/reg.h \
256 sys/scsiio.h \
257 sys/shm.h \
258 sys/signal.h \
259 sys/socket.h \
260 sys/sockio.h \
261 sys/soundcard.h \
262 sys/statvfs.h \
263 sys/strtio.h \
264 sys/syscall.h \
265 sys/sysctl.h \
266 sys/time.h \
267 sys/times.h \
268 sys/uio.h \
269 sys/un.h \
270 sys/vm86.h \
271 sys/wait.h \
272 syscall.h \
273 termios.h \
274 unicode/ubidi.h \
275 unistd.h \
276 utime.h \
277 valgrind/memcheck.h
278 )
279 AC_HEADER_STAT()
281 dnl **** Check for X11 ****
283 if test "$have_x" = "yes"
284 then
285 XLIB="-lXext -lX11"
286 ac_save_CPPFLAGS="$CPPFLAGS"
287 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
289 dnl *** All of the following tests require X11/Xlib.h
290 AC_CHECK_HEADERS([X11/Xlib.h \
291 X11/XKBlib.h \
292 X11/Xutil.h \
293 X11/extensions/shape.h \
294 X11/extensions/XInput.h \
295 X11/extensions/XShm.h \
296 X11/extensions/Xrandr.h \
297 X11/extensions/Xrender.h \
298 X11/extensions/xf86dga.h \
299 X11/extensions/xf86vmode.h],,,
300 [#ifdef HAVE_X11_XLIB_H
301 # include <X11/Xlib.h>
302 #endif
303 #ifdef HAVE_X11_XUTIL_H
304 # include <X11/Xutil.h>
305 #endif])
307 dnl *** Check for X keyboard extension
308 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
309 then
310 AC_CHECK_LIB(X11, XkbQueryExtension,
311 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
312 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
313 fi
315 dnl *** Check for X Shm extension
316 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
317 then
318 AC_CHECK_LIB(Xext, XShmQueryExtension,
319 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
320 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
321 fi
323 dnl *** Check for X shape extension
324 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
325 then
326 AC_CHECK_LIB(Xext,XShapeQueryExtension,
327 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
328 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
329 fi
331 dnl *** Check for XFree86 DGA / DGA 2.0 extension
332 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
333 then
334 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
335 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
336 [Define if you have the Xxf86dga library version 2])
337 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
338 ],,
339 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
340 fi
342 dnl *** Check for XFree86 VMODE extension
343 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
344 then
345 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
346 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
347 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
348 ],,
349 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
350 fi
352 dnl *** Check for X RandR extension
353 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
354 then
355 AC_TRY_COMPILE([#include <X11/Xlib.h>
356 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
357 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
358 fi
360 dnl *** Check for Transform functions in Xrender
361 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
362 then
363 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
364 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
365 [Define if Xrender has the XRenderSetPictureTransform function])],,
366 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
367 fi
368 dnl *** End of X11/Xlib.h check
370 dnl Check for the presence of OpenGL
371 if test "x$with_opengl" != "xno"
372 then
373 AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h,,,
374 [#ifdef HAVE_GL_GLX_H
375 # include <GL/glx.h>
376 #endif])
377 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
378 then
379 dnl Check for some problems due to old Mesa versions
380 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
381 AC_TRY_COMPILE(
382 [#include <GL/gl.h>],
383 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
384 [wine_cv_opengl_version_OK="yes"],
385 [wine_cv_opengl_version_OK="no"]
386 )
387 )
389 if test "$wine_cv_opengl_version_OK" = "yes"
390 then
391 dnl Check for the presence of the library
392 AC_CHECK_LIB(GL,glXCreateContext,
393 OPENGL_LIBS="-lGL"
394 ,,
395 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
397 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
398 then
399 OPENGLFILES='$(OPENGLFILES)'
400 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
401 else
402 if test -f /usr/X11R6/lib/libGL.a
403 then
404 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
405 This prevents linking to OpenGL. Delete the file and restart configure.])
406 fi
407 fi
409 dnl Check for GLU32 library.
410 AC_CHECK_LIB(GLU,gluLookAt,
411 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
412 GLU32FILES='$(GLU32FILES)']
413 ,,
414 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
415 )
416 fi
418 dnl Check for glut32 library.
419 AC_CHECK_LIB(glut,glutMainLoop,
420 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
421 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
422 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
423 fi
424 fi
426 dnl **** Check for NAS ****
427 AC_SUBST(NASLIBS,"")
428 AC_CHECK_HEADERS(audio/audiolib.h,
429 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
430 AC_CHECK_LIB(audio,AuCreateFlow,
431 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
432 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
433 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
435 CPPFLAGS="$ac_save_CPPFLAGS"
436 XFILES='$(XFILES)'
437 else
438 XLIB=""
439 X_CFLAGS=""
440 X_LIBS=""
441 fi
443 dnl **** Check for libxml2 ****
445 AC_SUBST(XML2LIBS,"")
446 AC_SUBST(XML2INCL,"")
447 AC_SUBST(XSLTLIBS,"")
448 AC_SUBST(XSLTINCL,"")
449 if test "$PKG_CONFIG" != "false"
450 then
451 ac_save_CPPFLAGS="$CPPFLAGS"
452 ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0`"
453 ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0`"
454 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
455 AC_CHECK_HEADERS(libxml/parser.h,
456 [AC_CHECK_LIB(xml2, xmlParseMemory,
457 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
458 XML2LIBS="$ac_xml_libs"
459 XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
460 AC_CHECK_LIB(xml2, xmlReadMemory,
461 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
462 ])
463 CPPFLAGS="$ac_save_CPPFLAGS"
464 ac_xslt_libs="`$PKG_CONFIG --libs libxslt`"
465 ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt`"
466 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
467 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
468 [AC_CHECK_LIB(xslt, xsltCompilePattern,
469 [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
470 XSLTLIBS="$ac_xslt_libs"
471 XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
472 ],,
473 [#ifdef HAVE_LIBXSLT_PATTERN_H
474 # include <libxslt/pattern.h>
475 #endif])
476 CPPFLAGS="$ac_save_CPPFLAGS"
477 fi
479 dnl **** Check which curses lib to use ***
480 CURSESLIBS=""
481 if test "x$with_curses" != "xno"
482 then
483 if test "$ac_cv_header_ncurses_h" = "yes"
484 then
485 AC_CHECK_LIB(ncurses,waddch,
486 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
487 CURSESLIBS="-lncurses"])
488 elif test "$ac_cv_header_curses_h" = "yes"
489 then
490 AC_CHECK_LIB(curses,waddch,
491 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
492 CURSESLIBS="-lcurses"])
493 fi
494 fi
495 AC_SUBST(CURSESLIBS)
497 dnl **** Check for SANE ****
498 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
499 AC_SUBST(SANELIBS,"")
500 AC_SUBST(SANEINCL,"")
501 if test "$sane_devel" != "no"
502 then
503 SANELIBS="`$sane_devel --libs`"
504 SANEINCL="`$sane_devel --cflags`"
505 ac_save_CPPFLAGS="$CPPFLAGS"
506 ac_save_LIBS="$LIBS"
507 CPPFLAGS="$CPPFLAGS $SANEINCL"
508 LIBS="$LIBS $SANELIBS"
509 AC_CHECK_HEADER(sane/sane.h,
510 [AC_CHECK_LIB(sane,sane_open,
511 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
512 [SANELIBS=""
513 SANEINCL=""])],
514 [SANELIBS=""
515 SANEINCL=""])
516 LIBS="$ac_save_LIBS"
517 CPPFLAGS="$ac_save_CPPFLAGS"
518 fi
520 dnl **** Check for the ICU library ****
521 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
522 then
523 saved_libs="$LIBS"
524 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
525 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
526 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
527 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
528 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
529 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
530 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
531 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
532 AC_MSG_RESULT(yes)],
533 [AC_MSG_RESULT(no)])
534 LIBS="$saved_libs"
535 fi
537 dnl **** Check for LittleCMS ***
538 AC_SUBST(LCMSLIBS,"")
539 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
540 then
541 AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
542 [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
543 LCMSLIBS="-llcms"])
544 fi
546 dnl **** Check for OpenLDAP ***
547 AC_SUBST(LDAPLIBS,"")
548 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
549 then
550 AC_CHECK_LIB(ldap_r, ldap_initialize,
551 [AC_CHECK_LIB(lber, ber_init,
552 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
553 LDAPLIBS="-lldap_r -llber"],,
554 [$LIBPTHREAD])],,
555 [$LIBPTHREAD])
556 WINE_CHECK_LIB_FUNCS(\
557 ldap_count_references \
558 ldap_first_reference \
559 ldap_next_reference \
560 ldap_parse_reference,
561 [$LDAPLIBS $LIBPTHREAD])
562 fi
564 dnl **** Check for FreeType 2 ****
565 AC_SUBST(FREETYPELIBS,"")
566 AC_SUBST(FREETYPEINCL,"")
567 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
568 if test "$ft_lib" = "no"
569 then
570 wine_cv_msg_freetype=no
571 else
572 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
573 if test "$ft_devel" = "no"
574 then
575 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
576 if test "$ft_devel2" = "freetype2-config"
577 then
578 ft_devel=$ft_devel2
579 fi
580 fi
581 if test "$ft_devel" = "no"
582 then
583 wine_cv_msg_freetype=yes
584 else
585 FREETYPELIBS=`$ft_devel --libs`
586 FREETYPEINCL=`$ft_devel --cflags`
587 ac_save_CPPFLAGS="$CPPFLAGS"
588 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
589 AC_CHECK_HEADERS(ft2build.h \
590 freetype/freetype.h \
591 freetype/ftglyph.h \
592 freetype/tttables.h \
593 freetype/ftnames.h \
594 freetype/ftsnames.h \
595 freetype/ttnameid.h \
596 freetype/ftoutln.h \
597 freetype/ftwinfnt.h \
598 freetype/ftmodapi.h \
599 freetype/internal/sfnt.h,,,
600 [#if HAVE_FT2BUILD_H
601 #include <ft2build.h>
602 #endif])
603 AC_TRY_CPP([#include <ft2build.h>
604 #include <freetype/fttrigon.h>],
605 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
606 [Define if you have the <freetype/fttrigon.h> header file.])
607 wine_cv_fttrigon=yes],
608 wine_cv_fttrigon=no)
609 CPPFLAGS="$ac_save_CPPFLAGS"
610 dnl Check that we have at least freetype/freetype.h
611 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
612 then
613 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
614 wine_cv_msg_freetype=no
615 else
616 FREETYPELIBS=""
617 FREETYPEINCL=""
618 wine_cv_msg_freetype=yes
619 fi
620 fi
621 fi
623 dnl Only build the fonts dir if we have both freetype and fontforge
624 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
625 then
626 AC_SUBST(FONTSSUBDIRS,"fonts")
627 fi
629 dnl **** Check for parport (currently Linux only) ****
630 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
631 AC_TRY_COMPILE(
632 [#include <linux/ppdev.h>],
633 [ioctl (1,PPCLAIM,0)],
634 [ac_cv_c_ppdev="yes"],
635 [ac_cv_c_ppdev="no"])
636 )
637 if test "$ac_cv_c_ppdev" = "yes"
638 then
639 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
640 fi
642 dnl **** Check for va_copy ****
643 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
644 AC_TRY_LINK(
645 [#include <stdarg.h>],
646 [va_list ap1, ap2;
647 va_copy(ap1,ap2);
648 ],
649 [ac_cv_c_va_copy="yes"],
650 [ac_cv_c_va_copy="no"])
651 )
652 if test "$ac_cv_c_va_copy" = "yes"
653 then
654 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
655 fi
656 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
657 AC_TRY_LINK(
658 [#include <stdarg.h>],
659 [va_list ap1, ap2;
660 __va_copy(ap1,ap2);
661 ],
662 [ac_cv_c___va_copy="yes"],
663 [ac_cv_c___va_copy="no"])
664 )
665 if test "$ac_cv_c___va_copy" = "yes"
666 then
667 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
668 fi
670 dnl **** Check for sigsetjmp ****
671 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
672 AC_TRY_LINK(
673 [#include <setjmp.h>],
674 [sigjmp_buf buf;
675 sigsetjmp( buf, 1 );
676 siglongjmp( buf, 1 );],
677 [ac_cv_c_sigsetjmp="yes"],
678 [ac_cv_c_sigsetjmp="no"])
679 )
680 if test "$ac_cv_c_sigsetjmp" = "yes"
681 then
682 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
683 fi
685 dnl **** Check for pthread_rwlock_t ****
686 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
687 #include <pthread.h>])
689 dnl **** Check for pthread functions ****
690 WINE_CHECK_LIB_FUNCS(\
691 pthread_getattr_np \
692 pthread_get_stackaddr_np \
693 pthread_get_stacksize_np,
694 [$LIBPTHREAD])
696 dnl **** Check for aRts Sound Server ****
697 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
698 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
699 then
700 ARTSC_CFLAGS=""
701 for i in `$ARTSCCONFIG --cflags`
702 do
703 case "$i" in
704 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
705 esac
706 done
707 ARTSC_LIBS=`$ARTSCCONFIG --libs`
708 save_CFLAGS="$CFLAGS"
709 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
710 AC_CHECK_LIB(artsc,arts_init,
711 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
712 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
713 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
714 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
715 $ARTSC_LIBS)
716 CFLAGS="$save_CFLAGS"
717 fi
719 dnl **** Check for EsounD ****
720 AC_PATH_PROG(ESDCONFIG, esd-config)
721 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
722 then
723 ESD_CFLAGS=""
724 for i in `$ESDCONFIG --cflags`
725 do
726 case "$i" in
727 -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
728 esac
729 done
730 ESD_LIBS=`$ESDCONFIG --libs`
731 save_CFLAGS="$CFLAGS"
732 CFLAGS="$CFLAGS $ESD_CFLAGS"
733 AC_CHECK_LIB(esd,esd_open_sound,
734 [AC_SUBST(ESDLIBS, $ESD_LIBS)
735 AC_SUBST(ESDINCL, $ESD_CFLAGS)
736 AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
737 CFLAGS="$save_CFLAGS"
738 fi
740 dnl **** Check for ALSA 1.x ****
741 AC_SUBST(ALSALIBS,"")
742 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
743 then
744 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
745 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
746 #include <alsa/asoundlib.h>
747 #elif defined(HAVE_SYS_ASOUNDLIB_H)
748 #include <sys/asoundlib.h>
749 #endif],
750 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
751 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
752 ALSALIBS="-lasound"])])
753 fi
755 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
757 AC_SUBST(AUDIOIOLIBS,"")
758 if test "$ac_cv_header_libaudioio_h" = "yes"
759 then
760 AC_CHECK_LIB(audioio,AudioIOGetVersion,
761 [AUDIOIOLIBS="-laudioio"
762 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
763 fi
765 dnl **** Check for capi4linux ****
767 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
768 then
769 AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
770 fi
772 dnl **** Check for gcc specific options ****
774 AC_SUBST(EXTRACFLAGS,"")
775 if test "x${GCC}" = "xyes"
776 then
777 EXTRACFLAGS="-Wall -pipe"
779 dnl Check for strength-reduce bug
780 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
781 AC_TRY_RUN([
782 int L[[4]] = {0,1,2,3};
783 int main(void) {
784 static int Array[[3]];
785 unsigned int B = 3;
786 int i;
787 for(i=0; i<B; i++) Array[[i]] = i - 3;
788 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
789 L[[i]] = 4;
791 exit( Array[[1]] != -2 || L[[2]] != 3);
792 }],
793 ac_cv_c_gcc_strength_bug="no",
794 ac_cv_c_gcc_strength_bug="yes",
795 ac_cv_c_gcc_strength_bug="yes") )
796 if test "$ac_cv_c_gcc_strength_bug" = "yes"
797 then
798 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
799 fi
801 dnl Check for -fshort-wchar
802 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
803 [WINE_TRY_CFLAGS([-fshort-wchar],
804 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
805 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
806 then
807 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
808 fi
810 dnl Check for -fno-strict-aliasing
811 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
812 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
813 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
814 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
815 then
816 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
817 fi
819 dnl Check for -gstabs+ option
820 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
821 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
822 if test "$ac_cv_c_gcc_gstabs" = "yes"
823 then
824 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
825 fi
827 dnl Check for -Wdeclaration-after-statement option
828 AC_CACHE_CHECK([for gcc -Wdeclaration-after-statement support], ac_cv_c_gcc_decl_after_statement,
829 [WINE_TRY_CFLAGS([-Wdeclaration-after-statement],ac_cv_c_gcc_decl_after_statement="yes", ac_cv_c_gcc_decl_after_statement="no")])
830 if test "$ac_cv_c_gcc_decl_after_statement" = "yes"
831 then
832 EXTRACFLAGS="$EXTRACFLAGS -Wdeclaration-after-statement"
833 fi
835 dnl Check for noisy string.h
836 saved_CFLAGS="$CFLAGS"
837 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
838 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
839 AC_TRY_COMPILE([#include <string.h>],[],
840 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
841 CFLAGS="$saved_CFLAGS"
842 if test "$ac_cv_c_string_h_warnings" = "no"
843 then
844 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
845 fi
847 AC_SUBST(BUILTINFLAG,"")
848 saved_CFLAGS="$CFLAGS"
849 CFLAGS="$CFLAGS -Werror"
850 AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
851 AC_TRY_COMPILE([],
852 [int iswlower(unsigned short);],
853 [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
854 CFLAGS="$saved_CFLAGS"
855 if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
856 then
857 BUILTINFLAG=""
858 for builtin in \
859 iswalnum iswalpha iswcntrl iswdigit iswgraph iswlower \
860 iswprint iswpunct iswspace iswupper iswxdigit towlower towupper
861 do
862 BUILTINFLAG="$BUILTINFLAG -fno-builtin-$builtin"
863 done
864 fi
865 fi
867 dnl **** Check how to define a function in assembly code ****
869 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
870 WINE_TRY_ASM_LINK(
871 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
872 ac_cv_asm_func_def=".def",
873 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
874 ac_cv_asm_func_def=".type @function",
875 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
876 ac_cv_asm_func_def=".type 2",
877 ac_cv_asm_func_def="unknown")])]))
879 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
880 case "$ac_cv_asm_func_def" in
881 ".def")
882 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
883 ".type @function")
884 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
885 ".type 2")
886 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
887 *)
888 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
889 esac
891 dnl **** Check for underscore on external symbols ****
893 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
894 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
895 [extern int ac_test;],
896 [if (ac_test) return 1],
897 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
899 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
900 if test "$ac_cv_c_extern_prefix" = "yes"
901 then
902 AC_DEFINE([__ASM_NAME(name)], ["_" name])
903 else
904 AC_DEFINE([__ASM_NAME(name)], [name])
905 fi
907 dnl **** Check for working dll ****
909 AC_SUBST(DLLEXT,"")
910 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
911 AC_SUBST(DLLIBS,"")
912 AC_SUBST(LDSHARED,"")
913 AC_SUBST(LDDLLFLAGS,"")
914 AC_SUBST(LIBEXT,"so")
915 AC_SUBST(IMPLIBEXT,"def")
917 case $host_os in
918 cygwin*|mingw32*)
919 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
920 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
921 if test "$DLLWRAP" = "false"; then
922 LIBEXT="a"
923 else
924 dnl FIXME - check whether dllwrap works correctly...
925 LIBEXT="dll"
926 fi
927 IMPLIBEXT="a"
928 dnl We can't build 16-bit NE dlls
929 WIN16_FILES=""
930 WIN16_INSTALL=""
931 ;;
932 *)
933 if test "$ac_cv_header_dlfcn_h" = "yes"
934 then
935 AC_CHECK_FUNCS(dlopen,,
936 [AC_CHECK_LIB(dl,dlopen,
937 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
938 DLLIBS="-ldl"],
939 [LIBEXT="a"])])
940 WINE_CHECK_LIB_FUNCS(dladdr,[$DLLIBS])
941 else
942 LIBEXT="a"
943 fi
945 if test "$LIBEXT" = "so"
946 then
947 DLLFLAGS="$DLLFLAGS -fPIC"
948 DLLEXT=".so"
949 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
950 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
951 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
952 if test "$ac_cv_c_dll_gnuelf" = "yes"
953 then
954 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
955 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
956 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
957 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
958 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
959 if test "$ac_cv_c_dll_zdefs" = "yes"
960 then
961 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
962 fi
964 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
965 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
966 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
967 if test "$ac_cv_c_dll_init_fini" = "yes"
968 then
969 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
970 fi
972 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
973 [echo '{ global: *; };' >conftest.map
974 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
975 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
976 rm -f conftest.map])
977 if test "$ac_cv_c_ld_version_scripts" = "yes"
978 then
979 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
980 fi
982 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
983 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
984 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
985 if test "$ac_cv_c_export_dynamic" = "yes"
986 then
987 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
988 fi
990 AC_CACHE_CHECK([whether the linker accepts --rpath], ac_cv_ld_rpath,
991 [WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
992 ac_cv_ld_rpath="yes",ac_cv_ld_rpath="no")])
993 if test "$ac_cv_ld_rpath" = "yes"
994 then
995 AC_SUBST(LDEXERPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])
996 fi
998 case $host_cpu in
999 *i[[3456789]]86*)
1000 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
1001 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1002 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
1003 if test "$ac_cv_ld_reloc_exec" = "yes"
1004 then
1005 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1006 fi
1007 ;;
1008 esac
1010 else
1011 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1012 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1013 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1014 if test "$ac_cv_c_dll_unixware" = "yes"
1015 then
1016 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1017 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1019 else
1020 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1021 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1022 if test "$ac_cv_c_dll_macho" = "yes"
1023 then
1024 LIBEXT="dylib"
1025 LDDLLFLAGS="-bundle"
1026 LDSHARED="\$(CC) -dynamiclib"
1027 STRIP="$STRIP -u -r"
1028 dnl declare needed frameworks
1029 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1030 AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1031 AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7ffe0000"])
1032 case $host_cpu in
1033 *powerpc*)
1034 CFLAGS="$CFLAGS -ffixed-r13"
1035 LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"
1036 ;;
1037 esac
1039 else
1040 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1041 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1042 if test "$ac_cv_c_dll_hpux" = "yes"
1043 then
1044 LIBEXT="sl"
1045 DLLEXT=".sl"
1046 LDDLLFLAGS="-shared -fPIC"
1047 LDSHARED="\$(CC) -shared"
1048 fi
1049 fi
1050 fi
1051 fi
1052 fi
1054 dnl Check for cross compiler to build test programs
1055 AC_SUBST(CROSSTEST,"")
1056 if test "$cross_compiling" = "no"
1057 then
1058 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1059 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1060 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1061 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1062 fi
1063 ;;
1064 esac
1066 if test "$LIBEXT" = "a"; then
1067 AC_MSG_ERROR(
1068 [could not find a way to build shared libraries.
1069 It is currently not possible to build Wine without shared library
1070 (.so) support to allow transparent switch between .so and .dll files.
1071 If you are using Linux, you will need a newer binutils.]
1072 )
1073 fi
1075 case $build_os in
1076 cygwin*|mingw32*)
1077 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1078 darwin*|macosx*)
1079 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1080 *)
1081 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1082 esac
1084 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1085 case $host_os in
1086 mingw32*)
1087 AC_SUBST(CRTLIBS,"-lmsvcrt")
1088 AC_SUBST(SOCKETLIBS,"-lws2_32")
1089 ;;
1090 esac
1092 case $host_cpu in
1093 *i[[3456789]]86*)
1094 case $host_os in
1095 linux* | k*bsd*-gnu)
1096 AC_SUBST(MAIN_BINARY,"wine-glibc")
1097 AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1098 darwin*)
1099 AC_SUBST(MAIN_BINARY,"wine-pthread") ;;
1100 *)
1101 AC_SUBST(MAIN_BINARY,"wine-kthread") ;;
1102 esac
1103 ;;
1104 *) AC_SUBST(MAIN_BINARY,"wine-pthread") ;;
1105 esac
1107 dnl **** Get the soname for libraries that we load dynamically ****
1109 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1110 then
1111 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1112 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1113 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1114 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1115 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1116 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1117 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1118 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1119 WINE_GET_SONAME(cups,cupsGetDefault)
1120 WINE_GET_SONAME(jack,jack_client_new)
1121 WINE_GET_SONAME(fontconfig,FcInit)
1122 WINE_GET_SONAME(ssl,SSL_library_init)
1123 WINE_GET_SONAME(crypto,BIO_new_socket)
1124 WINE_GET_SONAME(ncurses,waddch)
1125 WINE_GET_SONAME(curses,waddch)
1126 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1127 WINE_GET_SONAME(ungif,DGifOpen)
1128 WINE_GET_SONAME(gif,DGifOpen)
1129 WINE_GET_SONAME(capi20,capi20_isinstalled)
1130 fi
1133 dnl **** Check for functions ****
1135 AC_CHECK_FUNCS(\
1136 _lwp_create \
1137 _lwp_self \
1138 _pclose \
1139 _popen \
1140 _snprintf \
1141 _spawnvp \
1142 _stricmp \
1143 _strnicmp \
1144 _vsnprintf \
1145 asctime_r \
1146 chsize \
1147 clone \
1148 epoll_create \
1149 ffs \
1150 finite \
1151 fork \
1152 fpclass \
1153 fstatfs \
1154 fstatvfs \
1155 ftruncate \
1156 futimes \
1157 futimesat \
1158 getaddrinfo \
1159 getnetbyname \
1160 getopt_long \
1161 getpagesize \
1162 getprotobyname \
1163 getprotobynumber \
1164 getpwuid \
1165 getservbyport \
1166 gettid \
1167 gettimeofday \
1168 getuid \
1169 inet_network \
1170 lstat \
1171 memmove \
1172 mmap \
1173 pclose \
1174 popen \
1175 pread \
1176 pwrite \
1177 readlink \
1178 rfork \
1179 sched_yield \
1180 select \
1181 sendmsg \
1182 settimeofday \
1183 sigaltstack \
1184 sigprocmask \
1185 snprintf \
1186 spawnvp \
1187 statfs \
1188 statvfs \
1189 strcasecmp \
1190 strerror \
1191 strncasecmp \
1192 tcgetattr \
1193 timegm \
1194 usleep \
1195 vsnprintf \
1196 wait4 \
1197 waitpid \
1198 )
1200 dnl **** Checks for headers that depend on other ones ****
1202 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
1203 [#include <sys/types.h>
1204 #if HAVE_SYS_PARAM_H
1205 # include <sys/param.h>
1206 #endif])
1208 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
1209 [#include <sys/types.h>
1210 #if HAVE_SYS_SOCKET_H
1211 # include <sys/socket.h>
1212 #endif])
1214 AC_CHECK_HEADERS([resolv.h],,,
1215 [#include <sys/types.h>
1216 #if HAVE_SYS_SOCKET_H
1217 # include <sys/socket.h>
1218 #endif
1219 #if HAVE_NETINET_IN_H
1220 # include <netinet/in.h>
1221 #endif
1222 #if HAVE_ARPA_NAMESER_H
1223 # include <arpa/nameser.h>
1224 #endif])
1226 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1228 AC_CHECK_HEADERS([linux/ipx.h linux/videodev.h],,,
1229 [#ifdef HAVE_SYS_TIME_H
1230 #include <sys/time.h>
1231 #endif
1232 #include <sys/types.h>
1233 #ifdef HAVE_ASM_TYPES_H
1234 #include <asm/types.h>
1235 #endif])
1237 dnl **** Check for types ****
1239 AC_C_CONST
1240 AC_C_INLINE
1241 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1242 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1243 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1245 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1246 [#ifdef HAVE_LINUX_INPUT_H
1247 #include <linux/input.h>
1248 #endif])
1250 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1251 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1252 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1253 if test "$wine_cv_have_sigaddset" = "yes"
1254 then
1255 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1256 fi
1259 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1260 wine_cv_linux_gethostbyname_r_6,
1261 AC_TRY_LINK([
1262 #include <netdb.h>
1263 ], [
1264 char *name=NULL;
1265 struct hostent he;
1266 struct hostent *result;
1267 char *buf=NULL;
1268 int bufsize=0;
1269 int res,errnr;
1270 char *addr=NULL;
1271 int addrlen=0;
1272 int addrtype=0;
1273 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1274 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1275 ],
1276 wine_cv_linux_gethostbyname_r_6=yes,
1277 wine_cv_linux_gethostbyname_r_6=no
1278 )
1279 )
1280 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1281 then
1282 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1283 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1284 fi
1286 if test "$ac_cv_header_linux_joystick_h" = "yes"
1287 then
1288 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1289 wine_cv_linux_joystick_22_api,
1290 AC_TRY_COMPILE([
1291 #include <sys/ioctl.h>
1292 #include <linux/joystick.h>
1294 struct js_event blub;
1295 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1296 #error "no 2.2 header"
1297 #endif
1298 ],/*empty*/,
1299 wine_cv_linux_joystick_22_api=yes,
1300 wine_cv_linux_joystick_22_api=no,
1301 wine_cv_linux_joystick_22_api=no
1302 )
1303 )
1304 if test "$wine_cv_linux_joystick_22_api" = "yes"
1305 then
1306 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1307 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1308 fi
1309 fi
1311 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1313 dnl Check for statfs members
1314 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1315 [#include <sys/types.h>
1316 #ifdef HAVE_SYS_PARAM_H
1317 # include <sys/param.h>
1318 #endif
1319 #ifdef HAVE_SYS_MOUNT_H
1320 # include <sys/mount.h>
1321 #endif
1322 #ifdef HAVE_SYS_VFS_H
1323 # include <sys/vfs.h>
1324 #endif
1325 #ifdef HAVE_SYS_STATFS_H
1326 # include <sys/statfs.h>
1327 #endif])
1329 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1330 [#ifdef HAVE_SYS_STATVFS_H
1331 #include <sys/statvfs.h>
1332 #endif])
1334 dnl Check for socket structure members
1335 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1336 [#include <sys/types.h>
1337 #ifdef HAVE_SYS_SOCKET_H
1338 # include <sys/socket.h>
1339 #endif
1340 #ifdef HAVE_SYS_UN_H
1341 # include <sys/un.h>
1342 #endif])
1344 dnl Check for scsireq_t and sg_io_hdr_t members
1345 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1346 [#include <sys/types.h>
1347 #ifdef HAVE_SCSI_SG_H
1348 #include <scsi/sg.h>
1349 #endif])
1351 dnl Check for siginfo_t members
1352 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1354 dnl Check for struct mtget members
1355 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1356 [#include <sys/types.h>
1357 #ifdef HAVE_SYS_MTIO_H
1358 #include <sys/mtio.h>
1359 #endif])
1361 dnl Check for struct option
1362 AC_CHECK_MEMBERS([struct option.name],,,
1363 [#ifdef HAVE_GETOPT_H
1364 #include <getopt.h>
1365 #endif])
1367 dnl Check for stat.st_blocks
1368 AC_CHECK_MEMBERS([struct stat.st_blocks])
1370 dnl Check for the external timezone variables timezone and daylight
1371 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1372 AC_TRY_LINK([#include <time.h>],[timezone;],
1373 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1374 if test "$ac_cv_have_timezone" = "yes"
1375 then
1376 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1377 fi
1378 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1379 AC_TRY_LINK([#include <time.h>],[daylight;],
1380 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1381 if test "$ac_cv_have_daylight" = "yes"
1382 then
1383 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1384 fi
1386 dnl *** check for the need to define platform-specific symbols
1388 case $host_cpu in
1389 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1390 *x86_64*) WINE_CHECK_DEFINE([__x86_64__]) ;;
1391 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1392 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1393 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1394 esac
1396 case $host_vendor in
1397 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1398 esac
1400 dnl **** Generate output files ****
1402 AH_TOP([#define __WINE_CONFIG_H])
1404 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1405 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1406 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1407 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1408 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1409 WINE_CONFIG_EXTRA_DIR(include/wine)
1411 MAKE_RULES=Make.rules
1412 AC_SUBST_FILE(MAKE_RULES)
1414 MAKE_DLL_RULES=dlls/Makedll.rules
1415 AC_SUBST_FILE(MAKE_DLL_RULES)
1417 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1418 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1420 MAKE_TEST_RULES=dlls/Maketest.rules
1421 AC_SUBST_FILE(MAKE_TEST_RULES)
1423 MAKE_LIB_RULES=libs/Makelib.rules
1424 AC_SUBST_FILE(MAKE_LIB_RULES)
1426 MAKE_PROG_RULES=programs/Makeprog.rules
1427 AC_SUBST_FILE(MAKE_PROG_RULES)
1429 AC_CONFIG_FILES([
1430 Make.rules
1431 dlls/Makedll.rules
1432 dlls/Makeimplib.rules
1433 dlls/Maketest.rules
1434 libs/Makelib.rules
1435 programs/Makeprog.rules
1436 Makefile
1437 dlls/Makefile
1438 dlls/activeds/Makefile
1439 dlls/advapi32/Makefile
1440 dlls/advapi32/tests/Makefile
1441 dlls/advpack/Makefile
1442 dlls/advpack/tests/Makefile
1443 dlls/amstream/Makefile
1444 dlls/atl/Makefile
1445 dlls/avicap32/Makefile
1446 dlls/avifil32/Makefile
1447 dlls/cabinet/Makefile
1448 dlls/cabinet/tests/Makefile
1449 dlls/capi2032/Makefile
1450 dlls/cards/Makefile
1451 dlls/cfgmgr32/Makefile
1452 dlls/comcat/Makefile
1453 dlls/comctl32/Makefile
1454 dlls/comctl32/tests/Makefile
1455 dlls/commdlg/Makefile
1456 dlls/crtdll/Makefile
1457 dlls/crypt32/Makefile
1458 dlls/crypt32/tests/Makefile
1459 dlls/cryptdll/Makefile
1460 dlls/ctl3d32/Makefile
1461 dlls/d3d8/Makefile
1462 dlls/d3d9/Makefile
1463 dlls/d3d9/tests/Makefile
1464 dlls/d3dim/Makefile
1465 dlls/d3drm/Makefile
1466 dlls/d3dx8/Makefile
1467 dlls/d3dxof/Makefile
1468 dlls/dbghelp/Makefile
1469 dlls/dciman32/Makefile
1470 dlls/ddraw/Makefile
1471 dlls/ddraw/tests/Makefile
1472 dlls/devenum/Makefile
1473 dlls/dinput/Makefile
1474 dlls/dinput/tests/Makefile
1475 dlls/dinput8/Makefile
1476 dlls/dmband/Makefile
1477 dlls/dmcompos/Makefile
1478 dlls/dmime/Makefile
1479 dlls/dmloader/Makefile
1480 dlls/dmscript/Makefile
1481 dlls/dmstyle/Makefile
1482 dlls/dmsynth/Makefile
1483 dlls/dmusic/Makefile
1484 dlls/dmusic32/Makefile
1485 dlls/dplay/Makefile
1486 dlls/dplayx/Makefile
1487 dlls/dpnet/Makefile
1488 dlls/dpnhpast/Makefile
1489 dlls/dsound/Makefile
1490 dlls/dsound/tests/Makefile
1491 dlls/dswave/Makefile
1492 dlls/dxdiagn/Makefile
1493 dlls/dxerr8/Makefile
1494 dlls/dxerr9/Makefile
1495 dlls/dxguid/Makefile
1496 dlls/gdi/Makefile
1497 dlls/gdi/tests/Makefile
1498 dlls/glu32/Makefile
1499 dlls/glut32/Makefile
1500 dlls/hhctrl.ocx/Makefile
1501 dlls/iccvid/Makefile
1502 dlls/icmp/Makefile
1503 dlls/ifsmgr.vxd/Makefile
1504 dlls/imagehlp/Makefile
1505 dlls/imm32/Makefile
1506 dlls/iphlpapi/Makefile
1507 dlls/iphlpapi/tests/Makefile
1508 dlls/itss/Makefile
1509 dlls/kernel/Makefile
1510 dlls/kernel/tests/Makefile
1511 dlls/lzexpand/Makefile
1512 dlls/lzexpand/tests/Makefile
1513 dlls/mapi32/Makefile
1514 dlls/mapi32/tests/Makefile
1515 dlls/mciavi32/Makefile
1516 dlls/mcicda/Makefile
1517 dlls/mciseq/Makefile
1518 dlls/midimap/Makefile
1519 dlls/mlang/Makefile
1520 dlls/mlang/tests/Makefile
1521 dlls/mmdevldr.vxd/Makefile
1522 dlls/monodebg.vxd/Makefile
1523 dlls/mpr/Makefile
1524 dlls/msacm/Makefile
1525 dlls/msacm/imaadp32/Makefile
1526 dlls/msacm/msadp32/Makefile
1527 dlls/msacm/msg711/Makefile
1528 dlls/msacm/tests/Makefile
1529 dlls/msacm/winemp3/Makefile
1530 dlls/mscms/Makefile
1531 dlls/mscms/tests/Makefile
1532 dlls/msdmo/Makefile
1533 dlls/mshtml/Makefile
1534 dlls/mshtml/tests/Makefile
1535 dlls/msi/Makefile
1536 dlls/msi/tests/Makefile
1537 dlls/msimg32/Makefile
1538 dlls/msisys/Makefile
1539 dlls/msnet32/Makefile
1540 dlls/msrle32/Makefile
1541 dlls/msvcrt/Makefile
1542 dlls/msvcrt/tests/Makefile
1543 dlls/msvcrt20/Makefile
1544 dlls/msvcrt40/Makefile
1545 dlls/msvcrtd/Makefile
1546 dlls/msvcrtd/tests/Makefile
1547 dlls/msvidc32/Makefile
1548 dlls/msvideo/Makefile
1549 dlls/mswsock/Makefile
1550 dlls/msxml3/Makefile
1551 dlls/msxml3/tests/Makefile
1552 dlls/netapi32/Makefile
1553 dlls/netapi32/tests/Makefile
1554 dlls/newdev/Makefile
1555 dlls/ntdll/Makefile
1556 dlls/ntdll/tests/Makefile
1557 dlls/objsel/Makefile
1558 dlls/odbc32/Makefile
1559 dlls/odbccp32/Makefile
1560 dlls/ole32/Makefile
1561 dlls/ole32/tests/Makefile
1562 dlls/oleacc/Makefile
1563 dlls/oleaut32/Makefile
1564 dlls/oleaut32/tests/Makefile
1565 dlls/olecli32/Makefile
1566 dlls/oledlg/Makefile
1567 dlls/olepro32/Makefile
1568 dlls/olesvr32/Makefile
1569 dlls/opengl32/Makefile
1570 dlls/powrprof/Makefile
1571 dlls/psapi/Makefile
1572 dlls/psapi/tests/Makefile
1573 dlls/qcap/Makefile
1574 dlls/quartz/Makefile
1575 dlls/quartz/tests/Makefile
1576 dlls/rasapi32/Makefile
1577 dlls/riched20/Makefile
1578 dlls/riched20/tests/Makefile
1579 dlls/richedit/Makefile
1580 dlls/rpcrt4/Makefile
1581 dlls/rpcrt4/tests/Makefile
1582 dlls/rsabase/Makefile
1583 dlls/rsabase/tests/Makefile
1584 dlls/rsaenh/Makefile
1585 dlls/rsaenh/tests/Makefile
1586 dlls/secur32/Makefile
1587 dlls/secur32/tests/Makefile
1588 dlls/security/Makefile
1589 dlls/sensapi/Makefile
1590 dlls/serialui/Makefile
1591 dlls/setupapi/Makefile
1592 dlls/setupapi/tests/Makefile
1593 dlls/sfc/Makefile
1594 dlls/shdocvw/Makefile
1595 dlls/shdocvw/tests/Makefile
1596 dlls/shell32/Makefile
1597 dlls/shell32/tests/Makefile
1598 dlls/shfolder/Makefile
1599 dlls/shlwapi/Makefile
1600 dlls/shlwapi/tests/Makefile
1601 dlls/snmpapi/Makefile
1602 dlls/stdole2.tlb/Makefile
1603 dlls/stdole32.tlb/Makefile
1604 dlls/sti/Makefile
1605 dlls/strmiids/Makefile
1606 dlls/tapi32/Makefile
1607 dlls/twain/Makefile
1608 dlls/unicows/Makefile
1609 dlls/url/Makefile
1610 dlls/urlmon/Makefile
1611 dlls/urlmon/tests/Makefile
1612 dlls/user/Makefile
1613 dlls/user/tests/Makefile
1614 dlls/usp10/Makefile
1615 dlls/usp10/tests/Makefile
1616 dlls/uuid/Makefile
1617 dlls/uxtheme/Makefile
1618 dlls/vdhcp.vxd/Makefile
1619 dlls/vdmdbg/Makefile
1620 dlls/version/Makefile
1621 dlls/version/tests/Makefile
1622 dlls/vmm.vxd/Makefile
1623 dlls/vnbt.vxd/Makefile
1624 dlls/vnetbios.vxd/Makefile
1625 dlls/vtdapi.vxd/Makefile
1626 dlls/vwin32.vxd/Makefile
1627 dlls/win32s/Makefile
1628 dlls/winaspi/Makefile
1629 dlls/winecrt0/Makefile
1630 dlls/wined3d/Makefile
1631 dlls/winedos/Makefile
1632 dlls/wineps/Makefile
1633 dlls/wininet/Makefile
1634 dlls/wininet/tests/Makefile
1635 dlls/winmm/Makefile
1636 dlls/winmm/joystick/Makefile
1637 dlls/winmm/mciwave/Makefile
1638 dlls/winmm/tests/Makefile
1639 dlls/winmm/wavemap/Makefile
1640 dlls/winmm/winealsa/Makefile
1641 dlls/winmm/winearts/Makefile
1642 dlls/winmm/wineaudioio/Makefile
1643 dlls/winmm/wineesd/Makefile
1644 dlls/winmm/winejack/Makefile
1645 dlls/winmm/winenas/Makefile
1646 dlls/winmm/wineoss/Makefile
1647 dlls/winnls/Makefile
1648 dlls/winsock/Makefile
1649 dlls/winsock/tests/Makefile
1650 dlls/winspool/Makefile
1651 dlls/winspool/tests/Makefile
1652 dlls/wintab32/Makefile
1653 dlls/wintrust/Makefile
1654 dlls/wldap32/Makefile
1655 dlls/wow32/Makefile
1656 dlls/wsock32/Makefile
1657 dlls/wtsapi32/Makefile
1658 dlls/x11drv/Makefile
1659 documentation/Makefile
1660 fonts/Makefile
1661 include/Makefile
1662 libs/Makefile
1663 libs/port/Makefile
1664 libs/unicode/Makefile
1665 libs/wine/Makefile
1666 libs/wpp/Makefile
1667 loader/Makefile
1668 programs/Makefile
1669 programs/avitools/Makefile
1670 programs/clock/Makefile
1671 programs/cmdlgtst/Makefile
1672 programs/control/Makefile
1673 programs/eject/Makefile
1674 programs/expand/Makefile
1675 programs/explorer/Makefile
1676 programs/hh/Makefile
1677 programs/msiexec/Makefile
1678 programs/notepad/Makefile
1679 programs/progman/Makefile
1680 programs/regedit/Makefile
1681 programs/regsvr32/Makefile
1682 programs/rpcss/Makefile
1683 programs/rundll32/Makefile
1684 programs/start/Makefile
1685 programs/taskmgr/Makefile
1686 programs/uninstaller/Makefile
1687 programs/view/Makefile
1688 programs/wcmd/Makefile
1689 programs/wineboot/Makefile
1690 programs/winebrowser/Makefile
1691 programs/winecfg/Makefile
1692 programs/wineconsole/Makefile
1693 programs/winedbg/Makefile
1694 programs/winefile/Makefile
1695 programs/winemenubuilder/Makefile
1696 programs/winemine/Makefile
1697 programs/winepath/Makefile
1698 programs/winetest/Makefile
1699 programs/winevdm/Makefile
1700 programs/winhelp/Makefile
1701 programs/winver/Makefile
1702 programs/wordpad/Makefile
1703 server/Makefile
1704 tools/Makefile
1705 tools/widl/Makefile
1706 tools/winapi/Makefile
1707 tools/winebuild/Makefile
1708 tools/winedump/Makefile
1709 tools/winegcc/Makefile
1710 tools/wmc/Makefile
1711 tools/wrc/Makefile])
1713 AC_OUTPUT
1715 if test "$have_x" = "no"
1716 then
1717 echo
1718 echo "*** Warning: X development files not found. Wine will be built without"
1719 echo "*** X support, which currently does not work, and would probably not be"
1720 echo "*** what you want anyway. You will need to install devel packages of"
1721 echo "*** Xlib/Xfree86 at the very least."
1722 fi
1724 if test "$wine_cv_opengl_version_OK" = "no"
1725 then
1726 echo
1727 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1728 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1729 fi
1731 if test "$wine_cv_msg_freetype" = "yes"
1732 then
1733 echo
1734 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1735 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1736 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1737 echo "*** enable Wine to use TrueType fonts."
1738 fi
1740 if test -z "$ALSALIBS" -a \
1741 -z "$ARTSC_LIBS" -a \
1742 -z "$AUDIOIOLIBS" -a \
1743 -z "$NASLIBS" -a \
1744 -z "$ESD_LIBS" -a \
1745 -z "$ac_cv_lib_soname_jack" -a \
1746 "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1747 "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1748 "$ac_cv_header_soundcard_h" != "yes"
1749 then
1750 echo "*** No sound system was found. Windows applications will be silent."
1751 echo "*** The currently supported sound systems are:"
1752 echo "*** ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS"
1753 fi
1755 echo
1756 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1757 echo
1759 dnl Local Variables:
1760 dnl comment-start: "dnl "
1761 dnl comment-end: ""
1762 dnl comment-start-skip: "\\bdnl\\b\\s *"
1763 dnl compile-command: "autoconf"
1764 dnl End: