configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 dnl autoconf versions before 2.62 don't handle source dir symlinks correctly
   8 AC_PREREQ(2.62)
   9 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org],[wine],[http://www.winehq.org])
  10 AC_CONFIG_SRCDIR(server/atom.c)
  11 AC_CONFIG_HEADERS(include/config.h)
  12 AC_CONFIG_AUX_DIR(tools)
  13
  14 dnl autoconf versions before 2.63b don't have AS_VAR_APPEND or AS_VAR_IF
  15 m4_ifdef([AS_VAR_APPEND],,[as_fn_append () { eval $[1]=\$$[1]\$[2]; }
  16 AC_DEFUN([AS_VAR_APPEND],[as_fn_append $1 $2])])dnl
  17 m4_ifdef([AS_VAR_IF],,[AC_DEFUN([AS_VAR_IF],
  18 [AS_LITERAL_IF([$1],
  19   [AS_IF([test "x$$1" = x""$2], [$3], [$4])],
  20   [eval as_val=\$$1
  21    AS_IF([test "x$as_val" = x""$2], [$3], [$4])])])])dnl
  22 dnl autoconf versions before 2.64 don't have AC_PACKAGE_URL
  23 m4_ifdef([AC_PACKAGE_URL],,
  24   [AC_DEFINE([PACKAGE_URL], ["http://www.winehq.org"], [Define to the home page for this package.])
  25    AC_SUBST([PACKAGE_URL], ["http://www.winehq.org"])])dnl
  26
  27 dnl **** Command-line arguments ****
  28
  29 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  30 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  31 AC_ARG_ENABLE(tests, AS_HELP_STRING([--disable-tests],[do not build the regression tests]))
  32 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]))
  33
  34 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  36 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  37             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  38 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  40 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  41             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  42 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  43 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  45 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  46             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  47 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  48 AC_ARG_WITH(gettext,   AS_HELP_STRING([--without-gettext],[do not use gettext]))
  49 AC_ARG_WITH(gettextpo, AS_HELP_STRING([--with-gettextpo],[use the GetTextPO library to rebuild po files]),
  50             [if test "x$withval" = "xno"; then ac_cv_header_gettext_po_h=no; fi])
  51 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  52 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_GL_glu_h=no; fi])
  54 AC_ARG_WITH(gnutls,    AS_HELP_STRING([--without-gnutls],[do not use GnuTLS (schannel support)]))
  55 AC_ARG_WITH(gsm,       AS_HELP_STRING([--without-gsm],[do not use libgsm (GSM 06.10 codec support)]),
  56             [if test "x$withval" = "xno"; then ac_cv_header_gsm_h=no; ac_cv_header_gsm_gsm_h=no; fi])
  57 AC_ARG_WITH(gstreamer, AS_HELP_STRING([--without-gstreamer],[do not use GStreamer (codecs support)]))
  58 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  59 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  61 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  63 AC_ARG_WITH(mpg123,    AS_HELP_STRING([--without-mpg123],[do not use the mpg123 library]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_mpg123_h=no; fi])
  65 AC_ARG_WITH(openal,    AS_HELP_STRING([--without-openal],[do not use OpenAL]),
  66             [if test "x$withval" = "xno"; then ac_cv_header_AL_al_h=no; ac_cv_header_OpenAL_al_h=no; fi])
  67 AC_ARG_WITH(opencl,    AS_HELP_STRING([--without-opencl],[do not use OpenCL]),
  68             [if test "x$withval" = "xno"; then ac_cv_header_CL_cl_h=no; ac_cv_header_OpenCL_opencl_h=no; fi])
  69 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  70 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  71             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  72 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]))
  73 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  74             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  75 AC_ARG_WITH(pthread,   AS_HELP_STRING([--without-pthread],[do not use the pthread library]),
  76             [if test "x$withval" = "xno"; then ac_cv_header_pthread_h=no; fi])
  77 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  78 AC_ARG_WITH(tiff,       AS_HELP_STRING([--without-tiff],[do not use TIFF]),
  79             [if test "x$withval" = "xno"; then ac_cv_header_tiffio_h=no; fi])
  80 AC_ARG_WITH(v4l,       AS_HELP_STRING([--without-v4l],[do not use v4l1 (v4l support)]))
  81 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  82             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  83 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  84             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  85 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  86             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  87 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  88             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  89 AC_ARG_WITH(xinput2,   AS_HELP_STRING([--without-xinput2],[do not use the Xinput 2 extension]),
  90             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput2_h=no; fi])
  91 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  92 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  93             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  94 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  95             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  96 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  97             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  98 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  99             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
 100 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
 101 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
 102             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; ac_cv_header_X11_extensions_xf86vmproto_h=no; fi])
 103 AC_ARG_WITH(zlib,      AS_HELP_STRING([--without-zlib],[do not use Zlib (data compression)]),
 104             [if test "x$withval" = "xno"; then ac_cv_header_zlib_h=no; fi])
 105
 106 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
 107 AC_ARG_WITH(wine64,    AS_HELP_STRING([--with-wine64=DIR],[use the 64-bit Wine in DIR for a Wow64 build]))
 108
 109 AC_CANONICAL_HOST
 110
 111 dnl check for out of tree build with unclean source tree
 112 case "$srcdir" in
 113  .) ;;
 114  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 115       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 116 You need to run 'make distclean' in the source tree first.])
 117     fi ;;
 118 esac
 119
 120 dnl **** Check for some programs ****
 121
 122 AC_PROG_MAKE_SET
 123 AC_PROG_CC
 124 AC_PROG_CXX
 125 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 126 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 127 AC_DEFINE_UNQUOTED(EXEEXT,["$ac_exeext"],[Define to the file extension for executables.])
 128
 129 case $host in
 130   *-darwin*)
 131     if test "x$enable_win64" = "xyes"
 132     then
 133       CC="$CC -m64"
 134       CXX="$CXX -m64"
 135       host_cpu="x86_64"
 136       notice_platform="64-bit "
 137       AC_SUBST(TARGETFLAGS,"-m64")
 138     else
 139       CC="$CC -m32"
 140       CXX="$CXX -m32"
 141       host_cpu="i386"
 142       notice_platform="32-bit "
 143       AC_SUBST(TARGETFLAGS,"-m32")
 144       enable_win16=${enable_win16:-yes}
 145     fi
 146     ;;
 147   x86_64*)
 148     if test "x$enable_win64" != "xyes" -a "$cross_compiling" != "yes"
 149     then
 150       CC="$CC -m32"
 151       CXX="$CXX -m32"
 152       AC_MSG_CHECKING([whether $CC works])
 153       AC_LINK_IFELSE([AC_LANG_PROGRAM()],AC_MSG_RESULT([yes]),
 154                      [AC_MSG_RESULT([no])
 155                       AC_MSG_ERROR([Cannot build a 32-bit program, you need to install 32-bit development libraries.])])
 156       host_cpu="i386"
 157       notice_platform="32-bit "
 158       AC_SUBST(TARGETFLAGS,"-m32")
 159       enable_win16=${enable_win16:-yes}
 160     else
 161       if test "x${GCC}" = "xyes"
 162       then
 163         AC_MSG_CHECKING([whether $CC supports __builtin_ms_va_list])
 164         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[void func(__builtin_ms_va_list *args);]])],
 165                           [AC_MSG_RESULT([yes])],
 166                           [AC_MSG_RESULT([no])
 167                            AC_MSG_ERROR([You need gcc >= 4.4 to build Wine as 64-bit.])])
 168       fi
 169       AC_SUBST(TARGETFLAGS,"-m64")
 170     fi
 171     ;;
 172   *-mingw32*|*-cygwin*)
 173     enable_win16=${enable_win16:-no}
 174     CFLAGS="$CFLAGS -D_WIN32"
 175     ;;
 176   i[[3456789]]86*)
 177     enable_win16=${enable_win16:-yes}
 178     ;;
 179 esac
 180
 181 dnl enable_win16 defaults to yes on x86, to no on other CPUs
 182 enable_win16=${enable_win16:-no}
 183 enable_win64=${enable_win64:-no}
 184
 185 dnl Disable winetest too if tests are disabled
 186 enable_winetest=${enable_winetest:-$enable_tests}
 187
 188 dnl Some special cases for the wow64 build
 189 if test -n "$with_wine64"
 190 then
 191     if test "x$enable_win64" = "xyes"
 192     then
 193         AC_MSG_ERROR([--enable-win64 and --with-wine64 are mutually exclusive.
 194 --enable-win64 should be used in the 64-bit build tree, --with-wine64 in the 32-bit Wow64 build tree.])
 195     fi
 196     AC_SUBST([WOW64_DISABLE],[\#])
 197     enable_fonts=${enable_fonts:-no}
 198     enable_server=${enable_server:-no}
 199     enable_tools=${enable_tools:-no}
 200 elif test "x$enable_win64" = "xyes"
 201 then
 202     test "x$libdir" != "x\${exec_prefix}/lib" || libdir="\${exec_prefix}/lib64"
 203 fi
 204
 205 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 206   [wine_cv_toolsdir="$with_wine_tools"
 207    if test -z "$with_wine_tools"; then
 208      if test "$cross_compiling" = "yes"; then
 209        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 210      elif test -n "$with_wine64"; then
 211        wine_cv_toolsdir="$with_wine64"
 212      fi
 213    fi
 214    if test -z "$wine_cv_toolsdir"; then
 215      wine_cv_toolsdir="\$(top_builddir)"
 216    elif test -d "$wine_cv_toolsdir/tools/winebuild"; then
 217      case "$wine_cv_toolsdir" in
 218        /*) ;;
 219        *)  wine_cv_toolsdir="\$(top_builddir)/$wine_cv_toolsdir" ;;
 220      esac
 221    else
 222      AC_MSG_ERROR([could not find Wine tools in $wine_cv_toolsdir])
 223    fi])
 224 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 225 if test -n "$host_alias" -a "$host_alias" != "$build_alias"
 226 then
 227     AC_SUBST(TARGETFLAGS,"-b $host_alias $TARGETFLAGS")
 228 fi
 229
 230 dnl Check for flex
 231 AC_CHECK_PROGS(FLEX,flex,none)
 232 if test "$FLEX" = "none"
 233 then
 234   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 235 fi
 236 AC_MSG_CHECKING([whether flex is recent enough])
 237 cat >conftest.l <<EOF
 238 %top{
 239 #include "prediluvian.h"
 240 }
 241 %%
 242 EOF
 243 if $FLEX -t conftest.l >/dev/null 2>&AS_MESSAGE_LOG_FD
 244 then
 245   AC_MSG_RESULT([yes])
 246 else
 247   AC_MSG_RESULT([no])
 248   AC_MSG_ERROR([Your flex version is too old. Please install flex version 2.5.33 or newer.])
 249 fi
 250
 251 dnl Check for bison
 252 AC_CHECK_PROGS(BISON,bison,none)
 253 if test "$BISON" = "none"
 254 then
 255   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 256 fi
 257
 258 AC_CHECK_TOOLS(AR,[ar gar],ar)
 259 AC_SUBST(ARFLAGS,rc)
 260 AC_PROG_RANLIB
 261 AC_PROG_LN_S
 262 AC_PROG_EGREP
 263 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 264 AC_PROG_INSTALL
 265 dnl Prepend src dir to install path dir if it's a relative path
 266 case "$INSTALL" in
 267   [[\\/$]]* | ?:[[\\/]]* ) ;;
 268   *)  INSTALL="\\\$(top_srcdir)/$INSTALL" ;;
 269 esac
 270
 271 dnl Check for lint
 272 AC_CHECK_PROGS(LINT, lclint lint)
 273 if test "$LINT" = "lint"
 274 then
 275   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 276   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 277 fi
 278 AC_SUBST(LINTFLAGS)
 279
 280 dnl Check for various programs
 281 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 282 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 283 AC_CHECK_PROGS(RSVG, rsvg, false)
 284 AC_CHECK_PROGS(CONVERT, convert, false)
 285 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 286 AC_CHECK_PROGS(MSGFMT, msgfmt, false)
 287
 288 if test "x$enable_maintainer_mode" != "xyes"
 289 then
 290   AC_SUBST([MAINTAINER_MODE],[\#])
 291 else
 292   if test "$FONTFORGE" = "false"; then AC_MSG_ERROR([You need fontforge to rebuild fonts in maintainer mode.]); fi
 293   if test "$RSVG" = "false"; then AC_MSG_ERROR([You need rsvg to rebuild icons in maintainer mode.]); fi
 294
 295   dnl Check the imagemagick version
 296   if test "$CONVERT" = false
 297   then
 298     AC_MSG_ERROR([You need imagemagick to rebuild icons in maintainer mode.])
 299   else
 300     AC_MSG_CHECKING([for recent enough imagemagick])
 301     convert_version=`convert --version | head -n1`
 302     if test "x$convert_version" != "x"
 303     then
 304       convert_version_major=`expr "$convert_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 305       convert_version_minor=`expr "$convert_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 306       if test "$convert_version_major" -eq 6 -a "$convert_version_minor" -lt 6
 307       then
 308         CONVERT=false
 309       fi
 310     fi
 311     if test "$CONVERT" = false
 312     then
 313       AC_MSG_RESULT([no ($convert_version_major.$convert_version_minor)])
 314       AC_MSG_ERROR([You need imagemagick version 6.6 or newer to rebuild icons in maintainer mode.])
 315     else
 316       AC_MSG_RESULT([yes ($convert_version_major.$convert_version_minor)])
 317     fi
 318   fi
 319
 320   dnl Check the icotool version
 321   if test "$ICOTOOL" = false
 322   then
 323     AC_MSG_ERROR([You need icotool to rebuild icons in maintainer mode.])
 324   else
 325     AC_MSG_CHECKING([for recent enough icotool])
 326     icotool_version=`icotool --version | head -n1`
 327     if test "x$icotool_version" != "x"
 328     then
 329       icotool_version_major=`expr "$icotool_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 330       icotool_version_minor=`expr "$icotool_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 331       if test "$icotool_version_major" -eq 0 -a "$icotool_version_minor" -lt 29
 332       then
 333         ICOTOOL=false
 334         WINE_WARNING([icotool version 0.29.0 or newer is needed to rebuild icons.])
 335       fi
 336     fi
 337     if test "$ICOTOOL" = false
 338     then
 339       AC_MSG_RESULT([no ($icotool_version_major.$icotool_version_minor)])
 340       AC_MSG_ERROR([You need icotool version 0.29.0 or newer to rebuild icons in maintainer mode.])
 341     else
 342       AC_MSG_RESULT([yes ($icotool_version_major.$icotool_version_minor)])
 343     fi
 344   fi
 345
 346   dnl Maintainer mode requires gettext
 347   with_gettext=yes
 348   with_gettextpo=yes
 349   AS_UNSET(ac_cv_header_gettext_po_h)
 350 fi
 351
 352 test "x$with_gettext" != xno || MSGFMT=false
 353 WINE_WARNING_WITH(gettext,[test "$MSGFMT" = false],
 354                   [gettext tools not found, translations won't be built.])
 355
 356 dnl **** Check for some libraries ****
 357
 358 dnl Check for -li386 for NetBSD and OpenBSD
 359 AC_CHECK_LIB(i386,i386_set_ldt)
 360 dnl Check for -lossaudio for NetBSD
 361 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 362
 363 AC_SUBST(XLIB,"")
 364 AC_SUBST(OPENGL_LIBS,"")
 365
 366 dnl **** Check for header files ****
 367
 368 AC_SYS_LARGEFILE()
 369
 370 AC_CHECK_HEADERS(\
 371         AL/al.h \
 372         ApplicationServices/ApplicationServices.h \
 373         AudioToolbox/AudioConverter.h \
 374         AudioUnit/AudioUnit.h \
 375         AudioUnit/AudioComponent.h \
 376         CL/cl.h \
 377         Carbon/Carbon.h \
 378         CoreAudio/CoreAudio.h \
 379         DiskArbitration/DiskArbitration.h \
 380         IOKit/IOKitLib.h \
 381         IOKit/hid/IOHIDLib.h \
 382         OpenAL/al.h \
 383         OpenCL/opencl.h \
 384         QuickTime/ImageCompression.h \
 385         Security/Security.h \
 386         alias.h \
 387         alsa/asoundlib.h \
 388         arpa/inet.h \
 389         arpa/nameser.h \
 390         asm/types.h \
 391         capi20.h \
 392         curses.h \
 393         direct.h \
 394         dirent.h \
 395         dlfcn.h \
 396         elf.h \
 397         float.h \
 398         fnmatch.h \
 399         fontconfig/fontconfig.h \
 400         getopt.h \
 401         gettext-po.h \
 402         grp.h \
 403         gsm.h \
 404         gsm/gsm.h \
 405         ieeefp.h \
 406         inet/mib2.h \
 407         io.h \
 408         jpeglib.h \
 409         kstat.h \
 410         lber.h \
 411         lcms.h \
 412         lcms/lcms.h \
 413         ldap.h \
 414         link.h \
 415         linux/cdrom.h \
 416         linux/compiler.h \
 417         linux/hdreg.h \
 418         linux/input.h \
 419         linux/ioctl.h \
 420         linux/joystick.h \
 421         linux/major.h \
 422         linux/param.h \
 423         linux/serial.h \
 424         linux/types.h \
 425         linux/ucdrom.h \
 426         mach-o/nlist.h \
 427         mach-o/loader.h \
 428         mach/mach.h \
 429         mach/machine.h \
 430         machine/cpu.h \
 431         machine/limits.h \
 432         machine/sysarch.h \
 433         mntent.h \
 434         mpg123.h \
 435         ncurses.h \
 436         netdb.h \
 437         netinet/in.h \
 438         netinet/in_systm.h \
 439         netinet/tcp.h \
 440         netinet/tcp_fsm.h \
 441         openssl/err.h \
 442         openssl/ssl.h \
 443         png.h \
 444         poll.h \
 445         port.h \
 446         process.h \
 447         pthread.h \
 448         pwd.h \
 449         regex.h \
 450         sched.h \
 451         scsi/scsi.h \
 452         scsi/scsi_ioctl.h \
 453         scsi/sg.h \
 454         stdbool.h \
 455         stdint.h \
 456         strings.h \
 457         stropts.h \
 458         sys/asoundlib.h \
 459         sys/attr.h \
 460         sys/cdio.h \
 461         sys/elf32.h \
 462         sys/epoll.h \
 463         sys/errno.h \
 464         sys/event.h \
 465         sys/exec_elf.h \
 466         sys/filio.h \
 467         sys/inotify.h \
 468         sys/ioctl.h \
 469         sys/ipc.h \
 470         sys/limits.h \
 471         sys/link.h \
 472         sys/mman.h \
 473         sys/modem.h \
 474         sys/msg.h \
 475         sys/mtio.h \
 476         sys/param.h \
 477         sys/poll.h \
 478         sys/prctl.h \
 479         sys/protosw.h \
 480         sys/ptrace.h \
 481         sys/resource.h \
 482         sys/scsiio.h \
 483         sys/shm.h \
 484         sys/signal.h \
 485         sys/socket.h \
 486         sys/socketvar.h \
 487         sys/sockio.h \
 488         sys/statvfs.h \
 489         sys/strtio.h \
 490         sys/syscall.h \
 491         sys/tihdr.h \
 492         sys/time.h \
 493         sys/timeout.h \
 494         sys/times.h \
 495         sys/uio.h \
 496         sys/un.h \
 497         sys/utsname.h \
 498         sys/vm86.h \
 499         sys/wait.h \
 500         syscall.h \
 501         termios.h \
 502         tiffio.h \
 503         unistd.h \
 504         utime.h \
 505         valgrind/memcheck.h \
 506         valgrind/valgrind.h \
 507         zlib.h
 508 )
 509 AC_HEADER_STAT()
 510
 511 dnl **** Checks for headers that depend on other ones ****
 512
 513 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/sysctl.h sys/user.h sys/vfs.h],,,
 514     [#include <sys/types.h>
 515      #ifdef HAVE_SYS_PARAM_H
 516      # include <sys/param.h>
 517      #endif])
 518
 519 AC_CHECK_HEADERS(\
 520         netinet/ip.h \
 521         net/if.h \
 522         net/if_arp.h \
 523         net/if_dl.h \
 524         net/if_types.h \
 525         net/route.h \
 526         netinet/if_ether.h \
 527         netinet/if_inarp.h \
 528         netinet/in_pcb.h \
 529         netinet/ip_icmp.h \
 530         netinet/ip_var.h \
 531         netinet/udp.h \
 532         netipx/ipx.h \
 533 ,,,[#include <sys/types.h>
 534      #ifdef HAVE_SYS_SOCKET_H
 535      # include <sys/socket.h>
 536      #endif
 537      #ifdef HAVE_SYS_SOCKETVAR_H
 538      # include <sys/socketvar.h>
 539      #endif
 540      #ifdef HAVE_NET_ROUTE_H
 541      # include <net/route.h>
 542      #endif
 543      #ifdef HAVE_NETINET_IN_H
 544      # include <netinet/in.h>
 545      #endif
 546      #ifdef HAVE_NETINET_IN_SYSTM_H
 547      # include <netinet/in_systm.h>
 548      #endif
 549      #ifdef HAVE_NET_IF_H
 550      # include <net/if.h>
 551      #endif
 552      #ifdef HAVE_NETINET_IP_H
 553      # include <netinet/ip.h>
 554      #endif])
 555
 556 AC_CHECK_HEADERS([netinet/tcp_timer.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_var.h ],,,
 557     [#include <sys/types.h>
 558      #ifdef HAVE_ALIAS_H
 559      # include <alias.h>
 560      #endif
 561      #ifdef HAVE_SYS_SOCKET_H
 562      # include <sys/socket.h>
 563      #endif
 564      #ifdef HAVE_SYS_SOCKETVAR_H
 565      # include <sys/socketvar.h>
 566      #endif
 567      #ifdef HAVE_SYS_TIMEOUT_H
 568      # include <sys/timeout.h>
 569      #endif
 570      #ifdef HAVE_NETINET_IN_H
 571      # include <netinet/in.h>
 572      #endif
 573      #ifdef HAVE_NETINET_IN_SYSTM_H
 574      # include <netinet/in_systm.h>
 575      #endif
 576      #ifdef HAVE_NETINET_IP_H
 577      # include <netinet/ip.h>
 578      #endif
 579      #ifdef HAVE_NETINET_IP_VAR_H
 580      # include <netinet/ip_var.h>
 581      #endif
 582      #ifdef HAVE_NETINET_IP_ICMP_H
 583      # include <netinet/ip_icmp.h>
 584      #endif
 585      #ifdef HAVE_NETINET_UDP_H
 586      # include <netinet/udp.h>
 587      #endif
 588      #ifdef HAVE_NETINET_TCP_H
 589      # include <netinet/tcp.h>
 590      #endif
 591      #ifdef HAVE_NETINET_TCP_TIMER_H
 592      #include <netinet/tcp_timer.h>
 593      #endif])
 594
 595 AC_CHECK_HEADERS([linux/ipx.h linux/irda.h],,,
 596     [#include <sys/types.h>
 597      #ifdef HAVE_ASM_TYPES_H
 598      # include <asm/types.h>
 599      #endif
 600      #ifdef HAVE_SYS_SOCKET_H
 601      # include <sys/socket.h>
 602      #endif
 603      #ifdef HAVE_LINUX_TYPES_H
 604      # include <linux/types.h>
 605      #endif])
 606
 607 AC_CHECK_HEADERS([mach-o/dyld_images.h],,,
 608     [#ifdef HAVE_STDBOOL_H
 609      # include <stdbool.h>
 610      #endif
 611      #ifdef HAVE_STDINT_H
 612      # include <stdint.h>
 613      #endif])
 614
 615 AC_CHECK_HEADERS([resolv.h],,,
 616     [#include <sys/types.h>
 617      #ifdef HAVE_SYS_SOCKET_H
 618      # include <sys/socket.h>
 619      #endif
 620      #ifdef HAVE_NETINET_IN_H
 621      # include <netinet/in.h>
 622      #endif
 623      #ifdef HAVE_ARPA_NAMESER_H
 624      # include <arpa/nameser.h>
 625      #endif])
 626
 627 AC_CHECK_HEADERS([ifaddrs.h],,,[#include <sys/types.h>])
 628
 629 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 630
 631 AC_CHECK_HEADERS([sys/thr.h],,,
 632 [#include <sys/types.h>
 633 #ifdef HAVE_UCONTEXT_H
 634 #include <ucontext.h>
 635 #endif])
 636
 637 AC_CHECK_HEADERS([pthread_np.h],,,
 638 [#ifdef HAVE_PTHREAD_H
 639 #include <pthread.h>
 640 #endif])
 641
 642 AC_CHECK_HEADERS([linux/videodev.h linux/videodev2.h],,,
 643 [#ifdef HAVE_SYS_TIME_H
 644 #include <sys/time.h>
 645 #endif
 646 #include <sys/types.h>
 647 #ifdef HAVE_ASM_TYPES_H
 648 #include <asm/types.h>
 649 #endif])
 650
 651 dnl Check for broken kernel header that doesn't define __user
 652 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 653
 654 dnl **** Check for working dll ****
 655
 656 AC_SUBST(DLLEXT,"")
 657 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 658 AC_SUBST(LDSHARED,"")
 659 AC_SUBST(LDDLLFLAGS,"")
 660 AC_SUBST(LIBEXT,"so")
 661 AC_SUBST(IMPLIBEXT,"def")
 662 AC_SUBST(LDRPATH_INSTALL,"")
 663 AC_SUBST(LDRPATH_LOCAL,"")
 664 STATIC_IMPLIBEXT="def.a"
 665 WINE_PATH_LDD
 666
 667 case $host_os in
 668   cygwin*|mingw32*)
 669     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 670     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 671     if test "$DLLWRAP" = "false"; then
 672       LIBEXT="a"
 673     else
 674       dnl FIXME - check whether dllwrap works correctly...
 675       LIBEXT="dll"
 676     fi
 677     IMPLIBEXT="a"
 678     STATIC_IMPLIBEXT="a"
 679     dnl Disable modules that can't be used on Windows
 680     enable_iphlpapi=${enable_iphlpapi:-no}
 681     enable_kernel32=${enable_kernel32:-no}
 682     enable_msvcrt=${enable_msvcrt:-no}
 683     enable_ntdll=${enable_ntdll:-no}
 684     enable_ws2_32=${enable_ws2_32:-no}
 685     enable_loader=${enable_loader:-no}
 686     enable_server=${enable_server:-no}
 687     dnl Disable dependencies that are not useful on Windows
 688     with_x=${with_x:-no}
 689     with_pthread=${with_pthread:-no}
 690     ;;
 691   darwin*|macosx*)
 692     DLLEXT=".so"
 693     LIBEXT="dylib"
 694     DLLFLAGS="$DLLFLAGS -fPIC"
 695     LDDLLFLAGS="-bundle -multiply_defined suppress"
 696     LIBWINE_LDFLAGS="-multiply_defined suppress"
 697     LDSHARED="\$(CC) -dynamiclib"
 698     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(top_builddir)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 699     dnl declare needed frameworks
 700     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 701     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 702     AC_SUBST(APPLICATIONSERVICESLIB,"-framework ApplicationServices")
 703     case $host_os in
 704       darwin11*)
 705         AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-macosx_version_min,10.6,-segaddr,WINE_DOS,0x00001000,-segaddr,WINE_SHAREDHEAP,0x7f000000"]) ;;
 706       *)
 707         AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00001000,-segaddr,WINE_SHAREDHEAP,0x7f000000"]) ;;
 708     esac
 709     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 710     then
 711         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 712         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 713     fi
 714     if test "$ac_cv_header_Security_Security_h" = "yes"
 715     then
 716         AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 717         dnl Check for the SSLCopyPeerCertificates function
 718         ac_save_LIBS="$LIBS"
 719         LIBS="$LIBS $SECURITYLIB"
 720         AC_CHECK_FUNCS(SSLCopyPeerCertificates)
 721         LIBS="$ac_save_LIBS"
 722         with_gnutls=${with_gnutls:-no}
 723     fi
 724     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 725     then
 726         if test "$ac_cv_header_AudioUnit_AudioComponent_h" = "yes"
 727         then
 728             AC_SUBST(COREAUDIO,"-framework CoreFoundation -framework CoreAudio -framework AudioUnit -framework AudioToolbox -framework CoreMIDI")
 729         else
 730             dnl CoreServices needed by AudioUnit
 731             AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 732         fi
 733         dnl Check for the AUGraphAddNode function
 734         ac_save_LIBS="$LIBS"
 735         LIBS="$LIBS $COREAUDIO"
 736         AC_CHECK_FUNCS(AUGraphAddNode)
 737         LIBS="$ac_save_LIBS"
 738     fi
 739     if test "$ac_cv_header_OpenAL_al_h" = "yes"
 740     then
 741         AC_SUBST(FRAMEWORK_OPENAL,"-framework OpenAL")
 742         AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])
 743         ac_cv_lib_openal=yes
 744     fi
 745     if test "$ac_cv_header_OpenCL_opencl_h" = "yes"
 746     then
 747         AC_SUBST(LIBOPENCL,"-framework OpenCL")
 748         ac_cv_lib_OpenCL_clGetPlatformInfo=yes
 749     fi
 750     if test "$ac_cv_header_IOKit_hid_IOHIDLib_h" = "yes"
 751     then
 752         ac_save_LIBS="$LIBS"
 753         LIBS="$LIBS $IOKITLIB"
 754         AC_CHECK_FUNCS(IOHIDManagerCreate)
 755         LIBS="$ac_save_LIBS"
 756     fi
 757     case $host_cpu in
 758       *powerpc*)
 759         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 760         ;;
 761     esac
 762     if test "$ac_cv_header_QuickTime_ImageCompression_h" = "yes"
 763     then
 764         AC_SUBST(QUICKTIMELIB,"-framework QuickTime -framework ApplicationServices -framework CoreVideo")
 765         enable_wineqtdecoder=${enable_wineqtdecoder:-yes}
 766     else
 767         WINE_NOTICE([QuickTime ${notice_platform}development files not found, video decoding won't be supported.])
 768     fi
 769     dnl Enable quartz driver on Mac OS X
 770     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 771     then
 772         AC_SUBST(CARBONLIB,"-framework Carbon")
 773         enable_winequartz_drv=${enable_winequartz_drv:-yes}
 774     fi
 775     dnl Check for Xcode 3.x broken 16-bit support
 776     if test "x$enable_win16" = "xyes"
 777     then
 778         AC_MSG_CHECKING([whether 16-bit code can be built correctly])
 779         AC_RUN_IFELSE([AC_LANG_PROGRAM([[asm(".text\n"
 780                                             "bad:\tnop;nop\n"
 781                                             "good:\tnop;nop\n\t"
 782                                             ".globl _testfunc\n"
 783                                             "_testfunc:\tcallw good");
 784                                         extern void testfunc();]],
 785                                       [[unsigned short *p = (unsigned short *)testfunc;
 786                                         return p[0] != 0xe866 || p[1] != 0xfffa]])],
 787                                       AC_MSG_RESULT(yes),
 788                                       [AC_MSG_RESULT(no)
 789                                        AC_MSG_ERROR([Xcode 3.x cannot build 16-bit code correctly. Use --disable-win16 if you don't need 16-bit support.])],
 790                                        AC_MSG_RESULT([[cross-compiling, assuming yes]]))
 791     fi
 792     ;;
 793   *)
 794     DLLFLAGS="$DLLFLAGS -fPIC"
 795     DLLEXT=".so"
 796     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 797         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 798                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 799     if test "$ac_cv_c_dll_gnuelf" = "yes"
 800     then
 801       LDSHARED="\$(CC) -shared"
 802       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 803       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 804                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 805                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 806                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 807
 808       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 809
 810       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 811                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 812
 813       echo '{ global: *; };' >conftest.map
 814       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 815                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 816       rm -f conftest.map
 817
 818       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 819                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 820
 821       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 822                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 823                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"],
 824           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 825                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 826                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"])])
 827
 828       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 829                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 830
 831       case $host_cpu in
 832         *i[[3456789]]86* | x86_64)
 833           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 834                           [case $host_os in
 835                            freebsd* | kfreebsd*-gnu) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x60000400" ;;
 836                            *) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400" ;;
 837                            esac
 838                           ])
 839           AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 840           if test "x$PRELINK" = xfalse
 841           then
 842               WINE_WARNING([prelink not found, base address of core dlls won't be set correctly.])
 843           fi
 844           ;;
 845       esac
 846
 847     else
 848       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 849           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 850                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 851       if test "$ac_cv_c_dll_unixware" = "yes"
 852       then
 853         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 854         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 855
 856       else
 857         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 858           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 859         if test "$ac_cv_c_dll_hpux" = "yes"
 860         then
 861           LIBEXT="sl"
 862           DLLEXT=".sl"
 863           LDDLLFLAGS="-shared -fPIC"
 864           LDSHARED="\$(CC) -shared"
 865         fi
 866       fi
 867     fi
 868     ;;
 869 esac
 870
 871 enable_wineqtdecoder=${enable_wineqtdecoder:-no}
 872 enable_winequartz_drv=${enable_winequartz_drv:-no}
 873
 874 if test "$LIBEXT" = "a"; then
 875   AC_MSG_ERROR(
 876 [could not find a way to build shared libraries.
 877 It is currently not possible to build Wine without shared library
 878 (.so) support to allow transparent switch between .so and .dll files.
 879 If you are using Linux, you will need a newer binutils.]
 880 )
 881 fi
 882
 883 dnl Check for cross compiler to build test programs
 884 AC_SUBST([CROSSTEST_DISABLE],[\#])
 885 if test "$cross_compiling" = "no" -a "x$enable_tests" != xno -a "$LIBEXT" != "dll"
 886 then
 887     WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 888     if test "$CROSSCC" != "false"
 889     then
 890         ac_save_CC="$CC"
 891         CC="$CROSSCC"
 892         AC_MSG_CHECKING([whether $CROSSCC works])
 893         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 894                           [AC_MSG_RESULT([yes])
 895                            set x $CROSSCC
 896                            shift
 897                            target=""
 898                            while test $# -ge 1
 899                            do
 900                                case "$1" in
 901                                  *-gcc) target=`expr "$1" : '\(.*\)-gcc'` ;;
 902                                esac
 903                                shift
 904                            done
 905                            if test -n "$target"
 906                            then
 907                                CROSSTEST_DISABLE=""
 908                                AC_SUBST(CROSSTARGET,"$target")
 909                            fi],
 910                           [AC_MSG_RESULT([no])])
 911         CC="$ac_save_CC"
 912     fi
 913 fi
 914
 915 dnl **** Check for pthread ****
 916
 917 if test "$ac_cv_header_pthread_h" = "yes"
 918 then
 919     AC_CHECK_LIB(pthread,pthread_create,[AC_SUBST(LIBPTHREAD,"-lpthread")])
 920 fi
 921 WINE_ERROR_WITH(pthread,[test "x$LIBPTHREAD" = "x"],[pthread ${notice_platform}development files not found.
 922 Wine cannot support threads without libpthread.])
 923
 924 dnl **** Check for X11 ****
 925
 926 AC_PATH_XTRA
 927
 928 if test "$have_x" = "yes"
 929 then
 930     XLIB="-lX11"
 931     ac_save_CPPFLAGS="$CPPFLAGS"
 932     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 933
 934     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 935     WINE_CHECK_SONAME(Xext,XextCreateExtension,[XLIB="-lXext $XLIB"],,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 936
 937     dnl *** All of the following tests require X11/Xlib.h
 938     AC_CHECK_HEADERS([X11/Xlib.h \
 939                       X11/XKBlib.h \
 940                       X11/Xutil.h \
 941                       X11/Xcursor/Xcursor.h \
 942                       X11/extensions/shape.h \
 943                       X11/extensions/XInput.h \
 944                       X11/extensions/XInput2.h \
 945                       X11/extensions/XShm.h \
 946                       X11/extensions/Xcomposite.h \
 947                       X11/extensions/Xinerama.h \
 948                       X11/extensions/Xrandr.h \
 949                       X11/extensions/Xrender.h \
 950                       X11/extensions/xf86vmode.h \
 951                       X11/extensions/xf86vmproto.h],,,
 952 [#ifdef HAVE_X11_XLIB_H
 953 # include <X11/Xlib.h>
 954 #endif
 955 #ifdef HAVE_X11_XUTIL_H
 956 # include <X11/Xutil.h>
 957 #endif])
 958
 959         dnl *** Check for X keyboard extension
 960         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 961         then
 962               AC_CHECK_LIB(X11, XkbQueryExtension,
 963               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 964               $X_LIBS $XLIB $X_EXTRA_LIBS)
 965         fi
 966
 967         dnl *** Check for X cursor
 968         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 969         then
 970             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 971         fi
 972         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 973                          [libxcursor ${notice_platform}development files not found, the Xcursor extension won't be supported.])
 974
 975         dnl *** Check for X input extension
 976         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 977         then
 978             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 979         fi
 980         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 981                          [libxi ${notice_platform}development files not found, the Xinput extension won't be supported.])
 982
 983         dnl *** Check for X input 2 extension
 984         if test "x$ac_cv_lib_soname_Xi" != x
 985         then
 986             WINE_NOTICE_WITH(xinput2,[test "$ac_cv_header_X11_extensions_XInput2_h" != "yes"],
 987                              [XInput2 headers not found, the XInput 2 extension won't be supported.])
 988         fi
 989
 990         dnl *** Check for X Shm extension
 991         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 992         then
 993               AC_CHECK_LIB(Xext, XShmQueryExtension,
 994               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 995               $X_LIBS $XLIB $X_EXTRA_LIBS)
 996         fi
 997         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 998                          [XShm ${notice_platform}development files not found, X Shared Memory won't be supported.])
 999
1000         dnl *** Check for X shape extension
1001         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
1002         then
1003               AC_CHECK_LIB(Xext,XShapeQueryExtension,
1004               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
1005               $X_LIBS $XLIB $X_EXTRA_LIBS)
1006         fi
1007         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
1008                          [XShape ${notice_platform}development files not found, XShape won't be supported.])
1009
1010         dnl *** Check for XFree86 VMODE extension
1011         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes" -o "$ac_cv_header_X11_extensions_xf86vmproto_h" = "yes"
1012         then
1013             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1014         fi
1015         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
1016                          [libXxf86vm ${notice_platform}development files not found, XFree86 Vidmode won't be supported.])
1017
1018         dnl *** Check for Transform functions in Xrender
1019         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
1020         then
1021             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
1022               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
1023                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
1024                  [Define if Xrender has the XRenderSetPictureTransform function])],,
1025                 [$X_LIBS $XLIB $X_EXTRA_LIBS])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1026
1027         fi
1028         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
1029                          [libxrender ${notice_platform}development files not found, XRender won't be supported.])
1030
1031         dnl *** Check for X RandR extension
1032         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
1033         then
1034                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1035 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func; if (func) return 0;]])],
1036                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
1037         fi
1038         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
1039                          [libxrandr ${notice_platform}development files not found, XRandr won't be supported.])
1040
1041         dnl *** Check for Xinerama extension
1042         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
1043         then
1044                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1045 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func; if (func) return 0;]])],
1046                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
1047         fi
1048         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
1049                          [libxinerama ${notice_platform}development files not found, multi-monitor setups won't be supported.])
1050
1051         dnl *** Check for X Composite extension
1052         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
1053         then
1054             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1055         fi
1056         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
1057                          [libxcomposite ${notice_platform}development files not found, Xcomposite won't be supported.])
1058
1059         dnl *** Check for XICCallback struct
1060         AC_CHECK_MEMBERS([XICCallback.callback, XEvent.xcookie],,,
1061 [#ifdef HAVE_X11_XLIB_H
1062 #include <X11/Xlib.h>
1063 #endif])
1064
1065     dnl *** End of X11/Xlib.h check
1066
1067     dnl Check for the presence of OpenGL
1068     opengl_msg=""
1069     if test "x$with_opengl" != "xno"
1070     then
1071         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glu.h,,,
1072 [#ifdef HAVE_GL_GLX_H
1073 # include <GL/glx.h>
1074 #endif])
1075         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
1076         then
1077             dnl Check for some problems due to old Mesa versions
1078             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
1079               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;  return (test == GL_UNSIGNED_SHORT_5_6_5);]])],
1080                 [wine_cv_opengl_header_version_OK="yes"],
1081                 [wine_cv_opengl_header_version_OK="no"]))
1082
1083             if test "$wine_cv_opengl_header_version_OK" = "yes"
1084             then
1085                 dnl Check for the presence of the library
1086                 WINE_CHECK_SONAME(GL,glXCreateContext,
1087                              [OPENGL_LIBS="-lGL"
1088                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1089                              [WINE_CHECK_SONAME(GL,glXCreateContext,
1090                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
1091                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1092                                     [if test -f /usr/X11R6/lib/libGL.a
1093                                     then
1094                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
1095 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
1096                                     else
1097                                         opengl_msg="No OpenGL library found on this system."
1098                                     fi],
1099                                     $X_LIBS $XLIB -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
1100                              $X_LIBS $XLIB -lm $X_EXTRA_LIBS)
1101                  if test "$ac_cv_header_GL_glu_h" = "yes"
1102                  then
1103                     WINE_CHECK_SONAME(GLU,gluLookAt,,,[$OPENGL_LIBS $X_LIBS $X_PRE_LIBS $XLIB -lm $X_EXTRA_LIBS])
1104                  fi
1105                  WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_soname_GLU" = "x"],
1106                                  [libGLU ${notice_platform}development files not found, GLU won't be supported.])
1107              else
1108                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
1109              fi
1110          else
1111              opengl_msg="OpenGL development headers not found."
1112          fi
1113          test -n "$opengl_msg" && enable_opengl32=${enable_opengl32:-no}
1114          test "x$ac_cv_lib_soname_GLU" = "x" && enable_glu32=${enable_glu32:-no}
1115     else
1116          enable_opengl32=${enable_opengl32:-no}
1117          enable_glu32=${enable_glu32:-no}
1118     fi
1119     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
1120 OpenGL and Direct3D won't be supported.])
1121
1122     CPPFLAGS="$ac_save_CPPFLAGS"
1123 else
1124     XLIB=""
1125     X_CFLAGS=""
1126     X_LIBS=""
1127     enable_winex11_drv=${enable_winex11_drv:-no}
1128     enable_opengl32=${enable_opengl32:-no}
1129     enable_glu32=${enable_glu32:-no}
1130 fi
1131 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X ${notice_platform}development files not found. Wine will be built
1132 without X support, which probably isn't what you want. You will need
1133 to install ${notice_platform}development packages of Xlib/Xfree86 at the very least.])
1134
1135 dnl **** Check for OpenCL ****
1136 if test "$ac_cv_header_CL_cl_h" = "yes"
1137 then
1138     AC_CHECK_LIB(OpenCL,clGetPlatformInfo,[AC_SUBST(LIBOPENCL,["-lOpenCL"])])
1139 fi
1140 WINE_NOTICE_WITH(opencl,[test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes],
1141                  [OpenCL ${notice_platform}development files not found, OpenCL won't be supported.])
1142 test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes && enable_opencl=${enable_opencl:-no}
1143
1144 dnl **** Check for libxml2 ****
1145
1146 AC_SUBST(XML2LIBS,"")
1147 AC_SUBST(XML2INCL,"")
1148 AC_SUBST(XSLTINCL,"")
1149 if test "x$with_xml" != "xno"
1150 then
1151     ac_save_CPPFLAGS="$CPPFLAGS"
1152     if test "$PKG_CONFIG" != "false"
1153     then
1154         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
1155         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
1156     else
1157         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
1158         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
1159     fi
1160     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
1161     AC_CHECK_HEADERS([libxml/parser.h libxml/xmlsave.h libxml/SAX2.h])
1162     if test "$ac_cv_header_libxml_parser_h" = "yes" -a "$ac_cv_header_libxml_xmlsave_h" = "yes" -a "$ac_cv_header_libxml_SAX2_h" = "yes"
1163     then
1164         AC_CHECK_LIB(xml2, xmlParseMemory,
1165             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
1166              XML2LIBS="$ac_xml_libs"
1167              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
1168         AC_CHECK_LIB(xml2, xmlReadMemory,
1169             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
1170         AC_CHECK_LIB(xml2, xmlNewDocPI,
1171             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
1172         AC_CHECK_LIB(xml2, xmlSchemaSetParserStructuredErrors,
1173             [AC_DEFINE(HAVE_XMLSCHEMASSETPARSERSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetParserStructuredErrors function])],,$ac_xml_libs)
1174         AC_CHECK_LIB(xml2, xmlSchemaSetValidStructuredErrors,
1175             [AC_DEFINE(HAVE_XMLSCHEMASSETVALIDSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetValidStructuredErrors function])],,$ac_xml_libs)
1176         AC_CHECK_LIB(xml2, xmlFirstElementChild,
1177             [AC_DEFINE(HAVE_XMLFIRSTELEMENTCHILD,1,[Define if libxml2 has the xmlFirstElementChild function])],,$ac_xml_libs)
1178         AC_CHECK_TYPE([xmlDocProperties],
1179             [AC_DEFINE(HAVE_XMLDOC_PROPERTIES,1,[Define if libxml2 has the xmlDocProperties enum])],,[[#include <libxml/tree.h>]])
1180     fi
1181     CPPFLAGS="$ac_save_CPPFLAGS"
1182 fi
1183 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
1184                  [libxml2 ${notice_platform}development files not found (or too old), XML won't be supported.])
1185
1186 if test "x$with_xslt" != "xno"
1187 then
1188     if test "$PKG_CONFIG" != "false"
1189     then
1190         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
1191         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
1192     else
1193         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
1194         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
1195     fi
1196     ac_save_CPPFLAGS="$CPPFLAGS"
1197     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
1198     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
1199     [#ifdef HAVE_LIBXSLT_PATTERN_H
1200 # include <libxslt/pattern.h>
1201 #endif])
1202     CPPFLAGS="$ac_save_CPPFLAGS"
1203     if test "$ac_cv_header_libxslt_transform_h" = "yes"
1204     then
1205         WINE_CHECK_SONAME(xslt,xsltCompilePattern,
1206                          [XSLTINCL="$ac_xslt_cflags"],,[$ac_xslt_libs])
1207     fi
1208 fi
1209 WINE_WARNING_WITH(xslt,[test "x$ac_cv_lib_soname_xslt" = "x"],
1210                  [libxslt ${notice_platform}development files not found, xslt won't be supported.])
1211
1212 dnl **** Check for libhal ****
1213 AC_SUBST(HALINCL,"")
1214 if test "x$with_hal" != "xno"
1215 then
1216     ac_save_CPPFLAGS="$CPPFLAGS"
1217     if test "$PKG_CONFIG" != "false"
1218     then
1219         ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
1220         ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
1221         CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
1222     fi
1223     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
1224     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
1225     then
1226         AC_CHECK_LIB(dbus-1, dbus_connection_close,
1227           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
1228             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
1229     fi
1230     CPPFLAGS="$ac_save_CPPFLAGS"
1231 fi
1232 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x" -a "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1233                  [libhal/libdbus ${notice_platform}development files not found, no dynamic device support.])
1234
1235 dnl **** Check for libgnutls ****
1236 if test "x$with_gnutls" != "xno"
1237 then
1238     ac_save_CPPFLAGS="$CPPFLAGS"
1239     if test "$PKG_CONFIG" != "false"
1240     then
1241         ac_gnutls_libs="`$PKG_CONFIG --libs gnutls 2>/dev/null`"
1242         ac_gnutls_cflags="`$PKG_CONFIG --cflags gnutls 2>/dev/null`"
1243         CPPFLAGS="$CPPFLAGS $ac_gnutls_cflags"
1244     fi
1245     AC_CHECK_HEADER(gnutls/gnutls.h,
1246         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[static typeof(gnutls_mac_get_key_size) *func; if (func) return 0;]])],
1247             [WINE_CHECK_SONAME(gnutls,gnutls_global_init,
1248                 [AC_SUBST(GNUTLSINCL,"$ac_gnutls_cflags")],,[$ac_gnutls_libs])])])
1249     CPPFLAGS="$ac_save_CPPFLAGS"
1250 fi
1251 WINE_NOTICE_WITH(gnutls,[test "x$ac_cv_lib_soname_gnutls" = "x"],
1252                  [libgnutls ${notice_platform}development files not found, no schannel support.])
1253
1254 dnl **** Check which curses lib to use ***
1255 CURSESLIBS=""
1256 if test "$ac_cv_header_ncurses_h" = "yes"
1257 then
1258     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
1259 elif test "$ac_cv_header_curses_h" = "yes"
1260 then
1261     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
1262 fi
1263 ac_save_LIBS="$LIBS"
1264 LIBS="$LIBS $CURSESLIBS"
1265 AC_CHECK_FUNCS(mousemask)
1266 LIBS="$ac_save_LIBS"
1267 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
1268                  [lib(n)curses ${notice_platform}development files not found, curses won't be supported.])
1269
1270 dnl **** Check for SANE ****
1271 if test "x$with_sane" != "xno"
1272 then
1273     ac_save_CPPFLAGS="$CPPFLAGS"
1274     AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
1275     if test "$sane_devel" != "no"
1276     then
1277         ac_sane_incl="`$sane_devel --cflags`"
1278         ac_sane_libs="`$sane_devel --ldflags`"
1279         CPPFLAGS="$CPPFLAGS $ac_sane_incl"
1280     fi
1281     AC_CHECK_HEADER(sane/sane.h,
1282         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")],,[$ac_sane_libs])])
1283     CPPFLAGS="$ac_save_CPPFLAGS"
1284 fi
1285 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
1286                  [libsane ${notice_platform}development files not found, scanners won't be supported.])
1287
1288 dnl **** Check for libv4l1 ****
1289 if test "x$with_v4l" != "xno"
1290 then
1291     WINE_CHECK_SONAME(v4l1,v4l1_open,,,)
1292 fi
1293 WINE_NOTICE_WITH(v4l,[test "x$ac_cv_lib_soname_v4l1" = "x"],
1294                  [libv4l ${notice_platform}development files not found.])
1295
1296 dnl **** Check for libgphoto2 ****
1297 if test "x$with_gphoto" != "xno"
1298 then
1299     ac_save_CPPFLAGS="$CPPFLAGS"
1300     AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
1301     AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
1302     if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
1303     then
1304         ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
1305         ac_gphoto2_libs=""
1306         for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
1307         do
1308             case "$i" in
1309             -L/usr/lib|-L/usr/lib64) ;;
1310             -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
1311             esac
1312         done
1313         CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
1314     fi
1315     ac_gphoto2_libs=${ac_gphoto2_libs:-"-lgphoto2"}
1316     AC_CHECK_HEADER(gphoto2-camera.h,
1317                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
1318                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
1319                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
1320                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
1321                                   [$ac_gphoto2_libs])])
1322     CPPFLAGS="$ac_save_CPPFLAGS"
1323 fi
1324 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
1325                  [libgphoto2 ${notice_platform}development files not found, digital cameras won't be supported.])
1326
1327
1328 dnl **** Check for resolver library ***
1329 if test "$ac_cv_header_resolv_h" = "yes"
1330 then
1331     ac_save_LIBS="$LIBS"
1332     for lib in '' -lresolv
1333     do
1334       LIBS="$lib $ac_save_LIBS"
1335       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_NETINET_IN_H
1336 #include <netinet/in.h>
1337 #endif
1338 #include <resolv.h>]],[[res_query("foo",ns_c_in,0,0,0);]])],
1339         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
1340          AC_SUBST(RESOLVLIBS,"$lib")])
1341       if test "${RESOLVLIBS+set}" = set; then
1342         break
1343       fi
1344     done
1345     LIBS="$ac_save_LIBS"
1346 fi
1347
1348 dnl **** Check for LittleCMS ***
1349 AC_SUBST(LCMSLIBS,"")
1350 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
1351 then
1352     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
1353         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
1354          LCMSLIBS="-llcms"])
1355 fi
1356 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
1357                  [liblcms ${notice_platform}development files not found, Color Management won't be supported.])
1358
1359 dnl **** Check for FreeType 2 ****
1360 if test "x$with_freetype" != "xno"
1361 then
1362     AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],no)
1363     if test "$ft_devel" != "no"
1364     then
1365         ac_freetype_incl=`$ft_devel --cflags`
1366         ac_freetype_libs=`$ft_devel --libs`
1367     fi
1368     ac_freetype_libs=${ac_freetype_libs:-"-lfreetype"}
1369     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
1370     if test "$ft_lib" = "yes"
1371     then
1372         ac_save_CPPFLAGS="$CPPFLAGS"
1373         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
1374         AC_CHECK_HEADERS(ft2build.h \
1375                          freetype/freetype.h \
1376                          freetype/ftglyph.h \
1377                          freetype/fttypes.h \
1378                          freetype/tttables.h \
1379                          freetype/ftsnames.h \
1380                          freetype/ttnameid.h \
1381                          freetype/ftoutln.h \
1382                          freetype/ftwinfnt.h \
1383                          freetype/ftmodapi.h \
1384                          freetype/ftlcdfil.h,,,
1385                          [#ifdef HAVE_FT2BUILD_H
1386                           # include <ft2build.h>
1387                           #endif])
1388         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1389                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1390           [Define if you have the <freetype/fttrigon.h> header file.])
1391                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1392         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1393         dnl Check that we have at least freetype/freetype.h
1394         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1395         then
1396             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1397             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1398             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1399         fi
1400     fi
1401 fi
1402 WINE_ERROR_WITH(freetype,[test "x$FREETYPELIBS" = "x"],[FreeType ${notice_platform}development files not found. Fonts will not be built.])
1403 test "x$FREETYPELIBS" = "x" && enable_fonts=${enable_fonts:-no}
1404
1405 dnl **** Check for parport (currently Linux only) ****
1406 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1407  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_SYS_IOCTL_H
1408 # include <sys/ioctl.h>
1409 #endif
1410 #include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1411     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1412 if test "$ac_cv_c_ppdev" = "yes"
1413 then
1414     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1415 fi
1416
1417 dnl **** Check for pthread functions ****
1418 WINE_CHECK_LIB_FUNCS(\
1419         pthread_attr_get_np \
1420         pthread_getattr_np \
1421         pthread_get_stackaddr_np \
1422         pthread_get_stacksize_np,
1423         [$LIBPTHREAD])
1424
1425 dnl **** Check for zlib ****
1426 if test "$ac_cv_header_zlib_h" = "yes"
1427 then
1428     AC_CHECK_LIB(z,inflate,[AC_DEFINE(HAVE_ZLIB,1,[Define to 1 if you have the `z' library (-lz).])
1429                             AC_SUBST(ZLIB,"-lz")])
1430 fi
1431 WINE_NOTICE_WITH(zlib,[test "x$ZLIB" = "x"],[libz ${notice_platform}development files not found, data compression won't be supported.])
1432
1433 dnl **** Check for gettextpo ****
1434 if test "x$enable_tools" != xno
1435 then
1436     if test "$ac_cv_header_gettext_po_h" = "yes"
1437     then
1438         AC_CHECK_LIB(gettextpo,po_message_msgctxt,
1439                      [AC_DEFINE(HAVE_LIBGETTEXTPO,1,[Define to 1 if you have the `gettextpo' library (-lgettextpo).])
1440                       AC_SUBST(LIBGETTEXTPO,"-lgettextpo")])
1441     fi
1442     test "x$with_gettextpo" != xyes || WINE_NOTICE_WITH(gettextpo,[test "x$LIBGETTEXTPO" = "x"],
1443           [GetText ${notice_platform}development files not found (or too old), po files can't be rebuilt.])
1444 fi
1445
1446 dnl **** Check for gstreamer ****
1447 if test "x$with_gstreamer" != "xno"
1448 then
1449     ac_save_CPPFLAGS="$CPPFLAGS"
1450     if test "$PKG_CONFIG" != "false"; then
1451         ac_gst_incl=""
1452         for i in `$PKG_CONFIG --cflags gstreamer-app-0.10 2>/dev/null`
1453         do
1454             case "$i" in
1455                 -I*) ac_gst_incl="$ac_gst_incl $i";;
1456             esac
1457         done
1458         ac_gst_libs="`$PKG_CONFIG --libs gstreamer-app-0.10 2>/dev/null`"
1459         CPPFLAGS="$CPPFLAGS $ac_gst_incl"
1460         AC_CHECK_HEADER([gst/gstpad.h],
1461           [AC_CHECK_HEADER([gst/app/gstappsink.h],
1462              [AC_MSG_CHECKING([whether gint64 defined by gst/app/gstappsink.h is indeed 64-bit])
1463               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gst/app/gstappsink.h>]],
1464                                                  [[static int a[sizeof(gint64) > 4 ? 1 : -1]; if (a[0]) return 0;]])],
1465                 [AC_MSG_RESULT([yes])
1466                  AC_CHECK_LIB(gstreamer-0.10,gst_pad_get_caps_reffed,
1467                    [AC_CHECK_LIB(gstapp-0.10,gst_app_buffer_new,
1468                       [AC_SUBST(GSTREAMER_LIBS,"$ac_gst_libs")
1469                        AC_SUBST(GSTREAMER_INCL,"$ac_gst_incl")],,[$ac_gst_libs])])],
1470                 [AC_MSG_RESULT([no])])])])
1471     fi
1472     CPPFLAGS="$ac_save_CPPFLAGS"
1473 fi
1474 WINE_NOTICE_WITH(gstreamer,[test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" != xyes -a "x$ac_cv_header_QuickTime_ImageCompression_h" != xyes],
1475                  [gstreamer-0.10 base plugins ${notice_platform}development files not found, gstreamer support disabled])
1476 test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" = xyes || enable_winegstreamer=${enable_winegstreamer:-no}
1477
1478 dnl **** Check for ALSA 1.x ****
1479 AC_SUBST(ALSALIBS,"")
1480 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1481 then
1482     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access_mask,
1483         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1484 #include <alsa/asoundlib.h>
1485 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1486 #include <sys/asoundlib.h>
1487 #endif]], [[snd_pcm_hw_params_get_access_mask(NULL, NULL)]])],
1488                         [ALSALIBS="-lasound"])])
1489 fi
1490
1491 dnl **** Check for OSSv4 ****
1492 if test "x$with_oss" != xno
1493 then
1494     ac_save_CPPFLAGS="$CPPFLAGS"
1495     if test -f /etc/oss.conf
1496     then
1497         . /etc/oss.conf
1498     fi
1499     ac_oss_incl="-I${OSSLIBDIR:-/usr/lib/oss}/include"
1500     CPPFLAGS="$CPPFLAGS $ac_oss_incl"
1501     AC_CHECK_HEADER([sys/soundcard.h],
1502         [AC_CHECK_MEMBERS([oss_sysinfo.numaudioengines],
1503                           [AC_SUBST(OSS4INCL,"$ac_oss_incl")],,
1504                           [#include <sys/soundcard.h>])])
1505     CPPFLAGS="$ac_save_CPPFLAGS"
1506     if test "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes
1507     then
1508         WINE_NOTICE([OSS sound system found but too old (OSSv4 needed), OSS won't be supported.])
1509     fi
1510 fi
1511
1512 dnl **** Check for capi4linux ****
1513
1514 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1515 then
1516     WINE_CHECK_SONAME(capi20,capi20_register)
1517 fi
1518 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1519                  [libcapi20 ${notice_platform}development files not found, ISDN won't be supported.])
1520
1521 dnl **** Check for cups ****
1522 AC_SUBST(CUPSINCL,"")
1523 if test "x$with_cups" != "xno"
1524 then
1525     ac_save_CPPFLAGS="$CPPFLAGS"
1526     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1527     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1528     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1529     AC_CHECK_HEADERS(cups/cups.h,
1530             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1531                        [CUPSINCL="$ac_cups_cflags"],,
1532                        [$ac_cups_libs])])
1533     CPPFLAGS="$ac_save_CPPFLAGS"
1534 fi
1535 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1536                  [libcups ${notice_platform}development files not found, CUPS won't be supported.])
1537
1538 dnl **** Check for fontconfig ****
1539 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1540 then
1541     WINE_CHECK_SONAME(fontconfig,FcInit)
1542 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1543 then
1544     dnl fontconfig is in the X directory on Mac OS X
1545     ac_save_CPPFLAGS="$CPPFLAGS"
1546     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1547     $as_unset ac_cv_header_fontconfig_fontconfig_h
1548     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1549     CPPFLAGS="$ac_save_CPPFLAGS"
1550     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1551     then
1552         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1553         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1554     fi
1555 fi
1556 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1557                  [fontconfig ${notice_platform}development files not found, fontconfig won't be supported.])
1558
1559 dnl **** Check for SSL ****
1560 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1561 then
1562     WINE_CHECK_SONAME(ssl,SSL_library_init)
1563     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1564 fi
1565 WINE_WARNING_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1566                  [OpenSSL ${notice_platform}development files not found, SSL won't be supported.])
1567
1568 dnl **** Check for gsm codec ****
1569 if test "$ac_cv_header_gsm_h" = "yes" -o "$ac_cv_header_gsm_gsm_h" = "yes"
1570 then
1571     WINE_CHECK_SONAME(gsm,gsm_create)
1572 fi
1573 WINE_NOTICE_WITH(gsm,[test "x$ac_cv_lib_soname_gsm" = "x"],
1574                  [libgsm ${notice_platform}development files not found, gsm 06.10 codec won't be supported.])
1575
1576 dnl **** Check for libjpeg ****
1577 if test "$ac_cv_header_jpeglib_h" = "yes"
1578 then
1579     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1580 fi
1581 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1582                  [libjpeg ${notice_platform}development files not found, JPEG won't be supported.])
1583
1584 dnl **** Check for libpng ****
1585 if test "$ac_cv_header_png_h" = "yes"
1586 then
1587     WINE_CHECK_SONAME(png,png_create_read_struct,,,-lm -lz,[[libpng[[0-9]]*]])
1588     AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1589         [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1,[Define to 1 if libpng has the png_set_expand_gray_1_2_4_to_8 function.])]
1590         ,,-lm -lz)
1591 elif test -n "$X_CFLAGS" -a "x$with_png" != "xno"
1592 then
1593     dnl libpng is in the X directory on Mac OS X
1594     ac_save_CPPFLAGS="$CPPFLAGS"
1595     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1596     $as_unset ac_cv_header_png_h
1597     AC_CHECK_HEADERS([png.h])
1598     CPPFLAGS="$ac_save_CPPFLAGS"
1599     if test "$ac_cv_header_png_h" = "yes"
1600     then
1601         AC_SUBST(PNGINCL,"$X_CFLAGS")
1602         WINE_CHECK_SONAME(png,png_create_read_struct,,,[$X_LIBS -lm -lz],[[libpng[[0-9]]*]])
1603         AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1604                 [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1)],,[$X_LIBS -lm -lz])
1605     fi
1606 fi
1607 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1608                  [libpng ${notice_platform}development files not found, PNG won't be supported.])
1609
1610 dnl **** Check for libtiff ****
1611 if test "$ac_cv_header_tiffio_h" = "yes"
1612 then
1613     WINE_CHECK_SONAME(tiff,TIFFClientOpen)
1614 fi
1615 WINE_NOTICE_WITH(tiff,[test "x$ac_cv_lib_soname_tiff" = "x"],
1616                  [libtiff ${notice_platform}development files not found, TIFF won't be supported.])
1617
1618 dnl **** Check for mpg123 ****
1619 if test "$ac_cv_header_mpg123_h" = "yes"
1620 then
1621     AC_CHECK_LIB(mpg123,mpg123_feed,[AC_SUBST(LIBMPG123,"-lmpg123")])
1622 fi
1623 WINE_NOTICE_WITH(mpg123,[test "x$ac_cv_lib_mpg123_mpg123_feed" != xyes -a x"$ac_cv_header_CoreAudio_CoreAudio_h" != xyes],
1624                  [libmpg123 ${notice_platform}development files not found (or too old), mp3 codec won't be supported.])
1625 test "x$ac_cv_lib_mpg123_mpg123_feed" = xyes -o "x$ac_cv_header_AudioToolbox_AudioConverter_h" = xyes || enable_winemp3_acm=${enable_winemp3_acm:-no}
1626
1627 dnl **** Check for OpenAL 1.1 ****
1628 if test "$ac_cv_header_AL_al_h" = "yes"
1629 then
1630     WINE_CHECK_SONAME(openal,alGetSource3i,[AC_SUBST(LIBOPENAL,"-lopenal")
1631                       ac_cv_lib_openal=yes
1632                       AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])],,)
1633 fi
1634 WINE_NOTICE_WITH(openal,[test "x$ac_cv_lib_openal" != xyes],
1635                  [libopenal ${notice_platform}development files not found (or too old), OpenAL won't be supported.])
1636 test "x$ac_cv_lib_openal" = xyes || enable_openal32=${enable_openal32:-no}
1637
1638 dnl **** Check for libkstat ****
1639 if test "$ac_cv_header_kstat_h" = "yes"
1640 then
1641     AC_CHECK_LIB(kstat,kstat_open,
1642                  [AC_DEFINE(HAVE_LIBKSTAT, 1, [Define to 1 if you have the `kstat' library (-lkstat).])
1643                   AC_SUBST(LIBKSTAT,"-lkstat")])
1644 fi
1645
1646 dnl **** Check for libodbc ****
1647 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1648
1649 dnl **** Disable unsupported winmm drivers ****
1650 test -n "$ALSALIBS" || enable_winealsa_drv=${enable_winealsa_drv:-no}
1651 test -n "$COREAUDIO" || enable_winecoreaudio_drv=${enable_winecoreaudio_drv:-no}
1652 test "x$ac_cv_member_oss_sysinfo_numaudioengines" = xyes || enable_wineoss_drv=${enable_wineoss_drv:-no}
1653 test "$ac_cv_header_linux_joystick_h" = "yes" || enable_winejoystick_drv=${enable_winejoystick_drv:-no}
1654
1655 dnl **** Check for any sound system ****
1656 if test "x$ALSALIBS$COREAUDIO" = "x" -a \
1657         "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes -a \
1658         "x$with_alsa$with_coreaudio$with_oss" != xnonono
1659 then
1660     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1661 fi
1662
1663 dnl **** Check for gcc specific options ****
1664
1665 AC_SUBST(EXTRACFLAGS,"")
1666 if test "x${GCC}" = "xyes"
1667 then
1668   EXTRACFLAGS="-Wall -pipe"
1669
1670   dnl Check for strength-reduce bug
1671   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1672                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1673 [[static int Array[[3]];
1674   unsigned int B = 3;
1675   int i;
1676   for(i=0; i<B; i++) Array[[i]] = i - 3;
1677   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1678   L[[i]] = 4;
1679   return (Array[[1]] != -2 || L[[2]] != 3)]])],
1680     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1681   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1682   then
1683     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1684   fi
1685
1686   dnl Check for some compiler flags
1687   WINE_TRY_CFLAGS([-fno-builtin],[AC_SUBST(BUILTINFLAG,"-fno-builtin")])
1688   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1689   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1690   WINE_TRY_CFLAGS([-Wempty-body])
1691   WINE_TRY_CFLAGS([-Wstrict-prototypes])
1692   WINE_TRY_CFLAGS([-Wtype-limits])
1693   WINE_TRY_CFLAGS([-Wunused-but-set-parameter])
1694   WINE_TRY_CFLAGS([-Wwrite-strings])
1695
1696   dnl gcc-4.6+ omits frame pointers by default, breaking some copy protections
1697   case $host_cpu in
1698     *i[[3456789]]86*) WINE_TRY_CFLAGS([-fno-omit-frame-pointer]) ;;
1699   esac
1700
1701   dnl Check for noisy string.h
1702   saved_CFLAGS="$CFLAGS"
1703   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1704   AC_CACHE_CHECK([for broken string.h that generates warnings with -Wpointer-arith], ac_cv_c_string_h_warnings,
1705       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1706   CFLAGS="$saved_CFLAGS"
1707   if test "$ac_cv_c_string_h_warnings" = "no"
1708   then
1709     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1710   fi
1711
1712   dnl Check for noisy string.h on logical ops
1713   saved_CFLAGS="$CFLAGS"
1714   CFLAGS="$CFLAGS -Wlogical-op -Werror"
1715   AC_CACHE_CHECK([for broken string.h that generates warnings with -Wlogical-op], ac_cv_c_logicalop_noisy,
1716       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[char*f(const char *h,char n) {return strchr(h,n);}]])],[ac_cv_c_logicalop_noisy=no],[ac_cv_c_logicalop_noisy=yes]))
1717   CFLAGS="$saved_CFLAGS"
1718   if test "$ac_cv_c_logicalop_noisy" = "no"
1719   then
1720     EXTRACFLAGS="$EXTRACFLAGS -Wlogical-op"
1721   fi
1722
1723   dnl Enable -Werror for maintainer mode
1724   if test "x$enable_maintainer_mode" = "xyes"
1725   then
1726       WINE_TRY_CFLAGS([-Werror])
1727   fi
1728
1729   dnl Check for ms_hook_prologue support
1730   saved_CFLAGS="$CFLAGS"
1731   CFLAGS="$CFLAGS -Werror"
1732   AC_CACHE_CHECK([for ms_hook_prologue attribute], ac_cv_have_ms_hook_prologue,
1733                  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[int __attribute__((__ms_hook_prologue__)) test(void) { return 0; }]])],
1734                                    [ac_cv_have_ms_hook_prologue="yes"],[ac_cv_have_ms_hook_prologue="no"]))
1735   CFLAGS="$saved_CFLAGS"
1736   if test "$ac_cv_have_ms_hook_prologue" = "yes"
1737   then
1738       AC_DEFINE(DECLSPEC_HOTPATCH, [__attribute__((__ms_hook_prologue__))],
1739                 [Define to a function attribute for Microsoft hotpatch assembly prefix.])
1740   else
1741       AC_DEFINE(DECLSPEC_HOTPATCH, [/* */])
1742   fi
1743 fi
1744
1745 dnl **** Disable Fortify, it has too many false positives
1746
1747 AC_CACHE_CHECK([for the need to disable Fortify], ac_cv_c_fortify_enabled,
1748     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]],
1749 [[#if defined(__USE_FORTIFY_LEVEL) && __USE_FORTIFY_LEVEL > 0
1750 #error Fortify enabled
1751 #endif]])],
1752         [ac_cv_c_fortify_enabled=no],[ac_cv_c_fortify_enabled=yes]))
1753 if test "$ac_cv_c_fortify_enabled" = yes
1754 then
1755     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=0"
1756 fi
1757
1758 dnl **** Check for underscore on external symbols ****
1759
1760 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1761     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1762                       [extern int ac_test;],
1763                       [if (ac_test) return 1],
1764                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1765
1766 case $host_cpu in
1767   *i[[3456789]]86*)
1768     AC_CACHE_CHECK([whether external symbols need stdcall decoration], ac_cv_c_stdcall_suffix,
1769         WINE_TRY_ASM_LINK(["jmp _ac_test@4"],
1770 [#ifndef _MSC_VER
1771 #define __stdcall __attribute__((__stdcall__))
1772 #endif
1773 int __stdcall ac_test(int i) { return i; }],
1774                           [if (ac_test(1)) return 1],
1775                           ac_cv_c_stdcall_suffix="yes",ac_cv_c_stdcall_suffix="no")) ;;
1776   *) ac_cv_c_stdcall_suffix="no" ;;
1777 esac
1778
1779 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1780 if test "$ac_cv_c_extern_prefix" = "yes"
1781 then
1782     AC_DEFINE([__ASM_NAME(name)], ["_" name])
1783     asm_name_prefix="_"
1784 else
1785     AC_DEFINE([__ASM_NAME(name)], [name])
1786     asm_name_prefix=""
1787 fi
1788
1789 AH_TEMPLATE(__ASM_STDCALL,[Define to a macro to generate an stdcall suffix])
1790 if test "$ac_cv_c_stdcall_suffix" = "yes"
1791 then
1792     AC_DEFINE([__ASM_STDCALL(args)],["@" #args])
1793 else
1794     AC_DEFINE([__ASM_STDCALL(args)],[""])
1795 fi
1796
1797 dnl **** Check how to define a function in assembly code ****
1798
1799 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1800   WINE_TRY_ASM_LINK(
1801       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1802       ac_cv_asm_func_def=".def",
1803     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1804       ac_cv_asm_func_def=".type @function",
1805     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1806       ac_cv_asm_func_def=".type 2",
1807       ac_cv_asm_func_def="unknown")])]))
1808
1809 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1810 case "$ac_cv_asm_func_def" in
1811   ".def")
1812      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"])
1813      asm_func_header=".def $asm_name_prefix\" #name suffix \"; .scl 2; .type 32; .endef" ;;
1814   ".type @function")
1815      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"])
1816      asm_func_header=".type $asm_name_prefix\" #name suffix \",@function" ;;
1817   ".type 2")
1818      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"])
1819      asm_func_header=".type $asm_name_prefix\" #name suffix \",2" ;;
1820   *)
1821      AC_DEFINE([__ASM_FUNC(name)], [""])
1822      asm_func_header="" ;;
1823 esac
1824
1825 AC_CACHE_CHECK([whether asm() works outside of functions], ac_cv_c_asm_outside_funcs,
1826     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\n\t.long 0");]],)],
1827                       ac_cv_c_asm_outside_funcs="yes",ac_cv_c_asm_outside_funcs="no"))
1828
1829 AC_CACHE_CHECK([whether .previous is supported in assembly code], ac_cv_c_dot_previous,
1830     WINE_TRY_ASM_LINK([".text\nac_test:\t.long 0\n\t.previous"],,,
1831                       ac_cv_c_dot_previous="yes",ac_cv_c_dot_previous="no"))
1832
1833 AC_CACHE_CHECK([whether CFI directives are supported in assembly code], ac_cv_c_cfi_support,
1834     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\nac_test:\t.cfi_startproc\n\t.long 0\n\t.cfi_endproc");]])],
1835                       ac_cv_c_cfi_support="yes",ac_cv_c_cfi_support="no"))
1836
1837 asm_func_header=".globl $asm_name_prefix\" #name suffix \"\\n\\t$asm_func_header\\n$asm_name_prefix\" #name suffix \":\\n\\t"
1838 asm_func_trailer=""
1839 if test "$ac_cv_c_dot_previous" = "yes"
1840 then
1841    asm_func_trailer="\\n\\t.previous"
1842 fi
1843 if test "$ac_cv_c_cfi_support" = "yes"
1844 then
1845    asm_func_header="$asm_func_header.cfi_startproc\\n\\t"
1846    asm_func_trailer="\\n\\t.cfi_endproc$asm_func_trailer"
1847    AC_DEFINE([__ASM_CFI(str)],[str],[Define to a macro to output a .cfi assembly pseudo-op])
1848    AC_SUBST([UNWINDFLAGS],[-fasynchronous-unwind-tables])
1849 else
1850    AC_DEFINE([__ASM_CFI(str)],[""])
1851 fi
1852
1853 asm_func_code="$asm_func_header\" code \"$asm_func_trailer"
1854
1855 AH_TEMPLATE(__ASM_DEFINE_FUNC,[Define to a macro to define an assembly function])
1856 if test "$ac_cv_c_asm_outside_funcs" = "yes"
1857 then
1858     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[asm(".text\n\t.align 4\n\t$asm_func_code");])
1859 else
1860     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[void __asm_dummy_##name(void) { asm(".text\n\t.align 4\n\t$asm_func_code"); }])
1861 fi
1862 AC_DEFINE([__ASM_GLOBAL_FUNC(name,code)],[__ASM_DEFINE_FUNC(name,"",code)],
1863           [Define to a macro to generate an assembly function with C calling convention])
1864 AC_DEFINE([__ASM_STDCALL_FUNC(name,args,code)],[__ASM_DEFINE_FUNC(name,__ASM_STDCALL(args),code)],
1865           [Define to a macro to generate an assembly function with stdcall calling convention])
1866
1867 dnl **** Platform-specific checks ****
1868
1869 AC_SUBST(LDPATH,"")
1870 case $build_os in
1871   cygwin*|mingw32*)
1872     AC_SUBST(TOOLSEXT,".exe")
1873     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1874     ;;
1875   darwin*|macosx*)
1876     ;;
1877   *)
1878     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1879     ;;
1880 esac
1881
1882 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1883 case $host_os in
1884   mingw32*)
1885     AC_SUBST(CRTLIBS,"-lmsvcrt")
1886     AC_SUBST(SOCKETLIBS,"-L\$(top_builddir)/dlls/ws2_32 -lws2_32")
1887     ;;
1888 esac
1889
1890 AC_SUBST(MAIN_BINARY,"wine")
1891 test "x$enable_win64" != "xyes" || MAIN_BINARY="wine64"
1892
1893 case $host_os in
1894   linux*)
1895     case $host_cpu in
1896       *i[[3456789]]86*) AC_SUBST(EXTRA_BINARIES,"wine-preloader") ;;
1897       x86_64*) AC_SUBST(EXTRA_BINARIES,"wine64-preloader") ;;
1898     esac
1899     ;;
1900 esac
1901
1902 dnl **** Check for functions ****
1903
1904 ac_save_CFLAGS="$CFLAGS"
1905 CFLAGS="$CFLAGS $BUILTINFLAG"
1906 AC_CHECK_FUNCS(\
1907         _finite \
1908         _isnan \
1909         _pclose \
1910         _popen \
1911         _snprintf \
1912         _spawnvp \
1913         _strdup \
1914         _stricmp \
1915         _strnicmp \
1916         _strtoi64 \
1917         _strtoui64 \
1918         _vsnprintf \
1919         asctime_r \
1920         chsize \
1921         dlopen \
1922         epoll_create \
1923         ffs \
1924         finite \
1925         fnmatch \
1926         fork \
1927         fpclass \
1928         fstatfs \
1929         fstatvfs \
1930         ftruncate \
1931         futimes \
1932         futimesat \
1933         getattrlist \
1934         getdirentries \
1935         getopt_long \
1936         getpagesize \
1937         getpwuid \
1938         gettimeofday \
1939         getuid \
1940         kqueue \
1941         lstat \
1942         memmove \
1943         mmap \
1944         pclose \
1945         pipe2 \
1946         poll \
1947         popen \
1948         port_create \
1949         prctl \
1950         pread \
1951         pwrite \
1952         readdir \
1953         readlink \
1954         sched_yield \
1955         select \
1956         setproctitle \
1957         setrlimit \
1958         settimeofday \
1959         sigaltstack \
1960         sigprocmask \
1961         snprintf \
1962         spawnvp \
1963         statfs \
1964         statvfs \
1965         strcasecmp \
1966         strdup \
1967         strerror \
1968         strncasecmp \
1969         strtold \
1970         strtoll \
1971         strtoull \
1972         symlink \
1973         tcgetattr \
1974         thr_kill2 \
1975         timegm \
1976         usleep \
1977         vsnprintf \
1978         wait4 \
1979         waitpid \
1980 )
1981 CFLAGS="$ac_save_CFLAGS"
1982
1983 dnl Check for -ldl
1984 if test "$ac_cv_func_dlopen" = no
1985 then
1986     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1987 fi
1988 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1989
1990 dnl Check for -lpoll for Mac OS X/Darwin
1991 if test "$ac_cv_func_poll" = no
1992 then
1993     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1994 fi
1995
1996 dnl Check for -lnsl for Solaris
1997 AC_SEARCH_LIBS(gethostbyname, nsl)
1998
1999 dnl Check for -lsocket for Solaris
2000 AC_SEARCH_LIBS(connect, socket)
2001
2002 dnl Check for -lresolv for Solaris
2003 AC_SEARCH_LIBS(inet_aton, resolv)
2004
2005 dnl **** Check for functions which may rely on -lsocket on Solaris.
2006 AC_CHECK_FUNCS(\
2007         getaddrinfo \
2008         getnameinfo \
2009         getnetbyname \
2010         getprotobyname \
2011         getprotobynumber \
2012         getservbyport \
2013         inet_network \
2014         inet_ntop \
2015         inet_pton \
2016         sendmsg \
2017         socketpair \
2018 )
2019
2020 dnl **** Check for OpenLDAP ***
2021 AC_SUBST(LDAPLIBS,"")
2022 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
2023 then
2024     AC_CHECK_TYPE(LDAPSortKey,
2025         [AC_CHECK_LIB(ldap_r, ldap_initialize,
2026             [AC_CHECK_LIB(lber, ber_init,
2027                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
2028                  LDAPLIBS="-lldap_r -llber"],,
2029                  [$LIBPTHREAD])],,
2030                  [$LIBPTHREAD])],,
2031         [#include <ldap.h>])
2032     WINE_CHECK_LIB_FUNCS(\
2033         ldap_count_references \
2034         ldap_first_reference \
2035         ldap_next_reference \
2036         ldap_parse_reference \
2037         ldap_parse_sort_control \
2038         ldap_parse_sortresponse_control \
2039         ldap_parse_vlv_control \
2040         ldap_parse_vlvresponse_control,
2041         [$LDAPLIBS $LIBPTHREAD])
2042 fi
2043 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
2044                  [libldap (OpenLDAP) ${notice_platform}development files not found, LDAP won't be supported.])
2045
2046 AC_CACHE_CHECK([whether mkdir takes only one argument],
2047         wine_cv_one_arg_mkdir,
2048         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]],[[mkdir("foo");]])],
2049                           [wine_cv_one_arg_mkdir=yes],[wine_cv_one_arg_mkdir=no]))
2050 if test "$wine_cv_one_arg_mkdir" = "yes"
2051 then
2052   AC_DEFINE(HAVE_ONE_ARG_MKDIR, 1, [Define if mkdir takes only one argument])
2053 fi
2054
2055 AC_CACHE_CHECK([for sched_setaffinity],wine_cv_have_sched_setaffinity,
2056                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
2057 [[#define _GNU_SOURCE
2058 #include <sched.h>]], [[sched_setaffinity(0, 0, 0);]])],[wine_cv_have_sched_setaffinity=yes],[wine_cv_have_sched_setaffinity=no]))
2059 if test "$wine_cv_have_sched_setaffinity" = "yes"
2060 then
2061   AC_DEFINE(HAVE_SCHED_SETAFFINITY, 1, [Define to 1 if you have the `sched_setaffinity' function.])
2062 fi
2063
2064 dnl **** Check for types ****
2065
2066 AC_C_INLINE
2067 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
2068 AC_CHECK_TYPES([sigset_t],,,[#include <sys/types.h>
2069 #include <signal.h>])
2070 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
2071
2072 AC_CHECK_TYPES([struct xinpgen],,,
2073 [#include <sys/types.h>
2074 #ifdef HAVE_SYS_SOCKET_H
2075 #include <sys/socket.h>
2076 #endif
2077 #ifdef HAVE_SYS_SOCKETVAR_H
2078 #include <sys/socketvar.h>
2079 #endif
2080 #ifdef HAVE_NET_ROUTE_H
2081 #include <net/route.h>
2082 #endif
2083 #ifdef HAVE_NETINET_IN_H
2084 #include <netinet/in.h>
2085 #endif
2086 #ifdef HAVE_NETINET_IN_SYSTM_H
2087 #include <netinet/in_systm.h>
2088 #endif
2089 #ifdef HAVE_NETINET_IP_H
2090 #include <netinet/ip.h>
2091 #endif
2092 #ifdef HAVE_NETINET_IN_PCB_H
2093 #include <netinet/in_pcb.h>
2094 #endif])
2095
2096 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
2097 [#ifdef HAVE_LINUX_INPUT_H
2098 #include <linux/input.h>
2099 #endif])
2100
2101 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
2102                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
2103 if test "$wine_cv_have_sigaddset" = "yes"
2104 then
2105   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
2106 fi
2107
2108
2109 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
2110         wine_cv_linux_gethostbyname_r_6,
2111         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
2112     char *name=0;
2113     struct hostent he;
2114     struct hostent *result;
2115     char *buf=0;
2116     int bufsize=0;
2117     int errnr;
2118     char *addr=0;
2119     int addrlen=0;
2120     int addrtype=0;
2121     gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
2122     gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
2123     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
2124         ])
2125    )
2126    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
2127    then
2128       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
2129                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
2130    fi
2131
2132 if test "$ac_cv_header_linux_joystick_h" = "yes"
2133 then
2134    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
2135         wine_cv_linux_joystick_22_api,
2136         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2137         #include <sys/ioctl.h>
2138         #include <sys/types.h>
2139         #include <linux/joystick.h>
2140
2141         struct js_event blub;
2142         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
2143         #error "no 2.2 header"
2144         #endif
2145         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
2146    )
2147    if test "$wine_cv_linux_joystick_22_api" = "yes"
2148    then
2149       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
2150                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
2151    fi
2152 fi
2153
2154 dnl **** FIXME: what about mixed cases, where we need two of them? ***
2155
2156 dnl Check for statfs members
2157 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
2158 [#include <sys/types.h>
2159 #ifdef HAVE_SYS_PARAM_H
2160 # include <sys/param.h>
2161 #endif
2162 #ifdef HAVE_SYS_MOUNT_H
2163 # include <sys/mount.h>
2164 #endif
2165 #ifdef HAVE_SYS_VFS_H
2166 # include <sys/vfs.h>
2167 #endif
2168 #ifdef HAVE_SYS_STATFS_H
2169 # include <sys/statfs.h>
2170 #endif])
2171
2172 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
2173 [#ifdef HAVE_SYS_STATVFS_H
2174 #include <sys/statvfs.h>
2175 #endif])
2176
2177 dnl Check for socket structure members
2178 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
2179 [#include <sys/types.h>
2180 #ifdef HAVE_SYS_SOCKET_H
2181 # include <sys/socket.h>
2182 #endif
2183 #ifdef HAVE_SYS_UN_H
2184 # include <sys/un.h>
2185 #endif])
2186
2187 dnl Check for scsireq_t and sg_io_hdr_t members
2188 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
2189 [#include <sys/types.h>
2190 #ifdef HAVE_SCSI_SG_H
2191 #include <scsi/sg.h>
2192 #endif])
2193
2194 dnl Check for siginfo_t members
2195 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
2196
2197 dnl Check for struct mtget members
2198 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
2199 [#include <sys/types.h>
2200 #ifdef HAVE_SYS_MTIO_H
2201 #include <sys/mtio.h>
2202 #endif])
2203
2204 dnl Check for struct option
2205 AC_CHECK_MEMBERS([struct option.name],,,
2206 [#ifdef HAVE_GETOPT_H
2207 #include <getopt.h>
2208 #endif])
2209
2210 dnl Check for stat.st_blocks and ns-resolved times
2211 AC_CHECK_MEMBERS([struct stat.st_blocks,struct stat.st_mtim,struct stat.st_ctim,struct stat.st_atim])
2212
2213 dnl Check for sin6_scope_id
2214 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
2215 [#ifdef HAVE_SYS_TYPES_H
2216 #include <sys/types.h>
2217 #endif
2218 #ifdef HAVE_NETINET_IN_H
2219 #include <netinet/in.h>
2220 #endif])
2221
2222 dnl Check for ns_msg ptr member
2223 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
2224 [#ifdef HAVE_SYS_TYPES_H
2225 #include <sys/types.h>
2226 #endif
2227 #ifdef HAVE_NETINET_IN_H
2228 # include <netinet/in.h>
2229 #endif
2230 #ifdef HAVE_ARPA_NAMESER_H
2231 # include <arpa/nameser.h>
2232 #endif])
2233
2234 dnl Check for struct icmpstat.icps_outhist
2235 AC_CHECK_MEMBERS([struct icmpstat.icps_outhist],,,
2236 [#ifdef HAVE_SYS_TYPES_H
2237 #include <sys/types.h>
2238 #endif
2239 #ifdef HAVE_ALIAS_H
2240 #include <alias.h>
2241 #endif
2242 #ifdef HAVE_SYS_SOCKET_H
2243 #include <sys/socket.h>
2244 #endif
2245 #ifdef HAVE_SYS_SOCKETVAR_H
2246 #include <sys/socketvar.h>
2247 #endif
2248 #ifdef HAVE_SYS_TIMEOUT_H
2249 #include <sys/timeout.h>
2250 #endif
2251 #ifdef HAVE_NETINET_IN_H
2252 #include <netinet/in.h>
2253 #endif
2254 #ifdef HAVE_NETINET_IN_SYSTM_H
2255 #include <netinet/in_systm.h>
2256 #endif
2257 #ifdef HAVE_NETINET_IP_H
2258 #include <netinet/ip.h>
2259 #endif
2260 #ifdef HAVE_NETINET_IP_VAR_H
2261 #include <netinet/ip_var.h>
2262 #endif
2263 #ifdef HAVE_NETINET_IP_ICMP_H
2264 #include <netinet/ip_icmp.h>
2265 #endif
2266 #ifdef HAVE_NETINET_ICMP_VAR
2267 #include <netinet/icmp_var.h>
2268 #endif])
2269
2270 dnl Check for struct ifreq.ifr_hwaddr
2271 AC_CHECK_MEMBERS([struct ifreq.ifr_hwaddr],,,
2272 [#ifdef HAVE_SYS_TYPES_H
2273 #include <sys/types.h>
2274 #endif
2275 #ifdef HAVE_NET_IF_H
2276 # include <net/if.h>
2277 #endif])
2278
2279 dnl Check for the external timezone variables timezone and daylight
2280 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
2281                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
2282 if test "$ac_cv_have_timezone" = "yes"
2283 then
2284     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
2285 fi
2286 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
2287                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
2288 if test "$ac_cv_have_daylight" = "yes"
2289 then
2290     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
2291 fi
2292
2293 dnl Check for isinf
2294 ac_save_LIBS="$LIBS"
2295 LIBS="$LIBS -lm"
2296 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
2297                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
2298 if test "$ac_cv_have_isinf" = "yes"
2299 then
2300     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
2301 fi
2302
2303 dnl Check for isnan
2304 AC_CACHE_CHECK([for isnan], ac_cv_have_isnan,
2305                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isnan(f)]])],[ac_cv_have_isnan="yes"],[ac_cv_have_isnan="no"]))
2306 if test "$ac_cv_have_isnan" = "yes"
2307 then
2308     AC_DEFINE(HAVE_ISNAN, 1, [Define to 1 if you have the `isnan' function.])
2309 fi
2310 LIBS="$ac_save_LIBS"
2311
2312 dnl *** check for the need to define platform-specific symbols
2313
2314 case $host_cpu in
2315   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
2316   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
2317   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
2318   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
2319   *arm*)            WINE_CHECK_DEFINE([__arm__]) ;;
2320 esac
2321
2322 case $host_vendor in
2323   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
2324 esac
2325
2326 dnl **** Generate output files ****
2327
2328 AH_TOP([#ifndef WINE_CROSSTEST
2329 #define __WINE_CONFIG_H])
2330 AH_BOTTOM([#endif /* WINE_CROSSTEST */])
2331
2332 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
2333
2334 WINE_CONFIG_SYMLINK(dlls/shell32/AUTHORS,AUTHORS)
2335 WINE_CONFIG_SYMLINK(dlls/wineps.drv/generic.ppd)
2336 WINE_CONFIG_SYMLINK(fonts/marlett.ttf,,enable_fonts)
2337 WINE_CONFIG_SYMLINK(fonts/symbol.ttf,,enable_fonts)
2338 WINE_CONFIG_SYMLINK(fonts/tahoma.ttf,,enable_fonts)
2339 WINE_CONFIG_SYMLINK(fonts/tahomabd.ttf,,enable_fonts)
2340 WINE_CONFIG_SYMLINK(po/LINGUAS)
2341 WINE_CONFIG_SYMLINK(tools/l_intl.nls,,enable_tools)
2342 WINE_CONFIG_SYMLINK(wine,tools/winewrapper)
2343 WINE_CONFIG_SYMLINK(wine64,tools/winewrapper,enable_win64)
2344
2345 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/dibdrv)
2346 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
2347 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
2348 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
2349 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
2350 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
2351 WINE_CONFIG_EXTRA_DIR(include/wine)
2352
2353 WINE_CONFIG_MAKERULES([Make.rules],[MAKE_RULES])
2354 WINE_CONFIG_MAKERULES([Maketest.rules],[MAKE_TEST_RULES],[Make.rules])
2355 WINE_CONFIG_MAKERULES([dlls/Makedll.rules],[MAKE_DLL_RULES],[Make.rules])
2356 WINE_CONFIG_MAKERULES([dlls/Makeimplib.rules],[MAKE_IMPLIB_RULES],[Make.rules])
2357 WINE_CONFIG_MAKERULES([programs/Makeprog.rules],[MAKE_PROG_RULES],[Make.rules])
2358
2359 WINE_CONFIG_DLL(acledit)
2360 WINE_CONFIG_DLL(aclui,,[implib])
2361 WINE_CONFIG_DLL(activeds,,[implib])
2362 WINE_CONFIG_DLL(actxprxy)
2363 WINE_CONFIG_LIB(adsiid)
2364 WINE_CONFIG_DLL(advapi32,,[implib])
2365 WINE_CONFIG_TEST(dlls/advapi32/tests)
2366 WINE_CONFIG_DLL(advpack,,[implib])
2367 WINE_CONFIG_TEST(dlls/advpack/tests)
2368 WINE_CONFIG_DLL(amstream)
2369 WINE_CONFIG_TEST(dlls/amstream/tests)
2370 WINE_CONFIG_DLL(apphelp)
2371 WINE_CONFIG_DLL(appwiz.cpl,,[po])
2372 WINE_CONFIG_DLL(atl,,[implib])
2373 WINE_CONFIG_TEST(dlls/atl/tests)
2374 WINE_CONFIG_DLL(authz)
2375 WINE_CONFIG_DLL(avicap32,,[implib])
2376 WINE_CONFIG_DLL(avifil32,,[implib,po])
2377 WINE_CONFIG_TEST(dlls/avifil32/tests)
2378 WINE_CONFIG_DLL(avifile.dll16,enable_win16)
2379 WINE_CONFIG_DLL(avrt,,[implib])
2380 WINE_CONFIG_DLL(bcrypt)
2381 WINE_CONFIG_DLL(browseui,,[po])
2382 WINE_CONFIG_TEST(dlls/browseui/tests)
2383 WINE_CONFIG_DLL(cabinet,,[implib])
2384 WINE_CONFIG_TEST(dlls/cabinet/tests)
2385 WINE_CONFIG_DLL(capi2032,,[implib])
2386 WINE_CONFIG_DLL(cards,,[implib])
2387 WINE_CONFIG_DLL(cfgmgr32,,[implib])
2388 WINE_CONFIG_DLL(clusapi,,[implib])
2389 WINE_CONFIG_DLL(comcat)
2390 WINE_CONFIG_TEST(dlls/comcat/tests)
2391 WINE_CONFIG_DLL(comctl32,,[implib,po])
2392 WINE_CONFIG_TEST(dlls/comctl32/tests)
2393 WINE_CONFIG_DLL(comdlg32,,[implib,po])
2394 WINE_CONFIG_TEST(dlls/comdlg32/tests)
2395 WINE_CONFIG_DLL(comm.drv16,enable_win16)
2396 WINE_CONFIG_DLL(commdlg.dll16,enable_win16)
2397 WINE_CONFIG_DLL(compobj.dll16,enable_win16)
2398 WINE_CONFIG_DLL(compstui,,[implib])
2399 WINE_CONFIG_DLL(credui,,[implib,po])
2400 WINE_CONFIG_TEST(dlls/credui/tests)
2401 WINE_CONFIG_DLL(crtdll,,[implib])
2402 WINE_CONFIG_DLL(crypt32,,[implib,po])
2403 WINE_CONFIG_TEST(dlls/crypt32/tests)
2404 WINE_CONFIG_DLL(cryptdlg,,[po])
2405 WINE_CONFIG_DLL(cryptdll,,[implib])
2406 WINE_CONFIG_DLL(cryptnet,,[implib])
2407 WINE_CONFIG_TEST(dlls/cryptnet/tests)
2408 WINE_CONFIG_DLL(cryptui,,[implib,po])
2409 WINE_CONFIG_TEST(dlls/cryptui/tests)
2410 WINE_CONFIG_DLL(ctapi32)
2411 WINE_CONFIG_DLL(ctl3d.dll16,enable_win16)
2412 WINE_CONFIG_DLL(ctl3d32,,[implib])
2413 WINE_CONFIG_DLL(ctl3dv2.dll16,enable_win16)
2414 WINE_CONFIG_DLL(d3d10,,[implib])
2415 WINE_CONFIG_TEST(dlls/d3d10/tests)
2416 WINE_CONFIG_DLL(d3d10core,,[implib])
2417 WINE_CONFIG_TEST(dlls/d3d10core/tests)
2418 WINE_CONFIG_DLL(d3d8,,[implib])
2419 WINE_CONFIG_TEST(dlls/d3d8/tests)
2420 WINE_CONFIG_DLL(d3d9,,[implib])
2421 WINE_CONFIG_TEST(dlls/d3d9/tests)
2422 WINE_CONFIG_DLL(d3dcompiler_33)
2423 WINE_CONFIG_DLL(d3dcompiler_34)
2424 WINE_CONFIG_DLL(d3dcompiler_35)
2425 WINE_CONFIG_DLL(d3dcompiler_36)
2426 WINE_CONFIG_DLL(d3dcompiler_37)
2427 WINE_CONFIG_DLL(d3dcompiler_38)
2428 WINE_CONFIG_DLL(d3dcompiler_39)
2429 WINE_CONFIG_DLL(d3dcompiler_40)
2430 WINE_CONFIG_DLL(d3dcompiler_41)
2431 WINE_CONFIG_DLL(d3dcompiler_42)
2432 WINE_CONFIG_DLL(d3dcompiler_43,,[implib],[d3dcompiler])
2433 WINE_CONFIG_TEST(dlls/d3dcompiler_43/tests)
2434 WINE_CONFIG_DLL(d3dim,,[implib])
2435 WINE_CONFIG_DLL(d3drm,,[implib])
2436 WINE_CONFIG_TEST(dlls/d3drm/tests)
2437 WINE_CONFIG_DLL(d3dx10_33)
2438 WINE_CONFIG_DLL(d3dx10_34)
2439 WINE_CONFIG_DLL(d3dx10_35)
2440 WINE_CONFIG_DLL(d3dx10_36)
2441 WINE_CONFIG_DLL(d3dx10_37)
2442 WINE_CONFIG_DLL(d3dx10_38)
2443 WINE_CONFIG_DLL(d3dx10_39)
2444 WINE_CONFIG_DLL(d3dx10_40)
2445 WINE_CONFIG_DLL(d3dx10_41)
2446 WINE_CONFIG_DLL(d3dx10_42)
2447 WINE_CONFIG_DLL(d3dx10_43)
2448 WINE_CONFIG_DLL(d3dx9_24)
2449 WINE_CONFIG_DLL(d3dx9_25)
2450 WINE_CONFIG_DLL(d3dx9_26)
2451 WINE_CONFIG_DLL(d3dx9_27)
2452 WINE_CONFIG_DLL(d3dx9_28)
2453 WINE_CONFIG_DLL(d3dx9_29)
2454 WINE_CONFIG_DLL(d3dx9_30)
2455 WINE_CONFIG_DLL(d3dx9_31)
2456 WINE_CONFIG_DLL(d3dx9_32)
2457 WINE_CONFIG_DLL(d3dx9_33)
2458 WINE_CONFIG_DLL(d3dx9_34)
2459 WINE_CONFIG_DLL(d3dx9_35)
2460 WINE_CONFIG_DLL(d3dx9_36,,[implib],[d3dx9])
2461 WINE_CONFIG_TEST(dlls/d3dx9_36/tests)
2462 WINE_CONFIG_DLL(d3dx9_37)
2463 WINE_CONFIG_DLL(d3dx9_38)
2464 WINE_CONFIG_DLL(d3dx9_39)
2465 WINE_CONFIG_DLL(d3dx9_40)
2466 WINE_CONFIG_DLL(d3dx9_41)
2467 WINE_CONFIG_DLL(d3dx9_42)
2468 WINE_CONFIG_DLL(d3dx9_43)
2469 WINE_CONFIG_DLL(d3dxof,,[implib])
2470 WINE_CONFIG_TEST(dlls/d3dxof/tests)
2471 WINE_CONFIG_DLL(dbgeng,,[implib])
2472 WINE_CONFIG_DLL(dbghelp,,[implib])
2473 WINE_CONFIG_DLL(dciman32,,[implib])
2474 WINE_CONFIG_DLL(ddeml.dll16,enable_win16)
2475 WINE_CONFIG_DLL(ddraw,,[implib])
2476 WINE_CONFIG_TEST(dlls/ddraw/tests)
2477 WINE_CONFIG_DLL(ddrawex)
2478 WINE_CONFIG_TEST(dlls/ddrawex/tests)
2479 WINE_CONFIG_DLL(devenum,,[po])
2480 WINE_CONFIG_DLL(dinput,,[implib,po,staticimplib])
2481 WINE_CONFIG_TEST(dlls/dinput/tests)
2482 WINE_CONFIG_DLL(dinput8,,[implib])
2483 WINE_CONFIG_TEST(dlls/dinput8/tests)
2484 WINE_CONFIG_DLL(dispdib.dll16,enable_win16)
2485 WINE_CONFIG_DLL(dispex)
2486 WINE_CONFIG_TEST(dlls/dispex/tests)
2487 WINE_CONFIG_DLL(display.drv16,enable_win16)
2488 WINE_CONFIG_DLL(dmband)
2489 WINE_CONFIG_DLL(dmcompos)
2490 WINE_CONFIG_DLL(dmime)
2491 WINE_CONFIG_TEST(dlls/dmime/tests)
2492 WINE_CONFIG_DLL(dmloader)
2493 WINE_CONFIG_TEST(dlls/dmloader/tests)
2494 WINE_CONFIG_DLL(dmscript)
2495 WINE_CONFIG_DLL(dmstyle)
2496 WINE_CONFIG_DLL(dmsynth)
2497 WINE_CONFIG_DLL(dmusic)
2498 WINE_CONFIG_DLL(dmusic32,,[implib])
2499 WINE_CONFIG_DLL(dnsapi,,[implib])
2500 WINE_CONFIG_TEST(dlls/dnsapi/tests)
2501 WINE_CONFIG_DLL(dplay,,[implib])
2502 WINE_CONFIG_DLL(dplayx,,[implib])
2503 WINE_CONFIG_TEST(dlls/dplayx/tests)
2504 WINE_CONFIG_DLL(dpnaddr)
2505 WINE_CONFIG_DLL(dpnet,,[implib])
2506 WINE_CONFIG_TEST(dlls/dpnet/tests)
2507 WINE_CONFIG_DLL(dpnhpast)
2508 WINE_CONFIG_DLL(dpnlobby)
2509 WINE_CONFIG_DLL(dpwsockx)
2510 WINE_CONFIG_DLL(drmclien)
2511 WINE_CONFIG_DLL(dsound,,[implib])
2512 WINE_CONFIG_TEST(dlls/dsound/tests)
2513 WINE_CONFIG_DLL(dssenh)
2514 WINE_CONFIG_DLL(dswave)
2515 WINE_CONFIG_DLL(dwmapi,,[implib])
2516 WINE_CONFIG_DLL(dxdiagn,,[po])
2517 WINE_CONFIG_TEST(dlls/dxdiagn/tests)
2518 WINE_CONFIG_LIB(dxerr8)
2519 WINE_CONFIG_LIB(dxerr9)
2520 WINE_CONFIG_DLL(dxgi,,[implib])
2521 WINE_CONFIG_TEST(dlls/dxgi/tests)
2522 WINE_CONFIG_LIB(dxguid)
2523 WINE_CONFIG_DLL(explorerframe)
2524 WINE_CONFIG_TEST(dlls/explorerframe/tests)
2525 WINE_CONFIG_DLL(faultrep,,[implib])
2526 WINE_CONFIG_TEST(dlls/faultrep/tests)
2527 WINE_CONFIG_DLL(fltlib)
2528 WINE_CONFIG_DLL(fusion)
2529 WINE_CONFIG_TEST(dlls/fusion/tests)
2530 WINE_CONFIG_DLL(fwpuclnt)
2531 WINE_CONFIG_DLL(gameux)
2532 WINE_CONFIG_TEST(dlls/gameux/tests)
2533 WINE_CONFIG_DLL(gdi.exe16,enable_win16)
2534 WINE_CONFIG_DLL(gdi32,,[implib,po])
2535 WINE_CONFIG_TEST(dlls/gdi32/tests)
2536 WINE_CONFIG_DLL(gdiplus,,[implib])
2537 WINE_CONFIG_TEST(dlls/gdiplus/tests)
2538 WINE_CONFIG_DLL(glu32,,[implib])
2539 WINE_CONFIG_DLL(gphoto2.ds,,[po])
2540 WINE_CONFIG_DLL(gpkcsp)
2541 WINE_CONFIG_DLL(hal)
2542 WINE_CONFIG_DLL(hhctrl.ocx,,[po])
2543 WINE_CONFIG_DLL(hid,,[implib])
2544 WINE_CONFIG_DLL(hlink,,[implib])
2545 WINE_CONFIG_TEST(dlls/hlink/tests)
2546 WINE_CONFIG_DLL(hnetcfg)
2547 WINE_CONFIG_DLL(httpapi)
2548 WINE_CONFIG_DLL(iccvid,,[po])
2549 WINE_CONFIG_DLL(icmp)
2550 WINE_CONFIG_DLL(ieframe,,[implib,po])
2551 WINE_CONFIG_TEST(dlls/ieframe/tests)
2552 WINE_CONFIG_DLL(ifsmgr.vxd,enable_win16)
2553 WINE_CONFIG_DLL(imaadp32.acm)
2554 WINE_CONFIG_DLL(imagehlp,,[implib])
2555 WINE_CONFIG_TEST(dlls/imagehlp/tests)
2556 WINE_CONFIG_DLL(imm.dll16,enable_win16)
2557 WINE_CONFIG_DLL(imm32,,[implib])
2558 WINE_CONFIG_TEST(dlls/imm32/tests)
2559 WINE_CONFIG_DLL(inetcomm,,[implib])
2560 WINE_CONFIG_TEST(dlls/inetcomm/tests)
2561 WINE_CONFIG_DLL(inetcpl.cpl,,[po])
2562 WINE_CONFIG_DLL(inetmib1)
2563 WINE_CONFIG_TEST(dlls/inetmib1/tests)
2564 WINE_CONFIG_DLL(infosoft)
2565 WINE_CONFIG_TEST(dlls/infosoft/tests)
2566 WINE_CONFIG_DLL(initpki)
2567 WINE_CONFIG_DLL(inkobj)
2568 WINE_CONFIG_DLL(inseng)
2569 WINE_CONFIG_DLL(iphlpapi,,[implib])
2570 WINE_CONFIG_TEST(dlls/iphlpapi/tests)
2571 WINE_CONFIG_DLL(itircl)
2572 WINE_CONFIG_DLL(itss)
2573 WINE_CONFIG_TEST(dlls/itss/tests)
2574 WINE_CONFIG_DLL(jscript,,[po])
2575 WINE_CONFIG_TEST(dlls/jscript/tests)
2576 WINE_CONFIG_DLL(kernel32,,[implib,mc])
2577 WINE_CONFIG_TEST(dlls/kernel32/tests)
2578 WINE_CONFIG_DLL(keyboard.drv16,enable_win16)
2579 WINE_CONFIG_DLL(krnl386.exe16,enable_win16,[implib],[kernel])
2580 WINE_CONFIG_DLL(ktmw32)
2581 WINE_CONFIG_DLL(loadperf,,[implib])
2582 WINE_CONFIG_DLL(localspl,,[po])
2583 WINE_CONFIG_TEST(dlls/localspl/tests)
2584 WINE_CONFIG_DLL(localui,,[po])
2585 WINE_CONFIG_TEST(dlls/localui/tests)
2586 WINE_CONFIG_DLL(lz32,,[implib])
2587 WINE_CONFIG_TEST(dlls/lz32/tests)
2588 WINE_CONFIG_DLL(lzexpand.dll16,enable_win16)
2589 WINE_CONFIG_DLL(mapi32,,[implib,po])
2590 WINE_CONFIG_TEST(dlls/mapi32/tests)
2591 WINE_CONFIG_DLL(mapistub)
2592 WINE_CONFIG_DLL(mciavi32)
2593 WINE_CONFIG_DLL(mcicda)
2594 WINE_CONFIG_DLL(mciqtz32)
2595 WINE_CONFIG_DLL(mciseq)
2596 WINE_CONFIG_DLL(mciwave)
2597 WINE_CONFIG_DLL(midimap)
2598 WINE_CONFIG_DLL(mlang,,[implib])
2599 WINE_CONFIG_TEST(dlls/mlang/tests)
2600 WINE_CONFIG_DLL(mmcndmgr)
2601 WINE_CONFIG_DLL(mmdevapi)
2602 WINE_CONFIG_TEST(dlls/mmdevapi/tests)
2603 WINE_CONFIG_DLL(mmdevldr.vxd,enable_win16)
2604 WINE_CONFIG_DLL(mmsystem.dll16,enable_win16)
2605 WINE_CONFIG_DLL(monodebg.vxd,enable_win16)
2606 WINE_CONFIG_DLL(mountmgr.sys)
2607 WINE_CONFIG_DLL(mouse.drv16,enable_win16)
2608 WINE_CONFIG_DLL(mpr,,[implib,po])
2609 WINE_CONFIG_DLL(mprapi,,[implib])
2610 WINE_CONFIG_DLL(msacm.dll16,enable_win16)
2611 WINE_CONFIG_DLL(msacm32.drv)
2612 WINE_CONFIG_DLL(msacm32,,[implib])
2613 WINE_CONFIG_TEST(dlls/msacm32/tests)
2614 WINE_CONFIG_DLL(msadp32.acm)
2615 WINE_CONFIG_DLL(mscat32)
2616 WINE_CONFIG_DLL(mscms,,[implib])
2617 WINE_CONFIG_TEST(dlls/mscms/tests)
2618 WINE_CONFIG_DLL(mscoree)
2619 WINE_CONFIG_TEST(dlls/mscoree/tests)
2620 WINE_CONFIG_DLL(msctf)
2621 WINE_CONFIG_TEST(dlls/msctf/tests)
2622 WINE_CONFIG_DLL(msdaps)
2623 WINE_CONFIG_DLL(msdmo,,[implib])
2624 WINE_CONFIG_DLL(msftedit)
2625 WINE_CONFIG_DLL(msg711.acm)
2626 WINE_CONFIG_DLL(msgsm32.acm)
2627 WINE_CONFIG_DLL(mshtml.tlb)
2628 WINE_CONFIG_DLL(mshtml,,[implib,po])
2629 WINE_CONFIG_TEST(dlls/mshtml/tests)
2630 WINE_CONFIG_DLL(msi,,[implib,po])
2631 WINE_CONFIG_TEST(dlls/msi/tests)
2632 WINE_CONFIG_DLL(msimg32,,[implib])
2633 WINE_CONFIG_DLL(msimsg)
2634 WINE_CONFIG_DLL(msimtf)
2635 WINE_CONFIG_DLL(msisip)
2636 WINE_CONFIG_DLL(msisys.ocx)
2637 WINE_CONFIG_DLL(msnet32)
2638 WINE_CONFIG_DLL(mspatcha)
2639 WINE_CONFIG_DLL(msrle32,,[po])
2640 WINE_CONFIG_DLL(mssign32)
2641 WINE_CONFIG_DLL(mssip32)
2642 WINE_CONFIG_DLL(mstask)
2643 WINE_CONFIG_TEST(dlls/mstask/tests)
2644 WINE_CONFIG_DLL(msvcirt)
2645 WINE_CONFIG_DLL(msvcp100)
2646 WINE_CONFIG_DLL(msvcp60)
2647 WINE_CONFIG_DLL(msvcp70)
2648 WINE_CONFIG_DLL(msvcp71)
2649 WINE_CONFIG_DLL(msvcp80)
2650 WINE_CONFIG_DLL(msvcp90)
2651 WINE_CONFIG_TEST(dlls/msvcp90/tests)
2652 WINE_CONFIG_DLL(msvcr100)
2653 WINE_CONFIG_DLL(msvcr70,,[implib])
2654 WINE_CONFIG_DLL(msvcr71,,[implib])
2655 WINE_CONFIG_DLL(msvcr80)
2656 WINE_CONFIG_DLL(msvcr90)
2657 WINE_CONFIG_TEST(dlls/msvcr90/tests)
2658 WINE_CONFIG_DLL(msvcrt,,[implib])
2659 WINE_CONFIG_TEST(dlls/msvcrt/tests)
2660 WINE_CONFIG_DLL(msvcrt20,,[implib])
2661 WINE_CONFIG_DLL(msvcrt40,,[implib])
2662 WINE_CONFIG_DLL(msvcrtd,,[implib])
2663 WINE_CONFIG_TEST(dlls/msvcrtd/tests)
2664 WINE_CONFIG_DLL(msvfw32,,[implib,po])
2665 WINE_CONFIG_TEST(dlls/msvfw32/tests)
2666 WINE_CONFIG_DLL(msvidc32,,[po])
2667 WINE_CONFIG_DLL(msvideo.dll16,enable_win16)
2668 WINE_CONFIG_DLL(mswsock,,[implib])
2669 WINE_CONFIG_DLL(msxml)
2670 WINE_CONFIG_DLL(msxml2)
2671 WINE_CONFIG_DLL(msxml3)
2672 WINE_CONFIG_TEST(dlls/msxml3/tests)
2673 WINE_CONFIG_DLL(msxml4)
2674 WINE_CONFIG_DLL(msxml6)
2675 WINE_CONFIG_DLL(nddeapi,,[implib])
2676 WINE_CONFIG_DLL(netapi32,,[implib])
2677 WINE_CONFIG_TEST(dlls/netapi32/tests)
2678 WINE_CONFIG_DLL(newdev,,[implib])
2679 WINE_CONFIG_DLL(normaliz,,[implib])
2680 WINE_CONFIG_DLL(npmshtml)
2681 WINE_CONFIG_DLL(ntdll,,[implib])
2682 WINE_CONFIG_TEST(dlls/ntdll/tests)
2683 WINE_CONFIG_DLL(ntdsapi,,[implib])
2684 WINE_CONFIG_TEST(dlls/ntdsapi/tests)
2685 WINE_CONFIG_DLL(ntoskrnl.exe,,[implib])
2686 WINE_CONFIG_DLL(ntprint)
2687 WINE_CONFIG_TEST(dlls/ntprint/tests)
2688 WINE_CONFIG_DLL(objsel)
2689 WINE_CONFIG_DLL(odbc32,,[implib])
2690 WINE_CONFIG_DLL(odbccp32,,[implib])
2691 WINE_CONFIG_TEST(dlls/odbccp32/tests)
2692 WINE_CONFIG_DLL(ole2.dll16,enable_win16)
2693 WINE_CONFIG_DLL(ole2conv.dll16,enable_win16)
2694 WINE_CONFIG_DLL(ole2disp.dll16,enable_win16)
2695 WINE_CONFIG_DLL(ole2nls.dll16,enable_win16)
2696 WINE_CONFIG_DLL(ole2prox.dll16,enable_win16)
2697 WINE_CONFIG_DLL(ole2thk.dll16,enable_win16)
2698 WINE_CONFIG_DLL(ole32,,[implib])
2699 WINE_CONFIG_TEST(dlls/ole32/tests)
2700 WINE_CONFIG_DLL(oleacc,,[implib,po])
2701 WINE_CONFIG_TEST(dlls/oleacc/tests)
2702 WINE_CONFIG_DLL(oleaut32,,[implib,po])
2703 WINE_CONFIG_TEST(dlls/oleaut32/tests)
2704 WINE_CONFIG_DLL(olecli.dll16,enable_win16)
2705 WINE_CONFIG_DLL(olecli32,,[implib])
2706 WINE_CONFIG_DLL(oledb32)
2707 WINE_CONFIG_TEST(dlls/oledb32/tests)
2708 WINE_CONFIG_DLL(oledlg,,[implib,po])
2709 WINE_CONFIG_DLL(olepro32,,[implib])
2710 WINE_CONFIG_DLL(olesvr.dll16,enable_win16)
2711 WINE_CONFIG_DLL(olesvr32,,[implib])
2712 WINE_CONFIG_DLL(olethk32)
2713 WINE_CONFIG_DLL(openal32)
2714 WINE_CONFIG_DLL(opencl)
2715 WINE_CONFIG_DLL(opengl32,,[implib])
2716 WINE_CONFIG_TEST(dlls/opengl32/tests)
2717 WINE_CONFIG_DLL(pdh,,[implib])
2718 WINE_CONFIG_TEST(dlls/pdh/tests)
2719 WINE_CONFIG_DLL(pidgen)
2720 WINE_CONFIG_DLL(powrprof,,[implib])
2721 WINE_CONFIG_DLL(printui)
2722 WINE_CONFIG_DLL(propsys,,[implib])
2723 WINE_CONFIG_TEST(dlls/propsys/tests)
2724 WINE_CONFIG_DLL(psapi,,[implib])
2725 WINE_CONFIG_TEST(dlls/psapi/tests)
2726 WINE_CONFIG_DLL(pstorec)
2727 WINE_CONFIG_DLL(qcap)
2728 WINE_CONFIG_DLL(qedit)
2729 WINE_CONFIG_TEST(dlls/qedit/tests)
2730 WINE_CONFIG_DLL(qmgr)
2731 WINE_CONFIG_TEST(dlls/qmgr/tests)
2732 WINE_CONFIG_DLL(qmgrprxy)
2733 WINE_CONFIG_DLL(quartz,,[implib])
2734 WINE_CONFIG_TEST(dlls/quartz/tests)
2735 WINE_CONFIG_DLL(query)
2736 WINE_CONFIG_DLL(rasapi16.dll16,enable_win16)
2737 WINE_CONFIG_DLL(rasapi32,,[implib])
2738 WINE_CONFIG_TEST(dlls/rasapi32/tests)
2739 WINE_CONFIG_DLL(rasdlg,,[implib])
2740 WINE_CONFIG_DLL(regapi)
2741 WINE_CONFIG_DLL(resutils,,[implib])
2742 WINE_CONFIG_DLL(riched20,,[implib])
2743 WINE_CONFIG_TEST(dlls/riched20/tests)
2744 WINE_CONFIG_DLL(riched32)
2745 WINE_CONFIG_TEST(dlls/riched32/tests)
2746 WINE_CONFIG_DLL(rpcrt4,,[implib])
2747 WINE_CONFIG_TEST(dlls/rpcrt4/tests)
2748 WINE_CONFIG_DLL(rsabase)
2749 WINE_CONFIG_DLL(rsaenh,,[implib])
2750 WINE_CONFIG_TEST(dlls/rsaenh/tests)
2751 WINE_CONFIG_DLL(rstrtmgr)
2752 WINE_CONFIG_DLL(rtutils,,[implib])
2753 WINE_CONFIG_DLL(samlib)
2754 WINE_CONFIG_DLL(sane.ds,,[po])
2755 WINE_CONFIG_DLL(scarddlg)
2756 WINE_CONFIG_DLL(sccbase)
2757 WINE_CONFIG_DLL(schannel)
2758 WINE_CONFIG_TEST(dlls/schannel/tests)
2759 WINE_CONFIG_DLL(scrrun)
2760 WINE_CONFIG_DLL(secur32,,[implib])
2761 WINE_CONFIG_TEST(dlls/secur32/tests)
2762 WINE_CONFIG_DLL(security)
2763 WINE_CONFIG_DLL(sensapi,,[implib])
2764 WINE_CONFIG_DLL(serialui,,[implib])
2765 WINE_CONFIG_TEST(dlls/serialui/tests)
2766 WINE_CONFIG_DLL(setupapi,,[implib,po])
2767 WINE_CONFIG_TEST(dlls/setupapi/tests)
2768 WINE_CONFIG_DLL(setupx.dll16,enable_win16)
2769 WINE_CONFIG_DLL(sfc,,[implib])
2770 WINE_CONFIG_DLL(sfc_os,,[implib])
2771 WINE_CONFIG_DLL(shdoclc,,[po])
2772 WINE_CONFIG_DLL(shdocvw,,[implib])
2773 WINE_CONFIG_TEST(dlls/shdocvw/tests)
2774 WINE_CONFIG_DLL(shell.dll16,enable_win16)
2775 WINE_CONFIG_DLL(shell32,,[implib,po])
2776 WINE_CONFIG_TEST(dlls/shell32/tests)
2777 WINE_CONFIG_DLL(shfolder,,[implib])
2778 WINE_CONFIG_DLL(shlwapi,,[implib,po])
2779 WINE_CONFIG_TEST(dlls/shlwapi/tests)
2780 WINE_CONFIG_DLL(slbcsp)
2781 WINE_CONFIG_DLL(slc,,[implib])
2782 WINE_CONFIG_DLL(snmpapi,,[implib])
2783 WINE_CONFIG_TEST(dlls/snmpapi/tests)
2784 WINE_CONFIG_DLL(softpub)
2785 WINE_CONFIG_DLL(sound.drv16,enable_win16)
2786 WINE_CONFIG_DLL(spoolss,,[implib])
2787 WINE_CONFIG_TEST(dlls/spoolss/tests)
2788 WINE_CONFIG_DLL(stdole2.tlb)
2789 WINE_CONFIG_DLL(stdole32.tlb)
2790 WINE_CONFIG_DLL(sti,,[implib])
2791 WINE_CONFIG_TEST(dlls/sti/tests)
2792 WINE_CONFIG_DLL(storage.dll16,enable_win16)
2793 WINE_CONFIG_DLL(stress.dll16,enable_win16)
2794 WINE_CONFIG_LIB(strmbase)
2795 WINE_CONFIG_LIB(strmiids)
2796 WINE_CONFIG_DLL(svrapi)
2797 WINE_CONFIG_DLL(sxs)
2798 WINE_CONFIG_DLL(system.drv16,enable_win16)
2799 WINE_CONFIG_DLL(t2embed)
2800 WINE_CONFIG_DLL(tapi32,,[implib])
2801 WINE_CONFIG_DLL(toolhelp.dll16,enable_win16)
2802 WINE_CONFIG_DLL(traffic)
2803 WINE_CONFIG_DLL(twain.dll16,enable_win16)
2804 WINE_CONFIG_DLL(twain_32)
2805 WINE_CONFIG_TEST(dlls/twain_32/tests)
2806 WINE_CONFIG_DLL(typelib.dll16,enable_win16)
2807 WINE_CONFIG_DLL(unicows,,[implib])
2808 WINE_CONFIG_DLL(updspapi)
2809 WINE_CONFIG_DLL(url,,[implib])
2810 WINE_CONFIG_DLL(urlmon,,[implib])
2811 WINE_CONFIG_TEST(dlls/urlmon/tests)
2812 WINE_CONFIG_DLL(usbd.sys,,[implib])
2813 WINE_CONFIG_DLL(user.exe16,enable_win16)
2814 WINE_CONFIG_DLL(user32,,[implib,po])
2815 WINE_CONFIG_TEST(dlls/user32/tests)
2816 WINE_CONFIG_DLL(userenv,,[implib])
2817 WINE_CONFIG_TEST(dlls/userenv/tests)
2818 WINE_CONFIG_DLL(usp10,,[implib])
2819 WINE_CONFIG_TEST(dlls/usp10/tests)
2820 WINE_CONFIG_LIB(uuid)
2821 WINE_CONFIG_DLL(uxtheme,,[implib])
2822 WINE_CONFIG_TEST(dlls/uxtheme/tests)
2823 WINE_CONFIG_DLL(vbscript)
2824 WINE_CONFIG_TEST(dlls/vbscript/tests)
2825 WINE_CONFIG_DLL(vcomp)
2826 WINE_CONFIG_DLL(vdhcp.vxd,enable_win16)
2827 WINE_CONFIG_DLL(vdmdbg,,[implib])
2828 WINE_CONFIG_DLL(ver.dll16,enable_win16)
2829 WINE_CONFIG_DLL(version,,[implib])
2830 WINE_CONFIG_TEST(dlls/version/tests)
2831 WINE_CONFIG_DLL(vmm.vxd,enable_win16)
2832 WINE_CONFIG_DLL(vnbt.vxd,enable_win16)
2833 WINE_CONFIG_DLL(vnetbios.vxd,enable_win16)
2834 WINE_CONFIG_DLL(vtdapi.vxd,enable_win16)
2835 WINE_CONFIG_DLL(vwin32.vxd,enable_win16)
2836 WINE_CONFIG_DLL(w32skrnl,enable_win16)
2837 WINE_CONFIG_DLL(w32sys.dll16,enable_win16)
2838 WINE_CONFIG_DLL(wbemprox)
2839 WINE_CONFIG_DLL(wer,,[implib])
2840 WINE_CONFIG_TEST(dlls/wer/tests)
2841 WINE_CONFIG_DLL(wiaservc)
2842 WINE_CONFIG_DLL(win32s16.dll16,enable_win16)
2843 WINE_CONFIG_DLL(win87em.dll16,enable_win16)
2844 WINE_CONFIG_DLL(winaspi.dll16,enable_win16)
2845 WINE_CONFIG_DLL(windebug.dll16,enable_win16)
2846 WINE_CONFIG_DLL(windowscodecs,,[implib])
2847 WINE_CONFIG_TEST(dlls/windowscodecs/tests)
2848 WINE_CONFIG_DLL(winealsa.drv)
2849 WINE_CONFIG_DLL(winecoreaudio.drv)
2850 WINE_CONFIG_LIB(winecrt0)
2851 WINE_CONFIG_DLL(wined3d,,[implib])
2852 WINE_CONFIG_DLL(winegstreamer)
2853 WINE_CONFIG_DLL(winejoystick.drv)
2854 WINE_CONFIG_DLL(winemapi)
2855 WINE_CONFIG_DLL(winemp3.acm)
2856 WINE_CONFIG_DLL(wineoss.drv)
2857 WINE_CONFIG_DLL(wineps.drv,,[install-lib,po])
2858 WINE_CONFIG_DLL(wineps16.drv16,enable_win16)
2859 WINE_CONFIG_DLL(wineqtdecoder)
2860 WINE_CONFIG_DLL(winequartz.drv)
2861 WINE_CONFIG_DLL(winex11.drv)
2862 WINE_CONFIG_DLL(wing.dll16,enable_win16)
2863 WINE_CONFIG_DLL(wing32)
2864 WINE_CONFIG_DLL(winhttp,,[implib])
2865 WINE_CONFIG_TEST(dlls/winhttp/tests)
2866 WINE_CONFIG_DLL(wininet,,[implib,po])
2867 WINE_CONFIG_TEST(dlls/wininet/tests)
2868 WINE_CONFIG_DLL(winmm,,[implib,po])
2869 WINE_CONFIG_TEST(dlls/winmm/tests)
2870 WINE_CONFIG_DLL(winnls.dll16,enable_win16)
2871 WINE_CONFIG_DLL(winnls32,,[implib])
2872 WINE_CONFIG_DLL(winscard,,[implib])
2873 WINE_CONFIG_DLL(winsock.dll16,enable_win16)
2874 WINE_CONFIG_DLL(winspool.drv,,[implib,po],[winspool])
2875 WINE_CONFIG_TEST(dlls/winspool.drv/tests)
2876 WINE_CONFIG_DLL(winsta)
2877 WINE_CONFIG_DLL(wintab.dll16,enable_win16)
2878 WINE_CONFIG_DLL(wintab32,,[implib])
2879 WINE_CONFIG_TEST(dlls/wintab32/tests)
2880 WINE_CONFIG_DLL(wintrust,,[implib])
2881 WINE_CONFIG_TEST(dlls/wintrust/tests)
2882 WINE_CONFIG_DLL(wlanapi)
2883 WINE_CONFIG_DLL(wldap32,,[implib,po])
2884 WINE_CONFIG_TEST(dlls/wldap32/tests)
2885 WINE_CONFIG_DLL(wmi)
2886 WINE_CONFIG_DLL(wmiutils)
2887 WINE_CONFIG_DLL(wnaspi32,,[implib])
2888 WINE_CONFIG_DLL(wow32,enable_win16,[implib])
2889 WINE_CONFIG_DLL(ws2_32,,[implib])
2890 WINE_CONFIG_TEST(dlls/ws2_32/tests)
2891 WINE_CONFIG_DLL(wshom.ocx)
2892 WINE_CONFIG_TEST(dlls/wshom.ocx/tests)
2893 WINE_CONFIG_DLL(wsock32,,[implib])
2894 WINE_CONFIG_DLL(wtsapi32,,[implib])
2895 WINE_CONFIG_DLL(wuapi)
2896 WINE_CONFIG_DLL(wuaueng)
2897 WINE_CONFIG_DLL(xapofx1_1)
2898 WINE_CONFIG_DLL(xinput1_1)
2899 WINE_CONFIG_DLL(xinput1_2)
2900 WINE_CONFIG_DLL(xinput1_3,,[implib],[xinput])
2901 WINE_CONFIG_TEST(dlls/xinput1_3/tests)
2902 WINE_CONFIG_DLL(xinput9_1_0)
2903 WINE_CONFIG_DLL(xmllite)
2904 WINE_CONFIG_TEST(dlls/xmllite/tests)
2905 WINE_CONFIG_DLL(xolehlp)
2906 WINE_CONFIG_MAKEFILE([documentation])
2907 WINE_CONFIG_MAKEFILE([fonts],,[install-lib])
2908 WINE_CONFIG_MAKEFILE([include],,[install-dev])
2909 WINE_CONFIG_MAKEFILE([libs/port])
2910 WINE_CONFIG_MAKEFILE([libs/wine],,[install-dev,install-lib])
2911 WINE_CONFIG_MAKEFILE([libs/wpp])
2912 WINE_CONFIG_MAKEFILE([loader],,[install-lib,manpage])
2913 WINE_CONFIG_PROGRAM(aspnet_regiis,,[install])
2914 WINE_CONFIG_PROGRAM(attrib,,[install,po])
2915 WINE_CONFIG_PROGRAM(cabarc,,[install])
2916 WINE_CONFIG_PROGRAM(cacls,,[install])
2917 WINE_CONFIG_PROGRAM(clock,,[install,po])
2918 WINE_CONFIG_PROGRAM(cmd,,[install,po])
2919 WINE_CONFIG_TEST(programs/cmd/tests)
2920 WINE_CONFIG_PROGRAM(cmdlgtst)
2921 WINE_CONFIG_PROGRAM(control,,[install])
2922 WINE_CONFIG_PROGRAM(dxdiag,,[install,po])
2923 WINE_CONFIG_PROGRAM(eject,,[install])
2924 WINE_CONFIG_PROGRAM(expand,,[install])
2925 WINE_CONFIG_PROGRAM(explorer,,[install,po])
2926 WINE_CONFIG_PROGRAM(extrac32,,[install])
2927 WINE_CONFIG_PROGRAM(hh,,[install])
2928 WINE_CONFIG_PROGRAM(hostname,,[install,po])
2929 WINE_CONFIG_PROGRAM(icinfo,,[install])
2930 WINE_CONFIG_PROGRAM(iexplore,,[install])
2931 WINE_CONFIG_PROGRAM(ipconfig,,[install,po])
2932 WINE_CONFIG_PROGRAM(lodctr,,[install])
2933 WINE_CONFIG_PROGRAM(mofcomp,,[install])
2934 WINE_CONFIG_PROGRAM(mshta,,[install])
2935 WINE_CONFIG_PROGRAM(msiexec,,[install,installbin,manpage])
2936 WINE_CONFIG_PROGRAM(net,,[install,po])
2937 WINE_CONFIG_PROGRAM(netsh,,[install])
2938 WINE_CONFIG_PROGRAM(ngen,,[install])
2939 WINE_CONFIG_PROGRAM(notepad,,[install,installbin,manpage,po])
2940 WINE_CONFIG_PROGRAM(oleview,,[install,po])
2941 WINE_CONFIG_PROGRAM(ping,,[install])
2942 WINE_CONFIG_PROGRAM(plugplay,,[install])
2943 WINE_CONFIG_PROGRAM(presentationfontcache,,[install])
2944 WINE_CONFIG_PROGRAM(progman,,[install,po])
2945 WINE_CONFIG_PROGRAM(reg,,[install,po])
2946 WINE_CONFIG_PROGRAM(regasm,,[install])
2947 WINE_CONFIG_PROGRAM(regedit,,[install,installbin,manpage,po])
2948 WINE_CONFIG_TEST(programs/regedit/tests)
2949 WINE_CONFIG_PROGRAM(regsvcs,,[install])
2950 WINE_CONFIG_PROGRAM(regsvr32,,[install,installbin,manpage])
2951 WINE_CONFIG_PROGRAM(rpcss,,[install])
2952 WINE_CONFIG_PROGRAM(rundll.exe16,enable_win16,[install])
2953 WINE_CONFIG_PROGRAM(rundll32,,[install])
2954 WINE_CONFIG_PROGRAM(sc,,[install])
2955 WINE_CONFIG_PROGRAM(secedit,,[install])
2956 WINE_CONFIG_PROGRAM(servicemodelreg,,[install])
2957 WINE_CONFIG_PROGRAM(services,,[install])
2958 WINE_CONFIG_PROGRAM(spoolsv,,[install])
2959 WINE_CONFIG_PROGRAM(start,,[install,po])
2960 WINE_CONFIG_PROGRAM(svchost,,[install])
2961 WINE_CONFIG_PROGRAM(taskkill,,[install,po])
2962 WINE_CONFIG_PROGRAM(taskmgr,,[install,po])
2963 WINE_CONFIG_PROGRAM(termsv,,[install])
2964 WINE_CONFIG_PROGRAM(uninstaller,,[install,po])
2965 WINE_CONFIG_PROGRAM(unlodctr,,[install])
2966 WINE_CONFIG_PROGRAM(view,,[install,po])
2967 WINE_CONFIG_PROGRAM(wineboot,,[install,installbin,manpage,po])
2968 WINE_CONFIG_PROGRAM(winebrowser,,[install])
2969 WINE_CONFIG_PROGRAM(winecfg,,[install,installbin,manpage,po])
2970 WINE_CONFIG_PROGRAM(wineconsole,,[install,installbin,manpage,po])
2971 WINE_CONFIG_PROGRAM(winedbg,,[install,installbin,manpage,po])
2972 WINE_CONFIG_PROGRAM(winedevice,,[install])
2973 WINE_CONFIG_PROGRAM(winefile,,[install,installbin,manpage,po])
2974 WINE_CONFIG_PROGRAM(winemenubuilder,,[install])
2975 WINE_CONFIG_PROGRAM(winemine,,[install,installbin,manpage,po])
2976 WINE_CONFIG_PROGRAM(winemsibuilder,,[install])
2977 WINE_CONFIG_PROGRAM(winepath,,[install,installbin,manpage])
2978 WINE_CONFIG_PROGRAM(winetest)
2979 WINE_CONFIG_PROGRAM(winevdm,enable_win16,[install])
2980 WINE_CONFIG_PROGRAM(winhelp.exe16,enable_win16,[install])
2981 WINE_CONFIG_PROGRAM(winhlp32,,[install,po])
2982 WINE_CONFIG_PROGRAM(winoldap.mod16,enable_win16,[install])
2983 WINE_CONFIG_PROGRAM(winver,,[install])
2984 WINE_CONFIG_PROGRAM(wmic,,[install])
2985 WINE_CONFIG_PROGRAM(wordpad,,[install,po])
2986 WINE_CONFIG_PROGRAM(write,,[install,po])
2987 WINE_CONFIG_PROGRAM(wscript,,[install])
2988 WINE_CONFIG_TEST(programs/wscript/tests)
2989 WINE_CONFIG_PROGRAM(xcopy,,[install,po])
2990 WINE_CONFIG_MAKEFILE([server],,[install-lib,manpage])
2991 WINE_CONFIG_TOOL(tools,[install-dev,install-lib,manpage])
2992 WINE_CONFIG_TOOL(tools/widl,[install-dev,manpage])
2993 WINE_CONFIG_TOOL(tools/winebuild,[install-dev,manpage])
2994 WINE_CONFIG_TOOL(tools/winedump,[install-dev,manpage])
2995 WINE_CONFIG_TOOL(tools/winegcc,[install-dev,manpage])
2996 WINE_CONFIG_TOOL(tools/wmc,[install-dev,manpage])
2997 WINE_CONFIG_TOOL(tools/wrc,[install-dev,manpage])
2998
2999 AC_SUBST([LINGUAS],["\
3000 ar \
3001 bg \
3002 ca \
3003 cs \
3004 da \
3005 de \
3006 el \
3007 en \
3008 en_US \
3009 eo \
3010 es \
3011 fa \
3012 fi \
3013 fr \
3014 he \
3015 hi \
3016 hu \
3017 it \
3018 ja \
3019 ko \
3020 lt \
3021 ml \
3022 nb_NO \
3023 nl \
3024 or \
3025 pa \
3026 pl \
3027 pt_BR \
3028 pt_PT \
3029 rm \
3030 ro \
3031 ru \
3032 sk \
3033 sl \
3034 sr_RS@cyrillic \
3035 sr_RS@latin \
3036 sv \
3037 te \
3038 th \
3039 tr \
3040 uk \
3041 wa \
3042 zh_CN \
3043 zh_TW"])
3044
3045 dnl End of auto-generated output commands
3046
3047 AC_CONFIG_COMMANDS([Makefile], [wine_fn_output_makefile Makefile],
3048 [wine_fn_output_makefile ()
3049 {
3050     cat Make.tmp - <<\_WINE_EOF >\$tmp/makefile && mv -f \$tmp/makefile \$[]1 && rm -f Make.tmp && return
3051 $ALL_MAKEFILE_DEPENDS
3052 _WINE_EOF
3053     AS_ERROR([could not create Makefile])
3054 }])
3055
3056 AC_CONFIG_FILES([Make.tmp:Make.vars.in:Makefile.in])
3057
3058 dnl Some final makefile rules
3059
3060 if test "x$enable_maintainer_mode" = xyes
3061 then
3062     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3063 [\$(srcdir)/configure: configure.ac aclocal.m4
3064         cd \$(srcdir) && autoconf --warnings=all
3065 \$(srcdir)/include/config.h.in: include/stamp-h.in
3066 \$(srcdir)/include/stamp-h.in: configure.ac aclocal.m4
3067         cd \$(srcdir) && autoheader --warnings=all
3068         @echo timestamp > \$[@]])
3069 fi
3070
3071 if test "x$with_gettextpo" = xyes
3072 then
3073     test "$srcdir" = . || AC_MSG_ERROR([Rebuilding po files is not supported for out of tree builds.])
3074     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3075 [ALL_POT_FILES =$ALL_POT_FILES
3076 \$(LINGUAS:%=po/%.po): \$(srcdir)/po/wine.pot
3077         msgmerge -q \$[@] \$(srcdir)/po/wine.pot | msgattrib --no-obsolete -o \$[@].new && mv \$[@].new \$[@]
3078 \$(srcdir)/po/wine.pot: \$(ALL_POT_FILES)
3079         msgcat -o \$[@] \$(ALL_POT_FILES)])
3080 fi
3081
3082 if test "$MSGFMT" != false
3083 then
3084     AC_SUBST([PORCFLAGS],["--po-dir=\$(top_builddir)/po"])
3085     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],[__builddeps__: \$(ALL_MO_FILES)])
3086 else
3087     LINGUAS=
3088 fi
3089
3090 if test "x$enable_tools" != xno
3091 then
3092     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3093 [\$(MAKEDEP): tools/Makefile
3094 clean:: __clean__
3095         \$(RM) tools/makedep\$(EXEEXT)])
3096 fi
3097
3098 if test -n "$with_wine64"
3099 then
3100 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3101 [all: fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader
3102 fonts server tools:
3103         \$(RM) \$[@] && \$(LN_S) $with_wine64/\$[@] \$[@]
3104 $with_wine64/loader/wine:
3105         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine \$[@]
3106 $with_wine64/loader/wine-preloader:
3107         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine-preloader \$[@]
3108 clean::
3109         \$(RM) fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader])
3110 fi
3111
3112 AC_OUTPUT
3113
3114 if test "$no_create" = "yes"
3115 then
3116   exit 0
3117 fi
3118
3119 WINE_PRINT_MESSAGES
3120
3121 echo "
3122 $as_me: Finished.  Do '${ac_make}' to compile Wine.
3123 " >&AS_MESSAGE_FD
3124
3125 dnl Local Variables:
3126 dnl comment-start: "dnl "
3127 dnl comment-end: ""
3128 dnl comment-start-skip: "\\bdnl\\b\\s *"
3129 dnl compile-command: "autoreconf --warnings=all"
3130 dnl End: