configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10 LIBS="$LIBS -lm"
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK="-L\$(TOPOBJDIR) -lwine"
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS) \$(X11OBJS)"; LIB_TARGET=""; fi])
  33
  34 dnl AC_ARG_WITH(ipc,
  35 dnl [  --enable-ipc            use inter-process communication for DDE],
  36 dnl [if test "$enableval" = "no"; then : ; else OPTIONS="-DCONFIG_IPC"; fi])
  37
  38 AC_ARG_ENABLE(debug,
  39 [  --disable-debug         compile out all debugging messages],
  40 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  41
  42 AC_ARG_ENABLE(trace,
  43 [  --disable-trace         compile out TRACE messages],
  44 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  45
  46 AC_ARG_WITH(reentrant-x,
  47 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  48
  49 AC_SUBST(MAIN_TARGET)
  50 AC_SUBST(LIB_TARGET)
  51 AC_SUBST(ALT_LINK)
  52 AC_SUBST(OPTIONS)
  53
  54 if test "$DEBUG_MSGS" = "no"
  55 then
  56     AC_DEFINE(NO_DEBUG_MSGS)
  57     AC_DEFINE(NO_TRACE_MSGS)
  58 else
  59     if test "$TRACE_MSGS" = "no"
  60     then
  61         AC_DEFINE(NO_TRACE_MSGS)
  62     fi
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CPP
  70 AC_PATH_XTRA
  71 AC_PROG_YACC
  72 AC_PROG_LEX
  73 AC_PROG_RANLIB
  74 AC_PROG_INSTALL
  75 AC_PROG_LN_S
  76 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  77
  78 dnl **** Check for some libraries ****
  79
  80 dnl Check for -li386 for NetBSD and OpenBSD
  81 AC_CHECK_LIB(i386,i386_set_ldt)
  82 dnl Check for -lossaudio for NetBSD
  83 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  84 dnl Check for -lw for Solaris
  85 AC_CHECK_LIB(w,iswalnum)
  86 dnl Check for -lnsl for Solaris
  87 AC_CHECK_FUNCS(gethostbyname)
  88 if test "$ac_cv_func_gethostbyname" = "no"
  89 then
  90     AC_CHECK_LIB(nsl,gethostbyname)
  91 fi
  92 dnl Check for -lsocket for Solaris
  93 AC_CHECK_FUNCS(connect)
  94 if test "$ac_cv_func_connect" = "no"
  95 then
  96     AC_CHECK_LIB(socket,connect)
  97 fi
  98 dnl Check for -lxpg4 for FreeBSD
  99 AC_CHECK_LIB(xpg4,setrunelocale)
 100 dnl Check for -ldl
 101 AC_CHECK_LIB(dl,dlopen)
 102 AC_SUBST(XLIB)
 103 if test "$have_x" = "yes"
 104 then
 105     XLIB="-lXext -lX11"
 106     ac_save_CPPFLAGS="$CPPFLAGS"
 107     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 108
 109     dnl Check for -lXpm
 110     AC_CHECK_HEADERS(X11/xpm.h)
 111     if test "$ac_cv_header_X11_xpm_h" = "yes"
 112     then
 113         AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 114     fi
 115
 116     dnl Check for X Shm extension
 117     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/XShm.h)
 118     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 119     then
 120         AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 121     fi
 122     dnl Check for XFree86 DGA extension
 123     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86dga.h)
 124     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 125     then
 126          AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 127     fi
 128
 129     dnl Check for XFree86 VMODE extension
 130     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86vmode.h)
 131     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 132     then
 133         AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,AC_DEFINE(HAVE_LIBXXF86VM) X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm",,$X_LIBS -lXext -lX11)
 134     fi
 135
 136     dnl Check for the presence of Mesa
 137     AC_CHECK_HEADERS(GL/gl.h GL/osmesa.h)
 138     if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_osmesa_h" = "yes"
 139     then
 140         dnl Check for some problems due to old Mesa versions
 141         AC_CACHE_CHECK("for up-to-date Mesa version", wine_cv_mesa_version_OK,
 142           AC_TRY_COMPILE(
 143             [#include <GL/gl.h>],
 144             [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 145             [wine_cv_mesa_version_OK="yes"],
 146             [wine_cv_mesa_version_OK="no"]
 147           )
 148         )
 149
 150         if test "$wine_cv_mesa_version_OK" = "yes"
 151         then
 152             dnl Check for the presense of the library
 153             AC_CHECK_LIB(MesaGL,OSMesaCreateContext,AC_DEFINE(HAVE_LIBMESAGL) X_PRE_LIBS="$X_PRE_LIBS -lMesaGL",,$X_LIBS -lXext -lX11 -lm)
 154         fi
 155     fi
 156
 157     CPPFLAGS="$ac_save_CPPFLAGS"
 158 else
 159     XLIB=""
 160     X_CFLAGS=""
 161     X_LIBS=""
 162 fi
 163
 164 dnl **** Check which curses lib to use ***
 165 AC_CHECK_HEADERS(ncurses.h)
 166 if test "$ac_cv_header_ncurses_h" = "yes"
 167 then
 168     AC_CHECK_LIB(ncurses,waddch)
 169 fi
 170 if test "$ac_cv_lib_ncurses_waddch" = "yes"
 171 then
 172     AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 173     AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 174 else
 175     AC_CHECK_HEADERS(curses.h)
 176     if test "$ac_cv_header_curses_h" = "yes"
 177     then
 178        AC_CHECK_LIB(curses,waddch)
 179        AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 180        AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 181     fi
 182 fi
 183
 184 dnl **** Check for IPX (currently Linux only) ****
 185 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 186  AC_TRY_COMPILE(
 187    [#include <sys/socket.h>
 188     #include <netipx/ipx.h>],
 189    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 190    [AC_DEFINE(HAVE_IPX_GNU)
 191     ac_cv_c_ipx_gnu="yes"],
 192    [ac_cv_c_ipx_gnu="no"])
 193  )
 194
 195 if test "$ac_cv_c_ipx_gnu" = "no"
 196 then
 197  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 198   AC_TRY_COMPILE(
 199     [#include <sys/socket.h>
 200      #include <asm/types.h>
 201      #include <linux/ipx.h>],
 202     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 203     [AC_DEFINE(HAVE_IPX_LINUX)
 204      ac_cv_c_ipx_linux="yes"],
 205     [ac_cv_c_ipx_linux="no"])
 206   )
 207 fi
 208
 209 dnl **** Check for Open Sound System ****
 210 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 211
 212 AC_CACHE_CHECK("for Open Sound System",
 213         ac_cv_c_opensoundsystem,
 214         AC_TRY_COMPILE([
 215         #if defined(HAVE_SYS_SOUNDCARD_H)
 216                 #include <sys/soundcard.h>
 217         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 218                 #include <machine/soundcard.h>
 219         #elif defined(HAVE_SOUNDCARD_H)
 220                 #include <soundcard.h>
 221         #endif
 222         ],[
 223
 224 /* check for one of the Open Sound System specific SNDCTL_ defines */
 225 #if !defined(SNDCTL_DSP_STEREO)
 226 #error No open sound system
 227 #endif
 228 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 229
 230 if test "$ac_cv_c_opensoundsystem" = "yes"
 231 then
 232     AC_DEFINE(HAVE_OSS)
 233 fi
 234
 235 dnl **** If ln -s doesn't work, use cp instead ****
 236 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 237
 238 dnl **** Check for gcc strength-reduce bug ****
 239
 240 if test "x${GCC}" = "xyes"
 241 then
 242   CFLAGS="$CFLAGS -Wall"
 243   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 244                   AC_TRY_RUN([
 245 int main(void) {
 246   static int Array[[3]];
 247   unsigned int B = 3;
 248   int i;
 249   for(i=0; i<B; i++) Array[[i]] = i - 3;
 250   exit( Array[[1]] != -2 );
 251 }],
 252     ac_cv_c_gcc_strength_bug="no",
 253     ac_cv_c_gcc_strength_bug="yes",
 254     ac_cv_c_gcc_strength_bug="yes") )
 255   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 256   then
 257     CFLAGS="$CFLAGS -fno-strength-reduce"
 258   fi
 259 fi
 260
 261 dnl **** Check for underscore on external symbols ****
 262
 263 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 264                ac_cv_c_extern_prefix,
 265 [saved_libs=$LIBS
 266 LIBS="conftest_asm.s $LIBS"
 267 cat > conftest_asm.s <<EOF
 268         .globl _ac_test
 269 _ac_test:
 270         .long 0
 271 EOF
 272 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 273             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 274 LIBS=$saved_libs])
 275 if test "$ac_cv_c_extern_prefix" = "yes"
 276 then
 277   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 278 fi
 279
 280 dnl **** Check for .string in assembler ****
 281
 282 AC_CACHE_CHECK("whether assembler accepts .string",
 283                ac_cv_c_asm_string,
 284 [saved_libs=$LIBS
 285 LIBS="conftest_asm.s $LIBS"
 286 cat > conftest_asm.s <<EOF
 287         .string "test"
 288 EOF
 289 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 290 LIBS=$saved_libs])
 291 if test "$ac_cv_c_asm_string" = "yes"
 292 then
 293   AC_DEFINE(HAVE_ASM_STRING)
 294 fi
 295
 296 dnl **** Check for working dll ****
 297
 298 DLLFLAGS=""
 299 LDSHARED=""
 300 if test "$LIB_TARGET" = "libwine.so.1.0"
 301 then
 302   AC_CACHE_CHECK("whether we can build a Linux dll",
 303                  ac_cv_c_dll_linux,
 304   [saved_cflags=$CFLAGS
 305   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 306   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 307   CFLAGS=$saved_cflags
 308   ])
 309   if test "$ac_cv_c_dll_linux" = "yes"
 310   then
 311     DLLFLAGS="-fPIC"
 312     LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so"
 313   else
 314     AC_CACHE_CHECK("whether we can build a NetBSD dll",
 315                    ac_cv_c_dll_netbsd,
 316     [saved_cflags=$CFLAGS
 317     CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 318     AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 319     CFLAGS=$saved_cflags
 320     ])
 321     if test "$ac_cv_c_dll_netbsd" = "yes"
 322     then
 323       DLLFLAGS="-fPIC"
 324       LDSHARED="ld -Bshareable -Bforcearchive"
 325     fi
 326   fi
 327   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 328   then
 329     LIB_TARGET="libwine.a"
 330   fi
 331 fi
 332 AC_SUBST(DLLFLAGS)
 333 AC_SUBST(LDSHARED)
 334
 335 dnl **** Check for reentrant libc ****
 336 dnl
 337 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 338 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 339
 340 wine_cv_libc_reentrant=no
 341 dnl
 342 dnl Linux style errno location
 343 dnl
 344 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 345   [AC_TRY_RUN([int myerrno = 0;
 346 char buf[256];
 347 int *__errno_location(){return &myerrno;}
 348 main(){connect(0,buf,255); exit(!myerrno);}],
 349   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 350   wine_cv_libc_r__errno_location=yes )
 351 ])
 352 if test "$wine_cv_libc_r__errno_location" = "yes"
 353 then
 354     AC_DEFINE(HAVE__ERRNO_LOCATION)
 355     wine_cv_libc_reentrant=__errno_location
 356 fi
 357 dnl
 358 dnl FreeBSD style errno location
 359 dnl
 360 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 361   [AC_TRY_RUN([int myerrno = 0;
 362 char buf[256];
 363 int *__error(){return &myerrno;}
 364 main(){connect(0,buf,255); exit(!myerrno);}],
 365     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 366     wine_cv_libc_r__error=yes )
 367 ])
 368 if test "$wine_cv_libc_r__error" = "yes"
 369 then
 370     AC_DEFINE(HAVE__ERROR)
 371     wine_cv_libc_reentrant=__error
 372 fi
 373 dnl
 374 dnl Solaris style errno location
 375 dnl
 376 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 377   [AC_TRY_RUN([int myerrno = 0;
 378 char buf[256];
 379 int *___errno(){return &myerrno;}
 380 main(){connect(0,buf,255); exit(!myerrno);}],
 381     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 382     wine_cv_libc_r___errno=yes )
 383 ])
 384 if test "$wine_cv_libc_r___errno" = "yes"
 385 then
 386     AC_DEFINE(HAVE___ERRNO)
 387     wine_cv_libc_reentrant=___errno
 388 fi
 389 if test "$wine_cv_libc_reentrant" = "no"
 390 then
 391   AC_DEFINE(NO_REENTRANT_LIBC)
 392 fi
 393
 394 dnl **** Check for reentrant X libraries ****
 395 dnl
 396 dnl This may fail to determine whether X libraries are reentrant if
 397 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 398 dnl is possible with the --without-reentrant-x option.
 399
 400 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 401 then
 402 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 403   [ if test "x$with_reentrant_x" = "xno"
 404     then
 405         wine_cv_x_reentrant=no
 406     else
 407         libX11_check=none
 408         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 409             if test -r $dir/libX11.so; then
 410                 libX11_check="-D $dir/libX11.so"
 411                 break 1
 412             fi
 413             if test -r $dir/libX11.a; then
 414                 libX11_check="$dir/libX11.a"
 415                 break 1
 416             fi
 417         done
 418         if test "$libX11_check" != "none"; then
 419             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 420             then
 421                 wine_cv_x_reentrant=yes
 422             else
 423                 wine_cv_x_reentrant=no
 424             fi
 425         else
 426             wine_cv_x_reentrant=unknown
 427         fi
 428     fi ] )
 429 else
 430     wine_cv_x_reentrant=no
 431 fi
 432 if test "$wine_cv_x_reentrant" = "no"
 433 then
 434   AC_DEFINE(NO_REENTRANT_X11)
 435 fi
 436
 437 dnl **** Check for functions ****
 438
 439 AC_CHECK_FUNCS(\
 440         _lwp_create \
 441         clone \
 442         getpagesize \
 443         memmove \
 444         rfork \
 445         sendmsg \
 446         sigaltstack \
 447         strerror \
 448         stricmp \
 449         tcgetattr \
 450         timegm \
 451         usleep \
 452         vfscanf \
 453         wait4 \
 454         waitpid \
 455 )
 456
 457 dnl **** Check for header files ****
 458
 459 AC_CHECK_HEADERS(\
 460         arpa/nameser.h \
 461         curses.h \
 462         dlfcn.h \
 463         elf.h \
 464         float.h \
 465         libio.h \
 466         linux/cdrom.h \
 467         linux/ucdrom.h \
 468         ncurses.h \
 469         net/if.h \
 470         netinet/in.h \
 471         resolv.h \
 472         strings.h \
 473         sys/cdio.h \
 474         sys/file.h \
 475         sys/filio.h \
 476         sys/lwp.h \
 477         sys/modem.h \
 478         sys/mount.h \
 479         sys/param.h \
 480         sys/sockio.h \
 481         sys/statfs.h \
 482         sys/strtio.h \
 483         sys/syscall.h \
 484         sys/vfs.h \
 485         syscall.h \
 486         ucontext.h \
 487         unistd.h \
 488         wctype.h \
 489 )
 490 AC_HEADER_STAT()
 491
 492 dnl **** Check for types ****
 493
 494 AC_C_CONST()
 495 AC_TYPE_SIZE_T()
 496 AC_CHECK_SIZEOF(long long,0)
 497
 498 dnl **** statfs checks ****
 499
 500 if test "$ac_cv_header_sys_vfs_h" = "yes"
 501 then
 502     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 503                     wine_cv_sys_vfs_has_statfs,
 504         AC_TRY_COMPILE([
 505         #include <sys/types.h>
 506         #ifdef HAVE_SYS_PARAM_H
 507         # include <sys/param.h>
 508         #endif
 509         #include <sys/vfs.h>
 510         ],[
 511                 struct statfs stfs;
 512
 513                 memset(&stfs,0,sizeof(stfs));
 514         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 515         )
 516     )
 517     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 518     then
 519       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 520     fi
 521 fi
 522
 523 if test "$ac_cv_header_sys_statfs_h" = "yes"
 524 then
 525     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 526                     wine_cv_sys_statfs_has_statfs,
 527         AC_TRY_COMPILE([
 528         #include <sys/types.h>
 529         #ifdef HAVE_SYS_PARAM_H
 530         # include <sys/param.h>
 531         #endif
 532         #include <sys/statfs.h>
 533         ],[
 534                 struct statfs stfs;
 535         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 536         )
 537     )
 538     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 539     then
 540       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 541     fi
 542 fi
 543
 544 if test "$ac_cv_header_sys_mount_h" = "yes"
 545 then
 546     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 547                     wine_cv_sys_mount_has_statfs,
 548         AC_TRY_COMPILE([
 549         #include <sys/types.h>
 550         #ifdef HAVE_SYS_PARAM_H
 551         # include <sys/param.h>
 552         #endif
 553         #include <sys/mount.h>
 554         ],[
 555                 struct statfs stfs;
 556         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 557         )
 558     )
 559     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 560     then
 561       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 562     fi
 563 fi
 564
 565 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 566
 567 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 568   [ if test "x$statfs_bfree" = "xno"
 569     then
 570         wine_cv_statfs_bfree=no
 571     else
 572         AC_TRY_COMPILE([
 573         #include <sys/types.h>
 574         #ifdef HAVE_SYS_PARAM_H
 575         # include <sys/param.h>
 576         #endif
 577         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 578         # include <sys/mount.h>
 579         #else
 580         # ifdef STATFS_DEFINED_BY_SYS_VFS
 581         #  include <sys/vfs.h>
 582         # else
 583         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 584         #   include <sys/statfs.h>
 585         #  endif
 586         # endif
 587         #endif
 588         ],[
 589                 struct statfs stfs;
 590
 591                 stfs.f_bfree++;
 592         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 593         )
 594     fi ] )
 595 if test "$wine_cv_statfs_bfree" = "yes"
 596 then
 597   AC_DEFINE(STATFS_HAS_BFREE)
 598 fi
 599
 600 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 601   [ if test "x$statfs_bavail" = "xno"
 602     then
 603         wine_cv_statfs_bavail=no
 604     else
 605         AC_TRY_COMPILE([
 606         #include <sys/types.h>
 607         #ifdef HAVE_SYS_PARAM_H
 608         # include <sys/param.h>
 609         #endif
 610         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 611         # include <sys/mount.h>
 612         #else
 613         # ifdef STATFS_DEFINED_BY_SYS_VFS
 614         #  include <sys/vfs.h>
 615         # else
 616         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 617         #   include <sys/statfs.h>
 618         #  endif
 619         # endif
 620         #endif
 621         ],[
 622                 struct statfs stfs;
 623
 624                 stfs.f_bavail++;
 625         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 626         )
 627     fi ] )
 628 if test "$wine_cv_statfs_bavail" = "yes"
 629 then
 630   AC_DEFINE(STATFS_HAS_BAVAIL)
 631 fi
 632
 633 dnl *** check for working sigaltstack
 634 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 635
 636 AC_CACHE_CHECK("for working sigaltstack",
 637         ac_cv_c_working_sigaltstack,
 638         AC_TRY_RUN([
 639         #include <stdio.h>
 640         #include <time.h> /* <sys/time.h> ? bad magic without end */
 641         #include <sys/types.h>
 642         #include <sys/signal.h>
 643         #ifdef HAVE_SYS_PARAM_H
 644         # include <sys/param.h>
 645         #endif
 646         #ifdef HAVE_SYSCALL_H
 647         # include <syscall.h>
 648         #else
 649         # ifdef HAVE_SYS_SYSCALL_H
 650         #  include <sys/syscall.h>
 651         # endif
 652         #endif
 653
 654         unsigned char *xaltstack;
 655
 656         int
 657         main(int argc,char **argv) {
 658             struct sigaltstack  ss;
 659
 660             xaltstack = malloc(16384);
 661             ss.ss_sp    = xaltstack;
 662             ss.ss_size  = 16384;
 663             ss.ss_flags = 0;
 664             if (sigaltstack(&ss, NULL) < 0) {
 665                 /* this catches the glibc case */
 666                 perror("sigaltstack");
 667                 return (1); /* aka exit(1) aka fail */
 668             }
 669             /* assume it works. */
 670             return 0; /* OK */
 671         }
 672         ],
 673         ac_cv_c_working_sigaltstack="yes",
 674         ac_cv_c_working_sigaltstack="no",
 675         ac_cv_c_working_sigaltstack="no"
 676 ))
 677
 678 if test "$ac_cv_c_working_sigaltstack" = "yes"
 679 then
 680     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 681 fi
 682
 683
 684 dnl *** check for file descriptor passing with msg_accrights
 685
 686 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 687  AC_TRY_COMPILE([#include <sys/types.h>
 688 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 689                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 690 if test "$ac_cv_c_msg_accrights" = "yes"
 691 then
 692     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 693 fi
 694
 695 dnl $GCC is set by autoconf
 696 GCC_NO_BUILTIN=""
 697 if test "$GCC" = "yes"
 698 then
 699     GCC_NO_BUILTIN="-fno-builtin"
 700 fi
 701 AC_SUBST(GCC_NO_BUILTIN)
 702
 703 dnl **** Generate output files ****
 704
 705 MAKE_RULES=Make.rules
 706 AC_SUBST_FILE(MAKE_RULES)
 707
 708 AC_OUTPUT([
 709 Make.rules
 710 Makefile
 711 console/Makefile
 712 controls/Makefile
 713 debugger/Makefile
 714 dlls/Makefile
 715 dlls/advapi32/Makefile
 716 dlls/avifil32/Makefile
 717 dlls/comctl32/Makefile
 718 dlls/commdlg/Makefile
 719 dlls/imagehlp/Makefile
 720 dlls/msacm/Makefile
 721 dlls/msacm32/Makefile
 722 dlls/ntdll/Makefile
 723 dlls/psapi/Makefile
 724 dlls/rasapi32/Makefile
 725 dlls/shell32/Makefile
 726 dlls/tapi32/Makefile
 727 dlls/ver/Makefile
 728 dlls/version/Makefile
 729 dlls/winaspi/Makefile
 730 dlls/wnaspi32/Makefile
 731 documentation/Makefile
 732 files/Makefile
 733 graphics/Makefile
 734 graphics/metafiledrv/Makefile
 735 graphics/psdrv/Makefile
 736 graphics/ttydrv/Makefile
 737 graphics/win16drv/Makefile
 738 graphics/x11drv/Makefile
 739 if1632/Makefile
 740 include/Makefile
 741 ipc/Makefile
 742 library/Makefile
 743 libtest/Makefile
 744 loader/Makefile
 745 loader/ne/Makefile
 746 loader/dos/Makefile
 747 memory/Makefile
 748 misc/Makefile
 749 miscemu/Makefile
 750 msdos/Makefile
 751 multimedia/Makefile
 752 objects/Makefile
 753 ole/Makefile
 754 programs/Makefile
 755 programs/clock/Makefile
 756 programs/cmdlgtst/Makefile
 757 programs/control/Makefile
 758 programs/avitools/Makefile
 759 programs/notepad/Makefile
 760 programs/progman/Makefile
 761 programs/regtest/Makefile
 762 programs/regapi/Makefile
 763 programs/view/Makefile
 764 programs/winhelp/Makefile
 765 programs/winver/Makefile
 766 rc/Makefile
 767 relay32/Makefile
 768 resources/Makefile
 769 scheduler/Makefile
 770 server/Makefile
 771 tools/Makefile
 772 tools/wrc/Makefile
 773 tsx11/Makefile
 774 win32/Makefile
 775 windows/Makefile
 776 windows/ttydrv/Makefile
 777 windows/x11drv/Makefile ])
 778
 779 if test "$have_x" = "no"
 780 then
 781   echo
 782   echo "*** Warning: X development files not found. Wine will be built without"
 783   echo "*** X support, which currently does not work, and would probably not be"
 784   echo "*** what you want anyway. You will need to install devel packages of"
 785   echo "*** Xlib/Xfree86 and Xpm at the very least."
 786 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
 787 then
 788   echo
 789   echo "*** Warning: Xpm development files not found. Wine will be built without"
 790   echo "*** Xpm support, which currently does not work. You will need to install"
 791   echo "*** devel packages of Xpm."
 792 fi
 793
 794 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
 795 then
 796   echo
 797   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
 798   echo "*** terminal resize support. Consider upgrading ncurses."
 799 fi
 800
 801 if test "$wine_cv_libc_reentrant" = "no"
 802 then
 803   echo
 804   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 805   echo "*** thread support. Consider upgrading libc to a more recent"
 806   echo "*** reentrant version of libc."
 807 fi
 808
 809 if test "$wine_cv_mesa_version_OK" = "no"
 810 then
 811   echo
 812   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
 813   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)"
 814 fi
 815
 816 echo
 817 echo "Configure finished.  Do 'make depend && make' to compile Wine."
 818 echo
 819
 820 dnl Local Variables:
 821 dnl comment-start: "dnl "
 822 dnl comment-end: ""
 823 dnl comment-start-skip: "\\bdnl\\b\\s *"
 824 dnl compile-command: "autoconf"
 825 dnl End: