tools/wrc/parser.l

   1 /* -*-C-*-
   2  *
   3  * Copyright 1998-2000  Bertho A. Stultiens (BS)
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9  *
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18  *
  19  * History:
  20  * 21-May-2000 BS       - Fixed the ident requirement of resource names
  21  *                        which can be keywords.
  22  * 30-Apr-2000 BS       - Reintegration into the wine-tree
  23  * 11-Jan-2000 BS       - Very drastic cleanup because we don't have a
  24  *                        preprocessor in here anymore.
  25  * 02-Jan-2000 BS       - Removed the preprocessor code
  26  * 23-Dec-1999 BS       - Removed the copyright for Martin von Loewis.
  27  *                        There is really nothing left of his code in
  28  *                        this parser.
  29  * 20-Jun-1998 BS       - Changed the filename conversion. Filenames are
  30  *                        case-sensitive inder *nix, but not under dos.
  31  *                        default behaviour is to convert to lower case.
  32  *                      - All backslashes are converted to forward and
  33  *                        both single and double slash is recognized as
  34  *                        MS/Borland does.
  35  *                      - Fixed a bug in 'yywf' case that prevented
  36  *                        double quoted names to be scanned propperly.
  37  *
  38  * 19-May-1998 BS       - Started to build a preprocessor.
  39  *                      - Changed keyword processing completely to
  40  *                        table-lookups.
  41  *
  42  * 20-Apr-1998 BS       - Added ';' comment stripping
  43  *
  44  * 17-Apr-1998 BS       - Made the win32 keywords optional when compiling in
  45  *                        16bit mode
  46  *
  47  * 15-Apr-1998 BS       - Changed string handling to include escapes
  48  *                      - Added unicode string handling (no codepage
  49  *                        translation though).
  50  *                      - 'Borrowed' the main idea of string scanning from
  51  *                        the flex manual pages.
  52  *                      - Added conditional handling of scanning depending
  53  *                        on the state of the parser. This was mainly required
  54  *                        to distinguish a file to load or raw data that
  55  *                        follows. MS's definition of filenames is rather
  56  *                        complex... It can be unquoted or double quoted. If
  57  *                        double quoted, then the '\\' char is not automatically
  58  *                        escaped according to Borland's rc compiler, but it
  59  *                        accepts both "\\path\\file.rc" and "\path\file.rc".
  60  *                        This makes life very hard! I go for the escaped
  61  *                        version, as this seems to be the documented way...
  62  *                      - Single quoted strings are now parsed and converted
  63  *                        here.
  64  *                      - Added comment stripping. The implementation is
  65  *                        'borrowed' from the flex manpages.
  66  *                      - Rebuild string processing so that it may contain
  67  *                        escaped '\0'.
  68  */
  69
  70 /* Exclusive string handling */
  71 %x yystr
  72 /* Exclusive unicode string handling */
  73 %x yylstr
  74 /* Exclusive rcdata single quoted data handling */
  75 %x yyrcd
  76 /* Exclusive comment eating... */
  77 %x comment
  78 /* Set when stripping c-junk */
  79 %x pp_stripe
  80 %x pp_strips
  81 %x pp_stripp
  82 %x pp_stripp_final
  83 /* Set when scanning #line style directives */
  84 %x pp_line
  85 /* Set when scanning #pragma */
  86 %x pp_pragma
  87 %x pp_code_page
  88
  89 %option stack
  90 %option never-interactive
  91
  92 /* Some shortcut definitions */
  93 ws      [ \f\t\r]
  94 cident  [a-zA-Z_][0-9a-zA-Z_]*
  95
  96 %{
  97
  98 /*#define LEX_DEBUG*/
  99
 100 #include <stdio.h>
 101 #include <stdlib.h>
 102 #include <string.h>
 103 #include <ctype.h>
 104 #include <assert.h>
 105
 106 #include "wine/unicode.h"
 107 #include "wrc.h"
 108 #include "utils.h"
 109 #include "parser.h"
 110 #include "newstruc.h"
 111
 112 #include "y.tab.h"
 113
 114 #define YY_USE_PROTOS
 115 #define YY_NO_UNPUT
 116 #define YY_NO_TOP_STATE
 117
 118 /* Always update the current character position within a line */
 119 #define YY_USER_ACTION  char_number+=yyleng; wanted_id = want_id; want_id = 0;
 120
 121 static void addcchar(char c);
 122 static void addwchar(WCHAR s);
 123 static string_t *get_buffered_cstring(void);
 124 static string_t *get_buffered_wstring(void);
 125 static string_t *make_string(char *s);
 126
 127 static char *cbuffer;           /* Buffers for string collection */
 128 static int cbufidx;
 129 static int cbufalloc = 0;
 130 static WCHAR *wbuffer;
 131 static int wbufidx;
 132 static int wbufalloc = 0;
 133 static int stripslevel = 0;     /* Count {} during pp_strips/pp_stripe mode */
 134 static int stripplevel = 0;     /* Count () during pp_strips mode */
 135 static int cjunk_tagline;       /* Where did we start stripping (helps error tracking) */
 136
 137 static int current_codepage = -1;  /* use language default */
 138
 139 /*
 140  * This one is a bit tricky.
 141  * We set 'want_id' in the parser to get the first
 142  * identifier we get across in the scanner, but we
 143  * also want it to be reset at nearly any token we
 144  * see. Exceptions are:
 145  * - newlines
 146  * - comments
 147  * - whitespace
 148  *
 149  * The scanner will automatically reset 'want_id'
 150  * after *each* scanner reduction and puts is value
 151  * into the var below. In this way we can see the
 152  * state after the YY_RULE_SETUP (i.e. the user action;
 153  * see above) and don't have to worry too much when
 154  * it needs to be reset.
 155  */
 156 static int wanted_id = 0;
 157 static int save_wanted_id;      /* To save across comment reductions */
 158
 159 struct keyword {
 160         const char      *keyword;
 161         int             token;
 162         int             isextension;
 163         int             needcase;
 164         int             alwayskw;
 165 };
 166
 167 static struct keyword keywords[] = {
 168         { "ACCELERATORS",       tACCELERATORS,          0, 0, 0},
 169         { "ALT",                tALT,                   0, 0, 0},
 170         { "ASCII",              tASCII,                 0, 0, 0},
 171         { "AUTO3STATE",         tAUTO3STATE,            1, 0, 0},
 172         { "AUTOCHECKBOX",       tAUTOCHECKBOX,          1, 0, 0},
 173         { "AUTORADIOBUTTON",    tAUTORADIOBUTTON,       1, 0, 0},
 174         { "BEGIN",              tBEGIN,                 0, 0, 0},
 175         { "BITMAP",             tBITMAP,                0, 0, 0},
 176         { "BLOCK",              tBLOCK,                 0, 0, 0},
 177         { "BUTTON",             tBUTTON,                1, 0, 0},
 178         { "CAPTION",            tCAPTION,               0, 0, 0},
 179         { "CHARACTERISTICS",    tCHARACTERISTICS,       1, 0, 0},
 180         { "CHECKBOX",           tCHECKBOX,              0, 0, 0},
 181         { "CHECKED",            tCHECKED,               0, 0, 0},
 182         { "CLASS",              tCLASS,                 0, 0, 0},
 183         { "COMBOBOX",           tCOMBOBOX,              0, 0, 0},
 184         { "CONTROL",            tCONTROL,               0, 0, 0},
 185         { "CTEXT",              tCTEXT,                 0, 0, 0},
 186         { "CURSOR",             tCURSOR,                0, 0, 0},
 187         { "DEFPUSHBUTTON",      tDEFPUSHBUTTON,         0, 0, 0},
 188         { "DIALOG",             tDIALOG,                0, 0, 0},
 189         { "DIALOGEX",           tDIALOGEX,              1, 0, 0},
 190         { "DISCARDABLE",        tDISCARDABLE,           0, 0, 0},
 191         { "DLGINIT",            tDLGINIT,               0, 0, 0},
 192         { "EDITTEXT",           tEDITTEXT,              0, 0, 0},
 193         { "END",                tEND,                   0, 0, 0},
 194         { "EXSTYLE",            tEXSTYLE,               0, 0, 0},
 195         { "FILEFLAGS",          tFILEFLAGS,             0, 0, 0},
 196         { "FILEFLAGSMASK",      tFILEFLAGSMASK,         0, 0, 0},
 197         { "FILEOS",             tFILEOS,                0, 0, 0},
 198         { "FILESUBTYPE",        tFILESUBTYPE,           0, 0, 0},
 199         { "FILETYPE",           tFILETYPE,              0, 0, 0},
 200         { "FILEVERSION",        tFILEVERSION,           0, 0, 0},
 201         { "FIXED",              tFIXED,                 0, 0, 0},
 202         { "FONT",               tFONT,                  0, 0, 0},
 203         { "FONTDIR",            tFONTDIR,               0, 0, 0},       /* This is a Borland BRC extension */
 204         { "GRAYED",             tGRAYED,                0, 0, 0},
 205         { "GROUPBOX",           tGROUPBOX,              0, 0, 0},
 206         { "HELP",               tHELP,                  0, 0, 0},
 207         { "HTML",               tHTML,                  0, 0, 0},
 208         { "ICON",               tICON,                  0, 0, 0},
 209         { "IMPURE",             tIMPURE,                0, 0, 0},
 210         { "INACTIVE",           tINACTIVE,              0, 0, 0},
 211         { "LANGUAGE",           tLANGUAGE,              1, 0, 1},
 212         { "LISTBOX",            tLISTBOX,               0, 0, 0},
 213         { "LOADONCALL",         tLOADONCALL,            0, 0, 0},
 214         { "LTEXT",              tLTEXT,                 0, 0, 0},
 215         { "MENU",               tMENU,                  0, 0, 0},
 216         { "MENUBARBREAK",       tMENUBARBREAK,          0, 0, 0},
 217         { "MENUBREAK",          tMENUBREAK,             0, 0, 0},
 218         { "MENUEX",             tMENUEX,                1, 0, 0},
 219         { "MENUITEM",           tMENUITEM,              0, 0, 0},
 220         { "MESSAGETABLE",       tMESSAGETABLE,          1, 0, 0},
 221         { "MOVEABLE",           tMOVEABLE,              0, 0, 0},
 222         { "NOINVERT",           tNOINVERT,              0, 0, 0},
 223         { "NOT",                tNOT,                   0, 0, 0},
 224         { "POPUP",              tPOPUP,                 0, 0, 0},
 225         { "PRELOAD",            tPRELOAD,               0, 0, 0},
 226         { "PRODUCTVERSION",     tPRODUCTVERSION,        0, 0, 0},
 227         { "PURE",               tPURE,                  0, 0, 0},
 228         { "PUSHBUTTON",         tPUSHBUTTON,            0, 0, 0},
 229         { "RADIOBUTTON",        tRADIOBUTTON,           0, 0, 0},
 230         { "RCDATA",             tRCDATA,                0, 0, 0},
 231         { "RTEXT",              tRTEXT,                 0, 0, 0},
 232         { "SCROLLBAR",          tSCROLLBAR,             0, 0, 0},
 233         { "SEPARATOR",          tSEPARATOR,             0, 0, 0},
 234         { "SHIFT",              tSHIFT,                 0, 0, 0},
 235         { "STATE3",             tSTATE3,                1, 0, 0},
 236         { "STRING",             tSTRING,                0, 0, 0},
 237         { "STRINGTABLE",        tSTRINGTABLE,           0, 0, 1},
 238         { "STYLE",              tSTYLE,                 0, 0, 0},
 239         { "TOOLBAR",            tTOOLBAR,               1, 0, 0},
 240         { "VALUE",              tVALUE,                 0, 0, 0},
 241         { "VERSION",            tVERSION,               1, 0, 0},
 242         { "VERSIONINFO",        tVERSIONINFO,           0, 0, 0},
 243         { "VIRTKEY",            tVIRTKEY,               0, 0, 0}
 244 };
 245
 246 #define NKEYWORDS       (sizeof(keywords)/sizeof(keywords[0]))
 247 #define KWP(p)          ((const struct keyword *)(p))
 248 static int kw_cmp_func(const void *s1, const void *s2)
 249 {
 250         int ret;
 251         ret = strcasecmp(KWP(s1)->keyword, KWP(s2)->keyword);
 252         if(!ret && (KWP(s1)->needcase || KWP(s2)->needcase))
 253                 return strcmp(KWP(s1)->keyword, KWP(s2)->keyword);
 254         else
 255                 return ret;
 256 }
 257
 258 #define KW_BSEARCH
 259 #define DO_SORT
 260 static struct keyword *iskeyword(char *kw)
 261 {
 262         struct keyword *kwp;
 263         struct keyword key;
 264         key.keyword = kw;
 265         key.needcase = 0;
 266 #ifdef DO_SORT
 267         {
 268                 /* Make sure that it is sorted for bsearsh */
 269                 static int sorted = 0;
 270                 if(!sorted)
 271                 {
 272                         qsort(keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
 273                         sorted = 1;
 274                 }
 275         }
 276 #endif
 277 #ifdef KW_BSEARCH
 278         kwp = bsearch(&key, keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
 279 #else
 280         {
 281                 int i;
 282                 for(i = 0; i < NKEYWORDS; i++)
 283                 {
 284                         if(!kw_cmp_func(&key, &keywords[i]))
 285                                 break;
 286                 }
 287                 if(i < NKEYWORDS)
 288                         kwp = &keywords[i];
 289                 else
 290                         kwp = NULL;
 291         }
 292 #endif
 293
 294         if(kwp == NULL || (kwp->isextension && !extensions))
 295                 return NULL;
 296         else
 297                 return kwp;
 298 }
 299
 300 %}
 301
 302 /*
 303  **************************************************************************
 304  * The flexer starts here
 305  **************************************************************************
 306  */
 307 %%
 308         /*
 309          * Catch the GCC-style line statements here and parse them.
 310          * This has the advantage that you can #include at any
 311          * stage in the resource file.
 312          * The preprocessor generates line directives in the format:
 313          * # <linenum> "filename" <codes>
 314          *
 315          * Codes can be a sequence of:
 316          * - 1 start of new file
 317          * - 2 returning to previous
 318          * - 3 system header
 319          * - 4 interpret as C-code
 320          *
 321          * 4 is not used and 1 mutually excludes 2
 322          * Anyhow, we are not really interested in these at all
 323          * because we only want to know the linenumber and
 324          * filename.
 325          */
 326 <INITIAL,pp_strips,pp_stripp>^{ws}*\#{ws}*pragma{ws}+   yy_push_state(pp_pragma);
 327 <INITIAL,pp_strips,pp_stripp>^{ws}*\#{ws}*      yy_push_state(pp_line);
 328 <pp_line>[^\n]* {
 329                 int lineno;
 330                 char *cptr;
 331                 char *fname;
 332                 yy_pop_state();
 333                 lineno = (int)strtol(yytext, &cptr, 10);
 334                 if(!lineno)
 335                         yyerror("Malformed '#...' line-directive; invalid linenumber");
 336                 fname = strchr(cptr, '"');
 337                 if(!fname)
 338                         yyerror("Malformed '#...' line-directive; missing filename");
 339                 fname++;
 340                 cptr = strchr(fname, '"');
 341                 if(!cptr)
 342                         yyerror("Malformed '#...' line-directive; missing terminating \"");
 343                 *cptr = '\0';
 344                 line_number = lineno - 1;       /* We didn't read the newline */
 345                 input_name = xstrdup(fname);
 346         }
 347
 348 <pp_pragma>code_page[^\n]*      yyless(9); yy_pop_state(); yy_push_state(pp_code_page);
 349 <pp_pragma>[^\n]*               yy_pop_state(); if (pedantic) yywarning("Unrecognized #pragma directive '%s'",yytext);
 350
 351 <pp_code_page>\({ws}*default{ws}*\)[^\n]*       current_codepage = -1; yy_pop_state();
 352 <pp_code_page>\({ws}*[0-9]+{ws}*\)[^\n]* {
 353         char *p = yytext;
 354         yy_pop_state();
 355         while (*p < '0' || *p > '9') p++;
 356         current_codepage = strtol( p, NULL, 10 );
 357         if (current_codepage && !wine_cp_get_table( current_codepage ))
 358         {
 359             yyerror("Codepage %d not supported", current_codepage);
 360             current_codepage = 0;
 361         }
 362     }
 363 <pp_code_page>[^\n]*    yy_pop_state(); yyerror("Malformed #pragma code_page directive");
 364
 365         /*
 366          * Strip everything until a ';' taking
 367          * into account braces {} for structures,
 368          * classes and enums.
 369          */
 370 <pp_strips>\{                   stripslevel++;
 371 <pp_strips>\}                   stripslevel--;
 372 <pp_strips>;                    if(!stripslevel) yy_pop_state();
 373 <pp_strips>\/[^*\n]             ; /* To catch comments */
 374 <pp_strips>[^\{\};\n#/]*        ; /* Ignore rest */
 375 <pp_strips>\n                   line_number++; char_number = 1;
 376
 377 <pp_stripp>\(                   stripplevel++;
 378 <pp_stripp>\)                   {
 379                                         stripplevel--;
 380                                         if(!stripplevel)
 381                                         {
 382                                                 yy_pop_state();
 383                                                 yy_push_state(pp_stripp_final);
 384                                         }
 385                                 }
 386 <pp_stripp>\/[^*\n]             ; /* To catch comments */
 387 <pp_stripp>[^\(\);\n#/]*        ; /* Ignore rest */
 388 <pp_stripp>\n                   line_number++; char_number = 1;
 389
 390 <pp_stripp_final>{ws}*          ; /* Ignore */
 391 <pp_stripp_final>;              yy_pop_state(); /* Kill the semicolon */
 392 <pp_stripp_final>\n             line_number++; char_number = 1; yy_pop_state();
 393 <pp_stripp_final>.              yyless(0); yy_pop_state();
 394
 395 \{                      return tBEGIN;
 396 \}                      return tEND;
 397
 398 [0-9]+[lL]?             { yylval.num = strtoul(yytext,  0, 10); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 399 0[xX][0-9A-Fa-f]+[lL]?  { yylval.num = strtoul(yytext,  0, 16); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 400 0[oO][0-7]+[lL]?        { yylval.num = strtoul(yytext+2, 0, 8); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 401
 402         /*
 403          * The next two rules scan identifiers and filenames.
 404          * This is achieved by using the priority ruling
 405          * of the scanner where a '.' is valid in a filename
 406          * and *only* in a filename. In this case, the second
 407          * rule will be reduced because it is longer.
 408          */
 409 [A-Za-z_0-9.]+          {
 410                                 struct keyword *tok = iskeyword(yytext);
 411
 412                                 if(tok)
 413                                 {
 414                                         if(wanted_id && !tok->alwayskw)
 415                                         {
 416                                                 yylval.str = make_string(yytext);
 417                                                 return tIDENT;
 418                                         }
 419                                         else
 420                                                 return tok->token;
 421                                 }
 422                                 else
 423                                 {
 424                                         yylval.str = make_string(yytext);
 425                                         return tIDENT;
 426                                 }
 427                         }
 428 [A-Za-z_0-9./\\]+               yylval.str = make_string(yytext); return tFILENAME;
 429
 430         /*
 431          * Wide string scanning
 432          */
 433 L\"                     {
 434                                 yy_push_state(yylstr);
 435                                 wbufidx = 0;
 436                                 if(!win32)
 437                                         yywarning("16bit resource contains unicode strings\n");
 438                         }
 439 <yylstr>\"{ws}+ |
 440 <yylstr>\"              {
 441                                 yy_pop_state();
 442                                 yylval.str = get_buffered_wstring();
 443                                 return tSTRING;
 444                         }
 445 <yylstr>\\[0-7]{1,6}    { /* octal escape sequence */
 446                                 unsigned int result;
 447                                 result = strtoul(yytext+1, 0, 8);
 448                                 if ( result > 0xffff )
 449                                         yyerror("Character constant out of range");
 450                                 addwchar((WCHAR)result);
 451                         }
 452 <yylstr>\\x[0-9a-fA-F]{4} {  /* hex escape sequence */
 453                                 unsigned int result;
 454                                 result = strtoul(yytext+2, 0, 16);
 455                                 addwchar((WCHAR)result);
 456                         }
 457 <yylstr>\\x[0-9a-fA-F]{1,3} {  yyerror("Invalid hex escape sequence '%s'", yytext); }
 458
 459 <yylstr>\\[0-9]+        yyerror("Bad escape sequence");
 460 <yylstr>\\\n{ws}*       line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
 461 <yylstr>\\a             addwchar('\a');
 462 <yylstr>\\b             addwchar('\b');
 463 <yylstr>\\f             addwchar('\f');
 464 <yylstr>\\n             addwchar('\n');
 465 <yylstr>\\r             addwchar('\r');
 466 <yylstr>\\t             addwchar('\t');
 467 <yylstr>\\v             addwchar('\v');
 468 <yylstr>\\.             addwchar(yytext[1]);
 469 <yylstr>\\\r\n          addwchar(yytext[2]); line_number++; char_number = 1;
 470 <yylstr>\"\"            addwchar('\"');         /* "bla""bla"  -> "bla\"bla" */
 471 <yylstr>\\\"\"          addwchar('\"');         /* "bla\""bla" -> "bla\"bla" */
 472 <yylstr>\"{ws}+\"       ;                       /* "bla" "bla" -> "blabla" */
 473 <yylstr>[^\\\n\"]+      {
 474                                 char *yptr = yytext;
 475                                 while(*yptr)    /* FIXME: codepage translation */
 476                                         addwchar(*yptr++ & 0xff);
 477                         }
 478 <yylstr>\n              yyerror("Unterminated string");
 479
 480         /*
 481          * Normal string scanning
 482          */
 483 \"                      yy_push_state(yystr); cbufidx = 0;
 484 <yystr>\"{ws}+  |
 485 <yystr>\"               {
 486                                 yy_pop_state();
 487                                 yylval.str = get_buffered_cstring();
 488                                 return tSTRING;
 489                         }
 490 <yystr>\\[0-7]{1,3}     { /* octal escape sequence */
 491                                 int result;
 492                                 result = strtol(yytext+1, 0, 8);
 493                                 if ( result > 0xff )
 494                                         yyerror("Character constant out of range");
 495                                 addcchar((char)result);
 496                         }
 497 <yystr>\\x[0-9a-fA-F]{2} {  /* hex escape sequence */
 498                                 int result;
 499                                 result = strtol(yytext+2, 0, 16);
 500                                 addcchar((char)result);
 501                         }
 502 <yystr>\\x[0-9a-fA-F]   {  yyerror("Invalid hex escape sequence '%s'", yytext); }
 503
 504 <yystr>\\[0-9]+         yyerror("Bad escape sequence");
 505 <yystr>\\\n{ws}*        line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
 506 <yystr>\\a              addcchar('\a');
 507 <yystr>\\b              addcchar('\b');
 508 <yystr>\\f              addcchar('\f');
 509 <yystr>\\n              addcchar('\n');
 510 <yystr>\\r              addcchar('\r');
 511 <yystr>\\t              addcchar('\t');
 512 <yystr>\\v              addcchar('\v');
 513 <yystr>\\.              addcchar(yytext[1]);
 514 <yystr>\\\r\n           addcchar(yytext[2]); line_number++; char_number = 1;
 515 <yystr>[^\\\n\"]+       {
 516                                 char *yptr = yytext;
 517                                 while(*yptr)
 518                                         addcchar(*yptr++);
 519                         }
 520 <yystr>\"\"             addcchar('\"');         /* "bla""bla"   -> "bla\"bla" */
 521 <yystr>\\\"\"           addcchar('\"');         /* "bla\""bla"  -> "bla\"bla" */
 522 <yystr>\"{ws}+\"        ;                       /* "bla" "bla"  -> "blabla" */
 523 <yystr>\n               yyerror("Unterminated string");
 524
 525         /*
 526          * Raw data scanning
 527          */
 528 \'                      yy_push_state(yyrcd); cbufidx = 0;
 529 <yyrcd>\'               {
 530                                 yy_pop_state();
 531                                 yylval.raw = new_raw_data();
 532                                 yylval.raw->size = cbufidx;
 533                                 yylval.raw->data = xmalloc(yylval.raw->size);
 534                                 memcpy(yylval.raw->data, cbuffer, yylval.raw->size);
 535                                 return tRAWDATA;
 536                         }
 537 <yyrcd>[0-9a-fA-F]{2}   {
 538                                 int result;
 539                                 result = strtol(yytext, 0, 16);
 540                                 addcchar((char)result);
 541                         }
 542 <yyrcd>{ws}+            ;       /* Ignore space */
 543 <yyrcd>\n               line_number++; char_number = 1;
 544 <yyrcd>.                yyerror("Malformed data-line");
 545
 546         /*
 547          * Comment stripping
 548          * Should never occur after preprocessing
 549          */
 550 <INITIAL,pp_stripp,pp_strips>"/*"       {
 551                                 yy_push_state(comment);
 552                                 save_wanted_id = wanted_id;
 553                                 if(!no_preprocess)
 554                                         yywarning("Found comments after preprocessing, please report");
 555                         }
 556 <comment>[^*\n]*        ;
 557 <comment>"*"+[^*/\n]*   ;
 558 <comment>\n             line_number++; char_number = 1;
 559 <comment>"*"+"/"        yy_pop_state(); want_id = save_wanted_id;
 560
 561 ;[^\n]*                 want_id = wanted_id; /* not really comment, but left-over c-junk */
 562 "//"[^\n]*              want_id = wanted_id; if(!no_preprocess) yywarning("Found comments after preprocessing, please report");
 563
 564 \n                      {
 565                                 want_id = wanted_id;
 566                                 line_number++;
 567                                 char_number = 1;
 568                                 if(want_nl)
 569                                 {
 570                                         want_nl = 0;
 571                                         return tNL;
 572                                 }
 573                         }
 574 {ws}+                   want_id = wanted_id;    /* Eat whitespace */
 575
 576 <INITIAL>.              return yytext[0];
 577
 578 <<EOF>>                 {
 579                                 if(YY_START == pp_strips || YY_START == pp_stripe || YY_START == pp_stripp || YY_START == pp_stripp_final)
 580                                         yyerror("Unexpected end of file during c-junk scanning (started at %d)", cjunk_tagline);
 581                                 else
 582                                         yyterminate();
 583                         }
 584
 585 <*>.|\n                 {
 586                                 /* Catch all rule to find any unmatched text */
 587                                 if(*yytext == '\n')
 588                                 {
 589                                         line_number++;
 590                                         char_number = 1;
 591                                 }
 592                                 yywarning("Unmatched text '%c' (0x%02x) YY_START=%d stripslevel=%d",
 593                                         isprint(*yytext & 0xff) ? *yytext : '.', *yytext, YY_START,stripslevel);
 594                         }
 595
 596 %%
 597
 598 #ifndef yywrap
 599 int yywrap(void)
 600 {
 601 #if 0
 602         if(bufferstackidx > 0)
 603         {
 604                 return 0;
 605         }
 606 #endif
 607         return 1;
 608 }
 609 #endif
 610
 611 /* These dup functions copy the enclosed '\0' from
 612  * the resource string.
 613  */
 614 static void addcchar(char c)
 615 {
 616         if(cbufidx >= cbufalloc)
 617         {
 618                 cbufalloc += 1024;
 619                 cbuffer = xrealloc(cbuffer, cbufalloc * sizeof(cbuffer[0]));
 620                 if(cbufalloc > 65536)
 621                         yywarning("Reallocating string buffer larger than 64kB");
 622         }
 623         cbuffer[cbufidx++] = c;
 624 }
 625
 626 static void addwchar(WCHAR s)
 627 {
 628         if(wbufidx >= wbufalloc)
 629         {
 630                 wbufalloc += 1024;
 631                 wbuffer = xrealloc(wbuffer, wbufalloc * sizeof(wbuffer[0]));
 632                 if(wbufalloc > 65536)
 633                         yywarning("Reallocating wide string buffer larger than 64kB");
 634         }
 635         wbuffer[wbufidx++] = s;
 636 }
 637
 638 static string_t *get_buffered_cstring(void)
 639 {
 640     string_t *str = new_string();
 641
 642     str->size = cbufidx;
 643     str->type = str_char;
 644     str->str.cstr = (char *)xmalloc(cbufidx+1);
 645     memcpy(str->str.cstr, cbuffer, cbufidx);
 646     str->str.cstr[cbufidx] = '\0';
 647
 648     if (!current_codepage || current_codepage == -1 || !win32)  /* store as ANSI string */
 649     {
 650         if (!current_codepage) yyerror("Codepage set to Unicode only, cannot use ASCII string here");
 651         return str;
 652     }
 653     else  /* convert to Unicode before storing */
 654     {
 655         string_t *str_w = convert_string( str, str_unicode, current_codepage );
 656         if (!check_unicode_conversion( str, str_w, current_codepage ))
 657             yyerror("String %s does not convert identically to Unicode and back in codepage %d. "
 658                     "Try using a Unicode string instead.", str->str.cstr, current_codepage );
 659         free_string( str );
 660         return str_w;
 661     }
 662 }
 663
 664 static string_t *get_buffered_wstring(void)
 665 {
 666         string_t *str = new_string();
 667         str->size = wbufidx;
 668         str->type = str_unicode;
 669         str->str.wstr = xmalloc((wbufidx+1)*sizeof(WCHAR));
 670         memcpy(str->str.wstr, wbuffer, wbufidx*sizeof(WCHAR));
 671         str->str.wstr[wbufidx] = 0;
 672         return str;
 673 }
 674
 675 static string_t *make_string(char *s)
 676 {
 677         string_t *str = new_string();
 678         str->size = strlen(s);
 679         str->type = str_char;
 680         str->str.cstr = (char *)xmalloc(str->size+1);
 681         memcpy(str->str.cstr, s, str->size+1);
 682         return str;
 683 }