configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(debug,
  19 [  --disable-debug         compile out all debugging messages],
  20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  21
  22 AC_ARG_ENABLE(opengl,
  23 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe],
  24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  25
  26 AC_ARG_ENABLE(trace,
  27 [  --disable-trace         compile out TRACE messages],
  28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  29
  30 AC_ARG_WITH(curses,
  31 [  --without-curses        do not use curses],
  32 [if test "$withval" = "no"; then CURSES="no"; fi])
  33
  34 AC_ARG_WITH(reentrant-x,
  35 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  36
  37 AC_SUBST(OPTIONS)
  38
  39 if test "$DEBUG_MSGS" = "no"
  40 then
  41     AC_DEFINE(NO_DEBUG_MSGS)
  42     AC_DEFINE(NO_TRACE_MSGS)
  43 else
  44     if test "$TRACE_MSGS" = "no"
  45     then
  46         AC_DEFINE(NO_TRACE_MSGS)
  47     fi
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_DECL_YYTEXT
  66 AC_PROG_RANLIB
  67 AC_PROG_INSTALL
  68 AC_PROG_LN_S
  69 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  70 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  71 AC_CYGWIN
  72 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  73
  74 dnl Check for lint
  75 AC_CHECK_PROGS(LINT, lclint lint)
  76 if test "$LINT" = "lint"
  77 then
  78   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  79   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  80 fi
  81 AC_SUBST(LINT)
  82 AC_SUBST(LINTFLAGS)
  83
  84 if test "$CYGWIN" = "yes"
  85 then
  86     LDCOMBINE="ld -r --enable-stdcall-fixup"
  87 else
  88     LDCOMBINE="ld -r"
  89 fi
  90 AC_SUBST(LDCOMBINE)
  91
  92 dnl **** Check for some libraries ****
  93
  94 dnl Check for -lm for BeOS
  95 AC_CHECK_LIB(m,sqrt)
  96 dnl Check for -li386 for NetBSD and OpenBSD
  97 AC_CHECK_LIB(i386,i386_set_ldt)
  98 dnl Check for -lossaudio for NetBSD
  99 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 100 dnl Check for -lw for Solaris
 101 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 102 dnl Check for -lnsl for Solaris
 103 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 104 dnl Check for -lsocket for Solaris
 105 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 106 dnl Check for -lxpg4 for FreeBSD
 107 AC_CHECK_LIB(xpg4,setrunelocale)
 108 dnl Check for -lmmap for OS/2
 109 AC_CHECK_LIB(mmap,mmap)
 110 dnl Check for openpty
 111 AC_CHECK_FUNCS(openpty,,
 112         AC_CHECK_LIB(util,openpty,
 113                 AC_DEFINE(HAVE_OPENPTY)
 114                 LIBS="$LIBS -lutil"
 115         ))
 116
 117 AC_CHECK_HEADERS(dlfcn.h,
 118         AC_CHECK_FUNCS(dlopen,
 119                 AC_DEFINE(HAVE_DL_API),
 120                 AC_CHECK_LIB(dl,dlopen,
 121                         AC_DEFINE(HAVE_DL_API)
 122                         LIBS="$LIBS -ldl",
 123                         LIBEXT="a"
 124                 )
 125         ),
 126         LIBEXT="a"
 127 )
 128 AC_SUBST(XLIB)
 129 AC_SUBST(X_DLLS)
 130 X_DLLS=""
 131 AC_SUBST(XFILES)
 132 XFILES=""
 133 AC_SUBST(OPENGLFILES)
 134 OPENGLFILES=""
 135 AC_SUBST(OPENGL32_DLL)
 136 OPENGL32_DLL=""
 137 AC_SUBST(DGA_SRCS)
 138 DGA_SRCS=""
 139 AC_SUBST(DGA2_SRCS)
 140 DGA2_SRCS=""
 141 AC_SUBST(MESA_SRCS)
 142 MESA_SRCS=""
 143 if test "$have_x" = "yes"
 144 then
 145     XLIB="-lXext -lX11"
 146     ac_save_CPPFLAGS="$CPPFLAGS"
 147     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 148
 149     dnl *** Check for -lXpm
 150     AC_CHECK_HEADERS(X11/xpm.h,
 151       [ dnl *** If X11/xpm.h exists...
 152         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 153           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 154           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 155         )
 156       ],
 157       [ dnl *** If X11/xpm.h does not exist...
 158         dnl NOTE: autoconf does not allow commas inside the third
 159         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 160         dnl       magic it does.
 161         echo "Redhat            :       xpm xpm-devel"
 162         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 163         echo "SuSE              :       xpm"
 164         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 165         echo
 166         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 167         echo "the directory /contrib/libraries."
 168         echo
 169         exit 1
 170       ]
 171     )
 172
 173     dnl *** All three of the following tests require X11/Xlib.h
 174     AC_CHECK_HEADERS(X11/Xlib.h,
 175       [
 176         dnl *** Check for X keyboard extension
 177         AC_CHECK_HEADERS(X11/XKBlib.h,
 178             [ dnl *** If X11/XKBlib.h exists...
 179               AC_CHECK_LIB(X11, XkbQueryExtension,
 180               AC_DEFINE(HAVE_XKB),,
 181               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 182             ],
 183             AC_MSG_WARN([XKB extension not found!!])
 184         )
 185
 186         dnl *** Check for X Shm extension
 187         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 188             [ dnl *** If X11/extensions/XShm.h exists...
 189               AC_CHECK_LIB(Xext, XShmQueryExtension,
 190               AC_DEFINE(HAVE_LIBXXSHM),,
 191               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 192             ],
 193             AC_MSG_WARN([Xshm extension not found!!])
 194         )
 195
 196         dnl *** Check for X shape extension
 197         AC_CHECK_HEADERS(X11/extensions/shape.h,
 198             [ dnl *** If X11/extensions/shape.h exists...
 199               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 200               AC_DEFINE(HAVE_LIBXSHAPE),,
 201               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 202             ],
 203             AC_MSG_WARN([XShape extension not found!!])
 204         )
 205
 206         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 207         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 208             [ dnl *** If X11/extensions/xf86dga.h exists, check
 209               dnl *** for XDGAQueryExtension()...
 210               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 211                 [ dnl *** If found...
 212                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 213                   AC_DEFINE(HAVE_LIBXXF86DGA)
 214                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 215                   DGA_SRCS='$(DGA_SRCS)'
 216                   DGA2_SRCS='$(DGA2_SRCS)'
 217                ],
 218                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 219                   dnl *** instead (DGA 2.0 not found)...
 220                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 221                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 222                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 223                       DGA_SRCS='$(DGA_SRCS)'
 224                     ],,
 225                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 226                   )
 227                 ],
 228                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 229               )
 230             ],
 231             AC_MSG_WARN([DGA extension not found!!])
 232         )
 233
 234         dnl *** Check for XFree86 VMODE extension
 235         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 236             [ dnl *** If X11/extensions/xf86vmode.h exists...
 237                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 238                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 239                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 240                   ],,
 241                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 242                 )
 243             ],
 244             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 245         )
 246
 247         dnl *** Check for XVideo extension supporting XvImages
 248         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 249             [ dnl *** If X11/extensions/Xvlib.h exists...
 250                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 251                   [ AC_DEFINE(HAVE_XVIDEO)
 252                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 253                   ],,
 254                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 255                 )
 256             ],
 257             AC_MSG_WARN([XVideo extension not found !!])
 258         )
 259
 260       ]
 261     ) dnl *** End of X11/Xlib.h check
 262
 263     dnl Check for the presence of OpenGL
 264     if test $OPENGL = "yes" -o $OPENGL = "normal"
 265     then
 266         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 267         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 268         then
 269             dnl Check for some problems due to old Mesa versions
 270             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 271               AC_TRY_COMPILE(
 272                 [#include <GL/gl.h>],
 273                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 274                 [wine_cv_opengl_version_OK="yes"],
 275                 [wine_cv_opengl_version_OK="no"]
 276               )
 277             )
 278
 279             dnl Check for the thread-safety of the OpenGL library
 280             AC_CACHE_CHECK("for thread-safe OpenGL version",
 281                            wine_cv_opengl_version_threadsafe,
 282               [saved_libs=$LIBS
 283                LIBS="$X_LIBS -lGL"
 284                AC_TRY_LINK([],[pthread_getspecific();],
 285                               [wine_cv_opengl_version_threadsafe="yes"],
 286                               [wine_cv_opengl_version_threadsafe="no"])
 287                LIBS=$saved_libs]
 288             )
 289
 290             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 291             then
 292                 dnl Check for the presence of the library
 293                 AC_CHECK_LIB(GL,glXCreateContext,
 294                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 295                              MESA_SRCS='$(MESA_SRCS)'
 296                              ,,
 297                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 298
 299                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 300                 then
 301
 302                         OPENGLFILES='$(OPENGLFILES)'
 303                         AC_DEFINE(HAVE_OPENGL)
 304
 305                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 306
 307                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 308                         then
 309                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 310                                   AC_TRY_COMPILE([#include <GL/gl.h>
 311                                                   #ifdef HAVE_GL_GLEXT_H
 312                                                   # include <GL/glext.h>
 313                                                   #endif
 314                                                   ],
 315                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 316                                                  [wine_cv_extension_prototypes="yes"],
 317                                                  [wine_cv_extension_prototypes="no"]
 318                                   )
 319                                 )
 320                                 if test $wine_cv_extension_prototypes = "yes"
 321                                 then
 322                                         AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 323                                 fi
 324
 325                                 OPENGL32_DLL=opengl32
 326                         fi
 327                 fi
 328              fi
 329          fi
 330     fi
 331
 332     CPPFLAGS="$ac_save_CPPFLAGS"
 333     X_DLLS='$(X_DLLS)'
 334     XFILES='$(XFILES)'
 335 else
 336     XLIB=""
 337     X_CFLAGS=""
 338     X_LIBS=""
 339 fi
 340
 341 dnl **** Check which curses lib to use ***
 342 if test "$CURSES" = "yes"
 343 then
 344     AC_CHECK_HEADERS(ncurses.h)
 345     if test "$ac_cv_header_ncurses_h" = "yes"
 346     then
 347         AC_CHECK_LIB(ncurses,waddch)
 348     fi
 349     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 350     then
 351         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 352         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 353     else
 354         AC_CHECK_HEADERS(curses.h)
 355         if test "$ac_cv_header_curses_h" = "yes"
 356         then
 357             AC_CHECK_LIB(curses,waddch)
 358             if test "$ac_cv_lib_curses_waddch" = "yes"
 359             then
 360                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 361                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 362             fi
 363         fi
 364     fi
 365 fi
 366
 367 dnl **** Check for IPX (currently Linux only) ****
 368 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 369  AC_TRY_COMPILE(
 370    [#include <sys/socket.h>
 371     #include <netipx/ipx.h>],
 372    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 373    [ac_cv_c_ipx_gnu="yes"],
 374    [ac_cv_c_ipx_gnu="no"])
 375  )
 376 if test "$ac_cv_c_ipx_gnu" = "yes"
 377 then
 378     AC_DEFINE(HAVE_IPX_GNU)
 379 fi
 380
 381 if test "$ac_cv_c_ipx_gnu" = "no"
 382 then
 383  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 384   AC_TRY_COMPILE(
 385     [#include <sys/socket.h>
 386      #include <asm/types.h>
 387      #include <linux/ipx.h>],
 388     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 389     [ac_cv_c_ipx_linux="yes"],
 390     [ac_cv_c_ipx_linux="no"])
 391   )
 392   if test "$ac_cv_c_ipx_linux" = "yes"
 393   then
 394       AC_DEFINE(HAVE_IPX_LINUX)
 395   fi
 396 fi
 397
 398 dnl **** Check for Open Sound System ****
 399 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 400
 401 AC_CACHE_CHECK("for Open Sound System",
 402         ac_cv_c_opensoundsystem,
 403         AC_TRY_COMPILE([
 404         #if defined(HAVE_SYS_SOUNDCARD_H)
 405                 #include <sys/soundcard.h>
 406         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 407                 #include <machine/soundcard.h>
 408         #elif defined(HAVE_SOUNDCARD_H)
 409                 #include <soundcard.h>
 410         #endif
 411         ],[
 412
 413 /* check for one of the Open Sound System specific SNDCTL_ defines */
 414 #if !defined(SNDCTL_DSP_STEREO)
 415 #error No open sound system
 416 #endif
 417 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 418
 419 if test "$ac_cv_c_opensoundsystem" = "yes"
 420 then
 421     AC_DEFINE(HAVE_OSS)
 422 fi
 423
 424 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 425         ac_cv_c_opensoundsystem_midi,
 426         AC_TRY_COMPILE([
 427         #if defined(HAVE_SYS_SOUNDCARD_H)
 428                 #include <sys/soundcard.h>
 429         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 430                 #include <machine/soundcard.h>
 431         #elif defined(HAVE_SOUNDCARD_H)
 432                 #include <soundcard.h>
 433         #endif
 434         ],[
 435
 436 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 437 #if !defined(SNDCTL_SEQ_SYNC)
 438 #error No open sound system MIDI interface
 439 #endif
 440 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 441
 442 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 443 then
 444     AC_DEFINE(HAVE_OSS_MIDI)
 445 fi
 446
 447 dnl **** If ln -s doesn't work, use cp instead ****
 448 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 449
 450 dnl **** Check for gcc strength-reduce bug ****
 451
 452 if test "x${GCC}" = "xyes"
 453 then
 454   CFLAGS="$CFLAGS -Wall"
 455   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 456                   AC_TRY_RUN([
 457 int     L[[4]] = {0,1,2,3};
 458 int main(void) {
 459   static int Array[[3]];
 460   unsigned int B = 3;
 461   int i;
 462   for(i=0; i<B; i++) Array[[i]] = i - 3;
 463   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 464   L[[i]] = 4;
 465
 466   exit( Array[[1]] != -2 || L[[2]] != 3);
 467 }],
 468     ac_cv_c_gcc_strength_bug="no",
 469     ac_cv_c_gcc_strength_bug="yes",
 470     ac_cv_c_gcc_strength_bug="yes") )
 471   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 472   then
 473     CFLAGS="$CFLAGS -fno-strength-reduce"
 474   fi
 475
 476   dnl Check for -mpreferred-stack-boundary
 477   AC_CACHE_CHECK("for gcc -mpreferred-stack-boundary=2 support",
 478                  ac_cv_c_gcc_stack_boundary,
 479   [saved_cflags=$CFLAGS
 480   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 481   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 482   CFLAGS=$saved_cflags
 483   ])
 484   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 485   then
 486     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 487   fi
 488 fi
 489
 490 dnl **** Check if we need to place .type inside a .def directive ****
 491
 492 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
 493                ac_cv_c_type_in_def,
 494 [saved_libs=$LIBS
 495 LIBS="conftest_asm.s $LIBS"
 496 cat > conftest_asm.s <<EOF
 497         .globl _ac_test
 498         .def _ac_test; .scl 2; .type 32; .endef
 499 _ac_test:
 500         .long 0
 501 EOF
 502 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 503 LIBS=$saved_libs])
 504 if test "$ac_cv_c_type_in_def" = "yes"
 505 then
 506   AC_DEFINE(NEED_TYPE_IN_DEF)
 507 fi
 508
 509 dnl **** Check for underscore on external symbols ****
 510
 511 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 512                ac_cv_c_extern_prefix,
 513 [saved_libs=$LIBS
 514 LIBS="conftest_asm.s $LIBS"
 515 cat > conftest_asm.s <<EOF
 516         .globl _ac_test
 517 _ac_test:
 518         .long 0
 519 EOF
 520 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 521             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 522 LIBS=$saved_libs])
 523 if test "$ac_cv_c_extern_prefix" = "yes"
 524 then
 525   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 526 fi
 527
 528 dnl **** Check for .string in assembler ****
 529
 530 AC_CACHE_CHECK("whether assembler accepts .string",
 531                ac_cv_c_asm_string,
 532 [saved_libs=$LIBS
 533 LIBS="conftest_asm.s $LIBS"
 534 cat > conftest_asm.s <<EOF
 535         .string "test"
 536 EOF
 537 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 538 LIBS=$saved_libs])
 539 if test "$ac_cv_c_asm_string" = "yes"
 540 then
 541   AC_DEFINE(HAVE_ASM_STRING)
 542 fi
 543
 544 dnl **** Check for working dll ****
 545
 546 LDSHARED=""
 547 LDDLLFLAGS=""
 548 if test "$LIBEXT" = "so"
 549 then
 550   AC_CACHE_CHECK("whether we can build a Linux dll",
 551                  ac_cv_c_dll_linux,
 552   [saved_cflags=$CFLAGS
 553   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 554   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 555   CFLAGS=$saved_cflags
 556   ])
 557   if test "$ac_cv_c_dll_linux" = "yes"
 558   then
 559     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%) -Wl,-rpath,\$(libdir)"
 560     LDDLLFLAGS="-Wl,-Bsymbolic"
 561   else
 562     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 563                  ac_cv_c_dll_unixware,
 564     [saved_cflags=$CFLAGS
 565     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 566     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 567     CFLAGS=$saved_cflags
 568     ])
 569     if test "$ac_cv_c_dll_unixware" = "yes"
 570     then
 571       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,\$(libdir)/%)"
 572       LDDLLFLAGS="-Wl,-B,symbolic"
 573     else
 574       AC_CACHE_CHECK("whether we can build a NetBSD dll",
 575                    ac_cv_c_dll_netbsd,
 576       [saved_cflags=$CFLAGS
 577       CFLAGS="$CFLAGS -fPIC -Wl,-Bshareable,-Bforcearchive"
 578       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 579       CFLAGS=$saved_cflags
 580       ])
 581       if test "$ac_cv_c_dll_netbsd" = "yes"
 582       then
 583         LDSHARED="\$(CC) -Wl,-Bshareable,-Bforcearchive"
 584         LDDLLFLAGS="" #FIXME
 585       fi
 586     fi
 587   fi
 588   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 589   then
 590     LIBEXT="a"
 591     if test "$DLLWRAP" = "dllwrap"; then
 592       dnl FIXME - check whether dllwrap works correctly...
 593       if test "$CYGWIN" = "yes"; then
 594         echo "*** use dllwrap for building shared library."
 595         LIBEXT="dll"
 596       fi
 597     fi
 598   fi
 599 fi
 600
 601 if test "$LIBEXT" = "a"; then
 602   echo "*** It is currently not possible to build WINE without shared"
 603   echo "*** library (.so) support to allow transparent switch between .so"
 604   echo "*** and .dll files."
 605   echo "*** If you are using Linux, you will need a newer binutils."
 606   exit 1
 607 fi
 608
 609 DLLFLAGS=""
 610 LDPATH=""
 611
 612 if test "$LIBEXT" = "so"; then
 613     DLLFLAGS="-fPIC"
 614     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 615     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 616 elif test "$LIBEXT" = "dll"; then
 617     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 618     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 619     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 620 else
 621     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) \$(LIBWINE) \$(LIBUNICODE) \$(X_LIBS) \$(XLIB)"
 622     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 623                    ac_cv_c_whole_archive,
 624             [saved_cflags=$CFLAGS
 625             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 626             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 627             CFLAGS=$saved_cflags
 628             ])
 629     if test "$ac_cv_c_whole_archive" = "yes"
 630     then
 631         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 632     else
 633         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 634                        ac_cv_c_allextract,
 635                 [saved_cflags=$CFLAGS
 636                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 637                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 638                 CFLAGS=$saved_cflags
 639                 ])
 640         if test "$ac_cv_c_allextract" = "yes"
 641         then
 642             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 643         fi
 644     fi
 645 fi
 646
 647 AC_SUBST(DLL_LINK)
 648 AC_SUBST(DLLFLAGS)
 649 AC_SUBST(LDSHARED)
 650 AC_SUBST(LDDLLFLAGS)
 651 AC_SUBST(LIBEXT)
 652 AC_SUBST(LDPATH)
 653
 654 dnl **** Check for reentrant libc ****
 655 dnl
 656 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 657 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 658
 659 wine_cv_libc_reentrant=no
 660 dnl
 661 dnl Linux style errno location
 662 dnl
 663 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 664   [AC_TRY_RUN([int myerrno = 0;
 665 char buf[256];
 666 int *__errno_location(){return &myerrno;}
 667 main(){connect(0,buf,255); exit(!myerrno);}],
 668   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 669   wine_cv_libc_r__errno_location=yes )
 670 ])
 671 if test "$wine_cv_libc_r__errno_location" = "yes"
 672 then
 673     AC_DEFINE(HAVE__ERRNO_LOCATION)
 674     wine_cv_libc_reentrant=__errno_location
 675 fi
 676 dnl
 677 dnl FreeBSD style errno location
 678 dnl
 679 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 680   [AC_TRY_RUN([int myerrno = 0;
 681 char buf[256];
 682 int *__error(){return &myerrno;}
 683 main(){connect(0,buf,255); exit(!myerrno);}],
 684     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 685     wine_cv_libc_r__error=yes )
 686 ])
 687 if test "$wine_cv_libc_r__error" = "yes"
 688 then
 689     AC_DEFINE(HAVE__ERROR)
 690     wine_cv_libc_reentrant=__error
 691 fi
 692 dnl
 693 dnl Solaris style errno location
 694 dnl
 695 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 696   [AC_TRY_RUN([int myerrno = 0;
 697 char buf[256];
 698 int *___errno(){return &myerrno;}
 699 main(){connect(0,buf,255); exit(!myerrno);}],
 700     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 701     wine_cv_libc_r___errno=yes )
 702 ])
 703 if test "$wine_cv_libc_r___errno" = "yes"
 704 then
 705     AC_DEFINE(HAVE___ERRNO)
 706     wine_cv_libc_reentrant=___errno
 707 fi
 708 dnl
 709 dnl UnixWare style errno location
 710 dnl
 711 AC_CACHE_CHECK("for reentrant libc: __thr_errno", wine_cv_libc_r__thr_errno,
 712   [AC_TRY_RUN([int myerrno = 0;
 713 char buf[256];
 714 int *__thr_errno(){return &myerrno;}
 715 main(){connect(0,buf,255); exit(!myerrno);}],
 716     wine_cv_libc_r__thr_errno=yes, wine_cv_libc_r__thr_errno=no,
 717     wine_cv_libc_r__thr_errno=yes )
 718 ])
 719 if test "$wine_cv_libc_r__thr_errno" = "yes"
 720 then
 721     AC_DEFINE(HAVE__THR_ERRNO)
 722     wine_cv_libc_reentrant=__thr_errno
 723 fi
 724 if test "$wine_cv_libc_reentrant" = "no"
 725 then
 726   AC_DEFINE(NO_REENTRANT_LIBC)
 727 fi
 728
 729 dnl **** Check for reentrant X libraries ****
 730 dnl
 731 dnl This may fail to determine whether X libraries are reentrant if
 732 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 733 dnl is possible with the --without-reentrant-x option.
 734
 735 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 736 then
 737 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 738   [ if test "x$with_reentrant_x" = "xno"
 739     then
 740         wine_cv_x_reentrant=no
 741     else
 742         libX11_check=none
 743         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 744             if test -r $dir/libX11.so; then
 745                 libX11_check="-D $dir/libX11.so"
 746                 break 1
 747             fi
 748             if test -r $dir/libX11.a; then
 749                 libX11_check="$dir/libX11.a"
 750                 break 1
 751             fi
 752         done
 753         if test "$libX11_check" != "none"; then
 754             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 755             then
 756                 wine_cv_x_reentrant=yes
 757             else
 758                 wine_cv_x_reentrant=no
 759             fi
 760         else
 761             wine_cv_x_reentrant=unknown
 762         fi
 763     fi ] )
 764 else
 765     wine_cv_x_reentrant=no
 766 fi
 767 if test "$wine_cv_x_reentrant" = "no"
 768 then
 769   AC_DEFINE(NO_REENTRANT_X11)
 770 fi
 771
 772 dnl **** Check for endianness ****
 773
 774 AC_C_BIGENDIAN
 775
 776 AC_CACHE_CHECK( "whether bitfields are bigendian", wine_cv_bitfields_bigendian,
 777   [AC_TRY_RUN([
 778 union
 779 {
 780   int word;
 781   struct
 782   {
 783       int bit0 : 1;
 784       int rest : sizeof(int)*8 - 1;
 785   } bitfield;
 786 } u;
 787 main() { u.word = 0; u.bitfield.bit0 = 1; exit( u.word == 1 ); } ],
 788     wine_cv_bitfields_bigendian=yes, wine_cv_bitfields_bigendian=no,
 789     wine_cv_bitfields_bigendian=no ) ])
 790 if test "$wine_cv_bitfields_bigendian" = "yes"
 791 then
 792   AC_DEFINE(BITFIELDS_BIGENDIAN)
 793 fi
 794
 795 AC_CACHE_CHECK( "whether unaligned memory access is allowed", wine_cv_allow_unaligned_access,
 796   [AC_TRY_RUN([
 797 long volatile test[2];
 798 main()
 799 {
 800     long volatile *ua = (long volatile *)((char *)test + 1);
 801     *ua = 0;
 802     exit(0);
 803 } ], wine_cv_allow_unaligned_access=yes, wine_cv_allow_unaligned_access=no,
 804      wine_cv_allow_unaligned_access=no ) ])
 805 if test "$wine_cv_allow_unaligned_access" = "yes"
 806 then
 807   AC_DEFINE(ALLOW_UNALIGNED_ACCESS)
 808 fi
 809
 810
 811 dnl **** Check for functions ****
 812
 813 AC_FUNC_ALLOCA()
 814 AC_CHECK_FUNCS(\
 815         __libc_fork \
 816         _lwp_create \
 817         clone \
 818         finite \
 819         fpclass \
 820         getnetbyaddr \
 821         getnetbyname \
 822         getpagesize \
 823         getprotobyname \
 824         getprotobynumber \
 825         getrlimit \
 826         getservbyport \
 827         getsockopt \
 828         inet_network \
 829         lstat \
 830         memmove \
 831         mmap \
 832         rfork \
 833         select \
 834         sendmsg \
 835         settimeofday \
 836         sigaltstack \
 837         statfs \
 838         strcasecmp \
 839         strerror \
 840         strncasecmp \
 841         tcgetattr \
 842         timegm \
 843         usleep \
 844         vfscanf \
 845         wait4 \
 846         waitpid \
 847 )
 848
 849 dnl **** Check for header files ****
 850
 851 AC_CHECK_HEADERS(\
 852         arpa/inet.h \
 853         arpa/nameser.h \
 854         elf.h \
 855         float.h \
 856         ieeefp.h \
 857         libio.h \
 858         libutil.h \
 859         link.h \
 860         linux/cdrom.h \
 861         linux/input.h \
 862         linux/joystick.h \
 863         linux/ucdrom.h \
 864         net/if.h \
 865         netdb.h \
 866         netinet/in.h \
 867         netinet/in_systm.h \
 868         netinet/ip.h \
 869         netinet/tcp.h \
 870         pty.h \
 871         resolv.h \
 872         sched.h \
 873         socket.h \
 874         strings.h \
 875         sys/cdio.h \
 876         sys/errno.h \
 877         sys/file.h \
 878         sys/filio.h \
 879         sys/ipc.h \
 880         sys/lwp.h \
 881         sys/mman.h \
 882         sys/modem.h \
 883         sys/mount.h \
 884         sys/msg.h \
 885         sys/param.h \
 886         sys/ptrace.h \
 887         sys/reg.h \
 888         sys/signal.h \
 889         sys/shm.h \
 890         sys/socket.h \
 891         sys/sockio.h \
 892         sys/statfs.h \
 893         sys/strtio.h \
 894         sys/syscall.h \
 895         sys/user.h \
 896         sys/wait.h \
 897         sys/v86.h \
 898         sys/v86intr.h \
 899         sys/vfs.h \
 900         sys/vm86.h \
 901         syscall.h \
 902         ucontext.h \
 903 )
 904 AC_HEADER_STAT()
 905
 906 dnl **** Check for types ****
 907
 908 AC_C_CONST()
 909 AC_C_INLINE()
 910 AC_TYPE_SIZE_T()
 911 AC_CHECK_SIZEOF(long long,0)
 912
 913
 914 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
 915         wine_cv_linux_gethostbyname_r_6,
 916         AC_TRY_COMPILE([
 917 #include <netdb.h>
 918         ], [
 919     char *name=NULL;
 920     struct hostent he;
 921     struct hostent *result;
 922     char *buf=NULL;
 923     int bufsize=0;
 924     int res,errnr;
 925     char *addr=NULL;
 926     int addrlen=0;
 927     int addrtype=0;
 928     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 929     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 930     ],
 931         wine_cv_linux_gethostbyname_r_6=yes,
 932         wine_cv_linux_gethostbyname_r_6=no
 933         )
 934    )
 935    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 936    then
 937       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6)
 938    fi
 939
 940 if test "$ac_cv_header_linux_joystick_h" = "yes"
 941 then
 942    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 943         wine_cv_linux_joystick_22_api,
 944         AC_TRY_COMPILE([
 945         #include <sys/ioctl.h>
 946         #include <linux/joystick.h>
 947
 948         struct js_event blub;
 949         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 950         #error "no 2.2 header"
 951         #endif
 952         ],/*empty*/,
 953         wine_cv_linux_joystick_22_api=yes,
 954         wine_cv_linux_joystick_22_api=no,
 955         wine_cv_linux_joystick_22_api=no
 956         )
 957    )
 958    if test "$wine_cv_linux_joystick_22_api" = "yes"
 959    then
 960       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 961    fi
 962 fi
 963
 964 dnl **** statfs checks ****
 965
 966 if test "$ac_cv_header_sys_vfs_h" = "yes"
 967 then
 968     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 969                     wine_cv_sys_vfs_has_statfs,
 970         AC_TRY_COMPILE([
 971         #include <sys/types.h>
 972         #ifdef HAVE_SYS_PARAM_H
 973         # include <sys/param.h>
 974         #endif
 975         #include <sys/vfs.h>
 976         ],[
 977                 struct statfs stfs;
 978
 979                 memset(&stfs,0,sizeof(stfs));
 980         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 981         )
 982     )
 983     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 984     then
 985       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 986     fi
 987 fi
 988
 989 if test "$ac_cv_header_sys_statfs_h" = "yes"
 990 then
 991     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 992                     wine_cv_sys_statfs_has_statfs,
 993         AC_TRY_COMPILE([
 994         #include <sys/types.h>
 995         #ifdef HAVE_SYS_PARAM_H
 996         # include <sys/param.h>
 997         #endif
 998         #include <sys/statfs.h>
 999         ],[
1000                 struct statfs stfs;
1001         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1002         )
1003     )
1004     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1005     then
1006       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
1007     fi
1008 fi
1009
1010 if test "$ac_cv_header_sys_mount_h" = "yes"
1011 then
1012     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
1013                     wine_cv_sys_mount_has_statfs,
1014         AC_TRY_COMPILE([
1015         #include <sys/types.h>
1016         #ifdef HAVE_SYS_PARAM_H
1017         # include <sys/param.h>
1018         #endif
1019         #include <sys/mount.h>
1020         ],[
1021                 struct statfs stfs;
1022         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1023         )
1024     )
1025     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1026     then
1027       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
1028     fi
1029 fi
1030
1031 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1032
1033 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
1034   [ if test "x$statfs_bfree" = "xno"
1035     then
1036         wine_cv_statfs_bfree=no
1037     else
1038         AC_TRY_COMPILE([
1039         #include <sys/types.h>
1040         #ifdef HAVE_SYS_PARAM_H
1041         # include <sys/param.h>
1042         #endif
1043         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1044         # include <sys/mount.h>
1045         #else
1046         # ifdef STATFS_DEFINED_BY_SYS_VFS
1047         #  include <sys/vfs.h>
1048         # else
1049         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1050         #   include <sys/statfs.h>
1051         #  endif
1052         # endif
1053         #endif
1054         ],[
1055                 struct statfs stfs;
1056
1057                 stfs.f_bfree++;
1058         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1059         )
1060     fi ] )
1061 if test "$wine_cv_statfs_bfree" = "yes"
1062 then
1063   AC_DEFINE(STATFS_HAS_BFREE)
1064 fi
1065
1066 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
1067   [ if test "x$statfs_bavail" = "xno"
1068     then
1069         wine_cv_statfs_bavail=no
1070     else
1071         AC_TRY_COMPILE([
1072         #include <sys/types.h>
1073         #ifdef HAVE_SYS_PARAM_H
1074         # include <sys/param.h>
1075         #endif
1076         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1077         # include <sys/mount.h>
1078         #else
1079         # ifdef STATFS_DEFINED_BY_SYS_VFS
1080         #  include <sys/vfs.h>
1081         # else
1082         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1083         #   include <sys/statfs.h>
1084         #  endif
1085         # endif
1086         #endif
1087         ],[
1088                 struct statfs stfs;
1089
1090                 stfs.f_bavail++;
1091         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1092         )
1093     fi ] )
1094 if test "$wine_cv_statfs_bavail" = "yes"
1095 then
1096   AC_DEFINE(STATFS_HAS_BAVAIL)
1097 fi
1098
1099 dnl *** check for file descriptor passing with msg_accrights
1100
1101 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1102  AC_TRY_COMPILE([#include <sys/types.h>
1103 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1104                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1105 if test "$ac_cv_c_msg_accrights" = "yes"
1106 then
1107     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
1108 fi
1109
1110 dnl *** Check for the sun_len member in struct sockaddr_un
1111
1112 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
1113  AC_TRY_COMPILE([#include <sys/types.h>
1114 #include <sys/socket.h>
1115 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1116                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
1117 if test "$ac_cv_c_sun_len" = "yes"
1118 then
1119     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
1120 fi
1121
1122 dnl *** check for the need to define __i386__
1123
1124 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1125  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1126 yes
1127 #endif],
1128  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1129 if test "$ac_cv_cpp_def_i386" = "yes"
1130 then
1131     CFLAGS="$CFLAGS -D__i386__"
1132     LINTFLAGS="$LINTFLAGS -D__i386__"
1133 fi
1134
1135 dnl $GCC is set by autoconf
1136 GCC_NO_BUILTIN=""
1137 if test "$GCC" = "yes"
1138 then
1139     GCC_NO_BUILTIN="-fno-builtin"
1140 fi
1141 AC_SUBST(GCC_NO_BUILTIN)
1142
1143 dnl **** Generate output files ****
1144
1145 AC_OUTPUT_COMMANDS([
1146 extra_subdirs="\
1147 dlls/ddraw/d3ddevice \
1148 dlls/ddraw/dclipper \
1149 dlls/ddraw/ddraw \
1150 dlls/ddraw/direct3d \
1151 dlls/ddraw/dpalette \
1152 dlls/ddraw/dsurface \
1153 dlls/dinput/joystick \
1154 dlls/dinput/keyboard \
1155 dlls/dinput/mouse \
1156 dlls/kernel/messages \
1157 dlls/user/resources \
1158 "
1159 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1160
1161 MAKE_RULES=Make.rules
1162 AC_SUBST_FILE(MAKE_RULES)
1163
1164 MAKE_DLL_RULES=dlls/Makedll.rules
1165 AC_SUBST_FILE(MAKE_DLL_RULES)
1166
1167 MAKE_PROG_RULES=programs/Makeprog.rules
1168 AC_SUBST_FILE(MAKE_PROG_RULES)
1169
1170 AC_OUTPUT([
1171 Make.rules
1172 dlls/Makedll.rules
1173 programs/Makeprog.rules
1174 Makefile
1175 console/Makefile
1176 controls/Makefile
1177 debugger/Makefile
1178 dlls/Makefile
1179 dlls/advapi32/Makefile
1180 dlls/avifil32/Makefile
1181 dlls/comctl32/Makefile
1182 dlls/commdlg/Makefile
1183 dlls/crtdll/Makefile
1184 dlls/dciman32/Makefile
1185 dlls/ddraw/Makefile
1186 dlls/dinput/Makefile
1187 dlls/dplay/Makefile
1188 dlls/dplayx/Makefile
1189 dlls/dsound/Makefile
1190 dlls/gdi/Makefile
1191 dlls/icmp/Makefile
1192 dlls/imagehlp/Makefile
1193 dlls/imm32/Makefile
1194 dlls/kernel/Makefile
1195 dlls/lzexpand/Makefile
1196 dlls/mpr/Makefile
1197 dlls/msacm/Makefile
1198 dlls/msnet32/Makefile
1199 dlls/msvideo/Makefile
1200 dlls/ntdll/Makefile
1201 dlls/odbc32/Makefile
1202 dlls/ole32/Makefile
1203 dlls/oleaut32/Makefile
1204 dlls/olecli/Makefile
1205 dlls/oledlg/Makefile
1206 dlls/olepro32/Makefile
1207 dlls/olesvr/Makefile
1208 dlls/opengl32/Makefile
1209 dlls/psapi/Makefile
1210 dlls/rasapi32/Makefile
1211 dlls/richedit/Makefile
1212 dlls/rpcrt4/Makefile
1213 dlls/serialui/Makefile
1214 dlls/setupapi/Makefile
1215 dlls/shell32/Makefile
1216 dlls/shfolder/Makefile
1217 dlls/shlwapi/Makefile
1218 dlls/tapi32/Makefile
1219 dlls/ttydrv/Makefile
1220 dlls/urlmon/Makefile
1221 dlls/user/Makefile
1222 dlls/version/Makefile
1223 dlls/win32s/Makefile
1224 dlls/winaspi/Makefile
1225 dlls/winedos/Makefile
1226 dlls/wineps/Makefile
1227 dlls/wininet/Makefile
1228 dlls/winmm/Makefile
1229 dlls/winmm/joystick/Makefile
1230 dlls/winmm/mcianim/Makefile
1231 dlls/winmm/mciavi/Makefile
1232 dlls/winmm/mcicda/Makefile
1233 dlls/winmm/mciseq/Makefile
1234 dlls/winmm/mciwave/Makefile
1235 dlls/winmm/midimap/Makefile
1236 dlls/winmm/wavemap/Makefile
1237 dlls/winmm/wineoss/Makefile
1238 dlls/winnls/Makefile
1239 dlls/winsock/Makefile
1240 dlls/winspool/Makefile
1241 dlls/wow32/Makefile
1242 dlls/wsock32/Makefile
1243 dlls/x11drv/Makefile
1244 documentation/Makefile
1245 documentation/wine.conf.man
1246 documentation/wine.man
1247 files/Makefile
1248 graphics/Makefile
1249 graphics/enhmetafiledrv/Makefile
1250 graphics/metafiledrv/Makefile
1251 graphics/win16drv/Makefile
1252 graphics/x11drv/Makefile
1253 if1632/Makefile
1254 include/Makefile
1255 library/Makefile
1256 libtest/Makefile
1257 loader/Makefile
1258 loader/dos/Makefile
1259 loader/ne/Makefile
1260 memory/Makefile
1261 misc/Makefile
1262 miscemu/Makefile
1263 msdos/Makefile
1264 objects/Makefile
1265 ole/Makefile
1266 programs/Makefile
1267 programs/avitools/Makefile
1268 programs/clock/Makefile
1269 programs/cmdlgtst/Makefile
1270 programs/control/Makefile
1271 programs/notepad/Makefile
1272 programs/osversioncheck/Makefile
1273 programs/progman/Makefile
1274 programs/regapi/Makefile
1275 programs/regtest/Makefile
1276 programs/uninstaller/Makefile
1277 programs/view/Makefile
1278 programs/wcmd/Makefile
1279 programs/winemine/Makefile
1280 programs/winhelp/Makefile
1281 programs/winver/Makefile
1282 relay32/Makefile
1283 scheduler/Makefile
1284 server/Makefile
1285 tools/Makefile
1286 tools/cvdump/Makefile
1287 tools/winebuild/Makefile
1288 tools/winelauncher
1289 tools/wmc/Makefile
1290 tools/wrc/Makefile
1291 tsx11/Makefile
1292 unicode/Makefile
1293 win32/Makefile
1294 windows/Makefile
1295 windows/x11drv/Makefile ])
1296
1297 if test "$have_x" = "no"
1298 then
1299   echo
1300   echo "*** Warning: X development files not found. Wine will be built without"
1301   echo "*** X support, which currently does not work, and would probably not be"
1302   echo "*** what you want anyway. You will need to install devel packages of"
1303   echo "*** Xlib/Xfree86 and Xpm at the very least."
1304 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1305 then
1306   echo
1307   echo "*** Warning: Xpm development files not found. Wine will be built without"
1308   echo "*** Xpm support, which currently does not work. You will need to install"
1309   echo "*** devel packages of Xpm."
1310 fi
1311
1312 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1313 then
1314   echo
1315   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1316   echo "*** terminal resize support. Consider upgrading ncurses."
1317 fi
1318
1319 if test "$wine_cv_libc_reentrant" = "no"
1320 then
1321   echo
1322   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1323   echo "*** thread support. Consider upgrading libc to a more recent"
1324   echo "*** reentrant version of libc."
1325 fi
1326
1327 if test "$wine_cv_opengl_version_OK" = "no"
1328 then
1329   echo
1330   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1331   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1332 fi
1333
1334 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1335 then
1336   echo
1337   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1338   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1339   echo "*** A fix for glibc 2.1.3 that seem to work is included in this version of Wine,"
1340   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1341 fi
1342
1343 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1344 then
1345   echo
1346   echo "*** Warning: you explicitely linked in a thread-safe OpenGL version. If you"
1347   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1348   echo "*** support before reporting bugs."
1349 fi
1350
1351
1352 echo
1353 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1354 echo
1355
1356 dnl Local Variables:
1357 dnl comment-start: "dnl "
1358 dnl comment-end: ""
1359 dnl comment-start-skip: "\\bdnl\\b\\s *"
1360 dnl compile-command: "autoconf"
1361 dnl End: