aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]]),
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32,w64-mingw32],[x86_64-ac_wine_prefix-$2 ])" ;;
 132   *)
 133     ac_prefix_list="" ;;
 134 esac
 135 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 136
 137
 138 dnl **** Define helper functions for creating config.status files ****
 139 dnl
 140 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 141 dnl
 142 AC_DEFUN([WINE_CONFIG_HELPERS],
 143 [ALL_MAKEFILE_DEPENDS="
 144 # Rules automatically generated by configure
 145
 146 .INIT: Makefile
 147 .BEGIN: Makefile
 148 .MAKEFILEDEPS:
 149 Makefile: Makefile.in Make.rules config.status
 150         @./config.status Make.tmp Makefile"
 151
 152 AC_SUBST(ALL_WINETEST_DEPENDS,["# Test binaries"])
 153 AC_SUBST(ALL_TEST_BINARIES,"")
 154 AC_SUBST(ALL_PROGRAM_BIN_INSTALL_DIRS,"")
 155
 156 wine_fn_append_file ()
 157 {
 158     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 159 }
 160
 161 wine_fn_append_rule ()
 162 {
 163     AS_VAR_APPEND($[1],"$as_nl$[2]")
 164 }
 165
 166 wine_fn_all_dir_rules ()
 167 {
 168     wine_fn_append_file ALL_DIRS $[1]
 169     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 170 "__clean__ .PHONY: $[1]/__clean__
 171 $[1]/__clean__: $[1]/Makefile
 172         @cd $[1] && \$(MAKE) clean
 173         \$(RM) $[1]/Makefile
 174 $[1]/Makefile: $[1]/Makefile.in config.status $[2]
 175         @./config.status --file $[1]/Makefile && cd $[1] && \$(MAKE) depend
 176 depend .PHONY: $[1]/__depend__
 177 $[1]/__depend__: \$(MAKEDEP) dummy
 178         @./config.status --file $[1]/Makefile && cd $[1] && \$(MAKE) depend"
 179 }
 180
 181 wine_fn_config_makefile ()
 182 {
 183     ac_dir=$[1]
 184     ac_enable=$[2]
 185     wine_fn_all_dir_rules $ac_dir "Make.rules \$(MAKEDEP)"
 186
 187     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 188 "all .PHONY: $ac_dir
 189 $ac_dir: $ac_dir/Makefile dummy
 190         @cd $ac_dir && \$(MAKE)
 191 install:: $ac_dir
 192         @cd $ac_dir && \$(MAKE) install
 193 install-lib:: $ac_dir
 194         @cd $ac_dir && \$(MAKE) install-lib
 195 install-dev:: $ac_dir
 196         @cd $ac_dir && \$(MAKE) install-dev
 197 uninstall:: $ac_dir/Makefile
 198         @cd $ac_dir && \$(MAKE) uninstall"])
 199 }
 200
 201 wine_fn_config_lib ()
 202 {
 203     ac_name=$[1]
 204     ac_dir=dlls/$ac_name
 205     wine_fn_all_dir_rules $ac_dir "dlls/Makeimplib.rules \$(MAKEDEP)"
 206     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 207 "all __builddeps__: $ac_dir
 208 __buildcrossdeps__: $ac_dir/lib$ac_name.cross.a
 209 $ac_dir $ac_dir/lib$ac_name.cross.a: $ac_dir/Makefile tools/widl tools/winebuild tools/winegcc include
 210 $ac_dir: dummy
 211         @cd $ac_dir && \$(MAKE)
 212 $ac_dir/lib$ac_name.cross.a: dummy
 213         @cd $ac_dir && \$(MAKE) lib$ac_name.cross.a
 214 install install-dev:: $ac_dir
 215         @cd $ac_dir && \$(MAKE) install
 216 uninstall:: $ac_dir/Makefile
 217         @cd $ac_dir && \$(MAKE) uninstall"
 218 }
 219
 220 wine_fn_config_dll ()
 221 {
 222     ac_dir=$[1]
 223     ac_enable=$[2]
 224     ac_implib=$[3]
 225     ac_implibsrc=$[4]
 226     ac_file="dlls/$ac_dir/lib$ac_implib"
 227     ac_deps="tools/widl tools/winebuild tools/winegcc include"
 228
 229     wine_fn_all_dir_rules dlls/$ac_dir "dlls/Makedll.rules \$(MAKEDEP)"
 230
 231     AS_VAR_IF([$ac_enable],[no],
 232               dnl enable_win16 is special in that it disables import libs too
 233               [test "$ac_enable" != enable_win16 || return 0],
 234               [wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 235 "all .PHONY: dlls/$ac_dir
 236 dlls/$ac_dir: dlls/$ac_dir/Makefile __builddeps__ dummy
 237         @cd dlls/$ac_dir && \$(MAKE)
 238 install:: dlls/$ac_dir/Makefile __builddeps__
 239         @cd dlls/$ac_dir && \$(MAKE) install
 240 install-lib:: dlls/$ac_dir/Makefile __builddeps__
 241         @cd dlls/$ac_dir && \$(MAKE) install-lib
 242 uninstall manpages htmlpages sgmlpages xmlpages:: dlls/$ac_dir/Makefile
 243         @cd dlls/$ac_dir && \$(MAKE) \$[@]"])
 244
 245     if test -n "$ac_implibsrc"
 246     then
 247         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 248 "__builddeps__: $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT
 249 __buildcrossdeps__: $ac_file.cross.a
 250 $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 251 $ac_file.def: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 252         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 253 $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/Makefile dummy
 254         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 255 install-dev:: dlls/$ac_dir/Makefile __builddeps__
 256         @cd dlls/$ac_dir && \$(MAKE) install-dev"
 257     elif test -n "$ac_implib"
 258     then
 259         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 260 "__builddeps__: $ac_file.$IMPLIBEXT
 261 __buildcrossdeps__: $ac_file.cross.a
 262 $ac_file.$IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile $ac_deps
 263         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 264 install-dev:: dlls/$ac_dir/Makefile __builddeps__
 265         @cd dlls/$ac_dir && \$(MAKE) install-dev"
 266
 267         if test "$ac_dir" != "$ac_implib"
 268         then
 269             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 270 "__builddeps__: dlls/lib$ac_implib.$IMPLIBEXT
 271 __buildcrossdeps__: dlls/lib$ac_implib.cross.a
 272 dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 273         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.$IMPLIBEXT \$[@]
 274 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 275         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.cross.a \$[@]
 276 clean::
 277         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 278         fi
 279     fi
 280 }
 281
 282 wine_fn_config_program ()
 283 {
 284     ac_dir=$[1]
 285     ac_enable=$[2]
 286     ac_install=$[3]
 287     wine_fn_all_dir_rules programs/$ac_dir "programs/Makeprog.rules \$(MAKEDEP)"
 288
 289     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 290 "all .PHONY: programs/$ac_dir
 291 programs/$ac_dir: programs/$ac_dir/Makefile __builddeps__ dummy
 292         @cd programs/$ac_dir && \$(MAKE)"
 293
 294     if test -n "$ac_install"
 295     then
 296         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 297 "install install-lib:: programs/$ac_dir/Makefile __builddeps__
 298         @cd programs/$ac_dir && \$(MAKE) install
 299 uninstall:: programs/$ac_dir/Makefile
 300         @cd programs/$ac_dir && \$(MAKE) uninstall"
 301         test "$ac_install" != installbin || wine_fn_append_file ALL_PROGRAM_BIN_INSTALL_DIRS programs/$ac_dir
 302     fi])
 303 }
 304
 305 wine_fn_config_test ()
 306 {
 307     ac_dir=$[1]
 308     ac_name=$[2]
 309     wine_fn_append_file ALL_TEST_BINARIES $ac_name.exe
 310     wine_fn_append_rule ALL_WINETEST_DEPENDS \
 311 "$ac_name.exe: \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT
 312         cp \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT \$[@] && \$(STRIP) \$[@]
 313 $ac_name.rc:
 314         echo \"$ac_name.exe TESTRES \\\"$ac_name.exe\\\"\" >\$[@] || (\$(RM) \$[@] && false)
 315 $ac_name.res: $ac_name.rc $ac_name.exe"
 316     wine_fn_all_dir_rules $ac_dir "Maketest.rules \$(MAKEDEP)"
 317
 318     AS_VAR_IF([enable_tests],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 319 "all programs/winetest .PHONY: $ac_dir
 320 $ac_dir: $ac_dir/Makefile __builddeps__ dummy
 321         @cd $ac_dir && \$(MAKE)
 322 crosstest .PHONY: $ac_dir/__crosstest__
 323 $ac_dir/__crosstest__: $ac_dir/Makefile __buildcrossdeps__ dummy
 324         @cd $ac_dir && \$(MAKE) crosstest
 325 test .PHONY: $ac_dir/__test__
 326 $ac_dir/__test__: dummy
 327         @cd $ac_dir && \$(MAKE) test
 328 testclean::
 329         \$(RM) $ac_dir/*.ok"])
 330 }
 331
 332 wine_fn_config_tool ()
 333 {
 334     ac_dir=$[1]
 335     ac_deps="Make.rules"
 336     if test "$ac_dir" != tools
 337     then
 338         dnl makedep is in tools so tools makefile cannot depend on it
 339         ac_deps="$ac_deps \$(MAKEDEP)"
 340     fi
 341     wine_fn_all_dir_rules $ac_dir "$ac_deps"
 342
 343     AS_VAR_IF([enable_tools],[no],,[case $ac_dir in
 344       dnl tools directory has both install-lib and install-dev
 345       tools) wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 346 "install:: $ac_dir
 347         @cd $ac_dir && \$(MAKE) install
 348 install-lib:: $ac_dir
 349         @cd $ac_dir && \$(MAKE) install-lib
 350 install-dev:: $ac_dir
 351         @cd $ac_dir && \$(MAKE) install-dev" ;;
 352       *)     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 353 "install install-dev:: $ac_dir
 354         @cd $ac_dir && \$(MAKE) install" ;;
 355       esac
 356       wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 357 "uninstall:: $ac_dir/Makefile
 358         @cd $ac_dir && \$(MAKE) uninstall
 359 all __tooldeps__ .PHONY: $ac_dir
 360 $ac_dir: $ac_dir/Makefile libs/port dummy
 361         @cd $ac_dir && \$(MAKE)"])
 362 }
 363
 364 wine_fn_config_makerules ()
 365 {
 366     ac_rules=$[1]
 367     ac_deps=$[2]
 368     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 369 "$ac_rules: $ac_rules.in $ac_deps config.status
 370         @./config.status $ac_rules
 371 distclean::
 372         \$(RM) $ac_rules"
 373 }
 374
 375 wine_fn_config_symlink ()
 376 {
 377     ac_link=$[1]
 378     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 379 "$ac_link:
 380         @./config.status $ac_link
 381 distclean::
 382         \$(RM) $ac_link"
 383 }])
 384
 385 dnl **** Define helper function to append a file to a makefile file list ****
 386 dnl
 387 dnl Usage: WINE_APPEND_FILE(var,file)
 388 dnl
 389 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 390
 391 dnl **** Define helper function to append a rule to a makefile command list ****
 392 dnl
 393 dnl Usage: WINE_APPEND_RULE(var,rule)
 394 dnl
 395 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 396
 397 dnl **** Create nonexistent directories from config.status ****
 398 dnl
 399 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 400 dnl
 401 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 402 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 403
 404 dnl **** Create symlinks from config.status ****
 405 dnl
 406 dnl Usage: WINE_CONFIG_SYMLINK(name,target)
 407 dnl
 408 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 409 AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 410 m4_if([$2],,[test "$srcdir" = "." || ])wine_fn_config_symlink $1])
 411
 412 dnl **** Create a make rules file from config.status ****
 413 dnl
 414 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 415 dnl
 416 AC_DEFUN([WINE_CONFIG_MAKERULES],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 417 wine_fn_config_makerules $1 $3
 418 $2=$1
 419 AC_SUBST_FILE([$2])dnl
 420 AC_CONFIG_FILES([$1])])
 421
 422 dnl **** Create a makefile from config.status ****
 423 dnl
 424 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable)
 425 dnl
 426 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 427 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 428 wine_fn_config_makefile [$1] ac_enable[]dnl
 429 AS_VAR_POPDEF([ac_enable])])
 430
 431 dnl **** Create a dll makefile from config.status ****
 432 dnl
 433 dnl Usage: WINE_CONFIG_DLL(name,enable,implib,implibsrc)
 434 dnl
 435 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 436 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 437 wine_fn_config_dll [$1] ac_enable [$3] m4_ifval([$4],["$4"])dnl
 438 AS_VAR_POPDEF([ac_enable])])
 439
 440 dnl **** Create a program makefile from config.status ****
 441 dnl
 442 dnl Usage: WINE_CONFIG_PROGRAM(name,install,enable)
 443 dnl
 444 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 445 AS_VAR_PUSHDEF([ac_enable],m4_default([$3],[enable_]$1))dnl
 446 wine_fn_config_program [$1] ac_enable [$2]dnl
 447 AS_VAR_POPDEF([ac_enable])])
 448
 449 dnl **** Create a test makefile from config.status ****
 450 dnl
 451 dnl Usage: WINE_CONFIG_TEST(dir)
 452 dnl
 453 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 454 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 455 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 456 wine_fn_config_test $1 ac_name[]ac_suffix[]dnl
 457 m4_popdef([ac_suffix])dnl
 458 m4_popdef([ac_name])])
 459
 460 dnl **** Create a static lib makefile from config.status ****
 461 dnl
 462 dnl Usage: WINE_CONFIG_LIB(name)
 463 dnl
 464 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 465 wine_fn_config_lib $1])
 466
 467 dnl **** Create a tool makefile from config.status ****
 468 dnl
 469 dnl Usage: WINE_CONFIG_TOOL(name)
 470 dnl
 471 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 472 wine_fn_config_tool $1])
 473
 474 dnl **** Add a message to the list displayed at the end ****
 475 dnl
 476 dnl Usage: WINE_NOTICE(notice)
 477 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 478 dnl Usage: WINE_WARNING(warning)
 479 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 480 dnl Usage: WINE_PRINT_MESSAGES
 481 dnl
 482 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 483 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 484
 485 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 486   x)   WINE_NOTICE([$3]) ;;
 487   xno) ;;
 488   *)   AC_MSG_ERROR([$3
 489 This is an error since --with-$1 was requested.]) ;;
 490 esac])])
 491
 492 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 493   x)   WINE_WARNING([$3]) ;;
 494   xno) ;;
 495   *)   AC_MSG_ERROR([$3
 496 This is an error since --with-$1 was requested.]) ;;
 497 esac])])
 498
 499 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 500   xno) ;;
 501   *)   AC_MSG_ERROR([$3
 502 Use the --without-$1 option if you really want this.]) ;;
 503 esac])])
 504
 505 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 506 if test "x$wine_notices != "x; then
 507     echo >&AS_MESSAGE_FD
 508     IFS="|"
 509     for msg in $wine_notices; do
 510         IFS="$ac_save_IFS"
 511         if test -n "$msg"; then
 512             AC_MSG_NOTICE([$msg])
 513         fi
 514     done
 515 fi
 516 IFS="|"
 517 for msg in $wine_warnings; do
 518     IFS="$ac_save_IFS"
 519     if test -n "$msg"; then
 520         echo >&2
 521         AC_MSG_WARN([$msg])
 522     fi
 523 done
 524 IFS="$ac_save_IFS"])
 525
 526 dnl Local Variables:
 527 dnl compile-command: "autoreconf --warnings=all"
 528 dnl End: