| blob | fea9cfbc98680a979f5384c1396a609d20e73146 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Author: Michael Patra <micky@marie.physik.tu-berlin.de>
3 dnl <patra@itp1.physik.tu-berlin.de>
4 AC_REVISION([configure.in 1.00])
5 AC_INIT(controls/edit.c)
6 AC_CONFIG_HEADER(include/config.h)
7 AC_CONFIG_AUX_DIR(tools)
9 dnl **** Command-line arguments ****
11 dnl Default values
12 LIBEXT=so # library type .so or .a
13 TRACE_MSGS=yes # the TRACE() macro
14 DEBUG_MSGS=yes # the TRACE(), WARN(), and FIXME() macros.
15 CURSES=yes
16 OPENGL=normal
18 AC_ARG_ENABLE(debug,
19 [ --disable-debug compile out all debugging messages],
20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
22 AC_ARG_ENABLE(opengl,
23 [ --enable-opengl force usage of OpenGL even if the latter is thread-safe via pthread],
24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
26 AC_ARG_ENABLE(trace,
27 [ --disable-trace compile out TRACE messages],
28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
30 AC_ARG_WITH(curses,
31 [ --without-curses do not use curses],
32 [if test "$withval" = "no"; then CURSES="no"; fi])
34 AC_ARG_WITH(reentrant-x,
35 [ --without-reentrant-x compile for use with non-reentrant X libraries])
37 AC_SUBST(OPTIONS)
39 if test "$DEBUG_MSGS" = "no"
40 then
41 AC_DEFINE(NO_DEBUG_MSGS, 1, [Define if all debug messages are to be compiled out])
42 fi
44 if test "$TRACE_MSGS" = "no" -o "$DEBUG_MSGS" = "no"
45 then
46 AC_DEFINE(NO_TRACE_MSGS, 1, [Define if TRACE messages are to be compiled out])
47 fi
49 dnl **** Check for some programs ****
51 AC_PROG_MAKE_SET
52 AC_PROG_CC
53 AC_PROG_CPP
54 AC_PATH_XTRA
55 AC_PROG_YACC
56 AC_PROG_LEX
57 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
58 if test "$XLEX" = "none"
59 then
60 echo "*** Error: No suitable lex found. ***"
61 echo " Please install the 'flex' package."
62 exit 1
63 fi
64 AC_PROG_RANLIB
65 AC_PROG_INSTALL
66 AC_PROG_LN_S
67 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
68 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
69 AC_CYGWIN
70 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
72 dnl Check for lint
73 AC_CHECK_PROGS(LINT, lclint lint)
74 if test "$LINT" = "lint"
75 then
76 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
77 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
78 fi
79 AC_SUBST(LINT)
80 AC_SUBST(LINTFLAGS)
82 if test "$CYGWIN" = "yes"
83 then
84 LDCOMBINE="ld -r --enable-stdcall-fixup"
85 else
86 LDCOMBINE="ld -r"
87 fi
88 AC_SUBST(LDCOMBINE)
90 dnl **** Check for some libraries ****
92 dnl Check for -lm
93 AC_CHECK_LIB(m,sqrt)
94 dnl Check for -li386 for NetBSD and OpenBSD
95 AC_CHECK_LIB(i386,i386_set_ldt)
96 dnl Check for -lossaudio for NetBSD
97 AC_CHECK_LIB(ossaudio,_oss_ioctl)
98 dnl Check for -lw for Solaris
99 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
100 dnl Check for -lnsl for Solaris
101 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
102 dnl Check for -lsocket for Solaris
103 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
104 dnl Check for -lxpg4 for FreeBSD
105 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
106 dnl Check for -lmmap for OS/2
107 AC_CHECK_LIB(mmap,mmap)
108 dnl Check for openpty
109 AC_CHECK_FUNCS(openpty,,
110 AC_CHECK_LIB(util,openpty,
111 AC_DEFINE(HAVE_OPENPTY)
112 LIBS="$LIBS -lutil"
113 ))
115 AC_CHECK_HEADERS(dlfcn.h,
116 AC_CHECK_FUNCS(dlopen,,
117 AC_CHECK_LIB(dl,dlopen,
118 AC_DEFINE(HAVE_DLOPEN)
119 LIBS="$LIBS -ldl",
120 LIBEXT="a")
121 ),
122 LIBEXT="a"
123 )
125 JPEGLIB=""
126 AC_SUBST(JPEGLIB)
127 AC_CHECK_HEADERS(jpeglib.h,
128 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
129 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
130 JPEGLIB="-ljpeg"
131 )
132 )
135 AC_SUBST(XLIB)
136 AC_SUBST(X_DLLS)
137 X_DLLS=""
138 AC_SUBST(XFILES)
139 XFILES=""
140 AC_SUBST(OPENGLFILES)
141 OPENGLFILES=""
142 AC_SUBST(OPENGL32_DLL)
143 OPENGL32_DLL=""
144 GLU32FILES=""
145 AC_SUBST(GLU32FILES)
146 GLU32_DLL=""
147 AC_SUBST(GLU32_DLL)
148 if test "$have_x" = "yes"
149 then
150 XLIB="-lXext -lX11"
151 ac_save_CPPFLAGS="$CPPFLAGS"
152 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
154 dnl *** Check for -lXpm
155 AC_CHECK_HEADERS(X11/xpm.h,
156 [ dnl *** If X11/xpm.h exists...
157 AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
158 [ AC_DEFINE(HAVE_LIBXXPM, 1, [Define if you have the Xpm library])
159 X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
160 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
161 )
162 ],
163 [ dnl *** If X11/xpm.h does not exist...
164 dnl NOTE: autoconf does not allow commas inside the third
165 dnl parameter to AC_CHECK_HEADERS, due to some quoting
166 dnl magic it does.
167 echo "Redhat : xpm xpm-devel"
168 echo "Caldera OpenLinux : xpm xpm-devel xpm-devel-static"
169 echo "SuSE : xpm"
170 echo "Debian/Corel Linux: xpm4g xpm4g-dev"
171 echo
172 echo "Or get the sources from ftp.x.org and all its mirror sites from "
173 echo "the directory /contrib/libraries."
174 echo
175 exit 1
176 ]
177 )
179 dnl *** All three of the following tests require X11/Xlib.h
180 AC_CHECK_HEADERS(X11/Xlib.h,
181 [
182 dnl *** Check for X keyboard extension
183 AC_CHECK_HEADERS(X11/XKBlib.h,
184 [ dnl *** If X11/XKBlib.h exists...
185 AC_CHECK_LIB(X11, XkbQueryExtension,
186 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
187 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
188 ],
189 AC_MSG_WARN([XKB extension not found!!])
190 )
192 dnl *** Check for X Shm extension
193 AC_CHECK_HEADERS(X11/extensions/XShm.h,
194 [ dnl *** If X11/extensions/XShm.h exists...
195 AC_CHECK_LIB(Xext, XShmQueryExtension,
196 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
197 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
198 ],
199 AC_MSG_WARN([Xshm extension not found!!])
200 )
202 dnl *** Check for X shape extension
203 AC_CHECK_HEADERS(X11/extensions/shape.h,
204 [ dnl *** If X11/extensions/shape.h exists...
205 AC_CHECK_LIB(Xext,XShapeQueryExtension,
206 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
207 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
208 ],
209 AC_MSG_WARN([XShape extension not found!!])
210 )
212 dnl *** Check for XFree86 DGA / DGA 2.0 extension
213 AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
214 [ dnl *** If X11/extensions/xf86dga.h exists, check
215 dnl *** for XDGAQueryExtension()...
216 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
217 [ dnl *** If found...
218 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
219 [Define if you have the Xxf86dga library version 2])
220 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
221 ],
222 [ dnl *** If not found, look for XF86DGAQueryExtension()
223 dnl *** instead (DGA 2.0 not found)...
224 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
225 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
226 [Define if you have the Xxf86dga library version 1])
227 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
228 ],,
229 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
230 )
231 ],
232 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
233 )
234 ],
235 AC_MSG_WARN([DGA extension not found!!])
236 )
238 dnl *** Check for XFree86 VMODE extension
239 AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
240 [ dnl *** If X11/extensions/xf86vmode.h exists...
241 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
242 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
243 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
244 ],,
245 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
246 )
247 ],
248 AC_MSG_WARN([XFree86 VMODE extension not found!!])
249 )
251 dnl *** Check for XVideo extension supporting XvImages
252 AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
253 [ dnl *** If X11/extensions/Xvlib.h exists...
254 AC_CHECK_LIB(Xv, XvShmCreateImage,
255 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
256 X_PRE_LIBS="$X_PRE_LIBS -lXv"
257 ],,
258 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
259 )
260 ],
261 AC_MSG_WARN([XVideo extension not found !!])
262 )
264 ]
265 ) dnl *** End of X11/Xlib.h check
267 dnl Check for the presence of OpenGL
268 if test $OPENGL = "yes" -o $OPENGL = "normal"
269 then
270 AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
271 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
272 then
273 dnl Check for some problems due to old Mesa versions
274 AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
275 AC_TRY_COMPILE(
276 [#include <GL/gl.h>],
277 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
278 [wine_cv_opengl_version_OK="yes"],
279 [wine_cv_opengl_version_OK="no"]
280 )
281 )
283 dnl Check for the thread-safety of the OpenGL library
284 AC_CACHE_CHECK("for thread-safe OpenGL version",
285 wine_cv_opengl_version_threadsafe,
286 [saved_libs=$LIBS
287 LIBS="$X_LIBS -lGL"
288 AC_TRY_LINK([],[pthread_getspecific();],
289 [wine_cv_opengl_version_threadsafe="yes"],
290 [wine_cv_opengl_version_threadsafe="no"])
291 LIBS=$saved_libs]
292 )
294 if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
295 then
296 dnl Check for the presence of the library
297 AC_CHECK_LIB(GL,glXCreateContext,
298 X_PRE_LIBS="$X_PRE_LIBS -lGL"
299 ,,
300 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
302 if test $ac_cv_lib_GL_glXCreateContext = "yes"
303 then
305 OPENGLFILES='$(OPENGLFILES)'
306 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
308 AC_CHECK_LIB(GL,glXGetProcAddressARB,
309 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
310 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
311 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
313 if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
314 then
315 AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
316 AC_TRY_COMPILE([#include <GL/gl.h>
317 #ifdef HAVE_GL_GLEXT_H
318 # include <GL/glext.h>
319 #endif
320 ],
321 [PFNGLCOLORTABLEEXTPROC test_proc;],
322 [wine_cv_extension_prototypes="yes"],
323 [wine_cv_extension_prototypes="no"]
324 )
325 )
326 if test $wine_cv_extension_prototypes = "yes"
327 then
328 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
329 [Define if the OpenGL headers define extension typedefs])
330 fi
332 OPENGL32_DLL=opengl32
333 fi
335 fi
336 dnl Check for GLU32 library.
337 AC_CHECK_LIB(GLU,gluLookAt,
338 X_PRE_LIBS="$X_PRE_LIBS -lGLU"
339 GLU32FILES='$(GLU32FILES)'
340 GLU32_DLL=glu32
341 ,,
342 $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
343 )
344 fi
345 fi
346 fi
348 CPPFLAGS="$ac_save_CPPFLAGS"
349 X_DLLS='$(X_DLLS)'
350 XFILES='$(XFILES)'
351 else
352 XLIB=""
353 X_CFLAGS=""
354 X_LIBS=""
355 fi
357 dnl **** Check which curses lib to use ***
358 if test "$CURSES" = "yes"
359 then
360 AC_CHECK_HEADERS(ncurses.h,
361 AC_CHECK_LIB(ncurses,waddch),
362 AC_CHECK_HEADERS(curses.h,AC_CHECK_LIB(curses,waddch)))
363 AC_CHECK_FUNCS(getbkgd resizeterm)
364 fi
366 CUPSLIBS=""
367 dnl **** Check for CUPS ****
368 wine_cv_warn_cups_h=no
369 AC_CHECK_LIB(cups,cupsGetPPD,
370 AC_CHECK_HEADER(cups/cups.h,
371 AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
372 CUPSLIBS="-lcups",
373 wine_cv_warn_cups_h=yes)
374 )
375 AC_SUBST(CUPSLIBS)
377 dnl **** Check for FreeType 2 ****
378 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no)
379 if test "$ft_lib" = "no"
380 then
381 FREETYPELIBS=""
382 FREETYPEINCL=""
383 wine_cv_msg_freetype=no
384 else
385 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
386 if test "$ft_devel" = "no"
387 then
388 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
389 if test "$ft_devel2" = "freetype2-config"
390 then
391 ft_devel=$ft_devel2
392 fi
393 fi
394 if test "$ft_devel" = "no"
395 then
396 FREETYPELIBS=""
397 FREETYPEINCL=""
398 wine_cv_msg_freetype=yes
399 else
400 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
401 FREETYPELIBS=`$ft_devel --libs`
402 FREETYPEINCL=`$ft_devel --cflags`
403 ac_save_CPPFLAGS="$CPPFLAGS"
404 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
405 AC_CHECK_HEADERS(freetype/freetype.h \
406 freetype/ftglyph.h \
407 freetype/tttables.h \
408 freetype/ftnames.h \
409 freetype/ftsnames.h \
410 freetype/ttnameid.h)
411 CPPFLAGS="$ac_save_CPPFLAGS"
412 wine_cv_msg_freetype=no
413 fi
414 fi
415 AC_SUBST(FREETYPELIBS)
416 AC_SUBST(FREETYPEINCL)
418 dnl **** Check for parport (currently Linux only) ****
419 AC_CACHE_CHECK("for parport header/ppdev.h", ac_cv_c_ppdev,
420 AC_TRY_COMPILE(
421 [#include <linux/ppdev.h>],
422 [ioctl (1,PPCLAIM,0)],
423 [ac_cv_c_ppdev="yes"],
424 [ac_cv_c_ppdev="no"])
425 )
426 if test "$ac_cv_c_ppdev" = "yes"
427 then
428 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
429 fi
431 dnl **** Check for IPX (currently Linux only) ****
432 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
433 AC_TRY_COMPILE(
434 [#include <sys/socket.h>
435 #include <netipx/ipx.h>],
436 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
437 [ac_cv_c_ipx_gnu="yes"],
438 [ac_cv_c_ipx_gnu="no"])
439 )
440 if test "$ac_cv_c_ipx_gnu" = "yes"
441 then
442 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
443 fi
445 if test "$ac_cv_c_ipx_gnu" = "no"
446 then
447 AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
448 AC_TRY_COMPILE(
449 [#include <sys/socket.h>
450 #include <asm/types.h>
451 #include <linux/ipx.h>],
452 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
453 [ac_cv_c_ipx_linux="yes"],
454 [ac_cv_c_ipx_linux="no"])
455 )
456 if test "$ac_cv_c_ipx_linux" = "yes"
457 then
458 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
459 fi
460 fi
462 dnl **** Check for Open Sound System ****
463 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
465 AC_CACHE_CHECK("for Open Sound System",
466 ac_cv_c_opensoundsystem,
467 AC_TRY_COMPILE([
468 #if defined(HAVE_SYS_SOUNDCARD_H)
469 #include <sys/soundcard.h>
470 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
471 #include <machine/soundcard.h>
472 #elif defined(HAVE_SOUNDCARD_H)
473 #include <soundcard.h>
474 #endif
475 ],[
477 /* check for one of the Open Sound System specific SNDCTL_ defines */
478 #if !defined(SNDCTL_DSP_STEREO)
479 #error No open sound system
480 #endif
481 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
483 if test "$ac_cv_c_opensoundsystem" = "yes"
484 then
485 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
486 fi
488 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
489 ac_cv_c_opensoundsystem_midi,
490 AC_TRY_COMPILE([
491 #if defined(HAVE_SYS_SOUNDCARD_H)
492 #include <sys/soundcard.h>
493 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
494 #include <machine/soundcard.h>
495 #elif defined(HAVE_SOUNDCARD_H)
496 #include <soundcard.h>
497 #endif
498 ],[
500 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
501 #if !defined(SNDCTL_SEQ_SYNC)
502 #error No open sound system MIDI interface
503 #endif
504 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
506 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
507 then
508 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
509 fi
511 dnl **** If ln -s doesn't work, use cp instead ****
512 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
514 dnl **** Check for broken glibc mmap64 ****
516 AC_CACHE_CHECK( "whether mmap64 works defined as mmap", ac_cv_mmap64_works,
517 AC_TRY_RUN([
518 #define _FILE_OFFSET_BITS 64
519 #include <stdio.h>
520 #include <unistd.h>
521 #include <fcntl.h>
522 #include <sys/mman.h>
523 #include <errno.h>
525 int main(int argc,char **argv) {
526 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
527 if (fd == -1) exit(1);
529 unlink("conftest.map");
531 write(fd,"test",4);
533 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
534 (errno == EINVAL)
535 ) {
536 exit(1);
537 }
538 close(fd);
539 fprintf(stderr,"success!\n");
540 exit(0);
541 }
543 ],
544 ac_cv_mmap64_works="yes",
545 ac_cv_mmap64_works="no",
546 ac_cv_mmap64_works="no") )
548 if test "$ac_cv_mmap64_works" = "yes"
549 then
550 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
551 fi
553 dnl **** Check for gcc strength-reduce bug ****
555 if test "x${GCC}" = "xyes"
556 then
557 CFLAGS="$CFLAGS -Wall"
558 AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
559 AC_TRY_RUN([
560 int L[[4]] = {0,1,2,3};
561 int main(void) {
562 static int Array[[3]];
563 unsigned int B = 3;
564 int i;
565 for(i=0; i<B; i++) Array[[i]] = i - 3;
566 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
567 L[[i]] = 4;
569 exit( Array[[1]] != -2 || L[[2]] != 3);
570 }],
571 ac_cv_c_gcc_strength_bug="no",
572 ac_cv_c_gcc_strength_bug="yes",
573 ac_cv_c_gcc_strength_bug="yes") )
574 if test "$ac_cv_c_gcc_strength_bug" = "yes"
575 then
576 CFLAGS="$CFLAGS -fno-strength-reduce"
577 fi
579 dnl Check for -mpreferred-stack-boundary
580 AC_CACHE_CHECK("for gcc -mpreferred-stack-boundary=2 support",
581 ac_cv_c_gcc_stack_boundary,
582 [saved_cflags=$CFLAGS
583 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
584 AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
585 CFLAGS=$saved_cflags
586 ])
587 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
588 then
589 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
590 fi
591 fi
593 dnl **** Check if we need to place .type inside a .def directive ****
595 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
596 ac_cv_c_type_in_def,
597 [saved_libs=$LIBS
598 LIBS="conftest_asm.s $LIBS"
599 cat > conftest_asm.s <<EOF
600 .globl _ac_test
601 .def _ac_test; .scl 2; .type 32; .endef
602 _ac_test:
603 .long 0
604 EOF
605 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
606 LIBS=$saved_libs])
607 if test "$ac_cv_c_type_in_def" = "yes"
608 then
609 AC_DEFINE(NEED_TYPE_IN_DEF, 1, [Define if .type asm directive must be inside a .def directive])
610 fi
612 dnl **** Check for underscore on external symbols ****
614 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
615 ac_cv_c_extern_prefix,
616 [saved_libs=$LIBS
617 LIBS="conftest_asm.s $LIBS"
618 cat > conftest_asm.s <<EOF
619 .globl _ac_test
620 _ac_test:
621 .long 0
622 EOF
623 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
624 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
625 LIBS=$saved_libs])
626 if test "$ac_cv_c_extern_prefix" = "yes"
627 then
628 AC_DEFINE(NEED_UNDERSCORE_PREFIX, 1,
629 [Define if symbols declared in assembly code need an underscore prefix])
630 fi
632 dnl **** Check for .string in assembler ****
634 AC_CACHE_CHECK("whether assembler accepts .string",
635 ac_cv_c_asm_string,
636 [saved_libs=$LIBS
637 LIBS="conftest_asm.s $LIBS"
638 cat > conftest_asm.s <<EOF
639 .string "test"
640 EOF
641 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
642 LIBS=$saved_libs])
643 if test "$ac_cv_c_asm_string" = "yes"
644 then
645 AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
646 fi
648 dnl **** Check for working dll ****
650 LDSHARED=""
651 LDDLLFLAGS=""
652 if test "$LIBEXT" = "so"
653 then
654 AC_CACHE_CHECK("whether we can build a GNU style ELF dll",
655 ac_cv_c_dll_gnuelf,
656 [saved_cflags=$CFLAGS
657 CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
658 AC_TRY_LINK(,[return 1],ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")
659 CFLAGS=$saved_cflags
660 ])
661 if test "$ac_cv_c_dll_gnuelf" = "yes"
662 then
663 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
664 LDDLLFLAGS="-Wl,-Bsymbolic"
665 else
666 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
667 ac_cv_c_dll_unixware,
668 [saved_cflags=$CFLAGS
669 CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
670 AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
671 CFLAGS=$saved_cflags
672 ])
673 if test "$ac_cv_c_dll_unixware" = "yes"
674 then
675 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
676 LDDLLFLAGS="-Wl,-B,symbolic"
677 fi
678 fi
679 if test "$ac_cv_c_dll_gnuelf" = "no" -a "$ac_cv_c_dll_unixware" = "no"
680 then
681 LIBEXT="a"
682 if test "$DLLWRAP" = "dllwrap"; then
683 dnl FIXME - check whether dllwrap works correctly...
684 if test "$CYGWIN" = "yes"; then
685 echo "*** use dllwrap for building shared library."
686 LIBEXT="dll"
687 fi
688 fi
689 fi
690 fi
692 if test "$LIBEXT" = "a"; then
693 echo "*** It is currently not possible to build WINE without shared"
694 echo "*** library (.so) support to allow transparent switch between .so"
695 echo "*** and .dll files."
696 echo "*** If you are using Linux, you will need a newer binutils."
697 exit 1
698 fi
700 DLLFLAGS=""
701 LDPATH=""
703 if test "$LIBEXT" = "so"; then
704 DLLFLAGS="-fPIC"
705 DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
706 LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
707 elif test "$LIBEXT" = "dll"; then
708 #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
709 DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
710 LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
711 else
712 DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) \$(LIBWINE) \$(LIBUNICODE) \$(X_LIBS) \$(XLIB)"
713 AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
714 ac_cv_c_whole_archive,
715 [saved_cflags=$CFLAGS
716 CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
717 AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
718 CFLAGS=$saved_cflags
719 ])
720 if test "$ac_cv_c_whole_archive" = "yes"
721 then
722 DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
723 else
724 AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
725 ac_cv_c_allextract,
726 [saved_cflags=$CFLAGS
727 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
728 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
729 CFLAGS=$saved_cflags
730 ])
731 if test "$ac_cv_c_allextract" = "yes"
732 then
733 DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
734 fi
735 fi
736 fi
738 AC_SUBST(DLL_LINK)
739 AC_SUBST(DLLFLAGS)
740 AC_SUBST(LDSHARED)
741 AC_SUBST(LDDLLFLAGS)
742 AC_SUBST(LIBEXT)
743 AC_SUBST(LDPATH)
745 dnl **** Check for reentrant libc ****
746 dnl
747 dnl For cross-compiling we blindly assume that libc is reentrant. This is
748 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
750 AC_DEFUN(WINE_CHECK_ERRNO,
751 [
752 AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
753 [AC_TRY_RUN([int myerrno = 0;
754 char buf[256];
755 int *$1(){return &myerrno;}
756 main(){connect(0,buf,255); exit(!myerrno);}],
757 wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
758 wine_cv_libc_r_$1=yes )
759 ])
760 if test "$wine_cv_libc_r_$1" = "yes"
761 then
762 wine_cv_libc_reentrant=$1
763 fi
764 ])
766 wine_cv_libc_reentrant=no
767 dnl Linux style errno location
768 WINE_CHECK_ERRNO(__errno_location)
769 dnl FreeBSD style errno location
770 WINE_CHECK_ERRNO(__error)
771 dnl Solaris style errno location
772 WINE_CHECK_ERRNO(___errno)
773 dnl UnixWare style errno location
774 WINE_CHECK_ERRNO(__thr_errno)
775 dnl NetBSD style errno location
776 WINE_CHECK_ERRNO(__errno)
778 if test "$wine_cv_libc_reentrant" != "no"
779 then
780 AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
781 [Define to the name of the function returning errno for reentrant libc])
782 fi
784 dnl **** Check for reentrant X libraries ****
785 dnl
786 dnl This may fail to determine whether X libraries are reentrant if
787 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
788 dnl is possible with the --without-reentrant-x option.
790 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
791 then
792 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
793 [ if test "x$with_reentrant_x" = "xno"
794 then
795 wine_cv_x_reentrant=no
796 else
797 libX11_check=none
798 for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
799 if test -r $dir/libX11.so; then
800 libX11_check="-D $dir/libX11.so"
801 break 1
802 fi
803 if test -r $dir/libX11.a; then
804 libX11_check="$dir/libX11.a"
805 break 1
806 fi
807 done
808 if test "$libX11_check" != "none"; then
809 if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
810 then
811 wine_cv_x_reentrant=yes
812 else
813 wine_cv_x_reentrant=no
814 fi
815 else
816 wine_cv_x_reentrant=unknown
817 fi
818 fi ] )
819 else
820 wine_cv_x_reentrant=no
821 fi
822 if test "$wine_cv_x_reentrant" = "no"
823 then
824 AC_DEFINE(NO_REENTRANT_X11, 1,
825 [Define if X libraries are not reentrant (compiled without -D_REENTRANT)])
826 fi
829 dnl **** Check for functions ****
831 AC_FUNC_ALLOCA()
832 AC_CHECK_FUNCS(\
833 __libc_fork \
834 _lwp_create \
835 clone \
836 ecvt \
837 finite \
838 fpclass \
839 ftruncate64 \
840 getnetbyaddr \
841 getnetbyname \
842 getpagesize \
843 getprotobyname \
844 getprotobynumber \
845 getrlimit \
846 getservbyport \
847 getsockopt \
848 inet_network \
849 lseek64 \
850 lstat \
851 memmove \
852 mmap \
853 rfork \
854 select \
855 sendmsg \
856 settimeofday \
857 sigaltstack \
858 statfs \
859 strcasecmp \
860 strerror \
861 strncasecmp \
862 tcgetattr \
863 timegm \
864 usleep \
865 vfscanf \
866 wait4 \
867 waitpid \
868 )
870 dnl **** Check for header files ****
872 AC_CHECK_HEADERS(\
873 arpa/inet.h \
874 arpa/nameser.h \
875 elf.h \
876 float.h \
877 ieeefp.h \
878 libio.h \
879 libutil.h \
880 link.h \
881 linux/cdrom.h \
882 linux/input.h \
883 linux/joystick.h \
884 linux/ucdrom.h \
885 net/if.h \
886 netdb.h \
887 netinet/in.h \
888 netinet/in_systm.h \
889 netinet/ip.h \
890 netinet/tcp.h \
891 pty.h \
892 resolv.h \
893 sched.h \
894 socket.h \
895 strings.h \
896 sys/cdio.h \
897 sys/errno.h \
898 sys/file.h \
899 sys/filio.h \
900 sys/ipc.h \
901 sys/link.h \
902 sys/lwp.h \
903 sys/mman.h \
904 sys/modem.h \
905 sys/mount.h \
906 sys/msg.h \
907 sys/param.h \
908 sys/ptrace.h \
909 sys/reg.h \
910 sys/signal.h \
911 sys/shm.h \
912 sys/socket.h \
913 sys/sockio.h \
914 sys/statfs.h \
915 sys/strtio.h \
916 sys/syscall.h \
917 sys/user.h \
918 sys/wait.h \
919 sys/v86.h \
920 sys/v86intr.h \
921 sys/vfs.h \
922 sys/vm86.h \
923 syscall.h \
924 ucontext.h \
925 )
926 AC_HEADER_STAT()
928 dnl **** Check for types ****
930 AC_C_CONST()
931 AC_C_INLINE()
932 AC_TYPE_SIZE_T()
933 AC_CHECK_SIZEOF(long long,0)
935 AC_CACHE_CHECK("whether linux/input.h is for real",
936 wine_cv_linux_input_h,
937 AC_TRY_COMPILE([
938 #include <linux/input.h>
939 ] , [
940 int foo = EVIOCGBIT(EV_ABS,42);
941 int bar = BTN_PINKIE;
942 int fortytwo = 42;
943 ],
944 wine_cv_linux_input_h=yes,
945 wine_cv_linux_input_h=no,
946 no
947 )
948 )
949 if test "$wine_cv_linux_input_h" = "yes"
950 then
951 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
952 [Define if we have linux/input.h AND it contains the INPUT event API])
953 fi
956 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
957 wine_cv_linux_gethostbyname_r_6,
958 AC_TRY_COMPILE([
959 #include <netdb.h>
960 ], [
961 char *name=NULL;
962 struct hostent he;
963 struct hostent *result;
964 char *buf=NULL;
965 int bufsize=0;
966 int res,errnr;
967 char *addr=NULL;
968 int addrlen=0;
969 int addrtype=0;
970 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
971 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
972 ],
973 wine_cv_linux_gethostbyname_r_6=yes,
974 wine_cv_linux_gethostbyname_r_6=no
975 )
976 )
977 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
978 then
979 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
980 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
981 fi
983 if test "$ac_cv_header_linux_joystick_h" = "yes"
984 then
985 AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
986 wine_cv_linux_joystick_22_api,
987 AC_TRY_COMPILE([
988 #include <sys/ioctl.h>
989 #include <linux/joystick.h>
991 struct js_event blub;
992 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
993 #error "no 2.2 header"
994 #endif
995 ],/*empty*/,
996 wine_cv_linux_joystick_22_api=yes,
997 wine_cv_linux_joystick_22_api=no,
998 wine_cv_linux_joystick_22_api=no
999 )
1000 )
1001 if test "$wine_cv_linux_joystick_22_api" = "yes"
1002 then
1003 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1004 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1005 fi
1006 fi
1008 dnl **** statfs checks ****
1010 if test "$ac_cv_header_sys_vfs_h" = "yes"
1011 then
1012 AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
1013 wine_cv_sys_vfs_has_statfs,
1014 AC_TRY_COMPILE([
1015 #include <sys/types.h>
1016 #ifdef HAVE_SYS_PARAM_H
1017 # include <sys/param.h>
1018 #endif
1019 #include <sys/vfs.h>
1020 ],[
1021 struct statfs stfs;
1023 memset(&stfs,0,sizeof(stfs));
1024 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1025 )
1026 )
1027 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1028 then
1029 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1030 [Define if the struct statfs is defined by <sys/vfs.h>])
1031 fi
1032 fi
1034 if test "$ac_cv_header_sys_statfs_h" = "yes"
1035 then
1036 AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
1037 wine_cv_sys_statfs_has_statfs,
1038 AC_TRY_COMPILE([
1039 #include <sys/types.h>
1040 #ifdef HAVE_SYS_PARAM_H
1041 # include <sys/param.h>
1042 #endif
1043 #include <sys/statfs.h>
1044 ],[
1045 struct statfs stfs;
1046 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1047 )
1048 )
1049 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1050 then
1051 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1052 [Define if the struct statfs is defined by <sys/statfs.h>])
1053 fi
1054 fi
1056 if test "$ac_cv_header_sys_mount_h" = "yes"
1057 then
1058 AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
1059 wine_cv_sys_mount_has_statfs,
1060 AC_TRY_COMPILE([
1061 #include <sys/types.h>
1062 #ifdef HAVE_SYS_PARAM_H
1063 # include <sys/param.h>
1064 #endif
1065 #include <sys/mount.h>
1066 ],[
1067 struct statfs stfs;
1068 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1069 )
1070 )
1071 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1072 then
1073 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1074 [Define if the struct statfs is defined by <sys/mount.h>])
1075 fi
1076 fi
1078 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1080 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
1081 [ if test "x$statfs_bfree" = "xno"
1082 then
1083 wine_cv_statfs_bfree=no
1084 else
1085 AC_TRY_COMPILE([
1086 #include <sys/types.h>
1087 #ifdef HAVE_SYS_PARAM_H
1088 # include <sys/param.h>
1089 #endif
1090 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1091 # include <sys/mount.h>
1092 #else
1093 # ifdef STATFS_DEFINED_BY_SYS_VFS
1094 # include <sys/vfs.h>
1095 # else
1096 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1097 # include <sys/statfs.h>
1098 # endif
1099 # endif
1100 #endif
1101 ],[
1102 struct statfs stfs;
1104 stfs.f_bfree++;
1105 ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1106 )
1107 fi ] )
1108 if test "$wine_cv_statfs_bfree" = "yes"
1109 then
1110 AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])
1111 fi
1113 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
1114 [ if test "x$statfs_bavail" = "xno"
1115 then
1116 wine_cv_statfs_bavail=no
1117 else
1118 AC_TRY_COMPILE([
1119 #include <sys/types.h>
1120 #ifdef HAVE_SYS_PARAM_H
1121 # include <sys/param.h>
1122 #endif
1123 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1124 # include <sys/mount.h>
1125 #else
1126 # ifdef STATFS_DEFINED_BY_SYS_VFS
1127 # include <sys/vfs.h>
1128 # else
1129 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1130 # include <sys/statfs.h>
1131 # endif
1132 # endif
1133 #endif
1134 ],[
1135 struct statfs stfs;
1137 stfs.f_bavail++;
1138 ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1139 )
1140 fi ] )
1141 if test "$wine_cv_statfs_bavail" = "yes"
1142 then
1143 AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])
1144 fi
1146 dnl *** check for file descriptor passing with msg_accrights
1148 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1149 AC_TRY_COMPILE([#include <sys/types.h>
1150 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1151 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1152 if test "$ac_cv_c_msg_accrights" = "yes"
1153 then
1154 AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])
1155 fi
1157 dnl *** Check for the sa_len member in struct sockaddr
1159 AC_CACHE_CHECK("for sa_len in struct sockaddr", ac_cv_c_sockaddr_sa_len,
1160 AC_TRY_COMPILE([#include <sys/types.h>
1161 #include <sys/socket.h>
1162 ], [static struct sockaddr addr; addr.sa_len = 1],
1163 ac_cv_c_sockaddr_sa_len="yes", ac_cv_c_sockaddr_sa_len="no"))
1164 if test "$ac_cv_c_sockaddr_sa_len" = "yes"
1165 then
1166 AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])
1167 fi
1169 dnl *** Check for the sun_len member in struct sockaddr_un
1171 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sockaddr_sun_len,
1172 AC_TRY_COMPILE([#include <sys/types.h>
1173 #include <sys/socket.h>
1174 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1175 ac_cv_c_sockaddr_sun_len="yes", ac_cv_c_sockaddr_sun_len="no"))
1176 if test "$ac_cv_c_sockaddr_sun_len" = "yes"
1177 then
1178 AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])
1179 fi
1181 dnl *** check for the need to define __i386__
1183 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1184 AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1185 yes
1186 #endif],
1187 ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1188 if test "$ac_cv_cpp_def_i386" = "yes"
1189 then
1190 CFLAGS="$CFLAGS -D__i386__"
1191 LINTFLAGS="$LINTFLAGS -D__i386__"
1192 fi
1194 dnl $GCC is set by autoconf
1195 GCC_NO_BUILTIN=""
1196 if test "$GCC" = "yes"
1197 then
1198 GCC_NO_BUILTIN="-fno-builtin"
1199 fi
1200 AC_SUBST(GCC_NO_BUILTIN)
1202 dnl **** Generate output files ****
1204 AC_OUTPUT_COMMANDS([
1205 extra_subdirs="\
1206 dlls/ddraw/d3ddevice \
1207 dlls/ddraw/dclipper \
1208 dlls/ddraw/ddraw \
1209 dlls/ddraw/direct3d \
1210 dlls/ddraw/dpalette \
1211 dlls/ddraw/dsurface \
1212 dlls/dinput/joystick \
1213 dlls/dinput/keyboard \
1214 dlls/dinput/mouse \
1215 dlls/kernel/messages \
1216 dlls/user/dde \
1217 dlls/user/resources \
1218 dlls/wineps/data \
1219 "
1220 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1222 MAKE_RULES=Make.rules
1223 AC_SUBST_FILE(MAKE_RULES)
1225 MAKE_DLL_RULES=dlls/Makedll.rules
1226 AC_SUBST_FILE(MAKE_DLL_RULES)
1228 MAKE_PROG_RULES=programs/Makeprog.rules
1229 AC_SUBST_FILE(MAKE_PROG_RULES)
1231 AC_OUTPUT([
1232 Make.rules
1233 dlls/Makedll.rules
1234 programs/Makeprog.rules
1235 Makefile
1236 console/Makefile
1237 controls/Makefile
1238 debugger/Makefile
1239 dlls/Makefile
1240 dlls/advapi32/Makefile
1241 dlls/avifil32/Makefile
1242 dlls/comctl32/Makefile
1243 dlls/commdlg/Makefile
1244 dlls/crtdll/Makefile
1245 dlls/dciman32/Makefile
1246 dlls/ddraw/Makefile
1247 dlls/dinput/Makefile
1248 dlls/dplay/Makefile
1249 dlls/dplayx/Makefile
1250 dlls/dsound/Makefile
1251 dlls/gdi/Makefile
1252 dlls/glu32/Makefile
1253 dlls/icmp/Makefile
1254 dlls/imagehlp/Makefile
1255 dlls/imm32/Makefile
1256 dlls/kernel/Makefile
1257 dlls/lzexpand/Makefile
1258 dlls/mpr/Makefile
1259 dlls/msacm/Makefile
1260 dlls/msnet32/Makefile
1261 dlls/msvcrt/Makefile
1262 dlls/msvideo/Makefile
1263 dlls/ntdll/Makefile
1264 dlls/odbc32/Makefile
1265 dlls/ole32/Makefile
1266 dlls/oleaut32/Makefile
1267 dlls/olecli/Makefile
1268 dlls/oledlg/Makefile
1269 dlls/olepro32/Makefile
1270 dlls/olesvr/Makefile
1271 dlls/opengl32/Makefile
1272 dlls/psapi/Makefile
1273 dlls/quartz/Makefile
1274 dlls/rasapi32/Makefile
1275 dlls/richedit/Makefile
1276 dlls/rpcrt4/Makefile
1277 dlls/serialui/Makefile
1278 dlls/setupapi/Makefile
1279 dlls/shdocvw/Makefile
1280 dlls/shell32/Makefile
1281 dlls/shfolder/Makefile
1282 dlls/shlwapi/Makefile
1283 dlls/tapi32/Makefile
1284 dlls/ttydrv/Makefile
1285 dlls/urlmon/Makefile
1286 dlls/user/Makefile
1287 dlls/version/Makefile
1288 dlls/win32s/Makefile
1289 dlls/winaspi/Makefile
1290 dlls/winedos/Makefile
1291 dlls/wineps/Makefile
1292 dlls/wininet/Makefile
1293 dlls/winmm/Makefile
1294 dlls/winmm/joystick/Makefile
1295 dlls/winmm/mcianim/Makefile
1296 dlls/winmm/mciavi/Makefile
1297 dlls/winmm/mcicda/Makefile
1298 dlls/winmm/mciseq/Makefile
1299 dlls/winmm/mciwave/Makefile
1300 dlls/winmm/midimap/Makefile
1301 dlls/winmm/wavemap/Makefile
1302 dlls/winmm/wineoss/Makefile
1303 dlls/winnls/Makefile
1304 dlls/winsock/Makefile
1305 dlls/winspool/Makefile
1306 dlls/wintrust/Makefile
1307 dlls/wow32/Makefile
1308 dlls/wsock32/Makefile
1309 dlls/x11drv/Makefile
1310 documentation/Makefile
1311 documentation/wine.conf.man
1312 documentation/wine.man
1313 files/Makefile
1314 graphics/Makefile
1315 graphics/enhmetafiledrv/Makefile
1316 graphics/metafiledrv/Makefile
1317 graphics/win16drv/Makefile
1318 graphics/x11drv/Makefile
1319 if1632/Makefile
1320 include/Makefile
1321 library/Makefile
1322 libtest/Makefile
1323 loader/Makefile
1324 loader/dos/Makefile
1325 loader/ne/Makefile
1326 memory/Makefile
1327 misc/Makefile
1328 miscemu/Makefile
1329 msdos/Makefile
1330 objects/Makefile
1331 ole/Makefile
1332 programs/Makefile
1333 programs/avitools/Makefile
1334 programs/clock/Makefile
1335 programs/cmdlgtst/Makefile
1336 programs/control/Makefile
1337 programs/notepad/Makefile
1338 programs/osversioncheck/Makefile
1339 programs/progman/Makefile
1340 programs/regapi/Makefile
1341 programs/regtest/Makefile
1342 programs/uninstaller/Makefile
1343 programs/view/Makefile
1344 programs/wcmd/Makefile
1345 programs/winemine/Makefile
1346 programs/winetest/Makefile
1347 programs/winhelp/Makefile
1348 programs/winver/Makefile
1349 relay32/Makefile
1350 scheduler/Makefile
1351 server/Makefile
1352 tools/Makefile
1353 tools/cvdump/Makefile
1354 tools/specmaker/Makefile
1355 tools/winapi/Makefile
1356 tools/winebuild/Makefile
1357 tools/winelauncher
1358 tools/wmc/Makefile
1359 tools/wrc/Makefile
1360 tsx11/Makefile
1361 unicode/Makefile
1362 win32/Makefile
1363 windows/Makefile
1364 windows/x11drv/Makefile ])
1366 if test "$have_x" = "no"
1367 then
1368 echo
1369 echo "*** Warning: X development files not found. Wine will be built without"
1370 echo "*** X support, which currently does not work, and would probably not be"
1371 echo "*** what you want anyway. You will need to install devel packages of"
1372 echo "*** Xlib/Xfree86 and Xpm at the very least."
1373 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1374 then
1375 echo
1376 echo "*** Warning: Xpm development files not found. Wine will be built without"
1377 echo "*** Xpm support, which currently does not work. You will need to install"
1378 echo "*** devel packages of Xpm."
1379 fi
1381 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1382 then
1383 echo
1384 echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1385 echo "*** terminal resize support. Consider upgrading ncurses."
1386 fi
1388 if test "$wine_cv_libc_reentrant" = "no"
1389 then
1390 echo
1391 echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1392 echo "*** thread support. Consider upgrading libc to a more recent"
1393 echo "*** reentrant version of libc."
1394 fi
1396 if test "$wine_cv_opengl_version_OK" = "no"
1397 then
1398 echo
1399 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1400 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1401 fi
1403 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1404 then
1405 echo
1406 echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1407 echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1408 echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1409 echo "*** start configure with '--enable-opengl' to force OpenGL support."
1410 fi
1412 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1413 then
1414 echo
1415 echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1416 echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1417 echo "*** support before reporting bugs."
1418 fi
1420 if test "$wine_cv_warn_cups_h" = "yes"
1421 then
1422 echo
1423 echo "*** Note: You have cups runtime libraries, but no development"
1424 echo "*** libraries. Install the cups-devel package or whichever package"
1425 echo "*** contains cups.h to enable CUPS support in WINE."
1426 fi
1428 if test "$wine_cv_msg_freetype" = "yes"
1429 then
1430 echo
1431 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1432 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1433 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1434 echo "*** enable Wine to use TrueType fonts."
1435 fi
1437 echo
1438 echo "Configure finished. Do 'make depend && make' to compile Wine."
1439 echo
1441 dnl Local Variables:
1442 dnl comment-start: "dnl "
1443 dnl comment-end: ""
1444 dnl comment-start-skip: "\\bdnl\\b\\s *"
1445 dnl compile-command: "autoconf"
1446 dnl End: