| blob | 8c2a857bf1f6a51f74bb98a625407d7f72d941c5 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION)
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 dnl Default values
16 LIBEXT=so # library type .so or .a
18 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
19 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
20 AC_ARG_ENABLE(opengl,AC_HELP_STRING([--enable-opengl],[force usage of OpenGL even if the latter is thread-safe via pthread]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(OPTIONS)
25 if test "x$enable_debug" = "xno"
26 then
27 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
32 fi
34 dnl **** Check for some programs ****
36 AC_CANONICAL_HOST
37 AC_PROG_MAKE_SET
38 AC_PROG_CC
39 AC_PROG_CPP
41 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
42 [if test -z "$with_wine_tools"; then
43 if test "$cross_compiling" = "yes"; then
44 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
45 else
46 wine_cv_toolsdir="\$(TOPOBJDIR)"
47 fi
48 elif test -d "$with_wine_tools/tools/winebuild"; then
49 case $with_wine_tools in
50 /*) wine_cv_toolsdir="$with_wine_tools" ;;
51 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
52 esac
53 else
54 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
55 fi])
56 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
58 AC_PATH_XTRA
59 AC_PROG_YACC
60 AC_PROG_LEX
62 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
63 dnl **** without one present.
64 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
65 if test "$XYACC" = "none"
66 then
67 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
68 fi
69 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
70 if test "$XLEX" = "none"
71 then
72 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
73 fi
75 AC_CHECK_TOOL(LD,ld,ld)
76 AC_CHECK_TOOL(AR,ar,ar)
77 AC_PROG_RANLIB
78 AC_CHECK_TOOL(STRIP,strip,strip)
79 AC_CHECK_TOOL(WINDRES,windres,false)
80 AC_PROG_INSTALL
81 AC_PROG_LN_S
82 WINE_PROG_LN
83 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
84 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
86 dnl Check for lint
87 AC_CHECK_PROGS(LINT, lclint lint)
88 if test "$LINT" = "lint"
89 then
90 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
91 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
92 fi
93 AC_SUBST(LINT)
94 AC_SUBST(LINTFLAGS)
96 dnl **** Check for some libraries ****
98 dnl Check for -lm
99 AC_CHECK_LIB(m,sqrt)
100 dnl Check for -li386 for NetBSD and OpenBSD
101 AC_CHECK_LIB(i386,i386_set_ldt)
102 dnl Check for -lossaudio for NetBSD
103 AC_CHECK_LIB(ossaudio,_oss_ioctl)
104 dnl Check for -lw for Solaris
105 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
106 dnl Check for -lnsl for Solaris
107 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
108 dnl Check for -lsocket for Solaris
109 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
110 dnl Check for -lresolv for Solaris
111 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
112 dnl Check for -lxpg4 for FreeBSD
113 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
114 dnl Check for -lmmap for OS/2
115 AC_CHECK_LIB(mmap,mmap)
117 JPEGLIB=""
118 AC_SUBST(JPEGLIB)
119 AC_CHECK_HEADERS(jpeglib.h,
120 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
121 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
122 JPEGLIB="-ljpeg"
123 )
124 )
127 AC_SUBST(XLIB)
128 AC_SUBST(XFILES)
129 XFILES=""
130 AC_SUBST(OPENGLFILES)
131 OPENGLFILES=""
132 AC_SUBST(GLU32FILES)
133 GLU32FILES=""
134 if test "$have_x" = "yes"
135 then
136 XLIB="-lXext -lX11"
137 ac_save_CPPFLAGS="$CPPFLAGS"
138 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
140 dnl *** All of the following tests require X11/Xlib.h
141 AC_CHECK_HEADERS(X11/Xlib.h,
142 [
143 dnl *** Check for X keyboard extension
144 AC_CHECK_HEADERS(X11/XKBlib.h,
145 [ dnl *** If X11/XKBlib.h exists...
146 AC_CHECK_LIB(X11, XkbQueryExtension,
147 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
148 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
149 ],
150 AC_MSG_WARN([[Xkb extension not found, Wine will be built without it]]),
151 [#include <X11/Xlib.h>])
153 dnl *** Check for X Shm extension
154 AC_CHECK_HEADERS(X11/extensions/XShm.h,
155 [ dnl *** If X11/extensions/XShm.h exists...
156 AC_CHECK_LIB(Xext, XShmQueryExtension,
157 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
158 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
159 ],
160 AC_MSG_WARN([[XShm extension not found, Wine will be built without it]]),
161 [#include <X11/Xlib.h>])
163 dnl *** Check for Xutil
164 AC_CHECK_HEADERS(X11/Xutil.h,,,
165 [#include <X11/Xlib.h>])
167 dnl *** Check for X shape extension
168 AC_CHECK_HEADERS(X11/extensions/shape.h,
169 [ dnl *** If X11/extensions/shape.h exists...
170 AC_CHECK_LIB(Xext,XShapeQueryExtension,
171 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
172 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
173 ],
174 AC_MSG_WARN([[XShape extension not found, Wine will be built without it]]),
175 [#include <X11/Xlib.h>
176 #ifdef HAVE_X11_XUTIL_H
177 # include <X11/Xutil.h>
178 #endif])
180 dnl *** Check for XFree86 DGA / DGA 2.0 extension
181 AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
182 [ dnl *** If X11/extensions/xf86dga.h exists, check
183 dnl *** for XDGAQueryExtension()...
184 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
185 [ dnl *** If found...
186 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
187 [Define if you have the Xxf86dga library version 2])
188 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
189 ],
190 [ dnl *** If not found, look for XF86DGAQueryExtension()
191 dnl *** instead (DGA 2.0 not found)...
192 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
193 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
194 [Define if you have the Xxf86dga library version 1])
195 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
196 ],,
197 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
198 )
199 ],
200 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
201 )
202 ],
203 AC_MSG_WARN([[DGA extension not found, Wine will be built without it]]),
204 [#include <X11/Xlib.h>])
206 dnl *** Check for XFree86 VMODE extension
207 AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
208 [ dnl *** If X11/extensions/xf86vmode.h exists...
209 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
210 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
211 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
212 ],,
213 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
214 )
215 ],
216 AC_MSG_WARN([[XFree86 VMODE extension not found, Wine will be built without it]]),
217 [#include <X11/Xlib.h>])
219 dnl *** Check for XVideo extension supporting XvImages
220 AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
221 [ dnl *** If X11/extensions/Xvlib.h exists...
222 AC_CHECK_LIB(Xv, XvShmCreateImage,
223 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
224 X_PRE_LIBS="$X_PRE_LIBS -lXv"
225 ],,
226 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
227 )
228 ],
229 AC_MSG_WARN([[XVideo extension not found, Wine will be built without it]]),
230 [#include <X11/Xlib.h>])
232 dnl *** Check for XRender include file
233 AC_CHECK_HEADERS(X11/extensions/Xrender.h,,,[#include <X11/Xlib.h>])
234 ]
235 ) dnl *** End of X11/Xlib.h check
237 dnl Check for the presence of OpenGL
238 if test "x$enable_opengl" != "xno"
239 then
240 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
241 then
242 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
243 This prevents linking to OpenGL. Delete the file and restart configure.])
244 fi
246 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
247 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
248 then
249 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
250 dnl Check for some problems due to old Mesa versions
251 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
252 AC_TRY_COMPILE(
253 [#include <GL/gl.h>],
254 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
255 [wine_cv_opengl_version_OK="yes"],
256 [wine_cv_opengl_version_OK="no"]
257 )
258 )
260 dnl Check for the thread-safety of the OpenGL library
261 AC_CACHE_CHECK([for thread-safe OpenGL version],
262 wine_cv_opengl_version_threadsafe,
263 [saved_libs=$LIBS
264 LIBS="$X_LIBS -lGL"
265 AC_TRY_LINK([],[pthread_getspecific();],
266 [wine_cv_opengl_version_threadsafe="yes"],
267 [wine_cv_opengl_version_threadsafe="no"])
268 LIBS=$saved_libs]
269 )
271 if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o "x$enable_opengl" = "xyes" \)
272 then
273 dnl Check for the presence of the library
274 AC_CHECK_LIB(GL,glXCreateContext,
275 X_PRE_LIBS="$X_PRE_LIBS -lGL"
276 ,,
277 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
279 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
280 then
281 OPENGLFILES='$(OPENGLFILES)'
282 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
284 AC_CHECK_LIB(GL,glXGetProcAddressARB,
285 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
286 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
287 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
289 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
290 then
291 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
292 [AC_TRY_COMPILE([#include <GL/gl.h>
293 #ifdef HAVE_GL_GLEXT_H
294 # include <GL/glext.h>
295 #endif
296 ],
297 [PFNGLCOLORTABLEEXTPROC test_proc;],
298 [wine_cv_extension_prototypes="yes"],
299 [wine_cv_extension_prototypes="no"]
300 )]
301 )
302 if test "$wine_cv_extension_prototypes" = "yes"
303 then
304 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
305 [Define if the OpenGL headers define extension typedefs])
306 fi
307 fi
309 fi
310 dnl Check for GLU32 library.
311 AC_CHECK_LIB(GLU,gluLookAt,
312 [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
313 GLU32FILES='$(GLU32FILES)']
314 ,,
315 $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
316 )
317 fi
318 fi
319 fi
321 CPPFLAGS="$ac_save_CPPFLAGS"
322 XFILES='$(XFILES)'
323 else
324 XLIB=""
325 X_CFLAGS=""
326 X_LIBS=""
327 fi
329 dnl **** Check which curses lib to use ***
330 CURSESLIBS=""
331 if test "x$with_curses" != "xno"
332 then
333 AC_CHECK_HEADERS(ncurses.h,
334 [AC_CHECK_LIB(ncurses,waddch,
335 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
336 CURSESLIBS="-lncurses"],
337 [AC_CHECK_HEADERS(curses.h,
338 [AC_CHECK_LIB(curses,waddch,
339 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
340 CURSESLIBS="-lcurses"])])])])
341 saved_libs="$LIBS"
342 LIBS="$CURSESLIBS $LIBS"
343 AC_CHECK_FUNCS(getbkgd resizeterm)
344 LIBS="$saved_libs"
345 fi
346 AC_SUBST(CURSESLIBS)
348 CUPSLIBS=""
349 dnl **** Check for CUPS ****
350 wine_cv_warn_cups_h=no
351 AC_CHECK_LIB(cups,cupsGetPPD,
352 [AC_CHECK_HEADER(cups/cups.h,
353 [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
354 CUPSLIBS="-lcups"],
355 wine_cv_warn_cups_h=yes)]
356 )
357 AC_SUBST(CUPSLIBS)
359 dnl **** Check for SANE ****
360 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
361 if test "$sane_devel" = "no"
362 then
363 SANELIBS=""
364 SANEINCL=""
365 else
366 SANELIBS="`$sane_devel --libs`"
367 SANEINCL="`$sane_devel --cflags`"
368 ac_save_CPPFLAGS="$CPPFLAGS"
369 ac_save_LIBS="$LIBS"
370 CPPFLAGS="$CPPFLAGS $SANEINCL"
371 LIBS="$LIBS $SANELIBS"
372 AC_CHECK_HEADER(sane/sane.h,
373 [AC_CHECK_LIB(sane,sane_open,
374 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
375 [SANELIBS=""
376 SANEINCL=""])],
377 [SANELIBS=""
378 SANEINCL=""])
379 LIBS="$ac_save_LIBS"
380 CPPFLAGS="$ac_save_CPPFLAGS"
381 fi
382 AC_SUBST(SANELIBS)
383 AC_SUBST(SANEINCL)
385 dnl **** Check for FreeType 2 ****
386 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
387 if test "$ft_lib" = "no"
388 then
389 FREETYPEINCL=""
390 wine_cv_msg_freetype=no
391 else
392 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
393 if test "$ft_devel" = "no"
394 then
395 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
396 if test "$ft_devel2" = "freetype2-config"
397 then
398 ft_devel=$ft_devel2
399 fi
400 fi
401 if test "$ft_devel" = "no"
402 then
403 FREETYPEINCL=""
404 wine_cv_msg_freetype=yes
405 else
406 FREETYPEINCL=`$ft_devel --cflags`
407 ac_save_CPPFLAGS="$CPPFLAGS"
408 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
409 AC_CHECK_HEADERS(freetype/freetype.h \
410 freetype/ftglyph.h \
411 freetype/tttables.h \
412 freetype/ftnames.h \
413 freetype/ftsnames.h \
414 freetype/ttnameid.h \
415 freetype/ftoutln.h \
416 freetype/internal/sfnt.h)
417 AC_TRY_CPP([#include <ft2build.h>
418 #include <freetype/fttrigon.h>],
419 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
420 [Define if you have the <freetype/fttrigon.h> header file.])
421 wine_cv_fttrigon=yes],
422 wine_cv_fttrigon=no)
423 CPPFLAGS="$ac_save_CPPFLAGS"
424 dnl Check that we have at least freetype/freetype.h
425 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
426 then
427 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
428 wine_cv_msg_freetype=no
429 else
430 FREETYPEINCL=""
431 wine_cv_msg_freetype=yes
432 fi
433 fi
434 fi
435 AC_SUBST(FREETYPEINCL)
437 dnl **** Check for parport (currently Linux only) ****
438 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
439 AC_TRY_COMPILE(
440 [#include <linux/ppdev.h>],
441 [ioctl (1,PPCLAIM,0)],
442 [ac_cv_c_ppdev="yes"],
443 [ac_cv_c_ppdev="no"])
444 )
445 if test "$ac_cv_c_ppdev" = "yes"
446 then
447 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
448 fi
450 dnl **** Check for IPX (currently Linux only) ****
451 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
452 AC_TRY_COMPILE(
453 [#include <sys/socket.h>
454 #include <netipx/ipx.h>],
455 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
456 [ac_cv_c_ipx_gnu="yes"],
457 [ac_cv_c_ipx_gnu="no"])
458 )
459 if test "$ac_cv_c_ipx_gnu" = "yes"
460 then
461 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
462 fi
464 if test "$ac_cv_c_ipx_gnu" = "no"
465 then
466 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
467 AC_TRY_COMPILE(
468 [#include <sys/socket.h>
469 #include <asm/types.h>
470 #include <linux/ipx.h>],
471 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
472 [ac_cv_c_ipx_linux="yes"],
473 [ac_cv_c_ipx_linux="no"])
474 )
475 if test "$ac_cv_c_ipx_linux" = "yes"
476 then
477 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
478 fi
479 fi
481 dnl **** Check for Open Sound System ****
482 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
484 AC_CACHE_CHECK([for Open Sound System],
485 ac_cv_c_opensoundsystem,
486 AC_TRY_COMPILE([
487 #if defined(HAVE_SYS_SOUNDCARD_H)
488 #include <sys/soundcard.h>
489 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
490 #include <machine/soundcard.h>
491 #elif defined(HAVE_SOUNDCARD_H)
492 #include <soundcard.h>
493 #endif
494 ],[
496 /* check for one of the Open Sound System specific SNDCTL_ defines */
497 #if !defined(SNDCTL_DSP_STEREO)
498 #error No open sound system
499 #endif
500 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
502 if test "$ac_cv_c_opensoundsystem" = "yes"
503 then
504 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
505 fi
507 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
508 ac_cv_c_opensoundsystem_midi,
509 AC_TRY_COMPILE([
510 #if defined(HAVE_SYS_SOUNDCARD_H)
511 #include <sys/soundcard.h>
512 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
513 #include <machine/soundcard.h>
514 #elif defined(HAVE_SOUNDCARD_H)
515 #include <soundcard.h>
516 #endif
517 ],[
519 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
520 #if !defined(SNDCTL_SEQ_SYNC)
521 #error No open sound system MIDI interface
522 #endif
523 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
525 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
526 then
527 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
528 fi
530 dnl **** Check for aRts Sound Server ****
531 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
532 AC_CACHE_CHECK([for aRts Sound server],
533 ac_cv_c_artsserver,
534 if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
535 then
536 ac_cv_c_artsserver=no
537 else
538 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
539 ARTSC_LIBS=`$ARTSCCONFIG --libs`
540 ac_cv_c_artsserver=no
541 save_CFLAGS="$CFLAGS"
542 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
543 AC_TRY_COMPILE([
544 #include <artsc.h>
545 ],[
546 arts_stream_t stream;
547 ],[
548 ac_cv_c_artsserver=yes
549 ])
550 CFLAGS="$save_CFLAGS"
551 fi)
553 if test "$ac_cv_c_artsserver" = "yes"
554 then
555 AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
556 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
558 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
559 fi
561 dnl **** Check for ALSA ****
562 AC_SUBST(ALSALIBS,"")
563 AC_CHECK_HEADERS(sys/asoundlib.h)
564 if test "$ac_cv_header_sys_asoundlib_h" = "yes"
565 then
566 AC_CHECK_LIB(asound,snd_pcm_open,
567 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
568 ALSALIBS="-lasound")
569 fi
571 dnl **** Check for broken glibc mmap64 ****
573 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
574 AC_TRY_RUN([
575 #define _FILE_OFFSET_BITS 64
576 #include <stdio.h>
577 #include <unistd.h>
578 #include <fcntl.h>
579 #include <sys/mman.h>
580 #include <errno.h>
582 int main(int argc,char **argv) {
583 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
584 if (fd == -1) exit(1);
586 unlink("conftest.map");
588 write(fd,"test",4);
590 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
591 (errno == EINVAL)
592 ) {
593 exit(1);
594 }
595 close(fd);
596 fprintf(stderr,"success!\n");
597 exit(0);
598 }
600 ],
601 ac_cv_mmap64_works="yes",
602 ac_cv_mmap64_works="no",
603 ac_cv_mmap64_works="no") )
605 if test "$ac_cv_mmap64_works" = "yes"
606 then
607 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
608 fi
610 dnl **** Check for gcc strength-reduce bug ****
612 if test "x${GCC}" = "xyes"
613 then
614 CFLAGS="$CFLAGS -Wall"
615 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
616 AC_TRY_RUN([
617 int L[[4]] = {0,1,2,3};
618 int main(void) {
619 static int Array[[3]];
620 unsigned int B = 3;
621 int i;
622 for(i=0; i<B; i++) Array[[i]] = i - 3;
623 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
624 L[[i]] = 4;
626 exit( Array[[1]] != -2 || L[[2]] != 3);
627 }],
628 ac_cv_c_gcc_strength_bug="no",
629 ac_cv_c_gcc_strength_bug="yes",
630 ac_cv_c_gcc_strength_bug="yes") )
631 if test "$ac_cv_c_gcc_strength_bug" = "yes"
632 then
633 CFLAGS="$CFLAGS -fno-strength-reduce"
634 fi
636 dnl Check for -mpreferred-stack-boundary
637 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
638 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
639 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
640 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
641 then
642 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
643 fi
644 fi
646 dnl **** Check how to define a function in assembly code ****
648 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
649 WINE_TRY_ASM_LINK(
650 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
651 ac_cv_asm_func_def=".def",
652 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
653 ac_cv_asm_func_def=".type @function",
654 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
655 ac_cv_asm_func_def=".type 2",
656 ac_cv_asm_func_def="unknown")])]))
658 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
659 case "$ac_cv_asm_func_def" in
660 ".def")
661 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
662 ".type @function")
663 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
664 ".type 2")
665 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
666 *)
667 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
668 esac
670 dnl **** Check for underscore on external symbols ****
672 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
673 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
674 [extern int ac_test;],
675 [if (ac_test) return 1],
676 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
678 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
679 if test "$ac_cv_c_extern_prefix" = "yes"
680 then
681 AC_DEFINE([__ASM_NAME(name)], ["_" name])
682 else
683 AC_DEFINE([__ASM_NAME(name)], [name])
684 fi
686 dnl **** Check whether stdcall symbols need to be decorated ****
688 AC_CACHE_CHECK([whether stdcall symbols need to be decorated], ac_cv_c_stdcall_decoration,
689 WINE_TRY_ASM_LINK(["\t.globl _ac_test@0\n_ac_test@0:\n\t.globl ac_test@0\nac_test@0:"],
690 [extern void __attribute__((__stdcall__)) ac_test(void);],
691 [ac_test()],
692 ac_cv_c_stdcall_decoration="yes",ac_cv_c_stdcall_decoration="no"))
693 if test "$ac_cv_c_stdcall_decoration" = "yes"
694 then
695 AC_DEFINE(NEED_STDCALL_DECORATION, 1, [Define if stdcall symbols need to be decorated])
696 fi
698 dnl **** Check for .string in assembler ****
700 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
701 WINE_TRY_ASM_LINK([".string \"test\""],,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
702 if test "$ac_cv_c_asm_string" = "yes"
703 then
704 AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
705 fi
707 dnl **** Check for working dll ****
709 LDSHARED=""
710 LDDLLFLAGS=""
711 DLLIBS=""
713 case $host_os in
714 cygwin*|mingw32*)
715 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
716 if test "$DLLWRAP" = "false"; then
717 LIBEXT="a"
718 else
719 dnl FIXME - check whether dllwrap works correctly...
720 LIBEXT="dll"
721 fi
722 ;;
723 *)
724 AC_CHECK_HEADERS(dlfcn.h,
725 [AC_CHECK_FUNCS(dlopen,,
726 [AC_CHECK_LIB(dl,dlopen,
727 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
728 DLLIBS="-ldl"],
729 [LIBEXT="a"])])],
730 [LIBEXT="a"])
732 if test "$LIBEXT" = "so"
733 then
734 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
735 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
736 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
737 if test "$ac_cv_c_dll_gnuelf" = "yes"
738 then
739 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
740 LDDLLFLAGS="-Wl,-Bsymbolic"
741 else
742 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
743 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
744 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
745 if test "$ac_cv_c_dll_unixware" = "yes"
746 then
747 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
748 LDDLLFLAGS="-Wl,-B,symbolic"
749 fi
750 fi
751 fi
752 ;;
753 esac
755 if test "$LIBEXT" = "a"; then
756 AC_MSG_ERROR(
757 [could not find a way to build shared libraries.
758 It is currently not possible to build Wine without shared library
759 (.so) support to allow transparent switch between .so and .dll files.
760 If you are using Linux, you will need a newer binutils.]
761 )
762 fi
764 DLLFLAGS=""
766 if test "$LIBEXT" = "so"; then
767 DLLFLAGS="-fPIC"
768 DLLEXT=".so"
769 elif test "$LIBEXT" = "dll"; then
770 #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
771 DLLEXT=""
772 fi
774 case $build_os in
775 cygwin*|mingw32*)
776 LDPATH="PATH=\"\$(TOOLSDIR)/library:\$(TOOLSDIR)/unicode:\$\$PATH\"" ;;
777 *)
778 LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/library:\$(TOOLSDIR)/unicode:\$\$LD_LIBRARY_PATH\"" ;;
779 esac
781 AC_SUBST(DLLIBS)
782 AC_SUBST(DLLFLAGS)
783 AC_SUBST(DLLEXT)
784 AC_SUBST(LDSHARED)
785 AC_SUBST(LDDLLFLAGS)
786 AC_SUBST(LIBEXT)
787 AC_SUBST(LDPATH)
789 dnl **** Get the soname for libraries that we load dynamically ****
791 if test "$LIBEXT" = "so"
792 then
793 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
794 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
795 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
796 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
797 fi
800 dnl **** Check for reentrant libc ****
802 wine_cv_libc_reentrant=no
803 dnl Linux style errno location
804 WINE_CHECK_ERRNO([__errno_location], [wine_cv_libc_reentrant=__errno_location],
805 dnl FreeBSD style errno location
806 WINE_CHECK_ERRNO([__error], [wine_cv_libc_reentrant=__error],
807 dnl Solaris style errno location
808 WINE_CHECK_ERRNO([___errno], [wine_cv_libc_reentrant=___errno],
809 dnl UnixWare style errno location
810 WINE_CHECK_ERRNO([__thr_errno], [wine_cv_libc_reentrant=__thr_errno],
811 dnl NetBSD style errno location
812 WINE_CHECK_ERRNO([__errno], [wine_cv_libc_reentrant=__errno])
813 ))))
815 if test "$wine_cv_libc_reentrant" != "no"
816 then
817 AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
818 [Define to the name of the function returning errno for reentrant libc])
819 fi
821 dnl **** Check for reentrant X libraries ****
822 dnl
823 dnl This may fail to determine whether X libraries are reentrant if
824 dnl AC_PATH_XTRA does not set x_libraries.
826 if test "$have_x" = "yes"
827 then
828 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
829 [libX11_check=none
830 for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
831 if test -r $dir/libX11.so; then
832 libX11_check="-D $dir/libX11.so"
833 break
834 fi
835 if test -r $dir/libX11.a; then
836 libX11_check="$dir/libX11.a"
837 break
838 fi
839 done
840 if test "$libX11_check" != "none"; then
841 if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
842 then
843 wine_cv_x_reentrant=yes
844 else
845 wine_cv_x_reentrant=no
846 fi
847 else
848 wine_cv_x_reentrant=unknown
849 fi])
850 fi
852 dnl **** Check for functions ****
854 AC_FUNC_ALLOCA()
855 AC_CHECK_FUNCS(\
856 __libc_fork \
857 _lwp_create \
858 _pclose \
859 _popen \
860 _snprintf \
861 _stricmp \
862 _strnicmp \
863 chsize \
864 clone \
865 ecvt \
866 finite \
867 fpclass \
868 ftruncate \
869 ftruncate64 \
870 getnetbyaddr \
871 getnetbyname \
872 getpagesize \
873 getprotobyname \
874 getprotobynumber \
875 getpwuid \
876 getservbyport \
877 getsockopt \
878 inet_network \
879 lseek64 \
880 lstat \
881 memmove \
882 mmap \
883 pclose \
884 popen \
885 pread \
886 pwrite \
887 rfork \
888 select \
889 sendmsg \
890 settimeofday \
891 sigaltstack \
892 snprintf \
893 statfs \
894 strcasecmp \
895 strerror \
896 strncasecmp \
897 tcgetattr \
898 timegm \
899 usleep \
900 vfscanf \
901 wait4 \
902 waitpid \
903 )
905 dnl **** Check for header files ****
907 AC_CHECK_HEADERS(\
908 arpa/inet.h \
909 arpa/nameser.h \
910 direct.h \
911 elf.h \
912 float.h \
913 ieeefp.h \
914 io.h \
915 libio.h \
916 libutil.h \
917 link.h \
918 linux/cdrom.h \
919 linux/hdreg.h \
920 linux/input.h \
921 linux/joystick.h \
922 linux/major.h \
923 linux/param.h \
924 linux/serial.h \
925 linux/ucdrom.h \
926 netdb.h \
927 netinet/in.h \
928 netinet/in_systm.h \
929 netinet/tcp.h \
930 pty.h \
931 pwd.h \
932 sched.h \
933 scsi/sg.h \
934 socket.h \
935 stdint.h \
936 strings.h \
937 sys/cdio.h \
938 sys/errno.h \
939 sys/file.h \
940 sys/filio.h \
941 sys/inttypes.h \
942 sys/ioctl.h \
943 sys/ipc.h \
944 sys/link.h \
945 sys/lwp.h \
946 sys/mman.h \
947 sys/modem.h \
948 sys/mount.h \
949 sys/msg.h \
950 sys/param.h \
951 sys/ptrace.h \
952 sys/reg.h \
953 sys/shm.h \
954 sys/signal.h \
955 sys/socket.h \
956 sys/sockio.h \
957 sys/statfs.h \
958 sys/strtio.h \
959 sys/syscall.h \
960 sys/sysctl.h \
961 sys/time.h \
962 sys/user.h \
963 sys/v86.h \
964 sys/v86intr.h \
965 sys/vfs.h \
966 sys/vm86.h \
967 sys/wait.h \
968 syscall.h \
969 termios.h \
970 ucontext.h \
971 unistd.h \
972 )
973 AC_HEADER_STAT()
975 dnl *** Check for net/if.h
976 AC_CHECK_HEADERS(net/if.h,,,
977 [#if HAVE_SYS_TYPES_H
978 # include <sys/types.h>
979 #endif
980 #if HAVE_SYS_SOCKET_H
981 # include <sys/socket.h>
982 #endif])
984 dnl *** Check for netinet/ip.h
985 AC_CHECK_HEADERS(netinet/ip.h,,,
986 [#if HAVE_SYS_SOCKET_H
987 # include <sys/socket.h>
988 #endif
989 #if HAVE_NETINET_IN_SYSTM_H
990 # include <netinet/in_systm.h>
991 #endif])
993 dnl *** Check for resolv.h
994 AC_CHECK_HEADERS(resolv.h,,,
995 [#if HAVE_SYS_SOCKET_H
996 # include <sys/socket.h>
997 #endif])
999 dnl **** Check for types ****
1001 AC_C_CONST
1002 AC_C_INLINE
1003 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1004 AC_CHECK_SIZEOF(long long,0)
1006 AC_CACHE_CHECK([whether linux/input.h is for real],
1007 wine_cv_linux_input_h,
1008 AC_TRY_COMPILE([
1009 #include <linux/input.h>
1010 ] , [
1011 int foo = EVIOCGBIT(EV_ABS,42);
1012 int bar = BTN_PINKIE;
1013 int fortytwo = 42;
1014 ],
1015 wine_cv_linux_input_h=yes,
1016 wine_cv_linux_input_h=no,
1017 no
1018 )
1019 )
1020 if test "$wine_cv_linux_input_h" = "yes"
1021 then
1022 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1023 [Define if we have linux/input.h AND it contains the INPUT event API])
1024 fi
1027 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1028 wine_cv_linux_gethostbyname_r_6,
1029 AC_TRY_COMPILE([
1030 #include <netdb.h>
1031 ], [
1032 char *name=NULL;
1033 struct hostent he;
1034 struct hostent *result;
1035 char *buf=NULL;
1036 int bufsize=0;
1037 int res,errnr;
1038 char *addr=NULL;
1039 int addrlen=0;
1040 int addrtype=0;
1041 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1042 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1043 ],
1044 wine_cv_linux_gethostbyname_r_6=yes,
1045 wine_cv_linux_gethostbyname_r_6=no
1046 )
1047 )
1048 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1049 then
1050 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1051 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1052 fi
1054 if test "$ac_cv_header_linux_joystick_h" = "yes"
1055 then
1056 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1057 wine_cv_linux_joystick_22_api,
1058 AC_TRY_COMPILE([
1059 #include <sys/ioctl.h>
1060 #include <linux/joystick.h>
1062 struct js_event blub;
1063 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1064 #error "no 2.2 header"
1065 #endif
1066 ],/*empty*/,
1067 wine_cv_linux_joystick_22_api=yes,
1068 wine_cv_linux_joystick_22_api=no,
1069 wine_cv_linux_joystick_22_api=no
1070 )
1071 )
1072 if test "$wine_cv_linux_joystick_22_api" = "yes"
1073 then
1074 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1075 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1076 fi
1077 fi
1079 dnl **** statfs checks ****
1081 if test "$ac_cv_header_sys_vfs_h" = "yes"
1082 then
1083 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1084 wine_cv_sys_vfs_has_statfs,
1085 AC_TRY_COMPILE([
1086 #include <sys/types.h>
1087 #ifdef HAVE_SYS_PARAM_H
1088 # include <sys/param.h>
1089 #endif
1090 #include <sys/vfs.h>
1091 ],[
1092 struct statfs stfs;
1094 memset(&stfs,0,sizeof(stfs));
1095 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1096 )
1097 )
1098 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1099 then
1100 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1101 [Define if the struct statfs is defined by <sys/vfs.h>])
1102 fi
1103 fi
1105 if test "$ac_cv_header_sys_statfs_h" = "yes"
1106 then
1107 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1108 wine_cv_sys_statfs_has_statfs,
1109 AC_TRY_COMPILE([
1110 #include <sys/types.h>
1111 #ifdef HAVE_SYS_PARAM_H
1112 # include <sys/param.h>
1113 #endif
1114 #include <sys/statfs.h>
1115 ],[
1116 struct statfs stfs;
1117 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1118 )
1119 )
1120 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1121 then
1122 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1123 [Define if the struct statfs is defined by <sys/statfs.h>])
1124 fi
1125 fi
1127 if test "$ac_cv_header_sys_mount_h" = "yes"
1128 then
1129 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1130 wine_cv_sys_mount_has_statfs,
1131 AC_TRY_COMPILE([
1132 #include <sys/types.h>
1133 #ifdef HAVE_SYS_PARAM_H
1134 # include <sys/param.h>
1135 #endif
1136 #include <sys/mount.h>
1137 ],[
1138 struct statfs stfs;
1139 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1140 )
1141 )
1142 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1143 then
1144 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1145 [Define if the struct statfs is defined by <sys/mount.h>])
1146 fi
1147 fi
1149 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1151 WINE_CHECK_STRUCT_MEMBER(statfs,f_bfree,
1152 [#include <sys/types.h>
1153 #ifdef HAVE_SYS_PARAM_H
1154 # include <sys/param.h>
1155 #endif
1156 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1157 # include <sys/mount.h>
1158 #else
1159 # ifdef STATFS_DEFINED_BY_SYS_VFS
1160 # include <sys/vfs.h>
1161 # else
1162 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1163 # include <sys/statfs.h>
1164 # endif
1165 # endif
1166 #endif],
1167 [AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])])
1169 WINE_CHECK_STRUCT_MEMBER(statfs,f_bavail,
1170 [#include <sys/types.h>
1171 #ifdef HAVE_SYS_PARAM_H
1172 # include <sys/param.h>
1173 #endif
1174 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1175 # include <sys/mount.h>
1176 #else
1177 # ifdef STATFS_DEFINED_BY_SYS_VFS
1178 # include <sys/vfs.h>
1179 # else
1180 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1181 # include <sys/statfs.h>
1182 # endif
1183 # endif
1184 #endif],
1185 [AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])])
1187 dnl Check for file descriptor passing with msg_accrights
1188 WINE_CHECK_STRUCT_MEMBER(msghdr,msg_accrights,
1189 [#include <sys/types.h>
1190 #include <sys/socket.h>],
1191 [AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])])
1193 dnl Check for the sa_len member in struct sockaddr
1194 WINE_CHECK_STRUCT_MEMBER(sockaddr,sa_len,
1195 [#include <sys/types.h>
1196 #include <sys/socket.h>],
1197 [AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])])
1199 dnl Check for the sun_len member in struct sockaddr_un
1200 WINE_CHECK_STRUCT_MEMBER(sockaddr_un,sun_len,
1201 [#include <sys/types.h>
1202 #include <sys/socket.h>
1203 #include <sys/un.h>],
1204 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])])
1206 dnl *** check for the need to define __i386__
1208 case $host_cpu in
1209 *i[3456789]86* )
1210 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1211 AC_EGREP_CPP(yes,[#ifndef __i386__
1212 yes
1213 #endif],
1214 ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1215 ;;
1216 esac
1217 if test "$ac_cv_cpp_def_i386" = "yes"
1218 then
1219 CFLAGS="$CFLAGS -D__i386__"
1220 LINTFLAGS="$LINTFLAGS -D__i386__"
1221 fi
1223 dnl *** check for the need to define __sparc__
1225 case $host_cpu in
1226 *sparc* )
1227 AC_CACHE_CHECK([whether we need to define __sparc__],ac_cv_cpp_def_sparc,
1228 AC_EGREP_CPP(yes,[#ifndef __sparc__
1229 yes
1230 #endif],
1231 ac_cv_cpp_def_sparc="yes", ac_cv_cpp_def_sparc="no"))
1232 ;;
1233 esac
1234 if test "$ac_cv_cpp_def_sparc" = "yes"
1235 then
1236 CFLAGS="$CFLAGS -D__sparc__"
1237 LINTFLAGS="$LINTFLAGS -D__sparc__"
1238 fi
1240 dnl *** check for the need to define __sun__
1242 case $host_vendor in
1243 *sun* )
1244 AC_CACHE_CHECK([whether we need to define __sun__],ac_cv_cpp_def_sun,
1245 AC_EGREP_CPP(yes,[#ifndef __sun__
1246 yes
1247 #endif],
1248 ac_cv_cpp_def_sun="yes", ac_cv_cpp_def_sun="no"))
1249 ;;
1250 esac
1251 if test "$ac_cv_cpp_def_sun" = "yes"
1252 then
1253 CFLAGS="$CFLAGS -D__sun__"
1254 LINTFLAGS="$LINTFLAGS -D__sun__"
1255 fi
1257 dnl **** Generate output files ****
1259 AH_TOP([#define __WINE_CONFIG_H])
1261 WINE_CONFIG_EXTRA_DIR(controls)
1262 WINE_CONFIG_EXTRA_DIR(dlls/advapi32/tests)
1263 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1264 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1265 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1266 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1267 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1268 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1269 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1270 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1271 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1272 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1273 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1274 WINE_CONFIG_EXTRA_DIR(dlls/gdi/win16drv)
1275 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1276 WINE_CONFIG_EXTRA_DIR(dlls/kernel/tests)
1277 WINE_CONFIG_EXTRA_DIR(dlls/oleaut32/tests)
1278 WINE_CONFIG_EXTRA_DIR(dlls/shlwapi/tests)
1279 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1280 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1281 WINE_CONFIG_EXTRA_DIR(dlls/user/tests)
1282 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1283 WINE_CONFIG_EXTRA_DIR(dlls/wininet/tests)
1284 WINE_CONFIG_EXTRA_DIR(dlls/winsock/tests)
1285 WINE_CONFIG_EXTRA_DIR(files)
1286 WINE_CONFIG_EXTRA_DIR(graphics)
1287 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1288 WINE_CONFIG_EXTRA_DIR(if1632)
1289 WINE_CONFIG_EXTRA_DIR(include/wine)
1290 WINE_CONFIG_EXTRA_DIR(loader)
1291 WINE_CONFIG_EXTRA_DIR(loader/ne)
1292 WINE_CONFIG_EXTRA_DIR(memory)
1293 WINE_CONFIG_EXTRA_DIR(misc)
1294 WINE_CONFIG_EXTRA_DIR(msdos)
1295 WINE_CONFIG_EXTRA_DIR(objects)
1296 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1297 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1298 WINE_CONFIG_EXTRA_DIR(programs/winetest/tests)
1299 WINE_CONFIG_EXTRA_DIR(relay32)
1300 WINE_CONFIG_EXTRA_DIR(scheduler)
1301 WINE_CONFIG_EXTRA_DIR(win32)
1302 WINE_CONFIG_EXTRA_DIR(windows)
1304 MAKE_RULES=Make.rules
1305 AC_SUBST_FILE(MAKE_RULES)
1307 MAKE_DLL_RULES=dlls/Makedll.rules
1308 AC_SUBST_FILE(MAKE_DLL_RULES)
1310 MAKE_PROG_RULES=programs/Makeprog.rules
1311 AC_SUBST_FILE(MAKE_PROG_RULES)
1313 AC_CONFIG_FILES([
1314 Make.rules
1315 dlls/Makedll.rules
1316 programs/Makeprog.rules
1317 Makefile
1318 debugger/Makefile
1319 dlls/Makefile
1320 dlls/advapi32/Makefile
1321 dlls/avicap32/Makefile
1322 dlls/avifil32/Makefile
1323 dlls/comcat/Makefile
1324 dlls/comctl32/Makefile
1325 dlls/commdlg/Makefile
1326 dlls/crtdll/Makefile
1327 dlls/crypt32/Makefile
1328 dlls/d3d8/Makefile
1329 dlls/dciman32/Makefile
1330 dlls/ddraw/Makefile
1331 dlls/devenum/Makefile
1332 dlls/dinput/Makefile
1333 dlls/dinput8/Makefile
1334 dlls/dplay/Makefile
1335 dlls/dplayx/Makefile
1336 dlls/dsound/Makefile
1337 dlls/gdi/Makefile
1338 dlls/glu32/Makefile
1339 dlls/icmp/Makefile
1340 dlls/imagehlp/Makefile
1341 dlls/imm32/Makefile
1342 dlls/kernel/Makefile
1343 dlls/lzexpand/Makefile
1344 dlls/mapi32/Makefile
1345 dlls/mpr/Makefile
1346 dlls/msacm/Makefile
1347 dlls/msacm/imaadp32/Makefile
1348 dlls/msacm/msadp32/Makefile
1349 dlls/msacm/msg711/Makefile
1350 dlls/msacm/winemp3/Makefile
1351 dlls/msdmo/Makefile
1352 dlls/msimg32/Makefile
1353 dlls/msisys/Makefile
1354 dlls/msnet32/Makefile
1355 dlls/msrle32/Makefile
1356 dlls/msvcrt/Makefile
1357 dlls/msvcrt20/Makefile
1358 dlls/msvideo/Makefile
1359 dlls/netapi32/Makefile
1360 dlls/ntdll/Makefile
1361 dlls/odbc32/Makefile
1362 dlls/ole32/Makefile
1363 dlls/oleaut32/Makefile
1364 dlls/olecli/Makefile
1365 dlls/oledlg/Makefile
1366 dlls/olepro32/Makefile
1367 dlls/olesvr/Makefile
1368 dlls/opengl32/Makefile
1369 dlls/psapi/Makefile
1370 dlls/qcap/Makefile
1371 dlls/quartz/Makefile
1372 dlls/rasapi32/Makefile
1373 dlls/richedit/Makefile
1374 dlls/rpcrt4/Makefile
1375 dlls/serialui/Makefile
1376 dlls/setupapi/Makefile
1377 dlls/shdocvw/Makefile
1378 dlls/shell32/Makefile
1379 dlls/shfolder/Makefile
1380 dlls/shlwapi/Makefile
1381 dlls/snmpapi/Makefile
1382 dlls/sti/Makefile
1383 dlls/tapi32/Makefile
1384 dlls/ttydrv/Makefile
1385 dlls/twain/Makefile
1386 dlls/url/Makefile
1387 dlls/urlmon/Makefile
1388 dlls/user/Makefile
1389 dlls/version/Makefile
1390 dlls/win32s/Makefile
1391 dlls/winaspi/Makefile
1392 dlls/winedos/Makefile
1393 dlls/wineps/Makefile
1394 dlls/wininet/Makefile
1395 dlls/winmm/Makefile
1396 dlls/winmm/joystick/Makefile
1397 dlls/winmm/mcianim/Makefile
1398 dlls/winmm/mciavi/Makefile
1399 dlls/winmm/mcicda/Makefile
1400 dlls/winmm/mciseq/Makefile
1401 dlls/winmm/mciwave/Makefile
1402 dlls/winmm/midimap/Makefile
1403 dlls/winmm/wavemap/Makefile
1404 dlls/winmm/winealsa/Makefile
1405 dlls/winmm/winearts/Makefile
1406 dlls/winmm/wineoss/Makefile
1407 dlls/winnls/Makefile
1408 dlls/winsock/Makefile
1409 dlls/winspool/Makefile
1410 dlls/wintrust/Makefile
1411 dlls/wow32/Makefile
1412 dlls/wsock32/Makefile
1413 dlls/x11drv/Makefile
1414 documentation/Makefile
1415 include/Makefile
1416 library/Makefile
1417 miscemu/Makefile
1418 ole/Makefile
1419 programs/Makefile
1420 programs/avitools/Makefile
1421 programs/clock/Makefile
1422 programs/cmdlgtst/Makefile
1423 programs/control/Makefile
1424 programs/expand/Makefile
1425 programs/notepad/Makefile
1426 programs/osversioncheck/Makefile
1427 programs/progman/Makefile
1428 programs/regapi/Makefile
1429 programs/regedit/Makefile
1430 programs/regsvr32/Makefile
1431 programs/regtest/Makefile
1432 programs/uninstaller/Makefile
1433 programs/view/Makefile
1434 programs/wcmd/Makefile
1435 programs/wineconsole/Makefile
1436 programs/winefile/Makefile
1437 programs/winemine/Makefile
1438 programs/winepath/Makefile
1439 programs/winetest/Makefile
1440 programs/winhelp/Makefile
1441 programs/winver/Makefile
1442 server/Makefile
1443 tools/Makefile
1444 tools/widl/Makefile
1445 tools/winapi/Makefile
1446 tools/winebuild/Makefile
1447 tools/winedump/Makefile
1448 tools/wmc/Makefile
1449 tools/wpp/Makefile
1450 tools/wrc/Makefile
1451 tsx11/Makefile
1452 unicode/Makefile])
1454 AC_OUTPUT
1456 if test "$have_x" = "no"
1457 then
1458 echo
1459 echo "*** Warning: X development files not found. Wine will be built without"
1460 echo "*** X support, which currently does not work, and would probably not be"
1461 echo "*** what you want anyway. You will need to install devel packages of"
1462 echo "*** Xlib/Xfree86 at the very least."
1463 fi
1465 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1466 then
1467 echo
1468 echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1469 echo "*** terminal resize support. Consider upgrading ncurses."
1470 fi
1472 if test "$wine_cv_libc_reentrant" = "no"
1473 then
1474 echo
1475 echo "*** Warning: non-reentrant libc detected. Wine will be built without"
1476 echo "*** threading support. Consider upgrading libc to a more recent"
1477 echo "*** reentrant version of libc."
1478 fi
1480 if test "$have_x" = "yes" -a "$wine_cv_x_reentrant" != "yes"
1481 then
1482 echo
1483 echo "*** Warning: non-reentrant X11 library detected. Multi-threaded"
1484 echo "*** applications won't work properly. You should upgrade your X11 library."
1485 fi
1487 if test "$wine_cv_opengl_version_OK" = "no"
1488 then
1489 echo
1490 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1491 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1492 fi
1494 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a "x$enable_opengl" = "x"
1495 then
1496 echo
1497 echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1498 echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1499 echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1500 echo "*** start configure with '--enable-opengl' to force OpenGL support."
1501 fi
1503 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a "x$enable_opengl" = "xyes"
1504 then
1505 echo
1506 echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1507 echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1508 echo "*** support before reporting bugs."
1509 fi
1511 if test "$wine_cv_warn_cups_h" = "yes"
1512 then
1513 echo
1514 echo "*** Note: You have cups runtime libraries, but no development"
1515 echo "*** libraries. Install the cups-devel package or whichever package"
1516 echo "*** contains cups.h to enable CUPS support in Wine."
1517 fi
1519 if test "$wine_cv_msg_freetype" = "yes"
1520 then
1521 echo
1522 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1523 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1524 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1525 echo "*** enable Wine to use TrueType fonts."
1526 fi
1528 echo
1529 echo "Configure finished. Do 'make depend && make' to compile Wine."
1530 echo
1532 dnl Local Variables:
1533 dnl comment-start: "dnl "
1534 dnl comment-end: ""
1535 dnl comment-start-skip: "\\bdnl\\b\\s *"
1536 dnl compile-command: "autoconf"
1537 dnl End: