?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
server: Return an error for invalid requests instead of killing the client process.
[wine/multimedia.git] / tools / wrc / parser.y
blob27c378de1292d16b02ccaf8f195501e4bcda5bb1
1 %{
2 /*
3 * Copyright 1994 Martin von Loewis
4 * Copyright 1998-2000 Bertho A. Stultiens (BS)
5 * 1999 Juergen Schmied (JS)
6 *
7 * This library is free software; you can redistribute it and/or
8 * modify it under the terms of the GNU Lesser General Public
9 * License as published by the Free Software Foundation; either
10 * version 2.1 of the License, or (at your option) any later version.
11 *
12 * This library is distributed in the hope that it will be useful,
13 * but WITHOUT ANY WARRANTY; without even the implied warranty of
14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 * Lesser General Public License for more details.
16 *
17 * You should have received a copy of the GNU Lesser General Public
18 * License along with this library; if not, write to the Free Software
19 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
20 *
21 * History:
22 * 24-Jul-2000 BS - Made a fix for broken Berkeley yacc on
23 * non-terminals (see cjunk rule).
24 * 21-May-2000 BS - Partial implementation of font resources.
25 * - Corrected language propagation for binary
26 * resources such as bitmaps, icons, cursors,
27 * userres and rcdata. The language is now
28 * correct in .res files.
29 * - Fixed reading the resource name as ident,
30 * so that it may overlap keywords.
31 * 20-May-2000 BS - Implemented animated cursors and icons
32 * resource types.
33 * 30-Apr-2000 BS - Reintegration into the wine-tree
34 * 14-Jan-2000 BS - Redid the usertype resources so that they
35 * are compatible.
36 * 02-Jan-2000 BS - Removed the preprocessor from the grammar
37 * except for the # command (line numbers).
38 *
39 * 06-Nov-1999 JS - see CHANGES
40 *
41 * 29-Dec-1998 AdH - Grammar and function extensions.
42 * grammar: TOOLBAR resources, Named ICONs in
43 * DIALOGS
44 * functions: semantic actions for the grammar
45 * changes, resource files can now be anywhere
46 * on the include path instead of just in the
47 * current directory
48 *
49 * 20-Jun-1998 BS - Fixed a bug in load_file() where the name was not
50 * printed out correctly.
51 *
52 * 17-Jun-1998 BS - Fixed a bug in CLASS statement parsing which should
53 * also accept a tSTRING as argument.
54 *
55 * 25-May-1998 BS - Found out that I need to support language, version
56 * and characteristics in inline resources (bitmap,
57 * cursor, etc) but they can also be specified with
58 * a filename. This renders my filename-scanning scheme
59 * worthless. Need to build newline parsing to solve
60 * this one.
61 * It will come with version 1.1.0 (sigh).
62 *
63 * 19-May-1998 BS - Started to build a builtin preprocessor
64 *
65 * 30-Apr-1998 BS - Redid the stringtable parsing/handling. My previous
66 * ideas had some serious flaws.
67 *
68 * 27-Apr-1998 BS - Removed a lot of dead comments and put it in a doc
69 * file.
70 *
71 * 21-Apr-1998 BS - Added correct behavior for cursors and icons.
72 * - This file is growing too big. It is time to strip
73 * things and put it in a support file.
74 *
75 * 19-Apr-1998 BS - Tagged the stringtable resource so that only one
76 * resource will be created. This because the table
77 * has a different layout than other resources. The
78 * table has to be sorted, and divided into smaller
79 * resource entries (see comment in source).
80 *
81 * 17-Apr-1998 BS - Almost all strings, including identifiers, are parsed
82 * as string_t which include unicode strings upon
83 * input.
84 * - Parser now emits a warning when compiling win32
85 * extensions in win16 mode.
86 *
87 * 16-Apr-1998 BS - Raw data elements are now *optionally* separated
88 * by commas. Read the comments in file sq2dq.l.
89 * - FIXME: there are instances in the source that rely
90 * on the fact that int==32bit and pointers are int size.
91 * - Fixed the conflict in menuex by changing a rule
92 * back into right recursion. See note in source.
93 * - UserType resources cannot have an expression as its
94 * typeclass. See note in source.
95 *
96 * 15-Apr-1998 BS - Changed all right recursion into left recursion to
97 * get reduction of the parsestack.
98 * This also helps communication between bison and flex.
99 * Main advantage is that the Empty rule gets reduced
100 * first, which is used to allocate/link things.
101 * It also added a shift/reduce conflict in the menuex
102 * handling, due to expression/option possibility,
103 * although not serious.
104 *
105 * 14-Apr-1998 BS - Redone almost the entire parser. We're not talking
106 * about making it more efficient, but readable (for me)
107 * and slightly easier to expand/change.
108 * This is done primarily by using more reduce states
109 * with many (intuitive) types for the various resource
110 * statements.
111 * - Added expression handling for all resources where a
112 * number is accepted (not only for win32). Also added
113 * multiply and division (not MS compatible, but handy).
114 * Unary minus introduced a shift/reduce conflict, but
115 * it is not serious.
116 *
117 * 13-Apr-1998 BS - Reordered a lot of things
118 * - Made the source more readable
119 * - Added Win32 resource definitions
120 * - Corrected syntax problems with an old yacc (;)
121 * - Added extra comment about grammar
122 */
123 #include "config.h"
124 #include "wine/port.h"
125
126 #include <stdio.h>
127 #include <stdlib.h>
128 #include <stdarg.h>
129 #include <assert.h>
130 #include <ctype.h>
131 #include <string.h>
132 #ifdef HAVE_ALLOCA_H
133 #include <alloca.h>
134 #endif
135
136 #include "wrc.h"
137 #include "utils.h"
138 #include "newstruc.h"
139 #include "dumpres.h"
140 #include "wine/wpp.h"
141 #include "wine/unicode.h"
142 #include "parser.h"
143 #include "windef.h"
144 #include "winbase.h"
145 #include "wingdi.h"
146 #include "winuser.h"
147
148 #if defined(YYBYACC)
149 /* Berkeley yacc (byacc) doesn't seem to know about these */
150 /* Some *BSD supplied versions do define these though */
151 # ifndef YYEMPTY
152 # define YYEMPTY (-1) /* Empty lookahead value of yychar */
153 # endif
154 # ifndef YYLEX
155 # define YYLEX yylex()
156 # endif
157
158 #elif defined(YYBISON)
159 /* Bison was used for original development */
160 /* #define YYEMPTY -2 */
161 /* #define YYLEX yylex() */
162
163 #else
164 /* No yacc we know yet */
165 # if !defined(YYEMPTY) || !defined(YYLEX)
166 # error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
167 # elif defined(__GNUC__) /* gcc defines the #warning directive */
168 # warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
169 /* #else we just take a chance that it works... */
170 # endif
171 #endif
172
173 int want_nl = 0; /* Signal flex that we need the next newline */
174 int want_id = 0; /* Signal flex that we need the next identifier */
175 stringtable_t *tagstt; /* Stringtable tag.
176 * It is set while parsing a stringtable to one of
177 * the stringtables in the sttres list or a new one
178 * if the language was not parsed before.
179 */
180 stringtable_t *sttres; /* Stringtable resources. This holds the list of
181 * stringtables with different lanuages
182 */
183 static int dont_want_id = 0; /* See language parsing for details */
184
185 /* Set to the current options of the currently scanning stringtable */
186 static int *tagstt_memopt;
187 static characts_t *tagstt_characts;
188 static version_t *tagstt_version;
189
190 static const char riff[4] = "RIFF"; /* RIFF file magic for animated cursor/icon */
191
192 /* Prototypes of here defined functions */
193 static event_t *get_event_head(event_t *p);
194 static control_t *get_control_head(control_t *p);
195 static ver_value_t *get_ver_value_head(ver_value_t *p);
196 static ver_block_t *get_ver_block_head(ver_block_t *p);
197 static resource_t *get_resource_head(resource_t *p);
198 static menuex_item_t *get_itemex_head(menuex_item_t *p);
199 static menu_item_t *get_item_head(menu_item_t *p);
200 static raw_data_t *merge_raw_data_str(raw_data_t *r1, string_t *str);
201 static raw_data_t *merge_raw_data_int(raw_data_t *r1, int i);
202 static raw_data_t *merge_raw_data_long(raw_data_t *r1, int i);
203 static raw_data_t *merge_raw_data(raw_data_t *r1, raw_data_t *r2);
204 static raw_data_t *str2raw_data(string_t *str);
205 static raw_data_t *int2raw_data(int i);
206 static raw_data_t *long2raw_data(int i);
207 static raw_data_t *load_file(string_t *name, language_t *lang);
208 static itemex_opt_t *new_itemex_opt(int id, int type, int state, int helpid);
209 static event_t *add_string_event(string_t *key, int id, int flags, event_t *prev);
210 static event_t *add_event(int key, int id, int flags, event_t *prev);
211 static dialogex_t *dialogex_version(version_t *v, dialogex_t *dlg);
212 static dialogex_t *dialogex_characteristics(characts_t *c, dialogex_t *dlg);
213 static dialogex_t *dialogex_language(language_t *l, dialogex_t *dlg);
214 static dialogex_t *dialogex_menu(name_id_t *m, dialogex_t *dlg);
215 static dialogex_t *dialogex_class(name_id_t *n, dialogex_t *dlg);
216 static dialogex_t *dialogex_font(font_id_t *f, dialogex_t *dlg);
217 static dialogex_t *dialogex_caption(string_t *s, dialogex_t *dlg);
218 static dialogex_t *dialogex_exstyle(style_t *st, dialogex_t *dlg);
219 static dialogex_t *dialogex_style(style_t *st, dialogex_t *dlg);
220 static name_id_t *convert_ctlclass(name_id_t *cls);
221 static control_t *ins_ctrl(int type, int special_style, control_t *ctrl, control_t *prev);
222 static dialog_t *dialog_version(version_t *v, dialog_t *dlg);
223 static dialog_t *dialog_characteristics(characts_t *c, dialog_t *dlg);
224 static dialog_t *dialog_language(language_t *l, dialog_t *dlg);
225 static dialog_t *dialog_menu(name_id_t *m, dialog_t *dlg);
226 static dialog_t *dialog_class(name_id_t *n, dialog_t *dlg);
227 static dialog_t *dialog_font(font_id_t *f, dialog_t *dlg);
228 static dialog_t *dialog_caption(string_t *s, dialog_t *dlg);
229 static dialog_t *dialog_exstyle(style_t * st, dialog_t *dlg);
230 static dialog_t *dialog_style(style_t * st, dialog_t *dlg);
231 static resource_t *build_stt_resources(stringtable_t *stthead);
232 static stringtable_t *find_stringtable(lvc_t *lvc);
233 static toolbar_item_t *ins_tlbr_button(toolbar_item_t *prev, toolbar_item_t *idrec);
234 static toolbar_item_t *get_tlbr_buttons_head(toolbar_item_t *p, int *nitems);
235 static string_t *make_filename(string_t *s);
236 static resource_t *build_fontdirs(resource_t *tail);
237 static resource_t *build_fontdir(resource_t **fnt, int nfnt);
238 static int rsrcid_to_token(int lookahead);
239
240 %}
241 %union{
242 string_t *str;
243 int num;
244 int *iptr;
245 char *cptr;
246 resource_t *res;
247 accelerator_t *acc;
248 bitmap_t *bmp;
249 dialog_t *dlg;
250 dialogex_t *dlgex;
251 font_t *fnt;
252 fontdir_t *fnd;
253 menu_t *men;
254 menuex_t *menex;
255 html_t *html;
256 rcdata_t *rdt;
257 stringtable_t *stt;
258 stt_entry_t *stte;
259 user_t *usr;
260 messagetable_t *msg;
261 versioninfo_t *veri;
262 control_t *ctl;
263 name_id_t *nid;
264 font_id_t *fntid;
265 language_t *lan;
266 version_t *ver;
267 characts_t *chars;
268 event_t *event;
269 menu_item_t *menitm;
270 menuex_item_t *menexitm;
271 itemex_opt_t *exopt;
272 raw_data_t *raw;
273 lvc_t *lvc;
274 ver_value_t *val;
275 ver_block_t *blk;
276 ver_words_t *verw;
277 toolbar_t *tlbar;
278 toolbar_item_t *tlbarItems;
279 dlginit_t *dginit;
280 style_pair_t *styles;
281 style_t *style;
282 ani_any_t *ani;
283 }
284
285 %token tNL
286 %token <num> tNUMBER tLNUMBER
287 %token <str> tSTRING tIDENT tFILENAME
288 %token <raw> tRAWDATA
289 %token tACCELERATORS tBITMAP tCURSOR tDIALOG tDIALOGEX tMENU tMENUEX tMESSAGETABLE
290 %token tRCDATA tVERSIONINFO tSTRINGTABLE tFONT tFONTDIR tICON tHTML
291 %token tAUTO3STATE tAUTOCHECKBOX tAUTORADIOBUTTON tCHECKBOX tDEFPUSHBUTTON
292 %token tPUSHBUTTON tRADIOBUTTON tSTATE3 /* PUSHBOX */
293 %token tGROUPBOX tCOMBOBOX tLISTBOX tSCROLLBAR
294 %token tCONTROL tEDITTEXT
295 %token tRTEXT tCTEXT tLTEXT
296 %token tBLOCK tVALUE
297 %token tSHIFT tALT tASCII tVIRTKEY tGRAYED tCHECKED tINACTIVE tNOINVERT
298 %token tPURE tIMPURE tDISCARDABLE tLOADONCALL tPRELOAD tFIXED tMOVEABLE
299 %token tCLASS tCAPTION tCHARACTERISTICS tEXSTYLE tSTYLE tVERSION tLANGUAGE
300 %token tFILEVERSION tPRODUCTVERSION tFILEFLAGSMASK tFILEOS tFILETYPE tFILEFLAGS tFILESUBTYPE
301 %token tMENUBARBREAK tMENUBREAK tMENUITEM tPOPUP tSEPARATOR
302 %token tHELP
303 %token tSTRING tIDENT tRAWDATA
304 %token tTOOLBAR tBUTTON
305 %token tBEGIN tEND
306 %token tDLGINIT
307 %left '|'
308 %left '^'
309 %left '&'
310 %left '+' '-'
311 %left '*' '/'
312 %right '~' tNOT
313 %left pUPM
314
315 %type <res> resource_file resource resources resource_definition
316 %type <stt> stringtable strings
317 %type <fnt> font
318 %type <fnd> fontdir
319 %type <acc> accelerators
320 %type <event> events
321 %type <bmp> bitmap
322 %type <ani> cursor icon
323 %type <dlg> dialog dlg_attributes
324 %type <ctl> ctrls gen_ctrl lab_ctrl ctrl_desc iconinfo
325 %type <iptr> helpid
326 %type <dlgex> dialogex dlgex_attribs
327 %type <ctl> exctrls gen_exctrl lab_exctrl exctrl_desc
328 %type <html> html
329 %type <rdt> rcdata
330 %type <raw> raw_data raw_elements opt_data file_raw
331 %type <veri> versioninfo fix_version
332 %type <verw> ver_words
333 %type <blk> ver_blocks ver_block
334 %type <val> ver_values ver_value
335 %type <men> menu
336 %type <menitm> item_definitions menu_body
337 %type <menex> menuex
338 %type <menexitm> itemex_definitions menuex_body
339 %type <exopt> itemex_p_options itemex_options
340 %type <msg> messagetable
341 %type <usr> userres
342 %type <num> item_options
343 %type <nid> nameid nameid_s ctlclass usertype
344 %type <num> acc_opt acc accs
345 %type <iptr> loadmemopts lamo lama
346 %type <fntid> opt_font opt_exfont opt_expr
347 %type <lvc> opt_lvc
348 %type <lan> opt_language
349 %type <chars> opt_characts
350 %type <ver> opt_version
351 %type <num> expr xpr
352 %type <iptr> e_expr
353 %type <tlbar> toolbar
354 %type <tlbarItems> toolbar_items
355 %type <dginit> dlginit
356 %type <styles> optional_style_pair
357 %type <num> any_num
358 %type <style> style
359 %type <str> filename
360
361 %%
362
363 resource_file
364 : resources {
365 resource_t *rsc;
366 /* First add stringtables to the resource-list */
367 rsc = build_stt_resources(sttres);
368 /* 'build_stt_resources' returns a head and $1 is a tail */
369 if($1)
370 {
371 $1->next = rsc;
372 if(rsc)
373 rsc->prev = $1;
374 }
375 else
376 $1 = rsc;
377 /* Find the tail again */
378 while($1 && $1->next)
379 $1 = $1->next;
380 /* Now add any fontdirecory */
381 rsc = build_fontdirs($1);
382 /* 'build_fontdir' returns a head and $1 is a tail */
383 if($1)
384 {
385 $1->next = rsc;
386 if(rsc)
387 rsc->prev = $1;
388 }
389 else
390 $1 = rsc;
391 /* Final statement before were done */
392 resource_top = get_resource_head($1);
393 }
394 ;
395
396 /* Resources are put into a linked list */
397 resources
398 : /* Empty */ { $$ = NULL; want_id = 1; }
399 | resources resource {
400 if($2)
401 {
402 resource_t *tail = $2;
403 resource_t *head = $2;
404 while(tail->next)
405 tail = tail->next;
406 while(head->prev)
407 head = head->prev;
408 head->prev = $1;
409 if($1)
410 $1->next = head;
411 $$ = tail;
412 /* Check for duplicate identifiers */
413 while($1 && head)
414 {
415 resource_t *rsc = $1;
416 while(rsc)
417 {
418 if(rsc->type == head->type
419 && rsc->lan->id == head->lan->id
420 && rsc->lan->sub == head->lan->sub
421 && !compare_name_id(rsc->name, head->name))
422 {
423 yyerror("Duplicate resource name '%s'", get_nameid_str(rsc->name));
424 }
425 rsc = rsc->prev;
426 }
427 head = head->next;
428 }
429 }
430 else if($1)
431 {
432 resource_t *tail = $1;
433 while(tail->next)
434 tail = tail->next;
435 $$ = tail;
436 }
437 else
438 $$ = NULL;
439
440 if(!dont_want_id) /* See comments in language parsing below */
441 want_id = 1;
442 dont_want_id = 0;
443 }
444 /*
445 * The following newline rule will never get reduced because we never
446 * get the tNL token, unless we explicitely set the 'want_nl'
447 * flag, which we don't.
448 * The *ONLY* reason for this to be here is because Berkeley
449 * yacc (byacc), at least version 1.9, has a bug.
450 * (identified in the generated parser on the second
451 * line with:
452 * static char yysccsid[] = "@(#)yaccpar 1.9 (Berkeley) 02/21/93";
453 * )
454 * This extra rule fixes it.
455 * The problem is that the expression handling rule "expr: xpr"
456 * is not reduced on non-terminal tokens, defined above in the
457 * %token declarations. Token tNL is the only non-terminal that
458 * can occur. The error becomes visible in the language parsing
459 * rule below, which looks at the look-ahead token and tests it
460 * for tNL. However, byacc already generates an error upon reading
461 * the token instead of keeping it as a lookahead. The reason
462 * lies in the lack of a $default transition in the "expr : xpr . "
463 * state (currently state 25). It is probably omitted because tNL
464 * is a non-terminal and the state contains 2 s/r conflicts. The
465 * state enumerates all possible transitions instead of using a
466 * $default transition.
467 * All in all, it is a bug in byacc. (period)
468 */
469 | resources tNL
470 ;
471
472
473 /* Parse top level resource definitions etc. */
474 resource
475 : expr usrcvt resource_definition {
476 $$ = $3;
477 if($$)
478 {
479 if($1 > 65535 || $1 < -32768)
480 yyerror("Resource's ID out of range (%d)", $1);
481 $$->name = new_name_id();
482 $$->name->type = name_ord;
483 $$->name->name.i_name = $1;
484 chat("Got %s (%d)", get_typename($3), $$->name->name.i_name);
485 }
486 }
487 | tIDENT usrcvt resource_definition {
488 $$ = $3;
489 if($$)
490 {
491 $$->name = new_name_id();
492 $$->name->type = name_str;
493 $$->name->name.s_name = $1;
494 chat("Got %s (%s)", get_typename($3), $$->name->name.s_name->str.cstr);
495 }
496 }
497 | stringtable {
498 /* Don't do anything, stringtables are converted to
499 * resource_t structures when we are finished parsing and
500 * the final rule of the parser is reduced (see above)
501 */
502 $$ = NULL;
503 chat("Got STRINGTABLE");
504 }
505 | tLANGUAGE {want_nl = 1; } expr ',' expr {
506 /* We *NEED* the newline to delimit the expression.
507 * Otherwise, we would not be able to set the next
508 * want_id anymore because of the token-lookahead.
509 *
510 * However, we can test the lookahead-token for
511 * being "non-expression" type, in which case we
512 * continue. Fortunately, tNL is the only token that
513 * will break expression parsing and is implicitely
514 * void, so we just remove it. This scheme makes it
515 * possible to do some (not all) fancy preprocessor
516 * stuff.
517 * BTW, we also need to make sure that the next
518 * reduction of 'resources' above will *not* set
519 * want_id because we already have a lookahead that
520 * cannot be undone.
521 */
522 if(yychar != YYEMPTY && yychar != tNL)
523 dont_want_id = 1;
524
525 if(yychar == tNL)
526 yychar = YYEMPTY; /* Could use 'yyclearin', but we already need the*/
527 /* direct access to yychar in rule 'usrcvt' below. */
528 else if(yychar == tIDENT)
529 yywarning("LANGUAGE statement not delimited with newline; next identifier might be wrong");
530
531 want_nl = 0; /* We don't want it anymore if we didn't get it */
532
533 if(!win32)
534 yywarning("LANGUAGE not supported in 16-bit mode");
535 if(currentlanguage)
536 free(currentlanguage);
537 if (get_language_codepage($3, $5) == -1)
538 yyerror( "Language %04x is not supported", ($5<<10) + $3);
539 currentlanguage = new_language($3, $5);
540 $$ = NULL;
541 chat("Got LANGUAGE %d,%d (0x%04x)", $3, $5, ($5<<10) + $3);
542 }
543 ;
544
545 /*
546 * Remapping of numerical resource types
547 * (see also comment of called function below)
548 */
549 usrcvt : /* Empty */ { yychar = rsrcid_to_token(yychar); }
550 ;
551
552 /*
553 * Get a valid name/id
554 */
555 nameid : expr {
556 if($1 > 65535 || $1 < -32768)
557 yyerror("Resource's ID out of range (%d)", $1);
558 $$ = new_name_id();
559 $$->type = name_ord;
560 $$->name.i_name = $1;
561 }
562 | tIDENT {
563 $$ = new_name_id();
564 $$->type = name_str;
565 $$->name.s_name = $1;
566 }
567 ;
568
569 /*
570 * Extra string recognition for CLASS statement in dialogs
571 */
572 nameid_s: nameid { $$ = $1; }
573 | tSTRING {
574 $$ = new_name_id();
575 $$->type = name_str;
576 $$->name.s_name = $1;
577 }
578 ;
579
580 /* get the value for a single resource*/
581 resource_definition
582 : accelerators { $$ = new_resource(res_acc, $1, $1->memopt, $1->lvc.language); }
583 | bitmap { $$ = new_resource(res_bmp, $1, $1->memopt, $1->data->lvc.language); }
584 | cursor {
585 resource_t *rsc;
586 if($1->type == res_anicur)
587 {
588 $$ = rsc = new_resource(res_anicur, $1->u.ani, $1->u.ani->memopt, $1->u.ani->data->lvc.language);
589 }
590 else if($1->type == res_curg)
591 {
592 cursor_t *cur;
593 $$ = rsc = new_resource(res_curg, $1->u.curg, $1->u.curg->memopt, $1->u.curg->lvc.language);
594 for(cur = $1->u.curg->cursorlist; cur; cur = cur->next)
595 {
596 rsc->prev = new_resource(res_cur, cur, $1->u.curg->memopt, $1->u.curg->lvc.language);
597 rsc->prev->next = rsc;
598 rsc = rsc->prev;
599 rsc->name = new_name_id();
600 rsc->name->type = name_ord;
601 rsc->name->name.i_name = cur->id;
602 }
603 }
604 else
605 internal_error(__FILE__, __LINE__, "Invalid top-level type %d in cursor resource", $1->type);
606 free($1);
607 }
608 | dialog { $$ = new_resource(res_dlg, $1, $1->memopt, $1->lvc.language); }
609 | dialogex {
610 if(win32)
611 $$ = new_resource(res_dlgex, $1, $1->memopt, $1->lvc.language);
612 else
613 $$ = NULL;
614 }
615 | dlginit { $$ = new_resource(res_dlginit, $1, $1->memopt, $1->data->lvc.language); }
616 | font { $$ = new_resource(res_fnt, $1, $1->memopt, $1->data->lvc.language); }
617 | fontdir { $$ = new_resource(res_fntdir, $1, $1->memopt, $1->data->lvc.language); }
618 | icon {
619 resource_t *rsc;
620 if($1->type == res_aniico)
621 {
622 $$ = rsc = new_resource(res_aniico, $1->u.ani, $1->u.ani->memopt, $1->u.ani->data->lvc.language);
623 }
624 else if($1->type == res_icog)
625 {
626 icon_t *ico;
627 $$ = rsc = new_resource(res_icog, $1->u.icog, $1->u.icog->memopt, $1->u.icog->lvc.language);
628 for(ico = $1->u.icog->iconlist; ico; ico = ico->next)
629 {
630 rsc->prev = new_resource(res_ico, ico, $1->u.icog->memopt, $1->u.icog->lvc.language);
631 rsc->prev->next = rsc;
632 rsc = rsc->prev;
633 rsc->name = new_name_id();
634 rsc->name->type = name_ord;
635 rsc->name->name.i_name = ico->id;
636 }
637 }
638 else
639 internal_error(__FILE__, __LINE__, "Invalid top-level type %d in icon resource", $1->type);
640 free($1);
641 }
642 | menu { $$ = new_resource(res_men, $1, $1->memopt, $1->lvc.language); }
643 | menuex {
644 if(win32)
645 $$ = new_resource(res_menex, $1, $1->memopt, $1->lvc.language);
646 else
647 $$ = NULL;
648 }
649 | messagetable { $$ = new_resource(res_msg, $1, WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE, $1->data->lvc.language); }
650 | html { $$ = new_resource(res_html, $1, $1->memopt, $1->data->lvc.language); }
651 | rcdata { $$ = new_resource(res_rdt, $1, $1->memopt, $1->data->lvc.language); }
652 | toolbar { $$ = new_resource(res_toolbar, $1, $1->memopt, $1->lvc.language); }
653 | userres { $$ = new_resource(res_usr, $1, $1->memopt, $1->data->lvc.language); }
654 | versioninfo { $$ = new_resource(res_ver, $1, WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE, $1->lvc.language); }
655 ;
656
657
658 filename: tFILENAME { $$ = make_filename($1); }
659 | tIDENT { $$ = make_filename($1); }
660 | tSTRING { $$ = make_filename($1); }
661 ;
662
663 /* ------------------------------ Bitmap ------------------------------ */
664 bitmap : tBITMAP loadmemopts file_raw { $$ = new_bitmap($3, $2); }
665 ;
666
667 /* ------------------------------ Cursor ------------------------------ */
668 cursor : tCURSOR loadmemopts file_raw {
669 $$ = new_ani_any();
670 if($3->size > 4 && !memcmp($3->data, riff, sizeof(riff)))
671 {
672 $$->type = res_anicur;
673 $$->u.ani = new_ani_curico(res_anicur, $3, $2);
674 }
675 else
676 {
677 $$->type = res_curg;
678 $$->u.curg = new_cursor_group($3, $2);
679 }
680 }
681 ;
682
683 /* ------------------------------ Icon ------------------------------ */
684 icon : tICON loadmemopts file_raw {
685 $$ = new_ani_any();
686 if($3->size > 4 && !memcmp($3->data, riff, sizeof(riff)))
687 {
688 $$->type = res_aniico;
689 $$->u.ani = new_ani_curico(res_aniico, $3, $2);
690 }
691 else
692 {
693 $$->type = res_icog;
694 $$->u.icog = new_icon_group($3, $2);
695 }
696 }
697 ;
698
699 /* ------------------------------ Font ------------------------------ */
700 /*
701 * The reading of raw_data for fonts is a Borland BRC
702 * extension. MS generates an error. However, it is
703 * most logical to support this, considering how wine
704 * enters things in CVS (ascii).
705 */
706 font : tFONT loadmemopts file_raw { $$ = new_font($3, $2); }
707 ;
708
709 /*
710 * The fontdir is a Borland BRC extension which only
711 * reads the data as 'raw_data' from the file.
712 * I don't know whether it is interpreted.
713 * The fontdir is generated if it was not present and
714 * fonts are defined in the source.
715 */
716 fontdir : tFONTDIR loadmemopts file_raw { $$ = new_fontdir($3, $2); }
717 ;
718
719 /* ------------------------------ MessageTable ------------------------------ */
720 /* It might be interesting to implement the MS Message compiler here as well
721 * to get everything in one source. Might be a future project.
722 */
723 messagetable
724 : tMESSAGETABLE loadmemopts file_raw {
725 if(!win32)
726 yywarning("MESSAGETABLE not supported in 16-bit mode");
727 $$ = new_messagetable($3, $2);
728 }
729 ;
730
731 /* ------------------------------ HTML ------------------------------ */
732 html : tHTML loadmemopts file_raw { $$ = new_html($3, $2); }
733 ;
734
735 /* ------------------------------ RCData ------------------------------ */
736 rcdata : tRCDATA loadmemopts file_raw { $$ = new_rcdata($3, $2); }
737 ;
738
739 /* ------------------------------ DLGINIT ------------------------------ */
740 dlginit : tDLGINIT loadmemopts file_raw { $$ = new_dlginit($3, $2); }
741 ;
742
743 /* ------------------------------ UserType ------------------------------ */
744 userres : usertype loadmemopts file_raw {
745 #ifdef WORDS_BIGENDIAN
746 if(pedantic && byteorder != WRC_BO_LITTLE)
747 #else
748 if(pedantic && byteorder == WRC_BO_BIG)
749 #endif
750 yywarning("Byteordering is not little-endian and type cannot be interpreted");
751 $$ = new_user($1, $3, $2);
752 }
753 ;
754
755 usertype: tNUMBER {
756 $$ = new_name_id();
757 $$->type = name_ord;
758 $$->name.i_name = $1;
759 }
760 | tIDENT {
761 $$ = new_name_id();
762 $$->type = name_str;
763 $$->name.s_name = $1;
764 }
765 ;
766
767 /* ------------------------------ Accelerator ------------------------------ */
768 accelerators
769 : tACCELERATORS loadmemopts opt_lvc tBEGIN events tEND {
770 $$ = new_accelerator();
771 if($2)
772 {
773 $$->memopt = *($2);
774 free($2);
775 }
776 else
777 {
778 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE;
779 }
780 if(!$5)
781 yyerror("Accelerator table must have at least one entry");
782 $$->events = get_event_head($5);
783 if($3)
784 {
785 $$->lvc = *($3);
786 free($3);
787 }
788 if(!$$->lvc.language)
789 $$->lvc.language = dup_language(currentlanguage);
790 }
791 ;
792
793 events : /* Empty */ { $$=NULL; }
794 | events tSTRING ',' expr acc_opt { $$=add_string_event($2, $4, $5, $1); }
795 | events expr ',' expr acc_opt { $$=add_event($2, $4, $5, $1); }
796 ;
797
798 /*
799 * The empty rule generates a s/r conflict because of {bi,u}nary expr
800 * on - and +. It cannot be solved in any way because it is the same as
801 * the if/then/else problem (LALR(1) problem). The conflict is moved
802 * away by forcing it to be in the expression handling below.
803 */
804 acc_opt : /* Empty */ { $$ = 0; }
805 | ',' accs { $$ = $2; }
806 ;
807
808 accs : acc { $$ = $1; }
809 | accs ',' acc { $$ = $1 | $3; }
810 ;
811
812 acc : tNOINVERT { $$ = WRC_AF_NOINVERT; }
813 | tSHIFT { $$ = WRC_AF_SHIFT; }
814 | tCONTROL { $$ = WRC_AF_CONTROL; }
815 | tALT { $$ = WRC_AF_ALT; }
816 | tASCII { $$ = WRC_AF_ASCII; }
817 | tVIRTKEY { $$ = WRC_AF_VIRTKEY; }
818 ;
819
820 /* ------------------------------ Dialog ------------------------------ */
821 /* FIXME: Support EXSTYLE in the dialog line itself */
822 dialog : tDIALOG loadmemopts expr ',' expr ',' expr ',' expr dlg_attributes
823 tBEGIN ctrls tEND {
824 if($2)
825 {
826 $10->memopt = *($2);
827 free($2);
828 }
829 else
830 $10->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
831 $10->x = $3;
832 $10->y = $5;
833 $10->width = $7;
834 $10->height = $9;
835 $10->controls = get_control_head($12);
836 $$ = $10;
837 if(!$$->gotstyle)
838 {
839 $$->style = new_style(0,0);
840 $$->style->or_mask = WS_POPUP;
841 $$->gotstyle = TRUE;
842 }
843 if($$->title)
844 $$->style->or_mask |= WS_CAPTION;
845 if($$->font)
846 $$->style->or_mask |= DS_SETFONT;
847
848 $$->style->or_mask &= ~($$->style->and_mask);
849 $$->style->and_mask = 0;
850
851 if(!$$->lvc.language)
852 $$->lvc.language = dup_language(currentlanguage);
853 }
854 ;
855
856 dlg_attributes
857 : /* Empty */ { $$=new_dialog(); }
858 | dlg_attributes tSTYLE style { $$=dialog_style($3,$1); }
859 | dlg_attributes tEXSTYLE style { $$=dialog_exstyle($3,$1); }
860 | dlg_attributes tCAPTION tSTRING { $$=dialog_caption($3,$1); }
861 | dlg_attributes opt_font { $$=dialog_font($2,$1); }
862 | dlg_attributes tCLASS nameid_s { $$=dialog_class($3,$1); }
863 | dlg_attributes tMENU nameid { $$=dialog_menu($3,$1); }
864 | dlg_attributes opt_language { $$=dialog_language($2,$1); }
865 | dlg_attributes opt_characts { $$=dialog_characteristics($2,$1); }
866 | dlg_attributes opt_version { $$=dialog_version($2,$1); }
867 ;
868
869 ctrls : /* Empty */ { $$ = NULL; }
870 | ctrls tCONTROL gen_ctrl { $$=ins_ctrl(-1, 0, $3, $1); }
871 | ctrls tEDITTEXT ctrl_desc { $$=ins_ctrl(CT_EDIT, 0, $3, $1); }
872 | ctrls tLISTBOX ctrl_desc { $$=ins_ctrl(CT_LISTBOX, 0, $3, $1); }
873 | ctrls tCOMBOBOX ctrl_desc { $$=ins_ctrl(CT_COMBOBOX, 0, $3, $1); }
874 | ctrls tSCROLLBAR ctrl_desc { $$=ins_ctrl(CT_SCROLLBAR, 0, $3, $1); }
875 | ctrls tCHECKBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_CHECKBOX, $3, $1); }
876 | ctrls tDEFPUSHBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_DEFPUSHBUTTON, $3, $1); }
877 | ctrls tGROUPBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_GROUPBOX, $3, $1);}
878 | ctrls tPUSHBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBUTTON, $3, $1); }
879 /* | ctrls tPUSHBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBOX, $3, $1); } */
880 | ctrls tRADIOBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_RADIOBUTTON, $3, $1); }
881 | ctrls tAUTO3STATE lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTO3STATE, $3, $1); }
882 | ctrls tSTATE3 lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_3STATE, $3, $1); }
883 | ctrls tAUTOCHECKBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTOCHECKBOX, $3, $1); }
884 | ctrls tAUTORADIOBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTORADIOBUTTON, $3, $1); }
885 | ctrls tLTEXT lab_ctrl { $$=ins_ctrl(CT_STATIC, SS_LEFT, $3, $1); }
886 | ctrls tCTEXT lab_ctrl { $$=ins_ctrl(CT_STATIC, SS_CENTER, $3, $1); }
887 | ctrls tRTEXT lab_ctrl { $$=ins_ctrl(CT_STATIC, SS_RIGHT, $3, $1); }
888 /* special treatment for icons, as the extent is optional */
889 | ctrls tICON nameid_s opt_comma expr ',' expr ',' expr iconinfo {
890 $10->title = $3;
891 $10->id = $5;
892 $10->x = $7;
893 $10->y = $9;
894 $$ = ins_ctrl(CT_STATIC, SS_ICON, $10, $1);
895 }
896 ;
897
898 lab_ctrl
899 : nameid_s opt_comma expr ',' expr ',' expr ',' expr ',' expr optional_style_pair {
900 $$=new_control();
901 $$->title = $1;
902 $$->id = $3;
903 $$->x = $5;
904 $$->y = $7;
905 $$->width = $9;
906 $$->height = $11;
907 if($12)
908 {
909 $$->style = $12->style;
910 $$->gotstyle = TRUE;
911 if ($12->exstyle)
912 {
913 $$->exstyle = $12->exstyle;
914 $$->gotexstyle = TRUE;
915 }
916 free($12);
917 }
918 }
919 ;
920
921 ctrl_desc
922 : expr ',' expr ',' expr ',' expr ',' expr optional_style_pair {
923 $$ = new_control();
924 $$->id = $1;
925 $$->x = $3;
926 $$->y = $5;
927 $$->width = $7;
928 $$->height = $9;
929 if($10)
930 {
931 $$->style = $10->style;
932 $$->gotstyle = TRUE;
933 if ($10->exstyle)
934 {
935 $$->exstyle = $10->exstyle;
936 $$->gotexstyle = TRUE;
937 }
938 free($10);
939 }
940 }
941 ;
942
943 iconinfo: /* Empty */
944 { $$ = new_control(); }
945
946 | ',' expr ',' expr {
947 $$ = new_control();
948 $$->width = $2;
949 $$->height = $4;
950 }
951 | ',' expr ',' expr ',' style {
952 $$ = new_control();
953 $$->width = $2;
954 $$->height = $4;
955 $$->style = $6;
956 $$->gotstyle = TRUE;
957 }
958 | ',' expr ',' expr ',' style ',' style {
959 $$ = new_control();
960 $$->width = $2;
961 $$->height = $4;
962 $$->style = $6;
963 $$->gotstyle = TRUE;
964 $$->exstyle = $8;
965 $$->gotexstyle = TRUE;
966 }
967 ;
968
969 gen_ctrl: nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ',' expr ',' style {
970 $$=new_control();
971 $$->title = $1;
972 $$->id = $3;
973 $$->ctlclass = convert_ctlclass($5);
974 $$->style = $7;
975 $$->gotstyle = TRUE;
976 $$->x = $9;
977 $$->y = $11;
978 $$->width = $13;
979 $$->height = $15;
980 $$->exstyle = $17;
981 $$->gotexstyle = TRUE;
982 }
983 | nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ',' expr {
984 $$=new_control();
985 $$->title = $1;
986 $$->id = $3;
987 $$->ctlclass = convert_ctlclass($5);
988 $$->style = $7;
989 $$->gotstyle = TRUE;
990 $$->x = $9;
991 $$->y = $11;
992 $$->width = $13;
993 $$->height = $15;
994 }
995 ;
996
997 opt_font
998 : tFONT expr ',' tSTRING { $$ = new_font_id($2, $4, 0, 0); }
999 ;
1000
1001 /* ------------------------------ style flags ------------------------------ */
1002 optional_style_pair
1003 : /* Empty */ { $$ = NULL; }
1004 | ',' style { $$ = new_style_pair($2, 0); }
1005 | ',' style ',' style { $$ = new_style_pair($2, $4); }
1006 ;
1007
1008 style
1009 : style '|' style { $$ = new_style($1->or_mask | $3->or_mask, $1->and_mask | $3->and_mask); free($1); free($3);}
1010 | '(' style ')' { $$ = $2; }
1011 | any_num { $$ = new_style($1, 0); }
1012 | tNOT any_num { $$ = new_style(0, $2); }
1013 ;
1014
1015 ctlclass
1016 : expr {
1017 $$ = new_name_id();
1018 $$->type = name_ord;
1019 $$->name.i_name = $1;
1020 }
1021 | tSTRING {
1022 $$ = new_name_id();
1023 $$->type = name_str;
1024 $$->name.s_name = $1;
1025 }
1026 ;
1027
1028 /* ------------------------------ DialogEx ------------------------------ */
1029 dialogex: tDIALOGEX loadmemopts expr ',' expr ',' expr ',' expr helpid dlgex_attribs
1030 tBEGIN exctrls tEND {
1031 if(!win32)
1032 yywarning("DIALOGEX not supported in 16-bit mode");
1033 if($2)
1034 {
1035 $11->memopt = *($2);
1036 free($2);
1037 }
1038 else
1039 $11->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
1040 $11->x = $3;
1041 $11->y = $5;
1042 $11->width = $7;
1043 $11->height = $9;
1044 if($10)
1045 {
1046 $11->helpid = *($10);
1047 $11->gothelpid = TRUE;
1048 free($10);
1049 }
1050 $11->controls = get_control_head($13);
1051 $$ = $11;
1052
1053 assert($$->style != NULL);
1054 if(!$$->gotstyle)
1055 {
1056 $$->style->or_mask = WS_POPUP;
1057 $$->gotstyle = TRUE;
1058 }
1059 if($$->title)
1060 $$->style->or_mask |= WS_CAPTION;
1061 if($$->font)
1062 $$->style->or_mask |= DS_SETFONT;
1063
1064 $$->style->or_mask &= ~($$->style->and_mask);
1065 $$->style->and_mask = 0;
1066
1067 if(!$$->lvc.language)
1068 $$->lvc.language = dup_language(currentlanguage);
1069 }
1070 ;
1071
1072 dlgex_attribs
1073 : /* Empty */ { $$=new_dialogex(); }
1074 | dlgex_attribs tSTYLE style { $$=dialogex_style($3,$1); }
1075 | dlgex_attribs tEXSTYLE style { $$=dialogex_exstyle($3,$1); }
1076 | dlgex_attribs tCAPTION tSTRING { $$=dialogex_caption($3,$1); }
1077 | dlgex_attribs opt_font { $$=dialogex_font($2,$1); }
1078 | dlgex_attribs opt_exfont { $$=dialogex_font($2,$1); }
1079 | dlgex_attribs tCLASS nameid_s { $$=dialogex_class($3,$1); }
1080 | dlgex_attribs tMENU nameid { $$=dialogex_menu($3,$1); }
1081 | dlgex_attribs opt_language { $$=dialogex_language($2,$1); }
1082 | dlgex_attribs opt_characts { $$=dialogex_characteristics($2,$1); }
1083 | dlgex_attribs opt_version { $$=dialogex_version($2,$1); }
1084 ;
1085
1086 exctrls : /* Empty */ { $$ = NULL; }
1087 | exctrls tCONTROL gen_exctrl { $$=ins_ctrl(-1, 0, $3, $1); }
1088 | exctrls tEDITTEXT exctrl_desc { $$=ins_ctrl(CT_EDIT, 0, $3, $1); }
1089 | exctrls tLISTBOX exctrl_desc { $$=ins_ctrl(CT_LISTBOX, 0, $3, $1); }
1090 | exctrls tCOMBOBOX exctrl_desc { $$=ins_ctrl(CT_COMBOBOX, 0, $3, $1); }
1091 | exctrls tSCROLLBAR exctrl_desc { $$=ins_ctrl(CT_SCROLLBAR, 0, $3, $1); }
1092 | exctrls tCHECKBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_CHECKBOX, $3, $1); }
1093 | exctrls tDEFPUSHBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_DEFPUSHBUTTON, $3, $1); }
1094 | exctrls tGROUPBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_GROUPBOX, $3, $1);}
1095 | exctrls tPUSHBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBUTTON, $3, $1); }
1096 /* | exctrls tPUSHBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBOX, $3, $1); } */
1097 | exctrls tRADIOBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_RADIOBUTTON, $3, $1); }
1098 | exctrls tAUTO3STATE lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTO3STATE, $3, $1); }
1099 | exctrls tSTATE3 lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_3STATE, $3, $1); }
1100 | exctrls tAUTOCHECKBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTOCHECKBOX, $3, $1); }
1101 | exctrls tAUTORADIOBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTORADIOBUTTON, $3, $1); }
1102 | exctrls tLTEXT lab_exctrl { $$=ins_ctrl(CT_STATIC, SS_LEFT, $3, $1); }
1103 | exctrls tCTEXT lab_exctrl { $$=ins_ctrl(CT_STATIC, SS_CENTER, $3, $1); }
1104 | exctrls tRTEXT lab_exctrl { $$=ins_ctrl(CT_STATIC, SS_RIGHT, $3, $1); }
1105 /* special treatment for icons, as the extent is optional */
1106 | exctrls tICON nameid_s opt_comma expr ',' expr ',' expr iconinfo {
1107 $10->title = $3;
1108 $10->id = $5;
1109 $10->x = $7;
1110 $10->y = $9;
1111 $$ = ins_ctrl(CT_STATIC, SS_ICON, $10, $1);
1112 }
1113 ;
1114
1115 gen_exctrl
1116 : nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ','
1117 expr ',' style helpid opt_data {
1118 $$=new_control();
1119 $$->title = $1;
1120 $$->id = $3;
1121 $$->ctlclass = convert_ctlclass($5);
1122 $$->style = $7;
1123 $$->gotstyle = TRUE;
1124 $$->x = $9;
1125 $$->y = $11;
1126 $$->width = $13;
1127 $$->height = $15;
1128 if($17)
1129 {
1130 $$->exstyle = $17;
1131 $$->gotexstyle = TRUE;
1132 }
1133 if($18)
1134 {
1135 $$->helpid = *($18);
1136 $$->gothelpid = TRUE;
1137 free($18);
1138 }
1139 $$->extra = $19;
1140 }
1141 | nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ',' expr opt_data {
1142 $$=new_control();
1143 $$->title = $1;
1144 $$->id = $3;
1145 $$->style = $7;
1146 $$->gotstyle = TRUE;
1147 $$->ctlclass = convert_ctlclass($5);
1148 $$->x = $9;
1149 $$->y = $11;
1150 $$->width = $13;
1151 $$->height = $15;
1152 $$->extra = $16;
1153 }
1154 ;
1155
1156 lab_exctrl
1157 : nameid_s opt_comma expr ',' expr ',' expr ',' expr ',' expr optional_style_pair helpid opt_data {
1158 $$=new_control();
1159 $$->title = $1;
1160 $$->id = $3;
1161 $$->x = $5;
1162 $$->y = $7;
1163 $$->width = $9;
1164 $$->height = $11;
1165 if($12)
1166 {
1167 $$->style = $12->style;
1168 $$->gotstyle = TRUE;
1169
1170 if ($12->exstyle)
1171 {
1172 $$->exstyle = $12->exstyle;
1173 $$->gotexstyle = TRUE;
1174 }
1175 free($12);
1176 }
1177
1178 $$->extra = $14;
1179 }
1180 ;
1181
1182 exctrl_desc
1183 : expr ',' expr ',' expr ',' expr ',' expr optional_style_pair helpid opt_data {
1184 $$ = new_control();
1185 $$->id = $1;
1186 $$->x = $3;
1187 $$->y = $5;
1188 $$->width = $7;
1189 $$->height = $9;
1190 if($10)
1191 {
1192 $$->style = $10->style;
1193 $$->gotstyle = TRUE;
1194
1195 if ($10->exstyle)
1196 {
1197 $$->exstyle = $10->exstyle;
1198 $$->gotexstyle = TRUE;
1199 }
1200 free($10);
1201 }
1202 $$->extra = $12;
1203 }
1204 ;
1205
1206 opt_data: /* Empty */ { $$ = NULL; }
1207 | raw_data { $$ = $1; }
1208 ;
1209
1210 helpid : /* Empty */ { $$ = NULL; }
1211 | ',' expr { $$ = new_int($2); }
1212 ;
1213
1214 opt_exfont
1215 : tFONT expr ',' tSTRING ',' expr ',' expr opt_expr { $$ = new_font_id($2, $4, $6, $8); }
1216 ;
1217
1218 /*
1219 * FIXME: This odd expression is here to nullify an extra token found
1220 * in some appstudio produced resources which appear to do nothing.
1221 */
1222 opt_expr: /* Empty */ { $$ = NULL; }
1223 | ',' expr { $$ = NULL; }
1224 ;
1225
1226 /* ------------------------------ Menu ------------------------------ */
1227 menu : tMENU loadmemopts opt_lvc menu_body {
1228 if(!$4)
1229 yyerror("Menu must contain items");
1230 $$ = new_menu();
1231 if($2)
1232 {
1233 $$->memopt = *($2);
1234 free($2);
1235 }
1236 else
1237 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
1238 $$->items = get_item_head($4);
1239 if($3)
1240 {
1241 $$->lvc = *($3);
1242 free($3);
1243 }
1244 if(!$$->lvc.language)
1245 $$->lvc.language = dup_language(currentlanguage);
1246 }
1247 ;
1248
1249 menu_body
1250 : tBEGIN item_definitions tEND { $$ = $2; }
1251 ;
1252
1253 item_definitions
1254 : /* Empty */ {$$ = NULL;}
1255 | item_definitions tMENUITEM tSTRING opt_comma expr item_options {
1256 $$=new_menu_item();
1257 $$->prev = $1;
1258 if($1)
1259 $1->next = $$;
1260 $$->id = $5;
1261 $$->state = $6;
1262 $$->name = $3;
1263 }
1264 | item_definitions tMENUITEM tSEPARATOR {
1265 $$=new_menu_item();
1266 $$->prev = $1;
1267 if($1)
1268 $1->next = $$;
1269 }
1270 | item_definitions tPOPUP tSTRING item_options menu_body {
1271 $$ = new_menu_item();
1272 $$->prev = $1;
1273 if($1)
1274 $1->next = $$;
1275 $$->popup = get_item_head($5);
1276 $$->name = $3;
1277 }
1278 ;
1279
1280 /* NOTE: item_options is right recursive because it would introduce
1281 * a shift/reduce conflict on ',' in itemex_options due to the
1282 * empty rule here. The parser is now forced to look beyond the ','
1283 * before reducing (force shift).
1284 * Right recursion here is not a problem because we cannot expect
1285 * more than 7 parserstack places to be occupied while parsing this
1286 * (who would want to specify a MF_x flag twice?).
1287 */
1288 item_options
1289 : /* Empty */ { $$ = 0; }
1290 | opt_comma tCHECKED item_options { $$ = $3 | MF_CHECKED; }
1291 | opt_comma tGRAYED item_options { $$ = $3 | MF_GRAYED; }
1292 | opt_comma tHELP item_options { $$ = $3 | MF_HELP; }
1293 | opt_comma tINACTIVE item_options { $$ = $3 | MF_DISABLED; }
1294 | opt_comma tMENUBARBREAK item_options { $$ = $3 | MF_MENUBARBREAK; }
1295 | opt_comma tMENUBREAK item_options { $$ = $3 | MF_MENUBREAK; }
1296 ;
1297
1298 /* ------------------------------ MenuEx ------------------------------ */
1299 menuex : tMENUEX loadmemopts opt_lvc menuex_body {
1300 if(!win32)
1301 yywarning("MENUEX not supported in 16-bit mode");
1302 if(!$4)
1303 yyerror("MenuEx must contain items");
1304 $$ = new_menuex();
1305 if($2)
1306 {
1307 $$->memopt = *($2);
1308 free($2);
1309 }
1310 else
1311 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
1312 $$->items = get_itemex_head($4);
1313 if($3)
1314 {
1315 $$->lvc = *($3);
1316 free($3);
1317 }
1318 if(!$$->lvc.language)
1319 $$->lvc.language = dup_language(currentlanguage);
1320 }
1321 ;
1322
1323 menuex_body
1324 : tBEGIN itemex_definitions tEND { $$ = $2; }
1325 ;
1326
1327 itemex_definitions
1328 : /* Empty */ {$$ = NULL; }
1329 | itemex_definitions tMENUITEM tSTRING itemex_options {
1330 $$ = new_menuex_item();
1331 $$->prev = $1;
1332 if($1)
1333 $1->next = $$;
1334 $$->name = $3;
1335 $$->id = $4->id;
1336 $$->type = $4->type;
1337 $$->state = $4->state;
1338 $$->helpid = $4->helpid;
1339 $$->gotid = $4->gotid;
1340 $$->gottype = $4->gottype;
1341 $$->gotstate = $4->gotstate;
1342 $$->gothelpid = $4->gothelpid;
1343 free($4);
1344 }
1345 | itemex_definitions tMENUITEM tSEPARATOR {
1346 $$ = new_menuex_item();
1347 $$->prev = $1;
1348 if($1)
1349 $1->next = $$;
1350 }
1351 | itemex_definitions tPOPUP tSTRING itemex_p_options menuex_body {
1352 $$ = new_menuex_item();
1353 $$->prev = $1;
1354 if($1)
1355 $1->next = $$;
1356 $$->popup = get_itemex_head($5);
1357 $$->name = $3;
1358 $$->id = $4->id;
1359 $$->type = $4->type;
1360 $$->state = $4->state;
1361 $$->helpid = $4->helpid;
1362 $$->gotid = $4->gotid;
1363 $$->gottype = $4->gottype;
1364 $$->gotstate = $4->gotstate;
1365 $$->gothelpid = $4->gothelpid;
1366 free($4);
1367 }
1368 ;
1369
1370 itemex_options
1371 : /* Empty */ { $$ = new_itemex_opt(0, 0, 0, 0); }
1372 | ',' expr {
1373 $$ = new_itemex_opt($2, 0, 0, 0);
1374 $$->gotid = TRUE;
1375 }
1376 | ',' e_expr ',' e_expr item_options {
1377 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $5, 0);
1378 $$->gotid = TRUE;
1379 $$->gottype = TRUE;
1380 $$->gotstate = TRUE;
1381 if($2) free($2);
1382 if($4) free($4);
1383 }
1384 | ',' e_expr ',' e_expr ',' expr {
1385 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $6, 0);
1386 $$->gotid = TRUE;
1387 $$->gottype = TRUE;
1388 $$->gotstate = TRUE;
1389 if($2) free($2);
1390 if($4) free($4);
1391 }
1392 ;
1393
1394 itemex_p_options
1395 : /* Empty */ { $$ = new_itemex_opt(0, 0, 0, 0); }
1396 | ',' expr {
1397 $$ = new_itemex_opt($2, 0, 0, 0);
1398 $$->gotid = TRUE;
1399 }
1400 | ',' e_expr ',' expr {
1401 $$ = new_itemex_opt($2 ? *($2) : 0, $4, 0, 0);
1402 if($2) free($2);
1403 $$->gotid = TRUE;
1404 $$->gottype = TRUE;
1405 }
1406 | ',' e_expr ',' e_expr ',' expr {
1407 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $6, 0);
1408 if($2) free($2);
1409 if($4) free($4);
1410 $$->gotid = TRUE;
1411 $$->gottype = TRUE;
1412 $$->gotstate = TRUE;
1413 }
1414 | ',' e_expr ',' e_expr ',' e_expr ',' expr {
1415 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $6 ? *($6) : 0, $8);
1416 if($2) free($2);
1417 if($4) free($4);
1418 if($6) free($6);
1419 $$->gotid = TRUE;
1420 $$->gottype = TRUE;
1421 $$->gotstate = TRUE;
1422 $$->gothelpid = TRUE;
1423 }
1424 ;
1425
1426 /* ------------------------------ StringTable ------------------------------ */
1427 /* Stringtables are parsed differently than other resources because their
1428 * layout is substantially different from other resources.
1429 * The table is parsed through a _global_ variable 'tagstt' which holds the
1430 * current stringtable descriptor (stringtable_t *) and 'sttres' that holds a
1431 * list of stringtables of different languages.
1432 */
1433 stringtable
1434 : stt_head tBEGIN strings tEND {
1435 if(!$3)
1436 {
1437 yyerror("Stringtable must have at least one entry");
1438 }
1439 else
1440 {
1441 stringtable_t *stt;
1442 /* Check if we added to a language table or created
1443 * a new one.
1444 */
1445 for(stt = sttres; stt; stt = stt->next)
1446 {
1447 if(stt == tagstt)
1448 break;
1449 }
1450 if(!stt)
1451 {
1452 /* It is a new one */
1453 if(sttres)
1454 {
1455 sttres->prev = tagstt;
1456 tagstt->next = sttres;
1457 sttres = tagstt;
1458 }
1459 else
1460 sttres = tagstt;
1461 }
1462 /* Else were done */
1463 }
1464 if(tagstt_memopt)
1465 {
1466 free(tagstt_memopt);
1467 tagstt_memopt = NULL;
1468 }
1469
1470 $$ = tagstt;
1471 }
1472 ;
1473
1474 /* This is to get the language of the currently parsed stringtable */
1475 stt_head: tSTRINGTABLE loadmemopts opt_lvc {
1476 if((tagstt = find_stringtable($3)) == NULL)
1477 tagstt = new_stringtable($3);
1478 tagstt_memopt = $2;
1479 tagstt_version = $3->version;
1480 tagstt_characts = $3->characts;
1481 if($3)
1482 free($3);
1483 }
1484 ;
1485
1486 strings : /* Empty */ { $$ = NULL; }
1487 | strings expr opt_comma tSTRING {
1488 int i;
1489 assert(tagstt != NULL);
1490 if($2 > 65535 || $2 < -32768)
1491 yyerror("Stringtable entry's ID out of range (%d)", $2);
1492 /* Search for the ID */
1493 for(i = 0; i < tagstt->nentries; i++)
1494 {
1495 if(tagstt->entries[i].id == $2)
1496 yyerror("Stringtable ID %d already in use", $2);
1497 }
1498 /* If we get here, then we have a new unique entry */
1499 tagstt->nentries++;
1500 tagstt->entries = xrealloc(tagstt->entries, sizeof(tagstt->entries[0]) * tagstt->nentries);
1501 tagstt->entries[tagstt->nentries-1].id = $2;
1502 tagstt->entries[tagstt->nentries-1].str = $4;
1503 if(tagstt_memopt)
1504 tagstt->entries[tagstt->nentries-1].memopt = *tagstt_memopt;
1505 else
1506 tagstt->entries[tagstt->nentries-1].memopt = WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE | WRC_MO_PURE;
1507 tagstt->entries[tagstt->nentries-1].version = tagstt_version;
1508 tagstt->entries[tagstt->nentries-1].characts = tagstt_characts;
1509
1510 if(pedantic && !$4->size)
1511 yywarning("Zero length strings make no sense");
1512 if(!win32 && $4->size > 254)
1513 yyerror("Stringtable entry more than 254 characters");
1514 if(win32 && $4->size > 65534) /* Hmm..., does this happen? */
1515 yyerror("Stringtable entry more than 65534 characters (probably something else that went wrong)");
1516 $$ = tagstt;
1517 }
1518 ;
1519
1520 opt_comma /* There seem to be two ways to specify a stringtable... */
1521 : /* Empty */
1522 | ','
1523 ;
1524
1525 /* ------------------------------ VersionInfo ------------------------------ */
1526 versioninfo
1527 : tVERSIONINFO loadmemopts fix_version tBEGIN ver_blocks tEND {
1528 $$ = $3;
1529 if($2)
1530 {
1531 $$->memopt = *($2);
1532 free($2);
1533 }
1534 else
1535 $$->memopt = WRC_MO_MOVEABLE | (win32 ? WRC_MO_PURE : 0);
1536 $$->blocks = get_ver_block_head($5);
1537 /* Set language; there is no version or characteristics */
1538 $$->lvc.language = dup_language(currentlanguage);
1539 }
1540 ;
1541
1542 fix_version
1543 : /* Empty */ { $$ = new_versioninfo(); }
1544 | fix_version tFILEVERSION expr ',' expr ',' expr ',' expr {
1545 if($1->gotit.fv)
1546 yyerror("FILEVERSION already defined");
1547 $$ = $1;
1548 $$->filever_maj1 = $3;
1549 $$->filever_maj2 = $5;
1550 $$->filever_min1 = $7;
1551 $$->filever_min2 = $9;
1552 $$->gotit.fv = 1;
1553 }
1554 | fix_version tPRODUCTVERSION expr ',' expr ',' expr ',' expr {
1555 if($1->gotit.pv)
1556 yyerror("PRODUCTVERSION already defined");
1557 $$ = $1;
1558 $$->prodver_maj1 = $3;
1559 $$->prodver_maj2 = $5;
1560 $$->prodver_min1 = $7;
1561 $$->prodver_min2 = $9;
1562 $$->gotit.pv = 1;
1563 }
1564 | fix_version tFILEFLAGS expr {
1565 if($1->gotit.ff)
1566 yyerror("FILEFLAGS already defined");
1567 $$ = $1;
1568 $$->fileflags = $3;
1569 $$->gotit.ff = 1;
1570 }
1571 | fix_version tFILEFLAGSMASK expr {
1572 if($1->gotit.ffm)
1573 yyerror("FILEFLAGSMASK already defined");
1574 $$ = $1;
1575 $$->fileflagsmask = $3;
1576 $$->gotit.ffm = 1;
1577 }
1578 | fix_version tFILEOS expr {
1579 if($1->gotit.fo)
1580 yyerror("FILEOS already defined");
1581 $$ = $1;
1582 $$->fileos = $3;
1583 $$->gotit.fo = 1;
1584 }
1585 | fix_version tFILETYPE expr {
1586 if($1->gotit.ft)
1587 yyerror("FILETYPE already defined");
1588 $$ = $1;
1589 $$->filetype = $3;
1590 $$->gotit.ft = 1;
1591 }
1592 | fix_version tFILESUBTYPE expr {
1593 if($1->gotit.fst)
1594 yyerror("FILESUBTYPE already defined");
1595 $$ = $1;
1596 $$->filesubtype = $3;
1597 $$->gotit.fst = 1;
1598 }
1599 ;
1600
1601 ver_blocks
1602 : /* Empty */ { $$ = NULL; }
1603 | ver_blocks ver_block {
1604 $$ = $2;
1605 $$->prev = $1;
1606 if($1)
1607 $1->next = $$;
1608 }
1609 ;
1610
1611 ver_block
1612 : tBLOCK tSTRING tBEGIN ver_values tEND {
1613 $$ = new_ver_block();
1614 $$->name = $2;
1615 $$->values = get_ver_value_head($4);
1616 }
1617 ;
1618
1619 ver_values
1620 : /* Empty */ { $$ = NULL; }
1621 | ver_values ver_value {
1622 $$ = $2;
1623 $$->prev = $1;
1624 if($1)
1625 $1->next = $$;
1626 }
1627 ;
1628
1629 ver_value
1630 : ver_block {
1631 $$ = new_ver_value();
1632 $$->type = val_block;
1633 $$->value.block = $1;
1634 }
1635 | tVALUE tSTRING ',' tSTRING {
1636 $$ = new_ver_value();
1637 $$->type = val_str;
1638 $$->key = $2;
1639 $$->value.str = $4;
1640 }
1641 | tVALUE tSTRING ',' ver_words {
1642 $$ = new_ver_value();
1643 $$->type = val_words;
1644 $$->key = $2;
1645 $$->value.words = $4;
1646 }
1647 ;
1648
1649 ver_words
1650 : expr { $$ = new_ver_words($1); }
1651 | ver_words ',' expr { $$ = add_ver_words($1, $3); }
1652 ;
1653
1654 /* ------------------------------ Toolbar ------------------------------ */
1655 toolbar: tTOOLBAR loadmemopts expr ',' expr opt_lvc tBEGIN toolbar_items tEND {
1656 int nitems;
1657 toolbar_item_t *items = get_tlbr_buttons_head($8, &nitems);
1658 $$ = new_toolbar($3, $5, items, nitems);
1659 if($2)
1660 {
1661 $$->memopt = *($2);
1662 free($2);
1663 }
1664 else
1665 {
1666 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE;
1667 }
1668 if($6)
1669 {
1670 $$->lvc = *($6);
1671 free($6);
1672 }
1673 if(!$$->lvc.language)
1674 {
1675 $$->lvc.language = dup_language(currentlanguage);
1676 }
1677 }
1678 ;
1679
1680 toolbar_items
1681 : /* Empty */ { $$ = NULL; }
1682 | toolbar_items tBUTTON expr {
1683 toolbar_item_t *idrec = new_toolbar_item();
1684 idrec->id = $3;
1685 $$ = ins_tlbr_button($1, idrec);
1686 }
1687 | toolbar_items tSEPARATOR {
1688 toolbar_item_t *idrec = new_toolbar_item();
1689 idrec->id = 0;
1690 $$ = ins_tlbr_button($1, idrec);
1691 }
1692 ;
1693
1694 /* ------------------------------ Memory options ------------------------------ */
1695 loadmemopts
1696 : /* Empty */ { $$ = NULL; }
1697 | loadmemopts lamo {
1698 if($1)
1699 {
1700 *($1) |= *($2);
1701 $$ = $1;
1702 free($2);
1703 }
1704 else
1705 $$ = $2;
1706 }
1707 | loadmemopts lama {
1708 if($1)
1709 {
1710 *($1) &= *($2);
1711 $$ = $1;
1712 free($2);
1713 }
1714 else
1715 {
1716 *$2 &= WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE | WRC_MO_PURE;
1717 $$ = $2;
1718 }
1719 }
1720 ;
1721
1722 lamo : tPRELOAD { $$ = new_int(WRC_MO_PRELOAD); }
1723 | tMOVEABLE { $$ = new_int(WRC_MO_MOVEABLE); }
1724 | tDISCARDABLE { $$ = new_int(WRC_MO_DISCARDABLE); }
1725 | tPURE { $$ = new_int(WRC_MO_PURE); }
1726 ;
1727
1728 lama : tLOADONCALL { $$ = new_int(~WRC_MO_PRELOAD); }
1729 | tFIXED { $$ = new_int(~WRC_MO_MOVEABLE); }
1730 | tIMPURE { $$ = new_int(~WRC_MO_PURE); }
1731 ;
1732
1733 /* ------------------------------ Win32 options ------------------------------ */
1734 opt_lvc : /* Empty */ { $$ = new_lvc(); }
1735 | opt_lvc opt_language {
1736 if(!win32)
1737 yywarning("LANGUAGE not supported in 16-bit mode");
1738 if($1->language)
1739 yyerror("Language already defined");
1740 $$ = $1;
1741 $1->language = $2;
1742 }
1743 | opt_lvc opt_characts {
1744 if(!win32)
1745 yywarning("CHARACTERISTICS not supported in 16-bit mode");
1746 if($1->characts)
1747 yyerror("Characteristics already defined");
1748 $$ = $1;
1749 $1->characts = $2;
1750 }
1751 | opt_lvc opt_version {
1752 if(!win32)
1753 yywarning("VERSION not supported in 16-bit mode");
1754 if($1->version)
1755 yyerror("Version already defined");
1756 $$ = $1;
1757 $1->version = $2;
1758 }
1759 ;
1760
1761 /*
1762 * This here is another s/r conflict on {bi,u}nary + and -.
1763 * It is due to the look-ahead which must determine when the
1764 * rule opt_language ends. It could be solved with adding a
1765 * tNL at the end, but that seems unreasonable to do.
1766 * The conflict is now moved to the expression handling below.
1767 */
1768 opt_language
1769 : tLANGUAGE expr ',' expr { $$ = new_language($2, $4);
1770 if (get_language_codepage($2, $4) == -1)
1771 yyerror( "Language %04x is not supported", ($4<<10) + $2);
1772 }
1773 ;
1774
1775 opt_characts
1776 : tCHARACTERISTICS expr { $$ = new_characts($2); }
1777 ;
1778
1779 opt_version
1780 : tVERSION expr { $$ = new_version($2); }
1781 ;
1782
1783 /* ------------------------------ Raw data handling ------------------------------ */
1784 raw_data: opt_lvc tBEGIN raw_elements tEND {
1785 if($1)
1786 {
1787 $3->lvc = *($1);
1788 free($1);
1789 }
1790
1791 if(!$3->lvc.language)
1792 $3->lvc.language = dup_language(currentlanguage);
1793
1794 $$ = $3;
1795 }
1796 ;
1797
1798 raw_elements
1799 : tRAWDATA { $$ = $1; }
1800 | tNUMBER { $$ = int2raw_data($1); }
1801 | '-' tNUMBER { $$ = int2raw_data(-($2)); }
1802 | tLNUMBER { $$ = long2raw_data($1); }
1803 | '-' tLNUMBER { $$ = long2raw_data(-($2)); }
1804 | tSTRING { $$ = str2raw_data($1); }
1805 | raw_elements opt_comma tRAWDATA { $$ = merge_raw_data($1, $3); free($3->data); free($3); }
1806 | raw_elements opt_comma tNUMBER { $$ = merge_raw_data_int($1, $3); }
1807 | raw_elements opt_comma '-' tNUMBER { $$ = merge_raw_data_int($1, -($4)); }
1808 | raw_elements opt_comma tLNUMBER { $$ = merge_raw_data_long($1, $3); }
1809 | raw_elements opt_comma '-' tLNUMBER { $$ = merge_raw_data_long($1, -($4)); }
1810 | raw_elements opt_comma tSTRING { $$ = merge_raw_data_str($1, $3); }
1811 ;
1812
1813 /* File data or raw data */
1814 file_raw: filename { $$ = load_file($1,dup_language(currentlanguage)); }
1815 | raw_data { $$ = $1; }
1816 ;
1817
1818 /* ------------------------------ Win32 expressions ------------------------------ */
1819 /* All win16 numbers are also handled here. This is inconsistent with MS'
1820 * resource compiler, but what the heck, its just handy to have.
1821 */
1822 e_expr : /* Empty */ { $$ = 0; }
1823 | expr { $$ = new_int($1); }
1824 ;
1825
1826 /* This rule moves ALL s/r conflicts on {bi,u}nary - and + to here */
1827 expr : xpr { $$ = ($1); }
1828 ;
1829
1830 xpr : xpr '+' xpr { $$ = ($1) + ($3); }
1831 | xpr '-' xpr { $$ = ($1) - ($3); }
1832 | xpr '|' xpr { $$ = ($1) | ($3); }
1833 | xpr '&' xpr { $$ = ($1) & ($3); }
1834 | xpr '*' xpr { $$ = ($1) * ($3); }
1835 | xpr '/' xpr { $$ = ($1) / ($3); }
1836 | xpr '^' xpr { $$ = ($1) ^ ($3); }
1837 | '~' xpr { $$ = ~($2); }
1838 | '-' xpr %prec pUPM { $$ = -($2); }
1839 | '+' xpr %prec pUPM { $$ = $2; }
1840 | '(' xpr ')' { $$ = $2; }
1841 | any_num { $$ = $1; }
1842 | tNOT any_num { $$ = ~($2); }
1843 ;
1844
1845 any_num : tNUMBER { $$ = $1; }
1846 | tLNUMBER { $$ = $1; }
1847 ;
1848
1849 %%
1850 /* Dialog specific functions */
1851 static dialog_t *dialog_style(style_t * st, dialog_t *dlg)
1852 {
1853 assert(dlg != NULL);
1854 if(dlg->style == NULL)
1855 {
1856 dlg->style = new_style(0,0);
1857 }
1858
1859 if(dlg->gotstyle)
1860 {
1861 yywarning("Style already defined, or-ing together");
1862 }
1863 else
1864 {
1865 dlg->style->or_mask = 0;
1866 dlg->style->and_mask = 0;
1867 }
1868 dlg->style->or_mask |= st->or_mask;
1869 dlg->style->and_mask |= st->and_mask;
1870 dlg->gotstyle = TRUE;
1871 free(st);
1872 return dlg;
1873 }
1874
1875 static dialog_t *dialog_exstyle(style_t *st, dialog_t *dlg)
1876 {
1877 assert(dlg != NULL);
1878 if(dlg->exstyle == NULL)
1879 {
1880 dlg->exstyle = new_style(0,0);
1881 }
1882
1883 if(dlg->gotexstyle)
1884 {
1885 yywarning("ExStyle already defined, or-ing together");
1886 }
1887 else
1888 {
1889 dlg->exstyle->or_mask = 0;
1890 dlg->exstyle->and_mask = 0;
1891 }
1892 dlg->exstyle->or_mask |= st->or_mask;
1893 dlg->exstyle->and_mask |= st->and_mask;
1894 dlg->gotexstyle = TRUE;
1895 free(st);
1896 return dlg;
1897 }
1898
1899 static dialog_t *dialog_caption(string_t *s, dialog_t *dlg)
1900 {
1901 assert(dlg != NULL);
1902 if(dlg->title)
1903 yyerror("Caption already defined");
1904 dlg->title = s;
1905 return dlg;
1906 }
1907
1908 static dialog_t *dialog_font(font_id_t *f, dialog_t *dlg)
1909 {
1910 assert(dlg != NULL);
1911 if(dlg->font)
1912 yyerror("Font already defined");
1913 dlg->font = f;
1914 return dlg;
1915 }
1916
1917 static dialog_t *dialog_class(name_id_t *n, dialog_t *dlg)
1918 {
1919 assert(dlg != NULL);
1920 if(dlg->dlgclass)
1921 yyerror("Class already defined");
1922 dlg->dlgclass = n;
1923 return dlg;
1924 }
1925
1926 static dialog_t *dialog_menu(name_id_t *m, dialog_t *dlg)
1927 {
1928 assert(dlg != NULL);
1929 if(dlg->menu)
1930 yyerror("Menu already defined");
1931 dlg->menu = m;
1932 return dlg;
1933 }
1934
1935 static dialog_t *dialog_language(language_t *l, dialog_t *dlg)
1936 {
1937 assert(dlg != NULL);
1938 if(dlg->lvc.language)
1939 yyerror("Language already defined");
1940 dlg->lvc.language = l;
1941 return dlg;
1942 }
1943
1944 static dialog_t *dialog_characteristics(characts_t *c, dialog_t *dlg)
1945 {
1946 assert(dlg != NULL);
1947 if(dlg->lvc.characts)
1948 yyerror("Characteristics already defined");
1949 dlg->lvc.characts = c;
1950 return dlg;
1951 }
1952
1953 static dialog_t *dialog_version(version_t *v, dialog_t *dlg)
1954 {
1955 assert(dlg != NULL);
1956 if(dlg->lvc.version)
1957 yyerror("Version already defined");
1958 dlg->lvc.version = v;
1959 return dlg;
1960 }
1961
1962 /* Controls specific functions */
1963 static control_t *ins_ctrl(int type, int special_style, control_t *ctrl, control_t *prev)
1964 {
1965 /* Hm... this seems to be jammed in at all time... */
1966 int defaultstyle = WS_CHILD | WS_VISIBLE;
1967
1968 assert(ctrl != NULL);
1969 ctrl->prev = prev;
1970
1971 if(prev)
1972 prev->next = ctrl;
1973
1974 if(type != -1)
1975 {
1976 ctrl->ctlclass = new_name_id();
1977 ctrl->ctlclass->type = name_ord;
1978 ctrl->ctlclass->name.i_name = type;
1979 }
1980
1981 switch(type)
1982 {
1983 case CT_BUTTON:
1984 if(special_style != BS_GROUPBOX && special_style != BS_RADIOBUTTON)
1985 defaultstyle |= WS_TABSTOP;
1986 break;
1987 case CT_EDIT:
1988 defaultstyle |= WS_TABSTOP | WS_BORDER;
1989 break;
1990 case CT_LISTBOX:
1991 defaultstyle |= LBS_NOTIFY | WS_BORDER;
1992 break;
1993 case CT_COMBOBOX:
1994 if (!(ctrl->style->or_mask & (CBS_SIMPLE | CBS_DROPDOWN | CBS_DROPDOWNLIST)))
1995 defaultstyle |= CBS_SIMPLE;
1996 break;
1997 case CT_STATIC:
1998 if(special_style == SS_CENTER || special_style == SS_LEFT || special_style == SS_RIGHT)
1999 defaultstyle |= WS_GROUP;
2000 break;
2001 }
2002
2003 if(!ctrl->gotstyle) /* Handle default style setting */
2004 {
2005 switch(type)
2006 {
2007 case CT_EDIT:
2008 defaultstyle |= ES_LEFT;
2009 break;
2010 case CT_LISTBOX:
2011 defaultstyle |= LBS_NOTIFY;
2012 break;
2013 case CT_COMBOBOX:
2014 defaultstyle |= CBS_SIMPLE | WS_TABSTOP;
2015 break;
2016 case CT_SCROLLBAR:
2017 defaultstyle |= SBS_HORZ;
2018 break;
2019 case CT_BUTTON:
2020 switch(special_style)
2021 {
2022 case BS_CHECKBOX:
2023 case BS_DEFPUSHBUTTON:
2024 case BS_PUSHBUTTON:
2025 /* case BS_PUSHBOX: */
2026 case BS_AUTORADIOBUTTON:
2027 case BS_AUTO3STATE:
2028 case BS_3STATE:
2029 case BS_AUTOCHECKBOX:
2030 defaultstyle |= WS_TABSTOP;
2031 break;
2032 default:
2033 yywarning("Unknown default button control-style 0x%08x", special_style);
2034 case BS_GROUPBOX:
2035 case BS_RADIOBUTTON:
2036 break;
2037 }
2038 break;
2039
2040 case CT_STATIC:
2041 switch(special_style)
2042 {
2043 case SS_LEFT:
2044 case SS_RIGHT:
2045 case SS_CENTER:
2046 defaultstyle |= WS_GROUP;
2047 break;
2048 case SS_ICON: /* Special case */
2049 break;
2050 default:
2051 yywarning("Unknown default static control-style 0x%08x", special_style);
2052 break;
2053 }
2054 break;
2055 case -1: /* Generic control */
2056 goto byebye;
2057
2058 default:
2059 yyerror("Internal error (report this): Got weird control type 0x%08x", type);
2060 }
2061 }
2062
2063 /* The SS_ICON flag is always forced in for icon controls */
2064 if(type == CT_STATIC && special_style == SS_ICON)
2065 defaultstyle |= SS_ICON;
2066
2067 if (!ctrl->gotstyle)
2068 ctrl->style = new_style(0,0);
2069
2070 /* combine all styles */
2071 ctrl->style->or_mask = ctrl->style->or_mask | defaultstyle | special_style;
2072 ctrl->gotstyle = TRUE;
2073 byebye:
2074 /* combine with NOT mask */
2075 if (ctrl->gotstyle)
2076 {
2077 ctrl->style->or_mask &= ~(ctrl->style->and_mask);
2078 ctrl->style->and_mask = 0;
2079 }
2080 if (ctrl->gotexstyle)
2081 {
2082 ctrl->exstyle->or_mask &= ~(ctrl->exstyle->and_mask);
2083 ctrl->exstyle->and_mask = 0;
2084 }
2085 return ctrl;
2086 }
2087
2088 static name_id_t *convert_ctlclass(name_id_t *cls)
2089 {
2090 char *cc = NULL;
2091 int iclass;
2092
2093 if(cls->type == name_ord)
2094 return cls;
2095 assert(cls->type == name_str);
2096 if(cls->type == str_unicode)
2097 {
2098 yyerror("Don't yet support unicode class comparison");
2099 }
2100 else
2101 cc = cls->name.s_name->str.cstr;
2102
2103 if(!strcasecmp("BUTTON", cc))
2104 iclass = CT_BUTTON;
2105 else if(!strcasecmp("COMBOBOX", cc))
2106 iclass = CT_COMBOBOX;
2107 else if(!strcasecmp("LISTBOX", cc))
2108 iclass = CT_LISTBOX;
2109 else if(!strcasecmp("EDIT", cc))
2110 iclass = CT_EDIT;
2111 else if(!strcasecmp("STATIC", cc))
2112 iclass = CT_STATIC;
2113 else if(!strcasecmp("SCROLLBAR", cc))
2114 iclass = CT_SCROLLBAR;
2115 else
2116 return cls; /* No default, return user controlclass */
2117
2118 free(cls->name.s_name->str.cstr);
2119 free(cls->name.s_name);
2120 cls->type = name_ord;
2121 cls->name.i_name = iclass;
2122 return cls;
2123 }
2124
2125 /* DialogEx specific functions */
2126 static dialogex_t *dialogex_style(style_t * st, dialogex_t *dlg)
2127 {
2128 assert(dlg != NULL);
2129 if(dlg->style == NULL)
2130 {
2131 dlg->style = new_style(0,0);
2132 }
2133
2134 if(dlg->gotstyle)
2135 {
2136 yywarning("Style already defined, or-ing together");
2137 }
2138 else
2139 {
2140 dlg->style->or_mask = 0;
2141 dlg->style->and_mask = 0;
2142 }
2143 dlg->style->or_mask |= st->or_mask;
2144 dlg->style->and_mask |= st->and_mask;
2145 dlg->gotstyle = TRUE;
2146 free(st);
2147 return dlg;
2148 }
2149
2150 static dialogex_t *dialogex_exstyle(style_t * st, dialogex_t *dlg)
2151 {
2152 assert(dlg != NULL);
2153 if(dlg->exstyle == NULL)
2154 {
2155 dlg->exstyle = new_style(0,0);
2156 }
2157
2158 if(dlg->gotexstyle)
2159 {
2160 yywarning("ExStyle already defined, or-ing together");
2161 }
2162 else
2163 {
2164 dlg->exstyle->or_mask = 0;
2165 dlg->exstyle->and_mask = 0;
2166 }
2167 dlg->exstyle->or_mask |= st->or_mask;
2168 dlg->exstyle->and_mask |= st->and_mask;
2169 dlg->gotexstyle = TRUE;
2170 free(st);
2171 return dlg;
2172 }
2173
2174 static dialogex_t *dialogex_caption(string_t *s, dialogex_t *dlg)
2175 {
2176 assert(dlg != NULL);
2177 if(dlg->title)
2178 yyerror("Caption already defined");
2179 dlg->title = s;
2180 return dlg;
2181 }
2182
2183 static dialogex_t *dialogex_font(font_id_t *f, dialogex_t *dlg)
2184 {
2185 assert(dlg != NULL);
2186 if(dlg->font)
2187 yyerror("Font already defined");
2188 dlg->font = f;
2189 return dlg;
2190 }
2191
2192 static dialogex_t *dialogex_class(name_id_t *n, dialogex_t *dlg)
2193 {
2194 assert(dlg != NULL);
2195 if(dlg->dlgclass)
2196 yyerror("Class already defined");
2197 dlg->dlgclass = n;
2198 return dlg;
2199 }
2200
2201 static dialogex_t *dialogex_menu(name_id_t *m, dialogex_t *dlg)
2202 {
2203 assert(dlg != NULL);
2204 if(dlg->menu)
2205 yyerror("Menu already defined");
2206 dlg->menu = m;
2207 return dlg;
2208 }
2209
2210 static dialogex_t *dialogex_language(language_t *l, dialogex_t *dlg)
2211 {
2212 assert(dlg != NULL);
2213 if(dlg->lvc.language)
2214 yyerror("Language already defined");
2215 dlg->lvc.language = l;
2216 return dlg;
2217 }
2218
2219 static dialogex_t *dialogex_characteristics(characts_t *c, dialogex_t *dlg)
2220 {
2221 assert(dlg != NULL);
2222 if(dlg->lvc.characts)
2223 yyerror("Characteristics already defined");
2224 dlg->lvc.characts = c;
2225 return dlg;
2226 }
2227
2228 static dialogex_t *dialogex_version(version_t *v, dialogex_t *dlg)
2229 {
2230 assert(dlg != NULL);
2231 if(dlg->lvc.version)
2232 yyerror("Version already defined");
2233 dlg->lvc.version = v;
2234 return dlg;
2235 }
2236
2237 /* Accelerator specific functions */
2238 static event_t *add_event(int key, int id, int flags, event_t *prev)
2239 {
2240 event_t *ev = new_event();
2241
2242 if((flags & (WRC_AF_VIRTKEY | WRC_AF_ASCII)) == (WRC_AF_VIRTKEY | WRC_AF_ASCII))
2243 yyerror("Cannot use both ASCII and VIRTKEY");
2244
2245 ev->key = key;
2246 ev->id = id;
2247 ev->flags = flags & ~WRC_AF_ASCII;
2248 ev->prev = prev;
2249 if(prev)
2250 prev->next = ev;
2251 return ev;
2252 }
2253
2254 static event_t *add_string_event(string_t *key, int id, int flags, event_t *prev)
2255 {
2256 int keycode = 0;
2257 event_t *ev = new_event();
2258
2259 if(key->type != str_char)
2260 yyerror("Key code must be an ascii string");
2261
2262 if((flags & WRC_AF_VIRTKEY) && (!isupper(key->str.cstr[0] & 0xff) && !isdigit(key->str.cstr[0] & 0xff)))
2263 yyerror("VIRTKEY code is not equal to ascii value");
2264
2265 if(key->str.cstr[0] == '^' && (flags & WRC_AF_CONTROL) != 0)
2266 {
2267 yyerror("Cannot use both '^' and CONTROL modifier");
2268 }
2269 else if(key->str.cstr[0] == '^')
2270 {
2271 keycode = toupper(key->str.cstr[1]) - '@';
2272 if(keycode >= ' ')
2273 yyerror("Control-code out of range");
2274 }
2275 else
2276 keycode = key->str.cstr[0];
2277 ev->key = keycode;
2278 ev->id = id;
2279 ev->flags = flags & ~WRC_AF_ASCII;
2280 ev->prev = prev;
2281 if(prev)
2282 prev->next = ev;
2283 return ev;
2284 }
2285
2286 /* MenuEx specific functions */
2287 static itemex_opt_t *new_itemex_opt(int id, int type, int state, int helpid)
2288 {
2289 itemex_opt_t *opt = (itemex_opt_t *)xmalloc(sizeof(itemex_opt_t));
2290 opt->id = id;
2291 opt->type = type;
2292 opt->state = state;
2293 opt->helpid = helpid;
2294 return opt;
2295 }
2296
2297 /* Raw data functions */
2298 static raw_data_t *load_file(string_t *filename, language_t *lang)
2299 {
2300 FILE *fp = NULL;
2301 char *path;
2302 raw_data_t *rd;
2303 string_t *name;
2304 int codepage = get_language_codepage(lang->id, lang->sub);
2305
2306 /* FIXME: we may want to use utf-8 here */
2307 if (codepage <= 0 && filename->type != str_char)
2308 yyerror("Cannot convert filename to ASCII string");
2309 name = convert_string( filename, str_char, codepage );
2310 if (!(path = wpp_find_include(name->str.cstr, input_name)))
2311 yyerror("Cannot open file %s", name->str.cstr);
2312 if (!(fp = fopen( path, "rb" )))
2313 yyerror("Cannot open file %s", name->str.cstr);
2314 free( path );
2315 rd = new_raw_data();
2316 fseek(fp, 0, SEEK_END);
2317 rd->size = ftell(fp);
2318 fseek(fp, 0, SEEK_SET);
2319 if (rd->size)
2320 {
2321 rd->data = (char *)xmalloc(rd->size);
2322 fread(rd->data, rd->size, 1, fp);
2323 }
2324 else rd->data = NULL;
2325 fclose(fp);
2326 rd->lvc.language = lang;
2327 free_string(name);
2328 return rd;
2329 }
2330
2331 static raw_data_t *int2raw_data(int i)
2332 {
2333 raw_data_t *rd;
2334
2335 if( ( i >= 0 && (int)((unsigned short)i) != i) ||
2336 ( i < 0 && (int)((short)i) != i) )
2337 yywarning("Integer constant out of 16bit range (%d), truncated to %d\n", i, (short)i);
2338
2339 rd = new_raw_data();
2340 rd->size = sizeof(short);
2341 rd->data = (char *)xmalloc(rd->size);
2342 switch(byteorder)
2343 {
2344 #ifdef WORDS_BIGENDIAN
2345 default:
2346 #endif
2347 case WRC_BO_BIG:
2348 rd->data[0] = HIBYTE(i);
2349 rd->data[1] = LOBYTE(i);
2350 break;
2351
2352 #ifndef WORDS_BIGENDIAN
2353 default:
2354 #endif
2355 case WRC_BO_LITTLE:
2356 rd->data[1] = HIBYTE(i);
2357 rd->data[0] = LOBYTE(i);
2358 break;
2359 }
2360 return rd;
2361 }
2362
2363 static raw_data_t *long2raw_data(int i)
2364 {
2365 raw_data_t *rd;
2366 rd = new_raw_data();
2367 rd->size = sizeof(int);
2368 rd->data = (char *)xmalloc(rd->size);
2369 switch(byteorder)
2370 {
2371 #ifdef WORDS_BIGENDIAN
2372 default:
2373 #endif
2374 case WRC_BO_BIG:
2375 rd->data[0] = HIBYTE(HIWORD(i));
2376 rd->data[1] = LOBYTE(HIWORD(i));
2377 rd->data[2] = HIBYTE(LOWORD(i));
2378 rd->data[3] = LOBYTE(LOWORD(i));
2379 break;
2380
2381 #ifndef WORDS_BIGENDIAN
2382 default:
2383 #endif
2384 case WRC_BO_LITTLE:
2385 rd->data[3] = HIBYTE(HIWORD(i));
2386 rd->data[2] = LOBYTE(HIWORD(i));
2387 rd->data[1] = HIBYTE(LOWORD(i));
2388 rd->data[0] = LOBYTE(LOWORD(i));
2389 break;
2390 }
2391 return rd;
2392 }
2393
2394 static raw_data_t *str2raw_data(string_t *str)
2395 {
2396 raw_data_t *rd;
2397 rd = new_raw_data();
2398 rd->size = str->size * (str->type == str_char ? 1 : 2);
2399 rd->data = (char *)xmalloc(rd->size);
2400 if(str->type == str_char)
2401 memcpy(rd->data, str->str.cstr, rd->size);
2402 else if(str->type == str_unicode)
2403 {
2404 int i;
2405 switch(byteorder)
2406 {
2407 #ifdef WORDS_BIGENDIAN
2408 default:
2409 #endif
2410 case WRC_BO_BIG:
2411 for(i = 0; i < str->size; i++)
2412 {
2413 rd->data[2*i + 0] = HIBYTE((WORD)str->str.wstr[i]);
2414 rd->data[2*i + 1] = LOBYTE((WORD)str->str.wstr[i]);
2415 }
2416 break;
2417 #ifndef WORDS_BIGENDIAN
2418 default:
2419 #endif
2420 case WRC_BO_LITTLE:
2421 for(i = 0; i < str->size; i++)
2422 {
2423 rd->data[2*i + 1] = HIBYTE((WORD)str->str.wstr[i]);
2424 rd->data[2*i + 0] = LOBYTE((WORD)str->str.wstr[i]);
2425 }
2426 break;
2427 }
2428 }
2429 else
2430 internal_error(__FILE__, __LINE__, "Invalid stringtype");
2431 return rd;
2432 }
2433
2434 static raw_data_t *merge_raw_data(raw_data_t *r1, raw_data_t *r2)
2435 {
2436 r1->data = xrealloc(r1->data, r1->size + r2->size);
2437 memcpy(r1->data + r1->size, r2->data, r2->size);
2438 r1->size += r2->size;
2439 return r1;
2440 }
2441
2442 static raw_data_t *merge_raw_data_int(raw_data_t *r1, int i)
2443 {
2444 raw_data_t *t = int2raw_data(i);
2445 merge_raw_data(r1, t);
2446 free(t->data);
2447 free(t);
2448 return r1;
2449 }
2450
2451 static raw_data_t *merge_raw_data_long(raw_data_t *r1, int i)
2452 {
2453 raw_data_t *t = long2raw_data(i);
2454 merge_raw_data(r1, t);
2455 free(t->data);
2456 free(t);
2457 return r1;
2458 }
2459
2460 static raw_data_t *merge_raw_data_str(raw_data_t *r1, string_t *str)
2461 {
2462 raw_data_t *t = str2raw_data(str);
2463 merge_raw_data(r1, t);
2464 free(t->data);
2465 free(t);
2466 return r1;
2467 }
2468
2469 /* Function the go back in a list to get the head */
2470 static menu_item_t *get_item_head(menu_item_t *p)
2471 {
2472 if(!p)
2473 return NULL;
2474 while(p->prev)
2475 p = p->prev;
2476 return p;
2477 }
2478
2479 static menuex_item_t *get_itemex_head(menuex_item_t *p)
2480 {
2481 if(!p)
2482 return NULL;
2483 while(p->prev)
2484 p = p->prev;
2485 return p;
2486 }
2487
2488 static resource_t *get_resource_head(resource_t *p)
2489 {
2490 if(!p)
2491 return NULL;
2492 while(p->prev)
2493 p = p->prev;
2494 return p;
2495 }
2496
2497 static ver_block_t *get_ver_block_head(ver_block_t *p)
2498 {
2499 if(!p)
2500 return NULL;
2501 while(p->prev)
2502 p = p->prev;
2503 return p;
2504 }
2505
2506 static ver_value_t *get_ver_value_head(ver_value_t *p)
2507 {
2508 if(!p)
2509 return NULL;
2510 while(p->prev)
2511 p = p->prev;
2512 return p;
2513 }
2514
2515 static control_t *get_control_head(control_t *p)
2516 {
2517 if(!p)
2518 return NULL;
2519 while(p->prev)
2520 p = p->prev;
2521 return p;
2522 }
2523
2524 static event_t *get_event_head(event_t *p)
2525 {
2526 if(!p)
2527 return NULL;
2528 while(p->prev)
2529 p = p->prev;
2530 return p;
2531 }
2532
2533 /* Find a stringtable with given language */
2534 static stringtable_t *find_stringtable(lvc_t *lvc)
2535 {
2536 stringtable_t *stt;
2537
2538 assert(lvc != NULL);
2539
2540 if(!lvc->language)
2541 lvc->language = dup_language(currentlanguage);
2542
2543 for(stt = sttres; stt; stt = stt->next)
2544 {
2545 if(stt->lvc.language->id == lvc->language->id
2546 && stt->lvc.language->sub == lvc->language->sub)
2547 {
2548 /* Found a table with the same language */
2549 /* The version and characteristics are now handled
2550 * in the generation of the individual stringtables.
2551 * This enables localized analysis.
2552 if((stt->lvc.version && lvc->version && *(stt->lvc.version) != *(lvc->version))
2553 || (!stt->lvc.version && lvc->version)
2554 || (stt->lvc.version && !lvc->version))
2555 yywarning("Stringtable's versions are not the same, using first definition");
2556
2557 if((stt->lvc.characts && lvc->characts && *(stt->lvc.characts) != *(lvc->characts))
2558 || (!stt->lvc.characts && lvc->characts)
2559 || (stt->lvc.characts && !lvc->characts))
2560 yywarning("Stringtable's characteristics are not the same, using first definition");
2561 */
2562 return stt;
2563 }
2564 }
2565 return NULL;
2566 }
2567
2568 /* qsort sorting function for string table entries */
2569 #define STE(p) ((const stt_entry_t *)(p))
2570 static int sort_stt_entry(const void *e1, const void *e2)
2571 {
2572 return STE(e1)->id - STE(e2)->id;
2573 }
2574 #undef STE
2575
2576 static resource_t *build_stt_resources(stringtable_t *stthead)
2577 {
2578 stringtable_t *stt;
2579 stringtable_t *newstt;
2580 resource_t *rsc;
2581 resource_t *rsclist = NULL;
2582 resource_t *rsctail = NULL;
2583 int i;
2584 int j;
2585 DWORD andsum;
2586 DWORD orsum;
2587 characts_t *characts;
2588 version_t *version;
2589
2590 if(!stthead)
2591 return NULL;
2592
2593 /* For all languages defined */
2594 for(stt = stthead; stt; stt = stt->next)
2595 {
2596 assert(stt->nentries > 0);
2597
2598 /* Sort the entries */
2599 if(stt->nentries > 1)
2600 qsort(stt->entries, stt->nentries, sizeof(stt->entries[0]), sort_stt_entry);
2601
2602 for(i = 0; i < stt->nentries; )
2603 {
2604 newstt = new_stringtable(&stt->lvc);
2605 newstt->entries = (stt_entry_t *)xmalloc(16 * sizeof(stt_entry_t));
2606 newstt->nentries = 16;
2607 newstt->idbase = stt->entries[i].id & ~0xf;
2608 for(j = 0; j < 16 && i < stt->nentries; j++)
2609 {
2610 if(stt->entries[i].id - newstt->idbase == j)
2611 {
2612 newstt->entries[j] = stt->entries[i];
2613 i++;
2614 }
2615 }
2616 andsum = ~0;
2617 orsum = 0;
2618 characts = NULL;
2619 version = NULL;
2620 /* Check individual memory options and get
2621 * the first characteristics/version
2622 */
2623 for(j = 0; j < 16; j++)
2624 {
2625 if(!newstt->entries[j].str)
2626 continue;
2627 andsum &= newstt->entries[j].memopt;
2628 orsum |= newstt->entries[j].memopt;
2629 if(!characts)
2630 characts = newstt->entries[j].characts;
2631 if(!version)
2632 version = newstt->entries[j].version;
2633 }
2634 if(andsum != orsum)
2635 {
2636 warning("Stringtable's memory options are not equal (idbase: %d)", newstt->idbase);
2637 }
2638 /* Check version and characteristics */
2639 for(j = 0; j < 16; j++)
2640 {
2641 if(characts
2642 && newstt->entries[j].characts
2643 && *newstt->entries[j].characts != *characts)
2644 warning("Stringtable's characteristics are not the same (idbase: %d)", newstt->idbase);
2645 if(version
2646 && newstt->entries[j].version
2647 && *newstt->entries[j].version != *version)
2648 warning("Stringtable's versions are not the same (idbase: %d)", newstt->idbase);
2649 }
2650 rsc = new_resource(res_stt, newstt, newstt->memopt, newstt->lvc.language);
2651 rsc->name = new_name_id();
2652 rsc->name->type = name_ord;
2653 rsc->name->name.i_name = (newstt->idbase >> 4) + 1;
2654 rsc->memopt = andsum; /* Set to least common denominator */
2655 newstt->memopt = andsum;
2656 newstt->lvc.characts = characts;
2657 newstt->lvc.version = version;
2658 if(!rsclist)
2659 {
2660 rsclist = rsc;
2661 rsctail = rsc;
2662 }
2663 else
2664 {
2665 rsctail->next = rsc;
2666 rsc->prev = rsctail;
2667 rsctail = rsc;
2668 }
2669 }
2670 }
2671 return rsclist;
2672 }
2673
2674
2675 static toolbar_item_t *ins_tlbr_button(toolbar_item_t *prev, toolbar_item_t *idrec)
2676 {
2677 idrec->prev = prev;
2678 if(prev)
2679 prev->next = idrec;
2680
2681 return idrec;
2682 }
2683
2684 static toolbar_item_t *get_tlbr_buttons_head(toolbar_item_t *p, int *nitems)
2685 {
2686 if(!p)
2687 {
2688 *nitems = 0;
2689 return NULL;
2690 }
2691
2692 *nitems = 1;
2693
2694 while(p->prev)
2695 {
2696 (*nitems)++;
2697 p = p->prev;
2698 }
2699
2700 return p;
2701 }
2702
2703 static string_t *make_filename(string_t *str)
2704 {
2705 if(str->type == str_char)
2706 {
2707 char *cptr;
2708
2709 /* Remove escaped backslash and convert to forward */
2710 for(cptr = str->str.cstr; (cptr = strchr(cptr, '\\')) != NULL; cptr++)
2711 {
2712 if(cptr[1] == '\\')
2713 {
2714 memmove(cptr, cptr+1, strlen(cptr));
2715 str->size--;
2716 }
2717 *cptr = '/';
2718 }
2719 }
2720 else
2721 {
2722 WCHAR *wptr;
2723
2724 /* Remove escaped backslash and convert to forward */
2725 for(wptr = str->str.wstr; (wptr = strchrW(wptr, '\\')) != NULL; wptr++)
2726 {
2727 if(wptr[1] == '\\')
2728 {
2729 memmove(wptr, wptr+1, strlenW(wptr));
2730 str->size--;
2731 }
2732 *wptr = '/';
2733 }
2734 }
2735 return str;
2736 }
2737
2738 /*
2739 * Process all resources to extract fonts and build
2740 * a fontdir resource.
2741 *
2742 * Note: MS' resource compiler (build 1472) does not
2743 * handle font resources with different languages.
2744 * The fontdir is generated in the last active language
2745 * and font identifiers must be unique across the entire
2746 * source.
2747 * This is not logical considering the localization
2748 * constraints of all other resource types. MS has,
2749 * most probably, never testet localized fonts. However,
2750 * using fontresources is rare, so it might not occur
2751 * in normal applications.
2752 * Wine does require better localization because a lot
2753 * of languages are coded into the same executable.
2754 * Therefore, I will generate fontdirs for *each*
2755 * localized set of fonts.
2756 */
2757 static resource_t *build_fontdir(resource_t **fnt, int nfnt)
2758 {
2759 static int once = 0;
2760 if(!once)
2761 {
2762 warning("Need to parse fonts, not yet implemented (fnt: %p, nfnt: %d)", fnt, nfnt);
2763 once++;
2764 }
2765 return NULL;
2766 }
2767
2768 static resource_t *build_fontdirs(resource_t *tail)
2769 {
2770 resource_t *rsc;
2771 resource_t *lst = NULL;
2772 resource_t **fnt = NULL; /* List of all fonts */
2773 int nfnt = 0;
2774 resource_t **fnd = NULL; /* List of all fontdirs */
2775 int nfnd = 0;
2776 resource_t **lanfnt = NULL;
2777 int nlanfnt = 0;
2778 int i;
2779 name_id_t nid;
2780 string_t str;
2781 int fntleft;
2782
2783 nid.type = name_str;
2784 nid.name.s_name = &str;
2785 str.type = str_char;
2786 str.str.cstr = xstrdup("FONTDIR");
2787 str.size = 7;
2788
2789 /* Extract all fonts and fontdirs */
2790 for(rsc = tail; rsc; rsc = rsc->prev)
2791 {
2792 if(rsc->type == res_fnt)
2793 {
2794 nfnt++;
2795 fnt = xrealloc(fnt, nfnt * sizeof(*fnt));
2796 fnt[nfnt-1] = rsc;
2797 }
2798 else if(rsc->type == res_fntdir)
2799 {
2800 nfnd++;
2801 fnd = xrealloc(fnd, nfnd * sizeof(*fnd));
2802 fnd[nfnd-1] = rsc;
2803 }
2804 }
2805
2806 /* Verify the name of the present fontdirs */
2807 for(i = 0; i < nfnd; i++)
2808 {
2809 if(compare_name_id(&nid, fnd[i]->name))
2810 {
2811 warning("User supplied FONTDIR entry has an invalid name '%s', ignored",
2812 get_nameid_str(fnd[i]->name));
2813 fnd[i] = NULL;
2814 }
2815 }
2816
2817 /* Sanity check */
2818 if(nfnt == 0)
2819 {
2820 if(nfnd != 0)
2821 warning("Found %d FONTDIR entries without any fonts present", nfnd);
2822 goto clean;
2823 }
2824
2825 /* Copy space */
2826 lanfnt = xmalloc(nfnt * sizeof(*lanfnt));
2827
2828 /* Get all fonts covered by fontdirs */
2829 for(i = 0; i < nfnd; i++)
2830 {
2831 int j;
2832 WORD cnt;
2833 int isswapped = 0;
2834
2835 if(!fnd[i])
2836 continue;
2837 for(j = 0; j < nfnt; j++)
2838 {
2839 if(!fnt[j])
2840 continue;
2841 if(fnt[j]->lan->id == fnd[i]->lan->id && fnt[j]->lan->sub == fnd[i]->lan->sub)
2842 {
2843 lanfnt[nlanfnt] = fnt[j];
2844 nlanfnt++;
2845 fnt[j] = NULL;
2846 }
2847 }
2848
2849 cnt = *(WORD *)fnd[i]->res.fnd->data->data;
2850 if(nlanfnt == cnt)
2851 isswapped = 0;
2852 else if(nlanfnt == BYTESWAP_WORD(cnt))
2853 isswapped = 1;
2854 else
2855 error("FONTDIR for language %d,%d has wrong count (%d, expected %d)",
2856 fnd[i]->lan->id, fnd[i]->lan->sub, cnt, nlanfnt);
2857 #ifdef WORDS_BIGENDIAN
2858 if((byteorder == WRC_BO_LITTLE && !isswapped) || (byteorder != WRC_BO_LITTLE && isswapped))
2859 #else
2860 if((byteorder == WRC_BO_BIG && !isswapped) || (byteorder != WRC_BO_BIG && isswapped))
2861 #endif
2862 {
2863 internal_error(__FILE__, __LINE__, "User supplied FONTDIR needs byteswapping");
2864 }
2865 }
2866
2867 /* We now have fonts left where we need to make a fontdir resource */
2868 for(i = fntleft = 0; i < nfnt; i++)
2869 {
2870 if(fnt[i])
2871 fntleft++;
2872 }
2873 while(fntleft)
2874 {
2875 /* Get fonts of same language in lanfnt[] */
2876 for(i = nlanfnt = 0; i < nfnt; i++)
2877 {
2878 if(fnt[i])
2879 {
2880 if(!nlanfnt)
2881 {
2882 addlanfnt:
2883 lanfnt[nlanfnt] = fnt[i];
2884 nlanfnt++;
2885 fnt[i] = NULL;
2886 fntleft--;
2887 }
2888 else if(fnt[i]->lan->id == lanfnt[0]->lan->id && fnt[i]->lan->sub == lanfnt[0]->lan->sub)
2889 goto addlanfnt;
2890 }
2891 }
2892 /* and build a fontdir */
2893 rsc = build_fontdir(lanfnt, nlanfnt);
2894 if(rsc)
2895 {
2896 if(lst)
2897 {
2898 lst->next = rsc;
2899 rsc->prev = lst;
2900 }
2901 lst = rsc;
2902 }
2903 }
2904
2905 free(lanfnt);
2906 clean:
2907 if(fnt)
2908 free(fnt);
2909 if(fnd)
2910 free(fnd);
2911 free(str.str.cstr);
2912 return lst;
2913 }
2914
2915 /*
2916 * This gets invoked to determine whether the next resource
2917 * is to be of a standard-type (e.g. bitmaps etc.), or should
2918 * be a user-type resource. This function is required because
2919 * there is the _possibility_ of a lookahead token in the
2920 * parser, which is generated from the "expr" state in the
2921 * "nameid" parsing.
2922 *
2923 * The general resource format is:
2924 * <identifier> <type> <flags> <resourcebody>
2925 *
2926 * The <identifier> can either be tIDENT or "expr". The latter
2927 * will always generate a lookahead, which is the <type> of the
2928 * resource to parse. Otherwise, we need to get a new token from
2929 * the scanner to determine the next step.
2930 *
2931 * The problem arrises when <type> is numerical. This case should
2932 * map onto default resource-types and be parsed as such instead
2933 * of being mapped onto user-type resources.
2934 *
2935 * The trick lies in the fact that yacc (bison) doesn't care about
2936 * intermediate changes of the lookahead while reducing a rule. We
2937 * simply replace the lookahead with a token that will result in
2938 * a shift to the appropriate rule for the specific resource-type.
2939 */
2940 static int rsrcid_to_token(int lookahead)
2941 {
2942 int token;
2943 const char *type = "?";
2944
2945 /* Get a token if we don't have one yet */
2946 if(lookahead == YYEMPTY)
2947 lookahead = YYLEX;
2948
2949 /* Only numbers are possibly interesting */
2950 switch(lookahead)
2951 {
2952 case tNUMBER:
2953 case tLNUMBER:
2954 break;
2955 default:
2956 return lookahead;
2957 }
2958
2959 token = lookahead;
2960
2961 switch(yylval.num)
2962 {
2963 case WRC_RT_CURSOR:
2964 type = "CURSOR";
2965 token = tCURSOR;
2966 break;
2967 case WRC_RT_ICON:
2968 type = "ICON";
2969 token = tICON;
2970 break;
2971 case WRC_RT_BITMAP:
2972 type = "BITMAP";
2973 token = tBITMAP;
2974 break;
2975 case WRC_RT_FONT:
2976 type = "FONT";
2977 token = tFONT;
2978 break;
2979 case WRC_RT_FONTDIR:
2980 type = "FONTDIR";
2981 token = tFONTDIR;
2982 break;
2983 case WRC_RT_RCDATA:
2984 type = "RCDATA";
2985 token = tRCDATA;
2986 break;
2987 case WRC_RT_MESSAGETABLE:
2988 type = "MESSAGETABLE";
2989 token = tMESSAGETABLE;
2990 break;
2991 case WRC_RT_DLGINIT:
2992 type = "DLGINIT";
2993 token = tDLGINIT;
2994 break;
2995 case WRC_RT_ACCELERATOR:
2996 type = "ACCELERATOR";
2997 token = tACCELERATORS;
2998 break;
2999 case WRC_RT_MENU:
3000 type = "MENU";
3001 token = tMENU;
3002 break;
3003 case WRC_RT_DIALOG:
3004 type = "DIALOG";
3005 token = tDIALOG;
3006 break;
3007 case WRC_RT_VERSION:
3008 type = "VERSION";
3009 token = tVERSIONINFO;
3010 break;
3011 case WRC_RT_TOOLBAR:
3012 type = "TOOLBAR";
3013 token = tTOOLBAR;
3014 break;
3015 case WRC_RT_HTML:
3016 type = "HTML";
3017 token = tHTML;
3018 break;
3019
3020 case WRC_RT_STRING:
3021 type = "STRINGTABLE";
3022 break;
3023
3024 case WRC_RT_ANICURSOR:
3025 case WRC_RT_ANIICON:
3026 case WRC_RT_GROUP_CURSOR:
3027 case WRC_RT_GROUP_ICON:
3028 yywarning("Usertype uses reserved type ID %d, which is auto-generated", yylval.num);
3029 return lookahead;
3030
3031 case WRC_RT_DLGINCLUDE:
3032 case WRC_RT_PLUGPLAY:
3033 case WRC_RT_VXD:
3034 yywarning("Usertype uses reserved type ID %d, which is not supported by wrc yet", yylval.num);
3035 default:
3036 return lookahead;
3037 }
3038
3039 return token;
3040 }
Maarten's multimedia branch