tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of include/wine/server.h.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (
  26     "int"           => "%d",
  27     "short int"     => "%d",
  28     "char"          => "%c",
  29     "unsigned char" => "%02x",
  30     "unsigned short"=> "%04x",
  31     "unsigned int"  => "%08x",
  32     "unsigned long" => "%lx",
  33     "void*"         => "%p",
  34     "time_t"        => "%ld (long)",
  35     "size_t"        => "%lu (unsigned long)",
  36     "data_size_t"   => "%u",
  37     "obj_handle_t"  => "%p",
  38     "atom_t"        => "%04x",
  39     "user_handle_t" => "%p",
  40     "process_id_t"  => "%04x",
  41     "thread_id_t"   => "%04x",
  42     "abs_time_t"    => "&dump_abs_time",
  43     "rectangle_t"   => "&dump_rectangle",
  44     "char_info_t"   => "&dump_char_info",
  45 );
  46
  47 my @requests = ();
  48 my %replies = ();
  49
  50 my @trace_lines = ();
  51
  52
  53
  54 ### Generate a dumping function
  55
  56 sub DO_DUMP_FUNC($$@)
  57 {
  58     my $name = shift;
  59     my $req = shift;
  60     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  61     while ($#_ >= 0)
  62     {
  63         my $type = shift;
  64         my $var = shift;
  65         if (defined($formats{$type}))
  66         {
  67             if ($formats{$type} =~ /^&(.*)/)
  68             {
  69                 my $func = $1;
  70                 push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  71                 push @trace_lines, "    $func( &req->$var );\n";
  72                 push @trace_lines, "    fprintf( stderr, \",\" );\n" if ($#_ > 0);
  73             }
  74             elsif ($formats{$type} =~ /^(%.*)\s+\((.*)\)/)
  75             {
  76                 my ($format, $cast) = ($1, $2);
  77                 push @trace_lines, "    fprintf( stderr, \" $var=$format";
  78                 push @trace_lines, "," if ($#_ > 0);
  79                 push @trace_lines, "\", ($cast)req->$var );\n";
  80             }
  81             else
  82             {
  83                 push @trace_lines, "    fprintf( stderr, \" $var=$formats{$type}";
  84                 push @trace_lines, "," if ($#_ > 0);
  85                 push @trace_lines, "\", req->$var );\n";
  86             }
  87         }
  88         else  # must be some varargs format
  89         {
  90             my $func = $type;
  91             push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  92             push @trace_lines, "    $func;\n";
  93             push @trace_lines, "    fputc( ',', stderr );\n" if ($#_ > 0);
  94         }
  95     }
  96     push @trace_lines, "}\n\n";
  97 }
  98
  99 ### Parse the request definitions
 100
 101 sub PARSE_REQUESTS()
 102 {
 103     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 104     my $state = 0;
 105     my $name = "";
 106     my @in_struct = ();
 107     my @out_struct = ();
 108
 109     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 110
 111     while (<PROTOCOL>)
 112     {
 113         my ($type, $var);
 114         # strip comments
 115         s!/\*.*\*/!!g;
 116         # strip white space at end of line
 117         s/\s+$//;
 118
 119         if (/^\@HEADER/)
 120         {
 121             die "Misplaced \@HEADER" unless $state == 0;
 122             $state++;
 123             next;
 124         }
 125
 126         # ignore everything while in state 0
 127         next if $state == 0;
 128
 129         if (/^\@REQ\(\s*(\w+)\s*\)/)
 130         {
 131             $name = $1;
 132             die "Misplaced \@REQ" unless $state == 1;
 133             # start a new request
 134             @in_struct = ();
 135             @out_struct = ();
 136             print SERVER_PROT "struct ${name}_request\n{\n";
 137             print SERVER_PROT "    struct request_header __header;\n";
 138             $state++;
 139             next;
 140         }
 141
 142         if (/^\@REPLY/)
 143         {
 144             die "Misplaced \@REPLY" unless $state == 2;
 145             print SERVER_PROT "};\n";
 146             print SERVER_PROT "struct ${name}_reply\n{\n";
 147             print SERVER_PROT "    struct reply_header __header;\n";
 148             $state++;
 149             next;
 150         }
 151
 152         if (/^\@END/)
 153         {
 154             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 155             print SERVER_PROT "};\n";
 156
 157             if ($state == 2)  # build dummy reply struct
 158             {
 159                 print SERVER_PROT "struct ${name}_reply\n{\n";
 160                 print SERVER_PROT "    struct reply_header __header;\n";
 161                 print SERVER_PROT "};\n";
 162             }
 163
 164             # got a complete request
 165             push @requests, $name;
 166             DO_DUMP_FUNC( $name, "request", @in_struct);
 167             if ($#out_struct >= 0)
 168             {
 169                 $replies{$name} = 1;
 170                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 171             }
 172             $state = 1;
 173             next;
 174         }
 175
 176         if ($state != 1)
 177         {
 178             # skip empty lines (but keep them in output file)
 179             if (/^$/)
 180             {
 181                 print SERVER_PROT "\n";
 182                 next;
 183             }
 184
 185             if (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 186             {
 187                 $var = $1;
 188                 $type = "dump_varargs_" . $2 . "( min(cur_size,req->" . $3 . ") )";
 189                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 190             }
 191             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 192             {
 193                 $var = $1;
 194                 $type = "dump_varargs_" . $2 . "( cur_size )";
 195                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 196             }
 197             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 198             {
 199                 $type = $1;
 200                 $var = $3;
 201                 die "Unrecognized type $type" unless defined($formats{$type});
 202             }
 203             else
 204             {
 205                 die "Unrecognized syntax $_";
 206             }
 207             if ($state == 2) { push @in_struct, $type, $var; }
 208             if ($state == 3) { push @out_struct, $type, $var; }
 209         }
 210
 211         # Pass it through into the output file
 212         print SERVER_PROT $_ . "\n";
 213     }
 214     close PROTOCOL;
 215 }
 216
 217 ### Retrieve the server protocol version from the existing server_protocol.h file
 218
 219 sub GET_PROTOCOL_VERSION()
 220 {
 221     my $protocol = 0;
 222     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 223     while (<SERVER_PROT>)
 224     {
 225         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 226     }
 227     close SERVER_PROT;
 228     return $protocol;
 229 }
 230
 231 ### Retrieve the list of status and errors used in the server
 232
 233 sub GET_ERROR_NAMES()
 234 {
 235     my %errors = ();
 236     foreach my $f (glob "server/*.c")
 237     {
 238         open FILE, $f or die "Can't open $f";
 239         while (<FILE>)
 240         {
 241             if (/set_error\s*\(\s*STATUS_(\w+)\s*\)/)
 242             {
 243                 $errors{$1} = "STATUS_$1";
 244             }
 245             elsif (/set_win32_error\s*\(\s*(\w+)\s*\)/)
 246             {
 247                 $errors{$1} = "0xc0010000 | $1";
 248             }
 249         }
 250         close FILE;
 251     }
 252     return %errors;
 253 }
 254
 255 ### Replace the contents of a file between ### make_requests ### marks
 256
 257 sub REPLACE_IN_FILE($@)
 258 {
 259     my $name = shift;
 260     my @data = @_;
 261     my @lines = ();
 262     open(FILE,$name) or die "Can't open $name";
 263     while (<FILE>)
 264     {
 265         push @lines, $_;
 266         last if /\#\#\# make_requests begin \#\#\#/;
 267     }
 268     push @lines, "\n", @data;
 269     while (<FILE>)
 270     {
 271         if (/\#\#\# make_requests end \#\#\#/) { push @lines, "\n", $_; last; }
 272     }
 273     push @lines, <FILE>;
 274     open(FILE,">$name") or die "Can't modify $name";
 275     print FILE @lines;
 276     close(FILE);
 277 }
 278
 279 ### Main
 280
 281 # Get the server protocol version
 282 my $protocol = GET_PROTOCOL_VERSION();
 283
 284 my %errors = GET_ERROR_NAMES();
 285
 286 ### Create server_protocol.h and print header
 287
 288 open SERVER_PROT, ">include/wine/server_protocol.h" or die "Cannot create include/wine/server_protocol.h";
 289 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 290 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 291 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 292 print SERVER_PROT " */\n\n";
 293 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 294 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 295
 296 ### Parse requests to find request/reply structure definitions
 297
 298 PARSE_REQUESTS();
 299
 300 ### Build the request list and structures
 301
 302 print SERVER_PROT "\n\nenum request\n{\n";
 303 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 304 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 305
 306 print SERVER_PROT "union generic_request\n{\n";
 307 print SERVER_PROT "    struct request_max_size max_size;\n";
 308 print SERVER_PROT "    struct request_header request_header;\n";
 309 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 310 print SERVER_PROT "};\n";
 311
 312 print SERVER_PROT "union generic_reply\n{\n";
 313 print SERVER_PROT "    struct request_max_size max_size;\n";
 314 print SERVER_PROT "    struct reply_header reply_header;\n";
 315 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 316 print SERVER_PROT "};\n\n";
 317
 318 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol + 1;
 319 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 320 close SERVER_PROT;
 321
 322 ### Output the dumping function tables
 323
 324 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 325 foreach my $req (@requests)
 326 {
 327     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 328 }
 329 push @trace_lines, "};\n\n";
 330
 331 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 332 foreach my $req (@requests)
 333 {
 334     push @trace_lines, "    (dump_func)", $replies{$req} ? "dump_${req}_reply,\n" : "0,\n";
 335 }
 336 push @trace_lines, "};\n\n";
 337
 338 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 339 foreach my $req (@requests)
 340 {
 341     push @trace_lines, "    \"$req\",\n";
 342 }
 343 push @trace_lines, "};\n\n";
 344
 345 push @trace_lines, "static const struct\n{\n";
 346 push @trace_lines, "    const char  *name;\n";
 347 push @trace_lines, "    unsigned int value;\n";
 348 push @trace_lines, "} status_names[] =\n{\n";
 349
 350 foreach my $err (sort keys %errors)
 351 {
 352     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 353 }
 354 push @trace_lines, "    { NULL, 0 }\n";
 355 push @trace_lines, "};\n";
 356
 357 REPLACE_IN_FILE( "server/trace.c", @trace_lines );
 358
 359 ### Output the request handlers list
 360
 361 my @request_lines = ();
 362
 363 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 364 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 365 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 366 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 367 foreach my $req (@requests)
 368 {
 369     push @request_lines, "    (req_handler)req_$req,\n";
 370 }
 371 push @request_lines, "};\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 372
 373 REPLACE_IN_FILE( "server/request.h", @request_lines );