?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
wined3d: Rename the TEMP variables in vertexshader.c to R from T for consistency.
[wine/hacks.git] / tools / widl / parser.y
blob4f3ed5712c2cd05ec917f5fae6057bfac2714d29
1 %{
2 /*
3 * IDL Compiler
4 *
5 * Copyright 2002 Ove Kaaven
6 *
7 * This library is free software; you can redistribute it and/or
8 * modify it under the terms of the GNU Lesser General Public
9 * License as published by the Free Software Foundation; either
10 * version 2.1 of the License, or (at your option) any later version.
11 *
12 * This library is distributed in the hope that it will be useful,
13 * but WITHOUT ANY WARRANTY; without even the implied warranty of
14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 * Lesser General Public License for more details.
16 *
17 * You should have received a copy of the GNU Lesser General Public
18 * License along with this library; if not, write to the Free Software
19 * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
20 */
21
22 #include "config.h"
23
24 #include <stdio.h>
25 #include <stdlib.h>
26 #include <stdarg.h>
27 #include <assert.h>
28 #include <ctype.h>
29 #include <string.h>
30 #ifdef HAVE_ALLOCA_H
31 #include <alloca.h>
32 #endif
33
34 #include "windef.h"
35
36 #include "widl.h"
37 #include "utils.h"
38 #include "parser.h"
39 #include "header.h"
40 #include "typelib.h"
41
42 #if defined(YYBYACC)
43 /* Berkeley yacc (byacc) doesn't seem to know about these */
44 /* Some *BSD supplied versions do define these though */
45 # ifndef YYEMPTY
46 # define YYEMPTY (-1) /* Empty lookahead value of yychar */
47 # endif
48 # ifndef YYLEX
49 # define YYLEX yylex()
50 # endif
51
52 #elif defined(YYBISON)
53 /* Bison was used for original development */
54 /* #define YYEMPTY -2 */
55 /* #define YYLEX yylex() */
56
57 #else
58 /* No yacc we know yet */
59 # if !defined(YYEMPTY) || !defined(YYLEX)
60 # error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
61 # elif defined(__GNUC__) /* gcc defines the #warning directive */
62 # warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
63 /* #else we just take a chance that it works... */
64 # endif
65 #endif
66
67 static attr_t *make_attr(enum attr_type type);
68 static attr_t *make_attrv(enum attr_type type, unsigned long val);
69 static attr_t *make_attrp(enum attr_type type, void *val);
70 static expr_t *make_expr(enum expr_type type);
71 static expr_t *make_exprl(enum expr_type type, long val);
72 static expr_t *make_exprs(enum expr_type type, char *val);
73 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
74 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
75 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
76 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
77 static type_t *make_type(unsigned char type, type_t *ref);
78 static typeref_t *make_tref(char *name, type_t *ref);
79 static typeref_t *uniq_tref(typeref_t *ref);
80 static type_t *type_ref(typeref_t *ref);
81 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
82 static ifref_t *make_ifref(type_t *iface);
83 static var_t *make_var(char *name);
84 static func_t *make_func(var_t *def, var_t *args);
85 static class_t *make_class(char *name);
86
87 static type_t *reg_type(type_t *type, const char *name, int t);
88 static type_t *reg_types(type_t *type, var_t *names, int t);
89 static type_t *find_type(const char *name, int t);
90 static type_t *find_type2(char *name, int t);
91 static type_t *get_type(unsigned char type, char *name, int t);
92 static type_t *get_typev(unsigned char type, var_t *name, int t);
93 static int get_struct_type(var_t *fields);
94
95 static var_t *reg_const(var_t *var);
96 static var_t *find_const(char *name, int f);
97
98 #define tsENUM 1
99 #define tsSTRUCT 2
100 #define tsUNION 3
101
102 static type_t std_bool = { "boolean" };
103 static type_t std_int = { "int" };
104 static type_t std_int64 = { "__int64" };
105 static type_t std_uhyper = { "MIDL_uhyper" };
106
107 %}
108 %union {
109 attr_t *attr;
110 expr_t *expr;
111 type_t *type;
112 typeref_t *tref;
113 var_t *var;
114 func_t *func;
115 ifref_t *ifref;
116 class_t *clas;
117 char *str;
118 UUID *uuid;
119 unsigned int num;
120 }
121
122 %token <str> aIDENTIFIER
123 %token <str> aKNOWNTYPE
124 %token <num> aNUM aHEXNUM
125 %token <str> aSTRING
126 %token <uuid> aUUID
127 %token aEOF
128 %token SHL SHR
129 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
130 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
131 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
132 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
133 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
134 %token tDEFAULT
135 %token tDEFAULTCOLLELEM
136 %token tDEFAULTVALUE
137 %token tDEFAULTVTABLE
138 %token tDISPLAYBIND
139 %token tDISPINTERFACE
140 %token tDLLNAME tDOUBLE tDUAL
141 %token tENDPOINT
142 %token tENTRY tENUM tERRORSTATUST
143 %token tEXPLICITHANDLE tEXTERN
144 %token tFLOAT
145 %token tHANDLE
146 %token tHANDLET
147 %token tHELPCONTEXT tHELPFILE
148 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
149 %token tHIDDEN
150 %token tHYPER tID tIDEMPOTENT
151 %token tIIDIS
152 %token tIMMEDIATEBIND
153 %token tIMPLICITHANDLE
154 %token tIMPORT tIMPORTLIB
155 %token tIN tINLINE
156 %token tINPUTSYNC
157 %token tINT tINT64
158 %token tINTERFACE
159 %token tLCID
160 %token tLENGTHIS tLIBRARY
161 %token tLOCAL
162 %token tLONG
163 %token tMETHODS
164 %token tMODULE
165 %token tNONBROWSABLE
166 %token tNONCREATABLE
167 %token tNONEXTENSIBLE
168 %token tOBJECT tODL tOLEAUTOMATION
169 %token tOPTIONAL
170 %token tOUT
171 %token tPOINTERDEFAULT
172 %token tPROPERTIES
173 %token tPROPGET tPROPPUT tPROPPUTREF
174 %token tPTR
175 %token tPUBLIC
176 %token tRANGE
177 %token tREADONLY tREF
178 %token tREQUESTEDIT
179 %token tRESTRICTED
180 %token tRETVAL
181 %token tSHORT
182 %token tSIGNED
183 %token tSINGLE
184 %token tSIZEIS tSIZEOF
185 %token tSMALL
186 %token tSOURCE
187 %token tSTDCALL
188 %token tSTRING tSTRUCT
189 %token tSWITCH tSWITCHIS tSWITCHTYPE
190 %token tTRANSMITAS
191 %token tTYPEDEF
192 %token tUNION
193 %token tUNIQUE
194 %token tUNSIGNED
195 %token tUUID
196 %token tV1ENUM
197 %token tVARARG
198 %token tVERSION
199 %token tVOID
200 %token tWCHAR tWIREMARSHAL
201
202 %type <attr> m_attributes attributes attrib_list attribute
203 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
204 %type <expr> array array_list
205 %type <type> inherit interface interfacehdr interfacedef interfacedec
206 %type <type> dispinterface dispinterfacehdr dispinterfacedef
207 %type <type> module modulehdr moduledef
208 %type <type> base_type int_std
209 %type <type> enumdef structdef typedef uniondef
210 %type <ifref> gbl_statements coclass_ints coclass_int
211 %type <tref> type
212 %type <var> m_args no_args args arg
213 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
214 %type <var> m_ident t_ident ident p_ident pident pident_list
215 %type <var> dispint_props
216 %type <func> funcdef int_statements
217 %type <func> dispint_meths
218 %type <clas> coclass coclasshdr coclassdef
219 %type <num> pointer_type version
220 %type <str> libraryhdr
221
222 %left ','
223 %right '?' ':'
224 %left '|'
225 %left '&'
226 %left '-' '+'
227 %left '*' '/'
228 %left SHL SHR
229 %right '~'
230 %right CAST
231 %right PPTR
232 %right NEG
233
234 %%
235
236 input: gbl_statements { write_proxies($1); write_client($1); write_server($1); }
237 ;
238
239 gbl_statements: { $$ = NULL; }
240 | gbl_statements interfacedec { $$ = $1; }
241 | gbl_statements interfacedef { $$ = make_ifref($2); LINK($$, $1); }
242 | gbl_statements coclassdef { $$ = $1; add_coclass($2); }
243 | gbl_statements moduledef { $$ = $1; add_module($2); }
244 | gbl_statements librarydef { $$ = $1; }
245 | gbl_statements statement { $$ = $1; }
246 ;
247
248 imp_statements: {}
249 | imp_statements interfacedec { if (!parse_only) add_interface($2); }
250 | imp_statements interfacedef { if (!parse_only) add_interface($2); }
251 | imp_statements coclassdef { if (!parse_only) add_coclass($2); }
252 | imp_statements moduledef { if (!parse_only) add_module($2); }
253 | imp_statements statement {}
254 | imp_statements importlib {}
255 ;
256
257 int_statements: { $$ = NULL; }
258 | int_statements funcdef ';' { $$ = $2; LINK($$, $1); }
259 | int_statements statement { $$ = $1; }
260 ;
261
262 statement: ';' {}
263 | constdef ';' { if (!parse_only && do_header) { write_constdef($1); } }
264 | cppquote {}
265 | enumdef ';' { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
266 | externdef ';' { if (!parse_only && do_header) { write_externdef($1); } }
267 | import {}
268 | structdef ';' { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
269 | typedef ';' {}
270 | uniondef ';' { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
271 ;
272
273 cppquote: tCPPQUOTE '(' aSTRING ')' { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
274 ;
275 import_start: tIMPORT aSTRING ';' { assert(yychar == YYEMPTY);
276 if (!do_import($2)) yychar = aEOF; }
277 ;
278 import: import_start imp_statements aEOF {}
279 ;
280
281 importlib: tIMPORTLIB '(' aSTRING ')' { if(!parse_only) add_importlib($3); }
282 ;
283
284 libraryhdr: tLIBRARY aIDENTIFIER { $$ = $2; }
285 ;
286 library_start: attributes libraryhdr '{' { start_typelib($2, $1);
287 if (!parse_only && do_header) write_library($2, $1); }
288 ;
289 librarydef: library_start imp_statements '}' { end_typelib(); }
290 ;
291
292 m_args: { $$ = NULL; }
293 | args
294 ;
295
296 no_args: tVOID { $$ = NULL; }
297 ;
298
299 args: arg
300 | args ',' arg { LINK($3, $1); $$ = $3; }
301 | no_args
302 ;
303
304 /* split into two rules to get bison to resolve a tVOID conflict */
305 arg: attributes type pident array { $$ = $3;
306 set_type($$, $2, $4);
307 $$->attrs = $1;
308 }
309 | type pident array { $$ = $2;
310 set_type($$, $1, $3);
311 }
312 | attributes type pident '(' m_args ')' { $$ = $3;
313 $$->ptr_level--;
314 set_type($$, $2, NULL);
315 $$->attrs = $1;
316 $$->args = $5;
317 }
318 | type pident '(' m_args ')' { $$ = $2;
319 $$->ptr_level--;
320 set_type($$, $1, NULL);
321 $$->args = $4;
322 }
323 ;
324
325 array: { $$ = NULL; }
326 | '[' array_list ']' { $$ = $2; }
327 | '[' '*' ']' { $$ = make_expr(EXPR_VOID); }
328 ;
329
330 array_list: m_expr /* size of first dimension is optional */
331 | array_list ',' expr { LINK($3, $1); $$ = $3; }
332 | array_list ']' '[' expr { LINK($4, $1); $$ = $4; }
333 ;
334
335 m_attributes: { $$ = NULL; }
336 | attributes
337 ;
338
339 attributes:
340 '[' attrib_list ']' { $$ = $2; }
341 ;
342
343 attrib_list: attribute
344 | attrib_list ',' attribute { LINK($3, $1); $$ = $3; }
345 | attrib_list ']' '[' attribute { LINK($4, $1); $$ = $4; }
346 ;
347
348 attribute:
349 tAGGREGATABLE { $$ = make_attr(ATTR_AGGREGATABLE); }
350 | tAPPOBJECT { $$ = make_attr(ATTR_APPOBJECT); }
351 | tASYNC { $$ = make_attr(ATTR_ASYNC); }
352 | tAUTOHANDLE { $$ = make_attr(ATTR_AUTO_HANDLE); }
353 | tBINDABLE { $$ = make_attr(ATTR_BINDABLE); }
354 | tCALLAS '(' ident ')' { $$ = make_attrp(ATTR_CALLAS, $3); }
355 | tCASE '(' expr_list_const ')' { $$ = make_attrp(ATTR_CASE, $3); }
356 | tCONTEXTHANDLE { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
357 | tCONTEXTHANDLENOSERIALIZE { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
358 | tCONTEXTHANDLESERIALIZE { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
359 | tCONTROL { $$ = make_attr(ATTR_CONTROL); }
360 | tDEFAULT { $$ = make_attr(ATTR_DEFAULT); }
361 | tDEFAULTCOLLELEM { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
362 | tDEFAULTVALUE '(' expr_const ')' { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
363 | tDEFAULTVALUE '(' aSTRING ')' { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
364 | tDEFAULTVTABLE { $$ = make_attr(ATTR_DEFAULTVTABLE); }
365 | tDISPLAYBIND { $$ = make_attr(ATTR_DISPLAYBIND); }
366 | tDLLNAME '(' aSTRING ')' { $$ = make_attrp(ATTR_DLLNAME, $3); }
367 | tDUAL { $$ = make_attr(ATTR_DUAL); }
368 | tENDPOINT '(' aSTRING ')' { $$ = make_attrp(ATTR_ENDPOINT, $3); }
369 | tENTRY '(' aSTRING ')' { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
370 | tENTRY '(' expr_const ')' { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
371 | tEXPLICITHANDLE { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
372 | tHANDLE { $$ = make_attr(ATTR_HANDLE); }
373 | tHELPCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
374 | tHELPFILE '(' aSTRING ')' { $$ = make_attrp(ATTR_HELPFILE, $3); }
375 | tHELPSTRING '(' aSTRING ')' { $$ = make_attrp(ATTR_HELPSTRING, $3); }
376 | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
377 | tHELPSTRINGDLL '(' aSTRING ')' { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
378 | tHIDDEN { $$ = make_attr(ATTR_HIDDEN); }
379 | tID '(' expr_const ')' { $$ = make_attrp(ATTR_ID, $3); }
380 | tIDEMPOTENT { $$ = make_attr(ATTR_IDEMPOTENT); }
381 | tIIDIS '(' ident ')' { $$ = make_attrp(ATTR_IIDIS, $3); }
382 | tIMMEDIATEBIND { $$ = make_attr(ATTR_IMMEDIATEBIND); }
383 | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')' { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
384 | tIN { $$ = make_attr(ATTR_IN); }
385 | tINPUTSYNC { $$ = make_attr(ATTR_INPUTSYNC); }
386 | tLENGTHIS '(' m_exprs ')' { $$ = make_attrp(ATTR_LENGTHIS, $3); }
387 | tLOCAL { $$ = make_attr(ATTR_LOCAL); }
388 | tNONBROWSABLE { $$ = make_attr(ATTR_NONBROWSABLE); }
389 | tNONCREATABLE { $$ = make_attr(ATTR_NONCREATABLE); }
390 | tNONEXTENSIBLE { $$ = make_attr(ATTR_NONEXTENSIBLE); }
391 | tOBJECT { $$ = make_attr(ATTR_OBJECT); }
392 | tODL { $$ = make_attr(ATTR_ODL); }
393 | tOLEAUTOMATION { $$ = make_attr(ATTR_OLEAUTOMATION); }
394 | tOPTIONAL { $$ = make_attr(ATTR_OPTIONAL); }
395 | tOUT { $$ = make_attr(ATTR_OUT); }
396 | tPOINTERDEFAULT '(' pointer_type ')' { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
397 | tPROPGET { $$ = make_attr(ATTR_PROPGET); }
398 | tPROPPUT { $$ = make_attr(ATTR_PROPPUT); }
399 | tPROPPUTREF { $$ = make_attr(ATTR_PROPPUTREF); }
400 | tPUBLIC { $$ = make_attr(ATTR_PUBLIC); }
401 | tRANGE '(' expr_const ',' expr_const ')' { LINK($5, $3); $$ = make_attrp(ATTR_RANGE, $5); }
402 | tREADONLY { $$ = make_attr(ATTR_READONLY); }
403 | tREQUESTEDIT { $$ = make_attr(ATTR_REQUESTEDIT); }
404 | tRESTRICTED { $$ = make_attr(ATTR_RESTRICTED); }
405 | tRETVAL { $$ = make_attr(ATTR_RETVAL); }
406 | tSIZEIS '(' m_exprs ')' { $$ = make_attrp(ATTR_SIZEIS, $3); }
407 | tSOURCE { $$ = make_attr(ATTR_SOURCE); }
408 | tSTRING { $$ = make_attr(ATTR_STRING); }
409 | tSWITCHIS '(' expr ')' { $$ = make_attrp(ATTR_SWITCHIS, $3); }
410 | tSWITCHTYPE '(' type ')' { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
411 | tTRANSMITAS '(' type ')' { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
412 | tUUID '(' aUUID ')' { $$ = make_attrp(ATTR_UUID, $3); }
413 | tV1ENUM { $$ = make_attr(ATTR_V1ENUM); }
414 | tVARARG { $$ = make_attr(ATTR_VARARG); }
415 | tVERSION '(' version ')' { $$ = make_attrv(ATTR_VERSION, $3); }
416 | tWIREMARSHAL '(' type ')' { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
417 | pointer_type { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
418 ;
419
420 callconv:
421 | tSTDCALL
422 ;
423
424 cases: { $$ = NULL; }
425 | cases case { if ($2) { LINK($2, $1); $$ = $2; }
426 else { $$ = $1; }
427 }
428 ;
429
430 case: tCASE expr ':' field { attr_t *a = make_attrp(ATTR_CASE, $2);
431 $$ = $4; if (!$$) $$ = make_var(NULL);
432 LINK(a, $$->attrs); $$->attrs = a;
433 }
434 | tDEFAULT ':' field { attr_t *a = make_attr(ATTR_DEFAULT);
435 $$ = $3; if (!$$) $$ = make_var(NULL);
436 LINK(a, $$->attrs); $$->attrs = a;
437 }
438 ;
439
440 constdef: tCONST type ident '=' expr_const { $$ = reg_const($3);
441 set_type($$, $2, NULL);
442 $$->eval = $5;
443 }
444 ;
445
446 enums: { $$ = NULL; }
447 | enum_list ',' { $$ = $1; }
448 | enum_list
449 ;
450
451 enum_list: enum { if (!$$->eval)
452 $$->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
453 }
454 | enum_list ',' enum { LINK($3, $1); $$ = $3;
455 if (!$$->eval)
456 $$->eval = make_exprl(EXPR_NUM, $1->eval->cval + 1);
457 }
458 ;
459
460 enum: ident '=' expr_const { $$ = reg_const($1);
461 $$->eval = $3;
462 $$->type = make_type(RPC_FC_LONG, &std_int);
463 }
464 | ident { $$ = reg_const($1);
465 $$->type = make_type(RPC_FC_LONG, &std_int);
466 }
467 ;
468
469 enumdef: tENUM t_ident '{' enums '}' { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
470 $$->fields = $4;
471 $$->defined = TRUE;
472 if(in_typelib)
473 add_enum($$);
474 }
475 ;
476
477 m_exprs: m_expr
478 | m_exprs ',' m_expr { LINK($3, $1); $$ = $3; }
479 ;
480
481 /*
482 exprs: { $$ = make_expr(EXPR_VOID); }
483 | expr_list
484 ;
485
486 expr_list: expr
487 | expr_list ',' expr { LINK($3, $1); $$ = $3; }
488 ;
489 */
490
491 m_expr: { $$ = make_expr(EXPR_VOID); }
492 | expr
493 ;
494
495 expr: aNUM { $$ = make_exprl(EXPR_NUM, $1); }
496 | aHEXNUM { $$ = make_exprl(EXPR_HEXNUM, $1); }
497 | aIDENTIFIER { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
498 | expr '?' expr ':' expr { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
499 | expr '|' expr { $$ = make_expr2(EXPR_OR , $1, $3); }
500 | expr '&' expr { $$ = make_expr2(EXPR_AND, $1, $3); }
501 | expr '+' expr { $$ = make_expr2(EXPR_ADD, $1, $3); }
502 | expr '-' expr { $$ = make_expr2(EXPR_SUB, $1, $3); }
503 | expr '*' expr { $$ = make_expr2(EXPR_MUL, $1, $3); }
504 | expr '/' expr { $$ = make_expr2(EXPR_DIV, $1, $3); }
505 | expr SHL expr { $$ = make_expr2(EXPR_SHL, $1, $3); }
506 | expr SHR expr { $$ = make_expr2(EXPR_SHR, $1, $3); }
507 | '~' expr { $$ = make_expr1(EXPR_NOT, $2); }
508 | '-' expr %prec NEG { $$ = make_expr1(EXPR_NEG, $2); }
509 | '*' expr %prec PPTR { $$ = make_expr1(EXPR_PPTR, $2); }
510 | '(' type ')' expr %prec CAST { $$ = make_exprt(EXPR_CAST, $2, $4); }
511 | tSIZEOF '(' type ')' { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
512 | '(' expr ')' { $$ = $2; }
513 ;
514
515 expr_list_const: expr_const
516 | expr_list_const ',' expr_const { LINK($3, $1); $$ = $3; }
517 ;
518
519 expr_const: expr { $$ = $1;
520 if (!$$->is_const)
521 yyerror("expression is not constant");
522 }
523 ;
524
525 externdef: tEXTERN tCONST type ident { $$ = $4;
526 set_type($$, $3, NULL);
527 }
528 ;
529
530 fields: { $$ = NULL; }
531 | fields field { if ($2) { LINK($2, $1); $$ = $2; }
532 else { $$ = $1; }
533 }
534 ;
535
536 field: s_field ';' { $$ = $1; }
537 | m_attributes uniondef ';' { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
538 | attributes ';' { $$ = make_var(NULL); $$->attrs = $1; }
539 | ';' { $$ = NULL; }
540 ;
541
542 s_field: m_attributes type pident array { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
543 ;
544
545 funcdef:
546 m_attributes type callconv pident
547 '(' m_args ')' { set_type($4, $2, NULL);
548 $4->attrs = $1;
549 $$ = make_func($4, $6);
550 if (is_attr($4->attrs, ATTR_IN)) {
551 yyerror("inapplicable attribute [in] for function '%s'",$$->def->name);
552 }
553 }
554 ;
555
556 m_ident: { $$ = NULL; }
557 | ident
558 ;
559
560 t_ident: { $$ = NULL; }
561 | aIDENTIFIER { $$ = make_var($1); }
562 | aKNOWNTYPE { $$ = make_var($1); }
563 ;
564
565 ident: aIDENTIFIER { $$ = make_var($1); }
566 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
567 | aKNOWNTYPE { $$ = make_var($<str>1); }
568 | tASYNC { $$ = make_var($<str>1); }
569 | tID { $$ = make_var($<str>1); }
570 | tLCID { $$ = make_var($<str>1); }
571 | tRANGE { $$ = make_var($<str>1); }
572 | tRETVAL { $$ = make_var($<str>1); }
573 | tVERSION { $$ = make_var($<str>1); }
574 ;
575
576 base_type: tBYTE { $$ = make_type(RPC_FC_BYTE, NULL); }
577 | tWCHAR { $$ = make_type(RPC_FC_WCHAR, NULL); }
578 | int_std
579 | tSIGNED int_std { $$ = $2; $$->sign = 1; }
580 | tUNSIGNED int_std { $$ = $2; $$->sign = -1;
581 switch ($$->type) {
582 case RPC_FC_CHAR: break;
583 case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
584 case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
585 case RPC_FC_LONG: $$->type = RPC_FC_ULONG; break;
586 case RPC_FC_HYPER:
587 if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
588 break;
589 default: break;
590 }
591 }
592 | tUNSIGNED { $$ = make_type(RPC_FC_ULONG, &std_int); $$->sign = -1; }
593 | tFLOAT { $$ = make_type(RPC_FC_FLOAT, NULL); }
594 | tSINGLE { $$ = make_type(RPC_FC_FLOAT, NULL); }
595 | tDOUBLE { $$ = make_type(RPC_FC_DOUBLE, NULL); }
596 | tBOOLEAN { $$ = make_type(RPC_FC_BYTE, &std_bool); /* ? */ }
597 | tERRORSTATUST { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
598 | tHANDLET { $$ = make_type(RPC_FC_BIND_PRIMITIVE, NULL); /* ? */ }
599 ;
600
601 m_int:
602 | tINT
603 ;
604
605 int_std: tINT { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
606 | tSHORT m_int { $$ = make_type(RPC_FC_SHORT, NULL); }
607 | tSMALL { $$ = make_type(RPC_FC_SMALL, NULL); }
608 | tLONG m_int { $$ = make_type(RPC_FC_LONG, NULL); }
609 | tHYPER m_int { $$ = make_type(RPC_FC_HYPER, NULL); }
610 | tINT64 { $$ = make_type(RPC_FC_HYPER, &std_int64); }
611 | tCHAR { $$ = make_type(RPC_FC_CHAR, NULL); }
612 ;
613
614 coclass: tCOCLASS aIDENTIFIER { $$ = make_class($2); }
615 | tCOCLASS aKNOWNTYPE { $$ = make_class($2); }
616 ;
617
618 coclasshdr: attributes coclass { $$ = $2;
619 $$->attrs = $1;
620 if (!parse_only && do_header)
621 write_coclass($$);
622 }
623 ;
624
625 coclassdef: coclasshdr '{' coclass_ints '}' { $$ = $1;
626 $$->ifaces = $3;
627 }
628 ;
629
630 coclass_ints: { $$ = NULL; }
631 | coclass_ints coclass_int { LINK($2, $1); $$ = $2; }
632 ;
633
634 coclass_int:
635 m_attributes interfacedec { $$ = make_ifref($2); $$->attrs = $1; }
636 ;
637
638 dispinterface: tDISPINTERFACE aIDENTIFIER { $$ = get_type(0, $2, 0); }
639 | tDISPINTERFACE aKNOWNTYPE { $$ = get_type(0, $2, 0); }
640 ;
641
642 dispinterfacehdr: attributes dispinterface { attr_t *attrs;
643 $$ = $2;
644 if ($$->defined) yyerror("multiple definition error");
645 attrs = make_attr(ATTR_DISPINTERFACE);
646 LINK(attrs, $1);
647 $$->attrs = attrs;
648 $$->ref = find_type("IDispatch", 0);
649 if (!$$->ref) yyerror("IDispatch is undefined");
650 $$->defined = TRUE;
651 if (!parse_only && do_header) write_forward($$);
652 }
653 ;
654
655 dispint_props: tPROPERTIES ':' { $$ = NULL; }
656 | dispint_props s_field ';' { LINK($2, $1); $$ = $2; }
657 ;
658
659 dispint_meths: tMETHODS ':' { $$ = NULL; }
660 | dispint_meths funcdef ';' { LINK($2, $1); $$ = $2; }
661 ;
662
663 dispinterfacedef: dispinterfacehdr '{'
664 dispint_props
665 dispint_meths
666 '}' { $$ = $1;
667 $$->fields = $3;
668 $$->funcs = $4;
669 if (!parse_only && do_header) write_dispinterface($$);
670 }
671 /* FIXME: not sure how to handle this yet
672 | dispinterfacehdr '{' interface '}' { $$ = $1;
673 if (!parse_only && do_header) write_interface($$);
674 }
675 */
676 ;
677
678 inherit: { $$ = NULL; }
679 | ':' aKNOWNTYPE { $$ = find_type2($2, 0); }
680 ;
681
682 interface: tINTERFACE aIDENTIFIER { $$ = get_type(RPC_FC_IP, $2, 0); }
683 | tINTERFACE aKNOWNTYPE { $$ = get_type(RPC_FC_IP, $2, 0); }
684 ;
685
686 interfacehdr: attributes interface { $$ = $2;
687 if ($$->defined) yyerror("multiple definition error");
688 $$->attrs = $1;
689 $$->defined = TRUE;
690 if (!parse_only && do_header) write_forward($$);
691 }
692 ;
693
694 interfacedef: interfacehdr inherit
695 '{' int_statements '}' { $$ = $1;
696 $$->ref = $2;
697 $$->funcs = $4;
698 if (!parse_only && do_header) write_interface($$);
699 }
700 /* MIDL is able to import the definition of a base class from inside the
701 * definition of a derived class, I'll try to support it with this rule */
702 | interfacehdr ':' aIDENTIFIER
703 '{' import int_statements '}' { $$ = $1;
704 $$->ref = find_type2($3, 0);
705 if (!$$->ref) yyerror("base class '%s' not found in import", $3);
706 $$->funcs = $6;
707 if (!parse_only && do_header) write_interface($$);
708 }
709 | dispinterfacedef { $$ = $1; }
710 ;
711
712 interfacedec:
713 interface ';' { $$ = $1; if (!parse_only && do_header) write_forward($$); }
714 | dispinterface ';' { $$ = $1; if (!parse_only && do_header) write_forward($$); }
715 ;
716
717 module: tMODULE aIDENTIFIER { $$ = make_type(0, NULL); $$->name = $2; }
718 | tMODULE aKNOWNTYPE { $$ = make_type(0, NULL); $$->name = $2; }
719 ;
720
721 modulehdr: attributes module { $$ = $2;
722 $$->attrs = $1;
723 }
724 ;
725
726 moduledef: modulehdr '{' int_statements '}' { $$ = $1;
727 $$->funcs = $3;
728 /* FIXME: if (!parse_only && do_header) write_module($$); */
729 }
730 ;
731
732 p_ident: '*' pident %prec PPTR { $$ = $2; $$->ptr_level++; }
733 | tCONST p_ident { $$ = $2; /* FIXME */ }
734 ;
735
736 pident: ident
737 | p_ident
738 | '(' pident ')' { $$ = $2; }
739 ;
740
741 pident_list:
742 pident
743 | pident_list ',' pident { LINK($3, $1); $$ = $3; }
744 ;
745
746 pointer_type:
747 tREF { $$ = RPC_FC_RP; }
748 | tUNIQUE { $$ = RPC_FC_UP; }
749 | tPTR { $$ = RPC_FC_FP; }
750 ;
751
752 structdef: tSTRUCT t_ident '{' fields '}' { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
753 /* overwrite RPC_FC_STRUCT with a more exact type */
754 $$->type = get_struct_type( $4 );
755 $$->fields = $4;
756 $$->defined = TRUE;
757 if(in_typelib)
758 add_struct($$);
759 }
760 ;
761
762 type: tVOID { $$ = make_tref(NULL, make_type(0, NULL)); }
763 | aKNOWNTYPE { $$ = make_tref($1, find_type($1, 0)); }
764 | base_type { $$ = make_tref(NULL, $1); }
765 | tCONST type { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
766 | enumdef { $$ = make_tref(NULL, $1); }
767 | tENUM aIDENTIFIER { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
768 | structdef { $$ = make_tref(NULL, $1); }
769 | tSTRUCT aIDENTIFIER { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
770 | uniondef { $$ = make_tref(NULL, $1); }
771 | tUNION aIDENTIFIER { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
772 ;
773
774 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
775 $4->tname = tref->name;
776 tref->name = NULL;
777 $$ = type_ref(tref);
778 $$->attrs = $2;
779 if (!parse_only && do_header)
780 write_typedef($$, $4);
781 if (in_typelib && $$->attrs)
782 add_typedef($$, $4);
783 reg_types($$, $4, 0);
784 }
785 ;
786
787 uniondef: tUNION t_ident '{' fields '}' { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
788 $$->fields = $4;
789 $$->defined = TRUE;
790 }
791 | tUNION t_ident
792 tSWITCH '(' s_field ')'
793 m_ident '{' cases '}' { var_t *u = $7;
794 $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
795 if (!u) u = make_var("tagged_union");
796 u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
797 u->type->fields = $9;
798 u->type->defined = TRUE;
799 LINK(u, $5); $$->fields = u;
800 $$->defined = TRUE;
801 }
802 ;
803
804 version:
805 aNUM { $$ = MAKELONG($1, 0); }
806 | aNUM '.' aNUM { $$ = MAKELONG($1, $3); }
807 ;
808
809 %%
810
811 static attr_t *make_attr(enum attr_type type)
812 {
813 attr_t *a = xmalloc(sizeof(attr_t));
814 a->type = type;
815 a->u.ival = 0;
816 INIT_LINK(a);
817 return a;
818 }
819
820 static attr_t *make_attrv(enum attr_type type, unsigned long val)
821 {
822 attr_t *a = xmalloc(sizeof(attr_t));
823 a->type = type;
824 a->u.ival = val;
825 INIT_LINK(a);
826 return a;
827 }
828
829 static attr_t *make_attrp(enum attr_type type, void *val)
830 {
831 attr_t *a = xmalloc(sizeof(attr_t));
832 a->type = type;
833 a->u.pval = val;
834 INIT_LINK(a);
835 return a;
836 }
837
838 static expr_t *make_expr(enum expr_type type)
839 {
840 expr_t *e = xmalloc(sizeof(expr_t));
841 e->type = type;
842 e->ref = NULL;
843 e->u.lval = 0;
844 e->is_const = FALSE;
845 INIT_LINK(e);
846 return e;
847 }
848
849 static expr_t *make_exprl(enum expr_type type, long val)
850 {
851 expr_t *e = xmalloc(sizeof(expr_t));
852 e->type = type;
853 e->ref = NULL;
854 e->u.lval = val;
855 e->is_const = FALSE;
856 INIT_LINK(e);
857 /* check for numeric constant */
858 if (type == EXPR_NUM || type == EXPR_HEXNUM) {
859 e->is_const = TRUE;
860 e->cval = val;
861 }
862 return e;
863 }
864
865 static expr_t *make_exprs(enum expr_type type, char *val)
866 {
867 expr_t *e;
868 e = xmalloc(sizeof(expr_t));
869 e->type = type;
870 e->ref = NULL;
871 e->u.sval = val;
872 e->is_const = FALSE;
873 INIT_LINK(e);
874 /* check for predefined constants */
875 if (type == EXPR_IDENTIFIER) {
876 var_t *c = find_const(val, 0);
877 if (c) {
878 e->u.sval = c->name;
879 free(val);
880 e->is_const = TRUE;
881 e->cval = c->eval->cval;
882 }
883 }
884 return e;
885 }
886
887 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
888 {
889 expr_t *e;
890 e = xmalloc(sizeof(expr_t));
891 e->type = type;
892 e->ref = expr;
893 e->u.tref = tref;
894 e->is_const = FALSE;
895 INIT_LINK(e);
896 /* check for cast of constant expression */
897 if (type == EXPR_SIZEOF) {
898 switch (tref->ref->type) {
899 case RPC_FC_BYTE:
900 case RPC_FC_CHAR:
901 case RPC_FC_SMALL:
902 case RPC_FC_USMALL:
903 e->is_const = TRUE;
904 e->cval = 1;
905 break;
906 case RPC_FC_WCHAR:
907 case RPC_FC_USHORT:
908 case RPC_FC_SHORT:
909 e->is_const = TRUE;
910 e->cval = 2;
911 break;
912 case RPC_FC_LONG:
913 case RPC_FC_ULONG:
914 case RPC_FC_FLOAT:
915 case RPC_FC_ERROR_STATUS_T:
916 e->is_const = TRUE;
917 e->cval = 4;
918 break;
919 case RPC_FC_HYPER:
920 case RPC_FC_DOUBLE:
921 e->is_const = TRUE;
922 e->cval = 8;
923 break;
924 }
925 }
926 if (type == EXPR_CAST && expr->is_const) {
927 e->is_const = TRUE;
928 e->cval = expr->cval;
929 }
930 return e;
931 }
932
933 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
934 {
935 expr_t *e;
936 e = xmalloc(sizeof(expr_t));
937 e->type = type;
938 e->ref = expr;
939 e->u.lval = 0;
940 e->is_const = FALSE;
941 INIT_LINK(e);
942 /* check for compile-time optimization */
943 if (expr->is_const) {
944 e->is_const = TRUE;
945 switch (type) {
946 case EXPR_NEG:
947 e->cval = -expr->cval;
948 break;
949 case EXPR_NOT:
950 e->cval = ~expr->cval;
951 break;
952 default:
953 e->is_const = FALSE;
954 break;
955 }
956 }
957 return e;
958 }
959
960 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
961 {
962 expr_t *e;
963 e = xmalloc(sizeof(expr_t));
964 e->type = type;
965 e->ref = expr1;
966 e->u.ext = expr2;
967 e->is_const = FALSE;
968 INIT_LINK(e);
969 /* check for compile-time optimization */
970 if (expr1->is_const && expr2->is_const) {
971 e->is_const = TRUE;
972 switch (type) {
973 case EXPR_ADD:
974 e->cval = expr1->cval + expr2->cval;
975 break;
976 case EXPR_SUB:
977 e->cval = expr1->cval - expr2->cval;
978 break;
979 case EXPR_MUL:
980 e->cval = expr1->cval * expr2->cval;
981 break;
982 case EXPR_DIV:
983 e->cval = expr1->cval / expr2->cval;
984 break;
985 case EXPR_OR:
986 e->cval = expr1->cval | expr2->cval;
987 break;
988 case EXPR_AND:
989 e->cval = expr1->cval & expr2->cval;
990 break;
991 case EXPR_SHL:
992 e->cval = expr1->cval << expr2->cval;
993 break;
994 case EXPR_SHR:
995 e->cval = expr1->cval >> expr2->cval;
996 break;
997 default:
998 e->is_const = FALSE;
999 break;
1000 }
1001 }
1002 return e;
1003 }
1004
1005 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1006 {
1007 expr_t *e;
1008 e = xmalloc(sizeof(expr_t));
1009 e->type = type;
1010 e->ref = expr1;
1011 e->u.ext = expr2;
1012 e->ext2 = expr3;
1013 e->is_const = FALSE;
1014 INIT_LINK(e);
1015 /* check for compile-time optimization */
1016 if (expr1->is_const && expr2->is_const && expr3->is_const) {
1017 e->is_const = TRUE;
1018 switch (type) {
1019 case EXPR_COND:
1020 e->cval = expr1->cval ? expr2->cval : expr3->cval;
1021 break;
1022 default:
1023 e->is_const = FALSE;
1024 break;
1025 }
1026 }
1027 return e;
1028 }
1029
1030 static type_t *make_type(unsigned char type, type_t *ref)
1031 {
1032 type_t *t = xmalloc(sizeof(type_t));
1033 t->name = NULL;
1034 t->type = type;
1035 t->ref = ref;
1036 t->attrs = NULL;
1037 t->funcs = NULL;
1038 t->fields = NULL;
1039 t->ignore = parse_only;
1040 t->is_const = FALSE;
1041 t->sign = 0;
1042 t->defined = FALSE;
1043 t->written = FALSE;
1044 t->typelib_idx = -1;
1045 INIT_LINK(t);
1046 return t;
1047 }
1048
1049 static typeref_t *make_tref(char *name, type_t *ref)
1050 {
1051 typeref_t *t = xmalloc(sizeof(typeref_t));
1052 t->name = name;
1053 t->ref = ref;
1054 t->uniq = ref ? 0 : 1;
1055 return t;
1056 }
1057
1058 static typeref_t *uniq_tref(typeref_t *ref)
1059 {
1060 typeref_t *t = ref;
1061 type_t *tp;
1062 if (t->uniq) return t;
1063 tp = make_type(0, t->ref);
1064 tp->name = t->name;
1065 t->name = NULL;
1066 t->ref = tp;
1067 t->uniq = 1;
1068 return t;
1069 }
1070
1071 static type_t *type_ref(typeref_t *ref)
1072 {
1073 type_t *t = ref->ref;
1074 if (ref->name) free(ref->name);
1075 free(ref);
1076 return t;
1077 }
1078
1079 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1080 {
1081 v->type = ref->ref;
1082 v->tname = ref->name;
1083 ref->name = NULL;
1084 free(ref);
1085 v->array = arr;
1086 }
1087
1088 static ifref_t *make_ifref(type_t *iface)
1089 {
1090 ifref_t *l = xmalloc(sizeof(ifref_t));
1091 l->iface = iface;
1092 l->attrs = NULL;
1093 INIT_LINK(l);
1094 return l;
1095 }
1096
1097 static var_t *make_var(char *name)
1098 {
1099 var_t *v = xmalloc(sizeof(var_t));
1100 v->name = name;
1101 v->ptr_level = 0;
1102 v->type = NULL;
1103 v->tname = NULL;
1104 v->attrs = NULL;
1105 v->array = NULL;
1106 v->eval = NULL;
1107 INIT_LINK(v);
1108 return v;
1109 }
1110
1111 static func_t *make_func(var_t *def, var_t *args)
1112 {
1113 func_t *f = xmalloc(sizeof(func_t));
1114 f->def = def;
1115 f->args = args;
1116 f->ignore = parse_only;
1117 f->idx = -1;
1118 INIT_LINK(f);
1119 return f;
1120 }
1121
1122 static class_t *make_class(char *name)
1123 {
1124 class_t *c = xmalloc(sizeof(class_t));
1125 c->name = name;
1126 c->attrs = NULL;
1127 c->ifaces = NULL;
1128 INIT_LINK(c);
1129 return c;
1130 }
1131
1132 #define HASHMAX 64
1133
1134 static int hash_ident(const char *name)
1135 {
1136 const char *p = name;
1137 int sum = 0;
1138 /* a simple sum hash is probably good enough */
1139 while (*p) {
1140 sum += *p;
1141 p++;
1142 }
1143 return sum & (HASHMAX-1);
1144 }
1145
1146 /***** type repository *****/
1147
1148 struct rtype {
1149 const char *name;
1150 type_t *type;
1151 int t;
1152 struct rtype *next;
1153 };
1154
1155 struct rtype *type_hash[HASHMAX];
1156
1157 static type_t *reg_type(type_t *type, const char *name, int t)
1158 {
1159 struct rtype *nt;
1160 int hash;
1161 if (!name) {
1162 yyerror("registering named type without name");
1163 return type;
1164 }
1165 hash = hash_ident(name);
1166 nt = xmalloc(sizeof(struct rtype));
1167 nt->name = name;
1168 nt->type = type;
1169 nt->t = t;
1170 nt->next = type_hash[hash];
1171 type_hash[hash] = nt;
1172 return type;
1173 }
1174
1175 /* determine pointer type from attrs */
1176 static unsigned char get_pointer_type( type_t *type )
1177 {
1178 int t;
1179 if (is_attr( type->attrs, ATTR_STRING ))
1180 {
1181 type_t *t = type;
1182 while( t->type == 0 && t->ref )
1183 t = t->ref;
1184 switch( t->type )
1185 {
1186 case RPC_FC_CHAR:
1187 return RPC_FC_C_CSTRING;
1188 case RPC_FC_WCHAR:
1189 return RPC_FC_C_WSTRING;
1190 }
1191 }
1192 t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1193 if (t) return t;
1194 return RPC_FC_FP;
1195 }
1196
1197 static type_t *reg_types(type_t *type, var_t *names, int t)
1198 {
1199 type_t *ptr = type;
1200 int ptrc = 0;
1201
1202 while (names) {
1203 var_t *next = NEXT_LINK(names);
1204 if (names->name) {
1205 type_t *cur = ptr;
1206 int cptr = names->ptr_level;
1207 if (cptr > ptrc) {
1208 while (cptr > ptrc) {
1209 int t = get_pointer_type( cur );
1210 cur = ptr = make_type(t, cur);
1211 ptrc++;
1212 }
1213 } else {
1214 while (cptr < ptrc) {
1215 cur = cur->ref;
1216 cptr++;
1217 }
1218 }
1219 reg_type(cur, names->name, t);
1220 }
1221 free(names);
1222 names = next;
1223 }
1224 return type;
1225 }
1226
1227 static type_t *find_type(const char *name, int t)
1228 {
1229 struct rtype *cur = type_hash[hash_ident(name)];
1230 while (cur && (cur->t != t || strcmp(cur->name, name)))
1231 cur = cur->next;
1232 if (!cur) {
1233 yyerror("type '%s' not found", name);
1234 return NULL;
1235 }
1236 return cur->type;
1237 }
1238
1239 static type_t *find_type2(char *name, int t)
1240 {
1241 type_t *tp = find_type(name, t);
1242 free(name);
1243 return tp;
1244 }
1245
1246 int is_type(const char *name)
1247 {
1248 struct rtype *cur = type_hash[hash_ident(name)];
1249 while (cur && (cur->t || strcmp(cur->name, name)))
1250 cur = cur->next;
1251 if (cur) return TRUE;
1252 return FALSE;
1253 }
1254
1255 static type_t *get_type(unsigned char type, char *name, int t)
1256 {
1257 struct rtype *cur = NULL;
1258 type_t *tp;
1259 if (name) {
1260 cur = type_hash[hash_ident(name)];
1261 while (cur && (cur->t != t || strcmp(cur->name, name)))
1262 cur = cur->next;
1263 }
1264 if (cur) {
1265 free(name);
1266 return cur->type;
1267 }
1268 tp = make_type(type, NULL);
1269 tp->name = name;
1270 if (!name) return tp;
1271 return reg_type(tp, name, t);
1272 }
1273
1274 static type_t *get_typev(unsigned char type, var_t *name, int t)
1275 {
1276 char *sname = NULL;
1277 if (name) {
1278 sname = name->name;
1279 free(name);
1280 }
1281 return get_type(type, sname, t);
1282 }
1283
1284 static int get_struct_type(var_t *field)
1285 {
1286 int has_pointer = 0;
1287 int has_conformance = 0;
1288 int has_variance = 0;
1289
1290 for (; field; field = NEXT_LINK(field))
1291 {
1292 type_t *t = field->type;
1293
1294 /* get the base type */
1295 while( (t->type == 0) && t->ref )
1296 t = t->ref;
1297
1298 if (field->ptr_level > 0)
1299 {
1300 has_pointer = 1;
1301 continue;
1302 }
1303
1304 if (is_string_type(field->attrs, 0, field->array))
1305 {
1306 has_conformance = 1;
1307 has_variance = 1;
1308 continue;
1309 }
1310
1311 if (is_array_type(field->attrs, 0, field->array))
1312 {
1313 if (field->array && !field->array->is_const)
1314 {
1315 has_conformance = 1;
1316 if (PREV_LINK(field))
1317 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1318 field->name);
1319 }
1320 if (is_attr(field->attrs, ATTR_LENGTHIS))
1321 has_variance = 1;
1322 }
1323
1324 switch (t->type)
1325 {
1326 /*
1327 * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1328 * Simple types don't effect the type of struct.
1329 * A struct containing a simple struct is still a simple struct.
1330 * So long as we can block copy the data, we return RPC_FC_STRUCT.
1331 */
1332 case 0: /* void pointer */
1333 case RPC_FC_BYTE:
1334 case RPC_FC_CHAR:
1335 case RPC_FC_SMALL:
1336 case RPC_FC_USMALL:
1337 case RPC_FC_WCHAR:
1338 case RPC_FC_SHORT:
1339 case RPC_FC_USHORT:
1340 case RPC_FC_LONG:
1341 case RPC_FC_ULONG:
1342 case RPC_FC_INT3264:
1343 case RPC_FC_UINT3264:
1344 case RPC_FC_HYPER:
1345 case RPC_FC_FLOAT:
1346 case RPC_FC_DOUBLE:
1347 case RPC_FC_STRUCT:
1348 case RPC_FC_ENUM16:
1349 case RPC_FC_ENUM32:
1350 break;
1351
1352 case RPC_FC_UP:
1353 case RPC_FC_FP:
1354 has_pointer = 1;
1355 break;
1356 case RPC_FC_CARRAY:
1357 has_conformance = 1;
1358 if (PREV_LINK(field))
1359 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1360 field->name);
1361 break;
1362 case RPC_FC_C_CSTRING:
1363 case RPC_FC_C_WSTRING:
1364 has_conformance = 1;
1365 has_variance = 1;
1366 break;
1367
1368 /*
1369 * Propagate member attributes
1370 * a struct should be at least as complex as its member
1371 */
1372 case RPC_FC_CVSTRUCT:
1373 has_conformance = 1;
1374 has_variance = 1;
1375 has_pointer = 1;
1376 break;
1377
1378 case RPC_FC_CPSTRUCT:
1379 has_conformance = 1;
1380 if (PREV_LINK(field))
1381 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1382 field->name);
1383 has_pointer = 1;
1384 break;
1385
1386 case RPC_FC_CSTRUCT:
1387 has_conformance = 1;
1388 if (PREV_LINK(field))
1389 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1390 field->name);
1391 break;
1392
1393 case RPC_FC_PSTRUCT:
1394 has_pointer = 1;
1395 break;
1396
1397 default:
1398 fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1399 field->name, t->type);
1400 /* fallthru - treat it as complex */
1401
1402 /* as soon as we see one of these these members, it's bogus... */
1403 case RPC_FC_IP:
1404 case RPC_FC_ENCAPSULATED_UNION:
1405 case RPC_FC_NON_ENCAPSULATED_UNION:
1406 case RPC_FC_TRANSMIT_AS:
1407 case RPC_FC_REPRESENT_AS:
1408 case RPC_FC_PAD:
1409 case RPC_FC_EMBEDDED_COMPLEX:
1410 case RPC_FC_BOGUS_STRUCT:
1411 return RPC_FC_BOGUS_STRUCT;
1412 }
1413 }
1414
1415 if( has_variance )
1416 return RPC_FC_CVSTRUCT;
1417 if( has_conformance && has_pointer )
1418 return RPC_FC_CPSTRUCT;
1419 if( has_conformance )
1420 return RPC_FC_CSTRUCT;
1421 if( has_pointer )
1422 return RPC_FC_PSTRUCT;
1423 return RPC_FC_STRUCT;
1424 }
1425
1426 /***** constant repository *****/
1427
1428 struct rconst {
1429 char *name;
1430 var_t *var;
1431 struct rconst *next;
1432 };
1433
1434 struct rconst *const_hash[HASHMAX];
1435
1436 static var_t *reg_const(var_t *var)
1437 {
1438 struct rconst *nc;
1439 int hash;
1440 if (!var->name) {
1441 yyerror("registering constant without name");
1442 return var;
1443 }
1444 hash = hash_ident(var->name);
1445 nc = xmalloc(sizeof(struct rconst));
1446 nc->name = var->name;
1447 nc->var = var;
1448 nc->next = const_hash[hash];
1449 const_hash[hash] = nc;
1450 return var;
1451 }
1452
1453 static var_t *find_const(char *name, int f)
1454 {
1455 struct rconst *cur = const_hash[hash_ident(name)];
1456 while (cur && strcmp(cur->name, name))
1457 cur = cur->next;
1458 if (!cur) {
1459 if (f) yyerror("constant '%s' not found", name);
1460 return NULL;
1461 }
1462 return cur->var;
1463 }
useful hacks and other patches not (yet) suitable for mainline