configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10 LIBS="$LIBS -lm"
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK="-L\$(TOPOBJDIR) -lwine"
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS) \$(X11OBJS)"; LIB_TARGET=""; fi])
  33
  34 dnl AC_ARG_WITH(ipc,
  35 dnl [  --enable-ipc            use inter-process communication for DDE],
  36 dnl [if test "$enableval" = "no"; then : ; else OPTIONS="-DCONFIG_IPC"; fi])
  37
  38 AC_ARG_ENABLE(debug,
  39 [  --disable-debug         compile out all debugging messages],
  40 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  41
  42 AC_ARG_ENABLE(trace,
  43 [  --disable-trace         compile out TRACE messages],
  44 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  45
  46 AC_ARG_WITH(reentrant-x,
  47 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  48
  49 AC_SUBST(MAIN_TARGET)
  50 AC_SUBST(LIB_TARGET)
  51 AC_SUBST(ALT_LINK)
  52 AC_SUBST(OPTIONS)
  53
  54 if test "$DEBUG_MSGS" = "no"
  55 then
  56     AC_DEFINE(NO_DEBUG_MSGS)
  57     AC_DEFINE(NO_TRACE_MSGS)
  58 else
  59     if test "$TRACE_MSGS" = "no"
  60     then
  61         AC_DEFINE(NO_TRACE_MSGS)
  62     fi
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CPP
  70 AC_PATH_XTRA
  71 AC_PROG_YACC
  72 AC_PROG_LEX
  73 AC_PROG_RANLIB
  74 AC_PROG_INSTALL
  75 AC_PROG_LN_S
  76 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  77
  78 dnl **** Check for some libraries ****
  79
  80 dnl Check for -li386 for NetBSD and OpenBSD
  81 AC_CHECK_LIB(i386,i386_set_ldt)
  82 dnl Check for -lossaudio for NetBSD
  83 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  84 dnl Check for -lw for Solaris
  85 AC_CHECK_LIB(w,iswalnum)
  86 dnl Check for -lnsl for Solaris
  87 AC_CHECK_FUNCS(gethostbyname)
  88 if test "$ac_cv_func_gethostbyname" = "no"
  89 then
  90     AC_CHECK_LIB(nsl,gethostbyname)
  91 fi
  92 dnl Check for -lxpg4 for FreeBSD
  93 AC_CHECK_LIB(xpg4,setrunelocale)
  94 dnl Check for -ldl
  95 AC_CHECK_LIB(dl,dlopen)
  96 AC_SUBST(XLIB)
  97 if test "$have_x" = "yes"
  98 then
  99     XLIB="-lXpm -lXext -lX11"
 100     dnl Check for -lXpm
 101     dnl FIXME: should be done once we can compile without -lXpm
 102     dnl AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 103     dnl Check for X Shm extension
 104     AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 105     dnl Check for XFree86 DGA extension
 106     AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 107     dnl Check for XFree86 VMODE extension
 108     AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,AC_DEFINE(HAVE_LIBXXF86VM) X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm",,$X_LIBS -lXext -lX11)
 109     dnl Check for the presence of Mesa
 110     AC_CHECK_LIB(MesaGL,OSMesaCreateContext,AC_DEFINE(HAVE_LIBMESAGL) X_PRE_LIBS="$X_PRE_LIBS -lMesaGL",,$X_LIBS -lXext -lX11 -lm)
 111     AC_CHECK_HEADERS(GL/osmesa.h)
 112 else
 113     XLIB=""
 114     X_CFLAGS=""
 115     X_LIBS=""
 116 fi
 117
 118 dnl **** Check which curses lib to use ***
 119 AC_CHECK_LIB(ncurses,waddch)
 120 if test "$ac_cv_lib_ncurses_waddch" = "yes"
 121 then
 122     AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 123 else
 124     AC_CHECK_LIB(curses,waddch)
 125     AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 126 fi
 127
 128 dnl **** Check for IPX (currently Linux only) ****
 129 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 130  AC_TRY_COMPILE(
 131    [#include <sys/socket.h>
 132     #include <netipx/ipx.h>],
 133    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 134    [AC_DEFINE(HAVE_IPX_GNU)
 135     ac_cv_c_ipx_gnu="yes"],
 136    [ac_cv_c_ipx_gnu="no"])
 137  )
 138
 139 if test "$ac_cv_c_ipx_gnu" = "no"
 140 then
 141  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 142   AC_TRY_COMPILE(
 143     [#include <sys/socket.h>
 144      #include <asm/types.h>
 145      #include <linux/ipx.h>],
 146     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 147     [AC_DEFINE(HAVE_IPX_LINUX)
 148      ac_cv_c_ipx_linux="yes"],
 149     [ac_cv_c_ipx_linux="no"])
 150   )
 151 fi
 152
 153 dnl **** Check for Open Sound System ****
 154 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 155
 156 AC_CACHE_CHECK("for Open Sound System",
 157         ac_cv_c_opensoundsystem,
 158         AC_TRY_COMPILE([
 159         #if defined(HAVE_SYS_SOUNDCARD_H)
 160                 #include <sys/soundcard.h>
 161         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 162                 #include <machine/soundcard.h>
 163         #elif defined(HAVE_SOUNDCARD_H)
 164                 #include <soundcard.h>
 165         #endif
 166         ],[
 167
 168 /* check for one of the Open Sound System specific SNDCTL_ defines */
 169 #if !defined(SNDCTL_DSP_STEREO)
 170 #error No open sound system
 171 #endif
 172 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 173
 174 if test "$ac_cv_c_opensoundsystem" = "yes"
 175 then
 176     AC_DEFINE(HAVE_OSS)
 177 fi
 178
 179 dnl **** Check for union semun ****
 180
 181 AC_CACHE_CHECK("for union semun", ac_cv_c_union_semun,
 182  AC_TRY_COMPILE([#include <sys/types.h>
 183 #include <sys/sem.h>],[union semun foo],
 184                 ac_cv_c_union_semun="yes", ac_cv_c_union_semun="no"))
 185 if test "$ac_cv_c_union_semun" = "yes"
 186 then
 187     AC_DEFINE(HAVE_UNION_SEMUN)
 188 fi
 189
 190 dnl **** If ln -s doesn't work, use cp instead ****
 191 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 192
 193 dnl **** Check for gcc strength-reduce bug ****
 194
 195 if test "x${GCC}" = "xyes"
 196 then
 197   CFLAGS="$CFLAGS -Wall"
 198   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 199                   AC_TRY_RUN([
 200 int main(void) {
 201   static int Array[[3]];
 202   unsigned int B = 3;
 203   int i;
 204   for(i=0; i<B; i++) Array[[i]] = i - 3;
 205   exit( Array[[1]] != -2 );
 206 }],
 207     ac_cv_c_gcc_strength_bug="no",
 208     ac_cv_c_gcc_strength_bug="yes",
 209     ac_cv_c_gcc_strength_bug="yes") )
 210   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 211   then
 212     CFLAGS="$CFLAGS -fno-strength-reduce"
 213   fi
 214 fi
 215
 216 dnl **** Check for underscore on external symbols ****
 217
 218 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 219                ac_cv_c_extern_prefix,
 220 [saved_libs=$LIBS
 221 LIBS="conftest_asm.s $LIBS"
 222 cat > conftest_asm.s <<EOF
 223         .globl _ac_test
 224 _ac_test:
 225         .long 0
 226 EOF
 227 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 228             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 229 LIBS=$saved_libs])
 230 if test "$ac_cv_c_extern_prefix" = "yes"
 231 then
 232   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 233 fi
 234
 235 dnl **** Check for .string in assembler ****
 236
 237 AC_CACHE_CHECK("whether assembler accepts .string",
 238                ac_cv_c_asm_string,
 239 [saved_libs=$LIBS
 240 LIBS="conftest_asm.s $LIBS"
 241 cat > conftest_asm.s <<EOF
 242         .string "test"
 243 EOF
 244 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 245 LIBS=$saved_libs])
 246 if test "$ac_cv_c_asm_string" = "yes"
 247 then
 248   AC_DEFINE(HAVE_ASM_STRING)
 249 fi
 250
 251 dnl **** Check for working dll ****
 252
 253 DLLFLAGS=""
 254 LDSHARED=""
 255 if test "$LIB_TARGET" = "libwine.so.1.0"
 256 then
 257   AC_CACHE_CHECK("whether we can build a Linux dll",
 258                  ac_cv_c_dll_linux,
 259   [saved_cflags=$CFLAGS
 260   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 261   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 262   CFLAGS=$saved_cflags
 263   ])
 264   if test "$ac_cv_c_dll_linux" = "yes"
 265   then
 266     DLLFLAGS="-fPIC"
 267     LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so"
 268   else
 269     AC_CACHE_CHECK("whether we can build a NetBSD dll",
 270                    ac_cv_c_dll_netbsd,
 271     [saved_cflags=$CFLAGS
 272     CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 273     AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 274     CFLAGS=$saved_cflags
 275     ])
 276     if test "$ac_cv_c_dll_netbsd" = "yes"
 277     then
 278       DLLFLAGS="-fPIC"
 279       LDSHARED="ld -Bshareable -Bforcearchive"
 280     fi
 281   fi
 282   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 283   then
 284     LIB_TARGET="libwine.a"
 285   fi
 286 fi
 287 AC_SUBST(DLLFLAGS)
 288 AC_SUBST(LDSHARED)
 289
 290 dnl **** Check for reentrant libc ****
 291 dnl
 292 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 293 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 294
 295 AC_CACHE_CHECK("for reentrant libc", wine_cv_libc_reentrant,
 296   [AC_TRY_RUN([int myerrno = 0;
 297 char buf[256];
 298 int *__errno_location(){return &myerrno;}
 299 main(){connect(0,buf,255); exit(!myerrno);}],
 300   wine_cv_libc_reentrant=yes, wine_cv_libc_reentrant=no,
 301   wine_cv_libc_reentrant=yes ) ] )
 302 if test "$wine_cv_libc_reentrant" = "no"
 303 then
 304   AC_DEFINE(NO_REENTRANT_LIBC)
 305 fi
 306
 307 dnl **** Check for reentrant X libraries ****
 308 dnl
 309 dnl This may fail to determine whether X libraries are reentrant if
 310 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 311 dnl is possible with the --without-reentrant-x option.
 312
 313 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 314   [ if test "x$with_reentrant_x" = "xno"
 315     then
 316         wine_cv_x_reentrant=no
 317     else
 318         libX11_ckeck=none
 319         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 320             if test -r $dir/libX11.so; then
 321                 libX11_check="-D $dir/libX11.so"
 322                 break 1
 323             fi
 324             if test -r $dir/libX11.a; then
 325                 libX11_check="$dir/libX11.a"
 326                 break 1
 327             fi
 328         done
 329         if test "$libX11_check" != "none"; then
 330             if nm $libX11_check | grep __errno_location >/dev/null 2>&1
 331             then
 332                 wine_cv_x_reentrant=yes
 333             else
 334                 wine_cv_x_reentrant=no
 335             fi
 336         else
 337             wine_cv_x_reentrant=unknown
 338         fi
 339     fi ] )
 340 if test "$wine_cv_x_reentrant" = "no"
 341 then
 342   AC_DEFINE(NO_REENTRANT_X11)
 343 fi
 344
 345 dnl **** Check for functions and header files ****
 346
 347 AC_CHECK_FUNCS(clone getpagesize memmove sendmsg sigaltstack strerror stricmp tcgetattr timegm usleep wait4 waitpid vfscanf)
 348 AC_CHECK_HEADERS(wctype.h sys/syscall.h syscall.h sys/param.h sys/vfs.h sys/mount.h sys/statfs.h float.h linux/cdrom.h linux/ucdrom.h sys/cdio.h sys/filio.h sys/modem.h strings.h sys/strtio.h dlfcn.h unistd.h sys/sockio.h net/if.h netinet/in.h sys/file.h libio.h curses.h ncurses.h elf.h)
 349 AC_HEADER_STAT()
 350 AC_C_CONST()
 351 AC_TYPE_SIZE_T()
 352 AC_CHECK_SIZEOF(long long,0)
 353
 354 dnl **** Check for sendmsg in -lsocket if not found above ****
 355
 356 if test $ac_cv_func_sendmsg = no; then
 357     AC_CHECK_LIB(socket,sendmsg)
 358 fi
 359
 360 dnl **** statfs checks ****
 361
 362 if test "$ac_cv_header_sys_vfs_h" = "yes"
 363 then
 364     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 365                     wine_cv_sys_vfs_has_statfs,
 366         AC_TRY_COMPILE([
 367         #include <sys/types.h>
 368         #ifdef HAVE_SYS_PARAM_H
 369         # include <sys/param.h>
 370         #endif
 371         #include <sys/vfs.h>
 372         ],[
 373                 struct statfs stfs;
 374
 375                 memset(&stfs,0,sizeof(stfs));
 376         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 377         )
 378     )
 379     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 380     then
 381       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 382     fi
 383 fi
 384
 385 if test "$ac_cv_header_sys_statfs_h" = "yes"
 386 then
 387     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 388                     wine_cv_sys_statfs_has_statfs,
 389         AC_TRY_COMPILE([
 390         #include <sys/types.h>
 391         #ifdef HAVE_SYS_PARAM_H
 392         # include <sys/param.h>
 393         #endif
 394         #include <sys/statfs.h>
 395         ],[
 396                 struct statfs stfs;
 397         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 398         )
 399     )
 400     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 401     then
 402       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 403     fi
 404 fi
 405
 406 if test "$ac_cv_header_sys_mount_h" = "yes"
 407 then
 408     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 409                     wine_cv_sys_mount_has_statfs,
 410         AC_TRY_COMPILE([
 411         #include <sys/types.h>
 412         #ifdef HAVE_SYS_PARAM_H
 413         # include <sys/param.h>
 414         #endif
 415         #include <sys/mount.h>
 416         ],[
 417                 struct statfs stfs;
 418         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 419         )
 420     )
 421     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 422     then
 423       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 424     fi
 425 fi
 426
 427 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 428
 429 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 430   [ if test "x$statfs_bfree" = "xno"
 431     then
 432         wine_cv_statfs_bfree=no
 433     else
 434         AC_TRY_COMPILE([
 435         #include <sys/types.h>
 436         #ifdef HAVE_SYS_PARAM_H
 437         # include <sys/param.h>
 438         #endif
 439         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 440         # include <sys/mount.h>
 441         #else
 442         # ifdef STATFS_DEFINED_BY_SYS_VFS
 443         #  include <sys/vfs.h>
 444         # else
 445         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 446         #   include <sys/statfs.h>
 447         #  endif
 448         # endif
 449         #endif
 450         ],[
 451                 struct statfs stfs;
 452
 453                 stfs.f_bfree++;
 454         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 455         )
 456     fi ] )
 457 if test "$wine_cv_statfs_bfree" = "yes"
 458 then
 459   AC_DEFINE(STATFS_HAS_BFREE)
 460 fi
 461
 462 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 463   [ if test "x$statfs_bavail" = "xno"
 464     then
 465         wine_cv_statfs_bavail=no
 466     else
 467         AC_TRY_COMPILE([
 468         #include <sys/types.h>
 469         #ifdef HAVE_SYS_PARAM_H
 470         # include <sys/param.h>
 471         #endif
 472         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 473         # include <sys/mount.h>
 474         #else
 475         # ifdef STATFS_DEFINED_BY_SYS_VFS
 476         #  include <sys/vfs.h>
 477         # else
 478         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 479         #   include <sys/statfs.h>
 480         #  endif
 481         # endif
 482         #endif
 483         ],[
 484                 struct statfs stfs;
 485
 486                 stfs.f_bavail++;
 487         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 488         )
 489     fi ] )
 490 if test "$wine_cv_statfs_bavail" = "yes"
 491 then
 492   AC_DEFINE(STATFS_HAS_BAVAIL)
 493 fi
 494
 495 dnl *** check for working sigaltstack
 496 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 497
 498 AC_CACHE_CHECK("for working sigaltstack",
 499         ac_cv_c_working_sigaltstack,
 500         AC_TRY_RUN([
 501         #include <stdio.h>
 502         #include <time.h> /* <sys/time.h> ? bad magic without end */
 503         #include <sys/types.h>
 504         #include <sys/signal.h>
 505         #ifdef HAVE_SYS_PARAM_H
 506         # include <sys/param.h>
 507         #endif
 508         #ifdef HAVE_SYSCALL_H
 509         # include <syscall.h>
 510         #else
 511         # ifdef HAVE_SYS_SYSCALL_H
 512         #  include <sys/syscall.h>
 513         # endif
 514         #endif
 515
 516         unsigned char *xaltstack;
 517
 518         int
 519         main(int argc,char **argv) {
 520             struct sigaltstack  ss;
 521
 522             xaltstack = malloc(16384);
 523             ss.ss_sp    = xaltstack;
 524             ss.ss_size  = 16384;
 525             ss.ss_flags = 0;
 526             if (sigaltstack(&ss, NULL) < 0) {
 527                 /* this catches the glibc case */
 528                 perror("sigaltstack");
 529                 return (1); /* aka exit(1) aka fail */
 530             }
 531             /* assume it works. */
 532             return 0; /* OK */
 533         }
 534         ],
 535         ac_cv_c_working_sigaltstack="yes",
 536         ac_cv_c_working_sigaltstack="no",
 537         ac_cv_c_working_sigaltstack="no"
 538 ))
 539
 540 if test "$ac_cv_c_working_sigaltstack" = "yes"
 541 then
 542     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 543 fi
 544
 545
 546 dnl *** check for file descriptor passing with msg_accrights
 547
 548 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 549  AC_TRY_COMPILE([#include <sys/types.h>
 550 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 551                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 552 if test "$ac_cv_c_msg_accrights" = "yes"
 553 then
 554     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 555 fi
 556
 557 dnl **** Generate output files ****
 558
 559 MAKE_RULES=Make.rules
 560 AC_SUBST_FILE(MAKE_RULES)
 561
 562 AC_OUTPUT([
 563 Make.rules
 564 Makefile
 565 console/Makefile
 566 controls/Makefile
 567 debugger/Makefile
 568 dlls/Makefile
 569 dlls/advapi32/Makefile
 570 dlls/comctl32/Makefile
 571 dlls/imagehlp/Makefile
 572 dlls/msacm/Makefile
 573 dlls/msacm32/Makefile
 574 dlls/ntdll/Makefile
 575 dlls/psapi/Makefile
 576 dlls/rasapi32/Makefile
 577 dlls/shell32/Makefile
 578 dlls/ver/Makefile
 579 dlls/version/Makefile
 580 dlls/winaspi/Makefile
 581 dlls/wnaspi32/Makefile
 582 documentation/Makefile
 583 files/Makefile
 584 graphics/Makefile
 585 graphics/metafiledrv/Makefile
 586 graphics/psdrv/Makefile
 587 graphics/win16drv/Makefile
 588 graphics/x11drv/Makefile
 589 if1632/Makefile
 590 ipc/Makefile
 591 library/Makefile
 592 libtest/Makefile
 593 loader/Makefile
 594 loader/ne/Makefile
 595 loader/dos/Makefile
 596 memory/Makefile
 597 misc/Makefile
 598 miscemu/Makefile
 599 msdos/Makefile
 600 multimedia/Makefile
 601 objects/Makefile
 602 ole/Makefile
 603 programs/Makefile
 604 programs/clock/Makefile
 605 programs/control/Makefile
 606 programs/avitools/Makefile
 607 programs/notepad/Makefile
 608 programs/progman/Makefile
 609 programs/regtest/Makefile
 610 programs/view/Makefile
 611 programs/winhelp/Makefile
 612 programs/winver/Makefile
 613 rc/Makefile
 614 relay32/Makefile
 615 resources/Makefile
 616 scheduler/Makefile
 617 server/Makefile
 618 tools/Makefile
 619 tools/wrc/Makefile
 620 tsx11/Makefile
 621 win32/Makefile
 622 windows/Makefile
 623 windows/ttydrv/Makefile
 624 windows/x11drv/Makefile ])
 625
 626 if test "$have_x" = "no"
 627 then
 628   echo
 629   echo "*** Warning: X development files not found. Wine will be built without"
 630   echo "*** X support, which currently does not work, and would probably not be"
 631   echo "*** what you want anyway. You will need to install devel packages of"
 632   echo "*** Xlib/Xfree86 and Xpm at the very least."
 633 fi
 634
 635 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
 636 then
 637   echo
 638   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
 639   echo "*** terminal resize support. Consider upgrading ncurses."
 640 fi
 641
 642 if test "$wine_cv_libc_reentrant" = "no"
 643 then
 644   echo
 645   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 646   echo "*** thread support. Consider upgrading libc to a more recent"
 647   echo "*** reentrant version of libc."
 648 fi
 649
 650 echo
 651 echo "Configure finished.  Do 'make depend; make' to compile Wine."
 652 echo
 653
 654 dnl Local Variables:
 655 dnl comment-start: "dnl "
 656 dnl comment-end: ""
 657 dnl comment-start-skip: "\\bdnl\\b\\s *"
 658 dnl compile-command: "autoconf"
 659 dnl End: