configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(debug,
  19 [  --disable-debug         compile out all debugging messages],
  20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  21
  22 AC_ARG_ENABLE(opengl,
  23 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe],
  24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  25
  26 AC_ARG_ENABLE(trace,
  27 [  --disable-trace         compile out TRACE messages],
  28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  29
  30 AC_ARG_WITH(curses,
  31 [  --without-curses        do not use curses],
  32 [if test "$withval" = "no"; then CURSES="no"; fi])
  33
  34 AC_ARG_WITH(reentrant-x,
  35 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  36
  37 AC_SUBST(OPTIONS)
  38
  39 if test "$DEBUG_MSGS" = "no"
  40 then
  41     AC_DEFINE(NO_DEBUG_MSGS)
  42     AC_DEFINE(NO_TRACE_MSGS)
  43 else
  44     if test "$TRACE_MSGS" = "no"
  45     then
  46         AC_DEFINE(NO_TRACE_MSGS)
  47     fi
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_DECL_YYTEXT
  66 AC_PROG_RANLIB
  67 AC_PROG_INSTALL
  68 AC_PROG_LN_S
  69 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  70 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  71
  72 dnl Check for lint
  73 AC_CHECK_PROGS(LINT, lclint lint)
  74 if test "$LINT" = "lint"
  75 then
  76   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  77   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  78 fi
  79 AC_SUBST(LINT)
  80 AC_SUBST(LINTFLAGS)
  81
  82 dnl **** Check for some libraries ****
  83
  84 dnl Check for -lm for BeOS
  85 AC_CHECK_LIB(m,sqrt)
  86 dnl Check for -li386 for NetBSD and OpenBSD
  87 AC_CHECK_LIB(i386,i386_set_ldt)
  88 dnl Check for -lossaudio for NetBSD
  89 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  90 dnl Check for -lw for Solaris
  91 AC_CHECK_LIB(w,iswalnum)
  92 dnl Check for -lnsl for Solaris
  93 AC_CHECK_FUNCS(gethostbyname,, AC_CHECK_LIB(nsl, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", AC_CHECK_LIB(socket, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", , -lnsl), -lsocket))
  94 dnl Check for -lsocket for Solaris
  95 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
  96 dnl Check for -lxpg4 for FreeBSD
  97 AC_CHECK_LIB(xpg4,setrunelocale)
  98 dnl Check for -lmmap for OS/2
  99 AC_CHECK_LIB(mmap,mmap)
 100 dnl Check for openpty
 101 AC_CHECK_FUNCS(openpty,,
 102         AC_CHECK_LIB(util,openpty,
 103                 AC_DEFINE(HAVE_OPENPTY)
 104                 LIBS="$LIBS -lutil"
 105         ))
 106
 107 AC_CHECK_HEADERS(dlfcn.h,
 108         AC_CHECK_FUNCS(dlopen,
 109                 AC_DEFINE(HAVE_DL_API),
 110                 AC_CHECK_LIB(dl,dlopen,
 111                         AC_DEFINE(HAVE_DL_API)
 112                         LIBS="$LIBS -ldl",
 113                         LIBEXT="a"
 114                 )
 115         ),
 116         LIBEXT="a"
 117 )
 118 AC_SUBST(XLIB)
 119 AC_SUBST(X_DLLS)
 120 X_DLLS=""
 121 AC_SUBST(XFILES)
 122 XFILES=""
 123 AC_SUBST(OPENGLFILES)
 124 OPENGLFILES=""
 125 AC_SUBST(OPENGL32_DLL)
 126 OPENGL32_DLL=""
 127 AC_SUBST(DGA_SRCS)
 128 DGA_SRCS=""
 129 AC_SUBST(DGA2_SRCS)
 130 DGA2_SRCS=""
 131 AC_SUBST(MESA_SRCS)
 132 MESA_SRCS=""
 133 if test "$have_x" = "yes"
 134 then
 135     XLIB="-lXext -lX11"
 136     ac_save_CPPFLAGS="$CPPFLAGS"
 137     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 138
 139     dnl *** Check for -lXpm
 140     AC_CHECK_HEADERS(X11/xpm.h,
 141       [ dnl *** If X11/xpm.h exists...
 142         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 143           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 144           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 145         )
 146       ],
 147       [ dnl *** If X11/xpm.h does not exist...
 148         dnl NOTE: autoconf does not allow commas inside the third
 149         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 150         dnl       magic it does.
 151         echo "Redhat            :       xpm xpm-devel"
 152         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 153         echo "SuSE              :       xpm"
 154         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 155         echo
 156         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 157         echo "the directory /contrib/libraries."
 158         echo
 159         exit 1
 160       ]
 161     )
 162
 163     dnl *** All three of the following tests require X11/Xlib.h
 164     AC_CHECK_HEADERS(X11/Xlib.h,
 165       [
 166         dnl *** Check for X Shm extension
 167         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 168             [ dnl *** If X11/extensions/XShm.h exists...
 169               AC_CHECK_LIB(Xext, XShmQueryExtension,
 170               AC_DEFINE(HAVE_LIBXXSHM),,
 171               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 172             ],
 173             AC_MSG_WARN([Xshm extension not found!!])
 174         )
 175
 176         dnl *** Check for X shape extension
 177         AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/shape.h,
 178             [ dnl *** If X11/extensions/shape.h exists...
 179               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 180               AC_DEFINE(HAVE_LIBXSHAPE),,
 181               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 182             ],
 183             AC_MSG_WARN([XShape extension found!!])
 184         )
 185
 186         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 187         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 188             [ dnl *** If X11/extensions/xf86dga.h exists, check
 189               dnl *** for XDGAQueryExtension()...
 190               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 191                 [ dnl *** If found...
 192                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 193                   AC_DEFINE(HAVE_LIBXXF86DGA)
 194                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 195                   DGA_SRCS='$(DGA_SRCS)'
 196                   DGA2_SRCS='$(DGA2_SRCS)'
 197                ],
 198                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 199                   dnl *** instead (DGA 2.0 not found)...
 200                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 201                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 202                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 203                       DGA_SRCS='$(DGA_SRCS)'
 204                     ],,
 205                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 206                   )
 207                 ],
 208                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 209               )
 210             ],
 211             AC_MSG_WARN([DGA extension not found!!])
 212         )
 213
 214         dnl *** Check for XFree86 VMODE extension
 215         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 216             [ dnl *** If X11/extensions/xf86vmode.h exists...
 217                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 218                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 219                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 220                   ],,
 221                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 222                 )
 223             ],
 224             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 225         )
 226
 227         dnl *** Check for XVideo extension supporting XvImages
 228         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 229             [ dnl *** If X11/extensions/Xvlib.h exists...
 230                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 231                   [ AC_DEFINE(HAVE_XVIDEO)
 232                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 233                   ],,
 234                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 235                 )
 236             ],
 237             AC_MSG_WARN([XVideo extension not found !!])
 238         )
 239
 240       ]
 241     ) dnl *** End of X11/Xlib.h check
 242
 243     dnl Check for the presence of OpenGL
 244     if test $OPENGL = "yes" -o $OPENGL = "normal"
 245     then
 246         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 247         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 248         then
 249             dnl Check for some problems due to old Mesa versions
 250             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 251               AC_TRY_COMPILE(
 252                 [#include <GL/gl.h>],
 253                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 254                 [wine_cv_opengl_version_OK="yes"],
 255                 [wine_cv_opengl_version_OK="no"]
 256               )
 257             )
 258
 259             dnl Check for the thread-safety of the OpenGL library
 260             AC_CACHE_CHECK("for thread-safe OpenGL version",
 261                            wine_cv_opengl_version_threadsafe,
 262               [saved_libs=$LIBS
 263                LIBS="$X_LIBS -lGL"
 264                AC_TRY_LINK([],[pthread_getspecific();],
 265                               [wine_cv_opengl_version_threadsafe="yes"],
 266                               [wine_cv_opengl_version_threadsafe="no"])
 267                LIBS=$saved_libs]
 268             )
 269
 270             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 271             then
 272                 dnl Check for the presence of the library
 273                 AC_CHECK_LIB(GL,glXCreateContext,
 274                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 275                              MESA_SRCS='$(MESA_SRCS)'
 276                              ,,
 277                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 278
 279                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 280                 then
 281
 282                         OPENGLFILES='$(OPENGLFILES)'
 283                         AC_DEFINE(HAVE_OPENGL)
 284
 285                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 286
 287                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 288                         then
 289                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 290                                   AC_TRY_COMPILE([#include <GL/gl.h>
 291                                                   #ifdef HAVE_GL_GLEXT_H
 292                                                   # include <GL/glext.h>
 293                                                   #endif
 294                                                   ],
 295                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 296                                                  [wine_cv_extension_prototypes="yes"],
 297                                                  [wine_cv_extension_prototypes="no"]
 298                                   )
 299                                 )
 300                                 if test $wine_cv_extension_prototypes = "yes"
 301                                 then
 302                                         AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 303                                 fi
 304
 305                                 OPENGL32_DLL=opengl32
 306                         fi
 307                 fi
 308              fi
 309          fi
 310     fi
 311
 312     CPPFLAGS="$ac_save_CPPFLAGS"
 313     X_DLLS='$(X_DLLS)'
 314     XFILES='$(XFILES)'
 315 else
 316     XLIB=""
 317     X_CFLAGS=""
 318     X_LIBS=""
 319 fi
 320
 321 dnl **** Check which curses lib to use ***
 322 if test "$CURSES" = "yes"
 323 then
 324     AC_CHECK_HEADERS(ncurses.h)
 325     if test "$ac_cv_header_ncurses_h" = "yes"
 326     then
 327         AC_CHECK_LIB(ncurses,waddch)
 328     fi
 329     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 330     then
 331         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 332         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 333     else
 334         AC_CHECK_HEADERS(curses.h)
 335         if test "$ac_cv_header_curses_h" = "yes"
 336         then
 337             AC_CHECK_LIB(curses,waddch)
 338             if test "$ac_cv_lib_curses_waddch" = "yes"
 339             then
 340                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 341                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 342             fi
 343         fi
 344     fi
 345 fi
 346
 347 dnl **** Check for IPX (currently Linux only) ****
 348 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 349  AC_TRY_COMPILE(
 350    [#include <sys/socket.h>
 351     #include <netipx/ipx.h>],
 352    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 353    [ac_cv_c_ipx_gnu="yes"],
 354    [ac_cv_c_ipx_gnu="no"])
 355  )
 356 if test "$ac_cv_c_ipx_gnu" = "yes"
 357 then
 358     AC_DEFINE(HAVE_IPX_GNU)
 359 fi
 360
 361 if test "$ac_cv_c_ipx_gnu" = "no"
 362 then
 363  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 364   AC_TRY_COMPILE(
 365     [#include <sys/socket.h>
 366      #include <asm/types.h>
 367      #include <linux/ipx.h>],
 368     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 369     [ac_cv_c_ipx_linux="yes"],
 370     [ac_cv_c_ipx_linux="no"])
 371   )
 372   if test "$ac_cv_c_ipx_linux" = "yes"
 373   then
 374       AC_DEFINE(HAVE_IPX_LINUX)
 375   fi
 376 fi
 377
 378 dnl **** Check for Open Sound System ****
 379 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 380
 381 AC_CACHE_CHECK("for Open Sound System",
 382         ac_cv_c_opensoundsystem,
 383         AC_TRY_COMPILE([
 384         #if defined(HAVE_SYS_SOUNDCARD_H)
 385                 #include <sys/soundcard.h>
 386         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 387                 #include <machine/soundcard.h>
 388         #elif defined(HAVE_SOUNDCARD_H)
 389                 #include <soundcard.h>
 390         #endif
 391         ],[
 392
 393 /* check for one of the Open Sound System specific SNDCTL_ defines */
 394 #if !defined(SNDCTL_DSP_STEREO)
 395 #error No open sound system
 396 #endif
 397 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 398
 399 if test "$ac_cv_c_opensoundsystem" = "yes"
 400 then
 401     AC_DEFINE(HAVE_OSS)
 402 fi
 403
 404 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 405         ac_cv_c_opensoundsystem_midi,
 406         AC_TRY_COMPILE([
 407         #if defined(HAVE_SYS_SOUNDCARD_H)
 408                 #include <sys/soundcard.h>
 409         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 410                 #include <machine/soundcard.h>
 411         #elif defined(HAVE_SOUNDCARD_H)
 412                 #include <soundcard.h>
 413         #endif
 414         ],[
 415
 416 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 417 #if !defined(SNDCTL_SEQ_SYNC)
 418 #error No open sound system MIDI interface
 419 #endif
 420 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 421
 422 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 423 then
 424     AC_DEFINE(HAVE_OSS_MIDI)
 425 fi
 426
 427 dnl **** If ln -s doesn't work, use cp instead ****
 428 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 429
 430 dnl **** Check for gcc strength-reduce bug ****
 431
 432 if test "x${GCC}" = "xyes"
 433 then
 434   CFLAGS="$CFLAGS -Wall"
 435   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 436                   AC_TRY_RUN([
 437 int     L[[4]] = {0,1,2,3};
 438 int main(void) {
 439   static int Array[[3]];
 440   unsigned int B = 3;
 441   int i;
 442   for(i=0; i<B; i++) Array[[i]] = i - 3;
 443   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 444   L[[i]] = 4;
 445
 446   exit( Array[[1]] != -2 || L[[2]] != 3);
 447 }],
 448     ac_cv_c_gcc_strength_bug="no",
 449     ac_cv_c_gcc_strength_bug="yes",
 450     ac_cv_c_gcc_strength_bug="yes") )
 451   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 452   then
 453     CFLAGS="$CFLAGS -fno-strength-reduce"
 454   fi
 455 fi
 456
 457 dnl **** Check if we need to place .type inside a .def directive ****
 458
 459 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
 460                ac_cv_c_type_in_def,
 461 [saved_libs=$LIBS
 462 LIBS="conftest_asm.s $LIBS"
 463 cat > conftest_asm.s <<EOF
 464         .globl _ac_test
 465         .def _ac_test; .scl 2; .type 32; .endef
 466 _ac_test:
 467         .long 0
 468 EOF
 469 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 470 LIBS=$saved_libs])
 471 if test "$ac_cv_c_type_in_def" = "yes"
 472 then
 473   AC_DEFINE(NEED_TYPE_IN_DEF)
 474 fi
 475
 476 dnl **** Check for underscore on external symbols ****
 477
 478 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 479                ac_cv_c_extern_prefix,
 480 [saved_libs=$LIBS
 481 LIBS="conftest_asm.s $LIBS"
 482 cat > conftest_asm.s <<EOF
 483         .globl _ac_test
 484 _ac_test:
 485         .long 0
 486 EOF
 487 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 488             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 489 LIBS=$saved_libs])
 490 if test "$ac_cv_c_extern_prefix" = "yes"
 491 then
 492   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 493 fi
 494
 495 dnl **** Check for .string in assembler ****
 496
 497 AC_CACHE_CHECK("whether assembler accepts .string",
 498                ac_cv_c_asm_string,
 499 [saved_libs=$LIBS
 500 LIBS="conftest_asm.s $LIBS"
 501 cat > conftest_asm.s <<EOF
 502         .string "test"
 503 EOF
 504 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 505 LIBS=$saved_libs])
 506 if test "$ac_cv_c_asm_string" = "yes"
 507 then
 508   AC_DEFINE(HAVE_ASM_STRING)
 509 fi
 510
 511 dnl **** Check for working dll ****
 512
 513 LDSHARED=""
 514 LDDLLFLAGS=""
 515 if test "$LIBEXT" = "so"
 516 then
 517   AC_CACHE_CHECK("whether we can build a Linux dll",
 518                  ac_cv_c_dll_linux,
 519   [saved_cflags=$CFLAGS
 520   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 521   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 522   CFLAGS=$saved_cflags
 523   ])
 524   if test "$ac_cv_c_dll_linux" = "yes"
 525   then
 526     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%) -Wl,-rpath,\$(libdir)"
 527     LDDLLFLAGS="-Wl,-Bsymbolic"
 528   else
 529     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 530                  ac_cv_c_dll_unixware,
 531     [saved_cflags=$CFLAGS
 532     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 533     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 534     CFLAGS=$saved_cflags
 535     ])
 536     if test "$ac_cv_c_dll_unixware" = "yes"
 537     then
 538       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,h,\$(libdir)/%)"
 539       LDDLLFLAGS="-Wl,-B,symbolic"
 540     else
 541       AC_CACHE_CHECK("whether we can build a NetBSD dll",
 542                    ac_cv_c_dll_netbsd,
 543       [saved_cflags=$CFLAGS
 544       CFLAGS="$CFLAGS -fPIC -Wl,-Bshareable,-Bforcearchive"
 545       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 546       CFLAGS=$saved_cflags
 547       ])
 548       if test "$ac_cv_c_dll_netbsd" = "yes"
 549       then
 550         LDSHARED="\$(CC) -Wl,-Bshareable,-Bforcearchive"
 551         LDDLLFLAGS="" #FIXME
 552       fi
 553     fi
 554   fi
 555   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 556   then
 557     echo "*** It is currently not possible to build WINE without shared"
 558     echo "*** library (.so) support to allow transparent switch between .so"
 559     echo "*** and .dll files."
 560     echo "*** If you are using Linux, you will need a newer binutils."
 561     exit 1
 562   fi
 563 fi
 564
 565 DLLFLAGS=""
 566
 567 if test "$LIBEXT" = "so"; then
 568     DLLFLAGS="-fPIC"
 569     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) -L\$(TOPOBJDIR) -lwine -lwine_unicode"
 570 else
 571     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) -L\$(TOPOBJDIR) -lwine -lwine_unicode \$(X_LIBS) \$(XLIB)"
 572     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 573                    ac_cv_c_whole_archive,
 574             [saved_cflags=$CFLAGS
 575             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 576             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 577             CFLAGS=$saved_cflags
 578             ])
 579     if test "$ac_cv_c_whole_archive" = "yes"
 580     then
 581         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 582     else
 583         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 584                        ac_cv_c_allextract,
 585                 [saved_cflags=$CFLAGS
 586                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 587                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 588                 CFLAGS=$saved_cflags
 589                 ])
 590         if test "$ac_cv_c_allextract" = "yes"
 591         then
 592             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 593         fi
 594     fi
 595 fi
 596
 597 AC_SUBST(DLL_LINK)
 598 AC_SUBST(DLLFLAGS)
 599 AC_SUBST(LDSHARED)
 600 AC_SUBST(LDDLLFLAGS)
 601 AC_SUBST(LIBEXT)
 602
 603 dnl **** Check for reentrant libc ****
 604 dnl
 605 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 606 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 607
 608 wine_cv_libc_reentrant=no
 609 dnl
 610 dnl Linux style errno location
 611 dnl
 612 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 613   [AC_TRY_RUN([int myerrno = 0;
 614 char buf[256];
 615 int *__errno_location(){return &myerrno;}
 616 main(){connect(0,buf,255); exit(!myerrno);}],
 617   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 618   wine_cv_libc_r__errno_location=yes )
 619 ])
 620 if test "$wine_cv_libc_r__errno_location" = "yes"
 621 then
 622     AC_DEFINE(HAVE__ERRNO_LOCATION)
 623     wine_cv_libc_reentrant=__errno_location
 624 fi
 625 dnl
 626 dnl FreeBSD style errno location
 627 dnl
 628 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 629   [AC_TRY_RUN([int myerrno = 0;
 630 char buf[256];
 631 int *__error(){return &myerrno;}
 632 main(){connect(0,buf,255); exit(!myerrno);}],
 633     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 634     wine_cv_libc_r__error=yes )
 635 ])
 636 if test "$wine_cv_libc_r__error" = "yes"
 637 then
 638     AC_DEFINE(HAVE__ERROR)
 639     wine_cv_libc_reentrant=__error
 640 fi
 641 dnl
 642 dnl Solaris style errno location
 643 dnl
 644 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 645   [AC_TRY_RUN([int myerrno = 0;
 646 char buf[256];
 647 int *___errno(){return &myerrno;}
 648 main(){connect(0,buf,255); exit(!myerrno);}],
 649     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 650     wine_cv_libc_r___errno=yes )
 651 ])
 652 if test "$wine_cv_libc_r___errno" = "yes"
 653 then
 654     AC_DEFINE(HAVE___ERRNO)
 655     wine_cv_libc_reentrant=___errno
 656 fi
 657 dnl
 658 dnl UnixWare style errno location
 659 dnl
 660 AC_CACHE_CHECK("for reentrant libc: __thr_errno", wine_cv_libc_r__thr_errno,
 661   [AC_TRY_RUN([int myerrno = 0;
 662 char buf[256];
 663 int *__thr_errno(){return &myerrno;}
 664 main(){connect(0,buf,255); exit(!myerrno);}],
 665     wine_cv_libc_r__thr_errno=yes, wine_cv_libc_r__thr_errno=no,
 666     wine_cv_libc_r__thr_errno=yes )
 667 ])
 668 if test "$wine_cv_libc_r__thr_errno" = "yes"
 669 then
 670     AC_DEFINE(HAVE__THR_ERRNO)
 671     wine_cv_libc_reentrant=__thr_errno
 672 fi
 673 if test "$wine_cv_libc_reentrant" = "no"
 674 then
 675   AC_DEFINE(NO_REENTRANT_LIBC)
 676 fi
 677
 678 dnl **** Check for reentrant X libraries ****
 679 dnl
 680 dnl This may fail to determine whether X libraries are reentrant if
 681 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 682 dnl is possible with the --without-reentrant-x option.
 683
 684 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 685 then
 686 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 687   [ if test "x$with_reentrant_x" = "xno"
 688     then
 689         wine_cv_x_reentrant=no
 690     else
 691         libX11_check=none
 692         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 693             if test -r $dir/libX11.so; then
 694                 libX11_check="-D $dir/libX11.so"
 695                 break 1
 696             fi
 697             if test -r $dir/libX11.a; then
 698                 libX11_check="$dir/libX11.a"
 699                 break 1
 700             fi
 701         done
 702         if test "$libX11_check" != "none"; then
 703             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 704             then
 705                 wine_cv_x_reentrant=yes
 706             else
 707                 wine_cv_x_reentrant=no
 708             fi
 709         else
 710             wine_cv_x_reentrant=unknown
 711         fi
 712     fi ] )
 713 else
 714     wine_cv_x_reentrant=no
 715 fi
 716 if test "$wine_cv_x_reentrant" = "no"
 717 then
 718   AC_DEFINE(NO_REENTRANT_X11)
 719 fi
 720
 721 dnl **** Check for endianness ****
 722
 723 AC_C_BIGENDIAN
 724
 725 dnl **** Check for functions ****
 726
 727 AC_FUNC_ALLOCA()
 728 AC_CHECK_FUNCS(\
 729         __libc_fork \
 730         _lwp_create \
 731         clone \
 732         finite \
 733         fpclass \
 734         getnetbyaddr \
 735         getnetbyname \
 736         getpagesize \
 737         getprotobyname \
 738         getprotobynumber \
 739         getrlimit \
 740         getservbyport \
 741         getsockopt \
 742         inet_network \
 743         lstat \
 744         memmove \
 745         mmap \
 746         rfork \
 747         select \
 748         sendmsg \
 749         settimeofday \
 750         sigaltstack \
 751         statfs \
 752         strcasecmp \
 753         strerror \
 754         strncasecmp \
 755         tcgetattr \
 756         timegm \
 757         usleep \
 758         vfscanf \
 759         wait4 \
 760         waitpid \
 761 )
 762
 763 dnl **** Check for header files ****
 764
 765 AC_CHECK_HEADERS(\
 766         arpa/inet.h \
 767         arpa/nameser.h \
 768         elf.h \
 769         float.h \
 770         libio.h \
 771         libutil.h \
 772         link.h \
 773         linux/cdrom.h \
 774         linux/joystick.h \
 775         linux/ucdrom.h \
 776         net/if.h \
 777         netdb.h \
 778         netinet/in.h \
 779         netinet/in_systm.h \
 780         netinet/ip.h \
 781         netinet/tcp.h \
 782         pty.h \
 783         resolv.h \
 784         sched.h \
 785         socket.h \
 786         strings.h \
 787         sys/cdio.h \
 788         sys/errno.h \
 789         sys/file.h \
 790         sys/filio.h \
 791         sys/ipc.h \
 792         sys/lwp.h \
 793         sys/mman.h \
 794         sys/modem.h \
 795         sys/mount.h \
 796         sys/msg.h \
 797         sys/param.h \
 798         sys/ptrace.h \
 799         sys/reg.h \
 800         sys/signal.h \
 801         sys/shm.h \
 802         sys/socket.h \
 803         sys/sockio.h \
 804         sys/statfs.h \
 805         sys/strtio.h \
 806         sys/syscall.h \
 807         sys/user.h \
 808         sys/wait.h \
 809         sys/v86.h \
 810         sys/v86intr.h \
 811         sys/vfs.h \
 812         sys/vm86.h \
 813         syscall.h \
 814         ucontext.h \
 815 )
 816 AC_HEADER_STAT()
 817
 818 dnl **** Check for types ****
 819
 820 AC_C_CONST()
 821 AC_C_INLINE()
 822 AC_TYPE_SIZE_T()
 823 AC_CHECK_SIZEOF(long long,0)
 824
 825
 826 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
 827         wine_cv_linux_gethostbyname_r_6,
 828         AC_TRY_COMPILE([
 829 #include <netdb.h>
 830         ], [
 831     char *name=NULL;
 832     struct hostent he;
 833     struct hostent *result;
 834     char *buf=NULL;
 835     int bufsize=0;
 836     int res,errnr;
 837     char *addr=NULL;
 838     int addrlen=0;
 839     int addrtype=0;
 840     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 841     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 842     ],
 843         wine_cv_linux_gethostbyname_r_6=yes,
 844         wine_cv_linux_gethostbyname_r_6=no
 845         )
 846    )
 847    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 848    then
 849       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6)
 850    fi
 851
 852 if test "$ac_cv_header_linux_joystick_h" = "yes"
 853 then
 854    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 855         wine_cv_linux_joystick_22_api,
 856         AC_TRY_COMPILE([
 857         #include <sys/ioctl.h>
 858         #include <linux/joystick.h>
 859
 860         struct js_event blub;
 861         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 862         #error "no 2.2 header"
 863         #endif
 864         ],/*empty*/,
 865         wine_cv_linux_joystick_22_api=yes,
 866         wine_cv_linux_joystick_22_api=no,
 867         wine_cv_linux_joystick_22_api=no
 868         )
 869    )
 870    if test "$wine_cv_linux_joystick_22_api" = "yes"
 871    then
 872       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 873    fi
 874 fi
 875
 876 dnl **** statfs checks ****
 877
 878 if test "$ac_cv_header_sys_vfs_h" = "yes"
 879 then
 880     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 881                     wine_cv_sys_vfs_has_statfs,
 882         AC_TRY_COMPILE([
 883         #include <sys/types.h>
 884         #ifdef HAVE_SYS_PARAM_H
 885         # include <sys/param.h>
 886         #endif
 887         #include <sys/vfs.h>
 888         ],[
 889                 struct statfs stfs;
 890
 891                 memset(&stfs,0,sizeof(stfs));
 892         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 893         )
 894     )
 895     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 896     then
 897       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 898     fi
 899 fi
 900
 901 if test "$ac_cv_header_sys_statfs_h" = "yes"
 902 then
 903     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 904                     wine_cv_sys_statfs_has_statfs,
 905         AC_TRY_COMPILE([
 906         #include <sys/types.h>
 907         #ifdef HAVE_SYS_PARAM_H
 908         # include <sys/param.h>
 909         #endif
 910         #include <sys/statfs.h>
 911         ],[
 912                 struct statfs stfs;
 913         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 914         )
 915     )
 916     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 917     then
 918       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 919     fi
 920 fi
 921
 922 if test "$ac_cv_header_sys_mount_h" = "yes"
 923 then
 924     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 925                     wine_cv_sys_mount_has_statfs,
 926         AC_TRY_COMPILE([
 927         #include <sys/types.h>
 928         #ifdef HAVE_SYS_PARAM_H
 929         # include <sys/param.h>
 930         #endif
 931         #include <sys/mount.h>
 932         ],[
 933                 struct statfs stfs;
 934         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 935         )
 936     )
 937     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 938     then
 939       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 940     fi
 941 fi
 942
 943 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 944
 945 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 946   [ if test "x$statfs_bfree" = "xno"
 947     then
 948         wine_cv_statfs_bfree=no
 949     else
 950         AC_TRY_COMPILE([
 951         #include <sys/types.h>
 952         #ifdef HAVE_SYS_PARAM_H
 953         # include <sys/param.h>
 954         #endif
 955         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 956         # include <sys/mount.h>
 957         #else
 958         # ifdef STATFS_DEFINED_BY_SYS_VFS
 959         #  include <sys/vfs.h>
 960         # else
 961         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 962         #   include <sys/statfs.h>
 963         #  endif
 964         # endif
 965         #endif
 966         ],[
 967                 struct statfs stfs;
 968
 969                 stfs.f_bfree++;
 970         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 971         )
 972     fi ] )
 973 if test "$wine_cv_statfs_bfree" = "yes"
 974 then
 975   AC_DEFINE(STATFS_HAS_BFREE)
 976 fi
 977
 978 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 979   [ if test "x$statfs_bavail" = "xno"
 980     then
 981         wine_cv_statfs_bavail=no
 982     else
 983         AC_TRY_COMPILE([
 984         #include <sys/types.h>
 985         #ifdef HAVE_SYS_PARAM_H
 986         # include <sys/param.h>
 987         #endif
 988         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 989         # include <sys/mount.h>
 990         #else
 991         # ifdef STATFS_DEFINED_BY_SYS_VFS
 992         #  include <sys/vfs.h>
 993         # else
 994         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 995         #   include <sys/statfs.h>
 996         #  endif
 997         # endif
 998         #endif
 999         ],[
1000                 struct statfs stfs;
1001
1002                 stfs.f_bavail++;
1003         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1004         )
1005     fi ] )
1006 if test "$wine_cv_statfs_bavail" = "yes"
1007 then
1008   AC_DEFINE(STATFS_HAS_BAVAIL)
1009 fi
1010
1011 dnl *** check for file descriptor passing with msg_accrights
1012
1013 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1014  AC_TRY_COMPILE([#include <sys/types.h>
1015 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1016                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1017 if test "$ac_cv_c_msg_accrights" = "yes"
1018 then
1019     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
1020 fi
1021
1022 dnl *** Check for the sun_len member in struct sockaddr_un
1023
1024 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
1025  AC_TRY_COMPILE([#include <sys/types.h>
1026 #include <sys/socket.h>
1027 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1028                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
1029 if test "$ac_cv_c_sun_len" = "yes"
1030 then
1031     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
1032 fi
1033
1034 dnl *** check for the need to define __i386__
1035
1036 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1037  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1038 yes
1039 #endif],
1040  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1041 if test "$ac_cv_cpp_def_i386" = "yes"
1042 then
1043     CFLAGS="$CFLAGS -D__i386__"
1044     LINTFLAGS="$LINTFLAGS -D__i386__"
1045 fi
1046
1047 dnl $GCC is set by autoconf
1048 GCC_NO_BUILTIN=""
1049 if test "$GCC" = "yes"
1050 then
1051     GCC_NO_BUILTIN="-fno-builtin"
1052 fi
1053 AC_SUBST(GCC_NO_BUILTIN)
1054
1055 dnl **** Generate output files ****
1056
1057 AC_OUTPUT_COMMANDS([
1058 extra_subdirs="\
1059 dlls/ddraw/d3ddevice \
1060 dlls/ddraw/dclipper \
1061 dlls/ddraw/ddraw \
1062 dlls/ddraw/direct3d \
1063 dlls/ddraw/dpalette \
1064 dlls/ddraw/dsurface \
1065 dlls/dinput/joystick \
1066 dlls/dinput/keyboard \
1067 dlls/dinput/mouse \
1068 dlls/kernel/messages \
1069 dlls/user/resources \
1070 "
1071 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1072
1073 MAKE_RULES=Make.rules
1074 AC_SUBST_FILE(MAKE_RULES)
1075
1076 MAKE_DLL_RULES=dlls/Makedll.rules
1077 AC_SUBST_FILE(MAKE_DLL_RULES)
1078
1079 MAKE_PROG_RULES=programs/Makeprog.rules
1080 AC_SUBST_FILE(MAKE_PROG_RULES)
1081
1082 AC_OUTPUT([
1083 Make.rules
1084 dlls/Makedll.rules
1085 programs/Makeprog.rules
1086 Makefile
1087 console/Makefile
1088 controls/Makefile
1089 debugger/Makefile
1090 dlls/Makefile
1091 dlls/advapi32/Makefile
1092 dlls/avifil32/Makefile
1093 dlls/comctl32/Makefile
1094 dlls/commdlg/Makefile
1095 dlls/crtdll/Makefile
1096 dlls/dciman32/Makefile
1097 dlls/ddraw/Makefile
1098 dlls/dinput/Makefile
1099 dlls/dplay/Makefile
1100 dlls/dplayx/Makefile
1101 dlls/dsound/Makefile
1102 dlls/gdi/Makefile
1103 dlls/icmp/Makefile
1104 dlls/imagehlp/Makefile
1105 dlls/imm32/Makefile
1106 dlls/kernel/Makefile
1107 dlls/lzexpand/Makefile
1108 dlls/mpr/Makefile
1109 dlls/msacm/Makefile
1110 dlls/msnet32/Makefile
1111 dlls/msvideo/Makefile
1112 dlls/ntdll/Makefile
1113 dlls/odbc32/Makefile
1114 dlls/ole32/Makefile
1115 dlls/oleaut32/Makefile
1116 dlls/olecli/Makefile
1117 dlls/oledlg/Makefile
1118 dlls/olepro32/Makefile
1119 dlls/olesvr/Makefile
1120 dlls/opengl32/Makefile
1121 dlls/psapi/Makefile
1122 dlls/rasapi32/Makefile
1123 dlls/richedit/Makefile
1124 dlls/rpcrt4/Makefile
1125 dlls/serialui/Makefile
1126 dlls/setupapi/Makefile
1127 dlls/shell32/Makefile
1128 dlls/shfolder/Makefile
1129 dlls/shlwapi/Makefile
1130 dlls/tapi32/Makefile
1131 dlls/ttydrv/Makefile
1132 dlls/urlmon/Makefile
1133 dlls/user/Makefile
1134 dlls/version/Makefile
1135 dlls/win32s/Makefile
1136 dlls/winaspi/Makefile
1137 dlls/wineps/Makefile
1138 dlls/wininet/Makefile
1139 dlls/winmm/Makefile
1140 dlls/winmm/joystick/Makefile
1141 dlls/winmm/mcianim/Makefile
1142 dlls/winmm/mciavi/Makefile
1143 dlls/winmm/mcicda/Makefile
1144 dlls/winmm/mciseq/Makefile
1145 dlls/winmm/mciwave/Makefile
1146 dlls/winmm/midimap/Makefile
1147 dlls/winmm/wavemap/Makefile
1148 dlls/winmm/wineoss/Makefile
1149 dlls/winsock/Makefile
1150 dlls/winspool/Makefile
1151 dlls/wow32/Makefile
1152 dlls/wsock32/Makefile
1153 dlls/x11drv/Makefile
1154 documentation/Makefile
1155 documentation/wine.conf.man
1156 documentation/wine.man
1157 files/Makefile
1158 graphics/Makefile
1159 graphics/enhmetafiledrv/Makefile
1160 graphics/metafiledrv/Makefile
1161 graphics/win16drv/Makefile
1162 graphics/x11drv/Makefile
1163 if1632/Makefile
1164 include/Makefile
1165 library/Makefile
1166 libtest/Makefile
1167 loader/Makefile
1168 loader/dos/Makefile
1169 loader/ne/Makefile
1170 memory/Makefile
1171 misc/Makefile
1172 miscemu/Makefile
1173 msdos/Makefile
1174 objects/Makefile
1175 ole/Makefile
1176 programs/Makefile
1177 programs/avitools/Makefile
1178 programs/clock/Makefile
1179 programs/cmdlgtst/Makefile
1180 programs/control/Makefile
1181 programs/notepad/Makefile
1182 programs/osversioncheck/Makefile
1183 programs/progman/Makefile
1184 programs/regapi/Makefile
1185 programs/regtest/Makefile
1186 programs/uninstaller/Makefile
1187 programs/view/Makefile
1188 programs/wcmd/Makefile
1189 programs/winemine/Makefile
1190 programs/winhelp/Makefile
1191 programs/winver/Makefile
1192 relay32/Makefile
1193 scheduler/Makefile
1194 server/Makefile
1195 tools/Makefile
1196 tools/cvdump/Makefile
1197 tools/winebuild/Makefile
1198 tools/winelauncher
1199 tools/wmc/Makefile
1200 tools/wrc/Makefile
1201 tsx11/Makefile
1202 unicode/Makefile
1203 win32/Makefile
1204 windows/Makefile
1205 windows/x11drv/Makefile ])
1206
1207 if test "$have_x" = "no"
1208 then
1209   echo
1210   echo "*** Warning: X development files not found. Wine will be built without"
1211   echo "*** X support, which currently does not work, and would probably not be"
1212   echo "*** what you want anyway. You will need to install devel packages of"
1213   echo "*** Xlib/Xfree86 and Xpm at the very least."
1214 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1215 then
1216   echo
1217   echo "*** Warning: Xpm development files not found. Wine will be built without"
1218   echo "*** Xpm support, which currently does not work. You will need to install"
1219   echo "*** devel packages of Xpm."
1220 fi
1221
1222 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1223 then
1224   echo
1225   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1226   echo "*** terminal resize support. Consider upgrading ncurses."
1227 fi
1228
1229 if test "$wine_cv_libc_reentrant" = "no"
1230 then
1231   echo
1232   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1233   echo "*** thread support. Consider upgrading libc to a more recent"
1234   echo "*** reentrant version of libc."
1235 fi
1236
1237 if test "$wine_cv_opengl_version_OK" = "no"
1238 then
1239   echo
1240   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1241   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1242 fi
1243
1244 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1245 then
1246   echo
1247   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1248   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1249   echo "*** A fix for glibc 2.1.3 that seem to work is included in this version of Wine,"
1250   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1251 fi
1252
1253 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1254 then
1255   echo
1256   echo "*** Warning: you explicitely linked in a thread-safe OpenGL version. If you"
1257   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1258   echo "*** support before reporting bugs."
1259 fi
1260
1261
1262 echo
1263 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1264 echo
1265
1266 dnl Local Variables:
1267 dnl comment-start: "dnl "
1268 dnl comment-end: ""
1269 dnl comment-start-skip: "\\bdnl\\b\\s *"
1270 dnl compile-command: "autoconf"
1271 dnl End: