programs/winedbg/debug.l

   1 /* -*-C-*-
   2  * Lexical scanner for command line parsing
   3  *
   4  * Copyright 1993 Eric Youngdale
   5  *           2000 Eric Pouech
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 %option noinput nounput interactive 8bit prefix="dbg_"
  23
  24 %{
  25 #include "config.h"
  26 #include <stdlib.h>
  27 #include <string.h>
  28 #include <stdarg.h>
  29
  30 #ifndef HAVE_UNISTD_H
  31 #define YY_NO_UNISTD_H
  32 #endif
  33
  34 #include "debugger.h"
  35 #include "dbg.tab.h"
  36
  37 #undef YY_INPUT
  38
  39 static int read_input(const char* pfx, char* buf, int size)
  40 {
  41     int len;
  42     static char*  last_line = NULL;
  43     static size_t last_line_idx = 0;
  44
  45     /* try first to fetch the remaining of an existing line */
  46     if (last_line_idx == 0)
  47     {
  48         char* tmp = NULL;
  49         /* no remaining chars to be read from last line, grab a brand new line up to '\n' */
  50         lexeme_flush();
  51         len = input_fetch_entire_line(pfx, &tmp);
  52         if (len < 0) return 0;  /* eof */
  53         /* FIXME: should have a pair of buffers, and switch between the two, instead of
  54          * reallocating a new one for each line
  55          */
  56         if (last_line && (len == 0 || (len == 1 && tmp[0] == '\n') || (len == 2 && tmp[0] == '\r' && tmp[1] == '\n')))
  57         {
  58             HeapFree(GetProcessHeap(), 0, tmp);
  59         }
  60         else
  61         {
  62             HeapFree(GetProcessHeap(), 0, last_line);
  63             last_line = tmp;
  64         }
  65     }
  66
  67     len = min(strlen(last_line + last_line_idx), size - 1);
  68     memcpy(buf, last_line + last_line_idx, len);
  69     buf[len] = '\0';
  70     if ((last_line_idx += len) >= strlen(last_line))
  71         last_line_idx = 0;
  72     return len;
  73 }
  74
  75 #define YY_INPUT(buf,result,max_size) \
  76         if ((result = read_input("Wine-dbg>", buf, max_size)) < 0) \
  77             YY_FATAL_ERROR("read_input in flex scanner failed");
  78
  79 static int syntax_error;
  80 %}
  81
  82 DIGIT      [0-9]
  83 HEXDIGIT   [0-9a-fA-F]
  84 FORMAT     [ubcdgiswx]
  85 IDENTIFIER [_a-zA-Z~?][_a-zA-Z0-9~?@]*
  86 PATHNAME   [\\/-_a-zA-Z0-9\.~@]+
  87 STRING     \"[^\n"]+\"
  88
  89 %s FORMAT_EXPECTED
  90 %s PATH_EXPECTED
  91 %s INFO_CMD
  92 %s HELP_CMD
  93 %s BD_CMD
  94 %s LOCAL_CMD
  95 %s SHOW_CMD
  96 %s MODE_CMD
  97 %s MAINT_CMD
  98 %s NOCMD
  99
 100 %x ASTRING_EXPECTED
 101 %x NOPROCESS
 102 %%
 103                                         /* set to special state when no process is loaded. */
 104                                         if (!dbg_num_processes() && YYSTATE == INITIAL) {BEGIN(NOPROCESS);}
 105
 106 <<EOF>>                                 { return tEOF; }
 107 <*>\n                                   { BEGIN(INITIAL); syntax_error = 0; return tEOL; }
 108                                         /* Indicates end of command. Reset state. */
 109
 110                                         /* This rule must precede the ones below, */
 111                                         /* otherwise paths like '/' or '0x9' would */
 112                                         /* get parsed as an operator or tNUM */
 113 <PATH_EXPECTED>{PATHNAME}               { dbg_lval.string = lexeme_alloc(yytext); return tPATH; }
 114
 115 "||"                                    { return OP_LOR; }
 116 "&&"                                    { return OP_LAND; }
 117 "=="                                    { return OP_EQ; }
 118 "!="                                    { return OP_NE; }
 119 "<="                                    { return OP_LE; }
 120 ">="                                    { return OP_GE; }
 121 "<<"                                    { return OP_SHL; }
 122 ">>"                                    { return OP_SHR; }
 123 "->"                                    { return OP_DRF; }
 124 "::"                                    { return OP_SCOPE; }
 125 [-+<=>|&^()*/%:!~,\.]                   { return *yytext; }
 126 "["                                     { return *yytext; }
 127 "]"                                     { return *yytext; }
 128
 129 "0x"{HEXDIGIT}+                         { sscanf(yytext, "%x", &dbg_lval.integer); return tNUM; }
 130 {DIGIT}+                                { sscanf(yytext, "%d", &dbg_lval.integer); return tNUM; }
 131
 132 <FORMAT_EXPECTED>"/"{DIGIT}+{FORMAT}    { char* last;
 133                                           dbg_lval.integer = strtol(yytext+1, &last, 0) << 8;
 134                                           dbg_lval.integer |= *last;
 135                                           return tFORMAT; }
 136
 137 <FORMAT_EXPECTED>"/"{FORMAT}            { dbg_lval.integer = (1 << 8) | yytext[1]; return tFORMAT; }
 138
 139 {STRING}                                { dbg_lval.string = lexeme_alloc(yytext + 1); dbg_lval.string[strlen(dbg_lval.string) - 1] = '\0'; return tSTRING; }
 140 <ASTRING_EXPECTED>[^\n]+                { char* p = yytext; while (*p == ' ' || *p == '\t') p++;
 141                                           dbg_lval.string = lexeme_alloc(p); return tSTRING; }
 142
 143 <INITIAL,NOPROCESS>info|inf|in          { BEGIN(INFO_CMD); return tINFO; }
 144 <INITIAL>up                             { BEGIN(NOCMD); return tUP; }
 145 <INITIAL>down|dow|do                    { BEGIN(NOCMD); return tDOWN; }
 146 <INITIAL>frame|fram|fra|fr              { BEGIN(NOCMD); return tFRAME; }
 147 <INITIAL>list|lis|li|l                  { BEGIN(PATH_EXPECTED); return tLIST; }
 148 <INITIAL>enable|enabl|enab|ena          { BEGIN(BD_CMD); return tENABLE;}
 149 <INITIAL>disable|disabl|disab|disa|dis  { BEGIN(BD_CMD); return tDISABLE; }
 150 <INITIAL>disassemble|disassembl|disassemb|disassem|disasse|disass|disas { BEGIN(NOCMD); return tDISASSEMBLE; }
 151 <INITIAL>locally|local                  { BEGIN(LOCAL_CMD); return tLOCAL; }
 152 <INITIAL,LOCAL_CMD>display|displa|displ|disp    { BEGIN(FORMAT_EXPECTED); return tDISPLAY; }
 153 <INFO_CMD,BD_CMD>display|displa|displ|disp|dis|di|d     { BEGIN(NOCMD); return tDISPLAY; }
 154 <INITIAL>undisplay|undispla|undispl|undisp|undis|undi|und       { BEGIN(NOCMD); return tUNDISPLAY; }
 155 <INITIAL>delete|delet|dele|del          { BEGIN(BD_CMD); return tDELETE; }
 156 <INITIAL,NOPROCESS>quit|qui|qu|q        { BEGIN(NOCMD); return tQUIT; }
 157 <INITIAL>set|se                         { BEGIN(NOCMD); return tSET; }
 158 <INITIAL>x                              { BEGIN(FORMAT_EXPECTED); return tEXAM; }
 159 <INITIAL,NOPROCESS>help|hel|he|"?"      { BEGIN(HELP_CMD); return tHELP; }
 160
 161 <INITIAL,NOPROCESS>backtrace|backtrac|backtra|backt|back|bac|ba|bt { BEGIN(NOCMD); return tBACKTRACE; }
 162 <INITIAL,NOPROCESS>where|wher|whe       { BEGIN(NOCMD); return tBACKTRACE; }
 163
 164 <INITIAL>cont|con|co|c                  { BEGIN(NOCMD); return tCONT; }
 165 <INITIAL>pass|pas|pa                    { BEGIN(NOCMD); return tPASS; }
 166 <INITIAL>condition|conditio|conditi|condit|condi|cond   { BEGIN(NOCMD); return tCOND; }
 167 <INITIAL>step|ste|st|s                  { BEGIN(NOCMD); return tSTEP; }
 168 <INITIAL>next|nex|ne|n                  { BEGIN(NOCMD); return tNEXT; }
 169 <INITIAL>stepi|si                       { BEGIN(NOCMD); return tSTEPI; }
 170 <INITIAL>nexti|ni                       { BEGIN(NOCMD); return tNEXTI; }
 171 <INITIAL>finish|finis|fini|fin|fi       { BEGIN(NOCMD); return tFINISH; }
 172
 173 <INITIAL>abort|abor|abo                 { BEGIN(NOCMD); return tABORT; }
 174 <INITIAL>print|prin|pri|pr|p            { BEGIN(FORMAT_EXPECTED); return tPRINT; }
 175
 176 <INITIAL>show|sho|sh                    { BEGIN(SHOW_CMD); return tSHOW; }
 177 <INITIAL,NOPROCESS>source|sourc|sour|src { BEGIN(PATH_EXPECTED); return tSOURCE; }
 178 <INITIAL>symbolfile|symbols|symbol|sf   { BEGIN(PATH_EXPECTED); return tSYMBOLFILE; }
 179
 180 <INITIAL,INFO_CMD,BD_CMD>break|brea|bre|br|b    { BEGIN(NOCMD); return tBREAK; }
 181 <INITIAL,INFO_CMD,BD_CMD>hbreak|hbrea|hbre|hbr|hb { BEGIN(NOCMD); return tHBREAK; }
 182 <INITIAL>watch|watc|wat                 { BEGIN(NOCMD); return tWATCH; }
 183 <INITIAL>whatis|whati|what              { BEGIN(NOCMD); return tWHATIS; }
 184 <INITIAL,NOPROCESS>run|ru|r             { BEGIN(ASTRING_EXPECTED); return tRUN;}
 185 <INITIAL>detach|detac|deta|det          { BEGIN(NOCMD); return tDETACH; }
 186 <INITIAL>kill|kil|ki|k                  { BEGIN(NOCMD); return tKILL; }
 187 <INITIAL,NOPROCESS>maintenance|maint    { BEGIN(MAINT_CMD); return tMAINTENANCE; }
 188 <INITIAL>minidump|mdmp                  { BEGIN(PATH_EXPECTED); return tMINIDUMP; }
 189 <INITIAL>echo                           { BEGIN(ASTRING_EXPECTED); return tECHO; }
 190 <NOPROCESS>attach|attac|atta|att        { BEGIN(NOCMD); return tATTACH; }
 191 <INFO_CMD>share|shar|sha                { return tSHARE; }
 192 <MAINT_CMD>module|modul|mod             { BEGIN(ASTRING_EXPECTED); return tMODULE; }
 193 <INFO_CMD>locals|local|loca|loc         { return tLOCAL; }
 194 <INFO_CMD>class|clas|cla                { return tCLASS; }
 195 <INFO_CMD>process|proces|proce|proc     { return tPROCESS; }
 196 <INFO_CMD>threads|thread|threa|thre|thr|th { return tTHREAD; }
 197 <INFO_CMD>exception|except|exc|ex       { return tEXCEPTION; }
 198 <INFO_CMD>registers|regs|reg|re         { return tREGS; }
 199 <INFO_CMD>allregs|allreg|allre          { return tALLREGS; }
 200 <INFO_CMD>"all-registers"|"all-regs"|"all-reg"|"all-re" { return tALLREGS; }
 201 <INFO_CMD>segments|segment|segm|seg|se  { return tSEGMENTS; }
 202 <INFO_CMD>stack|stac|sta|st             { return tSTACK; }
 203 <INFO_CMD>symbol|symbo|symb|sym         { BEGIN(ASTRING_EXPECTED); return tSYMBOL; }
 204 <INFO_CMD>maps|map                      { return tMAPS; }
 205 <INFO_CMD>window|windo|wind|win|wnd     { return tWND; }
 206 <HELP_CMD>info|inf|in                   { return tINFO; }
 207 <MAINT_CMD>type                         { return tTYPE; }
 208
 209 <INITIAL,SHOW_CMD>directories|directorie|directori|director|directo|direct|direc|direc|dir {
 210                                           BEGIN(PATH_EXPECTED); return tDIR; }
 211
 212 char                                    { return tCHAR; }
 213 short                                   { return tSHORT; }
 214 int                                     { return tINT; }
 215 long                                    { return tLONG; }
 216 float                                   { return tFLOAT; }
 217 double                                  { return tDOUBLE; }
 218 unsigned                                { return tUNSIGNED; }
 219 signed                                  { return tSIGNED; }
 220 struct                                  { return tSTRUCT; }
 221 union                                   { return tUNION; }
 222 enum                                    { return tENUM; }
 223 all                                     { return tALL; }
 224
 225 {IDENTIFIER}                            { dbg_lval.string = lexeme_alloc(yytext); return tIDENTIFIER; }
 226 "$"{IDENTIFIER}                         { dbg_lval.string = lexeme_alloc(yytext+1); return tINTVAR; }
 227
 228 <*>[ \t\r]+                             /* Eat up whitespace and DOS LF */
 229
 230 <NOPROCESS>.                            { BEGIN(ASTRING_EXPECTED); yyless(0); return tNOPROCESS;}
 231 <*>.                                    { if (syntax_error == 0) { syntax_error++; dbg_printf("Syntax Error (%s)\n", yytext); } }
 232 %%
 233
 234 #ifndef dbg_wrap
 235 int dbg_wrap(void) { return 1; }
 236 #endif
 237
 238 static char** local_lexemes /* = NULL */;
 239 static int next_lexeme /* = 0 */;
 240 static int alloc_lexeme /* = 0 */;
 241
 242 char* lexeme_alloc_size(int size)
 243 {
 244     assert(0 <= next_lexeme && next_lexeme < alloc_lexeme + 1);
 245     if (next_lexeme >= alloc_lexeme)
 246     {
 247         alloc_lexeme += 32;
 248         local_lexemes = dbg_heap_realloc(local_lexemes, alloc_lexeme * sizeof(local_lexemes[0]));
 249         assert(local_lexemes);
 250     }
 251     return local_lexemes[next_lexeme++] = HeapAlloc(GetProcessHeap(), 0, size + 1);
 252 }
 253
 254 char* lexeme_alloc(const char* lexeme)
 255 {
 256     char*       ptr = lexeme_alloc_size(strlen(lexeme) + 1);
 257     return strcpy(ptr, lexeme);
 258 }
 259
 260 void lexeme_flush(void)
 261 {
 262     while (--next_lexeme >= 0) HeapFree(GetProcessHeap(), 0, local_lexemes[next_lexeme]);
 263     next_lexeme = 0;
 264 }