| blob | 5f2983eb28b8da0f2ddcf230910ef7d21243a0ef |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION)
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 dnl Default values
16 LIBEXT=so # library type .so or .a
18 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
19 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
20 AC_ARG_ENABLE(opengl,AC_HELP_STRING([--enable-opengl],[force usage of OpenGL even if the latter is thread-safe via pthread]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(OPTIONS)
25 if test "x$enable_debug" = "xno"
26 then
27 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
32 fi
34 dnl **** Check for some programs ****
36 AC_CANONICAL_HOST
37 AC_PROG_MAKE_SET
38 AC_PROG_CC
39 AC_PROG_CPP
41 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
42 [if test -z "$with_wine_tools"; then
43 if test "$cross_compiling" = "yes"; then
44 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
45 else
46 wine_cv_toolsdir="\$(TOPOBJDIR)"
47 fi
48 elif test -d "$with_wine_tools/tools/winebuild"; then
49 case $with_wine_tools in
50 /*) wine_cv_toolsdir="$with_wine_tools" ;;
51 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
52 esac
53 else
54 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
55 fi])
56 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
58 AC_PATH_XTRA
59 AC_PROG_YACC
60 AC_PROG_LEX
62 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
63 dnl **** without one present.
64 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
65 if test "$XYACC" = "none"
66 then
67 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
68 fi
69 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
70 if test "$XLEX" = "none"
71 then
72 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
73 fi
75 AC_CHECK_TOOL(LD,ld,ld)
76 AC_CHECK_TOOL(AR,ar,ar)
77 AC_PROG_RANLIB
78 AC_CHECK_TOOL(STRIP,strip,strip)
79 AC_CHECK_TOOL(WINDRES,windres,false)
80 AC_PROG_INSTALL
81 AC_PROG_LN_S
82 WINE_PROG_LN
83 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
84 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
86 dnl Check for lint
87 AC_CHECK_PROGS(LINT, lclint lint)
88 if test "$LINT" = "lint"
89 then
90 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
91 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
92 fi
93 AC_SUBST(LINT)
94 AC_SUBST(LINTFLAGS)
96 dnl **** Check for some libraries ****
98 dnl Check for -lm
99 AC_CHECK_LIB(m,sqrt)
100 dnl Check for -li386 for NetBSD and OpenBSD
101 AC_CHECK_LIB(i386,i386_set_ldt)
102 dnl Check for -lossaudio for NetBSD
103 AC_CHECK_LIB(ossaudio,_oss_ioctl)
104 dnl Check for -lw for Solaris
105 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
106 dnl Check for -lnsl for Solaris
107 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
108 dnl Check for -lsocket for Solaris
109 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
110 dnl Check for -lresolv for Solaris
111 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
112 dnl Check for -lxpg4 for FreeBSD
113 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
114 dnl Check for -lmmap for OS/2
115 AC_CHECK_LIB(mmap,mmap)
117 JPEGLIB=""
118 AC_SUBST(JPEGLIB)
119 AC_CHECK_HEADERS(jpeglib.h,
120 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
121 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
122 JPEGLIB="-ljpeg"
123 )
124 )
127 AC_SUBST(XLIB)
128 AC_SUBST(XFILES)
129 XFILES=""
130 AC_SUBST(OPENGLFILES)
131 OPENGLFILES=""
132 AC_SUBST(GLU32FILES)
133 GLU32FILES=""
134 if test "$have_x" = "yes"
135 then
136 XLIB="-lXext -lX11"
137 ac_save_CPPFLAGS="$CPPFLAGS"
138 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
140 dnl *** All of the following tests require X11/Xlib.h
141 AC_CHECK_HEADERS(X11/Xlib.h,
142 [
143 dnl *** Check for X keyboard extension
144 AC_CHECK_HEADERS(X11/XKBlib.h,
145 [ dnl *** If X11/XKBlib.h exists...
146 AC_CHECK_LIB(X11, XkbQueryExtension,
147 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
148 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
149 ],
150 AC_MSG_WARN([[Xkb extension not found, Wine will be built without it]]),
151 [#include <X11/Xlib.h>])
153 dnl *** Check for X Shm extension
154 AC_CHECK_HEADERS(X11/extensions/XShm.h,
155 [ dnl *** If X11/extensions/XShm.h exists...
156 AC_CHECK_LIB(Xext, XShmQueryExtension,
157 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
158 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
159 ],
160 AC_MSG_WARN([[XShm extension not found, Wine will be built without it]]),
161 [#include <X11/Xlib.h>])
163 dnl *** Check for Xutil
164 AC_CHECK_HEADERS(X11/Xutil.h,,,
165 [#include <X11/Xlib.h>])
167 dnl *** Check for X shape extension
168 AC_CHECK_HEADERS(X11/extensions/shape.h,
169 [ dnl *** If X11/extensions/shape.h exists...
170 AC_CHECK_LIB(Xext,XShapeQueryExtension,
171 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
172 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
173 ],
174 AC_MSG_WARN([[XShape extension not found, Wine will be built without it]]),
175 [#include <X11/Xlib.h>
176 #ifdef HAVE_X11_XUTIL_H
177 # include <X11/Xutil.h>
178 #endif])
180 dnl *** Check for XFree86 DGA / DGA 2.0 extension
181 AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
182 [ dnl *** If X11/extensions/xf86dga.h exists, check
183 dnl *** for XDGAQueryExtension()...
184 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
185 [ dnl *** If found...
186 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
187 [Define if you have the Xxf86dga library version 2])
188 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
189 ],
190 [ dnl *** If not found, look for XF86DGAQueryExtension()
191 dnl *** instead (DGA 2.0 not found)...
192 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
193 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
194 [Define if you have the Xxf86dga library version 1])
195 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
196 ],,
197 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
198 )
199 ],
200 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
201 )
202 ],
203 AC_MSG_WARN([[DGA extension not found, Wine will be built without it]]),
204 [#include <X11/Xlib.h>])
206 dnl *** Check for XFree86 VMODE extension
207 AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
208 [ dnl *** If X11/extensions/xf86vmode.h exists...
209 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
210 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
211 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
212 ],,
213 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
214 )
215 ],
216 AC_MSG_WARN([[XFree86 VMODE extension not found, Wine will be built without it]]),
217 [#include <X11/Xlib.h>])
219 dnl *** Check for XVideo extension supporting XvImages
220 AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
221 [ dnl *** If X11/extensions/Xvlib.h exists...
222 AC_CHECK_LIB(Xv, XvShmCreateImage,
223 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
224 X_PRE_LIBS="$X_PRE_LIBS -lXv"
225 ],,
226 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
227 )
228 ],
229 AC_MSG_WARN([[XVideo extension not found, Wine will be built without it]]),
230 [#include <X11/Xlib.h>])
232 dnl *** Check for XRender include file
233 AC_CHECK_HEADERS(X11/extensions/Xrender.h,,,[#include <X11/Xlib.h>])
234 ]
235 ) dnl *** End of X11/Xlib.h check
237 dnl Check for the presence of OpenGL
238 if test "x$enable_opengl" != "xno"
239 then
240 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
241 then
242 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
243 This prevents linking to OpenGL. Delete the file and restart configure.])
244 fi
246 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
247 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
248 then
249 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
250 dnl Check for some problems due to old Mesa versions
251 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
252 AC_TRY_COMPILE(
253 [#include <GL/gl.h>],
254 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
255 [wine_cv_opengl_version_OK="yes"],
256 [wine_cv_opengl_version_OK="no"]
257 )
258 )
260 dnl Check for the thread-safety of the OpenGL library
261 AC_CACHE_CHECK([for thread-safe OpenGL version],
262 wine_cv_opengl_version_threadsafe,
263 [saved_libs=$LIBS
264 LIBS="$X_LIBS -lGL"
265 AC_TRY_LINK([],[pthread_getspecific();],
266 [wine_cv_opengl_version_threadsafe="yes"],
267 [wine_cv_opengl_version_threadsafe="no"])
268 LIBS=$saved_libs]
269 )
271 if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o "x$enable_opengl" = "xyes" \)
272 then
273 dnl Check for the presence of the library
274 AC_CHECK_LIB(GL,glXCreateContext,
275 X_PRE_LIBS="$X_PRE_LIBS -lGL"
276 ,,
277 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
279 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
280 then
281 OPENGLFILES='$(OPENGLFILES)'
282 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
284 AC_CHECK_LIB(GL,glXGetProcAddressARB,
285 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
286 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
287 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
289 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
290 then
291 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
292 [AC_TRY_COMPILE([#include <GL/gl.h>
293 #ifdef HAVE_GL_GLEXT_H
294 # include <GL/glext.h>
295 #endif
296 ],
297 [PFNGLCOLORTABLEEXTPROC test_proc;],
298 [wine_cv_extension_prototypes="yes"],
299 [wine_cv_extension_prototypes="no"]
300 )]
301 )
302 if test "$wine_cv_extension_prototypes" = "yes"
303 then
304 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
305 [Define if the OpenGL headers define extension typedefs])
306 fi
307 fi
309 fi
310 dnl Check for GLU32 library.
311 AC_CHECK_LIB(GLU,gluLookAt,
312 [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
313 GLU32FILES='$(GLU32FILES)']
314 ,,
315 $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
316 )
317 fi
318 fi
319 fi
321 CPPFLAGS="$ac_save_CPPFLAGS"
322 XFILES='$(XFILES)'
323 else
324 XLIB=""
325 X_CFLAGS=""
326 X_LIBS=""
327 fi
329 dnl **** Check which curses lib to use ***
330 CURSESLIBS=""
331 if test "x$with_curses" != "xno"
332 then
333 AC_CHECK_HEADERS(ncurses.h,
334 [AC_CHECK_LIB(ncurses,waddch,
335 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
336 CURSESLIBS="-lncurses"],
337 [AC_CHECK_HEADERS(curses.h,
338 [AC_CHECK_LIB(curses,waddch,
339 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
340 CURSESLIBS="-lcurses"])])])])
341 saved_libs="$LIBS"
342 LIBS="$CURSESLIBS $LIBS"
343 AC_CHECK_FUNCS(getbkgd resizeterm)
344 LIBS="$saved_libs"
345 fi
346 AC_SUBST(CURSESLIBS)
348 CUPSLIBS=""
349 dnl **** Check for CUPS ****
350 wine_cv_warn_cups_h=no
351 AC_CHECK_LIB(cups,cupsGetPPD,
352 [AC_CHECK_HEADER(cups/cups.h,
353 [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
354 CUPSLIBS="-lcups"],
355 wine_cv_warn_cups_h=yes)]
356 )
357 AC_SUBST(CUPSLIBS)
359 dnl **** Check for SANE ****
360 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
361 if test "$sane_devel" = "no"
362 then
363 SANELIBS=""
364 SANEINCL=""
365 else
366 SANELIBS="`$sane_devel --libs`"
367 SANEINCL="`$sane_devel --cflags`"
368 ac_save_CPPFLAGS="$CPPFLAGS"
369 ac_save_LIBS="$LIBS"
370 CPPFLAGS="$CPPFLAGS $SANEINCL"
371 LIBS="$LIBS $SANELIBS"
372 AC_CHECK_HEADER(sane/sane.h,
373 [AC_CHECK_LIB(sane,sane_open,
374 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
375 [SANELIBS=""
376 SANEINCL=""])],
377 [SANELIBS=""
378 SANEINCL=""])
379 LIBS="$ac_save_LIBS"
380 CPPFLAGS="$ac_save_CPPFLAGS"
381 fi
382 AC_SUBST(SANELIBS)
383 AC_SUBST(SANEINCL)
385 dnl **** Check for FreeType 2 ****
386 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
387 if test "$ft_lib" = "no"
388 then
389 FREETYPEINCL=""
390 wine_cv_msg_freetype=no
391 else
392 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
393 if test "$ft_devel" = "no"
394 then
395 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
396 if test "$ft_devel2" = "freetype2-config"
397 then
398 ft_devel=$ft_devel2
399 fi
400 fi
401 if test "$ft_devel" = "no"
402 then
403 FREETYPEINCL=""
404 wine_cv_msg_freetype=yes
405 else
406 FREETYPEINCL=`$ft_devel --cflags`
407 ac_save_CPPFLAGS="$CPPFLAGS"
408 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
409 AC_CHECK_HEADERS(freetype/freetype.h \
410 freetype/ftglyph.h \
411 freetype/tttables.h \
412 freetype/ftnames.h \
413 freetype/ftsnames.h \
414 freetype/ttnameid.h \
415 freetype/ftoutln.h \
416 freetype/internal/sfnt.h)
417 AC_TRY_CPP([#include <ft2build.h>
418 #include <freetype/fttrigon.h>],
419 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
420 [Define if you have the <freetype/fttrigon.h> header file.])
421 wine_cv_fttrigon=yes],
422 wine_cv_fttrigon=no)
423 CPPFLAGS="$ac_save_CPPFLAGS"
424 dnl Check that we have at least freetype/freetype.h
425 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
426 then
427 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
428 wine_cv_msg_freetype=no
429 else
430 FREETYPEINCL=""
431 wine_cv_msg_freetype=yes
432 fi
433 fi
434 fi
435 AC_SUBST(FREETYPEINCL)
437 dnl **** Check for parport (currently Linux only) ****
438 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
439 AC_TRY_COMPILE(
440 [#include <linux/ppdev.h>],
441 [ioctl (1,PPCLAIM,0)],
442 [ac_cv_c_ppdev="yes"],
443 [ac_cv_c_ppdev="no"])
444 )
445 if test "$ac_cv_c_ppdev" = "yes"
446 then
447 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
448 fi
450 dnl **** Check for IPX (currently Linux only) ****
451 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
452 AC_TRY_COMPILE(
453 [#include <sys/socket.h>
454 #include <netipx/ipx.h>],
455 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
456 [ac_cv_c_ipx_gnu="yes"],
457 [ac_cv_c_ipx_gnu="no"])
458 )
459 if test "$ac_cv_c_ipx_gnu" = "yes"
460 then
461 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
462 fi
464 if test "$ac_cv_c_ipx_gnu" = "no"
465 then
466 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
467 AC_TRY_COMPILE(
468 [#include <sys/socket.h>
469 #include <asm/types.h>
470 #include <linux/ipx.h>],
471 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
472 [ac_cv_c_ipx_linux="yes"],
473 [ac_cv_c_ipx_linux="no"])
474 )
475 if test "$ac_cv_c_ipx_linux" = "yes"
476 then
477 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
478 fi
479 fi
481 dnl **** Check for Open Sound System ****
482 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
484 AC_CACHE_CHECK([for Open Sound System],
485 ac_cv_c_opensoundsystem,
486 AC_TRY_COMPILE([
487 #if defined(HAVE_SYS_SOUNDCARD_H)
488 #include <sys/soundcard.h>
489 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
490 #include <machine/soundcard.h>
491 #elif defined(HAVE_SOUNDCARD_H)
492 #include <soundcard.h>
493 #endif
494 ],[
496 /* check for one of the Open Sound System specific SNDCTL_ defines */
497 #if !defined(SNDCTL_DSP_STEREO)
498 #error No open sound system
499 #endif
500 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
502 if test "$ac_cv_c_opensoundsystem" = "yes"
503 then
504 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
505 fi
507 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
508 ac_cv_c_opensoundsystem_midi,
509 AC_TRY_COMPILE([
510 #if defined(HAVE_SYS_SOUNDCARD_H)
511 #include <sys/soundcard.h>
512 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
513 #include <machine/soundcard.h>
514 #elif defined(HAVE_SOUNDCARD_H)
515 #include <soundcard.h>
516 #endif
517 ],[
519 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
520 #if !defined(SNDCTL_SEQ_SYNC)
521 #error No open sound system MIDI interface
522 #endif
523 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
525 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
526 then
527 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
528 fi
530 dnl **** Check for aRts Sound Server ****
531 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
532 AC_CACHE_CHECK([for aRts Sound server],
533 ac_cv_c_artsserver,
534 if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
535 then
536 ac_cv_c_artsserver=no
537 else
538 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
539 ARTSC_LIBS=`$ARTSCCONFIG --libs`
540 ac_cv_c_artsserver=no
541 save_CFLAGS="$CFLAGS"
542 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
543 AC_TRY_COMPILE([
544 #include <artsc.h>
545 ],[
546 arts_stream_t stream;
547 ],[
548 ac_cv_c_artsserver=yes
549 ])
550 CFLAGS="$save_CFLAGS"
551 fi)
553 if test "$ac_cv_c_artsserver" = "yes"
554 then
555 AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
556 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
558 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
559 fi
561 dnl **** Check for ALSA ****
562 AC_SUBST(ALSALIBS,"")
563 AC_CHECK_HEADERS(sys/asoundlib.h)
564 if test "$ac_cv_header_sys_asoundlib_h" = "yes"
565 then
566 AC_CHECK_LIB(asound,snd_pcm_open,
567 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
568 ALSALIBS="-lasound")
569 fi
571 dnl **** Check for NAS ****
572 AC_SUBST(NASLIBS,"")
573 AC_CHECK_HEADERS(audio/audiolib.h,
574 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
575 AC_CHECK_LIB(audio,AuCreateFlow,
576 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
577 NASLIBS="-laudio -lXt \$(X_LIBS) \$(XLIB)"],,
578 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
580 dnl **** Check for broken glibc mmap64 ****
582 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
583 AC_TRY_RUN([
584 #define _FILE_OFFSET_BITS 64
585 #include <stdio.h>
586 #include <unistd.h>
587 #include <fcntl.h>
588 #include <sys/mman.h>
589 #include <errno.h>
591 int main(int argc,char **argv) {
592 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
593 if (fd == -1) exit(1);
595 unlink("conftest.map");
597 write(fd,"test",4);
599 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
600 (errno == EINVAL)
601 ) {
602 exit(1);
603 }
604 close(fd);
605 fprintf(stderr,"success!\n");
606 exit(0);
607 }
609 ],
610 ac_cv_mmap64_works="yes",
611 ac_cv_mmap64_works="no",
612 ac_cv_mmap64_works="no") )
614 if test "$ac_cv_mmap64_works" = "yes"
615 then
616 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
617 fi
619 dnl **** Check for gcc strength-reduce bug ****
621 if test "x${GCC}" = "xyes"
622 then
623 CFLAGS="$CFLAGS -Wall"
624 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
625 AC_TRY_RUN([
626 int L[[4]] = {0,1,2,3};
627 int main(void) {
628 static int Array[[3]];
629 unsigned int B = 3;
630 int i;
631 for(i=0; i<B; i++) Array[[i]] = i - 3;
632 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
633 L[[i]] = 4;
635 exit( Array[[1]] != -2 || L[[2]] != 3);
636 }],
637 ac_cv_c_gcc_strength_bug="no",
638 ac_cv_c_gcc_strength_bug="yes",
639 ac_cv_c_gcc_strength_bug="yes") )
640 if test "$ac_cv_c_gcc_strength_bug" = "yes"
641 then
642 CFLAGS="$CFLAGS -fno-strength-reduce"
643 fi
645 dnl Check for -mpreferred-stack-boundary
646 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
647 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
648 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
649 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
650 then
651 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
652 fi
653 fi
655 dnl **** Check how to define a function in assembly code ****
657 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
658 WINE_TRY_ASM_LINK(
659 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
660 ac_cv_asm_func_def=".def",
661 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
662 ac_cv_asm_func_def=".type @function",
663 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
664 ac_cv_asm_func_def=".type 2",
665 ac_cv_asm_func_def="unknown")])]))
667 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
668 case "$ac_cv_asm_func_def" in
669 ".def")
670 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
671 ".type @function")
672 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
673 ".type 2")
674 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
675 *)
676 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
677 esac
679 dnl **** Check for underscore on external symbols ****
681 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
682 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
683 [extern int ac_test;],
684 [if (ac_test) return 1],
685 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
687 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
688 if test "$ac_cv_c_extern_prefix" = "yes"
689 then
690 AC_DEFINE([__ASM_NAME(name)], ["_" name])
691 else
692 AC_DEFINE([__ASM_NAME(name)], [name])
693 fi
695 dnl **** Check whether stdcall symbols need to be decorated ****
697 AC_CACHE_CHECK([whether stdcall symbols need to be decorated], ac_cv_c_stdcall_decoration,
698 WINE_TRY_ASM_LINK(["\t.globl _ac_test@0\n_ac_test@0:\n\t.globl ac_test@0\nac_test@0:"],
699 [extern void __attribute__((__stdcall__)) ac_test(void);],
700 [ac_test()],
701 ac_cv_c_stdcall_decoration="yes",ac_cv_c_stdcall_decoration="no"))
702 if test "$ac_cv_c_stdcall_decoration" = "yes"
703 then
704 AC_DEFINE(NEED_STDCALL_DECORATION, 1, [Define if stdcall symbols need to be decorated])
705 fi
707 dnl **** Check for .string in assembler ****
709 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
710 WINE_TRY_ASM_LINK([".string \"test\""],,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
711 if test "$ac_cv_c_asm_string" = "yes"
712 then
713 AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
714 fi
716 dnl **** Check for working dll ****
718 LDSHARED=""
719 LDDLLFLAGS=""
720 DLLIBS=""
722 case $host_os in
723 cygwin*|mingw32*)
724 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
725 if test "$DLLWRAP" = "false"; then
726 LIBEXT="a"
727 else
728 dnl FIXME - check whether dllwrap works correctly...
729 LIBEXT="dll"
730 fi
731 ;;
732 *)
733 AC_CHECK_HEADERS(dlfcn.h,
734 [AC_CHECK_FUNCS(dlopen,,
735 [AC_CHECK_LIB(dl,dlopen,
736 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
737 DLLIBS="-ldl"],
738 [LIBEXT="a"])])],
739 [LIBEXT="a"])
741 if test "$LIBEXT" = "so"
742 then
743 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
744 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
745 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
746 if test "$ac_cv_c_dll_gnuelf" = "yes"
747 then
748 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
749 LDDLLFLAGS="-Wl,-Bsymbolic"
750 else
751 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
752 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
753 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
754 if test "$ac_cv_c_dll_unixware" = "yes"
755 then
756 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
757 LDDLLFLAGS="-Wl,-B,symbolic"
758 fi
759 fi
760 fi
761 ;;
762 esac
764 if test "$LIBEXT" = "a"; then
765 AC_MSG_ERROR(
766 [could not find a way to build shared libraries.
767 It is currently not possible to build Wine without shared library
768 (.so) support to allow transparent switch between .so and .dll files.
769 If you are using Linux, you will need a newer binutils.]
770 )
771 fi
773 DLLFLAGS=""
775 if test "$LIBEXT" = "so"; then
776 DLLFLAGS="-fPIC"
777 DLLEXT=".so"
778 elif test "$LIBEXT" = "dll"; then
779 #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
780 DLLEXT=""
781 fi
783 case $build_os in
784 cygwin*|mingw32*)
785 LDPATH="PATH=\"\$(TOOLSDIR)/library:\$(TOOLSDIR)/unicode:\$\$PATH\"" ;;
786 *)
787 LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/library:\$(TOOLSDIR)/unicode:\$\$LD_LIBRARY_PATH\"" ;;
788 esac
790 AC_SUBST(DLLIBS)
791 AC_SUBST(DLLFLAGS)
792 AC_SUBST(DLLEXT)
793 AC_SUBST(LDSHARED)
794 AC_SUBST(LDDLLFLAGS)
795 AC_SUBST(LIBEXT)
796 AC_SUBST(LDPATH)
798 dnl **** Get the soname for libraries that we load dynamically ****
800 if test "$LIBEXT" = "so"
801 then
802 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
803 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
804 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
805 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
806 fi
809 dnl **** Check for reentrant libc ****
811 wine_cv_libc_reentrant=no
812 dnl Linux style errno location
813 WINE_CHECK_ERRNO([__errno_location], [wine_cv_libc_reentrant=__errno_location],
814 dnl FreeBSD style errno location
815 WINE_CHECK_ERRNO([__error], [wine_cv_libc_reentrant=__error],
816 dnl Solaris style errno location
817 WINE_CHECK_ERRNO([___errno], [wine_cv_libc_reentrant=___errno],
818 dnl UnixWare style errno location
819 WINE_CHECK_ERRNO([__thr_errno], [wine_cv_libc_reentrant=__thr_errno],
820 dnl NetBSD style errno location
821 WINE_CHECK_ERRNO([__errno], [wine_cv_libc_reentrant=__errno])
822 ))))
824 if test "$wine_cv_libc_reentrant" != "no"
825 then
826 AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
827 [Define to the name of the function returning errno for reentrant libc])
828 fi
830 dnl **** Check for reentrant X libraries ****
831 dnl
832 dnl This may fail to determine whether X libraries are reentrant if
833 dnl AC_PATH_XTRA does not set x_libraries.
835 if test "$have_x" = "yes"
836 then
837 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
838 [libX11_check=none
839 for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
840 if test -r $dir/libX11.so; then
841 libX11_check="-D $dir/libX11.so"
842 break
843 fi
844 if test -r $dir/libX11.a; then
845 libX11_check="$dir/libX11.a"
846 break
847 fi
848 done
849 if test "$libX11_check" != "none"; then
850 if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
851 then
852 wine_cv_x_reentrant=yes
853 else
854 wine_cv_x_reentrant=no
855 fi
856 else
857 wine_cv_x_reentrant=unknown
858 fi])
859 fi
861 dnl **** Check for functions ****
863 AC_FUNC_ALLOCA()
864 AC_CHECK_FUNCS(\
865 __libc_fork \
866 _lwp_create \
867 _pclose \
868 _popen \
869 _snprintf \
870 _stricmp \
871 _strnicmp \
872 chsize \
873 clone \
874 ecvt \
875 finite \
876 fpclass \
877 ftruncate \
878 ftruncate64 \
879 getnetbyaddr \
880 getnetbyname \
881 getpagesize \
882 getprotobyname \
883 getprotobynumber \
884 getpwuid \
885 getservbyport \
886 getsockopt \
887 inet_network \
888 lseek64 \
889 lstat \
890 memmove \
891 mkstemp \
892 mmap \
893 pclose \
894 popen \
895 pread \
896 pwrite \
897 rfork \
898 select \
899 sendmsg \
900 settimeofday \
901 sigaltstack \
902 snprintf \
903 statfs \
904 strcasecmp \
905 strerror \
906 strncasecmp \
907 tcgetattr \
908 timegm \
909 usleep \
910 vfscanf \
911 wait4 \
912 waitpid \
913 )
915 dnl **** Check for header files ****
917 AC_CHECK_HEADERS(\
918 arpa/inet.h \
919 arpa/nameser.h \
920 direct.h \
921 elf.h \
922 float.h \
923 ieeefp.h \
924 io.h \
925 libio.h \
926 libutil.h \
927 link.h \
928 linux/cdrom.h \
929 linux/hdreg.h \
930 linux/input.h \
931 linux/joystick.h \
932 linux/major.h \
933 linux/param.h \
934 linux/serial.h \
935 linux/ucdrom.h \
936 netdb.h \
937 netinet/in.h \
938 netinet/in_systm.h \
939 netinet/tcp.h \
940 pty.h \
941 pwd.h \
942 sched.h \
943 scsi/sg.h \
944 socket.h \
945 stdint.h \
946 strings.h \
947 sys/cdio.h \
948 sys/errno.h \
949 sys/file.h \
950 sys/filio.h \
951 sys/inttypes.h \
952 sys/ioctl.h \
953 sys/ipc.h \
954 sys/link.h \
955 sys/lwp.h \
956 sys/mman.h \
957 sys/modem.h \
958 sys/mount.h \
959 sys/msg.h \
960 sys/param.h \
961 sys/ptrace.h \
962 sys/reg.h \
963 sys/shm.h \
964 sys/signal.h \
965 sys/socket.h \
966 sys/sockio.h \
967 sys/statfs.h \
968 sys/strtio.h \
969 sys/syscall.h \
970 sys/sysctl.h \
971 sys/time.h \
972 sys/user.h \
973 sys/v86.h \
974 sys/v86intr.h \
975 sys/vfs.h \
976 sys/vm86.h \
977 sys/wait.h \
978 syscall.h \
979 termios.h \
980 ucontext.h \
981 unistd.h \
982 )
983 AC_HEADER_STAT()
985 dnl *** Check for net/if.h
986 AC_CHECK_HEADERS(net/if.h,,,
987 [#if HAVE_SYS_TYPES_H
988 # include <sys/types.h>
989 #endif
990 #if HAVE_SYS_SOCKET_H
991 # include <sys/socket.h>
992 #endif])
994 dnl *** Check for netinet/ip.h
995 AC_CHECK_HEADERS(netinet/ip.h,,,
996 [#if HAVE_SYS_SOCKET_H
997 # include <sys/socket.h>
998 #endif
999 #if HAVE_NETINET_IN_SYSTM_H
1000 # include <netinet/in_systm.h>
1001 #endif])
1003 dnl *** Check for resolv.h
1004 AC_CHECK_HEADERS(resolv.h,,,
1005 [#if HAVE_SYS_SOCKET_H
1006 # include <sys/socket.h>
1007 #endif])
1009 dnl **** Check for types ****
1011 AC_C_CONST
1012 AC_C_INLINE
1013 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1014 AC_CHECK_SIZEOF(long long,0)
1016 AC_CACHE_CHECK([whether linux/input.h is for real],
1017 wine_cv_linux_input_h,
1018 AC_TRY_COMPILE([
1019 #include <linux/input.h>
1020 ] , [
1021 int foo = EVIOCGBIT(EV_ABS,42);
1022 int bar = BTN_PINKIE;
1023 int fortytwo = 42;
1024 ],
1025 wine_cv_linux_input_h=yes,
1026 wine_cv_linux_input_h=no,
1027 no
1028 )
1029 )
1030 if test "$wine_cv_linux_input_h" = "yes"
1031 then
1032 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1033 [Define if we have linux/input.h AND it contains the INPUT event API])
1034 fi
1037 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1038 wine_cv_linux_gethostbyname_r_6,
1039 AC_TRY_COMPILE([
1040 #include <netdb.h>
1041 ], [
1042 char *name=NULL;
1043 struct hostent he;
1044 struct hostent *result;
1045 char *buf=NULL;
1046 int bufsize=0;
1047 int res,errnr;
1048 char *addr=NULL;
1049 int addrlen=0;
1050 int addrtype=0;
1051 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1052 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1053 ],
1054 wine_cv_linux_gethostbyname_r_6=yes,
1055 wine_cv_linux_gethostbyname_r_6=no
1056 )
1057 )
1058 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1059 then
1060 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1061 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1062 fi
1064 if test "$ac_cv_header_linux_joystick_h" = "yes"
1065 then
1066 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1067 wine_cv_linux_joystick_22_api,
1068 AC_TRY_COMPILE([
1069 #include <sys/ioctl.h>
1070 #include <linux/joystick.h>
1072 struct js_event blub;
1073 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1074 #error "no 2.2 header"
1075 #endif
1076 ],/*empty*/,
1077 wine_cv_linux_joystick_22_api=yes,
1078 wine_cv_linux_joystick_22_api=no,
1079 wine_cv_linux_joystick_22_api=no
1080 )
1081 )
1082 if test "$wine_cv_linux_joystick_22_api" = "yes"
1083 then
1084 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1085 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1086 fi
1087 fi
1089 dnl **** statfs checks ****
1091 if test "$ac_cv_header_sys_vfs_h" = "yes"
1092 then
1093 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1094 wine_cv_sys_vfs_has_statfs,
1095 AC_TRY_COMPILE([
1096 #include <sys/types.h>
1097 #ifdef HAVE_SYS_PARAM_H
1098 # include <sys/param.h>
1099 #endif
1100 #include <sys/vfs.h>
1101 ],[
1102 struct statfs stfs;
1104 memset(&stfs,0,sizeof(stfs));
1105 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1106 )
1107 )
1108 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1109 then
1110 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1111 [Define if the struct statfs is defined by <sys/vfs.h>])
1112 fi
1113 fi
1115 if test "$ac_cv_header_sys_statfs_h" = "yes"
1116 then
1117 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1118 wine_cv_sys_statfs_has_statfs,
1119 AC_TRY_COMPILE([
1120 #include <sys/types.h>
1121 #ifdef HAVE_SYS_PARAM_H
1122 # include <sys/param.h>
1123 #endif
1124 #include <sys/statfs.h>
1125 ],[
1126 struct statfs stfs;
1127 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1128 )
1129 )
1130 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1131 then
1132 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1133 [Define if the struct statfs is defined by <sys/statfs.h>])
1134 fi
1135 fi
1137 if test "$ac_cv_header_sys_mount_h" = "yes"
1138 then
1139 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1140 wine_cv_sys_mount_has_statfs,
1141 AC_TRY_COMPILE([
1142 #include <sys/types.h>
1143 #ifdef HAVE_SYS_PARAM_H
1144 # include <sys/param.h>
1145 #endif
1146 #include <sys/mount.h>
1147 ],[
1148 struct statfs stfs;
1149 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1150 )
1151 )
1152 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1153 then
1154 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1155 [Define if the struct statfs is defined by <sys/mount.h>])
1156 fi
1157 fi
1159 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1161 WINE_CHECK_STRUCT_MEMBER(statfs,f_bfree,
1162 [#include <sys/types.h>
1163 #ifdef HAVE_SYS_PARAM_H
1164 # include <sys/param.h>
1165 #endif
1166 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1167 # include <sys/mount.h>
1168 #else
1169 # ifdef STATFS_DEFINED_BY_SYS_VFS
1170 # include <sys/vfs.h>
1171 # else
1172 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1173 # include <sys/statfs.h>
1174 # endif
1175 # endif
1176 #endif],
1177 [AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])])
1179 WINE_CHECK_STRUCT_MEMBER(statfs,f_bavail,
1180 [#include <sys/types.h>
1181 #ifdef HAVE_SYS_PARAM_H
1182 # include <sys/param.h>
1183 #endif
1184 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1185 # include <sys/mount.h>
1186 #else
1187 # ifdef STATFS_DEFINED_BY_SYS_VFS
1188 # include <sys/vfs.h>
1189 # else
1190 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1191 # include <sys/statfs.h>
1192 # endif
1193 # endif
1194 #endif],
1195 [AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])])
1197 dnl Check for file descriptor passing with msg_accrights
1198 WINE_CHECK_STRUCT_MEMBER(msghdr,msg_accrights,
1199 [#include <sys/types.h>
1200 #include <sys/socket.h>],
1201 [AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])])
1203 dnl Check for the sa_len member in struct sockaddr
1204 WINE_CHECK_STRUCT_MEMBER(sockaddr,sa_len,
1205 [#include <sys/types.h>
1206 #include <sys/socket.h>],
1207 [AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])])
1209 dnl Check for the sun_len member in struct sockaddr_un
1210 WINE_CHECK_STRUCT_MEMBER(sockaddr_un,sun_len,
1211 [#include <sys/types.h>
1212 #include <sys/socket.h>
1213 #include <sys/un.h>],
1214 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])])
1216 dnl *** check for the need to define __i386__
1218 case $host_cpu in
1219 *i[3456789]86* )
1220 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1221 AC_EGREP_CPP(yes,[#ifndef __i386__
1222 yes
1223 #endif],
1224 ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1225 ;;
1226 esac
1227 if test "$ac_cv_cpp_def_i386" = "yes"
1228 then
1229 CFLAGS="$CFLAGS -D__i386__"
1230 LINTFLAGS="$LINTFLAGS -D__i386__"
1231 fi
1233 dnl *** check for the need to define __sparc__
1235 case $host_cpu in
1236 *sparc* )
1237 AC_CACHE_CHECK([whether we need to define __sparc__],ac_cv_cpp_def_sparc,
1238 AC_EGREP_CPP(yes,[#ifndef __sparc__
1239 yes
1240 #endif],
1241 ac_cv_cpp_def_sparc="yes", ac_cv_cpp_def_sparc="no"))
1242 ;;
1243 esac
1244 if test "$ac_cv_cpp_def_sparc" = "yes"
1245 then
1246 CFLAGS="$CFLAGS -D__sparc__"
1247 LINTFLAGS="$LINTFLAGS -D__sparc__"
1248 fi
1250 dnl *** check for the need to define __sun__
1252 case $host_vendor in
1253 *sun* )
1254 AC_CACHE_CHECK([whether we need to define __sun__],ac_cv_cpp_def_sun,
1255 AC_EGREP_CPP(yes,[#ifndef __sun__
1256 yes
1257 #endif],
1258 ac_cv_cpp_def_sun="yes", ac_cv_cpp_def_sun="no"))
1259 ;;
1260 esac
1261 if test "$ac_cv_cpp_def_sun" = "yes"
1262 then
1263 CFLAGS="$CFLAGS -D__sun__"
1264 LINTFLAGS="$LINTFLAGS -D__sun__"
1265 fi
1267 dnl **** Generate output files ****
1269 AH_TOP([#define __WINE_CONFIG_H])
1271 WINE_CONFIG_EXTRA_DIR(controls)
1272 WINE_CONFIG_EXTRA_DIR(dlls/advapi32/tests)
1273 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1274 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1275 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1276 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1277 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1278 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1279 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1280 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1281 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1282 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1283 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1284 WINE_CONFIG_EXTRA_DIR(dlls/gdi/win16drv)
1285 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1286 WINE_CONFIG_EXTRA_DIR(dlls/kernel/tests)
1287 WINE_CONFIG_EXTRA_DIR(dlls/oleaut32/tests)
1288 WINE_CONFIG_EXTRA_DIR(dlls/shlwapi/tests)
1289 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1290 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1291 WINE_CONFIG_EXTRA_DIR(dlls/user/tests)
1292 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1293 WINE_CONFIG_EXTRA_DIR(dlls/wininet/tests)
1294 WINE_CONFIG_EXTRA_DIR(dlls/winsock/tests)
1295 WINE_CONFIG_EXTRA_DIR(files)
1296 WINE_CONFIG_EXTRA_DIR(graphics)
1297 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1298 WINE_CONFIG_EXTRA_DIR(if1632)
1299 WINE_CONFIG_EXTRA_DIR(include/wine)
1300 WINE_CONFIG_EXTRA_DIR(loader)
1301 WINE_CONFIG_EXTRA_DIR(loader/ne)
1302 WINE_CONFIG_EXTRA_DIR(memory)
1303 WINE_CONFIG_EXTRA_DIR(misc)
1304 WINE_CONFIG_EXTRA_DIR(msdos)
1305 WINE_CONFIG_EXTRA_DIR(objects)
1306 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1307 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1308 WINE_CONFIG_EXTRA_DIR(programs/winetest/tests)
1309 WINE_CONFIG_EXTRA_DIR(relay32)
1310 WINE_CONFIG_EXTRA_DIR(scheduler)
1311 WINE_CONFIG_EXTRA_DIR(win32)
1312 WINE_CONFIG_EXTRA_DIR(windows)
1314 MAKE_RULES=Make.rules
1315 AC_SUBST_FILE(MAKE_RULES)
1317 MAKE_DLL_RULES=dlls/Makedll.rules
1318 AC_SUBST_FILE(MAKE_DLL_RULES)
1320 MAKE_PROG_RULES=programs/Makeprog.rules
1321 AC_SUBST_FILE(MAKE_PROG_RULES)
1323 AC_CONFIG_FILES([
1324 Make.rules
1325 dlls/Makedll.rules
1326 programs/Makeprog.rules
1327 Makefile
1328 debugger/Makefile
1329 dlls/Makefile
1330 dlls/advapi32/Makefile
1331 dlls/avicap32/Makefile
1332 dlls/avifil32/Makefile
1333 dlls/comcat/Makefile
1334 dlls/comctl32/Makefile
1335 dlls/commdlg/Makefile
1336 dlls/crtdll/Makefile
1337 dlls/crypt32/Makefile
1338 dlls/d3d8/Makefile
1339 dlls/dciman32/Makefile
1340 dlls/ddraw/Makefile
1341 dlls/devenum/Makefile
1342 dlls/dinput/Makefile
1343 dlls/dinput8/Makefile
1344 dlls/dplay/Makefile
1345 dlls/dplayx/Makefile
1346 dlls/dsound/Makefile
1347 dlls/gdi/Makefile
1348 dlls/glu32/Makefile
1349 dlls/icmp/Makefile
1350 dlls/imagehlp/Makefile
1351 dlls/imm32/Makefile
1352 dlls/kernel/Makefile
1353 dlls/lzexpand/Makefile
1354 dlls/mapi32/Makefile
1355 dlls/mpr/Makefile
1356 dlls/msacm/Makefile
1357 dlls/msacm/imaadp32/Makefile
1358 dlls/msacm/msadp32/Makefile
1359 dlls/msacm/msg711/Makefile
1360 dlls/msacm/winemp3/Makefile
1361 dlls/msdmo/Makefile
1362 dlls/msimg32/Makefile
1363 dlls/msisys/Makefile
1364 dlls/msnet32/Makefile
1365 dlls/msrle32/Makefile
1366 dlls/msvcrt/Makefile
1367 dlls/msvcrt20/Makefile
1368 dlls/msvideo/Makefile
1369 dlls/netapi32/Makefile
1370 dlls/ntdll/Makefile
1371 dlls/odbc32/Makefile
1372 dlls/ole32/Makefile
1373 dlls/oleaut32/Makefile
1374 dlls/olecli/Makefile
1375 dlls/oledlg/Makefile
1376 dlls/olepro32/Makefile
1377 dlls/olesvr/Makefile
1378 dlls/opengl32/Makefile
1379 dlls/psapi/Makefile
1380 dlls/qcap/Makefile
1381 dlls/quartz/Makefile
1382 dlls/rasapi32/Makefile
1383 dlls/richedit/Makefile
1384 dlls/rpcrt4/Makefile
1385 dlls/serialui/Makefile
1386 dlls/setupapi/Makefile
1387 dlls/shdocvw/Makefile
1388 dlls/shell32/Makefile
1389 dlls/shfolder/Makefile
1390 dlls/shlwapi/Makefile
1391 dlls/snmpapi/Makefile
1392 dlls/sti/Makefile
1393 dlls/tapi32/Makefile
1394 dlls/ttydrv/Makefile
1395 dlls/twain/Makefile
1396 dlls/url/Makefile
1397 dlls/urlmon/Makefile
1398 dlls/user/Makefile
1399 dlls/version/Makefile
1400 dlls/win32s/Makefile
1401 dlls/winaspi/Makefile
1402 dlls/winedos/Makefile
1403 dlls/wineps/Makefile
1404 dlls/wininet/Makefile
1405 dlls/winmm/Makefile
1406 dlls/winmm/joystick/Makefile
1407 dlls/winmm/mcianim/Makefile
1408 dlls/winmm/mciavi/Makefile
1409 dlls/winmm/mcicda/Makefile
1410 dlls/winmm/mciseq/Makefile
1411 dlls/winmm/mciwave/Makefile
1412 dlls/winmm/midimap/Makefile
1413 dlls/winmm/wavemap/Makefile
1414 dlls/winmm/winealsa/Makefile
1415 dlls/winmm/winenas/Makefile
1416 dlls/winmm/winearts/Makefile
1417 dlls/winmm/wineoss/Makefile
1418 dlls/winnls/Makefile
1419 dlls/winsock/Makefile
1420 dlls/winspool/Makefile
1421 dlls/wintrust/Makefile
1422 dlls/wow32/Makefile
1423 dlls/wsock32/Makefile
1424 dlls/x11drv/Makefile
1425 documentation/Makefile
1426 include/Makefile
1427 library/Makefile
1428 miscemu/Makefile
1429 ole/Makefile
1430 programs/Makefile
1431 programs/avitools/Makefile
1432 programs/clock/Makefile
1433 programs/cmdlgtst/Makefile
1434 programs/control/Makefile
1435 programs/expand/Makefile
1436 programs/notepad/Makefile
1437 programs/osversioncheck/Makefile
1438 programs/progman/Makefile
1439 programs/regapi/Makefile
1440 programs/regedit/Makefile
1441 programs/regsvr32/Makefile
1442 programs/regtest/Makefile
1443 programs/uninstaller/Makefile
1444 programs/view/Makefile
1445 programs/wcmd/Makefile
1446 programs/wineconsole/Makefile
1447 programs/winefile/Makefile
1448 programs/winemine/Makefile
1449 programs/winepath/Makefile
1450 programs/winetest/Makefile
1451 programs/winhelp/Makefile
1452 programs/winver/Makefile
1453 server/Makefile
1454 tools/Makefile
1455 tools/widl/Makefile
1456 tools/winapi/Makefile
1457 tools/winebuild/Makefile
1458 tools/winedump/Makefile
1459 tools/wmc/Makefile
1460 tools/wpp/Makefile
1461 tools/wrc/Makefile
1462 tsx11/Makefile
1463 unicode/Makefile])
1465 AC_OUTPUT
1467 if test "$have_x" = "no"
1468 then
1469 echo
1470 echo "*** Warning: X development files not found. Wine will be built without"
1471 echo "*** X support, which currently does not work, and would probably not be"
1472 echo "*** what you want anyway. You will need to install devel packages of"
1473 echo "*** Xlib/Xfree86 at the very least."
1474 fi
1476 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1477 then
1478 echo
1479 echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1480 echo "*** terminal resize support. Consider upgrading ncurses."
1481 fi
1483 if test "$wine_cv_libc_reentrant" = "no"
1484 then
1485 echo
1486 echo "*** Warning: non-reentrant libc detected. Wine will be built without"
1487 echo "*** threading support. Consider upgrading libc to a more recent"
1488 echo "*** reentrant version of libc."
1489 fi
1491 if test "$have_x" = "yes" -a "$wine_cv_x_reentrant" != "yes"
1492 then
1493 echo
1494 echo "*** Warning: non-reentrant X11 library detected. Multi-threaded"
1495 echo "*** applications won't work properly. You should upgrade your X11 library."
1496 fi
1498 if test "$wine_cv_opengl_version_OK" = "no"
1499 then
1500 echo
1501 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1502 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1503 fi
1505 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a "x$enable_opengl" = "x"
1506 then
1507 echo
1508 echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1509 echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1510 echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1511 echo "*** start configure with '--enable-opengl' to force OpenGL support."
1512 fi
1514 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a "x$enable_opengl" = "xyes"
1515 then
1516 echo
1517 echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1518 echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1519 echo "*** support before reporting bugs."
1520 fi
1522 if test "$wine_cv_warn_cups_h" = "yes"
1523 then
1524 echo
1525 echo "*** Note: You have cups runtime libraries, but no development"
1526 echo "*** libraries. Install the cups-devel package or whichever package"
1527 echo "*** contains cups.h to enable CUPS support in Wine."
1528 fi
1530 if test "$wine_cv_msg_freetype" = "yes"
1531 then
1532 echo
1533 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1534 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1535 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1536 echo "*** enable Wine to use TrueType fonts."
1537 fi
1539 echo
1540 echo "Configure finished. Do 'make depend && make' to compile Wine."
1541 echo
1543 dnl Local Variables:
1544 dnl comment-start: "dnl "
1545 dnl comment-end: ""
1546 dnl comment-start-skip: "\\bdnl\\b\\s *"
1547 dnl compile-command: "autoconf"
1548 dnl End: