programs/winedbg/debug.l

   1 /* -*-C-*-
   2  * Lexical scanner for command line parsing
   3  *
   4  * Copyright 1993 Eric Youngdale
   5  *           2000 Eric Pouech
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20  */
  21
  22 %option nounput
  23
  24 %{
  25 #include <stdlib.h>
  26 #include <string.h>
  27 #include <stdarg.h>
  28
  29 #include "debugger.h"
  30 #include "dbg.tab.h"
  31
  32 #undef YY_INPUT
  33
  34 static int read_input(const char* pfx, char* buf, int size)
  35 {
  36     size_t      len;
  37 static char*  last_line = NULL;
  38 static size_t last_line_idx = 0;
  39
  40     /* try first to fetch the remaining of an existing line */
  41     if (last_line_idx == 0)
  42     {
  43         char* tmp = NULL;
  44         /* no remaining chars to be read from last line, grab a brand new line up to '\n' */
  45         lexeme_flush();
  46         len = input_fetch_entire_line(pfx, &tmp);
  47         /* FIXME: should have a pair of buffers, and switch between the two, instead of
  48          * reallocating a new one for each line
  49          */
  50         if (len == 0 || (len == 1 && tmp[0] == '\n') || (len == 2 && tmp[0] == '\r' && tmp[1] == '\n'))
  51         {
  52             HeapFree(GetProcessHeap(), 0, tmp);
  53         }
  54         else
  55         {
  56             HeapFree(GetProcessHeap(), 0, last_line);
  57             last_line = tmp;
  58         }
  59     }
  60
  61     len = min(strlen(last_line + last_line_idx), size - 1);
  62     memcpy(buf, last_line + last_line_idx, len);
  63     buf[len] = '\0';
  64     if ((last_line_idx += len) >= strlen(last_line))
  65         last_line_idx = 0;
  66     return len;
  67 }
  68
  69 #define YY_INPUT(buf,result,max_size) \
  70         if ((result = read_input("Wine-dbg>", buf, max_size)) < 0) \
  71             YY_FATAL_ERROR("read_input in flex scanner failed");
  72
  73 #define YY_NO_UNPUT
  74
  75 static int syntax_error;
  76 %}
  77
  78 DIGIT      [0-9]
  79 HEXDIGIT   [0-9a-fA-F]
  80 FORMAT     [ubcdgiswx]
  81 IDENTIFIER [_a-zA-Z~][_a-zA-Z0-9~@]*
  82 PATHNAME   [-/_a-zA-Z\.~][-/_a-zA-Z0-9\.~@]*
  83 STRING     \"[^\n"]+\"
  84
  85 %s FORMAT_EXPECTED
  86 %s PATH_EXPECTED
  87 %s INFO_CMD
  88 %s HELP_CMD
  89 %s BD_CMD
  90 %s LOCAL_CMD
  91 %s SHOW_CMD
  92 %s MODE_CMD
  93 %s MAINT_CMD
  94 %s NOCMD
  95
  96 %x ASTRING_EXPECTED
  97 %x NOPROCESS
  98 %%
  99                                         /* set to special state when no process is loaded. */
 100                                         if (!dbg_curr_process && YYSTATE == INITIAL) {BEGIN(NOPROCESS);}
 101
 102 <<EOF>>                                 { return tEOF; }
 103 <*>\n                                   { BEGIN(INITIAL); syntax_error = 0; return tEOL; }
 104                                         /* Indicates end of command. Reset state. */
 105
 106                                         /* This rule must precede the ones below, */
 107                                         /* otherwise paths like '/' or '0x9' would */
 108                                         /* get parsed as an operator or tNUM */
 109 <PATH_EXPECTED>{PATHNAME}               { yylval.string = lexeme_alloc(yytext); return tPATH; }
 110
 111 "||"                                    { return OP_LOR; }
 112 "&&"                                    { return OP_LAND; }
 113 "=="                                    { return OP_EQ; }
 114 "!="                                    { return OP_NE; }
 115 "<="                                    { return OP_LE; }
 116 ">="                                    { return OP_GE; }
 117 "<<"                                    { return OP_SHL; }
 118 ">>"                                    { return OP_SHR; }
 119 "->"                                    { return OP_DRF; }
 120 "::"                                    { return OP_SCOPE; }
 121 [-+<=>|&^()*/%:!~,\.]                   { return *yytext; }
 122 "["                                     { return *yytext; }
 123 "]"                                     { return *yytext; }
 124
 125 "0x"{HEXDIGIT}+                         { sscanf(yytext, "%x", &yylval.integer); return tNUM; }
 126 {DIGIT}+                                { sscanf(yytext, "%d", &yylval.integer); return tNUM; }
 127
 128 <FORMAT_EXPECTED>"/"{DIGIT}+{FORMAT}    { char* last;
 129                                           yylval.integer = strtol(yytext+1, &last, 0) << 8;
 130                                           yylval.integer |= *last;
 131                                           return tFORMAT; }
 132
 133 <FORMAT_EXPECTED>"/"{FORMAT}            { yylval.integer = (1 << 8) | yytext[1]; return tFORMAT; }
 134
 135 {STRING}                                { yylval.string = lexeme_alloc(yytext + 1); yylval.string[strlen(yylval.string) - 1] = '\0'; return tSTRING; }
 136 <ASTRING_EXPECTED>[^\n]+                { char* p = yytext; while (*p == ' ' || *p == '\t') p++;
 137                                           yylval.string = lexeme_alloc(p); return tSTRING; }
 138
 139 <INITIAL,NOPROCESS>info|inf|in          { BEGIN(INFO_CMD); return tINFO; }
 140 <INITIAL>up                             { BEGIN(NOCMD); return tUP; }
 141 <INITIAL>down|dow|do                    { BEGIN(NOCMD); return tDOWN; }
 142 <INITIAL>frame|fram|fra|fr              { BEGIN(NOCMD); return tFRAME; }
 143 <INITIAL>list|lis|li|l                  { BEGIN(PATH_EXPECTED); return tLIST; }
 144 <INITIAL>enable|enabl|enab|ena          { BEGIN(BD_CMD); return tENABLE;}
 145 <INITIAL>disable|disabl|disab|disa|dis  { BEGIN(BD_CMD); return tDISABLE; }
 146 <INITIAL>disassemble|disassembl|disassemb|disassem|disasse|disass|disas { BEGIN(NOCMD); return tDISASSEMBLE; }
 147 <INITIAL>locally|local                  { BEGIN(LOCAL_CMD); return tLOCAL; }
 148 <INITIAL,LOCAL_CMD>display|displa|displ|disp    { BEGIN(FORMAT_EXPECTED); return tDISPLAY; }
 149 <INFO_CMD,BD_CMD>display|displa|displ|disp|dis|di|d     { BEGIN(NOCMD); return tDISPLAY; }
 150 <INITIAL>undisplay|undispla|undispl|undisp|undis|undi|und       { BEGIN(NOCMD); return tUNDISPLAY; }
 151 <INITIAL>delete|delet|dele|del          { BEGIN(BD_CMD); return tDELETE; }
 152 <INITIAL,NOPROCESS>quit|qui|qu|q        { BEGIN(NOCMD); return tQUIT; }
 153 <INITIAL>set|se                         { BEGIN(NOCMD); return tSET; }
 154 <INITIAL>x                              { BEGIN(FORMAT_EXPECTED); return tEXAM; }
 155 <INITIAL,NOPROCESS>help|hel|he|"?"      { BEGIN(HELP_CMD); return tHELP; }
 156
 157 <INITIAL,NOPROCESS>backtrace|backtrac|backtra|backt|back|bac|ba|bt { BEGIN(NOCMD); return tBACKTRACE; }
 158 <INITIAL,NOPROCESS>where|wher|whe       { BEGIN(NOCMD); return tBACKTRACE; }
 159
 160 <INITIAL>cont|con|co|c                  { BEGIN(NOCMD); return tCONT; }
 161 <INITIAL>pass|pas|pa                    { BEGIN(NOCMD); return tPASS; }
 162 <INITIAL>condition|conditio|conditi|condit|condi|cond   { BEGIN(NOCMD); return tCOND; }
 163 <INITIAL>step|ste|st|s                  { BEGIN(NOCMD); return tSTEP; }
 164 <INITIAL>next|nex|ne|n                  { BEGIN(NOCMD); return tNEXT; }
 165 <INITIAL>stepi|si                       { BEGIN(NOCMD); return tSTEPI; }
 166 <INITIAL>nexti|ni                       { BEGIN(NOCMD); return tNEXTI; }
 167 <INITIAL>finish|finis|fini|fin|fi       { BEGIN(NOCMD); return tFINISH; }
 168
 169 <INITIAL>abort|abor|abo                 { BEGIN(NOCMD); return tABORT; }
 170 <INITIAL>print|prin|pri|pr|p            { BEGIN(FORMAT_EXPECTED); return tPRINT; }
 171
 172 <INITIAL>mode                           { BEGIN(MODE_CMD); return tMODE; }
 173 <INITIAL>show|sho|sh                    { BEGIN(SHOW_CMD); return tSHOW; }
 174 <INITIAL,NOPROCESS>source|sourc|sour|src { BEGIN(PATH_EXPECTED); return tSOURCE; }
 175 <INITIAL>symbolfile|symbols|symbol|sf   { BEGIN(PATH_EXPECTED); return tSYMBOLFILE; }
 176
 177 <INITIAL,INFO_CMD,BD_CMD>break|brea|bre|br|b    { BEGIN(NOCMD); return tBREAK; }
 178 <INITIAL>watch|watc|wat                 { BEGIN(NOCMD); return tWATCH; }
 179 <INITIAL>whatis|whati|what              { BEGIN(NOCMD); return tWHATIS; }
 180 <INITIAL,NOPROCESS>run|ru|r             { BEGIN(ASTRING_EXPECTED); return tRUN;}
 181 <INITIAL>detach|detac|deta|det          { BEGIN(NOCMD); return tDETACH; }
 182 <INITIAL>maintenance|maint              { BEGIN(MAINT_CMD); return tMAINTENANCE; }
 183 <INITIAL>minidump|mdmp                  { BEGIN(PATH_EXPECTED); return tMINIDUMP; }
 184 <NOPROCESS>attach|attac|atta|att        { BEGIN(NOCMD); return tATTACH; }
 185 <INFO_CMD>share|shar|sha                { return tSHARE; }
 186 <INFO_CMD>locals|local|loca|loc         { return tLOCAL; }
 187 <INFO_CMD>class|clas|cla                { return tCLASS; }
 188 <INFO_CMD>process|proces|proce|proc     { return tPROCESS; }
 189 <INFO_CMD>threads|thread|threa|thre|thr|th { return tTHREAD; }
 190 <INFO_CMD>exception|except|exc|ex       { return tEXCEPTION; }
 191 <INFO_CMD>registers|regs|reg|re         { return tREGS; }
 192 <INFO_CMD>segments|segment|segm|seg|se  { return tSEGMENTS; }
 193 <INFO_CMD>stack|stac|sta|st             { return tSTACK; }
 194 <INFO_CMD>symbol|symbo|symb|sym         { BEGIN(ASTRING_EXPECTED); return tSYMBOL; }
 195 <INFO_CMD>maps|map                      { return tMAPS; }
 196 <INFO_CMD>window|windo|wind|win|wnd     { return tWND; }
 197 <HELP_CMD>info|inf|in                   { return tINFO; }
 198 <MODE_CMD>vm86                          { return tVM86; }
 199 <MAINT_CMD>type                         { return tTYPE; }
 200
 201 <INITIAL,SHOW_CMD>directories|directorie|directori|director|directo|direct|direc|direc|dir {
 202                                           BEGIN(PATH_EXPECTED); return tDIR; }
 203
 204 char                                    { return tCHAR; }
 205 short                                   { return tSHORT; }
 206 int                                     { return tINT; }
 207 long                                    { return tLONG; }
 208 float                                   { return tFLOAT; }
 209 double                                  { return tDOUBLE; }
 210 unsigned                                { return tUNSIGNED; }
 211 signed                                  { return tSIGNED; }
 212 struct                                  { return tSTRUCT; }
 213 union                                   { return tUNION; }
 214 enum                                    { return tENUM; }
 215 all                                     { return tALL; }
 216
 217 {IDENTIFIER}                            { yylval.string = lexeme_alloc(yytext); return tIDENTIFIER; }
 218 "$"{IDENTIFIER}                         { yylval.string = lexeme_alloc(yytext+1); return tINTVAR; }
 219
 220 <*>[ \t\r]+                             /* Eat up whitespace and DOS LF */
 221
 222 <NOPROCESS>.                            { BEGIN(ASTRING_EXPECTED); yyless(0); return tNOPROCESS;}
 223 <*>.                                    { if (syntax_error == 0) { syntax_error++; dbg_printf("Syntax Error (%s)\n", yytext); } }
 224 %%
 225
 226 #ifndef yywrap
 227 int yywrap(void) { return 1; }
 228 #endif
 229
 230 static char** local_lexemes /* = NULL */;
 231 static int next_lexeme /* = 0 */;
 232 static int alloc_lexeme /* = 0 */;
 233
 234 char* lexeme_alloc_size(int size)
 235 {
 236     assert(0 <= next_lexeme && next_lexeme < alloc_lexeme + 1);
 237     if (next_lexeme >= alloc_lexeme)
 238     {
 239         alloc_lexeme += 32;
 240         local_lexemes = dbg_heap_realloc(local_lexemes, alloc_lexeme * sizeof(local_lexemes[0]));
 241         assert(local_lexemes);
 242     }
 243     return local_lexemes[next_lexeme++] = HeapAlloc(GetProcessHeap(), 0, size + 1);
 244 }
 245
 246 char* lexeme_alloc(const char* lexeme)
 247 {
 248     char*       ptr = lexeme_alloc_size(strlen(lexeme) + 1);
 249     return strcpy(ptr, lexeme);
 250 }
 251
 252 void lexeme_flush(void)
 253 {
 254     while (--next_lexeme >= 0) HeapFree(GetProcessHeap(), 0, local_lexemes[next_lexeme]);
 255     next_lexeme = 0;
 256 }