| blob | bb55fad83b8658cebb99062f17a206656e9aa65d |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
26 if test "x$enable_win16" = "xno"
27 then
28 WIN16_FILES=""
29 WIN16_INSTALL=""
30 fi
32 AC_SUBST(DLLDEFS,"")
33 if test "x$enable_debug" = "xno"
34 then
35 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
36 fi
37 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
38 then
39 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
40 fi
42 dnl **** Check for some programs ****
44 AC_CANONICAL_HOST
45 case $host in
46 x86_64*linux*)
47 if test "x$enable_win64" != "xyes"
48 then
49 test -n "$CC" || CC="gcc -m32"
50 test -n "$LD" || LD="ld -m elf_i386"
51 test -n "$AS" || AS="as --32"
52 host_cpu="i386"
53 fi
54 ;;
55 esac
57 AC_PROG_MAKE_SET
58 AC_PROG_CC
59 AC_PROG_CXX
60 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
61 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
63 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
64 [if test -z "$with_wine_tools"; then
65 if test "$cross_compiling" = "yes"; then
66 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
67 else
68 wine_cv_toolsdir="\$(TOPOBJDIR)"
69 fi
70 elif test -d "$with_wine_tools/tools/winebuild"; then
71 case $with_wine_tools in
72 /*) wine_cv_toolsdir="$with_wine_tools" ;;
73 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
74 esac
75 else
76 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
77 fi])
78 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
80 AC_PATH_XTRA
81 AC_PROG_LEX
83 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
84 dnl **** without one present.
85 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
86 if test "$XLEX" = "none"
87 then
88 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
89 fi
91 dnl Check for bison
92 AC_CHECK_PROGS(BISON,bison,none)
93 if test "$BISON" = "none"
94 then
95 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
96 fi
98 AC_CHECK_TOOLS(AS,[gas as],as)
99 AC_CHECK_TOOL(LD,ld,ld)
100 AC_CHECK_TOOL(AR,ar,ar)
101 AC_PROG_RANLIB
102 AC_CHECK_TOOL(STRIP,strip,strip)
103 AC_CHECK_TOOL(WINDRES,windres,false)
104 AC_PROG_LN_S
105 WINE_PROG_LN
106 AC_PROG_EGREP
107 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
108 AC_PROG_INSTALL
109 dnl Prepend src dir to install path dir if it's a relative path
110 case "$INSTALL" in
111 [[\\/$]]* | ?:[[\\/]]* ) ;;
112 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
113 esac
115 dnl Check for lint
116 AC_CHECK_PROGS(LINT, lclint lint)
117 if test "$LINT" = "lint"
118 then
119 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
120 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
121 fi
122 AC_SUBST(LINT)
123 AC_SUBST(LINTFLAGS)
125 dnl Check for various programs
126 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
128 dnl **** Check for some libraries ****
130 dnl Check for -li386 for NetBSD and OpenBSD
131 AC_CHECK_LIB(i386,i386_set_ldt)
132 dnl Check for -lossaudio for NetBSD
133 AC_CHECK_LIB(ossaudio,_oss_ioctl)
134 dnl Check for -lw for Solaris
135 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
136 dnl Check for -lnsl for Solaris
137 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
138 dnl Check for -lsocket for Solaris
139 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
140 dnl Check for -lresolv for Solaris
141 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
142 dnl Check for -lxpg4 for FreeBSD
143 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
144 dnl Check for -lpoll for Mac OS X/Darwin
145 AC_CHECK_LIB(poll,poll)
146 dnl Check for -lresolv for Mac OS X/Darwin
147 AC_CHECK_LIB(resolv,res_9_init)
148 dnl Check for -lpthread
149 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
151 AC_SUBST(XLIB)
152 AC_SUBST(XFILES)
153 XFILES=""
154 AC_SUBST(OPENGLFILES)
155 OPENGLFILES=""
156 AC_SUBST(GLU32FILES)
157 GLU32FILES=""
158 AC_SUBST(OPENGL_LIBS)
159 OPENGL_LIBS=""
161 dnl **** Check for header files ****
163 AC_CHECK_HEADERS(\
164 arpa/inet.h \
165 arpa/nameser.h \
166 asm/types.h \
167 cups/cups.h \
168 direct.h \
169 elf.h \
170 float.h \
171 fontconfig/fontconfig.h \
172 getopt.h \
173 gif_lib.h \
174 ieeefp.h \
175 io.h \
176 jack/jack.h \
177 jpeglib.h \
178 lcms/lcms.h \
179 lcms.h \
180 link.h \
181 linux/cdrom.h \
182 linux/compiler.h \
183 linux/hdreg.h \
184 linux/input.h \
185 linux/ioctl.h \
186 linux/joystick.h \
187 linux/major.h \
188 linux/param.h \
189 linux/serial.h \
190 linux/ucdrom.h \
191 mach/machine.h \
192 machine/cpu.h \
193 machine/limits.h \
194 mntent.h \
195 netdb.h \
196 netinet/in.h \
197 netinet/in_systm.h \
198 netinet/tcp.h \
199 netinet/tcp_fsm.h \
200 openssl/ssl.h \
201 poll.h \
202 process.h \
203 pthread.h \
204 pwd.h \
205 regex.h \
206 sched.h \
207 scsi/sg.h \
208 scsi/scsi.h \
209 scsi/scsi_ioctl.h \
210 stdint.h \
211 strings.h \
212 sys/cdio.h \
213 sys/elf32.h \
214 sys/errno.h \
215 sys/epoll.h \
216 sys/exec_elf.h \
217 sys/filio.h \
218 sys/ioctl.h \
219 sys/ipc.h \
220 sys/link.h \
221 sys/lwp.h \
222 sys/mman.h \
223 sys/modem.h \
224 sys/msg.h \
225 sys/param.h \
226 sys/poll.h \
227 sys/ptrace.h \
228 sys/reg.h \
229 sys/scsiio.h \
230 sys/shm.h \
231 sys/signal.h \
232 sys/socket.h \
233 sys/sockio.h \
234 sys/statfs.h \
235 sys/statvfs.h \
236 sys/strtio.h \
237 sys/syscall.h \
238 sys/sysctl.h \
239 sys/time.h \
240 sys/times.h \
241 sys/uio.h \
242 sys/un.h \
243 sys/vfs.h \
244 sys/vm86.h \
245 sys/wait.h \
246 syscall.h \
247 termios.h \
248 unistd.h \
249 utime.h \
250 valgrind/memcheck.h
251 )
252 AC_HEADER_STAT()
254 dnl **** Check for X11 ****
256 if test "$have_x" = "yes"
257 then
258 XLIB="-lXext -lX11"
259 ac_save_CPPFLAGS="$CPPFLAGS"
260 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
262 dnl *** All of the following tests require X11/Xlib.h
263 AC_CHECK_HEADERS(X11/Xlib.h,
264 [
265 AC_CHECK_HEADERS([X11/XKBlib.h \
266 X11/Xutil.h \
267 X11/extensions/shape.h \
268 X11/extensions/XInput.h \
269 X11/extensions/XShm.h \
270 X11/extensions/Xrandr.h \
271 X11/extensions/Xrender.h \
272 X11/extensions/xf86dga.h \
273 X11/extensions/xf86vmode.h],,,
274 [#include <X11/Xlib.h>
275 #ifdef HAVE_X11_XUTIL_H
276 # include <X11/Xutil.h>
277 #endif])
279 dnl *** Check for X keyboard extension
280 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
281 then
282 AC_CHECK_LIB(X11, XkbQueryExtension,
283 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
284 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
285 fi
287 dnl *** Check for X Shm extension
288 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
289 then
290 AC_CHECK_LIB(Xext, XShmQueryExtension,
291 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
292 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
293 fi
295 dnl *** Check for X shape extension
296 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
297 then
298 AC_CHECK_LIB(Xext,XShapeQueryExtension,
299 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
300 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
301 fi
303 dnl *** Check for XFree86 DGA / DGA 2.0 extension
304 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
305 then
306 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
307 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
308 [Define if you have the Xxf86dga library version 2])
309 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
310 ],,
311 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
312 fi
314 dnl *** Check for XFree86 VMODE extension
315 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
316 then
317 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
318 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
319 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
320 ],,
321 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
322 fi
324 dnl *** Check for X RandR extension
325 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
326 then
327 AC_TRY_COMPILE([#include <X11/Xlib.h>
328 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
329 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
330 fi
332 dnl *** Check for Transform functions in Xrender
333 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
334 then
335 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
336 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
337 [Define if Xrender has the XRenderSetPictureTransform function])],,
338 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
339 fi
340 ]
341 ) dnl *** End of X11/Xlib.h check
343 dnl Check for the presence of OpenGL
344 if test "x$with_opengl" != "xno"
345 then
346 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
347 then
348 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
349 This prevents linking to OpenGL. Delete the file and restart configure.])
350 fi
352 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
353 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
354 then
355 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
356 dnl Check for some problems due to old Mesa versions
357 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
358 AC_TRY_COMPILE(
359 [#include <GL/gl.h>],
360 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
361 [wine_cv_opengl_version_OK="yes"],
362 [wine_cv_opengl_version_OK="no"]
363 )
364 )
366 if test "$wine_cv_opengl_version_OK" = "yes"
367 then
368 dnl Check for the presence of the library
369 AC_CHECK_LIB(GL,glXCreateContext,
370 OPENGL_LIBS="-lGL"
371 ,,
372 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
374 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
375 then
376 OPENGLFILES='$(OPENGLFILES)'
377 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
378 fi
379 dnl Check for GLU32 library.
380 AC_CHECK_LIB(GLU,gluLookAt,
381 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
382 GLU32FILES='$(GLU32FILES)']
383 ,,
384 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
385 )
386 fi
388 dnl Check for glut32 library.
389 AC_CHECK_LIB(glut,glutMainLoop,
390 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
391 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
392 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
393 fi
394 fi
396 dnl **** Check for NAS ****
397 AC_SUBST(NASLIBS,"")
398 AC_CHECK_HEADERS(audio/audiolib.h,
399 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
400 AC_CHECK_LIB(audio,AuCreateFlow,
401 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
402 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
403 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
405 CPPFLAGS="$ac_save_CPPFLAGS"
406 XFILES='$(XFILES)'
407 else
408 XLIB=""
409 X_CFLAGS=""
410 X_LIBS=""
411 fi
413 dnl **** Check which curses lib to use ***
414 CURSESLIBS=""
415 if test "x$with_curses" != "xno"
416 then
417 AC_CHECK_HEADERS(ncurses.h,
418 [AC_CHECK_LIB(ncurses,waddch,
419 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
420 CURSESLIBS="-lncurses"],
421 [AC_CHECK_HEADERS(curses.h,
422 [AC_CHECK_LIB(curses,waddch,
423 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
424 CURSESLIBS="-lcurses"])])])])
425 fi
426 AC_SUBST(CURSESLIBS)
428 dnl **** Check for SANE ****
429 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
430 if test "$sane_devel" = "no"
431 then
432 SANELIBS=""
433 SANEINCL=""
434 else
435 SANELIBS="`$sane_devel --libs`"
436 SANEINCL="`$sane_devel --cflags`"
437 ac_save_CPPFLAGS="$CPPFLAGS"
438 ac_save_LIBS="$LIBS"
439 CPPFLAGS="$CPPFLAGS $SANEINCL"
440 LIBS="$LIBS $SANELIBS"
441 AC_CHECK_HEADER(sane/sane.h,
442 [AC_CHECK_LIB(sane,sane_open,
443 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
444 [SANELIBS=""
445 SANEINCL=""])],
446 [SANELIBS=""
447 SANEINCL=""])
448 LIBS="$ac_save_LIBS"
449 CPPFLAGS="$ac_save_CPPFLAGS"
450 fi
451 AC_SUBST(SANELIBS)
452 AC_SUBST(SANEINCL)
454 dnl **** Check for the ICU library ****
455 AC_CHECK_HEADERS(unicode/ubidi.h)
456 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
457 then
458 saved_libs="$LIBS"
459 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
460 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
461 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
462 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
463 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
464 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
465 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
466 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
467 AC_MSG_RESULT(yes)],
468 [AC_MSG_RESULT(no)])
469 LIBS="$saved_libs"
470 fi
472 dnl **** Check for FreeType 2 ****
473 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
474 if test "$ft_lib" = "no"
475 then
476 FREETYPELIBS=""
477 FREETYPEINCL=""
478 wine_cv_msg_freetype=no
479 else
480 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
481 if test "$ft_devel" = "no"
482 then
483 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
484 if test "$ft_devel2" = "freetype2-config"
485 then
486 ft_devel=$ft_devel2
487 fi
488 fi
489 if test "$ft_devel" = "no"
490 then
491 FREETYPELIBS=""
492 FREETYPEINCL=""
493 wine_cv_msg_freetype=yes
494 else
495 FREETYPELIBS=`$ft_devel --libs`
496 FREETYPEINCL=`$ft_devel --cflags`
497 ac_save_CPPFLAGS="$CPPFLAGS"
498 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
499 AC_CHECK_HEADERS(ft2build.h \
500 freetype/freetype.h \
501 freetype/ftglyph.h \
502 freetype/tttables.h \
503 freetype/ftnames.h \
504 freetype/ftsnames.h \
505 freetype/ttnameid.h \
506 freetype/ftoutln.h \
507 freetype/ftwinfnt.h \
508 freetype/internal/sfnt.h,,,
509 [#if HAVE_FT2BUILD_H
510 #include <ft2build.h>
511 #endif])
512 AC_TRY_CPP([#include <ft2build.h>
513 #include <freetype/fttrigon.h>],
514 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
515 [Define if you have the <freetype/fttrigon.h> header file.])
516 wine_cv_fttrigon=yes],
517 wine_cv_fttrigon=no)
518 CPPFLAGS="$ac_save_CPPFLAGS"
519 dnl Check that we have at least freetype/freetype.h
520 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
521 then
522 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
523 wine_cv_msg_freetype=no
524 else
525 FREETYPELIBS=""
526 FREETYPEINCL=""
527 wine_cv_msg_freetype=yes
528 fi
529 fi
530 fi
531 AC_SUBST(FREETYPELIBS)
532 AC_SUBST(FREETYPEINCL)
534 dnl Only build the fonts dir if we have both freetype and fontforge
535 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
536 then
537 AC_SUBST(FONTSSUBDIRS,"fonts")
538 fi
540 dnl **** Check for parport (currently Linux only) ****
541 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
542 AC_TRY_COMPILE(
543 [#include <linux/ppdev.h>],
544 [ioctl (1,PPCLAIM,0)],
545 [ac_cv_c_ppdev="yes"],
546 [ac_cv_c_ppdev="no"])
547 )
548 if test "$ac_cv_c_ppdev" = "yes"
549 then
550 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
551 fi
553 dnl **** Check for va_copy ****
554 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
555 AC_TRY_LINK(
556 [#include <stdarg.h>],
557 [va_list ap1, ap2;
558 va_copy(ap1,ap2);
559 ],
560 [ac_cv_c_va_copy="yes"],
561 [ac_cv_c_va_copy="no"])
562 )
563 if test "$ac_cv_c_va_copy" = "yes"
564 then
565 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
566 fi
567 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
568 AC_TRY_LINK(
569 [#include <stdarg.h>],
570 [va_list ap1, ap2;
571 __va_copy(ap1,ap2);
572 ],
573 [ac_cv_c___va_copy="yes"],
574 [ac_cv_c___va_copy="no"])
575 )
576 if test "$ac_cv_c___va_copy" = "yes"
577 then
578 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
579 fi
581 dnl **** Check for sigsetjmp ****
582 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
583 AC_TRY_LINK(
584 [#include <setjmp.h>],
585 [sigjmp_buf buf;
586 sigsetjmp( buf, 1 );
587 siglongjmp( buf, 1 );],
588 [ac_cv_c_sigsetjmp="yes"],
589 [ac_cv_c_sigsetjmp="no"])
590 )
591 if test "$ac_cv_c_sigsetjmp" = "yes"
592 then
593 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
594 fi
596 dnl **** Check for pthread_rwlock_t ****
597 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
598 #include <pthread.h>])
600 dnl **** Check for pthread functions ****
601 ac_save_LIBS="$LIBS"
602 LIBS="$LIBS $LIBPTHREAD"
603 AC_CHECK_FUNCS(\
604 pthread_getattr_np \
605 pthread_get_stackaddr_np \
606 pthread_get_stacksize_np \
607 )
608 LIBS="$ac_save_LIBS"
610 dnl **** Check for Open Sound System ****
611 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
613 AC_CACHE_CHECK([for Open Sound System],
614 ac_cv_c_opensoundsystem,
615 AC_TRY_COMPILE([
616 #if defined(HAVE_SYS_SOUNDCARD_H)
617 #include <sys/soundcard.h>
618 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
619 #include <machine/soundcard.h>
620 #elif defined(HAVE_SOUNDCARD_H)
621 #include <soundcard.h>
622 #endif
623 ],[
625 /* check for one of the Open Sound System specific SNDCTL_ defines */
626 #if !defined(SNDCTL_DSP_STEREO)
627 #error No open sound system
628 #endif
629 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
631 if test "$ac_cv_c_opensoundsystem" = "yes"
632 then
633 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
634 fi
636 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
637 ac_cv_c_opensoundsystem_midi,
638 AC_TRY_COMPILE([
639 #if defined(HAVE_SYS_SOUNDCARD_H)
640 #include <sys/soundcard.h>
641 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
642 #include <machine/soundcard.h>
643 #elif defined(HAVE_SOUNDCARD_H)
644 #include <soundcard.h>
645 #endif
646 ],[
648 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
649 #if !defined(SNDCTL_SEQ_SYNC)
650 #error No open sound system MIDI interface
651 #endif
652 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
654 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
655 then
656 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
657 fi
659 dnl **** Check for aRts Sound Server ****
660 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
661 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
662 then
663 ARTSC_CFLAGS=""
664 for i in `$ARTSCCONFIG --cflags`
665 do
666 case "$i" in
667 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
668 esac
669 done
670 ARTSC_LIBS=`$ARTSCCONFIG --libs`
671 save_CFLAGS="$CFLAGS"
672 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
673 AC_CHECK_LIB(artsc,arts_init,
674 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
675 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
676 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
677 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],)
678 CFLAGS="$save_CFLAGS"
679 fi
681 dnl **** Check for ALSA 1.x ****
682 AC_SUBST(ALSALIBS,"")
683 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
684 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
685 then
686 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
687 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
688 #include <alsa/asoundlib.h>
689 #elif defined(HAVE_SYS_ASOUNDLIB_H)
690 #include <sys/asoundlib.h>
691 #endif],
692 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
693 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
694 ALSALIBS="-lasound"])])
695 fi
697 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
699 AC_SUBST(AUDIOIOLIBS,"")
700 AC_CHECK_HEADERS(libaudioio.h,
701 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
702 [AUDIOIOLIBS="-laudioio"
703 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
705 dnl **** Check for capi4linux ****
707 AC_CHECK_HEADERS(capi20.h,[
708 AC_CHECK_HEADERS(linux/capi.h,[
709 AC_CHECK_LIB(capi20,capi20_register,[
710 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
711 ])
712 ])
713 ])
715 dnl **** Check for broken glibc mmap64 ****
717 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
718 AC_TRY_RUN([
719 #define _FILE_OFFSET_BITS 64
720 #include <stdio.h>
721 #include <unistd.h>
722 #include <fcntl.h>
723 #include <sys/mman.h>
724 #include <errno.h>
726 int main(int argc,char **argv) {
727 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
728 if (fd == -1) exit(1);
730 unlink("conftest.map");
732 write(fd,"test",4);
734 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
735 (errno == EINVAL)
736 ) {
737 exit(1);
738 }
739 close(fd);
740 fprintf(stderr,"success!\n");
741 exit(0);
742 }
744 ],
745 ac_cv_mmap64_works="yes",
746 ac_cv_mmap64_works="no",
747 ac_cv_mmap64_works="no") )
749 if test "$ac_cv_mmap64_works" = "yes"
750 then
751 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
752 fi
754 dnl **** Check for gcc specific options ****
756 AC_SUBST(EXTRACFLAGS,"")
757 if test "x${GCC}" = "xyes"
758 then
759 EXTRACFLAGS="-Wall -pipe"
761 dnl Check for strength-reduce bug
762 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
763 AC_TRY_RUN([
764 int L[[4]] = {0,1,2,3};
765 int main(void) {
766 static int Array[[3]];
767 unsigned int B = 3;
768 int i;
769 for(i=0; i<B; i++) Array[[i]] = i - 3;
770 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
771 L[[i]] = 4;
773 exit( Array[[1]] != -2 || L[[2]] != 3);
774 }],
775 ac_cv_c_gcc_strength_bug="no",
776 ac_cv_c_gcc_strength_bug="yes",
777 ac_cv_c_gcc_strength_bug="yes") )
778 if test "$ac_cv_c_gcc_strength_bug" = "yes"
779 then
780 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
781 fi
783 dnl Check for -fshort-wchar
784 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
785 [WINE_TRY_CFLAGS([-fshort-wchar],
786 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
787 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
788 then
789 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
790 fi
792 dnl Check for -mpreferred-stack-boundary
793 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
794 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
795 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
796 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
797 then
798 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
799 fi
801 dnl Check for -fno-strict-aliasing
802 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
803 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
804 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
805 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
806 then
807 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
808 fi
810 dnl Check for -gstabs+ option
811 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
812 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
813 if test "$ac_cv_c_gcc_gstabs" = "yes"
814 then
815 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
816 fi
818 dnl Check for noisy string.h
819 saved_CFLAGS="$CFLAGS"
820 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
821 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
822 AC_TRY_COMPILE([#include <string.h>],[],
823 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
824 CFLAGS="$saved_CFLAGS"
825 if test "$ac_cv_c_string_h_warnings" = "no"
826 then
827 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
828 fi
829 fi
831 dnl **** Check how to define a function in assembly code ****
833 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
834 WINE_TRY_ASM_LINK(
835 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
836 ac_cv_asm_func_def=".def",
837 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
838 ac_cv_asm_func_def=".type @function",
839 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
840 ac_cv_asm_func_def=".type 2",
841 ac_cv_asm_func_def="unknown")])]))
843 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
844 case "$ac_cv_asm_func_def" in
845 ".def")
846 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
847 ".type @function")
848 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
849 ".type 2")
850 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
851 *)
852 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
853 esac
855 dnl **** Check for underscore on external symbols ****
857 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
858 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
859 [extern int ac_test;],
860 [if (ac_test) return 1],
861 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
863 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
864 if test "$ac_cv_c_extern_prefix" = "yes"
865 then
866 AC_DEFINE([__ASM_NAME(name)], ["_" name])
867 else
868 AC_DEFINE([__ASM_NAME(name)], [name])
869 fi
871 dnl **** Check how to do strings in assembler ****
873 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
874 WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
875 WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
876 WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
877 AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
879 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
880 [Define to the assembler keyword used to specify an ASCII string])
882 dnl **** Check for .short in assembler ****
884 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
885 WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
886 WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
887 AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
889 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
890 [Define to the assembler keyword used to specify a word value])
892 dnl **** Check for .size in assembler ****
894 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
895 WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
896 ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
898 if test "$ac_cv_c_asm_size" = "yes"
899 then
900 AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
901 fi
903 dnl **** Check for working dll ****
905 AC_SUBST(DLLEXT,"")
906 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
907 AC_SUBST(DLLIBS,"")
908 AC_SUBST(LDSHARED,"")
909 AC_SUBST(LDDLLFLAGS,"")
910 AC_SUBST(LIBEXT,"so")
911 AC_SUBST(IMPLIBEXT,"def")
913 case $host_os in
914 cygwin*|mingw32*)
915 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
916 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
917 if test "$DLLWRAP" = "false"; then
918 LIBEXT="a"
919 else
920 dnl FIXME - check whether dllwrap works correctly...
921 LIBEXT="dll"
922 fi
923 IMPLIBEXT="a"
924 dnl We can't build 16-bit NE dlls
925 WIN16_FILES=""
926 WIN16_INSTALL=""
927 ;;
928 *)
929 AC_CHECK_HEADERS(dlfcn.h,
930 [AC_CHECK_FUNCS(dlopen,,
931 [AC_CHECK_LIB(dl,dlopen,
932 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
933 DLLIBS="-ldl"],
934 [LIBEXT="a"])])],
935 [LIBEXT="a"])
937 if test "$LIBEXT" = "so"
938 then
939 DLLFLAGS="$DLLFLAGS -fPIC"
940 DLLEXT=".so"
941 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
942 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
943 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
944 if test "$ac_cv_c_dll_gnuelf" = "yes"
945 then
946 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
947 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
948 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
949 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
950 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
951 if test "$ac_cv_c_dll_zdefs" = "yes"
952 then
953 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
954 fi
956 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
957 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
958 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
959 if test "$ac_cv_c_dll_init_fini" = "yes"
960 then
961 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
962 fi
964 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
965 [echo '{ global: *; };' >conftest.map
966 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
967 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
968 rm -f conftest.map])
969 if test "$ac_cv_c_ld_version_scripts" = "yes"
970 then
971 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
972 fi
974 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
975 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
976 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
977 if test "$ac_cv_c_export_dynamic" = "yes"
978 then
979 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
980 fi
982 case $host_cpu in
983 *i[[3456789]]86*)
984 AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
985 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
986 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
987 if test "$ac_cv_ld_reloc_exec" = "yes"
988 then
989 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
990 fi
991 ;;
992 esac
994 else
995 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
996 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
997 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
998 if test "$ac_cv_c_dll_unixware" = "yes"
999 then
1000 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1001 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1003 else
1004 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1005 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1006 if test "$ac_cv_c_dll_macho" = "yes"
1007 then
1008 LIBEXT="dylib"
1009 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
1010 LDSHARED="\$(CC) -dynamiclib"
1011 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
1012 STRIP="$STRIP -u -r"
1013 dnl Relocate wine executable
1014 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1015 dnl Relocate libwine.dyld too
1016 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1017 dnl declare needed frameworks
1018 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1019 AC_SUBST(IOKITLIB,"-framework IOKit")
1020 dnl using IOKit imply we use CoreFoundation too
1021 IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1022 else
1023 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1024 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1025 if test "$ac_cv_c_dll_hpux" = "yes"
1026 then
1027 LIBEXT="sl"
1028 DLLEXT=".sl"
1029 LDDLLFLAGS="-shared -fPIC"
1030 LDSHARED="\$(CC) -shared"
1031 fi
1032 fi
1033 fi
1034 fi
1035 fi
1037 dnl Check for cross compiler to build test programs
1038 AC_SUBST(CROSSTEST,"")
1039 if test "$cross_compiling" = "no"
1040 then
1041 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1042 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1043 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1044 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1045 fi
1046 ;;
1047 esac
1049 if test "$LIBEXT" = "a"; then
1050 AC_MSG_ERROR(
1051 [could not find a way to build shared libraries.
1052 It is currently not possible to build Wine without shared library
1053 (.so) support to allow transparent switch between .so and .dll files.
1054 If you are using Linux, you will need a newer binutils.]
1055 )
1056 fi
1058 case $build_os in
1059 cygwin*|mingw32*)
1060 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1061 darwin*|macosx*)
1062 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1063 *)
1064 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1065 esac
1067 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1068 case $host_os in
1069 mingw32*)
1070 AC_SUBST(CRTLIBS,"-lmsvcrt")
1071 AC_SUBST(SOCKETLIBS,"-lws2_32")
1072 ;;
1073 esac
1075 case $host_os in
1076 linux*)
1077 case $host_cpu in
1078 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1079 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1080 esac
1081 AC_SUBST(MAIN_BINARY,"wine-glibc")
1082 ;;
1083 darwin*)
1084 AC_SUBST(WINE_BINARIES,"wine-pthread")
1085 AC_SUBST(MAIN_BINARY,"wine-pthread")
1086 ;;
1087 *)
1088 AC_SUBST(WINE_BINARIES,"wine-kthread")
1089 AC_SUBST(MAIN_BINARY,"wine-kthread")
1090 ;;
1091 esac
1093 dnl **** Get the soname for libraries that we load dynamically ****
1095 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1096 then
1097 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1098 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1099 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1100 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1101 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1102 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1103 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1104 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1105 WINE_GET_SONAME(cups,cupsGetDefault)
1106 WINE_GET_SONAME(jack,jack_client_new)
1107 WINE_GET_SONAME(fontconfig,FcInit)
1108 WINE_GET_SONAME(ssl,SSL_library_init)
1109 WINE_GET_SONAME(crypto,BIO_new_socket)
1110 WINE_GET_SONAME(ncurses,waddch)
1111 WINE_GET_SONAME(curses,waddch)
1112 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1113 WINE_GET_SONAME(ungif,DGifOpen)
1114 WINE_GET_SONAME(gif,DGifOpen)
1115 WINE_GET_SONAME(lcms,cmsOpenProfileFromFile)
1116 WINE_GET_SONAME(capi20,capi20_isinstalled)
1117 fi
1120 dnl **** Check for functions ****
1122 AC_FUNC_ALLOCA()
1123 AC_CHECK_FUNCS(\
1124 _lwp_create \
1125 _lwp_self \
1126 _pclose \
1127 _popen \
1128 _snprintf \
1129 _spawnvp \
1130 _stricmp \
1131 _strnicmp \
1132 _vsnprintf \
1133 chsize \
1134 clone \
1135 epoll_create \
1136 ffs \
1137 finite \
1138 fork \
1139 fpclass \
1140 fstatfs \
1141 fstatvfs \
1142 ftruncate \
1143 futimes \
1144 futimesat \
1145 getnetbyname \
1146 getopt_long \
1147 getpagesize \
1148 getprotobyname \
1149 getprotobynumber \
1150 getpwuid \
1151 getservbyport \
1152 gettid \
1153 gettimeofday \
1154 getuid \
1155 inet_network \
1156 lstat \
1157 memmove \
1158 mmap \
1159 pclose \
1160 popen \
1161 pread \
1162 pwrite \
1163 readlink \
1164 rfork \
1165 sched_yield \
1166 select \
1167 sendmsg \
1168 settimeofday \
1169 sigaltstack \
1170 sigprocmask \
1171 snprintf \
1172 spawnvp \
1173 statfs \
1174 statvfs \
1175 strcasecmp \
1176 strerror \
1177 strncasecmp \
1178 tcgetattr \
1179 timegm \
1180 usleep \
1181 vsnprintf \
1182 wait4 \
1183 waitpid \
1184 )
1186 dnl **** Checks for headers that depend on other ones ****
1188 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1189 [#include <sys/types.h>
1190 #if HAVE_SYS_PARAM_H
1191 # include <sys/param.h>
1192 #endif])
1194 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1195 [#include <sys/types.h>
1196 #if HAVE_SYS_SOCKET_H
1197 # include <sys/socket.h>
1198 #endif])
1200 AC_CHECK_HEADERS([resolv.h],,,
1201 [#include <sys/types.h>
1202 #if HAVE_SYS_SOCKET_H
1203 # include <sys/socket.h>
1204 #endif
1205 #if HAVE_NETINET_IN_H
1206 # include <netinet/in.h>
1207 #endif
1208 #if HAVE_ARPA_NAMESER_H
1209 # include <arpa/nameser.h>
1210 #endif])
1212 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1214 dnl **** Check for v4l(2) headers ****
1216 AC_CHECK_HEADERS(linux/videodev.h,,,
1217 [#ifdef HAVE_SYS_TIME_H
1218 #include <sys/time.h>
1219 #endif
1220 #ifdef HAVE_ASM_TYPES_H
1221 #include <asm/types.h>
1222 #endif])
1224 dnl **** Check for IPX headers (currently Linux only) ****
1226 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1227 AC_TRY_COMPILE(
1228 [#include <sys/types.h>
1229 #ifdef HAVE_SYS_SOCKET_H
1230 # include <sys/socket.h>
1231 #endif
1232 #include <netipx/ipx.h>],
1233 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1234 [ac_cv_c_ipx_gnu="yes"],
1235 [ac_cv_c_ipx_gnu="no"])
1236 )
1237 if test "$ac_cv_c_ipx_gnu" = "yes"
1238 then
1239 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1240 fi
1242 if test "$ac_cv_c_ipx_gnu" = "no"
1243 then
1244 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1245 AC_TRY_COMPILE(
1246 [#include <sys/types.h>
1247 #ifdef HAVE_SYS_SOCKET_H
1248 # include <sys/socket.h>
1249 #endif
1250 #include <asm/types.h>
1251 #include <linux/ipx.h>],
1252 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1253 [ac_cv_c_ipx_linux="yes"],
1254 [ac_cv_c_ipx_linux="no"])
1255 )
1256 if test "$ac_cv_c_ipx_linux" = "yes"
1257 then
1258 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1259 fi
1260 fi
1262 dnl **** Check for types ****
1264 AC_C_CONST
1265 AC_C_INLINE
1266 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1267 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1269 AC_CACHE_CHECK([whether linux/input.h is for real],
1270 wine_cv_linux_input_h,
1271 AC_TRY_COMPILE([
1272 #include <linux/input.h>
1273 ] , [
1274 int foo = EVIOCGBIT(EV_ABS,42);
1275 int bar = BTN_PINKIE;
1276 int fortytwo = 42;
1277 ],
1278 wine_cv_linux_input_h=yes,
1279 wine_cv_linux_input_h=no,
1280 no
1281 )
1282 )
1283 if test "$wine_cv_linux_input_h" = "yes"
1284 then
1285 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1286 [Define if we have linux/input.h AND it contains the INPUT event API])
1287 fi
1289 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1290 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1291 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1292 if test "$wine_cv_have_sigaddset" = "yes"
1293 then
1294 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1295 fi
1298 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1299 wine_cv_linux_gethostbyname_r_6,
1300 AC_TRY_LINK([
1301 #include <netdb.h>
1302 ], [
1303 char *name=NULL;
1304 struct hostent he;
1305 struct hostent *result;
1306 char *buf=NULL;
1307 int bufsize=0;
1308 int res,errnr;
1309 char *addr=NULL;
1310 int addrlen=0;
1311 int addrtype=0;
1312 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1313 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1314 ],
1315 wine_cv_linux_gethostbyname_r_6=yes,
1316 wine_cv_linux_gethostbyname_r_6=no
1317 )
1318 )
1319 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1320 then
1321 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1322 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1323 fi
1325 if test "$ac_cv_header_linux_joystick_h" = "yes"
1326 then
1327 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1328 wine_cv_linux_joystick_22_api,
1329 AC_TRY_COMPILE([
1330 #include <sys/ioctl.h>
1331 #include <linux/joystick.h>
1333 struct js_event blub;
1334 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1335 #error "no 2.2 header"
1336 #endif
1337 ],/*empty*/,
1338 wine_cv_linux_joystick_22_api=yes,
1339 wine_cv_linux_joystick_22_api=no,
1340 wine_cv_linux_joystick_22_api=no
1341 )
1342 )
1343 if test "$wine_cv_linux_joystick_22_api" = "yes"
1344 then
1345 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1346 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1347 fi
1348 fi
1350 dnl **** statfs checks ****
1352 if test "$ac_cv_header_sys_vfs_h" = "yes"
1353 then
1354 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1355 wine_cv_sys_vfs_has_statfs,
1356 AC_TRY_COMPILE([
1357 #include <sys/types.h>
1358 #ifdef HAVE_SYS_PARAM_H
1359 # include <sys/param.h>
1360 #endif
1361 #include <sys/vfs.h>
1362 ],[
1363 struct statfs stfs;
1365 memset(&stfs,0,sizeof(stfs));
1366 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1367 )
1368 )
1369 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1370 then
1371 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1372 [Define if the struct statfs is defined by <sys/vfs.h>])
1373 fi
1374 fi
1376 if test "$ac_cv_header_sys_statfs_h" = "yes"
1377 then
1378 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1379 wine_cv_sys_statfs_has_statfs,
1380 AC_TRY_COMPILE([
1381 #include <sys/types.h>
1382 #ifdef HAVE_SYS_PARAM_H
1383 # include <sys/param.h>
1384 #endif
1385 #include <sys/statfs.h>
1386 ],[
1387 struct statfs stfs;
1388 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1389 )
1390 )
1391 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1392 then
1393 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1394 [Define if the struct statfs is defined by <sys/statfs.h>])
1395 fi
1396 fi
1398 if test "$ac_cv_header_sys_mount_h" = "yes"
1399 then
1400 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1401 wine_cv_sys_mount_has_statfs,
1402 AC_TRY_COMPILE([
1403 #include <sys/types.h>
1404 #ifdef HAVE_SYS_PARAM_H
1405 # include <sys/param.h>
1406 #endif
1407 #include <sys/mount.h>
1408 ],[
1409 struct statfs stfs;
1410 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1411 )
1412 )
1413 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1414 then
1415 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1416 [Define if the struct statfs is defined by <sys/mount.h>])
1417 fi
1418 fi
1420 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1422 dnl Check for statfs members
1423 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1424 [#include <sys/types.h>
1425 #ifdef HAVE_SYS_PARAM_H
1426 # include <sys/param.h>
1427 #endif
1428 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1429 # include <sys/mount.h>
1430 #else
1431 # ifdef STATFS_DEFINED_BY_SYS_VFS
1432 # include <sys/vfs.h>
1433 # else
1434 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1435 # include <sys/statfs.h>
1436 # endif
1437 # endif
1438 #endif])
1440 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1441 [#ifdef HAVE_SYS_STATVFS_H
1442 #include <sys/statvfs.h>
1443 #endif])
1445 dnl Check for socket structure members
1446 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1447 [#include <sys/types.h>
1448 #ifdef HAVE_SYS_SOCKET_H
1449 # include <sys/socket.h>
1450 #endif
1451 #ifdef HAVE_SYS_UN_H
1452 # include <sys/un.h>
1453 #endif])
1455 dnl Check for siginfo_t members
1456 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1458 dnl Check for struct option
1459 AC_CHECK_MEMBERS([struct option.name],,,
1460 [#ifdef HAVE_GETOPT_H
1461 #include <getopt.h>
1462 #endif])
1464 dnl Check for stat.st_blocks
1465 AC_CHECK_MEMBERS([struct stat.st_blocks])
1467 dnl *** check for the need to define platform-specific symbols
1469 case $host_cpu in
1470 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1471 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1472 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1473 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1474 esac
1476 case $host_vendor in
1477 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1478 esac
1480 dnl **** Generate output files ****
1482 AH_TOP([#define __WINE_CONFIG_H])
1484 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1485 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1486 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1487 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1488 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1489 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1490 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1491 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1492 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1493 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1494 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1495 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1496 WINE_CONFIG_EXTRA_DIR(include/wine)
1497 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1498 WINE_CONFIG_EXTRA_DIR(windows)
1500 MAKE_RULES=Make.rules
1501 AC_SUBST_FILE(MAKE_RULES)
1503 MAKE_DLL_RULES=dlls/Makedll.rules
1504 AC_SUBST_FILE(MAKE_DLL_RULES)
1506 MAKE_TEST_RULES=dlls/Maketest.rules
1507 AC_SUBST_FILE(MAKE_TEST_RULES)
1509 MAKE_LIB_RULES=libs/Makelib.rules
1510 AC_SUBST_FILE(MAKE_LIB_RULES)
1512 MAKE_PROG_RULES=programs/Makeprog.rules
1513 AC_SUBST_FILE(MAKE_PROG_RULES)
1515 AC_CONFIG_FILES([
1516 Make.rules
1517 dlls/Makedll.rules
1518 dlls/Maketest.rules
1519 libs/Makelib.rules
1520 programs/Makeprog.rules
1521 Makefile
1522 dlls/Makefile
1523 dlls/advapi32/Makefile
1524 dlls/advapi32/tests/Makefile
1525 dlls/advpack/Makefile
1526 dlls/advpack/tests/Makefile
1527 dlls/amstream/Makefile
1528 dlls/atl/Makefile
1529 dlls/avicap32/Makefile
1530 dlls/avifil32/Makefile
1531 dlls/cabinet/Makefile
1532 dlls/capi2032/Makefile
1533 dlls/cards/Makefile
1534 dlls/cfgmgr32/Makefile
1535 dlls/comcat/Makefile
1536 dlls/comctl32/Makefile
1537 dlls/comctl32/tests/Makefile
1538 dlls/commdlg/Makefile
1539 dlls/crtdll/Makefile
1540 dlls/crypt32/Makefile
1541 dlls/cryptdll/Makefile
1542 dlls/ctl3d/Makefile
1543 dlls/d3d8/Makefile
1544 dlls/d3d9/Makefile
1545 dlls/d3dim/Makefile
1546 dlls/d3drm/Makefile
1547 dlls/d3dx8/Makefile
1548 dlls/d3dxof/Makefile
1549 dlls/dbghelp/Makefile
1550 dlls/dciman32/Makefile
1551 dlls/ddraw/Makefile
1552 dlls/ddraw/tests/Makefile
1553 dlls/devenum/Makefile
1554 dlls/dinput/Makefile
1555 dlls/dinput/tests/Makefile
1556 dlls/dinput8/Makefile
1557 dlls/dmband/Makefile
1558 dlls/dmcompos/Makefile
1559 dlls/dmime/Makefile
1560 dlls/dmloader/Makefile
1561 dlls/dmscript/Makefile
1562 dlls/dmstyle/Makefile
1563 dlls/dmsynth/Makefile
1564 dlls/dmusic/Makefile
1565 dlls/dmusic32/Makefile
1566 dlls/dplay/Makefile
1567 dlls/dplayx/Makefile
1568 dlls/dpnet/Makefile
1569 dlls/dpnhpast/Makefile
1570 dlls/dsound/Makefile
1571 dlls/dsound/tests/Makefile
1572 dlls/dswave/Makefile
1573 dlls/dxdiagn/Makefile
1574 dlls/dxerr8/Makefile
1575 dlls/dxerr9/Makefile
1576 dlls/dxguid/Makefile
1577 dlls/gdi/Makefile
1578 dlls/gdi/tests/Makefile
1579 dlls/glu32/Makefile
1580 dlls/glut32/Makefile
1581 dlls/hhctrl.ocx/Makefile
1582 dlls/iccvid/Makefile
1583 dlls/icmp/Makefile
1584 dlls/ifsmgr.vxd/Makefile
1585 dlls/imagehlp/Makefile
1586 dlls/imm32/Makefile
1587 dlls/iphlpapi/Makefile
1588 dlls/iphlpapi/tests/Makefile
1589 dlls/itss/Makefile
1590 dlls/kernel/Makefile
1591 dlls/kernel/tests/Makefile
1592 dlls/lzexpand/Makefile
1593 dlls/lzexpand/tests/Makefile
1594 dlls/mapi32/Makefile
1595 dlls/mapi32/tests/Makefile
1596 dlls/mlang/Makefile
1597 dlls/mlang/tests/Makefile
1598 dlls/mmdevldr.vxd/Makefile
1599 dlls/monodebg.vxd/Makefile
1600 dlls/mpr/Makefile
1601 dlls/msacm/Makefile
1602 dlls/msacm/imaadp32/Makefile
1603 dlls/msacm/msadp32/Makefile
1604 dlls/msacm/msg711/Makefile
1605 dlls/msacm/winemp3/Makefile
1606 dlls/msacm/tests/Makefile
1607 dlls/mscms/Makefile
1608 dlls/mscms/tests/Makefile
1609 dlls/msdmo/Makefile
1610 dlls/mshtml/Makefile
1611 dlls/msi/Makefile
1612 dlls/msi/tests/Makefile
1613 dlls/msimg32/Makefile
1614 dlls/msisys/Makefile
1615 dlls/msnet32/Makefile
1616 dlls/msrle32/Makefile
1617 dlls/msvcrt/Makefile
1618 dlls/msvcrt/tests/Makefile
1619 dlls/msvcrt20/Makefile
1620 dlls/msvcrt40/Makefile
1621 dlls/msvcrtd/Makefile
1622 dlls/msvcrtd/tests/Makefile
1623 dlls/msvidc32/Makefile
1624 dlls/msvideo/Makefile
1625 dlls/mswsock/Makefile
1626 dlls/netapi32/Makefile
1627 dlls/netapi32/tests/Makefile
1628 dlls/newdev/Makefile
1629 dlls/ntdll/Makefile
1630 dlls/ntdll/tests/Makefile
1631 dlls/odbc32/Makefile
1632 dlls/odbccp32/Makefile
1633 dlls/ole32/Makefile
1634 dlls/ole32/tests/Makefile
1635 dlls/oleacc/Makefile
1636 dlls/oleaut32/Makefile
1637 dlls/oleaut32/tests/Makefile
1638 dlls/olecli/Makefile
1639 dlls/oledlg/Makefile
1640 dlls/olepro32/Makefile
1641 dlls/olesvr/Makefile
1642 dlls/opengl32/Makefile
1643 dlls/powrprof/Makefile
1644 dlls/psapi/Makefile
1645 dlls/psapi/tests/Makefile
1646 dlls/qcap/Makefile
1647 dlls/quartz/Makefile
1648 dlls/quartz/tests/Makefile
1649 dlls/rasapi32/Makefile
1650 dlls/riched20/Makefile
1651 dlls/richedit/Makefile
1652 dlls/rpcrt4/Makefile
1653 dlls/rpcrt4/tests/Makefile
1654 dlls/rsabase/Makefile
1655 dlls/rsabase/tests/Makefile
1656 dlls/rsaenh/Makefile
1657 dlls/rsaenh/tests/Makefile
1658 dlls/secur32/Makefile
1659 dlls/sensapi/Makefile
1660 dlls/serialui/Makefile
1661 dlls/setupapi/Makefile
1662 dlls/shdocvw/Makefile
1663 dlls/shell32/Makefile
1664 dlls/shell32/tests/Makefile
1665 dlls/shfolder/Makefile
1666 dlls/shlwapi/Makefile
1667 dlls/shlwapi/tests/Makefile
1668 dlls/snmpapi/Makefile
1669 dlls/stdole32.tlb/Makefile
1670 dlls/sti/Makefile
1671 dlls/strmiids/Makefile
1672 dlls/tapi32/Makefile
1673 dlls/ttydrv/Makefile
1674 dlls/twain/Makefile
1675 dlls/unicows/Makefile
1676 dlls/url/Makefile
1677 dlls/urlmon/Makefile
1678 dlls/urlmon/tests/Makefile
1679 dlls/user/Makefile
1680 dlls/user/tests/Makefile
1681 dlls/uuid/Makefile
1682 dlls/uxtheme/Makefile
1683 dlls/vdhcp.vxd/Makefile
1684 dlls/vdmdbg/Makefile
1685 dlls/version/Makefile
1686 dlls/version/tests/Makefile
1687 dlls/vmm.vxd/Makefile
1688 dlls/vnbt.vxd/Makefile
1689 dlls/vnetbios.vxd/Makefile
1690 dlls/vtdapi.vxd/Makefile
1691 dlls/vwin32.vxd/Makefile
1692 dlls/win32s/Makefile
1693 dlls/winaspi/Makefile
1694 dlls/wined3d/Makefile
1695 dlls/winedos/Makefile
1696 dlls/wineps/Makefile
1697 dlls/wininet/Makefile
1698 dlls/wininet/tests/Makefile
1699 dlls/winmm/Makefile
1700 dlls/winmm/joystick/Makefile
1701 dlls/winmm/mcianim/Makefile
1702 dlls/winmm/mciavi/Makefile
1703 dlls/winmm/mcicda/Makefile
1704 dlls/winmm/mciseq/Makefile
1705 dlls/winmm/mciwave/Makefile
1706 dlls/winmm/midimap/Makefile
1707 dlls/winmm/tests/Makefile
1708 dlls/winmm/wavemap/Makefile
1709 dlls/winmm/winealsa/Makefile
1710 dlls/winmm/winearts/Makefile
1711 dlls/winmm/wineaudioio/Makefile
1712 dlls/winmm/winejack/Makefile
1713 dlls/winmm/winenas/Makefile
1714 dlls/winmm/wineoss/Makefile
1715 dlls/winnls/Makefile
1716 dlls/winsock/Makefile
1717 dlls/winsock/tests/Makefile
1718 dlls/winspool/Makefile
1719 dlls/winspool/tests/Makefile
1720 dlls/wintab32/Makefile
1721 dlls/wintrust/Makefile
1722 dlls/wow32/Makefile
1723 dlls/wsock32/Makefile
1724 dlls/wtsapi32/Makefile
1725 dlls/x11drv/Makefile
1726 documentation/Makefile
1727 fonts/Makefile
1728 include/Makefile
1729 libs/Makefile
1730 libs/port/Makefile
1731 libs/unicode/Makefile
1732 libs/wine/Makefile
1733 libs/wpp/Makefile
1734 loader/Makefile
1735 programs/Makefile
1736 programs/avitools/Makefile
1737 programs/clock/Makefile
1738 programs/cmdlgtst/Makefile
1739 programs/control/Makefile
1740 programs/expand/Makefile
1741 programs/msiexec/Makefile
1742 programs/notepad/Makefile
1743 programs/progman/Makefile
1744 programs/regedit/Makefile
1745 programs/regsvr32/Makefile
1746 programs/rpcss/Makefile
1747 programs/rundll32/Makefile
1748 programs/start/Makefile
1749 programs/taskmgr/Makefile
1750 programs/uninstaller/Makefile
1751 programs/view/Makefile
1752 programs/wcmd/Makefile
1753 programs/wineboot/Makefile
1754 programs/winebrowser/Makefile
1755 programs/winecfg/Makefile
1756 programs/wineconsole/Makefile
1757 programs/winedbg/Makefile
1758 programs/winefile/Makefile
1759 programs/winemenubuilder/Makefile
1760 programs/winemine/Makefile
1761 programs/winepath/Makefile
1762 programs/winetest/Makefile
1763 programs/winevdm/Makefile
1764 programs/winhelp/Makefile
1765 programs/winver/Makefile
1766 server/Makefile
1767 tools/Makefile
1768 tools/widl/Makefile
1769 tools/winapi/Makefile
1770 tools/winebuild/Makefile
1771 tools/winedump/Makefile
1772 tools/winegcc/Makefile
1773 tools/wmc/Makefile
1774 tools/wrc/Makefile])
1776 AC_OUTPUT
1778 if test "$have_x" = "no"
1779 then
1780 echo
1781 echo "*** Warning: X development files not found. Wine will be built without"
1782 echo "*** X support, which currently does not work, and would probably not be"
1783 echo "*** what you want anyway. You will need to install devel packages of"
1784 echo "*** Xlib/Xfree86 at the very least."
1785 fi
1787 if test "$wine_cv_opengl_version_OK" = "no"
1788 then
1789 echo
1790 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1791 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1792 fi
1794 if test "$wine_cv_msg_freetype" = "yes"
1795 then
1796 echo
1797 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1798 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1799 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1800 echo "*** enable Wine to use TrueType fonts."
1801 fi
1803 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1804 -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1805 "$ac_cv_c_opensoundsystem" = "no"
1806 then
1807 echo "*** No sound system was found. Windows applications will be silent."
1808 echo "*** The currently supported sound systems are:"
1809 echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1810 fi
1812 echo
1813 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1814 echo
1816 dnl Local Variables:
1817 dnl comment-start: "dnl "
1818 dnl comment-end: ""
1819 dnl comment-start-skip: "\\bdnl\\b\\s *"
1820 dnl compile-command: "autoconf"
1821 dnl End: