| blob | d808c8854dde322de068a001091173ce22d47e42 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53b)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(DLLDEFS,"")
25 if test "x$enable_debug" = "xno"
26 then
27 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
32 fi
34 AC_CANONICAL_HOST
35 case $host in
36 x86_64*linux*)
37 if test "x$enable_win64" != "xyes"
38 then
39 test -n "$CC" || CC="gcc -m32"
40 test -n "$LD" || LD="ld -m elf_i386"
41 test -n "$AS" || AS="as --32"
42 host_cpu="i386"
43 fi
44 ;;
45 esac
47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
48 case $host_cpu in
49 *i[[3456789]]86*)
50 if test "x$enable_win16" != "xno"
51 then
52 enable_win16="yes"
53 fi
54 ;;
55 esac
57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
59 if test "x$enable_win16" != "xyes"
60 then
61 WIN16_FILES=""
62 WIN16_INSTALL=""
63 fi
65 dnl **** Check for some programs ****
67 AC_PROG_MAKE_SET
68 AC_PROG_CC
69 AC_PROG_CXX
70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
74 [if test -z "$with_wine_tools"; then
75 if test "$cross_compiling" = "yes"; then
76 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
77 else
78 wine_cv_toolsdir="\$(TOPOBJDIR)"
79 fi
80 elif test -d "$with_wine_tools/tools/winebuild"; then
81 case $with_wine_tools in
82 /*) wine_cv_toolsdir="$with_wine_tools" ;;
83 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
84 esac
85 else
86 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
87 fi])
88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
90 AC_PATH_XTRA
91 AC_PROG_LEX
93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
94 dnl **** without one present.
95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
96 if test "$XLEX" = "none"
97 then
98 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
99 fi
101 dnl Check for bison
102 AC_CHECK_PROGS(BISON,bison,none)
103 if test "$BISON" = "none"
104 then
105 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
106 fi
108 AC_CHECK_TOOLS(AS,[gas as],as)
109 AC_CHECK_TOOL(LD,ld,ld)
110 AC_CHECK_TOOL(AR,ar,ar)
111 AC_PROG_RANLIB
112 AC_CHECK_TOOL(STRIP,strip,strip)
113 AC_CHECK_TOOL(WINDRES,windres,false)
114 AC_PROG_LN_S
115 WINE_PROG_LN
116 AC_PROG_EGREP
117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
118 AC_PROG_INSTALL
119 dnl Prepend src dir to install path dir if it's a relative path
120 case "$INSTALL" in
121 [[\\/$]]* | ?:[[\\/]]* ) ;;
122 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
123 esac
125 dnl Check for lint
126 AC_CHECK_PROGS(LINT, lclint lint)
127 if test "$LINT" = "lint"
128 then
129 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
130 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
131 fi
132 AC_SUBST(LINT)
133 AC_SUBST(LINTFLAGS)
135 dnl Check for various programs
136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
137 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
139 case $host_cpu in
140 *i[[3456789]]86*)
141 AC_CHECK_PROGS(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
142 ;;
143 esac
145 dnl **** Check for some libraries ****
147 dnl Check for -li386 for NetBSD and OpenBSD
148 AC_CHECK_LIB(i386,i386_set_ldt)
149 dnl Check for -lossaudio for NetBSD
150 AC_CHECK_LIB(ossaudio,_oss_ioctl)
151 dnl Check for -lnsl for Solaris
152 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
153 dnl Check for -lsocket for Solaris
154 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
155 dnl Check for -lresolv for Solaris
156 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
157 dnl Check for -lxpg4 for FreeBSD
158 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
159 dnl Check for -lpoll for Mac OS X/Darwin
160 AC_CHECK_LIB(poll,poll)
161 dnl Check for -lresolv for Mac OS X/Darwin
162 AC_CHECK_LIB(resolv,res_9_init)
163 dnl Check for -lpthread
164 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
166 AC_SUBST(XLIB,"")
167 AC_SUBST(XFILES,"")
168 AC_SUBST(OPENGLFILES,"")
169 AC_SUBST(GLU32FILES,"")
170 AC_SUBST(OPENGL_LIBS,"")
172 dnl **** Check for header files ****
174 AC_CHECK_HEADERS(\
175 IOKit/IOKitLib.h \
176 alsa/asoundlib.h \
177 arpa/inet.h \
178 arpa/nameser.h \
179 asm/types.h \
180 capi20.h \
181 cups/cups.h \
182 curses.h \
183 direct.h \
184 dlfcn.h \
185 elf.h \
186 float.h \
187 fontconfig/fontconfig.h \
188 getopt.h \
189 gif_lib.h \
190 ieeefp.h \
191 io.h \
192 jack/jack.h \
193 jpeglib.h \
194 lber.h \
195 lcms.h \
196 lcms/lcms.h \
197 ldap.h \
198 libaudioio.h \
199 link.h \
200 linux/capi.h \
201 linux/cdrom.h \
202 linux/compiler.h \
203 linux/hdreg.h \
204 linux/input.h \
205 linux/ioctl.h \
206 linux/joystick.h \
207 linux/major.h \
208 linux/param.h \
209 linux/serial.h \
210 linux/ucdrom.h \
211 mach/machine.h \
212 machine/cpu.h \
213 machine/limits.h \
214 machine/soundcard.h \
215 mntent.h \
216 ncurses.h \
217 netdb.h \
218 netinet/in.h \
219 netinet/in_systm.h \
220 netinet/tcp.h \
221 netinet/tcp_fsm.h \
222 openssl/err.h \
223 openssl/ssl.h \
224 poll.h \
225 process.h \
226 pthread.h \
227 pwd.h \
228 regex.h \
229 sched.h \
230 scsi/scsi.h \
231 scsi/scsi_ioctl.h \
232 scsi/sg.h \
233 soundcard.h \
234 stdint.h \
235 strings.h \
236 sys/asoundlib.h \
237 sys/cdio.h \
238 sys/elf32.h \
239 sys/epoll.h \
240 sys/errno.h \
241 sys/exec_elf.h \
242 sys/filio.h \
243 sys/ioctl.h \
244 sys/ipc.h \
245 sys/limits.h \
246 sys/link.h \
247 sys/lwp.h \
248 sys/mman.h \
249 sys/modem.h \
250 sys/msg.h \
251 sys/mtio.h \
252 sys/param.h \
253 sys/poll.h \
254 sys/ptrace.h \
255 sys/reg.h \
256 sys/scsiio.h \
257 sys/shm.h \
258 sys/signal.h \
259 sys/socket.h \
260 sys/sockio.h \
261 sys/soundcard.h \
262 sys/statvfs.h \
263 sys/strtio.h \
264 sys/syscall.h \
265 sys/sysctl.h \
266 sys/time.h \
267 sys/times.h \
268 sys/uio.h \
269 sys/un.h \
270 sys/vm86.h \
271 sys/wait.h \
272 syscall.h \
273 termios.h \
274 unicode/ubidi.h \
275 unistd.h \
276 utime.h \
277 valgrind/memcheck.h
278 )
279 AC_HEADER_STAT()
281 dnl **** Check for X11 ****
283 if test "$have_x" = "yes"
284 then
285 XLIB="-lXext -lX11"
286 ac_save_CPPFLAGS="$CPPFLAGS"
287 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
289 dnl *** All of the following tests require X11/Xlib.h
290 AC_CHECK_HEADERS([X11/Xlib.h \
291 X11/XKBlib.h \
292 X11/Xutil.h \
293 X11/extensions/shape.h \
294 X11/extensions/XInput.h \
295 X11/extensions/XShm.h \
296 X11/extensions/Xrandr.h \
297 X11/extensions/Xrender.h \
298 X11/extensions/xf86dga.h \
299 X11/extensions/xf86vmode.h],,,
300 [#ifdef HAVE_X11_XLIB_H
301 # include <X11/Xlib.h>
302 #endif
303 #ifdef HAVE_X11_XUTIL_H
304 # include <X11/Xutil.h>
305 #endif])
307 dnl *** Check for X keyboard extension
308 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
309 then
310 AC_CHECK_LIB(X11, XkbQueryExtension,
311 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
312 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
313 fi
315 dnl *** Check for X Shm extension
316 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
317 then
318 AC_CHECK_LIB(Xext, XShmQueryExtension,
319 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
320 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
321 fi
323 dnl *** Check for X shape extension
324 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
325 then
326 AC_CHECK_LIB(Xext,XShapeQueryExtension,
327 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
328 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
329 fi
331 dnl *** Check for XFree86 DGA / DGA 2.0 extension
332 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
333 then
334 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
335 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
336 [Define if you have the Xxf86dga library version 2])
337 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
338 ],,
339 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
340 fi
342 dnl *** Check for XFree86 VMODE extension
343 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
344 then
345 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
346 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
347 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
348 ],,
349 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
350 fi
352 dnl *** Check for X RandR extension
353 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
354 then
355 AC_TRY_COMPILE([#include <X11/Xlib.h>
356 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
357 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
358 fi
360 dnl *** Check for Transform functions in Xrender
361 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
362 then
363 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
364 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
365 [Define if Xrender has the XRenderSetPictureTransform function])],,
366 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
367 fi
368 dnl *** End of X11/Xlib.h check
370 dnl Check for the presence of OpenGL
371 if test "x$with_opengl" != "xno"
372 then
373 AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h,,,
374 [#ifdef HAVE_GL_GLX_H
375 # include <GL/glx.h>
376 #endif])
377 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
378 then
379 dnl Check for some problems due to old Mesa versions
380 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
381 AC_TRY_COMPILE(
382 [#include <GL/gl.h>],
383 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
384 [wine_cv_opengl_version_OK="yes"],
385 [wine_cv_opengl_version_OK="no"]
386 )
387 )
389 if test "$wine_cv_opengl_version_OK" = "yes"
390 then
391 dnl Check for the presence of the library
392 AC_CHECK_LIB(GL,glXCreateContext,
393 OPENGL_LIBS="-lGL"
394 ,,
395 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
397 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
398 then
399 OPENGLFILES='$(OPENGLFILES)'
400 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
401 else
402 if test -f /usr/X11R6/lib/libGL.a
403 then
404 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
405 This prevents linking to OpenGL. Delete the file and restart configure.])
406 fi
407 fi
409 dnl Check for GLU32 library.
410 AC_CHECK_LIB(GLU,gluLookAt,
411 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
412 GLU32FILES='$(GLU32FILES)']
413 ,,
414 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
415 )
416 fi
418 dnl Check for glut32 library.
419 AC_CHECK_LIB(glut,glutMainLoop,
420 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
421 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
422 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
423 fi
424 fi
426 dnl **** Check for NAS ****
427 AC_SUBST(NASLIBS,"")
428 AC_CHECK_HEADERS(audio/audiolib.h,
429 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
430 AC_CHECK_LIB(audio,AuCreateFlow,
431 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
432 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
433 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
435 CPPFLAGS="$ac_save_CPPFLAGS"
436 XFILES='$(XFILES)'
437 else
438 XLIB=""
439 X_CFLAGS=""
440 X_LIBS=""
441 fi
443 dnl **** Check for libxml2 ****
445 AC_SUBST(XML2LIBS,"")
446 AC_SUBST(XML2INCL,"")
447 AC_SUBST(XSLTLIBS,"")
448 AC_SUBST(XSLTINCL,"")
449 if test "$PKG_CONFIG" != "false"
450 then
451 ac_save_CPPFLAGS="$CPPFLAGS"
452 ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0`"
453 ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0`"
454 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
455 AC_CHECK_HEADERS(libxml/parser.h,
456 [AC_CHECK_LIB(xml2, xmlParseMemory,
457 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
458 XML2LIBS="$ac_xml_libs"
459 XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
460 AC_CHECK_LIB(xml2, xmlReadMemory,
461 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
462 ])
463 CPPFLAGS="$ac_save_CPPFLAGS"
464 ac_xslt_libs="`$PKG_CONFIG --libs libxslt`"
465 ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt`"
466 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
467 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
468 [AC_CHECK_LIB(xslt, xsltCompilePattern,
469 [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
470 XSLTLIBS="$ac_xslt_libs"
471 XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
472 ],,
473 [#ifdef HAVE_LIBXSLT_PATTERN_H
474 # include <libxslt/pattern.h>
475 #endif])
476 CPPFLAGS="$ac_save_CPPFLAGS"
477 fi
479 dnl **** Check which curses lib to use ***
480 CURSESLIBS=""
481 if test "x$with_curses" != "xno"
482 then
483 if test "$ac_cv_header_ncurses_h" = "yes"
484 then
485 AC_CHECK_LIB(ncurses,waddch,
486 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
487 CURSESLIBS="-lncurses"])
488 elif test "$ac_cv_header_curses_h" = "yes"
489 then
490 AC_CHECK_LIB(curses,waddch,
491 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
492 CURSESLIBS="-lcurses"])
493 fi
494 fi
495 AC_SUBST(CURSESLIBS)
497 dnl **** Check for SANE ****
498 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
499 AC_SUBST(SANELIBS,"")
500 AC_SUBST(SANEINCL,"")
501 if test "$sane_devel" != "no"
502 then
503 SANELIBS="`$sane_devel --libs`"
504 SANEINCL="`$sane_devel --cflags`"
505 ac_save_CPPFLAGS="$CPPFLAGS"
506 ac_save_LIBS="$LIBS"
507 CPPFLAGS="$CPPFLAGS $SANEINCL"
508 LIBS="$LIBS $SANELIBS"
509 AC_CHECK_HEADER(sane/sane.h,
510 [AC_CHECK_LIB(sane,sane_open,
511 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
512 [SANELIBS=""
513 SANEINCL=""])],
514 [SANELIBS=""
515 SANEINCL=""])
516 LIBS="$ac_save_LIBS"
517 CPPFLAGS="$ac_save_CPPFLAGS"
518 fi
520 dnl **** Check for the ICU library ****
521 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
522 then
523 saved_libs="$LIBS"
524 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
525 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
526 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
527 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
528 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
529 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
530 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
531 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
532 AC_MSG_RESULT(yes)],
533 [AC_MSG_RESULT(no)])
534 LIBS="$saved_libs"
535 fi
537 dnl **** Check for LittleCMS ***
538 AC_SUBST(LCMSLIBS,"")
539 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
540 then
541 AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
542 [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
543 LCMSLIBS="-llcms"])
544 fi
546 dnl **** Check for OpenLDAP ***
547 AC_SUBST(LDAPLIBS,"")
548 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
549 then
550 AC_CHECK_LIB(ldap_r, ldap_initialize,
551 [AC_CHECK_LIB(lber, ber_init,
552 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
553 LDAPLIBS="-lldap_r -llber"],,
554 [$LIBPTHREAD])],,
555 [$LIBPTHREAD])
556 ac_save_LIBS="$LIBS"
557 LIBS="$LIBS $LDAPLIBS $LIBPTHREAD"
558 AC_CHECK_FUNCS(\
559 ldap_count_references \
560 ldap_first_reference \
561 ldap_next_reference \
562 ldap_parse_reference)
563 LIBS="$ac_save_LIBS"
564 fi
566 dnl **** Check for FreeType 2 ****
567 AC_SUBST(FREETYPELIBS,"")
568 AC_SUBST(FREETYPEINCL,"")
569 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
570 if test "$ft_lib" = "no"
571 then
572 wine_cv_msg_freetype=no
573 else
574 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
575 if test "$ft_devel" = "no"
576 then
577 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
578 if test "$ft_devel2" = "freetype2-config"
579 then
580 ft_devel=$ft_devel2
581 fi
582 fi
583 if test "$ft_devel" = "no"
584 then
585 wine_cv_msg_freetype=yes
586 else
587 FREETYPELIBS=`$ft_devel --libs`
588 FREETYPEINCL=`$ft_devel --cflags`
589 ac_save_CPPFLAGS="$CPPFLAGS"
590 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
591 AC_CHECK_HEADERS(ft2build.h \
592 freetype/freetype.h \
593 freetype/ftglyph.h \
594 freetype/tttables.h \
595 freetype/ftnames.h \
596 freetype/ftsnames.h \
597 freetype/ttnameid.h \
598 freetype/ftoutln.h \
599 freetype/ftwinfnt.h \
600 freetype/ftmodapi.h \
601 freetype/internal/sfnt.h,,,
602 [#if HAVE_FT2BUILD_H
603 #include <ft2build.h>
604 #endif])
605 AC_TRY_CPP([#include <ft2build.h>
606 #include <freetype/fttrigon.h>],
607 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
608 [Define if you have the <freetype/fttrigon.h> header file.])
609 wine_cv_fttrigon=yes],
610 wine_cv_fttrigon=no)
611 CPPFLAGS="$ac_save_CPPFLAGS"
612 dnl Check that we have at least freetype/freetype.h
613 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
614 then
615 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
616 wine_cv_msg_freetype=no
617 else
618 FREETYPELIBS=""
619 FREETYPEINCL=""
620 wine_cv_msg_freetype=yes
621 fi
622 fi
623 fi
625 dnl Only build the fonts dir if we have both freetype and fontforge
626 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
627 then
628 AC_SUBST(FONTSSUBDIRS,"fonts")
629 fi
631 dnl **** Check for parport (currently Linux only) ****
632 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
633 AC_TRY_COMPILE(
634 [#include <linux/ppdev.h>],
635 [ioctl (1,PPCLAIM,0)],
636 [ac_cv_c_ppdev="yes"],
637 [ac_cv_c_ppdev="no"])
638 )
639 if test "$ac_cv_c_ppdev" = "yes"
640 then
641 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
642 fi
644 dnl **** Check for va_copy ****
645 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
646 AC_TRY_LINK(
647 [#include <stdarg.h>],
648 [va_list ap1, ap2;
649 va_copy(ap1,ap2);
650 ],
651 [ac_cv_c_va_copy="yes"],
652 [ac_cv_c_va_copy="no"])
653 )
654 if test "$ac_cv_c_va_copy" = "yes"
655 then
656 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
657 fi
658 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
659 AC_TRY_LINK(
660 [#include <stdarg.h>],
661 [va_list ap1, ap2;
662 __va_copy(ap1,ap2);
663 ],
664 [ac_cv_c___va_copy="yes"],
665 [ac_cv_c___va_copy="no"])
666 )
667 if test "$ac_cv_c___va_copy" = "yes"
668 then
669 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
670 fi
672 dnl **** Check for sigsetjmp ****
673 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
674 AC_TRY_LINK(
675 [#include <setjmp.h>],
676 [sigjmp_buf buf;
677 sigsetjmp( buf, 1 );
678 siglongjmp( buf, 1 );],
679 [ac_cv_c_sigsetjmp="yes"],
680 [ac_cv_c_sigsetjmp="no"])
681 )
682 if test "$ac_cv_c_sigsetjmp" = "yes"
683 then
684 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
685 fi
687 dnl **** Check for pthread_rwlock_t ****
688 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
689 #include <pthread.h>])
691 dnl **** Check for pthread functions ****
692 ac_save_LIBS="$LIBS"
693 LIBS="$LIBS $LIBPTHREAD"
694 AC_CHECK_FUNCS(\
695 pthread_getattr_np \
696 pthread_get_stackaddr_np \
697 pthread_get_stacksize_np \
698 )
699 LIBS="$ac_save_LIBS"
701 dnl **** Check for aRts Sound Server ****
702 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
703 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
704 then
705 ARTSC_CFLAGS=""
706 for i in `$ARTSCCONFIG --cflags`
707 do
708 case "$i" in
709 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
710 esac
711 done
712 ARTSC_LIBS=`$ARTSCCONFIG --libs`
713 save_CFLAGS="$CFLAGS"
714 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
715 AC_CHECK_LIB(artsc,arts_init,
716 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
717 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
718 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
719 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
720 $ARTSC_LIBS)
721 CFLAGS="$save_CFLAGS"
722 fi
724 dnl **** Check for EsounD ****
725 AC_PATH_PROG(ESDCONFIG, esd-config)
726 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
727 then
728 ESD_CFLAGS=""
729 for i in `$ESDCONFIG --cflags`
730 do
731 case "$i" in
732 -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
733 esac
734 done
735 ESD_LIBS=`$ESDCONFIG --libs`
736 save_CFLAGS="$CFLAGS"
737 CFLAGS="$CFLAGS $ESD_CFLAGS"
738 AC_CHECK_LIB(esd,esd_open_sound,
739 [AC_SUBST(ESDLIBS, $ESD_LIBS)
740 AC_SUBST(ESDINCL, $ESD_CFLAGS)
741 AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
742 CFLAGS="$save_CFLAGS"
743 fi
745 dnl **** Check for ALSA 1.x ****
746 AC_SUBST(ALSALIBS,"")
747 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
748 then
749 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
750 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
751 #include <alsa/asoundlib.h>
752 #elif defined(HAVE_SYS_ASOUNDLIB_H)
753 #include <sys/asoundlib.h>
754 #endif],
755 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
756 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
757 ALSALIBS="-lasound"])])
758 fi
760 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
762 AC_SUBST(AUDIOIOLIBS,"")
763 if test "$ac_cv_header_libaudioio_h" = "yes"
764 then
765 AC_CHECK_LIB(audioio,AudioIOGetVersion,
766 [AUDIOIOLIBS="-laudioio"
767 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
768 fi
770 dnl **** Check for capi4linux ****
772 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
773 then
774 AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
775 fi
777 dnl **** Check for gcc specific options ****
779 AC_SUBST(EXTRACFLAGS,"")
780 if test "x${GCC}" = "xyes"
781 then
782 EXTRACFLAGS="-Wall -pipe"
784 dnl Check for strength-reduce bug
785 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
786 AC_TRY_RUN([
787 int L[[4]] = {0,1,2,3};
788 int main(void) {
789 static int Array[[3]];
790 unsigned int B = 3;
791 int i;
792 for(i=0; i<B; i++) Array[[i]] = i - 3;
793 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
794 L[[i]] = 4;
796 exit( Array[[1]] != -2 || L[[2]] != 3);
797 }],
798 ac_cv_c_gcc_strength_bug="no",
799 ac_cv_c_gcc_strength_bug="yes",
800 ac_cv_c_gcc_strength_bug="yes") )
801 if test "$ac_cv_c_gcc_strength_bug" = "yes"
802 then
803 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
804 fi
806 dnl Check for -fshort-wchar
807 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
808 [WINE_TRY_CFLAGS([-fshort-wchar],
809 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
810 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
811 then
812 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
813 fi
815 dnl Check for -fno-strict-aliasing
816 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
817 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
818 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
819 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
820 then
821 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
822 fi
824 dnl Check for -gstabs+ option
825 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
826 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
827 if test "$ac_cv_c_gcc_gstabs" = "yes"
828 then
829 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
830 fi
832 dnl Check for -Wdeclaration-after-statement option
833 AC_CACHE_CHECK([for gcc -Wdeclaration-after-statement support], ac_cv_c_gcc_decl_after_statement,
834 [WINE_TRY_CFLAGS([-Wdeclaration-after-statement],ac_cv_c_gcc_decl_after_statement="yes", ac_cv_c_gcc_decl_after_statement="no")])
835 if test "$ac_cv_c_gcc_decl_after_statement" = "yes"
836 then
837 EXTRACFLAGS="$EXTRACFLAGS -Wdeclaration-after-statement"
838 fi
840 dnl Check for noisy string.h
841 saved_CFLAGS="$CFLAGS"
842 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
843 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
844 AC_TRY_COMPILE([#include <string.h>],[],
845 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
846 CFLAGS="$saved_CFLAGS"
847 if test "$ac_cv_c_string_h_warnings" = "no"
848 then
849 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
850 fi
852 AC_SUBST(BUILTINFLAG,"")
853 saved_CFLAGS="$CFLAGS"
854 CFLAGS="$CFLAGS -Werror"
855 AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
856 AC_TRY_COMPILE([],
857 [int iswlower(unsigned short);],
858 [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
859 CFLAGS="$saved_CFLAGS"
860 if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
861 then
862 BUILTINFLAG=""
863 for builtin in \
864 iswalnum iswalpha iswcntrl iswdigit iswgraph iswlower \
865 iswprint iswpunct iswspace iswupper iswxdigit towlower towupper
866 do
867 BUILTINFLAG="$BUILTINFLAG -fno-builtin-$builtin"
868 done
869 fi
870 fi
872 dnl **** Check how to define a function in assembly code ****
874 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
875 WINE_TRY_ASM_LINK(
876 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
877 ac_cv_asm_func_def=".def",
878 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
879 ac_cv_asm_func_def=".type @function",
880 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
881 ac_cv_asm_func_def=".type 2",
882 ac_cv_asm_func_def="unknown")])]))
884 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
885 case "$ac_cv_asm_func_def" in
886 ".def")
887 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
888 ".type @function")
889 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
890 ".type 2")
891 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
892 *)
893 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
894 esac
896 dnl **** Check for underscore on external symbols ****
898 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
899 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
900 [extern int ac_test;],
901 [if (ac_test) return 1],
902 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
904 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
905 if test "$ac_cv_c_extern_prefix" = "yes"
906 then
907 AC_DEFINE([__ASM_NAME(name)], ["_" name])
908 else
909 AC_DEFINE([__ASM_NAME(name)], [name])
910 fi
912 dnl **** Check for working dll ****
914 AC_SUBST(DLLEXT,"")
915 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
916 AC_SUBST(DLLIBS,"")
917 AC_SUBST(LDSHARED,"")
918 AC_SUBST(LDDLLFLAGS,"")
919 AC_SUBST(LIBEXT,"so")
920 AC_SUBST(IMPLIBEXT,"def")
922 case $host_os in
923 cygwin*|mingw32*)
924 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
925 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
926 if test "$DLLWRAP" = "false"; then
927 LIBEXT="a"
928 else
929 dnl FIXME - check whether dllwrap works correctly...
930 LIBEXT="dll"
931 fi
932 IMPLIBEXT="a"
933 dnl We can't build 16-bit NE dlls
934 WIN16_FILES=""
935 WIN16_INSTALL=""
936 ;;
937 *)
938 if test "$ac_cv_header_dlfcn_h" = "yes"
939 then
940 AC_CHECK_FUNCS(dlopen,,
941 [AC_CHECK_LIB(dl,dlopen,
942 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
943 DLLIBS="-ldl"],
944 [LIBEXT="a"])])
945 else
946 LIBEXT="a"
947 fi
949 if test "$LIBEXT" = "so"
950 then
951 DLLFLAGS="$DLLFLAGS -fPIC"
952 DLLEXT=".so"
953 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
954 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
955 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
956 if test "$ac_cv_c_dll_gnuelf" = "yes"
957 then
958 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
959 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
960 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
961 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
962 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
963 if test "$ac_cv_c_dll_zdefs" = "yes"
964 then
965 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
966 fi
968 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
969 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
970 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
971 if test "$ac_cv_c_dll_init_fini" = "yes"
972 then
973 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
974 fi
976 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
977 [echo '{ global: *; };' >conftest.map
978 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
979 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
980 rm -f conftest.map])
981 if test "$ac_cv_c_ld_version_scripts" = "yes"
982 then
983 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
984 fi
986 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
987 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
988 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
989 if test "$ac_cv_c_export_dynamic" = "yes"
990 then
991 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
992 fi
994 case $host_cpu in
995 *i[[3456789]]86*)
996 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
997 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
998 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
999 if test "$ac_cv_ld_reloc_exec" = "yes"
1000 then
1001 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1002 fi
1003 ;;
1004 esac
1006 else
1007 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1008 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1009 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1010 if test "$ac_cv_c_dll_unixware" = "yes"
1011 then
1012 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1013 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1015 else
1016 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1017 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1018 if test "$ac_cv_c_dll_macho" = "yes"
1019 then
1020 LIBEXT="dylib"
1021 LDDLLFLAGS="-bundle"
1022 LDSHARED="\$(CC) -dynamiclib"
1023 STRIP="$STRIP -u -r"
1024 dnl declare needed frameworks
1025 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1026 AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1027 case $host_cpu in
1028 *i[[3456789]]86*)
1029 AC_SUBST(LDEXECFLAGS,"-image_base 0x7bf00000")
1030 ;;
1031 *powerpc*)
1032 CFLAGS="$CFLAGS -ffixed-r13"
1033 LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"
1034 dnl Relocate wine executable (FIXME: is this really needed?)
1035 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1036 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1037 ;;
1038 esac
1040 else
1041 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1042 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1043 if test "$ac_cv_c_dll_hpux" = "yes"
1044 then
1045 LIBEXT="sl"
1046 DLLEXT=".sl"
1047 LDDLLFLAGS="-shared -fPIC"
1048 LDSHARED="\$(CC) -shared"
1049 fi
1050 fi
1051 fi
1052 fi
1053 fi
1055 dnl Check for cross compiler to build test programs
1056 AC_SUBST(CROSSTEST,"")
1057 if test "$cross_compiling" = "no"
1058 then
1059 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1060 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1061 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1062 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1063 fi
1064 ;;
1065 esac
1067 if test "$LIBEXT" = "a"; then
1068 AC_MSG_ERROR(
1069 [could not find a way to build shared libraries.
1070 It is currently not possible to build Wine without shared library
1071 (.so) support to allow transparent switch between .so and .dll files.
1072 If you are using Linux, you will need a newer binutils.]
1073 )
1074 fi
1076 case $build_os in
1077 cygwin*|mingw32*)
1078 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1079 darwin*|macosx*)
1080 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1081 *)
1082 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1083 esac
1085 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1086 case $host_os in
1087 mingw32*)
1088 AC_SUBST(CRTLIBS,"-lmsvcrt")
1089 AC_SUBST(SOCKETLIBS,"-lws2_32")
1090 ;;
1091 esac
1093 case $host_os in
1094 linux* | k*bsd*-gnu)
1095 case $host_cpu in
1096 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1097 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1098 esac
1099 AC_SUBST(MAIN_BINARY,"wine-glibc")
1100 ;;
1101 darwin*)
1102 AC_SUBST(WINE_BINARIES,"wine-pthread")
1103 AC_SUBST(MAIN_BINARY,"wine-pthread")
1104 ;;
1105 *)
1106 AC_SUBST(WINE_BINARIES,"wine-kthread")
1107 AC_SUBST(MAIN_BINARY,"wine-kthread")
1108 ;;
1109 esac
1111 dnl **** Get the soname for libraries that we load dynamically ****
1113 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1114 then
1115 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1116 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1117 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1118 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1119 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1120 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1121 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1122 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1123 WINE_GET_SONAME(cups,cupsGetDefault)
1124 WINE_GET_SONAME(jack,jack_client_new)
1125 WINE_GET_SONAME(fontconfig,FcInit)
1126 WINE_GET_SONAME(ssl,SSL_library_init)
1127 WINE_GET_SONAME(crypto,BIO_new_socket)
1128 WINE_GET_SONAME(ncurses,waddch)
1129 WINE_GET_SONAME(curses,waddch)
1130 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1131 WINE_GET_SONAME(ungif,DGifOpen)
1132 WINE_GET_SONAME(gif,DGifOpen)
1133 WINE_GET_SONAME(capi20,capi20_isinstalled)
1134 fi
1137 dnl **** Check for functions ****
1139 AC_CHECK_FUNCS(\
1140 _lwp_create \
1141 _lwp_self \
1142 _pclose \
1143 _popen \
1144 _snprintf \
1145 _spawnvp \
1146 _stricmp \
1147 _strnicmp \
1148 _vsnprintf \
1149 asctime_r \
1150 chsize \
1151 clone \
1152 epoll_create \
1153 ffs \
1154 finite \
1155 fork \
1156 fpclass \
1157 fstatfs \
1158 fstatvfs \
1159 ftruncate \
1160 futimes \
1161 futimesat \
1162 getaddrinfo \
1163 getnetbyname \
1164 getopt_long \
1165 getpagesize \
1166 getprotobyname \
1167 getprotobynumber \
1168 getpwuid \
1169 getservbyport \
1170 gettid \
1171 gettimeofday \
1172 getuid \
1173 inet_network \
1174 lstat \
1175 memmove \
1176 mmap \
1177 pclose \
1178 popen \
1179 pread \
1180 pwrite \
1181 readlink \
1182 rfork \
1183 sched_yield \
1184 select \
1185 sendmsg \
1186 settimeofday \
1187 sigaltstack \
1188 sigprocmask \
1189 snprintf \
1190 spawnvp \
1191 statfs \
1192 statvfs \
1193 strcasecmp \
1194 strerror \
1195 strncasecmp \
1196 tcgetattr \
1197 timegm \
1198 usleep \
1199 vsnprintf \
1200 wait4 \
1201 waitpid \
1202 )
1204 dnl **** Checks for headers that depend on other ones ****
1206 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
1207 [#include <sys/types.h>
1208 #if HAVE_SYS_PARAM_H
1209 # include <sys/param.h>
1210 #endif])
1212 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
1213 [#include <sys/types.h>
1214 #if HAVE_SYS_SOCKET_H
1215 # include <sys/socket.h>
1216 #endif])
1218 AC_CHECK_HEADERS([resolv.h],,,
1219 [#include <sys/types.h>
1220 #if HAVE_SYS_SOCKET_H
1221 # include <sys/socket.h>
1222 #endif
1223 #if HAVE_NETINET_IN_H
1224 # include <netinet/in.h>
1225 #endif
1226 #if HAVE_ARPA_NAMESER_H
1227 # include <arpa/nameser.h>
1228 #endif])
1230 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1232 AC_CHECK_HEADERS([linux/ipx.h linux/videodev.h],,,
1233 [#ifdef HAVE_SYS_TIME_H
1234 #include <sys/time.h>
1235 #endif
1236 #include <sys/types.h>
1237 #ifdef HAVE_ASM_TYPES_H
1238 #include <asm/types.h>
1239 #endif])
1241 dnl **** Check for types ****
1243 AC_C_CONST
1244 AC_C_INLINE
1245 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1246 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1247 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1249 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1250 [#ifdef HAVE_LINUX_INPUT_H
1251 #include <linux/input.h>
1252 #endif])
1254 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1255 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1256 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1257 if test "$wine_cv_have_sigaddset" = "yes"
1258 then
1259 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1260 fi
1263 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1264 wine_cv_linux_gethostbyname_r_6,
1265 AC_TRY_LINK([
1266 #include <netdb.h>
1267 ], [
1268 char *name=NULL;
1269 struct hostent he;
1270 struct hostent *result;
1271 char *buf=NULL;
1272 int bufsize=0;
1273 int res,errnr;
1274 char *addr=NULL;
1275 int addrlen=0;
1276 int addrtype=0;
1277 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1278 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1279 ],
1280 wine_cv_linux_gethostbyname_r_6=yes,
1281 wine_cv_linux_gethostbyname_r_6=no
1282 )
1283 )
1284 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1285 then
1286 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1287 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1288 fi
1290 if test "$ac_cv_header_linux_joystick_h" = "yes"
1291 then
1292 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1293 wine_cv_linux_joystick_22_api,
1294 AC_TRY_COMPILE([
1295 #include <sys/ioctl.h>
1296 #include <linux/joystick.h>
1298 struct js_event blub;
1299 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1300 #error "no 2.2 header"
1301 #endif
1302 ],/*empty*/,
1303 wine_cv_linux_joystick_22_api=yes,
1304 wine_cv_linux_joystick_22_api=no,
1305 wine_cv_linux_joystick_22_api=no
1306 )
1307 )
1308 if test "$wine_cv_linux_joystick_22_api" = "yes"
1309 then
1310 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1311 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1312 fi
1313 fi
1315 dnl **** statfs checks ****
1317 if test "$ac_cv_header_sys_vfs_h" = "yes"
1318 then
1319 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1320 wine_cv_sys_vfs_has_statfs,
1321 AC_TRY_COMPILE([
1322 #include <sys/types.h>
1323 #ifdef HAVE_SYS_PARAM_H
1324 # include <sys/param.h>
1325 #endif
1326 #include <sys/vfs.h>
1327 ],[
1328 struct statfs stfs;
1330 memset(&stfs,0,sizeof(stfs));
1331 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1332 )
1333 )
1334 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1335 then
1336 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1337 [Define if the struct statfs is defined by <sys/vfs.h>])
1338 fi
1339 fi
1341 if test "$ac_cv_header_sys_statfs_h" = "yes"
1342 then
1343 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1344 wine_cv_sys_statfs_has_statfs,
1345 AC_TRY_COMPILE([
1346 #include <sys/types.h>
1347 #ifdef HAVE_SYS_PARAM_H
1348 # include <sys/param.h>
1349 #endif
1350 #include <sys/statfs.h>
1351 ],[
1352 struct statfs stfs;
1353 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1354 )
1355 )
1356 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1357 then
1358 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1359 [Define if the struct statfs is defined by <sys/statfs.h>])
1360 fi
1361 fi
1363 if test "$ac_cv_header_sys_mount_h" = "yes"
1364 then
1365 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1366 wine_cv_sys_mount_has_statfs,
1367 AC_TRY_COMPILE([
1368 #include <sys/types.h>
1369 #ifdef HAVE_SYS_PARAM_H
1370 # include <sys/param.h>
1371 #endif
1372 #include <sys/mount.h>
1373 ],[
1374 struct statfs stfs;
1375 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1376 )
1377 )
1378 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1379 then
1380 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1381 [Define if the struct statfs is defined by <sys/mount.h>])
1382 fi
1383 fi
1385 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1387 dnl Check for statfs members
1388 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1389 [#include <sys/types.h>
1390 #ifdef HAVE_SYS_PARAM_H
1391 # include <sys/param.h>
1392 #endif
1393 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1394 # include <sys/mount.h>
1395 #else
1396 # ifdef STATFS_DEFINED_BY_SYS_VFS
1397 # include <sys/vfs.h>
1398 # else
1399 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1400 # include <sys/statfs.h>
1401 # endif
1402 # endif
1403 #endif])
1405 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1406 [#ifdef HAVE_SYS_STATVFS_H
1407 #include <sys/statvfs.h>
1408 #endif])
1410 dnl Check for socket structure members
1411 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1412 [#include <sys/types.h>
1413 #ifdef HAVE_SYS_SOCKET_H
1414 # include <sys/socket.h>
1415 #endif
1416 #ifdef HAVE_SYS_UN_H
1417 # include <sys/un.h>
1418 #endif])
1420 dnl Check for scsireq_t and sg_io_hdr_t members
1421 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1422 [#include <sys/types.h>
1423 #ifdef HAVE_SCSI_SG_H
1424 #include <scsi/sg.h>
1425 #endif])
1427 dnl Check for siginfo_t members
1428 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1430 dnl Check for struct mtget members
1431 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1432 [#ifdef HAVE_SYS_MTIO_H
1433 #include <sys/mtio.h>
1434 #endif])
1436 dnl Check for struct option
1437 AC_CHECK_MEMBERS([struct option.name],,,
1438 [#ifdef HAVE_GETOPT_H
1439 #include <getopt.h>
1440 #endif])
1442 dnl Check for stat.st_blocks
1443 AC_CHECK_MEMBERS([struct stat.st_blocks])
1445 dnl Check for the external timezone variables timezone and daylight
1446 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1447 AC_TRY_LINK([#include <time.h>],[timezone;],
1448 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1449 if test "$ac_cv_have_timezone" = "yes"
1450 then
1451 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1452 fi
1453 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1454 AC_TRY_LINK([#include <time.h>],[daylight;],
1455 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1456 if test "$ac_cv_have_daylight" = "yes"
1457 then
1458 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1459 fi
1461 dnl *** check for the need to define platform-specific symbols
1463 case $host_cpu in
1464 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1465 *x86_64*) WINE_CHECK_DEFINE([__x86_64__]) ;;
1466 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1467 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1468 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1469 esac
1471 case $host_vendor in
1472 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1473 esac
1475 dnl **** Generate output files ****
1477 AH_TOP([#define __WINE_CONFIG_H])
1479 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1480 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1481 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1482 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1483 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1484 WINE_CONFIG_EXTRA_DIR(include/wine)
1486 MAKE_RULES=Make.rules
1487 AC_SUBST_FILE(MAKE_RULES)
1489 MAKE_DLL_RULES=dlls/Makedll.rules
1490 AC_SUBST_FILE(MAKE_DLL_RULES)
1492 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1493 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1495 MAKE_TEST_RULES=dlls/Maketest.rules
1496 AC_SUBST_FILE(MAKE_TEST_RULES)
1498 MAKE_LIB_RULES=libs/Makelib.rules
1499 AC_SUBST_FILE(MAKE_LIB_RULES)
1501 MAKE_PROG_RULES=programs/Makeprog.rules
1502 AC_SUBST_FILE(MAKE_PROG_RULES)
1504 AC_CONFIG_FILES([
1505 Make.rules
1506 dlls/Makedll.rules
1507 dlls/Makeimplib.rules
1508 dlls/Maketest.rules
1509 libs/Makelib.rules
1510 programs/Makeprog.rules
1511 Makefile
1512 dlls/Makefile
1513 dlls/activeds/Makefile
1514 dlls/advapi32/Makefile
1515 dlls/advapi32/tests/Makefile
1516 dlls/advpack/Makefile
1517 dlls/advpack/tests/Makefile
1518 dlls/amstream/Makefile
1519 dlls/atl/Makefile
1520 dlls/avicap32/Makefile
1521 dlls/avifil32/Makefile
1522 dlls/cabinet/Makefile
1523 dlls/cabinet/tests/Makefile
1524 dlls/capi2032/Makefile
1525 dlls/cards/Makefile
1526 dlls/cfgmgr32/Makefile
1527 dlls/comcat/Makefile
1528 dlls/comctl32/Makefile
1529 dlls/comctl32/tests/Makefile
1530 dlls/commdlg/Makefile
1531 dlls/crtdll/Makefile
1532 dlls/crypt32/Makefile
1533 dlls/crypt32/tests/Makefile
1534 dlls/cryptdll/Makefile
1535 dlls/ctl3d/Makefile
1536 dlls/d3d8/Makefile
1537 dlls/d3d9/Makefile
1538 dlls/d3d9/tests/Makefile
1539 dlls/d3dim/Makefile
1540 dlls/d3drm/Makefile
1541 dlls/d3dx8/Makefile
1542 dlls/d3dxof/Makefile
1543 dlls/dbghelp/Makefile
1544 dlls/dciman32/Makefile
1545 dlls/ddraw/Makefile
1546 dlls/ddraw/tests/Makefile
1547 dlls/devenum/Makefile
1548 dlls/dinput/Makefile
1549 dlls/dinput/tests/Makefile
1550 dlls/dinput8/Makefile
1551 dlls/dmband/Makefile
1552 dlls/dmcompos/Makefile
1553 dlls/dmime/Makefile
1554 dlls/dmloader/Makefile
1555 dlls/dmscript/Makefile
1556 dlls/dmstyle/Makefile
1557 dlls/dmsynth/Makefile
1558 dlls/dmusic/Makefile
1559 dlls/dmusic32/Makefile
1560 dlls/dplay/Makefile
1561 dlls/dplayx/Makefile
1562 dlls/dpnet/Makefile
1563 dlls/dpnhpast/Makefile
1564 dlls/dsound/Makefile
1565 dlls/dsound/tests/Makefile
1566 dlls/dswave/Makefile
1567 dlls/dxdiagn/Makefile
1568 dlls/dxerr8/Makefile
1569 dlls/dxerr9/Makefile
1570 dlls/dxguid/Makefile
1571 dlls/gdi/Makefile
1572 dlls/gdi/tests/Makefile
1573 dlls/glu32/Makefile
1574 dlls/glut32/Makefile
1575 dlls/hhctrl.ocx/Makefile
1576 dlls/iccvid/Makefile
1577 dlls/icmp/Makefile
1578 dlls/ifsmgr.vxd/Makefile
1579 dlls/imagehlp/Makefile
1580 dlls/imm32/Makefile
1581 dlls/iphlpapi/Makefile
1582 dlls/iphlpapi/tests/Makefile
1583 dlls/itss/Makefile
1584 dlls/kernel/Makefile
1585 dlls/kernel/tests/Makefile
1586 dlls/lzexpand/Makefile
1587 dlls/lzexpand/tests/Makefile
1588 dlls/mapi32/Makefile
1589 dlls/mapi32/tests/Makefile
1590 dlls/mciavi32/Makefile
1591 dlls/mcicda/Makefile
1592 dlls/mciseq/Makefile
1593 dlls/midimap/Makefile
1594 dlls/mlang/Makefile
1595 dlls/mlang/tests/Makefile
1596 dlls/mmdevldr.vxd/Makefile
1597 dlls/monodebg.vxd/Makefile
1598 dlls/mpr/Makefile
1599 dlls/msacm/Makefile
1600 dlls/msacm/imaadp32/Makefile
1601 dlls/msacm/msadp32/Makefile
1602 dlls/msacm/msg711/Makefile
1603 dlls/msacm/tests/Makefile
1604 dlls/msacm/winemp3/Makefile
1605 dlls/mscms/Makefile
1606 dlls/mscms/tests/Makefile
1607 dlls/msdmo/Makefile
1608 dlls/mshtml/Makefile
1609 dlls/mshtml/tests/Makefile
1610 dlls/msi/Makefile
1611 dlls/msi/tests/Makefile
1612 dlls/msimg32/Makefile
1613 dlls/msisys/Makefile
1614 dlls/msnet32/Makefile
1615 dlls/msrle32/Makefile
1616 dlls/msvcrt/Makefile
1617 dlls/msvcrt/tests/Makefile
1618 dlls/msvcrt20/Makefile
1619 dlls/msvcrt40/Makefile
1620 dlls/msvcrtd/Makefile
1621 dlls/msvcrtd/tests/Makefile
1622 dlls/msvidc32/Makefile
1623 dlls/msvideo/Makefile
1624 dlls/mswsock/Makefile
1625 dlls/msxml3/Makefile
1626 dlls/msxml3/tests/Makefile
1627 dlls/netapi32/Makefile
1628 dlls/netapi32/tests/Makefile
1629 dlls/newdev/Makefile
1630 dlls/ntdll/Makefile
1631 dlls/ntdll/tests/Makefile
1632 dlls/objsel/Makefile
1633 dlls/odbc32/Makefile
1634 dlls/odbccp32/Makefile
1635 dlls/ole32/Makefile
1636 dlls/ole32/tests/Makefile
1637 dlls/oleacc/Makefile
1638 dlls/oleaut32/Makefile
1639 dlls/oleaut32/tests/Makefile
1640 dlls/olecli/Makefile
1641 dlls/oledlg/Makefile
1642 dlls/olepro32/Makefile
1643 dlls/olesvr/Makefile
1644 dlls/opengl32/Makefile
1645 dlls/powrprof/Makefile
1646 dlls/psapi/Makefile
1647 dlls/psapi/tests/Makefile
1648 dlls/qcap/Makefile
1649 dlls/quartz/Makefile
1650 dlls/quartz/tests/Makefile
1651 dlls/rasapi32/Makefile
1652 dlls/riched20/Makefile
1653 dlls/richedit/Makefile
1654 dlls/rpcrt4/Makefile
1655 dlls/rpcrt4/tests/Makefile
1656 dlls/rsabase/Makefile
1657 dlls/rsabase/tests/Makefile
1658 dlls/rsaenh/Makefile
1659 dlls/rsaenh/tests/Makefile
1660 dlls/secur32/Makefile
1661 dlls/secur32/tests/Makefile
1662 dlls/security/Makefile
1663 dlls/sensapi/Makefile
1664 dlls/serialui/Makefile
1665 dlls/setupapi/Makefile
1666 dlls/setupapi/tests/Makefile
1667 dlls/shdocvw/Makefile
1668 dlls/shdocvw/tests/Makefile
1669 dlls/shell32/Makefile
1670 dlls/shell32/tests/Makefile
1671 dlls/shfolder/Makefile
1672 dlls/shlwapi/Makefile
1673 dlls/shlwapi/tests/Makefile
1674 dlls/snmpapi/Makefile
1675 dlls/stdole2.tlb/Makefile
1676 dlls/stdole32.tlb/Makefile
1677 dlls/sti/Makefile
1678 dlls/strmiids/Makefile
1679 dlls/tapi32/Makefile
1680 dlls/twain/Makefile
1681 dlls/unicows/Makefile
1682 dlls/url/Makefile
1683 dlls/urlmon/Makefile
1684 dlls/urlmon/tests/Makefile
1685 dlls/user/Makefile
1686 dlls/user/tests/Makefile
1687 dlls/usp10/Makefile
1688 dlls/uuid/Makefile
1689 dlls/uxtheme/Makefile
1690 dlls/vdhcp.vxd/Makefile
1691 dlls/vdmdbg/Makefile
1692 dlls/version/Makefile
1693 dlls/version/tests/Makefile
1694 dlls/vmm.vxd/Makefile
1695 dlls/vnbt.vxd/Makefile
1696 dlls/vnetbios.vxd/Makefile
1697 dlls/vtdapi.vxd/Makefile
1698 dlls/vwin32.vxd/Makefile
1699 dlls/win32s/Makefile
1700 dlls/winaspi/Makefile
1701 dlls/winecrt0/Makefile
1702 dlls/wined3d/Makefile
1703 dlls/winedos/Makefile
1704 dlls/wineps/Makefile
1705 dlls/wininet/Makefile
1706 dlls/wininet/tests/Makefile
1707 dlls/winmm/Makefile
1708 dlls/winmm/joystick/Makefile
1709 dlls/winmm/mciwave/Makefile
1710 dlls/winmm/tests/Makefile
1711 dlls/winmm/wavemap/Makefile
1712 dlls/winmm/winealsa/Makefile
1713 dlls/winmm/winearts/Makefile
1714 dlls/winmm/wineaudioio/Makefile
1715 dlls/winmm/wineesd/Makefile
1716 dlls/winmm/winejack/Makefile
1717 dlls/winmm/winenas/Makefile
1718 dlls/winmm/wineoss/Makefile
1719 dlls/winnls/Makefile
1720 dlls/winsock/Makefile
1721 dlls/winsock/tests/Makefile
1722 dlls/winspool/Makefile
1723 dlls/winspool/tests/Makefile
1724 dlls/wintab32/Makefile
1725 dlls/wintrust/Makefile
1726 dlls/wldap32/Makefile
1727 dlls/wow32/Makefile
1728 dlls/wsock32/Makefile
1729 dlls/wtsapi32/Makefile
1730 dlls/x11drv/Makefile
1731 documentation/Makefile
1732 fonts/Makefile
1733 include/Makefile
1734 libs/Makefile
1735 libs/port/Makefile
1736 libs/unicode/Makefile
1737 libs/wine/Makefile
1738 libs/wpp/Makefile
1739 loader/Makefile
1740 programs/Makefile
1741 programs/avitools/Makefile
1742 programs/clock/Makefile
1743 programs/cmdlgtst/Makefile
1744 programs/control/Makefile
1745 programs/eject/Makefile
1746 programs/expand/Makefile
1747 programs/explorer/Makefile
1748 programs/hh/Makefile
1749 programs/msiexec/Makefile
1750 programs/notepad/Makefile
1751 programs/progman/Makefile
1752 programs/regedit/Makefile
1753 programs/regsvr32/Makefile
1754 programs/rpcss/Makefile
1755 programs/rundll32/Makefile
1756 programs/start/Makefile
1757 programs/taskmgr/Makefile
1758 programs/uninstaller/Makefile
1759 programs/view/Makefile
1760 programs/wcmd/Makefile
1761 programs/wineboot/Makefile
1762 programs/winebrowser/Makefile
1763 programs/winecfg/Makefile
1764 programs/wineconsole/Makefile
1765 programs/winedbg/Makefile
1766 programs/winefile/Makefile
1767 programs/winemenubuilder/Makefile
1768 programs/winemine/Makefile
1769 programs/winepath/Makefile
1770 programs/winetest/Makefile
1771 programs/winevdm/Makefile
1772 programs/winhelp/Makefile
1773 programs/winver/Makefile
1774 server/Makefile
1775 tools/Makefile
1776 tools/widl/Makefile
1777 tools/winapi/Makefile
1778 tools/winebuild/Makefile
1779 tools/winedump/Makefile
1780 tools/winegcc/Makefile
1781 tools/wmc/Makefile
1782 tools/wrc/Makefile])
1784 AC_OUTPUT
1786 if test "$have_x" = "no"
1787 then
1788 echo
1789 echo "*** Warning: X development files not found. Wine will be built without"
1790 echo "*** X support, which currently does not work, and would probably not be"
1791 echo "*** what you want anyway. You will need to install devel packages of"
1792 echo "*** Xlib/Xfree86 at the very least."
1793 fi
1795 if test "$wine_cv_opengl_version_OK" = "no"
1796 then
1797 echo
1798 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1799 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1800 fi
1802 if test "$wine_cv_msg_freetype" = "yes"
1803 then
1804 echo
1805 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1806 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1807 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1808 echo "*** enable Wine to use TrueType fonts."
1809 fi
1811 if test -z "$ALSALIBS" -a \
1812 -z "$ARTSC_LIBS" -a \
1813 -z "$AUDIOIOLIBS" -a \
1814 -z "$NASLIBS" -a \
1815 -z "$ESD_LIBS" -a \
1816 -z "$ac_cv_lib_soname_jack" -a \
1817 "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1818 "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1819 "$ac_cv_header_soundcard_h" != "yes"
1820 then
1821 echo "*** No sound system was found. Windows applications will be silent."
1822 echo "*** The currently supported sound systems are:"
1823 echo "*** ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS"
1824 fi
1826 echo
1827 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1828 echo
1830 dnl Local Variables:
1831 dnl comment-start: "dnl "
1832 dnl comment-end: ""
1833 dnl comment-start-skip: "\\bdnl\\b\\s *"
1834 dnl compile-command: "autoconf"
1835 dnl End: