aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl WINE_CHECK_HOST_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
  26 dnl
  27 dnl Like AC_CHECK_TOOL but without the broken fallback to non-prefixed name
  28 dnl
  29 AC_DEFUN([WINE_CHECK_HOST_TOOL],
  30 [AS_VAR_SET_IF([ac_tool_prefix],
  31   AC_CHECK_PROG([$1],[${ac_tool_prefix}$2],[${ac_tool_prefix}$2],,[$4]))
  32 AS_VAR_IF([ac_cv_prog_$1],[],
  33   [AS_VAR_IF([cross_compiling],[yes],[],
  34     [AS_UNSET([ac_cv_prog_$1])
  35      AC_CHECK_PROG([$1],[$2],[$2],[$3],[$4])])],
  36 [AS_VAR_COPY([$1],[ac_cv_prog_$1])])])
  37
  38 dnl **** Initialize the programs used by other checks ****
  39 dnl
  40 dnl Usage: WINE_PATH_SONAME_TOOLS
  41 dnl Usage: WINE_PATH_PKG_CONFIG
  42 dnl
  43 AC_DEFUN([WINE_PATH_SONAME_TOOLS],
  44 [AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)
  45 AC_CHECK_TOOL(READELF,[readelf],true)])
  46
  47 AC_DEFUN([WINE_PATH_PKG_CONFIG],
  48 [WINE_CHECK_HOST_TOOL(PKG_CONFIG,[pkg-config])])
  49
  50 dnl **** Extract the soname of a library ****
  51 dnl
  52 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  53 dnl
  54 AC_DEFUN([WINE_CHECK_SONAME],
  55 [AC_REQUIRE([WINE_PATH_SONAME_TOOLS])dnl
  56 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  57 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  58 AC_MSG_CHECKING([for -l$1])
  59 AC_CACHE_VAL(ac_Lib,
  60 [ac_check_soname_save_LIBS=$LIBS
  61 LIBS="-l$1 $5 $LIBS"
  62   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  63   [case "$LIBEXT" in
  64     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  65     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  66     *) AS_VAR_SET(ac_Lib,[`$READELF -d conftest$ac_exeext | grep "NEEDED.*ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\\m4_dquote(\\(ac_lib_pattern\\.$LIBEXT[[^    ]]*\\)\\).*$/\1/"';2,$d'`])
  67        AS_VAR_IF([ac_Lib],[],
  68              [AS_VAR_SET(ac_Lib,[`$LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^  ]]*\).*$/\1/"';2,$d'`])]) ;;
  69   esac])
  70   LIBS=$ac_check_soname_save_LIBS])dnl
  71 AS_VAR_IF([ac_Lib],[],
  72       [AC_MSG_RESULT([not found])
  73        $4],
  74       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  75        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  76                           [Define to the soname of the lib$1 library.])
  77        $3])dnl
  78 m4_popdef([ac_lib_pattern])dnl
  79 AS_VAR_POPDEF([ac_Lib])])
  80
  81 dnl **** Get flags from pkg-config or alternate xxx-config program ****
  82 dnl
  83 dnl Usage: WINE_PACKAGE_FLAGS(var,pkg-name,[default-lib,[cflags-alternate,libs-alternate,[checks]]])
  84 dnl
  85 AC_DEFUN([WINE_PACKAGE_FLAGS],
  86 [AC_REQUIRE([WINE_PATH_PKG_CONFIG])dnl
  87 AS_VAR_PUSHDEF([ac_cflags],[[$1]_CFLAGS])dnl
  88 AS_VAR_PUSHDEF([ac_libs],[[$1]_LIBS])dnl
  89 AC_ARG_VAR(ac_cflags, [C compiler flags for $2, overriding pkg-config])dnl
  90 AS_VAR_IF([ac_cflags],[],
  91       [AS_VAR_SET_IF([PKG_CONFIG],
  92       [ac_cflags=`$PKG_CONFIG --cflags [$2] 2>/dev/null`])])
  93 m4_ifval([$4],[test "$cross_compiling" = yes || ac_cflags=[$]{ac_cflags:-[$4]}])
  94 AC_ARG_VAR(ac_libs, [Linker flags for $2, overriding pkg-config])dnl
  95 AS_VAR_IF([ac_libs],[],
  96       [AS_VAR_SET_IF([PKG_CONFIG],
  97       [ac_libs=`$PKG_CONFIG --libs [$2] 2>/dev/null`])])
  98 m4_ifval([$5],[test "$cross_compiling" = yes || ac_libs=[$]{ac_libs:-[$5]}])
  99 m4_ifval([$3],[ac_libs=[$]{ac_libs:-"$3"}])
 100 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 cflags: $ac_cflags"]) >&AS_MESSAGE_LOG_FD
 101 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 libs: $ac_libs"]) >&AS_MESSAGE_LOG_FD
 102 ac_save_CPPFLAGS=$CPPFLAGS
 103 CPPFLAGS="$CPPFLAGS $ac_cflags"
 104 $6
 105 CPPFLAGS=$ac_save_CPPFLAGS
 106 test -z "$ac_cflags" || ac_cflags=`echo " $ac_cflags" | sed 's/ -I\([[^/]]\)/ -I\$(top_builddir)\/\1/g'`
 107 test -z "$ac_libs" || ac_libs=`echo " $ac_libs" | sed 's/ -L\([[^/]]\)/ -L\$(top_builddir)\/\1/g'`
 108 AS_VAR_POPDEF([ac_libs])dnl
 109 AS_VAR_POPDEF([ac_cflags])])dnl
 110
 111 dnl **** Link C code with an assembly file ****
 112 dnl
 113 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_TRY_ASM_LINK],
 116 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[$2]],[[asm($1); $3]])],[$4],[$5])])
 117
 118 dnl **** Check if we can link an empty program with special CFLAGS ****
 119 dnl
 120 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
 121 dnl
 122 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
 123 dnl
 124 AC_DEFUN([WINE_TRY_CFLAGS],
 125 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
 126 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
 127 [ac_wine_try_cflags_saved=$CFLAGS
 128 CFLAGS="$CFLAGS $1"
 129 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]])],
 130                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
 131 CFLAGS=$ac_wine_try_cflags_saved])
 132 AS_VAR_IF([ac_var],[yes],[m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
 133 AS_VAR_POPDEF([ac_var])])
 134
 135 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
 136 dnl
 137 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
 138 dnl
 139 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
 140 [ac_wine_try_cflags_saved=$CFLAGS
 141 CFLAGS="$CFLAGS $1"
 142 AC_LINK_IFELSE([AC_LANG_SOURCE([void myfunc() {}])],[$2],[$3])
 143 CFLAGS=$ac_wine_try_cflags_saved])
 144
 145 dnl **** Check whether we need to define a symbol on the compiler command line ****
 146 dnl
 147 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
 148 dnl
 149 AC_DEFUN([WINE_CHECK_DEFINE],
 150 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 151 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 152     AC_EGREP_CPP(yes,[#ifndef $1
 153 yes
 154 #endif],
 155     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 156 AS_VAR_IF([ac_var],[yes],
 157       [CFLAGS="$CFLAGS -D$1"
 158   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 159 AS_VAR_POPDEF([ac_var])])
 160
 161 dnl **** Check for functions with some extra libraries ****
 162 dnl
 163 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 164 dnl
 165 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 166 [ac_wine_check_funcs_save_LIBS="$LIBS"
 167 LIBS="$LIBS $2"
 168 AC_CHECK_FUNCS([$1],[$3],[$4])
 169 LIBS="$ac_wine_check_funcs_save_LIBS"])
 170
 171 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 172 dnl
 173 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 174 dnl
 175 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 176 [case "$host_cpu" in
 177   i[[3456789]]86*)
 178     ac_prefix_list="m4_foreach([ac_wine_prefix],[w64-mingw32, pc-mingw32, mingw32msvc, mingw32],
 179                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))
 180                         mingw32-$2" ;;
 181   x86_64)
 182     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, w64-mingw32, mingw32msvc],
 183                         m4_foreach([ac_wine_cpu],[x86_64,amd64],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 184   *)
 185     ac_prefix_list="" ;;
 186 esac
 187 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 188
 189
 190 dnl **** Define helper functions for creating config.status files ****
 191 dnl
 192 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 193 dnl
 194 AC_DEFUN([WINE_CONFIG_HELPERS],
 195 [wine_rules_file=conf$$rules.make
 196 rm -f $wine_rules_file
 197 ALL_POT_FILES=""
 198 GITIGNORE="# Automatically generated by configure; DO NOT EDIT!!"
 199 AC_SUBST(ALL_TEST_RESOURCES,"")
 200
 201 wine_fn_append_file ()
 202 {
 203     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 204 }
 205
 206 wine_fn_ignore_file ()
 207 {
 208     case "$[1]" in
 209       */*) AS_VAR_APPEND([GITIGNORE],"$as_nl$[1]") ;;
 210       \**) AS_VAR_APPEND([GITIGNORE],"$as_nl$[1]") ;;
 211       *)   AS_VAR_APPEND([GITIGNORE],"$as_nl/$[1]") ;;
 212     esac
 213 }
 214
 215 wine_fn_append_rule ()
 216 {
 217     AS_ECHO("$[1]") >>$wine_rules_file
 218 }
 219
 220 wine_fn_has_flag ()
 221 {
 222     expr ",$ac_flags," : ".*,$[1],.*" >/dev/null
 223 }
 224
 225 wine_fn_depend_rules ()
 226 {
 227     wine_fn_append_rule \
 228 "$ac_dir/Makefile: $srcdir/$ac_dir/Makefile.in $srcdir/Make.vars.in config.status \$(MAKEDEP)
 229         @./config.status --file $ac_dir/Makefile:Make.vars.in:$ac_dir/Makefile.in && \$(MAKEDEP) $ac_dir
 230 depend: $ac_dir/depend
 231 .PHONY: $ac_dir/depend
 232 $ac_dir/depend: \$(MAKEDEP) dummy
 233         @./config.status --file $ac_dir/Makefile:Make.vars.in:$ac_dir/Makefile.in && \$(MAKEDEP) $ac_dir"
 234 }
 235
 236 wine_fn_pot_rules ()
 237 {
 238     test "x$with_gettextpo" = xyes || return
 239
 240     if wine_fn_has_flag mc
 241     then
 242         wine_fn_append_file ALL_POT_FILES $ac_dir/msg.pot
 243         wine_fn_append_rule \
 244 "$ac_dir/msg.pot: $ac_dir/Makefile dummy
 245         @cd $ac_dir && \$(MAKE) msg.pot
 246 $ac_dir/msg.pot: tools/wmc include"
 247     fi
 248     if wine_fn_has_flag po
 249     then
 250         wine_fn_append_file ALL_POT_FILES $ac_dir/rsrc.pot
 251         wine_fn_append_rule \
 252 "$ac_dir/rsrc.pot: $ac_dir/Makefile dummy
 253         @cd $ac_dir && \$(MAKE) rsrc.pot
 254 $ac_dir/rsrc.pot: tools/wrc include"
 255     fi
 256 }
 257
 258 wine_fn_all_rules ()
 259 {
 260     wine_fn_depend_rules
 261     wine_fn_append_rule \
 262 "all: $ac_dir
 263 .PHONY: $ac_dir
 264 $ac_dir: $ac_dir/Makefile dummy
 265         @cd $ac_dir && \$(MAKE)"
 266 }
 267
 268 wine_fn_install_rules ()
 269 {
 270     wine_fn_has_flag install-lib || wine_fn_has_flag install-dev || return
 271
 272     wine_fn_append_rule \
 273 ".PHONY: $ac_dir/install $ac_dir/uninstall
 274 $ac_dir/install:: $ac_dir
 275         @cd $ac_dir && \$(MAKE) install
 276 $ac_dir/uninstall:: $ac_dir/Makefile
 277         @cd $ac_dir && \$(MAKE) uninstall
 278 install:: $ac_dir/install
 279 __uninstall__: $ac_dir/uninstall"
 280
 281     if wine_fn_has_flag install-lib
 282     then
 283         wine_fn_append_rule \
 284 ".PHONY: $ac_dir/install-lib
 285 $ac_dir/install-lib:: $ac_dir
 286         @cd $ac_dir && \$(MAKE) install-lib
 287 install-lib:: $ac_dir/install-lib"
 288     fi
 289
 290     if wine_fn_has_flag install-dev
 291     then
 292         wine_fn_append_rule \
 293 ".PHONY: $ac_dir/install-dev
 294 $ac_dir/install-dev:: $ac_dir
 295         @cd $ac_dir && \$(MAKE) install-dev
 296 install-dev:: $ac_dir/install-dev"
 297     fi
 298 }
 299
 300 wine_fn_clean_rules ()
 301 {
 302     ac_clean=$[@]
 303     ac_extraclean="$ac_dir/Makefile"
 304     test "$srcdir" = . && ac_extraclean="$ac_extraclean $ac_dir/.gitignore"
 305
 306     if wine_fn_has_flag clean
 307     then
 308         wine_fn_append_rule \
 309 "__clean__: $ac_dir/clean
 310 .PHONY: $ac_dir/clean
 311 $ac_dir/clean: $ac_dir/Makefile
 312         @cd $ac_dir && \$(MAKE) clean
 313         \$(RM) $ac_extraclean"
 314     else
 315         wine_fn_append_rule \
 316 "__clean__: $ac_dir/clean
 317 .PHONY: $ac_dir/clean
 318 $ac_dir/clean: dummy
 319         \$(RM) \$(CLEAN_FILES:%=$ac_dir/%) $ac_clean $ac_extraclean"
 320     fi
 321 }
 322
 323 wine_fn_disabled_rules ()
 324 {
 325     ac_clean=$[@]
 326     ac_extraclean="$ac_dir/Makefile"
 327     test "$srcdir" = . && ac_extraclean="$ac_extraclean $ac_dir/.gitignore"
 328
 329     wine_fn_append_rule \
 330 "__clean__: $ac_dir/clean
 331 .PHONY: $ac_dir/clean
 332 $ac_dir/clean: dummy
 333         \$(RM) \$(CLEAN_FILES:%=$ac_dir/%) $ac_clean $ac_extraclean"
 334 }
 335
 336 wine_fn_config_makefile ()
 337 {
 338     ac_dir=$[1]
 339     ac_enable=$[2]
 340     ac_flags=$[3]
 341
 342     AS_VAR_IF([$ac_enable],[no],[wine_fn_disabled_rules; return])
 343     wine_fn_all_rules
 344     wine_fn_install_rules
 345     wine_fn_clean_rules
 346 }
 347
 348 wine_fn_config_lib ()
 349 {
 350     ac_name=$[1]
 351     ac_flags=$[2]
 352     ac_dir=dlls/$ac_name
 353     ac_deps="include"
 354
 355     AS_VAR_IF([enable_tools],[no],,[ac_deps="tools/widl tools/winebuild tools/winegcc $ac_deps"])
 356     wine_fn_all_rules
 357     wine_fn_clean_rules
 358
 359     wine_fn_append_rule \
 360 ".PHONY: $ac_dir/install $ac_dir/uninstall
 361 $ac_dir/install:: $ac_dir
 362         \$(INSTALL_DATA) $ac_dir/lib$ac_name.a \$(DESTDIR)\$(dlldir)/lib$ac_name.a
 363 $ac_dir/uninstall::
 364         \$(RM) \$(DESTDIR)\$(dlldir)/lib$ac_name.a
 365 install install-dev:: $ac_dir/install
 366 __uninstall__: $ac_dir/uninstall
 367 __builddeps__: $ac_dir
 368 $ac_dir: $ac_deps"
 369 }
 370
 371 wine_fn_config_dll ()
 372 {
 373     ac_name=$[1]
 374     ac_dir=dlls/$ac_name
 375     ac_enable=$[2]
 376     ac_flags=$[3]
 377     ac_implib=${4:-$ac_name}
 378     ac_file=$ac_dir/lib$ac_implib
 379     ac_dll=$ac_name
 380     ac_deps="include"
 381     ac_implibflags=""
 382
 383     AS_VAR_IF([enable_tools],[no],,[ac_deps="tools/widl tools/winebuild tools/winegcc $ac_deps"])
 384     case $ac_name in
 385       *16) ac_implibflags=" -m16" ;;
 386       *.*) ;;
 387       *)   ac_dll=$ac_dll.dll ;;
 388     esac
 389
 390     ac_clean=
 391     wine_fn_has_flag implib && ac_clean="$ac_clean $ac_file.$IMPLIBEXT"
 392     wine_fn_has_flag mc && ac_clean="$ac_clean $ac_dir/msg.pot"
 393     wine_fn_has_flag po && ac_clean="$ac_clean $ac_dir/rsrc.pot"
 394     test -n "$DLLEXT" || ac_clean="$ac_clean $ac_dir/$ac_dll"
 395
 396     AS_VAR_IF([$ac_enable],[no],
 397               dnl enable_win16 is special in that it disables import libs too
 398               [if wine_fn_has_flag implib && test "$ac_enable" != enable_win16
 399                then
 400                    wine_fn_depend_rules
 401                    wine_fn_clean_rules $ac_clean
 402                else
 403                    wine_fn_disabled_rules $ac_clean
 404                    return
 405                fi],
 406
 407               [wine_fn_all_rules
 408                wine_fn_clean_rules $ac_clean
 409                wine_fn_append_rule \
 410 "$ac_dir: __builddeps__
 411 manpages htmlpages sgmlpages xmlpages:: $ac_dir/Makefile
 412         @cd $ac_dir && \$(MAKE) \$[@]
 413 .PHONY: $ac_dir/install-lib $ac_dir/uninstall
 414 install install-lib:: $ac_dir/install-lib
 415 __uninstall__: $ac_dir/uninstall"
 416                 if test -n "$DLLEXT"
 417                 then
 418                     wine_fn_append_rule \
 419 "$ac_dir/install-lib:: $ac_dir
 420         \$(INSTALL_PROGRAM) $ac_dir/$ac_dll$DLLEXT \$(DESTDIR)\$(dlldir)/$DLLPREFIX$ac_dll$DLLEXT
 421         \$(INSTALL_DATA) $ac_dir/$ac_dll.fake \$(DESTDIR)\$(fakedlldir)/$ac_dll
 422 $ac_dir/uninstall::
 423         \$(RM) \$(DESTDIR)\$(dlldir)/$DLLPREFIX$ac_dll$DLLEXT \$(DESTDIR)\$(fakedlldir)/$ac_dll"
 424                 else
 425                     wine_fn_append_rule \
 426 "$ac_dir/install-lib:: $ac_dir
 427         \$(INSTALL_PROGRAM) $ac_dir/$ac_dll \$(DESTDIR)\$(dlldir)/$ac_dll
 428 $ac_dir/uninstall::
 429         \$(RM) \$(DESTDIR)\$(dlldir)/$ac_dll"
 430                 fi
 431
 432                 wine_fn_pot_rules])
 433
 434     if wine_fn_has_flag staticimplib
 435     then
 436         wine_fn_append_rule \
 437 "__builddeps__: $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT
 438 $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 439 $ac_file.def: $srcdir/$ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 440         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --def -o \$[@] --export $srcdir/$ac_dir/$ac_name.spec
 441 $ac_file.$STATIC_IMPLIBEXT: $ac_dir/Makefile dummy
 442         @cd $ac_dir && \$(MAKE) lib$ac_implib.$STATIC_IMPLIBEXT
 443 .PHONY: $ac_dir/install-dev $ac_dir/uninstall
 444 $ac_dir/install-dev:: $ac_file.$IMPLIBEXT
 445         \$(INSTALL_DATA) $ac_file.$IMPLIBEXT \$(DESTDIR)\$(dlldir)/lib$ac_implib.$IMPLIBEXT
 446 $ac_dir/uninstall::
 447         \$(RM) \$(DESTDIR)\$(dlldir)/lib$ac_implib.$IMPLIBEXT
 448 install install-dev:: $ac_dir/install-dev
 449 __uninstall__: $ac_dir/uninstall"
 450
 451         if test "$IMPLIBEXT" != "$STATIC_IMPLIBEXT"
 452         then
 453             wine_fn_append_rule \
 454 "$ac_dir/install-dev:: $ac_file.$STATIC_IMPLIBEXT __builddeps__
 455         \$(INSTALL_DATA) $ac_file.$STATIC_IMPLIBEXT \$(DESTDIR)\$(dlldir)/lib$ac_implib.$STATIC_IMPLIBEXT
 456 $ac_dir/uninstall::
 457         \$(RM) \$(DESTDIR)\$(dlldir)/lib$ac_implib.$STATIC_IMPLIBEXT"
 458         fi
 459
 460         if test -n "$CROSSTARGET" -a -z "$ac_implibflags"
 461         then
 462             wine_fn_append_rule \
 463 "__builddeps__: $ac_file.cross.a
 464 $ac_file.cross.a: $ac_dir/Makefile dummy
 465         @cd $ac_dir && \$(MAKE) lib$ac_implib.cross.a"
 466         fi
 467
 468     elif wine_fn_has_flag implib
 469     then
 470         wine_fn_append_rule \
 471 "__builddeps__: $ac_file.$IMPLIBEXT
 472 $ac_file.def: $srcdir/$ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 473         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --def -o \$[@] --export $srcdir/$ac_dir/$ac_name.spec
 474 $ac_file.a: $srcdir/$ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 475         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --implib -o \$[@] --export $srcdir/$ac_dir/$ac_name.spec
 476 .PHONY: $ac_dir/install-dev $ac_dir/uninstall
 477 $ac_dir/install-dev:: $ac_file.$IMPLIBEXT
 478         \$(INSTALL_DATA) $ac_file.$IMPLIBEXT \$(DESTDIR)\$(dlldir)/lib$ac_implib.$IMPLIBEXT
 479 $ac_dir/uninstall::
 480         \$(RM) \$(DESTDIR)\$(dlldir)/lib$ac_implib.$IMPLIBEXT
 481 install install-dev:: $ac_dir/install-dev
 482 __uninstall__: $ac_dir/uninstall"
 483         if test -n "$CROSSTARGET" -a -z "$ac_implibflags"
 484         then
 485             wine_fn_append_rule \
 486 "__builddeps__: $ac_file.cross.a
 487 $ac_file.cross.a: $srcdir/$ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 488         \$(WINEBUILD) \$(CROSSTARGET:%=-b %)$ac_implibflags -w --implib -o \$[@] --export $srcdir/$ac_dir/$ac_name.spec"
 489         fi
 490
 491         if test "$ac_name" != "$ac_implib"
 492         then
 493             wine_fn_append_rule \
 494 "__builddeps__: dlls/lib$ac_implib.$IMPLIBEXT
 495 dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 496         \$(RM) \$[@] && \$(LN_S) $ac_name/lib$ac_implib.$IMPLIBEXT \$[@]
 497 clean::
 498         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 499             wine_fn_ignore_file "dlls/lib$ac_implib.$IMPLIBEXT"
 500             if test -n "$CROSSTARGET" -a -z "$ac_implibflags"
 501             then
 502                 wine_fn_append_rule \
 503 "__builddeps__: dlls/lib$ac_implib.cross.a
 504 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 505         \$(RM) \$[@] && \$(LN_S) $ac_name/lib$ac_implib.cross.a \$[@]
 506 clean::
 507         \$(RM) dlls/lib$ac_implib.cross.a"
 508                 wine_fn_ignore_file "dlls/lib$ac_implib.cross.a"
 509             fi
 510         fi
 511     fi
 512 }
 513
 514 wine_fn_config_program ()
 515 {
 516     ac_name=$[1]
 517     ac_dir=programs/$ac_name
 518     ac_enable=$[2]
 519     ac_flags=$[3]
 520     ac_program=$ac_name
 521
 522     case $ac_name in
 523       *.*) ;;
 524       *)   ac_program=$ac_program.exe ;;
 525     esac
 526
 527     ac_clean=
 528     wine_fn_has_flag mc && ac_clean="$ac_clean $ac_dir/msg.pot"
 529     wine_fn_has_flag po && ac_clean="$ac_clean $ac_dir/rsrc.pot"
 530     wine_fn_has_flag manpage && ac_clean="$ac_clean $ac_dir/$ac_name.man"
 531     test -n "$DLLEXT" || ac_clean="$ac_clean $ac_dir/$ac_program"
 532
 533     AS_VAR_IF([$ac_enable],[no],[wine_fn_disabled_rules $ac_clean; return])
 534
 535     wine_fn_all_rules
 536     wine_fn_clean_rules $ac_clean
 537     wine_fn_append_rule "$ac_dir: __builddeps__"
 538     wine_fn_pot_rules
 539
 540     wine_fn_has_flag install || return
 541     wine_fn_append_rule \
 542 ".PHONY: $ac_dir/install $ac_dir/uninstall
 543 install install-lib:: $ac_dir/install
 544 __uninstall__: $ac_dir/uninstall"
 545
 546     if test -n "$DLLEXT"
 547     then
 548         wine_fn_append_rule \
 549 "$ac_dir/install:: $ac_dir
 550         \$(INSTALL_PROGRAM) $ac_dir/$ac_program$DLLEXT \$(DESTDIR)\$(dlldir)/$DLLPREFIX$ac_program$DLLEXT
 551         \$(INSTALL_DATA) $ac_dir/$ac_program.fake \$(DESTDIR)\$(fakedlldir)/$ac_program
 552 $ac_dir/uninstall::
 553         \$(RM) \$(DESTDIR)\$(dlldir)/$DLLPREFIX$ac_program$DLLEXT \$(DESTDIR)\$(fakedlldir)/$ac_program"
 554
 555         if test -z "$with_wine64" && wine_fn_has_flag installbin
 556         then
 557             wine_fn_append_rule \
 558 "$ac_dir/install:: __tooldeps__
 559         \$(INSTALL_SCRIPT) \$(TOOLSDIR)/tools/wineapploader \$(DESTDIR)\$(bindir)/$ac_name
 560 $ac_dir/uninstall::
 561         \$(RM) \$(DESTDIR)\$(bindir)/$ac_name"
 562         fi
 563     else
 564         wine_fn_append_rule \
 565 "$ac_dir/install:: $ac_dir
 566         \$(INSTALL_PROGRAM) $ac_dir/$ac_program \$(DESTDIR)\$(bindir)/$ac_program
 567 $ac_dir/uninstall::
 568         \$(RM) \$(DESTDIR)\$(bindir)/$ac_program"
 569     fi
 570
 571     if test -z "$with_wine64" && wine_fn_has_flag manpage
 572     then
 573         wine_fn_append_rule \
 574 "$ac_dir/install:: $ac_dir
 575         \$(INSTALL_DATA) $ac_dir/$ac_name.man \$(DESTDIR)\$(mandir)/man\$(prog_manext)/$ac_name.\$(prog_manext)
 576 $ac_dir/uninstall::
 577         \$(RM) \$(DESTDIR)\$(mandir)/man\$(prog_manext)/$ac_name.\$(prog_manext)"
 578     fi
 579 }
 580
 581 wine_fn_config_test ()
 582 {
 583     ac_dir=$[1]
 584     ac_name=$[2]
 585     ac_flags=$[3]
 586
 587     ac_clean=
 588     test -n "$CROSSTARGET" && ac_clean=`expr $ac_dir/${ac_name} : "\\(.*\\)_test"`_crosstest.exe
 589     test -n "$DLLEXT" || ac_clean="$ac_dir/${ac_name}.exe $ac_dir/${ac_name}-stripped.exe"
 590     ac_clean="$ac_clean $ac_dir/testlist.c"
 591
 592     AS_VAR_IF([enable_tests],[no],[wine_fn_disabled_rules $ac_clean; return])
 593
 594     wine_fn_append_file ALL_TEST_RESOURCES $ac_name.res
 595     wine_fn_all_rules
 596     wine_fn_clean_rules $ac_clean
 597
 598     wine_fn_append_rule \
 599 "$ac_dir: programs/winetest/Makefile __builddeps__
 600 programs/winetest: $ac_dir
 601 check test: $ac_dir/test
 602 .PHONY: $ac_dir/test
 603 $ac_dir/test: dummy
 604         @cd $ac_dir && \$(MAKE) test
 605 testclean::
 606         \$(RM) $ac_dir/*.ok"
 607
 608         if test -n "$CROSSTARGET"
 609         then
 610             wine_fn_append_rule \
 611 "crosstest: $ac_dir/crosstest
 612 .PHONY: $ac_dir/crosstest
 613 $ac_dir/crosstest: $ac_dir/Makefile __builddeps__ dummy
 614         @cd $ac_dir && \$(MAKE) crosstest"
 615         fi
 616 }
 617
 618 wine_fn_config_tool ()
 619 {
 620     ac_dir=$[1]
 621     ac_flags=$[2]
 622     AS_VAR_IF([enable_tools],[no],[return])
 623
 624     wine_fn_all_rules
 625     wine_fn_install_rules
 626     wine_fn_clean_rules
 627
 628     wine_fn_append_rule "__tooldeps__: $ac_dir"
 629     wine_fn_append_rule "$ac_dir: libs/port"
 630     case $ac_dir in
 631       tools/winebuild) wine_fn_append_rule "\$(WINEBUILD): $ac_dir" ;;
 632     esac
 633 }
 634
 635 wine_fn_config_symlink ()
 636 {
 637     ac_linkdir=
 638     if test "x$[1]" = "x-d"
 639     then
 640         ac_linkdir=$[2]
 641         shift; shift
 642     fi
 643     ac_links=$[@]
 644     wine_fn_append_rule \
 645 "$ac_links:
 646         @./config.status \$[@]
 647 distclean::
 648         \$(RM) $ac_links"
 649     for f in $ac_links; do wine_fn_ignore_file $f; done
 650     test -n "$ac_linkdir" || return
 651     wine_fn_append_rule "$ac_linkdir/Makefile $ac_linkdir/depend: $ac_links"
 652 }])
 653
 654 dnl **** Define helper function to append a file to a makefile file list ****
 655 dnl
 656 dnl Usage: WINE_APPEND_FILE(var,file)
 657 dnl
 658 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 659
 660 dnl **** Define helper function to append a rule to a makefile command list ****
 661 dnl
 662 dnl Usage: WINE_APPEND_RULE(rule)
 663 dnl
 664 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule "$1"])
 665
 666 dnl **** Create symlinks from config.status ****
 667 dnl
 668 dnl Usage: WINE_CONFIG_SYMLINK(target,src,files,enable,srcfile)
 669 dnl
 670 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 671 m4_ifval([$4],[if test "x$[$4]" != xno; then
 672 ])m4_foreach([f],[$3],
 673 [AC_CONFIG_LINKS(m4_ifval([$1],[$1/])f[:]m4_ifval([$2],[$2/])m4_ifval([$5],[$5],f))])dnl
 674 m4_if([$1],[$2],[test "$srcdir" = "." || ])dnl
 675 wine_fn_config_symlink[]m4_if([$1],[$2],,m4_ifval([$1],[ -d $1]))[]m4_foreach([f],[$3],[ ]m4_ifval([$1],[$1/])f)m4_ifval([$4],[
 676 fi])[]dnl
 677 ])])
 678
 679 dnl **** Create a makefile from config.status ****
 680 dnl
 681 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable,flags)
 682 dnl
 683 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 684 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 685 m4_append_uniq([_AC_USER_OPTS],ac_enable,[
 686 ])dnl
 687 wine_fn_config_makefile [$1] ac_enable [$3]dnl
 688 AS_VAR_POPDEF([ac_enable])])
 689
 690 dnl **** Create a dll makefile from config.status ****
 691 dnl
 692 dnl Usage: WINE_CONFIG_DLL(name,enable,flags,implib)
 693 dnl
 694 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 695 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 696 m4_append_uniq([_AC_USER_OPTS],ac_enable,[
 697 ])dnl
 698 wine_fn_config_dll [$1] ac_enable [$3] [$4]dnl
 699 AS_VAR_POPDEF([ac_enable])])
 700
 701 dnl **** Create a program makefile from config.status ****
 702 dnl
 703 dnl Usage: WINE_CONFIG_PROGRAM(name,enable,flags)
 704 dnl
 705 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 706 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 707 m4_append_uniq([_AC_USER_OPTS],ac_enable,[
 708 ])dnl
 709 wine_fn_config_program [$1] ac_enable [$3]dnl
 710 AS_VAR_POPDEF([ac_enable])])
 711
 712 dnl **** Create a test makefile from config.status ****
 713 dnl
 714 dnl Usage: WINE_CONFIG_TEST(dir,flags)
 715 dnl
 716 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 717 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 718 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 719 wine_fn_config_test $1 ac_name[]ac_suffix [$2]dnl
 720 m4_popdef([ac_suffix])dnl
 721 m4_popdef([ac_name])])
 722
 723 dnl **** Create a static lib makefile from config.status ****
 724 dnl
 725 dnl Usage: WINE_CONFIG_LIB(name,flags)
 726 dnl
 727 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 728 wine_fn_config_lib [$1] [$2]])
 729
 730 dnl **** Create a tool makefile from config.status ****
 731 dnl
 732 dnl Usage: WINE_CONFIG_TOOL(name,flags)
 733 dnl
 734 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 735 m4_append_uniq([_AC_USER_OPTS],[enable_tools],[
 736 ])dnl
 737 wine_fn_config_tool [$1] [$2]])
 738
 739 dnl **** Append a file to the .gitignore list ****
 740 dnl
 741 dnl Usage: WINE_IGNORE_FILE(file,enable)
 742 dnl
 743 AC_DEFUN([WINE_IGNORE_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 744 m4_ifval([$2],[test "x$[$2]" = xno || ])wine_fn_ignore_file $1])
 745
 746 dnl **** Add a message to the list displayed at the end ****
 747 dnl
 748 dnl Usage: WINE_NOTICE(notice)
 749 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 750 dnl Usage: WINE_WARNING(warning)
 751 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 752 dnl Usage: WINE_PRINT_MESSAGES
 753 dnl
 754 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 755 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 756
 757 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 758   x)   WINE_NOTICE([$3]) ;;
 759   xno) ;;
 760   *)   AC_MSG_ERROR([$3
 761 This is an error since --with-$1 was requested.]) ;;
 762 esac])])
 763
 764 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 765   x)   WINE_WARNING([$3]) ;;
 766   xno) ;;
 767   *)   AC_MSG_ERROR([$3
 768 This is an error since --with-$1 was requested.]) ;;
 769 esac])])
 770
 771 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 772   xno) ;;
 773   *)   AC_MSG_ERROR([$3
 774 Use the --without-$1 option if you really want this.]) ;;
 775 esac])])
 776
 777 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 778 if test "x$wine_notices != "x; then
 779     echo >&AS_MESSAGE_FD
 780     IFS="|"
 781     for msg in $wine_notices; do
 782         IFS="$ac_save_IFS"
 783         AS_VAR_SET_IF([msg],[AC_MSG_NOTICE([$msg])])
 784     done
 785 fi
 786 IFS="|"
 787 for msg in $wine_warnings; do
 788     IFS="$ac_save_IFS"
 789     AS_VAR_SET_IF([msg],[echo >&2
 790         AC_MSG_WARN([$msg])])
 791 done
 792 IFS="$ac_save_IFS"])
 793
 794 dnl Local Variables:
 795 dnl compile-command: "autoreconf --warnings=all"
 796 dnl End: