| blob | 943262db66041a105f8d9d7715c4a4c852300542 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53b)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(DLLDEFS,"")
25 if test "x$enable_debug" = "xno"
26 then
27 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
32 fi
34 AC_CANONICAL_HOST
35 case $host in
36 x86_64*linux*)
37 if test "x$enable_win64" != "xyes"
38 then
39 test -n "$CC" || CC="gcc -m32"
40 test -n "$LD" || LD="ld -m elf_i386"
41 test -n "$AS" || AS="as --32"
42 host_cpu="i386"
43 fi
44 ;;
45 esac
47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
48 case $host_cpu in
49 *i[[3456789]]86*)
50 if test "x$enable_win16" != "xno"
51 then
52 enable_win16="yes"
53 fi
54 ;;
55 esac
57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
59 if test "x$enable_win16" != "xyes"
60 then
61 WIN16_FILES=""
62 WIN16_INSTALL=""
63 fi
65 dnl **** Check for some programs ****
67 AC_PROG_MAKE_SET
68 AC_PROG_CC
69 AC_PROG_CXX
70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
74 [if test -z "$with_wine_tools"; then
75 if test "$cross_compiling" = "yes"; then
76 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
77 else
78 wine_cv_toolsdir="\$(TOPOBJDIR)"
79 fi
80 elif test -d "$with_wine_tools/tools/winebuild"; then
81 case $with_wine_tools in
82 /*) wine_cv_toolsdir="$with_wine_tools" ;;
83 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
84 esac
85 else
86 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
87 fi])
88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
90 AC_PATH_XTRA
91 AC_PROG_LEX
93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
94 dnl **** without one present.
95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
96 if test "$XLEX" = "none"
97 then
98 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
99 fi
101 dnl Check for bison
102 AC_CHECK_PROGS(BISON,bison,none)
103 if test "$BISON" = "none"
104 then
105 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
106 fi
108 AC_CHECK_TOOLS(AS,[gas as],as)
109 AC_CHECK_TOOL(LD,ld,ld)
110 AC_CHECK_TOOL(AR,ar,ar)
111 AC_PROG_RANLIB
112 AC_CHECK_TOOL(STRIP,strip,strip)
113 AC_CHECK_TOOL(WINDRES,windres,false)
114 AC_PROG_LN_S
115 WINE_PROG_LN
116 AC_PROG_EGREP
117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
118 AC_PROG_INSTALL
119 dnl Prepend src dir to install path dir if it's a relative path
120 case "$INSTALL" in
121 [[\\/$]]* | ?:[[\\/]]* ) ;;
122 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
123 esac
125 dnl Check for lint
126 AC_CHECK_PROGS(LINT, lclint lint)
127 if test "$LINT" = "lint"
128 then
129 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
130 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
131 fi
132 AC_SUBST(LINT)
133 AC_SUBST(LINTFLAGS)
135 dnl Check for various programs
136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
137 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
139 case $host_cpu in
140 *i[[3456789]]86*)
141 AC_CHECK_PROGS(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
142 ;;
143 esac
145 dnl **** Check for some libraries ****
147 dnl Check for -li386 for NetBSD and OpenBSD
148 AC_CHECK_LIB(i386,i386_set_ldt)
149 dnl Check for -lossaudio for NetBSD
150 AC_CHECK_LIB(ossaudio,_oss_ioctl)
151 dnl Check for -lnsl for Solaris
152 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
153 dnl Check for -lsocket for Solaris
154 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
155 dnl Check for -lresolv for Solaris
156 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
157 dnl Check for -lxpg4 for FreeBSD
158 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
159 dnl Check for -lpoll for Mac OS X/Darwin
160 AC_CHECK_LIB(poll,poll)
161 dnl Check for -lresolv for Mac OS X/Darwin
162 AC_CHECK_LIB(resolv,res_9_init)
163 dnl Check for -lpthread
164 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
166 AC_SUBST(XLIB,"")
167 AC_SUBST(XFILES,"")
168 AC_SUBST(OPENGLFILES,"")
169 AC_SUBST(GLU32FILES,"")
170 AC_SUBST(OPENGL_LIBS,"")
172 dnl **** Check for header files ****
174 AC_CHECK_HEADERS(\
175 IOKit/IOKitLib.h \
176 alsa/asoundlib.h \
177 arpa/inet.h \
178 arpa/nameser.h \
179 asm/types.h \
180 capi20.h \
181 cups/cups.h \
182 curses.h \
183 direct.h \
184 dlfcn.h \
185 elf.h \
186 float.h \
187 fontconfig/fontconfig.h \
188 getopt.h \
189 gif_lib.h \
190 ieeefp.h \
191 io.h \
192 jack/jack.h \
193 jpeglib.h \
194 lber.h \
195 lcms.h \
196 lcms/lcms.h \
197 ldap.h \
198 libaudioio.h \
199 link.h \
200 linux/capi.h \
201 linux/cdrom.h \
202 linux/compiler.h \
203 linux/hdreg.h \
204 linux/input.h \
205 linux/ioctl.h \
206 linux/joystick.h \
207 linux/major.h \
208 linux/param.h \
209 linux/serial.h \
210 linux/ucdrom.h \
211 mach/machine.h \
212 machine/cpu.h \
213 machine/limits.h \
214 machine/soundcard.h \
215 mntent.h \
216 ncurses.h \
217 netdb.h \
218 netinet/in.h \
219 netinet/in_systm.h \
220 netinet/tcp.h \
221 netinet/tcp_fsm.h \
222 openssl/err.h \
223 openssl/ssl.h \
224 poll.h \
225 process.h \
226 pthread.h \
227 pwd.h \
228 regex.h \
229 sched.h \
230 scsi/scsi.h \
231 scsi/scsi_ioctl.h \
232 scsi/sg.h \
233 soundcard.h \
234 stdint.h \
235 strings.h \
236 sys/asoundlib.h \
237 sys/cdio.h \
238 sys/elf32.h \
239 sys/epoll.h \
240 sys/errno.h \
241 sys/exec_elf.h \
242 sys/filio.h \
243 sys/ioctl.h \
244 sys/ipc.h \
245 sys/limits.h \
246 sys/link.h \
247 sys/lwp.h \
248 sys/mman.h \
249 sys/modem.h \
250 sys/msg.h \
251 sys/param.h \
252 sys/poll.h \
253 sys/ptrace.h \
254 sys/reg.h \
255 sys/scsiio.h \
256 sys/shm.h \
257 sys/signal.h \
258 sys/socket.h \
259 sys/sockio.h \
260 sys/soundcard.h \
261 sys/statvfs.h \
262 sys/strtio.h \
263 sys/syscall.h \
264 sys/sysctl.h \
265 sys/time.h \
266 sys/times.h \
267 sys/uio.h \
268 sys/un.h \
269 sys/vm86.h \
270 sys/wait.h \
271 syscall.h \
272 termios.h \
273 unicode/ubidi.h \
274 unistd.h \
275 utime.h \
276 valgrind/memcheck.h
277 )
278 AC_HEADER_STAT()
280 dnl **** Check for X11 ****
282 if test "$have_x" = "yes"
283 then
284 XLIB="-lXext -lX11"
285 ac_save_CPPFLAGS="$CPPFLAGS"
286 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
288 dnl *** All of the following tests require X11/Xlib.h
289 AC_CHECK_HEADERS([X11/Xlib.h \
290 X11/XKBlib.h \
291 X11/Xutil.h \
292 X11/extensions/shape.h \
293 X11/extensions/XInput.h \
294 X11/extensions/XShm.h \
295 X11/extensions/Xrandr.h \
296 X11/extensions/Xrender.h \
297 X11/extensions/xf86dga.h \
298 X11/extensions/xf86vmode.h],,,
299 [#ifdef HAVE_X11_XLIB_H
300 # include <X11/Xlib.h>
301 #endif
302 #ifdef HAVE_X11_XUTIL_H
303 # include <X11/Xutil.h>
304 #endif])
306 dnl *** Check for X keyboard extension
307 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
308 then
309 AC_CHECK_LIB(X11, XkbQueryExtension,
310 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
311 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
312 fi
314 dnl *** Check for X Shm extension
315 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
316 then
317 AC_CHECK_LIB(Xext, XShmQueryExtension,
318 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
319 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
320 fi
322 dnl *** Check for X shape extension
323 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
324 then
325 AC_CHECK_LIB(Xext,XShapeQueryExtension,
326 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
327 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
328 fi
330 dnl *** Check for XFree86 DGA / DGA 2.0 extension
331 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
332 then
333 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
334 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
335 [Define if you have the Xxf86dga library version 2])
336 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
337 ],,
338 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
339 fi
341 dnl *** Check for XFree86 VMODE extension
342 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
343 then
344 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
345 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
346 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
347 ],,
348 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
349 fi
351 dnl *** Check for X RandR extension
352 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
353 then
354 AC_TRY_COMPILE([#include <X11/Xlib.h>
355 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
356 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
357 fi
359 dnl *** Check for Transform functions in Xrender
360 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
361 then
362 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
363 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
364 [Define if Xrender has the XRenderSetPictureTransform function])],,
365 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
366 fi
367 dnl *** End of X11/Xlib.h check
369 dnl Check for the presence of OpenGL
370 if test "x$with_opengl" != "xno"
371 then
372 AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h,,,
373 [#ifdef HAVE_GL_GLX_H
374 # include <GL/glx.h>
375 #endif])
376 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
377 then
378 dnl Check for some problems due to old Mesa versions
379 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
380 AC_TRY_COMPILE(
381 [#include <GL/gl.h>],
382 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
383 [wine_cv_opengl_version_OK="yes"],
384 [wine_cv_opengl_version_OK="no"]
385 )
386 )
388 if test "$wine_cv_opengl_version_OK" = "yes"
389 then
390 dnl Check for the presence of the library
391 AC_CHECK_LIB(GL,glXCreateContext,
392 OPENGL_LIBS="-lGL"
393 ,,
394 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
396 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
397 then
398 OPENGLFILES='$(OPENGLFILES)'
399 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
400 else
401 if test -f /usr/X11R6/lib/libGL.a
402 then
403 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
404 This prevents linking to OpenGL. Delete the file and restart configure.])
405 fi
406 fi
408 dnl Check for GLU32 library.
409 AC_CHECK_LIB(GLU,gluLookAt,
410 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
411 GLU32FILES='$(GLU32FILES)']
412 ,,
413 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
414 )
415 fi
417 dnl Check for glut32 library.
418 AC_CHECK_LIB(glut,glutMainLoop,
419 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
420 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
421 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
422 fi
423 fi
425 dnl **** Check for NAS ****
426 AC_SUBST(NASLIBS,"")
427 AC_CHECK_HEADERS(audio/audiolib.h,
428 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
429 AC_CHECK_LIB(audio,AuCreateFlow,
430 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
431 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
432 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
434 CPPFLAGS="$ac_save_CPPFLAGS"
435 XFILES='$(XFILES)'
436 else
437 XLIB=""
438 X_CFLAGS=""
439 X_LIBS=""
440 fi
442 dnl **** Check for libxml2 ****
444 AC_SUBST(XML2LIBS,"")
445 AC_SUBST(XML2INCL,"")
446 AC_SUBST(XSLTLIBS,"")
447 AC_SUBST(XSLTINCL,"")
448 if test "$PKG_CONFIG" != "false"
449 then
450 ac_save_CPPFLAGS="$CPPFLAGS"
451 ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0`"
452 ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0`"
453 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
454 AC_CHECK_HEADERS(libxml/parser.h,
455 [AC_CHECK_LIB(xml2, xmlParseMemory,
456 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
457 XML2LIBS="$ac_xml_libs"
458 XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
459 AC_CHECK_LIB(xml2, xmlReadMemory,
460 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
461 ])
462 CPPFLAGS="$ac_save_CPPFLAGS"
463 ac_xslt_libs="`$PKG_CONFIG --libs libxslt`"
464 ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt`"
465 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
466 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
467 [AC_CHECK_LIB(xslt, xsltCompilePattern,
468 [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
469 XSLTLIBS="$ac_xslt_libs"
470 XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
471 ],,
472 [#ifdef HAVE_LIBXSLT_PATTERN_H
473 # include <libxslt/pattern.h>
474 #endif])
475 CPPFLAGS="$ac_save_CPPFLAGS"
476 fi
478 dnl **** Check which curses lib to use ***
479 CURSESLIBS=""
480 if test "x$with_curses" != "xno"
481 then
482 if test "$ac_cv_header_ncurses_h" = "yes"
483 then
484 AC_CHECK_LIB(ncurses,waddch,
485 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
486 CURSESLIBS="-lncurses"])
487 elif test "$ac_cv_header_curses_h" = "yes"
488 then
489 AC_CHECK_LIB(curses,waddch,
490 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
491 CURSESLIBS="-lcurses"])
492 fi
493 fi
494 AC_SUBST(CURSESLIBS)
496 dnl **** Check for SANE ****
497 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
498 AC_SUBST(SANELIBS,"")
499 AC_SUBST(SANEINCL,"")
500 if test "$sane_devel" != "no"
501 then
502 SANELIBS="`$sane_devel --libs`"
503 SANEINCL="`$sane_devel --cflags`"
504 ac_save_CPPFLAGS="$CPPFLAGS"
505 ac_save_LIBS="$LIBS"
506 CPPFLAGS="$CPPFLAGS $SANEINCL"
507 LIBS="$LIBS $SANELIBS"
508 AC_CHECK_HEADER(sane/sane.h,
509 [AC_CHECK_LIB(sane,sane_open,
510 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
511 [SANELIBS=""
512 SANEINCL=""])],
513 [SANELIBS=""
514 SANEINCL=""])
515 LIBS="$ac_save_LIBS"
516 CPPFLAGS="$ac_save_CPPFLAGS"
517 fi
519 dnl **** Check for the ICU library ****
520 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
521 then
522 saved_libs="$LIBS"
523 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
524 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
525 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
526 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
527 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
528 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
529 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
530 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
531 AC_MSG_RESULT(yes)],
532 [AC_MSG_RESULT(no)])
533 LIBS="$saved_libs"
534 fi
536 dnl **** Check for LittleCMS ***
537 AC_SUBST(LCMSLIBS,"")
538 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
539 then
540 AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
541 [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
542 LCMSLIBS="-llcms"])
543 fi
545 dnl **** Check for OpenLDAP ***
546 AC_SUBST(LDAPLIBS,"")
547 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
548 then
549 AC_CHECK_LIB(ldap_r, ldap_initialize,
550 [AC_CHECK_LIB(lber, ber_init,
551 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
552 LDAPLIBS="-lldap_r -llber"],,
553 [$LIBPTHREAD])],,
554 [$LIBPTHREAD])
555 fi
557 dnl **** Check for FreeType 2 ****
558 AC_SUBST(FREETYPELIBS,"")
559 AC_SUBST(FREETYPEINCL,"")
560 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
561 if test "$ft_lib" = "no"
562 then
563 wine_cv_msg_freetype=no
564 else
565 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
566 if test "$ft_devel" = "no"
567 then
568 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
569 if test "$ft_devel2" = "freetype2-config"
570 then
571 ft_devel=$ft_devel2
572 fi
573 fi
574 if test "$ft_devel" = "no"
575 then
576 wine_cv_msg_freetype=yes
577 else
578 FREETYPELIBS=`$ft_devel --libs`
579 FREETYPEINCL=`$ft_devel --cflags`
580 ac_save_CPPFLAGS="$CPPFLAGS"
581 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
582 AC_CHECK_HEADERS(ft2build.h \
583 freetype/freetype.h \
584 freetype/ftglyph.h \
585 freetype/tttables.h \
586 freetype/ftnames.h \
587 freetype/ftsnames.h \
588 freetype/ttnameid.h \
589 freetype/ftoutln.h \
590 freetype/ftwinfnt.h \
591 freetype/internal/sfnt.h,,,
592 [#if HAVE_FT2BUILD_H
593 #include <ft2build.h>
594 #endif])
595 AC_TRY_CPP([#include <ft2build.h>
596 #include <freetype/fttrigon.h>],
597 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
598 [Define if you have the <freetype/fttrigon.h> header file.])
599 wine_cv_fttrigon=yes],
600 wine_cv_fttrigon=no)
601 CPPFLAGS="$ac_save_CPPFLAGS"
602 dnl Check that we have at least freetype/freetype.h
603 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
604 then
605 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
606 wine_cv_msg_freetype=no
607 else
608 FREETYPELIBS=""
609 FREETYPEINCL=""
610 wine_cv_msg_freetype=yes
611 fi
612 fi
613 fi
615 dnl Only build the fonts dir if we have both freetype and fontforge
616 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
617 then
618 AC_SUBST(FONTSSUBDIRS,"fonts")
619 fi
621 dnl **** Check for parport (currently Linux only) ****
622 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
623 AC_TRY_COMPILE(
624 [#include <linux/ppdev.h>],
625 [ioctl (1,PPCLAIM,0)],
626 [ac_cv_c_ppdev="yes"],
627 [ac_cv_c_ppdev="no"])
628 )
629 if test "$ac_cv_c_ppdev" = "yes"
630 then
631 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
632 fi
634 dnl **** Check for va_copy ****
635 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
636 AC_TRY_LINK(
637 [#include <stdarg.h>],
638 [va_list ap1, ap2;
639 va_copy(ap1,ap2);
640 ],
641 [ac_cv_c_va_copy="yes"],
642 [ac_cv_c_va_copy="no"])
643 )
644 if test "$ac_cv_c_va_copy" = "yes"
645 then
646 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
647 fi
648 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
649 AC_TRY_LINK(
650 [#include <stdarg.h>],
651 [va_list ap1, ap2;
652 __va_copy(ap1,ap2);
653 ],
654 [ac_cv_c___va_copy="yes"],
655 [ac_cv_c___va_copy="no"])
656 )
657 if test "$ac_cv_c___va_copy" = "yes"
658 then
659 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
660 fi
662 dnl **** Check for sigsetjmp ****
663 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
664 AC_TRY_LINK(
665 [#include <setjmp.h>],
666 [sigjmp_buf buf;
667 sigsetjmp( buf, 1 );
668 siglongjmp( buf, 1 );],
669 [ac_cv_c_sigsetjmp="yes"],
670 [ac_cv_c_sigsetjmp="no"])
671 )
672 if test "$ac_cv_c_sigsetjmp" = "yes"
673 then
674 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
675 fi
677 dnl **** Check for pthread_rwlock_t ****
678 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
679 #include <pthread.h>])
681 dnl **** Check for pthread functions ****
682 ac_save_LIBS="$LIBS"
683 LIBS="$LIBS $LIBPTHREAD"
684 AC_CHECK_FUNCS(\
685 pthread_getattr_np \
686 pthread_get_stackaddr_np \
687 pthread_get_stacksize_np \
688 )
689 LIBS="$ac_save_LIBS"
691 dnl **** Check for aRts Sound Server ****
692 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
693 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
694 then
695 ARTSC_CFLAGS=""
696 for i in `$ARTSCCONFIG --cflags`
697 do
698 case "$i" in
699 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
700 esac
701 done
702 ARTSC_LIBS=`$ARTSCCONFIG --libs`
703 save_CFLAGS="$CFLAGS"
704 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
705 AC_CHECK_LIB(artsc,arts_init,
706 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
707 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
708 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
709 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
710 $ARTSC_LIBS)
711 CFLAGS="$save_CFLAGS"
712 fi
714 dnl **** Check for EsounD ****
715 AC_PATH_PROG(ESDCONFIG, esd-config)
716 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
717 then
718 ESD_CFLAGS=""
719 for i in `$ESDCONFIG --cflags`
720 do
721 case "$i" in
722 -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
723 esac
724 done
725 ESD_LIBS=`$ESDCONFIG --libs`
726 save_CFLAGS="$CFLAGS"
727 CFLAGS="$CFLAGS $ESD_CFLAGS"
728 AC_CHECK_LIB(esd,esd_open_sound,
729 [AC_SUBST(ESDLIBS, $ESD_LIBS)
730 AC_SUBST(ESDINCL, $ESD_CFLAGS)
731 AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
732 CFLAGS="$save_CFLAGS"
733 fi
735 dnl **** Check for ALSA 1.x ****
736 AC_SUBST(ALSALIBS,"")
737 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
738 then
739 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
740 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
741 #include <alsa/asoundlib.h>
742 #elif defined(HAVE_SYS_ASOUNDLIB_H)
743 #include <sys/asoundlib.h>
744 #endif],
745 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
746 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
747 ALSALIBS="-lasound"])])
748 fi
750 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
752 AC_SUBST(AUDIOIOLIBS,"")
753 if test "$ac_cv_header_libaudioio_h" = "yes"
754 then
755 AC_CHECK_LIB(audioio,AudioIOGetVersion,
756 [AUDIOIOLIBS="-laudioio"
757 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
758 fi
760 dnl **** Check for capi4linux ****
762 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
763 then
764 AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
765 fi
767 dnl **** Check for gcc specific options ****
769 AC_SUBST(EXTRACFLAGS,"")
770 if test "x${GCC}" = "xyes"
771 then
772 EXTRACFLAGS="-Wall -pipe"
774 dnl Check for strength-reduce bug
775 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
776 AC_TRY_RUN([
777 int L[[4]] = {0,1,2,3};
778 int main(void) {
779 static int Array[[3]];
780 unsigned int B = 3;
781 int i;
782 for(i=0; i<B; i++) Array[[i]] = i - 3;
783 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
784 L[[i]] = 4;
786 exit( Array[[1]] != -2 || L[[2]] != 3);
787 }],
788 ac_cv_c_gcc_strength_bug="no",
789 ac_cv_c_gcc_strength_bug="yes",
790 ac_cv_c_gcc_strength_bug="yes") )
791 if test "$ac_cv_c_gcc_strength_bug" = "yes"
792 then
793 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
794 fi
796 dnl Check for -fshort-wchar
797 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
798 [WINE_TRY_CFLAGS([-fshort-wchar],
799 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
800 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
801 then
802 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
803 fi
805 dnl Check for -mpreferred-stack-boundary
806 case $host_cpu in
807 *i[[3456789]]86*)
808 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
809 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
810 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
811 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
812 then
813 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
814 fi
815 ;;
816 esac
818 dnl Check for -fno-strict-aliasing
819 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
820 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
821 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
822 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
823 then
824 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
825 fi
827 dnl Check for -gstabs+ option
828 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
829 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
830 if test "$ac_cv_c_gcc_gstabs" = "yes"
831 then
832 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
833 fi
835 dnl Check for -Wdeclaration-after-statement option
836 AC_CACHE_CHECK([for gcc -Wdeclaration-after-statement support], ac_cv_c_gcc_decl_after_statement,
837 [WINE_TRY_CFLAGS([-Wdeclaration-after-statement],ac_cv_c_gcc_decl_after_statement="yes", ac_cv_c_gcc_decl_after_statement="no")])
838 if test "$ac_cv_c_gcc_decl_after_statement" = "yes"
839 then
840 EXTRACFLAGS="$EXTRACFLAGS -Wdeclaration-after-statement"
841 fi
843 dnl Check for noisy string.h
844 saved_CFLAGS="$CFLAGS"
845 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
846 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
847 AC_TRY_COMPILE([#include <string.h>],[],
848 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
849 CFLAGS="$saved_CFLAGS"
850 if test "$ac_cv_c_string_h_warnings" = "no"
851 then
852 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
853 fi
855 AC_SUBST(BUILTINFLAG,"")
856 saved_CFLAGS="$CFLAGS"
857 CFLAGS="$CFLAGS -Werror"
858 AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
859 AC_TRY_COMPILE([],
860 [int iswlower(unsigned short);],
861 [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
862 CFLAGS="$saved_CFLAGS"
863 if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
864 then
865 BUILTINFLAG=""
866 for builtin in \
867 iswalnum iswalpha iswcntrl iswdigit iswgraph iswlower \
868 iswprint iswpunct iswspace iswupper iswxdigit towlower towupper
869 do
870 BUILTINFLAG="$BUILTINFLAG -fno-builtin-$builtin"
871 done
872 fi
873 fi
875 dnl **** Check how to define a function in assembly code ****
877 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
878 WINE_TRY_ASM_LINK(
879 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
880 ac_cv_asm_func_def=".def",
881 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
882 ac_cv_asm_func_def=".type @function",
883 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
884 ac_cv_asm_func_def=".type 2",
885 ac_cv_asm_func_def="unknown")])]))
887 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
888 case "$ac_cv_asm_func_def" in
889 ".def")
890 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
891 ".type @function")
892 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
893 ".type 2")
894 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
895 *)
896 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
897 esac
899 dnl **** Check for underscore on external symbols ****
901 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
902 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
903 [extern int ac_test;],
904 [if (ac_test) return 1],
905 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
907 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
908 if test "$ac_cv_c_extern_prefix" = "yes"
909 then
910 AC_DEFINE([__ASM_NAME(name)], ["_" name])
911 else
912 AC_DEFINE([__ASM_NAME(name)], [name])
913 fi
915 dnl **** Check for working dll ****
917 AC_SUBST(DLLEXT,"")
918 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
919 AC_SUBST(DLLIBS,"")
920 AC_SUBST(LDSHARED,"")
921 AC_SUBST(LDDLLFLAGS,"")
922 AC_SUBST(LIBEXT,"so")
923 AC_SUBST(IMPLIBEXT,"def")
925 case $host_os in
926 cygwin*|mingw32*)
927 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
928 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
929 if test "$DLLWRAP" = "false"; then
930 LIBEXT="a"
931 else
932 dnl FIXME - check whether dllwrap works correctly...
933 LIBEXT="dll"
934 fi
935 IMPLIBEXT="a"
936 dnl We can't build 16-bit NE dlls
937 WIN16_FILES=""
938 WIN16_INSTALL=""
939 ;;
940 *)
941 if test "$ac_cv_header_dlfcn_h" = "yes"
942 then
943 AC_CHECK_FUNCS(dlopen,,
944 [AC_CHECK_LIB(dl,dlopen,
945 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
946 DLLIBS="-ldl"],
947 [LIBEXT="a"])])
948 else
949 LIBEXT="a"
950 fi
952 if test "$LIBEXT" = "so"
953 then
954 DLLFLAGS="$DLLFLAGS -fPIC"
955 DLLEXT=".so"
956 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
957 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
958 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
959 if test "$ac_cv_c_dll_gnuelf" = "yes"
960 then
961 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
962 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
963 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
964 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
965 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
966 if test "$ac_cv_c_dll_zdefs" = "yes"
967 then
968 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
969 fi
971 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
972 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
973 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
974 if test "$ac_cv_c_dll_init_fini" = "yes"
975 then
976 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
977 fi
979 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
980 [echo '{ global: *; };' >conftest.map
981 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
982 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
983 rm -f conftest.map])
984 if test "$ac_cv_c_ld_version_scripts" = "yes"
985 then
986 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
987 fi
989 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
990 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
991 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
992 if test "$ac_cv_c_export_dynamic" = "yes"
993 then
994 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
995 fi
997 case $host_cpu in
998 *i[[3456789]]86*)
999 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
1000 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1001 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
1002 if test "$ac_cv_ld_reloc_exec" = "yes"
1003 then
1004 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1005 fi
1006 ;;
1007 esac
1009 else
1010 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1011 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1012 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1013 if test "$ac_cv_c_dll_unixware" = "yes"
1014 then
1015 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1016 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1018 else
1019 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1020 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1021 if test "$ac_cv_c_dll_macho" = "yes"
1022 then
1023 LIBEXT="dylib"
1024 LDDLLFLAGS="-bundle"
1025 LDSHARED="\$(CC) -dynamiclib"
1026 STRIP="$STRIP -u -r"
1027 dnl declare needed frameworks
1028 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1029 AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1030 case $host_cpu in
1031 *i[[3456789]]86*)
1032 AC_SUBST(LDEXECFLAGS,"-image_base 0x7bf00000")
1033 ;;
1034 *powerpc*)
1035 CFLAGS="$CFLAGS -ffixed-r13"
1036 LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"
1037 dnl Relocate wine executable (FIXME: is this really needed?)
1038 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1039 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1040 ;;
1041 esac
1043 else
1044 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1045 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1046 if test "$ac_cv_c_dll_hpux" = "yes"
1047 then
1048 LIBEXT="sl"
1049 DLLEXT=".sl"
1050 LDDLLFLAGS="-shared -fPIC"
1051 LDSHARED="\$(CC) -shared"
1052 fi
1053 fi
1054 fi
1055 fi
1056 fi
1058 dnl Check for cross compiler to build test programs
1059 AC_SUBST(CROSSTEST,"")
1060 if test "$cross_compiling" = "no"
1061 then
1062 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1063 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1064 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1065 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1066 fi
1067 ;;
1068 esac
1070 if test "$LIBEXT" = "a"; then
1071 AC_MSG_ERROR(
1072 [could not find a way to build shared libraries.
1073 It is currently not possible to build Wine without shared library
1074 (.so) support to allow transparent switch between .so and .dll files.
1075 If you are using Linux, you will need a newer binutils.]
1076 )
1077 fi
1079 case $build_os in
1080 cygwin*|mingw32*)
1081 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1082 darwin*|macosx*)
1083 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1084 *)
1085 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1086 esac
1088 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1089 case $host_os in
1090 mingw32*)
1091 AC_SUBST(CRTLIBS,"-lmsvcrt")
1092 AC_SUBST(SOCKETLIBS,"-lws2_32")
1093 ;;
1094 esac
1096 case $host_os in
1097 linux*)
1098 case $host_cpu in
1099 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1100 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1101 esac
1102 AC_SUBST(MAIN_BINARY,"wine-glibc")
1103 ;;
1104 darwin*)
1105 AC_SUBST(WINE_BINARIES,"wine-pthread")
1106 AC_SUBST(MAIN_BINARY,"wine-pthread")
1107 ;;
1108 *)
1109 AC_SUBST(WINE_BINARIES,"wine-kthread")
1110 AC_SUBST(MAIN_BINARY,"wine-kthread")
1111 ;;
1112 esac
1114 dnl **** Get the soname for libraries that we load dynamically ****
1116 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1117 then
1118 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1119 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1120 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1121 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1122 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1123 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1124 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1125 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1126 WINE_GET_SONAME(cups,cupsGetDefault)
1127 WINE_GET_SONAME(jack,jack_client_new)
1128 WINE_GET_SONAME(fontconfig,FcInit)
1129 WINE_GET_SONAME(ssl,SSL_library_init)
1130 WINE_GET_SONAME(crypto,BIO_new_socket)
1131 WINE_GET_SONAME(ncurses,waddch)
1132 WINE_GET_SONAME(curses,waddch)
1133 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1134 WINE_GET_SONAME(ungif,DGifOpen)
1135 WINE_GET_SONAME(gif,DGifOpen)
1136 WINE_GET_SONAME(capi20,capi20_isinstalled)
1137 fi
1140 dnl **** Check for functions ****
1142 AC_CHECK_FUNCS(\
1143 _lwp_create \
1144 _lwp_self \
1145 _pclose \
1146 _popen \
1147 _snprintf \
1148 _spawnvp \
1149 _stricmp \
1150 _strnicmp \
1151 _vsnprintf \
1152 chsize \
1153 clone \
1154 epoll_create \
1155 ffs \
1156 finite \
1157 fork \
1158 fpclass \
1159 fstatfs \
1160 fstatvfs \
1161 ftruncate \
1162 futimes \
1163 futimesat \
1164 getaddrinfo \
1165 getnetbyname \
1166 getopt_long \
1167 getpagesize \
1168 getprotobyname \
1169 getprotobynumber \
1170 getpwuid \
1171 getservbyport \
1172 gettid \
1173 gettimeofday \
1174 getuid \
1175 inet_network \
1176 lstat \
1177 memmove \
1178 mmap \
1179 pclose \
1180 popen \
1181 pread \
1182 pwrite \
1183 readlink \
1184 rfork \
1185 sched_yield \
1186 select \
1187 sendmsg \
1188 settimeofday \
1189 sigaltstack \
1190 sigprocmask \
1191 snprintf \
1192 spawnvp \
1193 statfs \
1194 statvfs \
1195 strcasecmp \
1196 strerror \
1197 strncasecmp \
1198 tcgetattr \
1199 timegm \
1200 usleep \
1201 vsnprintf \
1202 wait4 \
1203 waitpid \
1204 )
1206 dnl **** Checks for headers that depend on other ones ****
1208 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
1209 [#include <sys/types.h>
1210 #if HAVE_SYS_PARAM_H
1211 # include <sys/param.h>
1212 #endif])
1214 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
1215 [#include <sys/types.h>
1216 #if HAVE_SYS_SOCKET_H
1217 # include <sys/socket.h>
1218 #endif])
1220 AC_CHECK_HEADERS([resolv.h],,,
1221 [#include <sys/types.h>
1222 #if HAVE_SYS_SOCKET_H
1223 # include <sys/socket.h>
1224 #endif
1225 #if HAVE_NETINET_IN_H
1226 # include <netinet/in.h>
1227 #endif
1228 #if HAVE_ARPA_NAMESER_H
1229 # include <arpa/nameser.h>
1230 #endif])
1232 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1234 AC_CHECK_HEADERS([linux/ipx.h linux/videodev.h],,,
1235 [#ifdef HAVE_SYS_TIME_H
1236 #include <sys/time.h>
1237 #endif
1238 #include <sys/types.h>
1239 #ifdef HAVE_ASM_TYPES_H
1240 #include <asm/types.h>
1241 #endif])
1243 dnl **** Check for types ****
1245 AC_C_CONST
1246 AC_C_INLINE
1247 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1248 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1249 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1251 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1252 [#ifdef HAVE_LINUX_INPUT_H
1253 #include <linux/input.h>
1254 #endif])
1256 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1257 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1258 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1259 if test "$wine_cv_have_sigaddset" = "yes"
1260 then
1261 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1262 fi
1265 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1266 wine_cv_linux_gethostbyname_r_6,
1267 AC_TRY_LINK([
1268 #include <netdb.h>
1269 ], [
1270 char *name=NULL;
1271 struct hostent he;
1272 struct hostent *result;
1273 char *buf=NULL;
1274 int bufsize=0;
1275 int res,errnr;
1276 char *addr=NULL;
1277 int addrlen=0;
1278 int addrtype=0;
1279 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1280 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1281 ],
1282 wine_cv_linux_gethostbyname_r_6=yes,
1283 wine_cv_linux_gethostbyname_r_6=no
1284 )
1285 )
1286 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1287 then
1288 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1289 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1290 fi
1292 if test "$ac_cv_header_linux_joystick_h" = "yes"
1293 then
1294 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1295 wine_cv_linux_joystick_22_api,
1296 AC_TRY_COMPILE([
1297 #include <sys/ioctl.h>
1298 #include <linux/joystick.h>
1300 struct js_event blub;
1301 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1302 #error "no 2.2 header"
1303 #endif
1304 ],/*empty*/,
1305 wine_cv_linux_joystick_22_api=yes,
1306 wine_cv_linux_joystick_22_api=no,
1307 wine_cv_linux_joystick_22_api=no
1308 )
1309 )
1310 if test "$wine_cv_linux_joystick_22_api" = "yes"
1311 then
1312 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1313 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1314 fi
1315 fi
1317 dnl **** statfs checks ****
1319 if test "$ac_cv_header_sys_vfs_h" = "yes"
1320 then
1321 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1322 wine_cv_sys_vfs_has_statfs,
1323 AC_TRY_COMPILE([
1324 #include <sys/types.h>
1325 #ifdef HAVE_SYS_PARAM_H
1326 # include <sys/param.h>
1327 #endif
1328 #include <sys/vfs.h>
1329 ],[
1330 struct statfs stfs;
1332 memset(&stfs,0,sizeof(stfs));
1333 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1334 )
1335 )
1336 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1337 then
1338 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1339 [Define if the struct statfs is defined by <sys/vfs.h>])
1340 fi
1341 fi
1343 if test "$ac_cv_header_sys_statfs_h" = "yes"
1344 then
1345 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1346 wine_cv_sys_statfs_has_statfs,
1347 AC_TRY_COMPILE([
1348 #include <sys/types.h>
1349 #ifdef HAVE_SYS_PARAM_H
1350 # include <sys/param.h>
1351 #endif
1352 #include <sys/statfs.h>
1353 ],[
1354 struct statfs stfs;
1355 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1356 )
1357 )
1358 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1359 then
1360 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1361 [Define if the struct statfs is defined by <sys/statfs.h>])
1362 fi
1363 fi
1365 if test "$ac_cv_header_sys_mount_h" = "yes"
1366 then
1367 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1368 wine_cv_sys_mount_has_statfs,
1369 AC_TRY_COMPILE([
1370 #include <sys/types.h>
1371 #ifdef HAVE_SYS_PARAM_H
1372 # include <sys/param.h>
1373 #endif
1374 #include <sys/mount.h>
1375 ],[
1376 struct statfs stfs;
1377 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1378 )
1379 )
1380 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1381 then
1382 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1383 [Define if the struct statfs is defined by <sys/mount.h>])
1384 fi
1385 fi
1387 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1389 dnl Check for statfs members
1390 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1391 [#include <sys/types.h>
1392 #ifdef HAVE_SYS_PARAM_H
1393 # include <sys/param.h>
1394 #endif
1395 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1396 # include <sys/mount.h>
1397 #else
1398 # ifdef STATFS_DEFINED_BY_SYS_VFS
1399 # include <sys/vfs.h>
1400 # else
1401 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1402 # include <sys/statfs.h>
1403 # endif
1404 # endif
1405 #endif])
1407 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1408 [#ifdef HAVE_SYS_STATVFS_H
1409 #include <sys/statvfs.h>
1410 #endif])
1412 dnl Check for socket structure members
1413 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1414 [#include <sys/types.h>
1415 #ifdef HAVE_SYS_SOCKET_H
1416 # include <sys/socket.h>
1417 #endif
1418 #ifdef HAVE_SYS_UN_H
1419 # include <sys/un.h>
1420 #endif])
1422 dnl Check for scsireq_t and sg_io_hdr_t members
1423 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1424 [#include <sys/types.h>
1425 #ifdef HAVE_SCSI_SG_H
1426 #include <scsi/sg.h>
1427 #endif])
1429 dnl Check for siginfo_t members
1430 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1432 dnl Check for struct option
1433 AC_CHECK_MEMBERS([struct option.name],,,
1434 [#ifdef HAVE_GETOPT_H
1435 #include <getopt.h>
1436 #endif])
1438 dnl Check for stat.st_blocks
1439 AC_CHECK_MEMBERS([struct stat.st_blocks])
1441 dnl Check for the external timezone variables timezone and daylight
1442 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1443 AC_TRY_LINK([#include <time.h>],[timezone;],
1444 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1445 if test "$ac_cv_have_timezone" = "yes"
1446 then
1447 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1448 fi
1449 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1450 AC_TRY_LINK([#include <time.h>],[daylight;],
1451 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1452 if test "$ac_cv_have_daylight" = "yes"
1453 then
1454 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1455 fi
1457 dnl *** check for the need to define platform-specific symbols
1459 case $host_cpu in
1460 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1461 *x86_64*) WINE_CHECK_DEFINE([__x86_64__]) ;;
1462 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1463 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1464 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1465 esac
1467 case $host_vendor in
1468 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1469 esac
1471 dnl **** Generate output files ****
1473 AH_TOP([#define __WINE_CONFIG_H])
1475 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1476 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1477 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1478 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1479 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1480 WINE_CONFIG_EXTRA_DIR(include/wine)
1482 MAKE_RULES=Make.rules
1483 AC_SUBST_FILE(MAKE_RULES)
1485 MAKE_DLL_RULES=dlls/Makedll.rules
1486 AC_SUBST_FILE(MAKE_DLL_RULES)
1488 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1489 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1491 MAKE_TEST_RULES=dlls/Maketest.rules
1492 AC_SUBST_FILE(MAKE_TEST_RULES)
1494 MAKE_LIB_RULES=libs/Makelib.rules
1495 AC_SUBST_FILE(MAKE_LIB_RULES)
1497 MAKE_PROG_RULES=programs/Makeprog.rules
1498 AC_SUBST_FILE(MAKE_PROG_RULES)
1500 AC_CONFIG_FILES([
1501 Make.rules
1502 dlls/Makedll.rules
1503 dlls/Makeimplib.rules
1504 dlls/Maketest.rules
1505 libs/Makelib.rules
1506 programs/Makeprog.rules
1507 Makefile
1508 dlls/Makefile
1509 dlls/activeds/Makefile
1510 dlls/advapi32/Makefile
1511 dlls/advapi32/tests/Makefile
1512 dlls/advpack/Makefile
1513 dlls/advpack/tests/Makefile
1514 dlls/amstream/Makefile
1515 dlls/atl/Makefile
1516 dlls/avicap32/Makefile
1517 dlls/avifil32/Makefile
1518 dlls/cabinet/Makefile
1519 dlls/capi2032/Makefile
1520 dlls/cards/Makefile
1521 dlls/cfgmgr32/Makefile
1522 dlls/comcat/Makefile
1523 dlls/comctl32/Makefile
1524 dlls/comctl32/tests/Makefile
1525 dlls/commdlg/Makefile
1526 dlls/crtdll/Makefile
1527 dlls/crypt32/Makefile
1528 dlls/crypt32/tests/Makefile
1529 dlls/cryptdll/Makefile
1530 dlls/ctl3d/Makefile
1531 dlls/d3d8/Makefile
1532 dlls/d3d9/Makefile
1533 dlls/d3dim/Makefile
1534 dlls/d3drm/Makefile
1535 dlls/d3dx8/Makefile
1536 dlls/d3dxof/Makefile
1537 dlls/dbghelp/Makefile
1538 dlls/dciman32/Makefile
1539 dlls/ddraw/Makefile
1540 dlls/ddraw/tests/Makefile
1541 dlls/devenum/Makefile
1542 dlls/dinput/Makefile
1543 dlls/dinput/tests/Makefile
1544 dlls/dinput8/Makefile
1545 dlls/dmband/Makefile
1546 dlls/dmcompos/Makefile
1547 dlls/dmime/Makefile
1548 dlls/dmloader/Makefile
1549 dlls/dmscript/Makefile
1550 dlls/dmstyle/Makefile
1551 dlls/dmsynth/Makefile
1552 dlls/dmusic/Makefile
1553 dlls/dmusic32/Makefile
1554 dlls/dplay/Makefile
1555 dlls/dplayx/Makefile
1556 dlls/dpnet/Makefile
1557 dlls/dpnhpast/Makefile
1558 dlls/dsound/Makefile
1559 dlls/dsound/tests/Makefile
1560 dlls/dswave/Makefile
1561 dlls/dxdiagn/Makefile
1562 dlls/dxerr8/Makefile
1563 dlls/dxerr9/Makefile
1564 dlls/dxguid/Makefile
1565 dlls/gdi/Makefile
1566 dlls/gdi/tests/Makefile
1567 dlls/glu32/Makefile
1568 dlls/glut32/Makefile
1569 dlls/hhctrl.ocx/Makefile
1570 dlls/iccvid/Makefile
1571 dlls/icmp/Makefile
1572 dlls/ifsmgr.vxd/Makefile
1573 dlls/imagehlp/Makefile
1574 dlls/imm32/Makefile
1575 dlls/iphlpapi/Makefile
1576 dlls/iphlpapi/tests/Makefile
1577 dlls/itss/Makefile
1578 dlls/kernel/Makefile
1579 dlls/kernel/tests/Makefile
1580 dlls/lzexpand/Makefile
1581 dlls/lzexpand/tests/Makefile
1582 dlls/mapi32/Makefile
1583 dlls/mapi32/tests/Makefile
1584 dlls/mciavi32/Makefile
1585 dlls/mcicda/Makefile
1586 dlls/mciseq/Makefile
1587 dlls/midimap/Makefile
1588 dlls/mlang/Makefile
1589 dlls/mlang/tests/Makefile
1590 dlls/mmdevldr.vxd/Makefile
1591 dlls/monodebg.vxd/Makefile
1592 dlls/mpr/Makefile
1593 dlls/msacm/Makefile
1594 dlls/msacm/imaadp32/Makefile
1595 dlls/msacm/msadp32/Makefile
1596 dlls/msacm/msg711/Makefile
1597 dlls/msacm/tests/Makefile
1598 dlls/msacm/winemp3/Makefile
1599 dlls/mscms/Makefile
1600 dlls/mscms/tests/Makefile
1601 dlls/msdmo/Makefile
1602 dlls/mshtml/Makefile
1603 dlls/mshtml/tests/Makefile
1604 dlls/msi/Makefile
1605 dlls/msi/tests/Makefile
1606 dlls/msimg32/Makefile
1607 dlls/msisys/Makefile
1608 dlls/msnet32/Makefile
1609 dlls/msrle32/Makefile
1610 dlls/msvcrt/Makefile
1611 dlls/msvcrt/tests/Makefile
1612 dlls/msvcrt20/Makefile
1613 dlls/msvcrt40/Makefile
1614 dlls/msvcrtd/Makefile
1615 dlls/msvcrtd/tests/Makefile
1616 dlls/msvidc32/Makefile
1617 dlls/msvideo/Makefile
1618 dlls/mswsock/Makefile
1619 dlls/msxml3/Makefile
1620 dlls/msxml3/tests/Makefile
1621 dlls/netapi32/Makefile
1622 dlls/netapi32/tests/Makefile
1623 dlls/newdev/Makefile
1624 dlls/ntdll/Makefile
1625 dlls/ntdll/tests/Makefile
1626 dlls/objsel/Makefile
1627 dlls/odbc32/Makefile
1628 dlls/odbccp32/Makefile
1629 dlls/ole32/Makefile
1630 dlls/ole32/tests/Makefile
1631 dlls/oleacc/Makefile
1632 dlls/oleaut32/Makefile
1633 dlls/oleaut32/tests/Makefile
1634 dlls/olecli/Makefile
1635 dlls/oledlg/Makefile
1636 dlls/olepro32/Makefile
1637 dlls/olesvr/Makefile
1638 dlls/opengl32/Makefile
1639 dlls/powrprof/Makefile
1640 dlls/psapi/Makefile
1641 dlls/psapi/tests/Makefile
1642 dlls/qcap/Makefile
1643 dlls/quartz/Makefile
1644 dlls/quartz/tests/Makefile
1645 dlls/rasapi32/Makefile
1646 dlls/riched20/Makefile
1647 dlls/richedit/Makefile
1648 dlls/rpcrt4/Makefile
1649 dlls/rpcrt4/tests/Makefile
1650 dlls/rsabase/Makefile
1651 dlls/rsabase/tests/Makefile
1652 dlls/rsaenh/Makefile
1653 dlls/rsaenh/tests/Makefile
1654 dlls/secur32/Makefile
1655 dlls/secur32/tests/Makefile
1656 dlls/sensapi/Makefile
1657 dlls/serialui/Makefile
1658 dlls/setupapi/Makefile
1659 dlls/setupapi/tests/Makefile
1660 dlls/shdocvw/Makefile
1661 dlls/shdocvw/tests/Makefile
1662 dlls/shell32/Makefile
1663 dlls/shell32/tests/Makefile
1664 dlls/shfolder/Makefile
1665 dlls/shlwapi/Makefile
1666 dlls/shlwapi/tests/Makefile
1667 dlls/snmpapi/Makefile
1668 dlls/stdole2.tlb/Makefile
1669 dlls/stdole32.tlb/Makefile
1670 dlls/sti/Makefile
1671 dlls/strmiids/Makefile
1672 dlls/tapi32/Makefile
1673 dlls/twain/Makefile
1674 dlls/unicows/Makefile
1675 dlls/url/Makefile
1676 dlls/urlmon/Makefile
1677 dlls/urlmon/tests/Makefile
1678 dlls/user/Makefile
1679 dlls/user/tests/Makefile
1680 dlls/usp10/Makefile
1681 dlls/uuid/Makefile
1682 dlls/uxtheme/Makefile
1683 dlls/vdhcp.vxd/Makefile
1684 dlls/vdmdbg/Makefile
1685 dlls/version/Makefile
1686 dlls/version/tests/Makefile
1687 dlls/vmm.vxd/Makefile
1688 dlls/vnbt.vxd/Makefile
1689 dlls/vnetbios.vxd/Makefile
1690 dlls/vtdapi.vxd/Makefile
1691 dlls/vwin32.vxd/Makefile
1692 dlls/win32s/Makefile
1693 dlls/winaspi/Makefile
1694 dlls/winecrt0/Makefile
1695 dlls/wined3d/Makefile
1696 dlls/winedos/Makefile
1697 dlls/wineps/Makefile
1698 dlls/wininet/Makefile
1699 dlls/wininet/tests/Makefile
1700 dlls/winmm/Makefile
1701 dlls/winmm/joystick/Makefile
1702 dlls/winmm/mciwave/Makefile
1703 dlls/winmm/tests/Makefile
1704 dlls/winmm/wavemap/Makefile
1705 dlls/winmm/winealsa/Makefile
1706 dlls/winmm/winearts/Makefile
1707 dlls/winmm/wineaudioio/Makefile
1708 dlls/winmm/wineesd/Makefile
1709 dlls/winmm/winejack/Makefile
1710 dlls/winmm/winenas/Makefile
1711 dlls/winmm/wineoss/Makefile
1712 dlls/winnls/Makefile
1713 dlls/winsock/Makefile
1714 dlls/winsock/tests/Makefile
1715 dlls/winspool/Makefile
1716 dlls/winspool/tests/Makefile
1717 dlls/wintab32/Makefile
1718 dlls/wintrust/Makefile
1719 dlls/wldap32/Makefile
1720 dlls/wow32/Makefile
1721 dlls/wsock32/Makefile
1722 dlls/wtsapi32/Makefile
1723 dlls/x11drv/Makefile
1724 documentation/Makefile
1725 fonts/Makefile
1726 include/Makefile
1727 libs/Makefile
1728 libs/port/Makefile
1729 libs/unicode/Makefile
1730 libs/wine/Makefile
1731 libs/wpp/Makefile
1732 loader/Makefile
1733 programs/Makefile
1734 programs/avitools/Makefile
1735 programs/clock/Makefile
1736 programs/cmdlgtst/Makefile
1737 programs/control/Makefile
1738 programs/eject/Makefile
1739 programs/expand/Makefile
1740 programs/explorer/Makefile
1741 programs/hh/Makefile
1742 programs/msiexec/Makefile
1743 programs/notepad/Makefile
1744 programs/progman/Makefile
1745 programs/regedit/Makefile
1746 programs/regsvr32/Makefile
1747 programs/rpcss/Makefile
1748 programs/rundll32/Makefile
1749 programs/start/Makefile
1750 programs/taskmgr/Makefile
1751 programs/uninstaller/Makefile
1752 programs/view/Makefile
1753 programs/wcmd/Makefile
1754 programs/wineboot/Makefile
1755 programs/winebrowser/Makefile
1756 programs/winecfg/Makefile
1757 programs/wineconsole/Makefile
1758 programs/winedbg/Makefile
1759 programs/winefile/Makefile
1760 programs/winemenubuilder/Makefile
1761 programs/winemine/Makefile
1762 programs/winepath/Makefile
1763 programs/winetest/Makefile
1764 programs/winevdm/Makefile
1765 programs/winhelp/Makefile
1766 programs/winver/Makefile
1767 server/Makefile
1768 tools/Makefile
1769 tools/widl/Makefile
1770 tools/winapi/Makefile
1771 tools/winebuild/Makefile
1772 tools/winedump/Makefile
1773 tools/winegcc/Makefile
1774 tools/wmc/Makefile
1775 tools/wrc/Makefile])
1777 AC_OUTPUT
1779 if test "$have_x" = "no"
1780 then
1781 echo
1782 echo "*** Warning: X development files not found. Wine will be built without"
1783 echo "*** X support, which currently does not work, and would probably not be"
1784 echo "*** what you want anyway. You will need to install devel packages of"
1785 echo "*** Xlib/Xfree86 at the very least."
1786 fi
1788 if test "$wine_cv_opengl_version_OK" = "no"
1789 then
1790 echo
1791 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1792 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1793 fi
1795 if test "$wine_cv_msg_freetype" = "yes"
1796 then
1797 echo
1798 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1799 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1800 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1801 echo "*** enable Wine to use TrueType fonts."
1802 fi
1804 if test -z "$ALSALIBS" -a \
1805 -z "$ARTSC_LIBS" -a \
1806 -z "$AUDIOIOLIBS" -a \
1807 -z "$NASLIBS" -a \
1808 -z "$ESD_LIBS" -a \
1809 -z "$ac_cv_lib_soname_jack" -a \
1810 "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1811 "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1812 "$ac_cv_header_soundcard_h" != "yes"
1813 then
1814 echo "*** No sound system was found. Windows applications will be silent."
1815 echo "*** The currently supported sound systems are:"
1816 echo "*** ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS"
1817 fi
1819 echo
1820 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1821 echo
1823 dnl Local Variables:
1824 dnl comment-start: "dnl "
1825 dnl comment-end: ""
1826 dnl comment-start-skip: "\\bdnl\\b\\s *"
1827 dnl compile-command: "autoconf"
1828 dnl End: