| blob | dc79d057d95b90d9713de38e144648ccaf1d51ab |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION)
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
25 if test "x$enable_win16" = "xno"
26 then
27 WIN16_FILES=""
28 WIN16_INSTALL=""
29 fi
30 if test "x$enable_debug" = "xno"
31 then
32 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
33 fi
34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
35 then
36 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
37 fi
39 dnl **** Check for some programs ****
41 AC_CANONICAL_HOST
42 AC_PROG_MAKE_SET
43 AC_PROG_CC
44 AC_PROG_CPP
46 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
47 [if test -z "$with_wine_tools"; then
48 if test "$cross_compiling" = "yes"; then
49 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
50 else
51 wine_cv_toolsdir="\$(TOPOBJDIR)"
52 fi
53 elif test -d "$with_wine_tools/tools/winebuild"; then
54 case $with_wine_tools in
55 /*) wine_cv_toolsdir="$with_wine_tools" ;;
56 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
57 esac
58 else
59 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
60 fi])
61 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
63 AC_PATH_XTRA
64 AC_PROG_YACC
65 AC_PROG_LEX
67 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
68 dnl **** without one present.
69 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
70 if test "$XYACC" = "none"
71 then
72 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
73 fi
74 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
75 if test "$XLEX" = "none"
76 then
77 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
78 fi
80 AC_CHECK_TOOLS(AS,[gas as],as)
81 AC_CHECK_TOOL(LD,ld,ld)
82 AC_CHECK_TOOL(AR,ar,ar)
83 AC_PROG_RANLIB
84 AC_CHECK_TOOL(STRIP,strip,strip)
85 AC_CHECK_TOOL(WINDRES,windres,false)
86 AC_PROG_LN_S
87 WINE_PROG_LN
88 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
89 AC_PROG_INSTALL
90 dnl Prepend src dir to install path dir if it's a relative path
91 case "$INSTALL" in
92 [[\\/$]]* | ?:[[\\/]]* ) ;;
93 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
94 esac
96 dnl Check for lint
97 AC_CHECK_PROGS(LINT, lclint lint)
98 if test "$LINT" = "lint"
99 then
100 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
101 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
102 fi
103 AC_SUBST(LINT)
104 AC_SUBST(LINTFLAGS)
106 dnl Check for db2html
107 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
108 AC_SUBST(DB2HTML)
110 dnl Check for db2pdf
111 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
112 AC_SUBST(DB2PDF)
114 dnl Check for db2ps
115 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
116 AC_SUBST(DB2PS)
118 dnl Check for db2txt
119 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
120 AC_SUBST(DB2TXT)
122 dnl **** Check for some libraries ****
124 dnl Check for -lm
125 AC_CHECK_LIB(m,sqrt)
126 dnl Check for -li386 for NetBSD and OpenBSD
127 AC_CHECK_LIB(i386,i386_set_ldt)
128 dnl Check for -lossaudio for NetBSD
129 AC_CHECK_LIB(ossaudio,_oss_ioctl)
130 dnl Check for -lw for Solaris
131 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
132 dnl Check for -lnsl for Solaris
133 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
134 dnl Check for -lsocket for Solaris
135 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
136 dnl Check for -lresolv for Solaris
137 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
138 dnl Check for -lxpg4 for FreeBSD
139 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
140 dnl Check for -lpthread
141 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
143 JPEGLIB=""
144 AC_SUBST(JPEGLIB)
145 AC_CHECK_HEADERS(jpeglib.h,
146 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
147 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
148 JPEGLIB="-ljpeg"
149 )
150 )
152 AC_SUBST(GIFLIB,"")
153 AC_CHECK_HEADERS(gif_lib.h,
154 AC_CHECK_LIB(ungif,DGifOpen,
155 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
156 GIFLIB="-lungif"],
157 [AC_CHECK_LIB(gif,DGifOpen,
158 [AC_DEFINE(HAVE_LIBGIF,1)
159 GIFLIB="-lgif"])]))
161 AC_SUBST(XLIB)
162 AC_SUBST(XFILES)
163 XFILES=""
164 AC_SUBST(OPENGLFILES)
165 OPENGLFILES=""
166 AC_SUBST(GLU32FILES)
167 GLU32FILES=""
168 AC_SUBST(OPENGL_LIBS)
169 OPENGL_LIBS=""
170 if test "$have_x" = "yes"
171 then
172 XLIB="-lXext -lX11"
173 ac_save_CPPFLAGS="$CPPFLAGS"
174 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
176 dnl *** All of the following tests require X11/Xlib.h
177 AC_CHECK_HEADERS(X11/Xlib.h,
178 [
179 AC_CHECK_HEADERS([X11/XKBlib.h \
180 X11/Xutil.h \
181 X11/extensions/shape.h \
182 X11/extensions/XShm.h \
183 X11/extensions/Xrandr.h \
184 X11/extensions/Xrender.h \
185 X11/extensions/Xvlib.h \
186 X11/extensions/xf86dga.h \
187 X11/extensions/xf86vmode.h],,,
188 [#include <X11/Xlib.h>
189 #ifdef HAVE_X11_XUTIL_H
190 # include <X11/Xutil.h>
191 #endif])
193 dnl *** Check for X keyboard extension
194 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
195 then
196 AC_CHECK_LIB(X11, XkbQueryExtension,
197 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
198 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
199 fi
201 dnl *** Check for X Shm extension
202 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
203 then
204 AC_CHECK_LIB(Xext, XShmQueryExtension,
205 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
206 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
207 fi
209 dnl *** Check for X shape extension
210 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
211 then
212 AC_CHECK_LIB(Xext,XShapeQueryExtension,
213 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
214 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
215 fi
217 dnl *** Check for XFree86 DGA / DGA 2.0 extension
218 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
219 then
220 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
221 [ dnl *** If found...
222 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
223 [Define if you have the Xxf86dga library version 2])
224 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
225 ],
226 [ dnl *** If not found, look for XF86DGAQueryExtension()
227 dnl *** instead (DGA 2.0 not found)...
228 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
229 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
230 [Define if you have the Xxf86dga library version 1])
231 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
232 ],,
233 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
234 )
235 ],
236 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
237 fi
239 dnl *** Check for XFree86 VMODE extension
240 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
241 then
242 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
243 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
244 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
245 ],,
246 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
247 fi
249 dnl *** Check for X RandR extension
250 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
251 then
252 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
253 [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
254 X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
255 ],,
256 $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
257 fi
259 dnl *** Check for XVideo extension supporting XvImages
260 if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
261 then
262 AC_CHECK_LIB(Xv, XvShmCreateImage,
263 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
264 X_PRE_LIBS="$X_PRE_LIBS -lXv"
265 ],,
266 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
267 fi
268 ]
269 ) dnl *** End of X11/Xlib.h check
271 dnl Check for the presence of OpenGL
272 if test "x$with_opengl" != "xno"
273 then
274 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
275 then
276 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
277 This prevents linking to OpenGL. Delete the file and restart configure.])
278 fi
280 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
281 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
282 then
283 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
284 dnl Check for some problems due to old Mesa versions
285 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
286 AC_TRY_COMPILE(
287 [#include <GL/gl.h>],
288 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
289 [wine_cv_opengl_version_OK="yes"],
290 [wine_cv_opengl_version_OK="no"]
291 )
292 )
294 if test "$wine_cv_opengl_version_OK" = "yes"
295 then
296 dnl Check for the presence of the library
297 AC_CHECK_LIB(GL,glXCreateContext,
298 OPENGL_LIBS="-lGL"
299 ,,
300 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
302 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
303 then
304 OPENGLFILES='$(OPENGLFILES)'
305 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
307 AC_CHECK_LIB(GL,glXGetProcAddressARB,
308 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
309 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
310 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
312 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
313 then
314 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
315 [AC_TRY_COMPILE([#include <GL/gl.h>
316 #ifdef HAVE_GL_GLEXT_H
317 # include <GL/glext.h>
318 #endif
319 ],
320 [PFNGLCOLORTABLEEXTPROC test_proc;],
321 [wine_cv_extension_prototypes="yes"],
322 [wine_cv_extension_prototypes="no"]
323 )]
324 )
325 if test "$wine_cv_extension_prototypes" = "yes"
326 then
327 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
328 [Define if the OpenGL headers define extension typedefs])
329 fi
330 fi
332 fi
333 dnl Check for GLU32 library.
334 AC_CHECK_LIB(GLU,gluLookAt,
335 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
336 GLU32FILES='$(GLU32FILES)']
337 ,,
338 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
339 )
340 fi
341 fi
342 fi
344 dnl **** Check for NAS ****
345 AC_SUBST(NASLIBS,"")
346 AC_CHECK_HEADERS(audio/audiolib.h,
347 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
348 AC_CHECK_LIB(audio,AuCreateFlow,
349 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
350 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
351 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
353 CPPFLAGS="$ac_save_CPPFLAGS"
354 XFILES='$(XFILES)'
355 else
356 XLIB=""
357 X_CFLAGS=""
358 X_LIBS=""
359 fi
361 dnl **** Check which curses lib to use ***
362 CURSESLIBS=""
363 if test "x$with_curses" != "xno"
364 then
365 AC_CHECK_HEADERS(ncurses.h,
366 [AC_CHECK_LIB(ncurses,waddch,
367 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
368 CURSESLIBS="-lncurses"],
369 [AC_CHECK_HEADERS(curses.h,
370 [AC_CHECK_LIB(curses,waddch,
371 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
372 CURSESLIBS="-lcurses"])])])])
373 saved_libs="$LIBS"
374 LIBS="$CURSESLIBS $LIBS"
375 AC_CHECK_FUNCS(getbkgd resizeterm)
376 LIBS="$saved_libs"
377 fi
378 AC_SUBST(CURSESLIBS)
380 dnl **** Check for SANE ****
381 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
382 if test "$sane_devel" = "no"
383 then
384 SANELIBS=""
385 SANEINCL=""
386 else
387 SANELIBS="`$sane_devel --libs`"
388 SANEINCL="`$sane_devel --cflags`"
389 ac_save_CPPFLAGS="$CPPFLAGS"
390 ac_save_LIBS="$LIBS"
391 CPPFLAGS="$CPPFLAGS $SANEINCL"
392 LIBS="$LIBS $SANELIBS"
393 AC_CHECK_HEADER(sane/sane.h,
394 [AC_CHECK_LIB(sane,sane_open,
395 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
396 [SANELIBS=""
397 SANEINCL=""])],
398 [SANELIBS=""
399 SANEINCL=""])
400 LIBS="$ac_save_LIBS"
401 CPPFLAGS="$ac_save_CPPFLAGS"
402 fi
403 AC_SUBST(SANELIBS)
404 AC_SUBST(SANEINCL)
406 dnl **** Check for the ICU library ****
407 AC_CHECK_HEADERS(unicode/ubidi.h)
408 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
409 then
410 AC_CACHE_CHECK([whether we can statically link the ICU libraries], ac_cv_lib_icu,
411 [saved_libs="$LIBS"
412 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
413 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
414 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
415 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
416 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
417 [ac_cv_lib_icu="yes"],[ac_cv_lib_icu="no"])
418 LIBS="$saved_libs"])
419 if test "$ac_cv_lib_icu" = "yes"
420 then
421 AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
422 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
423 fi
424 fi
426 dnl **** Check for FreeType 2 ****
427 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
428 if test "$ft_lib" = "no"
429 then
430 FREETYPEINCL=""
431 wine_cv_msg_freetype=no
432 else
433 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
434 if test "$ft_devel" = "no"
435 then
436 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
437 if test "$ft_devel2" = "freetype2-config"
438 then
439 ft_devel=$ft_devel2
440 fi
441 fi
442 if test "$ft_devel" = "no"
443 then
444 FREETYPEINCL=""
445 wine_cv_msg_freetype=yes
446 else
447 FREETYPEINCL=`$ft_devel --cflags`
448 ac_save_CPPFLAGS="$CPPFLAGS"
449 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
450 AC_CHECK_HEADERS(ft2build.h \
451 freetype/freetype.h \
452 freetype/ftglyph.h \
453 freetype/tttables.h \
454 freetype/ftnames.h \
455 freetype/ftsnames.h \
456 freetype/ttnameid.h \
457 freetype/ftoutln.h \
458 freetype/internal/sfnt.h,,,
459 [#if HAVE_FT2BUILD_H
460 #include <ft2build.h>
461 #endif])
462 AC_TRY_CPP([#include <ft2build.h>
463 #include <freetype/fttrigon.h>],
464 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
465 [Define if you have the <freetype/fttrigon.h> header file.])
466 wine_cv_fttrigon=yes],
467 wine_cv_fttrigon=no)
468 CPPFLAGS="$ac_save_CPPFLAGS"
469 dnl Check that we have at least freetype/freetype.h
470 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
471 then
472 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
473 wine_cv_msg_freetype=no
474 else
475 FREETYPEINCL=""
476 wine_cv_msg_freetype=yes
477 fi
478 fi
479 fi
480 AC_SUBST(FREETYPEINCL)
482 dnl **** Check for parport (currently Linux only) ****
483 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
484 AC_TRY_COMPILE(
485 [#include <linux/ppdev.h>],
486 [ioctl (1,PPCLAIM,0)],
487 [ac_cv_c_ppdev="yes"],
488 [ac_cv_c_ppdev="no"])
489 )
490 if test "$ac_cv_c_ppdev" = "yes"
491 then
492 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
493 fi
495 dnl **** Check for va_copy ****
496 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
497 AC_TRY_LINK(
498 [#include <stdarg.h>],
499 [va_list ap1, ap2;
500 va_copy(ap1,ap2);
501 ],
502 [ac_cv_c_va_copy="yes"],
503 [ac_cv_c_va_copy="no"])
504 )
505 if test "$ac_cv_c_va_copy" = "yes"
506 then
507 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
508 fi
509 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
510 AC_TRY_LINK(
511 [#include <stdarg.h>],
512 [va_list ap1, ap2;
513 __va_copy(ap1,ap2);
514 ],
515 [ac_cv_c___va_copy="yes"],
516 [ac_cv_c___va_copy="no"])
517 )
518 if test "$ac_cv_c___va_copy" = "yes"
519 then
520 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
521 fi
523 dnl **** Check for sigsetjmp ****
524 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
525 AC_TRY_LINK(
526 [#include <setjmp.h>],
527 [sigjmp_buf buf;
528 sigsetjmp( buf, 1 );
529 siglongjmp( buf, 1 );],
530 [ac_cv_c_sigsetjmp="yes"],
531 [ac_cv_c_sigsetjmp="no"])
532 )
533 if test "$ac_cv_c_sigsetjmp" = "yes"
534 then
535 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
536 fi
538 dnl **** Check for pthread_rwlock_t ****
539 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
540 #include <pthread.h>])
542 dnl **** Check for pthread_getattr_np ****
543 ac_save_LIBS="$LIBS"
544 LIBS="$LIBS $LIBPTHREAD"
545 AC_CHECK_FUNCS(pthread_getattr_np)
546 LIBS="$ac_save_LIBS"
548 dnl **** Check for Open Sound System ****
549 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
551 AC_CACHE_CHECK([for Open Sound System],
552 ac_cv_c_opensoundsystem,
553 AC_TRY_COMPILE([
554 #if defined(HAVE_SYS_SOUNDCARD_H)
555 #include <sys/soundcard.h>
556 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
557 #include <machine/soundcard.h>
558 #elif defined(HAVE_SOUNDCARD_H)
559 #include <soundcard.h>
560 #endif
561 ],[
563 /* check for one of the Open Sound System specific SNDCTL_ defines */
564 #if !defined(SNDCTL_DSP_STEREO)
565 #error No open sound system
566 #endif
567 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
569 if test "$ac_cv_c_opensoundsystem" = "yes"
570 then
571 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
572 fi
574 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
575 ac_cv_c_opensoundsystem_midi,
576 AC_TRY_COMPILE([
577 #if defined(HAVE_SYS_SOUNDCARD_H)
578 #include <sys/soundcard.h>
579 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
580 #include <machine/soundcard.h>
581 #elif defined(HAVE_SOUNDCARD_H)
582 #include <soundcard.h>
583 #endif
584 ],[
586 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
587 #if !defined(SNDCTL_SEQ_SYNC)
588 #error No open sound system MIDI interface
589 #endif
590 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
592 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
593 then
594 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
595 fi
597 dnl **** Check for aRts Sound Server ****
598 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
599 AC_CACHE_CHECK([for aRts Sound server],
600 ac_cv_c_artsserver,
601 if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
602 then
603 ac_cv_c_artsserver=no
604 else
605 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
606 ARTSC_LIBS=`$ARTSCCONFIG --libs`
607 ac_cv_c_artsserver=no
608 save_CFLAGS="$CFLAGS"
609 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
610 AC_TRY_COMPILE([
611 #include <artsc.h>
612 ],[
613 arts_stream_t stream;
614 ],[
615 ac_cv_c_artsserver=yes
616 ])
617 CFLAGS="$save_CFLAGS"
618 fi)
620 if test "$ac_cv_c_artsserver" = "yes"
621 then
622 AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
623 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
625 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
626 fi
628 dnl **** Check for ALSA ****
629 AC_SUBST(ALSALIBS,"")
630 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
631 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
632 then
633 AC_CHECK_LIB(asound,snd_pcm_open,
634 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
635 ALSALIBS="-lasound")
636 fi
638 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
640 AC_SUBST(AUDIOIOLIBS,"")
641 AC_CHECK_HEADERS(libaudioio.h,
642 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
643 [AUDIOIOLIBS="-laudioio"
644 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
646 dnl **** Check for capi4linux ****
648 AC_CHECK_HEADERS(capi20.h,[
649 AC_CHECK_HEADERS(linux/capi.h,[
650 AC_CHECK_LIB(capi20,capi20_register,[
651 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
652 AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
653 ])
654 ])
655 ])
657 dnl **** Check for broken glibc mmap64 ****
659 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
660 AC_TRY_RUN([
661 #define _FILE_OFFSET_BITS 64
662 #include <stdio.h>
663 #include <unistd.h>
664 #include <fcntl.h>
665 #include <sys/mman.h>
666 #include <errno.h>
668 int main(int argc,char **argv) {
669 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
670 if (fd == -1) exit(1);
672 unlink("conftest.map");
674 write(fd,"test",4);
676 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
677 (errno == EINVAL)
678 ) {
679 exit(1);
680 }
681 close(fd);
682 fprintf(stderr,"success!\n");
683 exit(0);
684 }
686 ],
687 ac_cv_mmap64_works="yes",
688 ac_cv_mmap64_works="no",
689 ac_cv_mmap64_works="no") )
691 if test "$ac_cv_mmap64_works" = "yes"
692 then
693 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
694 fi
696 dnl **** Check for gcc specific options ****
698 AC_SUBST(EXTRACFLAGS,"")
699 if test "x${GCC}" = "xyes"
700 then
701 EXTRACFLAGS=-Wall
703 dnl Check for strength-reduce bug
704 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
705 AC_TRY_RUN([
706 int L[[4]] = {0,1,2,3};
707 int main(void) {
708 static int Array[[3]];
709 unsigned int B = 3;
710 int i;
711 for(i=0; i<B; i++) Array[[i]] = i - 3;
712 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
713 L[[i]] = 4;
715 exit( Array[[1]] != -2 || L[[2]] != 3);
716 }],
717 ac_cv_c_gcc_strength_bug="no",
718 ac_cv_c_gcc_strength_bug="yes",
719 ac_cv_c_gcc_strength_bug="yes") )
720 if test "$ac_cv_c_gcc_strength_bug" = "yes"
721 then
722 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
723 fi
725 dnl Check for -mpreferred-stack-boundary
726 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
727 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
728 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
729 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
730 then
731 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
732 fi
734 dnl Check for -fno-strict-aliasing
735 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
736 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
737 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
738 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
739 then
740 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
741 fi
743 dnl Check for -gstabs+ option
744 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
745 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
746 if test "$ac_cv_c_gcc_gstabs" = "yes"
747 then
748 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
749 fi
751 dnl Check for noisy string.h
752 saved_CFLAGS="$CFLAGS"
753 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
754 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
755 AC_TRY_COMPILE([#include <string.h>],[],
756 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
757 CFLAGS="$saved_CFLAGS"
758 if test "$ac_cv_c_string_h_warnings" = "no"
759 then
760 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
761 fi
762 fi
764 dnl **** Check how to define a function in assembly code ****
766 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
767 WINE_TRY_ASM_LINK(
768 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
769 ac_cv_asm_func_def=".def",
770 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
771 ac_cv_asm_func_def=".type @function",
772 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
773 ac_cv_asm_func_def=".type 2",
774 ac_cv_asm_func_def="unknown")])]))
776 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
777 case "$ac_cv_asm_func_def" in
778 ".def")
779 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
780 ".type @function")
781 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
782 ".type 2")
783 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
784 *)
785 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
786 esac
788 dnl **** Check for underscore on external symbols ****
790 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
791 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
792 [extern int ac_test;],
793 [if (ac_test) return 1],
794 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
796 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
797 if test "$ac_cv_c_extern_prefix" = "yes"
798 then
799 AC_DEFINE([__ASM_NAME(name)], ["_" name])
800 else
801 AC_DEFINE([__ASM_NAME(name)], [name])
802 fi
804 dnl **** Check how to do strings in assembler ****
806 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
807 WINE_TRY_ASM_LINK([".data\n\t.string \"test\"\n\t.text"],,,
808 ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
809 if test "$ac_cv_c_asm_string" = "yes"
810 then
811 AC_DEFINE(__ASM_STRING, [".string"], [Define to the assembler keyword used to specify an ASCII string])
812 else
813 AC_CACHE_CHECK([whether assembler accepts .asciz], ac_cv_c_asm_asciz,
814 WINE_TRY_ASM_LINK([".data\n\t.asciz \"test\"\n\t.text"],,,
815 ac_cv_c_asm_asciz="yes",ac_cv_c_asm_asciz="no"))
816 if test "$ac_cv_c_asm_asciz" = "yes"
817 then
818 AC_DEFINE(__ASM_STRING, [".asciz"])
819 else
820 AC_DEFINE(__ASM_STRING, [".ascii"])
821 fi
822 fi
824 dnl **** Check for .short in assembler ****
826 AC_CACHE_CHECK([whether assembler accepts .short], ac_cv_c_asm_short,
827 WINE_TRY_ASM_LINK([".data\n\t.short 1\n\t.text"],,,
828 ac_cv_c_asm_short="yes",ac_cv_c_asm_short="no"))
829 if test "$ac_cv_c_asm_short" = "yes"
830 then
831 AC_DEFINE(__ASM_SHORT, [".short"], [Define to the assembler keyword used to specify a word value])
832 else
833 AC_DEFINE(__ASM_SHORT, [".half"])
834 fi
836 dnl **** Check for working dll ****
838 AC_SUBST(DLLEXT,"")
839 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
840 AC_SUBST(DLLIBS,"")
841 AC_SUBST(LDSHARED,"")
842 AC_SUBST(LDDLL,"")
843 AC_SUBST(LIBEXT,"so")
844 AC_SUBST(IMPLIBEXT,"def")
846 case $host_os in
847 cygwin*|mingw32*)
848 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
849 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
850 if test "$DLLWRAP" = "false"; then
851 LIBEXT="a"
852 else
853 dnl FIXME - check whether dllwrap works correctly...
854 LIBEXT="dll"
855 fi
856 IMPLIBEXT="a"
857 ;;
858 *)
859 AC_CHECK_HEADERS(dlfcn.h,
860 [AC_CHECK_FUNCS(dlopen,,
861 [AC_CHECK_LIB(dl,dlopen,
862 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
863 DLLIBS="-ldl"],
864 [LIBEXT="a"])])],
865 [LIBEXT="a"])
867 if test "$LIBEXT" = "so"
868 then
869 DLLFLAGS="$DLLFLAGS -fPIC"
870 DLLEXT=".so"
871 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
872 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
873 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
874 if test "$ac_cv_c_dll_gnuelf" = "yes"
875 then
876 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
877 LDDLL="\$(CC) -shared -Wl,-Bsymbolic"
878 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
879 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
880 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
881 if test "$ac_cv_c_dll_zdefs" = "yes"
882 then
883 LDDLL="$LDDLL,-z,defs"
884 fi
885 AC_CACHE_CHECK([whether we can relocate the executable to 0x3c000000], ac_cv_ld_reloc_exec,
886 [saved_CFLAGS="$CFLAGS"
887 CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x3c000100"
888 AC_TRY_RUN([#include <unistd.h>
889 int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
890 ac_cv_ld_reloc_exec="yes",
891 ac_cv_ld_reloc_exec="no",
892 ac_cv_ld_reloc_exec="no")
893 CFLAGS="$saved_CFLAGS"])
894 if test "$ac_cv_ld_reloc_exec" = "yes"
895 then
896 AC_SUBST(LDEXECFLAGS,["-Wl,--section-start,.interp=0x3c000100"])
897 fi
898 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
899 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
900 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
901 if test "$ac_cv_c_export_dynamic" = "yes"
902 then
903 LDEXECFLAGS="$LDEXECFLAGS -Wl,--export-dynamic"
904 fi
905 else
906 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
907 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
908 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
909 if test "$ac_cv_c_dll_unixware" = "yes"
910 then
911 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
912 LDDLL="\$(CC) -Wl,-G,-B,symbolic"
913 fi
914 fi
915 fi
917 dnl Check for cross compiler to build test programs
918 AC_SUBST(CROSSTEST,"")
919 if test "$cross_compiling" = "no"
920 then
921 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc,false)
922 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool,false)
923 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres,false)
924 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
925 fi
926 ;;
927 esac
929 if test "$LIBEXT" = "a"; then
930 AC_MSG_ERROR(
931 [could not find a way to build shared libraries.
932 It is currently not possible to build Wine without shared library
933 (.so) support to allow transparent switch between .so and .dll files.
934 If you are using Linux, you will need a newer binutils.]
935 )
936 fi
938 case $build_os in
939 cygwin*|mingw32*)
940 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
941 *)
942 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
943 esac
945 dnl Mingw needs explicit msvcrt for linking libwine
946 case $host_os in
947 mingw32*)
948 AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
949 esac
951 case $host_os in
952 linux*)
953 AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
954 AC_SUBST(MAIN_BINARY,"wine-glibc")
955 ;;
956 *)
957 AC_SUBST(WINE_BINARIES,"wine-kthread")
958 AC_SUBST(MAIN_BINARY,"wine-kthread")
959 ;;
960 esac
962 dnl **** Get the soname for libraries that we load dynamically ****
964 if test "$LIBEXT" = "so"
965 then
966 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
967 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
968 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
969 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
970 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
971 WINE_GET_SONAME(cups,cupsGetDefault)
972 WINE_GET_SONAME(jack,jack_client_new)
973 WINE_GET_SONAME(fontconfig,FcInit)
974 WINE_GET_SONAME(ssl,SSL_library_init)
975 WINE_GET_SONAME(crypto,BIO_new_socket)
976 WINE_GET_SONAME(ncurses,waddch)
977 WINE_GET_SONAME(curses,waddch)
978 fi
981 dnl **** Check for functions ****
983 AC_FUNC_ALLOCA()
984 AC_CHECK_FUNCS(\
985 _lwp_create \
986 _lwp_self \
987 _pclose \
988 _popen \
989 _snprintf \
990 _spawnvp \
991 _stricmp \
992 _strnicmp \
993 _vsnprintf \
994 chsize \
995 clone \
996 finite \
997 fpclass \
998 ftruncate \
999 ftruncate64 \
1000 getnetbyaddr \
1001 getnetbyname \
1002 getopt_long \
1003 getpagesize \
1004 getprotobyname \
1005 getprotobynumber \
1006 getpwuid \
1007 getservbyport \
1008 gettid \
1009 gettimeofday \
1010 inet_network \
1011 lseek64 \
1012 lstat \
1013 memmove \
1014 mmap \
1015 pclose \
1016 popen \
1017 pread \
1018 pwrite \
1019 rfork \
1020 select \
1021 sendmsg \
1022 settimeofday \
1023 sigaltstack \
1024 snprintf \
1025 spawnvp \
1026 statfs \
1027 strcasecmp \
1028 strerror \
1029 strncasecmp \
1030 tcgetattr \
1031 timegm \
1032 usleep \
1033 vfscanf \
1034 vsnprintf \
1035 wait4 \
1036 waitpid \
1037 )
1039 dnl **** Check for header files ****
1041 AC_CHECK_HEADERS(\
1042 arpa/inet.h \
1043 arpa/nameser.h \
1044 cups/cups.h \
1045 direct.h \
1046 elf.h \
1047 float.h \
1048 fontconfig/fontconfig.h \
1049 getopt.h \
1050 ieeefp.h \
1051 io.h \
1052 jack/jack.h \
1053 libio.h \
1054 libutil.h \
1055 link.h \
1056 linux/cdrom.h \
1057 linux/hdreg.h \
1058 linux/input.h \
1059 linux/joystick.h \
1060 linux/major.h \
1061 linux/param.h \
1062 linux/serial.h \
1063 linux/ucdrom.h \
1064 machine/cpu.h \
1065 netdb.h \
1066 netinet/in.h \
1067 netinet/in_systm.h \
1068 netinet/tcp.h \
1069 netinet/tcp_fsm.h \
1070 openssl/ssl.h \
1071 process.h \
1072 pthread.h \
1073 pty.h \
1074 pwd.h \
1075 regex.h \
1076 sched.h \
1077 scsi/sg.h \
1078 scsi/scsi.h \
1079 scsi/scsi_ioctl.h \
1080 socket.h \
1081 stdint.h \
1082 strings.h \
1083 sys/cdio.h \
1084 sys/errno.h \
1085 sys/file.h \
1086 sys/filio.h \
1087 sys/inttypes.h \
1088 sys/ioctl.h \
1089 sys/ipc.h \
1090 sys/link.h \
1091 sys/lwp.h \
1092 sys/mman.h \
1093 sys/modem.h \
1094 sys/msg.h \
1095 sys/param.h \
1096 sys/poll.h \
1097 sys/ptrace.h \
1098 sys/reg.h \
1099 sys/scsiio.h \
1100 sys/shm.h \
1101 sys/signal.h \
1102 sys/socket.h \
1103 sys/sockio.h \
1104 sys/statfs.h \
1105 sys/strtio.h \
1106 sys/syscall.h \
1107 sys/sysctl.h \
1108 sys/time.h \
1109 sys/times.h \
1110 sys/uio.h \
1111 sys/un.h \
1112 sys/v86.h \
1113 sys/v86intr.h \
1114 sys/vfs.h \
1115 sys/vm86.h \
1116 sys/wait.h \
1117 syscall.h \
1118 termios.h \
1119 unistd.h \
1120 utime.h \
1121 valgrind/memcheck.h
1122 )
1123 AC_HEADER_STAT()
1125 dnl **** Checks for headers that depend on other ones ****
1127 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1128 [#include <sys/types.h>
1129 #if HAVE_SYS_PARAM_H
1130 # include <sys/param.h>
1131 #endif])
1133 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1134 [#include <sys/types.h>
1135 #if HAVE_SYS_SOCKET_H
1136 # include <sys/socket.h>
1137 #endif])
1139 AC_CHECK_HEADERS([resolv.h],,,
1140 [#include <sys/types.h>
1141 #if HAVE_SYS_SOCKET_H
1142 # include <sys/socket.h>
1143 #endif
1144 #if HAVE_NETINET_IN_H
1145 # include <netinet/in.h>
1146 #endif
1147 #if HAVE_ARPA_NAMESER_H
1148 # include <arpa/nameser.h>
1149 #endif])
1151 AC_CHECK_HEADERS(netinet/ip.h,,,
1152 [#include <sys/types.h>
1153 #if HAVE_SYS_SOCKET_H
1154 # include <sys/socket.h>
1155 #endif
1156 #if HAVE_NETINET_IN_SYSTM_H
1157 # include <netinet/in_systm.h>
1158 #endif])
1160 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1162 dnl **** Check for IPX headers (currently Linux only) ****
1164 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1165 AC_TRY_COMPILE(
1166 [#include <sys/types.h>
1167 #ifdef HAVE_SYS_SOCKET_H
1168 # include <sys/socket.h>
1169 #endif
1170 #include <netipx/ipx.h>],
1171 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1172 [ac_cv_c_ipx_gnu="yes"],
1173 [ac_cv_c_ipx_gnu="no"])
1174 )
1175 if test "$ac_cv_c_ipx_gnu" = "yes"
1176 then
1177 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1178 fi
1180 if test "$ac_cv_c_ipx_gnu" = "no"
1181 then
1182 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1183 AC_TRY_COMPILE(
1184 [#include <sys/types.h>
1185 #ifdef HAVE_SYS_SOCKET_H
1186 # include <sys/socket.h>
1187 #endif
1188 #include <asm/types.h>
1189 #include <linux/ipx.h>],
1190 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1191 [ac_cv_c_ipx_linux="yes"],
1192 [ac_cv_c_ipx_linux="no"])
1193 )
1194 if test "$ac_cv_c_ipx_linux" = "yes"
1195 then
1196 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1197 fi
1198 fi
1200 dnl **** Check for types ****
1202 AC_C_CONST
1203 AC_C_INLINE
1204 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1205 AC_CHECK_SIZEOF(long long,0)
1207 AC_CACHE_CHECK([whether linux/input.h is for real],
1208 wine_cv_linux_input_h,
1209 AC_TRY_COMPILE([
1210 #include <linux/input.h>
1211 ] , [
1212 int foo = EVIOCGBIT(EV_ABS,42);
1213 int bar = BTN_PINKIE;
1214 int fortytwo = 42;
1215 ],
1216 wine_cv_linux_input_h=yes,
1217 wine_cv_linux_input_h=no,
1218 no
1219 )
1220 )
1221 if test "$wine_cv_linux_input_h" = "yes"
1222 then
1223 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1224 [Define if we have linux/input.h AND it contains the INPUT event API])
1225 fi
1228 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1229 wine_cv_linux_gethostbyname_r_6,
1230 AC_TRY_COMPILE([
1231 #include <netdb.h>
1232 ], [
1233 char *name=NULL;
1234 struct hostent he;
1235 struct hostent *result;
1236 char *buf=NULL;
1237 int bufsize=0;
1238 int res,errnr;
1239 char *addr=NULL;
1240 int addrlen=0;
1241 int addrtype=0;
1242 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1243 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1244 ],
1245 wine_cv_linux_gethostbyname_r_6=yes,
1246 wine_cv_linux_gethostbyname_r_6=no
1247 )
1248 )
1249 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1250 then
1251 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1252 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1253 fi
1255 if test "$ac_cv_header_linux_joystick_h" = "yes"
1256 then
1257 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1258 wine_cv_linux_joystick_22_api,
1259 AC_TRY_COMPILE([
1260 #include <sys/ioctl.h>
1261 #include <linux/joystick.h>
1263 struct js_event blub;
1264 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1265 #error "no 2.2 header"
1266 #endif
1267 ],/*empty*/,
1268 wine_cv_linux_joystick_22_api=yes,
1269 wine_cv_linux_joystick_22_api=no,
1270 wine_cv_linux_joystick_22_api=no
1271 )
1272 )
1273 if test "$wine_cv_linux_joystick_22_api" = "yes"
1274 then
1275 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1276 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1277 fi
1278 fi
1280 dnl **** statfs checks ****
1282 if test "$ac_cv_header_sys_vfs_h" = "yes"
1283 then
1284 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1285 wine_cv_sys_vfs_has_statfs,
1286 AC_TRY_COMPILE([
1287 #include <sys/types.h>
1288 #ifdef HAVE_SYS_PARAM_H
1289 # include <sys/param.h>
1290 #endif
1291 #include <sys/vfs.h>
1292 ],[
1293 struct statfs stfs;
1295 memset(&stfs,0,sizeof(stfs));
1296 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1297 )
1298 )
1299 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1300 then
1301 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1302 [Define if the struct statfs is defined by <sys/vfs.h>])
1303 fi
1304 fi
1306 if test "$ac_cv_header_sys_statfs_h" = "yes"
1307 then
1308 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1309 wine_cv_sys_statfs_has_statfs,
1310 AC_TRY_COMPILE([
1311 #include <sys/types.h>
1312 #ifdef HAVE_SYS_PARAM_H
1313 # include <sys/param.h>
1314 #endif
1315 #include <sys/statfs.h>
1316 ],[
1317 struct statfs stfs;
1318 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1319 )
1320 )
1321 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1322 then
1323 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1324 [Define if the struct statfs is defined by <sys/statfs.h>])
1325 fi
1326 fi
1328 if test "$ac_cv_header_sys_mount_h" = "yes"
1329 then
1330 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1331 wine_cv_sys_mount_has_statfs,
1332 AC_TRY_COMPILE([
1333 #include <sys/types.h>
1334 #ifdef HAVE_SYS_PARAM_H
1335 # include <sys/param.h>
1336 #endif
1337 #include <sys/mount.h>
1338 ],[
1339 struct statfs stfs;
1340 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1341 )
1342 )
1343 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1344 then
1345 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1346 [Define if the struct statfs is defined by <sys/mount.h>])
1347 fi
1348 fi
1350 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1352 dnl Check for statfs members
1353 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail],,,
1354 [#include <sys/types.h>
1355 #ifdef HAVE_SYS_PARAM_H
1356 # include <sys/param.h>
1357 #endif
1358 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1359 # include <sys/mount.h>
1360 #else
1361 # ifdef STATFS_DEFINED_BY_SYS_VFS
1362 # include <sys/vfs.h>
1363 # else
1364 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1365 # include <sys/statfs.h>
1366 # endif
1367 # endif
1368 #endif])
1370 dnl Check for socket structure members
1371 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1372 [#include <sys/types.h>
1373 #ifdef HAVE_SYS_SOCKET_H
1374 # include <sys/socket.h>
1375 #endif
1376 #ifdef HAVE_SYS_UN_H
1377 # include <sys/un.h>
1378 #endif])
1380 dnl Check for siginfo_t members
1381 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1383 dnl Check for struct option
1384 AC_CHECK_MEMBERS([struct option.name],,,
1385 [#ifdef HAVE_GETOPT_H
1386 #include <getopt.h>
1387 #endif])
1389 dnl Check for stat.st_blocks
1390 AC_CHECK_MEMBERS([struct stat.st_blocks])
1392 dnl *** check for the need to define platform-specific symbols
1394 case $host_cpu in
1395 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1396 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1397 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1398 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1399 esac
1401 case $host_vendor in
1402 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1403 esac
1405 dnl **** Generate output files ****
1407 AH_TOP([#define __WINE_CONFIG_H])
1409 WINE_CONFIG_EXTRA_DIR(controls)
1410 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1411 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1412 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1413 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1414 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1415 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1416 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1417 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1418 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1419 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1420 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1421 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1422 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1423 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1424 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1425 WINE_CONFIG_EXTRA_DIR(files)
1426 WINE_CONFIG_EXTRA_DIR(graphics)
1427 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1428 WINE_CONFIG_EXTRA_DIR(include/wine)
1429 WINE_CONFIG_EXTRA_DIR(misc)
1430 WINE_CONFIG_EXTRA_DIR(objects)
1431 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1432 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1433 WINE_CONFIG_EXTRA_DIR(windows)
1435 MAKE_RULES=Make.rules
1436 AC_SUBST_FILE(MAKE_RULES)
1438 MAKE_DLL_RULES=dlls/Makedll.rules
1439 AC_SUBST_FILE(MAKE_DLL_RULES)
1441 MAKE_TEST_RULES=dlls/Maketest.rules
1442 AC_SUBST_FILE(MAKE_TEST_RULES)
1444 MAKE_LIB_RULES=libs/Makelib.rules
1445 AC_SUBST_FILE(MAKE_LIB_RULES)
1447 MAKE_PROG_RULES=programs/Makeprog.rules
1448 AC_SUBST_FILE(MAKE_PROG_RULES)
1450 AC_CONFIG_FILES([
1451 Make.rules
1452 dlls/Makedll.rules
1453 dlls/Maketest.rules
1454 libs/Makelib.rules
1455 programs/Makeprog.rules
1456 Makefile
1457 dlls/Makefile
1458 dlls/advapi32/Makefile
1459 dlls/advapi32/tests/Makefile
1460 dlls/avicap32/Makefile
1461 dlls/avifil32/Makefile
1462 dlls/cabinet/Makefile
1463 dlls/capi2032/Makefile
1464 dlls/cfgmgr32/Makefile
1465 dlls/comcat/Makefile
1466 dlls/comctl32/Makefile
1467 dlls/comctl32/tests/Makefile
1468 dlls/commdlg/Makefile
1469 dlls/crtdll/Makefile
1470 dlls/crypt32/Makefile
1471 dlls/ctl3d/Makefile
1472 dlls/wined3d/Makefile
1473 dlls/d3d8/Makefile
1474 dlls/d3d9/Makefile
1475 dlls/d3dim/Makefile
1476 dlls/d3dx8/Makefile
1477 dlls/dciman32/Makefile
1478 dlls/ddraw/Makefile
1479 dlls/ddraw/tests/Makefile
1480 dlls/devenum/Makefile
1481 dlls/dinput/Makefile
1482 dlls/dinput8/Makefile
1483 dlls/dmband/Makefile
1484 dlls/dmcompos/Makefile
1485 dlls/dmime/Makefile
1486 dlls/dmloader/Makefile
1487 dlls/dmscript/Makefile
1488 dlls/dmstyle/Makefile
1489 dlls/dmsynth/Makefile
1490 dlls/dmusic/Makefile
1491 dlls/dmusic32/Makefile
1492 dlls/dplay/Makefile
1493 dlls/dplayx/Makefile
1494 dlls/dpnhpast/Makefile
1495 dlls/dsound/Makefile
1496 dlls/dsound/tests/Makefile
1497 dlls/gdi/Makefile
1498 dlls/gdi/tests/Makefile
1499 dlls/glu32/Makefile
1500 dlls/icmp/Makefile
1501 dlls/imagehlp/Makefile
1502 dlls/imm32/Makefile
1503 dlls/iphlpapi/Makefile
1504 dlls/kernel/Makefile
1505 dlls/kernel/tests/Makefile
1506 dlls/lzexpand/Makefile
1507 dlls/mapi32/Makefile
1508 dlls/mpr/Makefile
1509 dlls/msacm/Makefile
1510 dlls/msacm/imaadp32/Makefile
1511 dlls/msacm/msadp32/Makefile
1512 dlls/msacm/msg711/Makefile
1513 dlls/msacm/winemp3/Makefile
1514 dlls/msdmo/Makefile
1515 dlls/mshtml/Makefile
1516 dlls/msi/Makefile
1517 dlls/msimg32/Makefile
1518 dlls/msisys/Makefile
1519 dlls/msnet32/Makefile
1520 dlls/msvcrt/Makefile
1521 dlls/msvcrt/tests/Makefile
1522 dlls/msvcrt20/Makefile
1523 dlls/msvcrtd/Makefile
1524 dlls/msvideo/Makefile
1525 dlls/msvideo/msrle32/Makefile
1526 dlls/mswsock/Makefile
1527 dlls/netapi32/Makefile
1528 dlls/netapi32/tests/Makefile
1529 dlls/ntdll/Makefile
1530 dlls/ntdll/tests/Makefile
1531 dlls/odbc32/Makefile
1532 dlls/ole32/Makefile
1533 dlls/oleacc/Makefile
1534 dlls/oleaut32/Makefile
1535 dlls/oleaut32/tests/Makefile
1536 dlls/olecli/Makefile
1537 dlls/oledlg/Makefile
1538 dlls/olepro32/Makefile
1539 dlls/olesvr/Makefile
1540 dlls/opengl32/Makefile
1541 dlls/psapi/Makefile
1542 dlls/qcap/Makefile
1543 dlls/quartz/Makefile
1544 dlls/rasapi32/Makefile
1545 dlls/richedit/Makefile
1546 dlls/rpcrt4/Makefile
1547 dlls/rpcrt4/tests/Makefile
1548 dlls/serialui/Makefile
1549 dlls/setupapi/Makefile
1550 dlls/shdocvw/Makefile
1551 dlls/shell32/Makefile
1552 dlls/shell32/tests/Makefile
1553 dlls/shfolder/Makefile
1554 dlls/shlwapi/Makefile
1555 dlls/shlwapi/tests/Makefile
1556 dlls/snmpapi/Makefile
1557 dlls/sti/Makefile
1558 dlls/tapi32/Makefile
1559 dlls/ttydrv/Makefile
1560 dlls/twain/Makefile
1561 dlls/url/Makefile
1562 dlls/urlmon/Makefile
1563 dlls/urlmon/tests/Makefile
1564 dlls/user/Makefile
1565 dlls/user/tests/Makefile
1566 dlls/uxtheme/Makefile
1567 dlls/version/Makefile
1568 dlls/win32s/Makefile
1569 dlls/winaspi/Makefile
1570 dlls/winedos/Makefile
1571 dlls/wineps/Makefile
1572 dlls/wininet/Makefile
1573 dlls/wininet/tests/Makefile
1574 dlls/winmm/Makefile
1575 dlls/winmm/joystick/Makefile
1576 dlls/winmm/mcianim/Makefile
1577 dlls/winmm/mciavi/Makefile
1578 dlls/winmm/mcicda/Makefile
1579 dlls/winmm/mciseq/Makefile
1580 dlls/winmm/mciwave/Makefile
1581 dlls/winmm/midimap/Makefile
1582 dlls/winmm/tests/Makefile
1583 dlls/winmm/wavemap/Makefile
1584 dlls/winmm/winealsa/Makefile
1585 dlls/winmm/winearts/Makefile
1586 dlls/winmm/wineaudioio/Makefile
1587 dlls/winmm/winenas/Makefile
1588 dlls/winmm/winejack/Makefile
1589 dlls/winmm/wineoss/Makefile
1590 dlls/winnls/Makefile
1591 dlls/winsock/Makefile
1592 dlls/winsock/tests/Makefile
1593 dlls/winspool/Makefile
1594 dlls/winspool/tests/Makefile
1595 dlls/wintab32/Makefile
1596 dlls/wintrust/Makefile
1597 dlls/wow32/Makefile
1598 dlls/wsock32/Makefile
1599 dlls/x11drv/Makefile
1600 documentation/Makefile
1601 include/Makefile
1602 libs/Makefile
1603 libs/port/Makefile
1604 libs/unicode/Makefile
1605 libs/uuid/Makefile
1606 libs/wine/Makefile
1607 libs/wpp/Makefile
1608 loader/Makefile
1609 programs/Makefile
1610 programs/avitools/Makefile
1611 programs/clock/Makefile
1612 programs/cmdlgtst/Makefile
1613 programs/control/Makefile
1614 programs/expand/Makefile
1615 programs/notepad/Makefile
1616 programs/osversioncheck/Makefile
1617 programs/progman/Makefile
1618 programs/regapi/Makefile
1619 programs/regedit/Makefile
1620 programs/regsvr32/Makefile
1621 programs/regtest/Makefile
1622 programs/rpcss/Makefile
1623 programs/rundll32/Makefile
1624 programs/start/Makefile
1625 programs/uninstaller/Makefile
1626 programs/view/Makefile
1627 programs/wcmd/Makefile
1628 programs/wineboot/Makefile
1629 programs/winecfg/Makefile
1630 programs/wineconsole/Makefile
1631 programs/winedbg/Makefile
1632 programs/winefile/Makefile
1633 programs/winemenubuilder/Makefile
1634 programs/winemine/Makefile
1635 programs/winepath/Makefile
1636 programs/winevdm/Makefile
1637 programs/winhelp/Makefile
1638 programs/winver/Makefile
1639 server/Makefile
1640 tools/Makefile
1641 tools/widl/Makefile
1642 tools/winapi/Makefile
1643 tools/winebuild/Makefile
1644 tools/winedump/Makefile
1645 tools/winegcc/Makefile
1646 tools/wmc/Makefile
1647 tools/wrc/Makefile])
1649 AC_OUTPUT
1651 if test "$have_x" = "no"
1652 then
1653 echo
1654 echo "*** Warning: X development files not found. Wine will be built without"
1655 echo "*** X support, which currently does not work, and would probably not be"
1656 echo "*** what you want anyway. You will need to install devel packages of"
1657 echo "*** Xlib/Xfree86 at the very least."
1658 fi
1660 if test "$wine_cv_opengl_version_OK" = "no"
1661 then
1662 echo
1663 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1664 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1665 fi
1667 if test "$wine_cv_msg_freetype" = "yes"
1668 then
1669 echo
1670 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1671 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1672 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1673 echo "*** enable Wine to use TrueType fonts."
1674 fi
1676 echo
1677 echo "Configure finished. Do 'make depend && make' to compile Wine."
1678 echo
1680 dnl Local Variables:
1681 dnl comment-start: "dnl "
1682 dnl comment-end: ""
1683 dnl comment-start-skip: "\\bdnl\\b\\s *"
1684 dnl compile-command: "autoconf"
1685 dnl End: