programs/winedbg/debug.l

   1 /* -*-C-*-
   2  * Lexical scanner for command line parsing
   3  *
   4  * Copyright 1993 Eric Youngdale
   5  *           2000 Eric Pouech
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 %option noinput nounput interactive 8bit prefix="dbg_"
  23
  24 %{
  25 #include "config.h"
  26 #include <stdlib.h>
  27 #include <string.h>
  28 #include <stdarg.h>
  29
  30 #ifndef HAVE_UNISTD_H
  31 #define YY_NO_UNISTD_H
  32 #endif
  33
  34 #include "debugger.h"
  35 #include "dbg.tab.h"
  36
  37 #undef YY_INPUT
  38
  39 static char** local_lexemes /* = NULL */;
  40 static int next_lexeme /* = 0 */;
  41 static int alloc_lexeme /* = 0 */;
  42
  43 char* lexeme_alloc_size(int size)
  44 {
  45     assert(0 <= next_lexeme && next_lexeme < alloc_lexeme + 1);
  46     if (next_lexeme >= alloc_lexeme)
  47     {
  48         alloc_lexeme += 32;
  49         local_lexemes = dbg_heap_realloc(local_lexemes, alloc_lexeme * sizeof(local_lexemes[0]));
  50         assert(local_lexemes);
  51     }
  52     return local_lexemes[next_lexeme++] = HeapAlloc(GetProcessHeap(), 0, size + 1);
  53 }
  54
  55 static char* lexeme_alloc(const char* lexeme)
  56 {
  57     char*       ptr = lexeme_alloc_size(strlen(lexeme) + 1);
  58     return strcpy(ptr, lexeme);
  59 }
  60
  61 void lexeme_flush(void)
  62 {
  63     while (--next_lexeme >= 0) HeapFree(GetProcessHeap(), 0, local_lexemes[next_lexeme]);
  64     next_lexeme = 0;
  65 }
  66
  67 static int read_input(const char* pfx, char* buf, int size)
  68 {
  69     int len;
  70     static char*  last_line = NULL;
  71     static size_t last_line_idx = 0;
  72
  73     /* try first to fetch the remaining of an existing line */
  74     if (last_line_idx == 0)
  75     {
  76         char* tmp = NULL;
  77         /* no remaining chars to be read from last line, grab a brand new line up to '\n' */
  78         lexeme_flush();
  79         len = input_fetch_entire_line(pfx, &tmp);
  80         if (len < 0) return 0;  /* eof */
  81
  82         /* remove carriage return in newline */
  83         if (len >= 2 && tmp[len - 2] == '\r')
  84         {
  85             tmp[len - 2] = '\n';
  86             tmp[len - 1] = '\0';
  87             len--;
  88         }
  89
  90         /* FIXME: should have a pair of buffers, and switch between the two, instead of
  91          * reallocating a new one for each line
  92          */
  93         if (last_line && (len == 0 || (len == 1 && tmp[0] == '\n')))
  94         {
  95             HeapFree(GetProcessHeap(), 0, tmp);
  96         }
  97         else
  98         {
  99             HeapFree(GetProcessHeap(), 0, last_line);
 100             last_line = tmp;
 101         }
 102     }
 103
 104     len = min(strlen(last_line + last_line_idx), size - 1);
 105     memcpy(buf, last_line + last_line_idx, len);
 106     buf[len] = '\0';
 107     if ((last_line_idx += len) >= strlen(last_line))
 108         last_line_idx = 0;
 109     return len;
 110 }
 111
 112 #define YY_INPUT(buf,result,max_size) \
 113         if ((result = read_input("Wine-dbg>", buf, max_size)) < 0) \
 114             YY_FATAL_ERROR("read_input in flex scanner failed");
 115
 116 static int syntax_error;
 117 %}
 118
 119 DIGIT      [0-9]
 120 HEXDIGIT   [0-9a-fA-F]
 121 FORMAT     [ubcdgiswxa]
 122 IDENTIFIER [_a-zA-Z~?][_a-zA-Z0-9~?@]*
 123 PATHNAME   [\\/_a-zA-Z0-9\.~@][\\/\-_a-zA-Z0-9\.~@]*
 124 STRING     \"[^\n"]+\"
 125
 126 %s FORMAT_EXPECTED
 127 %s INFO_CMD
 128 %s HELP_CMD
 129 %s BD_CMD
 130 %s LOCAL_CMD
 131 %s SHOW_CMD
 132 %s MODE_CMD
 133 %s MAINT_CMD
 134 %s NOCMD
 135 %s PATH_ACCEPTED
 136
 137 %x PATH_EXPECTED
 138 %x ASTRING_EXPECTED
 139 %x NOPROCESS
 140 %%
 141                                         /* set to special state when no process is loaded. */
 142                                         if (!dbg_num_processes() && YYSTATE == INITIAL) {BEGIN(NOPROCESS);}
 143
 144 <<EOF>>                                 { return tEOF; }
 145 <*>\n                                   { BEGIN(INITIAL); syntax_error = 0; return tEOL; }
 146                                         /* Indicates end of command. Reset state. */
 147
 148 "||"                                    { return OP_LOR; }
 149 "&&"                                    { return OP_LAND; }
 150 "=="                                    { return OP_EQ; }
 151 "!="                                    { return OP_NE; }
 152 "<="                                    { return OP_LE; }
 153 ">="                                    { return OP_GE; }
 154 "<<"                                    { return OP_SHL; }
 155 ">>"                                    { return OP_SHR; }
 156 "->"                                    { return OP_DRF; }
 157 "::"                                    { return OP_SCOPE; }
 158 "["                                     { return *yytext; }
 159 "]"                                     { return *yytext; }
 160
 161 "0x"{HEXDIGIT}+                         { sscanf(yytext, "%lx", &dbg_lval.integer); return tNUM; }
 162 {DIGIT}+                                { sscanf(yytext, "%ld", &dbg_lval.integer); return tNUM; }
 163
 164 <FORMAT_EXPECTED>"/"{DIGIT}+{FORMAT}    { char* last;
 165                                           dbg_lval.integer = strtol(yytext+1, &last, 0) << 8;
 166                                           dbg_lval.integer |= *last;
 167                                           return tFORMAT; }
 168
 169 <FORMAT_EXPECTED>"/"{FORMAT}            { dbg_lval.integer = (1 << 8) | yytext[1]; return tFORMAT; }
 170
 171 {STRING}                                { dbg_lval.string = lexeme_alloc(yytext + 1); dbg_lval.string[strlen(dbg_lval.string) - 1] = '\0'; return tSTRING; }
 172 <ASTRING_EXPECTED>[^\n]+                { char* p = yytext; while (*p == ' ' || *p == '\t') p++;
 173                                           dbg_lval.string = lexeme_alloc(p); return tSTRING; }
 174
 175 <INITIAL,NOPROCESS>info|inf|in          { BEGIN(INFO_CMD); return tINFO; }
 176 <INITIAL>up                             { BEGIN(NOCMD); return tUP; }
 177 <INITIAL>down|dow|do                    { BEGIN(NOCMD); return tDOWN; }
 178 <INITIAL,INFO_CMD>frame|fram|fra|fr     { BEGIN(NOCMD); return tFRAME; }
 179 <INITIAL>list|lis|li|l                  { BEGIN(PATH_ACCEPTED); return tLIST; }
 180 <INITIAL>enable|enabl|enab|ena          { BEGIN(BD_CMD); return tENABLE;}
 181 <INITIAL>disable|disabl|disab|disa|dis  { BEGIN(BD_CMD); return tDISABLE; }
 182 <INITIAL>disassemble|disassembl|disassemb|disassem|disasse|disass|disas { BEGIN(NOCMD); return tDISASSEMBLE; }
 183 <INITIAL>locally|local                  { BEGIN(LOCAL_CMD); return tLOCAL; }
 184 <INITIAL,LOCAL_CMD>display|displa|displ|disp    { BEGIN(FORMAT_EXPECTED); return tDISPLAY; }
 185 <INFO_CMD,BD_CMD>display|displa|displ|disp|dis|di|d     { BEGIN(NOCMD); return tDISPLAY; }
 186 <INITIAL>undisplay|undispla|undispl|undisp|undis|undi|und       { BEGIN(NOCMD); return tUNDISPLAY; }
 187 <INITIAL>delete|delet|dele|del          { BEGIN(BD_CMD); return tDELETE; }
 188 <INITIAL,NOPROCESS>quit|qui|qu|q        { BEGIN(NOCMD); return tQUIT; }
 189 <INITIAL>set|se                         { BEGIN(NOCMD); return tSET; }
 190 <INITIAL>x                              { BEGIN(FORMAT_EXPECTED); return tEXAM; }
 191 <INITIAL,NOPROCESS>help|hel|he|"?"      { BEGIN(HELP_CMD); return tHELP; }
 192
 193 <INITIAL,NOPROCESS>backtrace|backtrac|backtra|backt|back|bac|ba|bt { BEGIN(NOCMD); return tBACKTRACE; }
 194 <INITIAL,NOPROCESS>where|wher|whe       { BEGIN(NOCMD); return tBACKTRACE; }
 195
 196 <INITIAL>cont|con|co|c                  { BEGIN(NOCMD); return tCONT; }
 197 <INITIAL>pass|pas|pa                    { BEGIN(NOCMD); return tPASS; }
 198 <INITIAL>condition|conditio|conditi|condit|condi|cond   { BEGIN(NOCMD); return tCOND; }
 199 <INITIAL>step|ste|st|s                  { BEGIN(NOCMD); return tSTEP; }
 200 <INITIAL>next|nex|ne|n                  { BEGIN(NOCMD); return tNEXT; }
 201 <INITIAL>stepi|si                       { BEGIN(NOCMD); return tSTEPI; }
 202 <INITIAL>nexti|ni                       { BEGIN(NOCMD); return tNEXTI; }
 203 <INITIAL>finish|finis|fini|fin|fi       { BEGIN(NOCMD); return tFINISH; }
 204
 205 <INITIAL>abort|abor|abo                 { BEGIN(NOCMD); return tABORT; }
 206 <INITIAL>print|prin|pri|pr|p            { BEGIN(FORMAT_EXPECTED); return tPRINT; }
 207
 208 <INITIAL>show|sho|sh                    { BEGIN(SHOW_CMD); return tSHOW; }
 209 <INITIAL,NOPROCESS>source|sourc|sour|src { BEGIN(PATH_EXPECTED); return tSOURCE; }
 210 <INITIAL>symbolfile|symbols|symbol|sf   { BEGIN(PATH_EXPECTED); return tSYMBOLFILE; }
 211
 212 <INITIAL,INFO_CMD,BD_CMD>break|brea|bre|br|b    { BEGIN(PATH_ACCEPTED); return tBREAK; }
 213 <INITIAL,INFO_CMD,BD_CMD>hbreak|hbrea|hbre|hbr|hb { BEGIN(PATH_ACCEPTED); return tHBREAK; }
 214 <INITIAL>watch|watc|wat                 { BEGIN(NOCMD); return tWATCH; }
 215 <INITIAL>rwatch|rwatc|rwat              { BEGIN(NOCMD); return tRWATCH; }
 216 <INITIAL>whatis|whati|what              { BEGIN(NOCMD); return tWHATIS; }
 217 <INITIAL,NOPROCESS>run|ru|r             { BEGIN(ASTRING_EXPECTED); return tRUN;}
 218 <INITIAL>detach|detac|deta|det          { BEGIN(NOCMD); return tDETACH; }
 219 <INITIAL>kill|kil|ki|k                  { BEGIN(NOCMD); return tKILL; }
 220 <INITIAL,NOPROCESS>maintenance|maint    { BEGIN(MAINT_CMD); return tMAINTENANCE; }
 221 <INITIAL>minidump|mdmp                  { BEGIN(PATH_EXPECTED); return tMINIDUMP; }
 222 <INITIAL>echo                           { BEGIN(ASTRING_EXPECTED); return tECHO; }
 223 <NOPROCESS>attach|attac|atta|att        { BEGIN(NOCMD); return tATTACH; }
 224 <INFO_CMD>share|shar|sha                { return tSHARE; }
 225 <MAINT_CMD>module|modul|mod             { BEGIN(ASTRING_EXPECTED); return tMODULE; }
 226 <INFO_CMD>locals|local|loca|loc         { return tLOCAL; }
 227 <INFO_CMD>class|clas|cla                { return tCLASS; }
 228 <INFO_CMD>process|proces|proce|proc     { return tPROCESS; }
 229 <INFO_CMD>threads|thread|threa|thre|thr|th { return tTHREAD; }
 230 <INFO_CMD>exception|except|exc|ex       { return tEXCEPTION; }
 231 <INFO_CMD>registers|regs|reg|re         { return tREGS; }
 232 <INFO_CMD>allregs|allreg|allre          { return tALLREGS; }
 233 <INFO_CMD>"all-registers"|"all-regs"|"all-reg"|"all-re" { return tALLREGS; }
 234 <INFO_CMD>segments|segment|segm|seg|se  { return tSEGMENTS; }
 235 <INFO_CMD>stack|stac|sta|st             { return tSTACK; }
 236 <INFO_CMD>symbol|symbo|symb|sym         { BEGIN(ASTRING_EXPECTED); return tSYMBOL; }
 237 <INFO_CMD>maps|map                      { return tMAPS; }
 238 <INFO_CMD>window|windo|wind|win|wnd     { return tWND; }
 239 <HELP_CMD>info|inf|in                   { return tINFO; }
 240 <MAINT_CMD>type                         { return tTYPE; }
 241
 242 <INITIAL,SHOW_CMD>directories|directorie|directori|director|directo|direct|direc|direc|dir {
 243                                           BEGIN(PATH_EXPECTED); return tDIR; }
 244
 245 char                                    { return tCHAR; }
 246 short                                   { return tSHORT; }
 247 int                                     { return tINT; }
 248 long                                    { return tLONG; }
 249 float                                   { return tFLOAT; }
 250 double                                  { return tDOUBLE; }
 251 unsigned                                { return tUNSIGNED; }
 252 signed                                  { return tSIGNED; }
 253 struct                                  { return tSTRUCT; }
 254 union                                   { return tUNION; }
 255 enum                                    { return tENUM; }
 256 all                                     { return tALL; }
 257
 258 {IDENTIFIER}                            { dbg_lval.string = lexeme_alloc(yytext); return tIDENTIFIER; }
 259 "$"{IDENTIFIER}                         { dbg_lval.string = lexeme_alloc(yytext+1); return tINTVAR; }
 260
 261 <PATH_EXPECTED,PATH_ACCEPTED>{PATHNAME} { dbg_lval.string = lexeme_alloc(yytext); return tPATH; }
 262
 263 [-+<=>|&^()*/%:!~,\.]                   { return *yytext; }
 264
 265 <*>[ \t\r]+                             /* Eat up whitespace and DOS LF */
 266
 267 <NOPROCESS>.                            { BEGIN(ASTRING_EXPECTED); yyless(0); return tNOPROCESS;}
 268 <*>.                                    { if (syntax_error == 0) { syntax_error++; dbg_printf("Syntax Error (%s)\n", yytext); } }
 269 %%
 270
 271 #ifndef dbg_wrap
 272 int dbg_wrap(void) { return 1; }
 273 #endif