configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$CXX"|| CXX="g++ -m32"
  28       test -n "$LD" || LD="ld -m elf_i386"
  29       test -n "$AS" || AS="as --32"
  30       host_cpu="i386"
  31     fi
  32     ;;
  33 esac
  34
  35 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  36 case $host_cpu in
  37   *i[[3456789]]86*)
  38     if test "x$enable_win16" != "xno"
  39     then
  40       enable_win16="yes"
  41     fi
  42     ;;
  43 esac
  44
  45 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  46 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  47 if test "x$enable_win16" != "xyes"
  48 then
  49   WIN16_FILES=""
  50   WIN16_INSTALL=""
  51 fi
  52
  53 dnl check for out of tree build with unclean source tree
  54 case "$srcdir" in
  55  .) ;;
  56  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  57       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  58 You need to run 'make distclean' in the source tree first.])
  59     fi ;;
  60 esac
  61
  62 dnl **** Check for some programs ****
  63
  64 AC_PROG_MAKE_SET
  65 AC_PROG_CC
  66 AC_PROG_CXX
  67 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  68 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  69
  70 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  71   [if test -z "$with_wine_tools"; then
  72      if test "$cross_compiling" = "yes"; then
  73        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  74      else
  75        wine_cv_toolsdir="\$(TOPOBJDIR)"
  76      fi
  77    elif test -d "$with_wine_tools/tools/winebuild"; then
  78      case $with_wine_tools in
  79        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  80        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  81      esac
  82    else
  83      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  84    fi])
  85 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  86
  87 AC_PATH_XTRA
  88
  89 dnl Check for flex
  90 AC_CHECK_PROGS(FLEX,flex,none)
  91 if test "$FLEX" = "none"
  92 then
  93   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  94 fi
  95
  96 dnl Check for bison
  97 AC_CHECK_PROGS(BISON,bison,none)
  98 if test "$BISON" = "none"
  99 then
 100   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 101 fi
 102
 103 AC_CHECK_TOOLS(AS,[gas as],as)
 104 AC_CHECK_TOOL(LD,ld,ld)
 105 AC_CHECK_TOOL(AR,ar,ar)
 106 AC_PROG_RANLIB
 107 AC_CHECK_TOOL(STRIP,strip,strip)
 108 AC_CHECK_TOOL(WINDRES,windres,false)
 109 AC_PROG_LN_S
 110 WINE_PROG_LN
 111 AC_PROG_EGREP
 112 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 113 AC_PROG_INSTALL
 114 dnl Prepend src dir to install path dir if it's a relative path
 115 case "$INSTALL" in
 116   [[\\/$]]* | ?:[[\\/]]* ) ;;
 117   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 118 esac
 119
 120 dnl Check for lint
 121 AC_CHECK_PROGS(LINT, lclint lint)
 122 if test "$LINT" = "lint"
 123 then
 124   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 125   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 126 fi
 127 AC_SUBST(LINT)
 128 AC_SUBST(LINTFLAGS)
 129
 130 dnl Check for various programs
 131 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 132 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 133
 134 case $host_cpu in
 135   *i[[3456789]]86*)
 136     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 137     ;;
 138 esac
 139
 140 dnl **** Check for some libraries ****
 141
 142 dnl Check for -li386 for NetBSD and OpenBSD
 143 AC_CHECK_LIB(i386,i386_set_ldt)
 144 dnl Check for -lossaudio for NetBSD
 145 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 146 dnl Check for -lpthread
 147 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 148
 149 AC_SUBST(XLIB,"")
 150 AC_SUBST(XFILES,"")
 151 AC_SUBST(OPENGLFILES,"")
 152 AC_SUBST(GLU32FILES,"")
 153 AC_SUBST(OPENGL_LIBS,"")
 154 AC_SUBST(QUARTZFILES,"")
 155
 156 dnl **** Check for header files ****
 157
 158 AC_CHECK_HEADERS(\
 159         AudioUnit/AudioUnit.h \
 160         Carbon/Carbon.h \
 161         CoreAudio/CoreAudio.h \
 162         DiskArbitration/DiskArbitration.h \
 163         IOKit/IOKitLib.h \
 164         alsa/asoundlib.h \
 165         arpa/inet.h \
 166         arpa/nameser.h \
 167         asm/types.h \
 168         capi20.h \
 169         cups/cups.h \
 170         curses.h \
 171         direct.h \
 172         dlfcn.h \
 173         elf.h \
 174         float.h \
 175         fontconfig/fontconfig.h \
 176         getopt.h \
 177         ieeefp.h \
 178         io.h \
 179         jack/jack.h \
 180         jpeglib.h \
 181         lber.h \
 182         lcms.h \
 183         lcms/lcms.h \
 184         ldap.h \
 185         libaudioio.h \
 186         link.h \
 187         linux/cdrom.h \
 188         linux/compiler.h \
 189         linux/hdreg.h \
 190         linux/input.h \
 191         linux/ioctl.h \
 192         linux/joystick.h \
 193         linux/major.h \
 194         linux/param.h \
 195         linux/serial.h \
 196         linux/ucdrom.h \
 197         mach/mach.h \
 198         mach/machine.h \
 199         machine/cpu.h \
 200         machine/limits.h \
 201         machine/soundcard.h \
 202         mntent.h \
 203         ncurses.h \
 204         netdb.h \
 205         netinet/in.h \
 206         netinet/in_systm.h \
 207         netinet/tcp.h \
 208         netinet/tcp_fsm.h \
 209         openssl/err.h \
 210         openssl/ssl.h \
 211         png.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/socketvar.h \
 252         sys/sockio.h \
 253         sys/soundcard.h \
 254         sys/statvfs.h \
 255         sys/strtio.h \
 256         sys/syscall.h \
 257         sys/sysctl.h \
 258         sys/time.h \
 259         sys/times.h \
 260         sys/uio.h \
 261         sys/un.h \
 262         sys/vm86.h \
 263         sys/wait.h \
 264         syscall.h \
 265         termios.h \
 266         unicode/ubidi.h \
 267         unistd.h \
 268         utime.h \
 269         valgrind/memcheck.h
 270 )
 271 AC_HEADER_STAT()
 272
 273 dnl **** Checks for headers that depend on other ones ****
 274
 275 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 276     [#include <sys/types.h>
 277      #if HAVE_SYS_PARAM_H
 278      # include <sys/param.h>
 279      #endif])
 280
 281 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 282     [#include <sys/types.h>
 283      #if HAVE_SYS_SOCKET_H
 284      # include <sys/socket.h>
 285      #endif])
 286      #if HAVE_SYS_SOCKETVAR_H
 287      # include <sys/socketvar.h>
 288      #endif
 289
 290 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 291     [#include <sys/types.h>
 292      #if HAVE_SYS_SOCKET_H
 293      # include <sys/socket.h>
 294      #endif
 295      #if HAVE_SYS_SOCKETVAR_H
 296      # include <sys/socketvar.h>
 297      #endif
 298      #if HAVE_NETINET_IN_H
 299      # include <netinet/in.h>
 300      #endif
 301      #ifdef HAVE_NETINET_TCP_H
 302      # include <netinet/tcp.h>
 303      #endif])
 304
 305 AC_CHECK_HEADERS([linux/ipx.h],,,
 306     [#include <sys/types.h>
 307      #ifdef HAVE_ASM_TYPES_H
 308      # include <asm/types.h>
 309      #endif
 310      #if HAVE_SYS_SOCKET_H
 311      # include <sys/socket.h>
 312      #endif])
 313
 314 AC_CHECK_HEADERS([resolv.h],,,
 315     [#include <sys/types.h>
 316      #if HAVE_SYS_SOCKET_H
 317      # include <sys/socket.h>
 318      #endif
 319      #if HAVE_NETINET_IN_H
 320      # include <netinet/in.h>
 321      #endif
 322      #if HAVE_ARPA_NAMESER_H
 323      # include <arpa/nameser.h>
 324      #endif])
 325
 326 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 327
 328 AC_CHECK_HEADERS([sys/thr.h],,,
 329 [#include <sys/types.h>
 330 #if HAVE_UCONTEXT_H
 331 #include <ucontext.h>
 332 #endif])
 333
 334 AC_CHECK_HEADERS([pthread_np.h],,,
 335 [#ifdef HAVE_PTHREAD_H
 336 #include <pthread.h>
 337 #endif])
 338
 339 AC_CHECK_HEADERS([linux/videodev.h],,,
 340 [#ifdef HAVE_SYS_TIME_H
 341 #include <sys/time.h>
 342 #endif
 343 #include <sys/types.h>
 344 #ifdef HAVE_ASM_TYPES_H
 345 #include <asm/types.h>
 346 #endif])
 347
 348 dnl Check for broken kernel header that doesn't define __user
 349 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 350
 351 dnl **** Check for working dll ****
 352
 353 AC_SUBST(DLLEXT,"")
 354 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 355 AC_SUBST(LDSHARED,"")
 356 AC_SUBST(LDDLLFLAGS,"")
 357 AC_SUBST(LIBEXT,"so")
 358 AC_SUBST(IMPLIBEXT,"def")
 359 AC_SUBST(LDRPATH_INSTALL,"")
 360 AC_SUBST(LDRPATH_LOCAL,"")
 361 WINE_PATH_LDD
 362
 363 case $host_os in
 364   cygwin*|mingw32*)
 365     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 366     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 367     AC_CHECK_TOOL(MINGWAR,ar,false)
 368     if test "$DLLWRAP" = "false"; then
 369       LIBEXT="a"
 370     else
 371       dnl FIXME - check whether dllwrap works correctly...
 372       LIBEXT="dll"
 373     fi
 374     IMPLIBEXT="a"
 375     dnl We can't build 16-bit NE dlls
 376     WIN16_FILES=""
 377     WIN16_INSTALL=""
 378     ;;
 379   darwin*|macosx*)
 380     DLLEXT=".so"
 381     LIBEXT="dylib"
 382     DLLFLAGS="$DLLFLAGS -fPIC"
 383     LDDLLFLAGS="-bundle -multiply_defined suppress"
 384     LIBWINE_LDFLAGS="-multiply_defined suppress"
 385     LDSHARED="\$(CC) -dynamiclib"
 386     STRIP="$STRIP -x"
 387     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 388     dnl declare needed frameworks
 389     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 390     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 391     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 392     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 393     then
 394         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 395         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 396     fi
 397     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 398     then
 399         dnl CoreServices needed by AudioUnit
 400         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 401     fi
 402     case $host_cpu in
 403       *powerpc*)
 404         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 405         ;;
 406     esac
 407     dnl Enable quartz driver on Mac OS X
 408     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 409     then
 410         AC_SUBST(CARBONLIB,"-framework Carbon")
 411         QUARTZFILES='$(QUARTZFILES)'
 412     fi
 413     ;;
 414   *)
 415     DLLFLAGS="$DLLFLAGS -fPIC"
 416     DLLEXT=".so"
 417     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 418         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 419                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 420     if test "$ac_cv_c_dll_gnuelf" = "yes"
 421     then
 422       LDSHARED="\$(CC) -shared"
 423       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 424       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 425                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 426                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 427                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 428
 429       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 430
 431       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 432                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 433
 434       echo '{ global: *; };' >conftest.map
 435       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 436                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 437       rm -f conftest.map
 438
 439       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 440                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 441
 442       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 443                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 444                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 445           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 446                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 447                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 448
 449       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 450                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 451
 452       case $host_cpu in
 453         *i[[3456789]]86* | x86_64)
 454           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 455                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 456           ;;
 457       esac
 458
 459     else
 460       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 461           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 462                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 463       if test "$ac_cv_c_dll_unixware" = "yes"
 464       then
 465         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 466         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 467
 468       else
 469         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 470           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 471         if test "$ac_cv_c_dll_hpux" = "yes"
 472         then
 473           LIBEXT="sl"
 474           DLLEXT=".sl"
 475           LDDLLFLAGS="-shared -fPIC"
 476           LDSHARED="\$(CC) -shared"
 477         fi
 478       fi
 479     fi
 480
 481     dnl Check for cross compiler to build test programs
 482     AC_SUBST(CROSSTEST,"")
 483     if test "$cross_compiling" = "no"
 484     then
 485       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 486       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 487       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 488       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 489       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 490     fi
 491     ;;
 492 esac
 493
 494 if test "$LIBEXT" = "a"; then
 495   AC_MSG_ERROR(
 496 [could not find a way to build shared libraries.
 497 It is currently not possible to build Wine without shared library
 498 (.so) support to allow transparent switch between .so and .dll files.
 499 If you are using Linux, you will need a newer binutils.]
 500 )
 501 fi
 502
 503 dnl **** Check for X11 ****
 504
 505 if test "$have_x" = "yes"
 506 then
 507     XLIB="-lXext -lX11"
 508     ac_save_CPPFLAGS="$CPPFLAGS"
 509     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 510
 511     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 512     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 513
 514     dnl *** All of the following tests require X11/Xlib.h
 515     AC_CHECK_HEADERS([X11/Xlib.h \
 516                       X11/XKBlib.h \
 517                       X11/Xutil.h \
 518                       X11/Xcursor/Xcursor.h \
 519                       X11/extensions/shape.h \
 520                       X11/extensions/XInput.h \
 521                       X11/extensions/XShm.h \
 522                       X11/extensions/Xinerama.h \
 523                       X11/extensions/Xrandr.h \
 524                       X11/extensions/Xrender.h \
 525                       X11/extensions/xf86vmode.h],,,
 526 [#ifdef HAVE_X11_XLIB_H
 527 # include <X11/Xlib.h>
 528 #endif
 529 #ifdef HAVE_X11_XUTIL_H
 530 # include <X11/Xutil.h>
 531 #endif])
 532
 533         dnl *** Check for X keyboard extension
 534         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 535         then
 536               AC_CHECK_LIB(X11, XkbQueryExtension,
 537               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 538               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 539         fi
 540
 541         dnl *** Check for X cursor
 542         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 543         then
 544             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 545         fi
 546
 547         dnl *** Check for X input extension
 548         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 549         then
 550             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 551         fi
 552
 553         dnl *** Check for X Shm extension
 554         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 555         then
 556               AC_CHECK_LIB(Xext, XShmQueryExtension,
 557               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 558               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 559         fi
 560         WINE_NOTICE_IF([test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],[XShm development files not found.
 561 Wine will be built without XShm support. (winex11.drv)])
 562
 563         dnl *** Check for X shape extension
 564         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 565         then
 566               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 567               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 568               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 569         fi
 570         WINE_NOTICE_IF([test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],[XShape development files not found.
 571 Wine will be built without XShape support. (winex11.drv)])
 572
 573         dnl *** Check for XFree86 VMODE extension
 574         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 575         then
 576                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 577                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 578                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 579                   ],,
 580                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 581         fi
 582         WINE_NOTICE_IF([test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],[Xxf86vm development files not found.
 583 Wine will be built without XF86 Vidmode support. (winex11.drv)])
 584
 585         dnl *** Check for Transform functions in Xrender
 586         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 587         then
 588             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 589               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 590                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 591                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 592                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 593
 594         fi
 595         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xrender" = "x"],[XRender development files not found.
 596 Wine will be built without XRender support. (winex11.drv)])
 597
 598         dnl *** Check for X RandR extension
 599         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 600         then
 601                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 602 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 603                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 604         fi
 605         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xrandr" = "x"],[XRandr development files not found.
 606 Wine will be built without XRandr support. (winex11.drv)])
 607
 608         dnl *** Check for Xinerama extension
 609         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 610         then
 611                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 612 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 613                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 614         fi
 615         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xinerama" = "x"],[Xinerama development files not found.
 616 Wine will be built without Xinerama support. (winex11.drv)])
 617
 618     dnl *** End of X11/Xlib.h check
 619
 620     dnl Check for the presence of OpenGL
 621     if test "x$with_opengl" != "xno"
 622     then
 623         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 624 [#ifdef HAVE_GL_GLX_H
 625 # include <GL/glx.h>
 626 #endif])
 627         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 628         then
 629             dnl Check for some problems due to old Mesa versions
 630             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 631               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 632                 [wine_cv_opengl_header_version_OK="yes"],
 633                 [wine_cv_opengl_header_version_OK="no"]))
 634
 635             if test "$wine_cv_opengl_header_version_OK" = "yes"
 636             then
 637                 dnl Check for the presence of the library
 638                 WINE_CHECK_SONAME(GL,glXCreateContext,
 639                              [OPENGL_LIBS="-lGL"
 640                              OPENGLFILES='$(OPENGLFILES)'
 641                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 642                              [if test -f /usr/X11R6/lib/libGL.a
 643                               then
 644                                   WINE_WARNING([/usr/X11R6/lib/libGL.a is present on your system.
 645 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
 646                               else
 647                                   WINE_WARNING([No OpenGL library found on this system.
 648 Wine will be build without OpenGL or Direct3D support.])
 649                               fi],
 650                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 651
 652                 dnl Check for GLU32 library.
 653                 AC_CHECK_LIB(GLU,gluLookAt,
 654                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 655                              GLU32FILES='$(GLU32FILES)']
 656                              ,,
 657                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 658              else
 659                  WINE_WARNING([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).
 660 Wine will be build without OpenGL or Direct3D support.])
 661              fi
 662          else
 663              WINE_WARNING([OpenGL development headers not found.
 664 Wine will be build without OpenGL or Direct3D support.])
 665          fi
 666     fi
 667
 668     dnl **** Check for NAS ****
 669     AC_SUBST(NASLIBS,"")
 670     AC_CHECK_HEADERS(audio/audiolib.h,
 671          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 672           AC_CHECK_LIB(audio,AuCreateFlow,
 673                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 674                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 675                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 676                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 677                           [$X_LIBS])
 678                        ],,
 679                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 680
 681     CPPFLAGS="$ac_save_CPPFLAGS"
 682     XFILES='$(XFILES)'
 683 else
 684     XLIB=""
 685     X_CFLAGS=""
 686     X_LIBS=""
 687     WINE_WARNING([X development files not found. Wine will be built
 688 without X support, which probably isn't what you want. You will need to install
 689 development packages of Xlib/Xfree86 at the very least.])
 690 fi
 691
 692 dnl **** Check for libxml2 ****
 693
 694 AC_SUBST(XML2LIBS,"")
 695 AC_SUBST(XML2INCL,"")
 696 AC_SUBST(XSLTLIBS,"")
 697 AC_SUBST(XSLTINCL,"")
 698 ac_save_CPPFLAGS="$CPPFLAGS"
 699 if test "$PKG_CONFIG" != "false"
 700 then
 701     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 702     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 703 else
 704     ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 705     ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 706 fi
 707 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 708 AC_CHECK_HEADERS(libxml/parser.h,
 709         [AC_CHECK_LIB(xml2, xmlParseMemory,
 710             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 711              XML2LIBS="$ac_xml_libs"
 712              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 713          AC_CHECK_LIB(xml2, xmlReadMemory,
 714             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 715          AC_CHECK_LIB(xml2, xmlNewDocPI,
 716             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 717     ])
 718 CPPFLAGS="$ac_save_CPPFLAGS"
 719 WINE_NOTICE_IF([test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],[libxml2 development files not found.
 720 Wine will be built without XML support. (msxml.dll)])
 721
 722 if test "$PKG_CONFIG" != "false"
 723 then
 724     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 725     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 726 else
 727     ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 728     ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 729 fi
 730 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 731 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 732         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 733             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 734              XSLTLIBS="$ac_xslt_libs"
 735              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 736         ],,
 737 [#ifdef HAVE_LIBXSLT_PATTERN_H
 738 # include <libxslt/pattern.h>
 739 #endif])
 740 CPPFLAGS="$ac_save_CPPFLAGS"
 741 WINE_NOTICE_IF([test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],[libxslt development files not found.
 742 Wine will be built without xslt support. (msxml.dll)])
 743
 744 dnl **** Check for libhal ****
 745 AC_SUBST(HALINCL,"")
 746 if test "$PKG_CONFIG" != "false"
 747 then
 748     ac_save_CPPFLAGS="$CPPFLAGS"
 749     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 750     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 751     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 752     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 753     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 754     then
 755         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 756           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 757             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 758     fi
 759     CPPFLAGS="$ac_save_CPPFLAGS"
 760 fi
 761 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_hal" = "x"],[libhal development files not found.
 762 Wine will be built without dynamic device support. (explorer.exe)])
 763
 764 dnl **** Check which curses lib to use ***
 765 CURSESLIBS=""
 766 if test "$ac_cv_header_ncurses_h" = "yes"
 767 then
 768     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 769 elif test "$ac_cv_header_curses_h" = "yes"
 770 then
 771     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 772 fi
 773 ac_save_LIBS="$LIBS"
 774 LIBS="$LIBS $CURSESLIBS"
 775 AC_CHECK_FUNCS(mousemask)
 776 LIBS="$ac_save_LIBS"
 777 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],[lib(n)curses development files not found.
 778 Wine will be built without (n)curses support. (wineconsole.exe)])
 779
 780 dnl **** Check for SANE ****
 781 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 782 if test "$sane_devel" != "no"
 783 then
 784     ac_sane_incl="`$sane_devel --cflags`"
 785     ac_save_CPPFLAGS="$CPPFLAGS"
 786     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 787     AC_CHECK_HEADER(sane/sane.h,
 788         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 789     CPPFLAGS="$ac_save_CPPFLAGS"
 790 fi
 791 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_sane" = "x"],[libsane development files not found.
 792 Wine will be built without scanner support. (sane.ds/twain_32.dll)])
 793
 794 dnl **** Check for libgphoto2 ****
 795 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 796 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 797 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 798 then
 799     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 800     ac_gphoto2_libs=""
 801     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 802     do
 803       case "$i" in
 804         -L/usr/lib|-L/usr/lib64) ;;
 805         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 806       esac
 807     done
 808     ac_save_CPPFLAGS="$CPPFLAGS"
 809     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 810     AC_CHECK_HEADER(gphoto2-camera.h,
 811                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 812                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 813                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 814                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 815                                   [$GPHOTO2LIBS])])
 816     CPPFLAGS="$ac_save_CPPFLAGS"
 817 fi
 818 WINE_NOTICE_IF([test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],[libgphoto2 development files not found.
 819 Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
 820
 821
 822 dnl **** Check for the ICU library ****
 823 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 824 then
 825     saved_libs="$LIBS"
 826     icu_libs="-lsicuuc -lsicudata -lstdc++ -lgcc_s"
 827     if test -n "$ICU_LIB_DIR"
 828     then
 829         icu_libs="-L$ICU_LIB_DIR $icu_libs"
 830     fi
 831     AC_MSG_CHECKING(whether can link with ICU libraries)
 832     LIBS="$saved_libs $icu_libs"
 833     AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <unicode/ubidi.h>]],[[ubidi_open()]])],
 834                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 835                  AC_SUBST(ICULIBS,"$icu_libs")
 836                  AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 837     LIBS="$saved_libs"
 838 fi
 839 WINE_NOTICE_IF([test "x$ICULIBS" = "x"],[libicu development files not found.
 840 Wine will be built without bidi (Right to Left) support. (gdi32.dll)])
 841
 842 dnl **** Check for resolver library ***
 843 AC_SUBST(RESOLVLIBS,"")
 844 if test "$ac_cv_header_resolv_h" = "yes"
 845 then
 846     AC_CHECK_LIB(resolv, res_query,
 847         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 848          RESOLVLIBS="-lresolv"])
 849 fi
 850
 851 dnl **** Check for LittleCMS ***
 852 AC_SUBST(LCMSLIBS,"")
 853 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 854 then
 855     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 856         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 857          LCMSLIBS="-llcms"])
 858 fi
 859 WINE_NOTICE_IF([test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],[liblcms development files not found.
 860 Wine will be built without Color Management support. (mscms.dll)])
 861
 862 dnl **** Check for OpenLDAP ***
 863 AC_SUBST(LDAPLIBS,"")
 864 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 865 then
 866     AC_CHECK_LIB(ldap_r, ldap_initialize,
 867         [AC_CHECK_LIB(lber, ber_init,
 868             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 869              LDAPLIBS="-lldap_r -llber"],,
 870              [$LIBPTHREAD])],,
 871              [$LIBPTHREAD])
 872     WINE_CHECK_LIB_FUNCS(\
 873         ldap_count_references \
 874         ldap_first_reference \
 875         ldap_next_reference \
 876         ldap_parse_reference,
 877         [$LDAPLIBS $LIBPTHREAD])
 878 fi
 879 WINE_NOTICE_IF([test "x$LDAPLIBS" = "x"],[libldap (OpenLDAP) development files not found.
 880 Wine will be built without LDAP support. (wldap32.dll)])
 881
 882 dnl **** Check for FreeType 2 ****
 883 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 884 if test "$ft_devel" != "false"
 885 then
 886     ac_freetype_libs=`$ft_devel --libs`
 887     ac_freetype_incl=`$ft_devel --cflags`
 888     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 889     if test "$ft_lib" = "yes"
 890     then
 891         ac_save_CPPFLAGS="$CPPFLAGS"
 892         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 893         AC_CHECK_HEADERS(ft2build.h \
 894                          freetype/freetype.h \
 895                          freetype/ftglyph.h \
 896                          freetype/tttables.h \
 897                          freetype/ftnames.h \
 898                          freetype/ftsnames.h \
 899                          freetype/ttnameid.h \
 900                          freetype/ftoutln.h \
 901                          freetype/ftwinfnt.h \
 902                          freetype/ftmodapi.h \
 903                          freetype/internal/sfnt.h,,,
 904                          [#if HAVE_FT2BUILD_H
 905                           #include <ft2build.h>
 906                           #endif])
 907         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 908                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 909           [Define if you have the <freetype/fttrigon.h> header file.])
 910                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 911         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 912         ac_save_CFLAGS="$CFLAGS"
 913         CFLAGS="$CFLAGS $ac_freetype_libs"
 914         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 915         CFLAGS="$ac_save_CFLAGS"
 916         CPPFLAGS="$ac_save_CPPFLAGS"
 917         dnl Check that we have at least freetype/freetype.h
 918         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 919         then
 920             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 921             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
 922             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
 923         fi
 924     fi
 925 fi
 926
 927 dnl Only build the fonts dir if we have both freetype and fontforge
 928 if test "$FONTFORGE" = "false"
 929 then
 930     WINE_WARNING([FontForge is missing.
 931 Fonts will not be built. Dialog text may be invisible or unaligned.])
 932 elif test "x$FREETYPELIBS" = "x"
 933 then
 934     WINE_WARNING([FreeType development files not found.
 935 Fonts will not be built. Dialog text may be invisible or unaligned.])
 936 else
 937   AC_SUBST(FONTSSUBDIRS,"fonts")
 938 fi
 939
 940 dnl **** Check for parport (currently Linux only) ****
 941 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 942  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
 943     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
 944 if test "$ac_cv_c_ppdev" = "yes"
 945 then
 946     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 947 fi
 948
 949 dnl **** Check for va_copy ****
 950 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 951  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
 952     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
 953  )
 954 if test "$ac_cv_c_va_copy" = "yes"
 955 then
 956     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 957 fi
 958 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 959  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
 960     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
 961  )
 962 if test "$ac_cv_c___va_copy" = "yes"
 963 then
 964     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 965 fi
 966
 967 dnl **** Check for sigsetjmp ****
 968 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 969  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
 970     sigsetjmp( buf, 1 );
 971     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
 972  )
 973 if test "$ac_cv_c_sigsetjmp" = "yes"
 974 then
 975     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 976 fi
 977
 978 dnl **** Check for pthread_rwlock_t ****
 979 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 980 #include <pthread.h>])
 981
 982 dnl **** Check for pthread functions ****
 983 WINE_CHECK_LIB_FUNCS(\
 984         pthread_attr_get_np \
 985         pthread_getattr_np \
 986         pthread_get_stackaddr_np \
 987         pthread_get_stacksize_np,
 988         [$LIBPTHREAD])
 989
 990 dnl **** Check for EsounD ****
 991 AC_PATH_PROG(ESDCONFIG, esd-config)
 992 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 993 then
 994     ESD_CFLAGS=""
 995     for i in `$ESDCONFIG --cflags`
 996     do
 997       case "$i" in
 998         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 999       esac
1000     done
1001     ESD_LIBS=`$ESDCONFIG --libs`
1002     save_CFLAGS="$CFLAGS"
1003     CFLAGS="$CFLAGS $ESD_CFLAGS"
1004     AC_CHECK_LIB(esd,esd_open_sound,
1005         [AC_SUBST(ESDLIBS, $ESD_LIBS)
1006          AC_SUBST(ESDINCL, $ESD_CFLAGS)
1007          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
1008     CFLAGS="$save_CFLAGS"
1009 fi
1010
1011 dnl **** Check for ALSA 1.x ****
1012 AC_SUBST(ALSALIBS,"")
1013 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1014 then
1015     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1016         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1017 #include <alsa/asoundlib.h>
1018 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1019 #include <sys/asoundlib.h>
1020 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1021                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1022                          ALSALIBS="-lasound"],[])])
1023 fi
1024
1025 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1026 AC_SUBST(AUDIOIOLIBS,"")
1027 if test "$ac_cv_header_libaudioio_h" = "yes"
1028 then
1029     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1030                   [AUDIOIOLIBS="-laudioio"
1031                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1032 fi
1033
1034 dnl **** Check for capi4linux ****
1035
1036 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1037 then
1038     WINE_CHECK_SONAME(capi20,capi20_register)
1039 fi
1040 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_capi20" = "x"],[libcapi20 development files not found.
1041 Wine will be built without ISDN support. (capi2032.dll)])
1042
1043 dnl **** Check for cups ****
1044 if test "$ac_cv_header_cups_cups_h" = "yes"
1045 then
1046     WINE_CHECK_SONAME(cups,cupsGetDefault)
1047 fi
1048 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_cups" = "x"],[libcups development files not found.
1049 Wine will be built without CUPS support.])
1050
1051 dnl **** Check for jack ****
1052 if test "$ac_cv_header_jack_jack_h" = "yes"
1053 then
1054     WINE_CHECK_SONAME(jack,jack_client_new)
1055 fi
1056
1057 dnl **** Check for fontconfig ****
1058 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1059 then
1060     WINE_CHECK_SONAME(fontconfig,FcInit)
1061 fi
1062 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_fontconfig" = "x"],[fontconfig development files not found.
1063 Wine will be built without fontconfig support.])
1064
1065 dnl **** Check for SSL ****
1066 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1067 then
1068     WINE_CHECK_SONAME(ssl,SSL_library_init)
1069     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1070 fi
1071 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_ssl" = "x"],[OpenSSL development files not found.
1072 Wine will be built without SSL support. (wininet.dll)])
1073
1074 dnl **** Check for libjpeg ****
1075 if test "$ac_cv_header_jpeglib_h" = "yes"
1076 then
1077     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1078 fi
1079 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_jpeg" = "x"],[libjpeg development files not found.
1080 Wine will be built without JPEG support. (oleaut32.dll)])
1081
1082 dnl **** Check for libpng ****
1083 if test "$ac_cv_header_png_h" = "yes"
1084 then
1085     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1086 fi
1087 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_png" = "x"],[libpng development files not found.
1088 Wine will be built without PNG support. (oleaut32.dll)])
1089
1090 dnl **** Check for any sound system ****
1091 WINE_WARNING_IF([test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1092                  "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1093                  "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1094                  "$ac_cv_header_soundcard_h" != "yes"],
1095 [No sound system was found. Windows applications will be silent.])
1096
1097 dnl **** Check for gcc specific options ****
1098
1099 AC_SUBST(EXTRACFLAGS,"")
1100 if test "x${GCC}" = "xyes"
1101 then
1102   EXTRACFLAGS="-Wall -pipe"
1103
1104   dnl Check for strength-reduce bug
1105   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1106                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1107 [[static int Array[[3]];
1108   unsigned int B = 3;
1109   int i;
1110   for(i=0; i<B; i++) Array[[i]] = i - 3;
1111   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1112   L[[i]] = 4;
1113   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1114     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1115   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1116   then
1117     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1118   fi
1119
1120   dnl Check for some compiler flags
1121
1122   WINE_TRY_CFLAGS([-fshort-wchar],
1123                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1124                              [Specifies the compiler flag that forces a short wchar_t])])
1125   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1126   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1127   WINE_TRY_CFLAGS([-Wwrite-strings])
1128
1129   dnl Check for noisy string.h
1130   saved_CFLAGS="$CFLAGS"
1131   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1132   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1133       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1134   CFLAGS="$saved_CFLAGS"
1135   if test "$ac_cv_c_string_h_warnings" = "no"
1136   then
1137     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1138   fi
1139
1140   AC_SUBST(BUILTINFLAG,"")
1141   saved_CFLAGS="$CFLAGS"
1142   CFLAGS="$CFLAGS -Werror"
1143   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1144       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1145   CFLAGS="$saved_CFLAGS"
1146   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1147   then
1148     BUILTINFLAG="-fno-builtin"
1149   fi
1150 fi
1151
1152 dnl **** Check how to define a function in assembly code ****
1153
1154 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1155   WINE_TRY_ASM_LINK(
1156       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1157       ac_cv_asm_func_def=".def",
1158     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1159       ac_cv_asm_func_def=".type @function",
1160     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1161       ac_cv_asm_func_def=".type 2",
1162       ac_cv_asm_func_def="unknown")])]))
1163
1164 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1165 case "$ac_cv_asm_func_def" in
1166   ".def")
1167      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1168   ".type @function")
1169      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1170   ".type 2")
1171      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1172   *)
1173      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1174 esac
1175
1176 dnl **** Check for underscore on external symbols ****
1177
1178 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1179     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1180                       [extern int ac_test;],
1181                       [if (ac_test) return 1],
1182                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1183
1184 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1185 if test "$ac_cv_c_extern_prefix" = "yes"
1186 then
1187   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1188 else
1189   AC_DEFINE([__ASM_NAME(name)], [name])
1190 fi
1191
1192 dnl **** Platform-specific checks ****
1193
1194 AC_SUBST(LDPATH,"")
1195 case $build_os in
1196   cygwin*|mingw32*)
1197     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1198     ;;
1199   darwin*|macosx*)
1200     ;;
1201   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1202     if test -z "$LDRPATH_LOCAL"
1203     then
1204       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1205     fi
1206     ;;
1207   *)
1208     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1209     ;;
1210 esac
1211
1212 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1213 case $host_os in
1214   mingw32*)
1215     AC_SUBST(CRTLIBS,"-lmsvcrt")
1216     AC_SUBST(SOCKETLIBS,"-lws2_32")
1217     ;;
1218 esac
1219
1220 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1221 case $host_cpu in
1222   *i[[3456789]]86*)
1223     case $host_os in
1224       linux* | k*bsd*-gnu)
1225         AC_SUBST(MAIN_BINARY,"wine-glibc")
1226         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1227       freebsd*)
1228         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1229         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1230     esac
1231     ;;
1232 esac
1233
1234 dnl **** Check for functions ****
1235
1236 AC_CHECK_FUNCS(\
1237         _pclose \
1238         _popen \
1239         _snprintf \
1240         _spawnvp \
1241         _stricmp \
1242         _strnicmp \
1243         _vsnprintf \
1244         asctime_r \
1245         chsize \
1246         clone \
1247         dlopen \
1248         epoll_create \
1249         ffs \
1250         finite \
1251         fork \
1252         fpclass \
1253         fstatfs \
1254         fstatvfs \
1255         ftruncate \
1256         futimes \
1257         futimesat \
1258         getdirentries \
1259         getopt_long \
1260         getpagesize \
1261         getpwuid \
1262         gettid \
1263         gettimeofday \
1264         getuid \
1265         inet_pton \
1266         kqueue \
1267         lstat \
1268         memmove \
1269         mmap \
1270         pclose \
1271         poll \
1272         popen \
1273         prctl \
1274         pread \
1275         pwrite \
1276         readlink \
1277         rfork \
1278         sched_yield \
1279         select \
1280         setrlimit \
1281         settimeofday \
1282         sigaltstack \
1283         sigprocmask \
1284         snprintf \
1285         spawnvp \
1286         statfs \
1287         statvfs \
1288         strcasecmp \
1289         strerror \
1290         strncasecmp \
1291         strtold \
1292         tcgetattr \
1293         thr_kill2 \
1294         timegm \
1295         usleep \
1296         vsnprintf \
1297         wait4 \
1298         waitpid \
1299 )
1300
1301 dnl Check for -ldl
1302 if test "$ac_cv_func_dlopen" = no
1303 then
1304     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1305 fi
1306 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1307
1308 dnl Check for -lpoll for Mac OS X/Darwin
1309 if test "$ac_cv_func_poll" = no
1310 then
1311     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1312 fi
1313
1314 dnl Check for -lnsl for Solaris
1315 AC_SEARCH_LIBS(gethostbyname, nsl)
1316
1317 dnl Check for -lsocket for Solaris
1318 AC_SEARCH_LIBS(connect, socket)
1319
1320 dnl Check for -lresolv for Solaris
1321 AC_SEARCH_LIBS(inet_aton, resolv)
1322
1323 dnl **** Check for functions which may rely on -lsocket on Solaris.
1324 AC_CHECK_FUNCS(\
1325         getaddrinfo \
1326         getnameinfo \
1327         getnetbyname \
1328         getprotobyname \
1329         getprotobynumber \
1330         getservbyport \
1331         inet_network \
1332         sendmsg \
1333 )
1334
1335 dnl **** Check for types ****
1336
1337 AC_C_CONST
1338 AC_C_INLINE
1339 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1340 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1341 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1342
1343 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1344 [#ifdef HAVE_LINUX_INPUT_H
1345 #include <linux/input.h>
1346 #endif])
1347
1348 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1349                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1350 if test "$wine_cv_have_sigaddset" = "yes"
1351 then
1352   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1353 fi
1354
1355
1356 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1357         wine_cv_linux_gethostbyname_r_6,
1358         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1359     char *name=NULL;
1360     struct hostent he;
1361     struct hostent *result;
1362     char *buf=NULL;
1363     int bufsize=0;
1364     int res,errnr;
1365     char *addr=NULL;
1366     int addrlen=0;
1367     int addrtype=0;
1368     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1369     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1370     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1371         ])
1372    )
1373    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1374    then
1375       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1376                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1377    fi
1378
1379 if test "$ac_cv_header_linux_joystick_h" = "yes"
1380 then
1381    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1382         wine_cv_linux_joystick_22_api,
1383         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1384         #include <sys/ioctl.h>
1385         #include <sys/types.h>
1386         #include <linux/joystick.h>
1387
1388         struct js_event blub;
1389         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1390         #error "no 2.2 header"
1391         #endif
1392         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1393    )
1394    if test "$wine_cv_linux_joystick_22_api" = "yes"
1395    then
1396       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1397                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1398    fi
1399 fi
1400
1401 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1402
1403 dnl Check for statfs members
1404 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1405 [#include <sys/types.h>
1406 #ifdef HAVE_SYS_PARAM_H
1407 # include <sys/param.h>
1408 #endif
1409 #ifdef HAVE_SYS_MOUNT_H
1410 # include <sys/mount.h>
1411 #endif
1412 #ifdef HAVE_SYS_VFS_H
1413 # include <sys/vfs.h>
1414 #endif
1415 #ifdef HAVE_SYS_STATFS_H
1416 # include <sys/statfs.h>
1417 #endif])
1418
1419 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1420 [#ifdef HAVE_SYS_STATVFS_H
1421 #include <sys/statvfs.h>
1422 #endif])
1423
1424 dnl Check for socket structure members
1425 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1426 [#include <sys/types.h>
1427 #ifdef HAVE_SYS_SOCKET_H
1428 # include <sys/socket.h>
1429 #endif
1430 #ifdef HAVE_SYS_UN_H
1431 # include <sys/un.h>
1432 #endif])
1433
1434 dnl Check for scsireq_t and sg_io_hdr_t members
1435 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1436 [#include <sys/types.h>
1437 #ifdef HAVE_SCSI_SG_H
1438 #include <scsi/sg.h>
1439 #endif])
1440
1441 dnl Check for siginfo_t members
1442 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1443
1444 dnl Check for struct mtget members
1445 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1446 [#include <sys/types.h>
1447 #ifdef HAVE_SYS_MTIO_H
1448 #include <sys/mtio.h>
1449 #endif])
1450
1451 dnl Check for struct option
1452 AC_CHECK_MEMBERS([struct option.name],,,
1453 [#ifdef HAVE_GETOPT_H
1454 #include <getopt.h>
1455 #endif])
1456
1457 dnl Check for stat.st_blocks
1458 AC_CHECK_MEMBERS([struct stat.st_blocks])
1459
1460 dnl Check for sin6_scope_id
1461 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1462 [#ifdef HAVE_SYS_TYPES_H
1463 #include <sys/types.h>
1464 #endif
1465 #ifdef HAVE_NETINET_IN_H
1466 #include <netinet/in.h>
1467 #endif])
1468
1469 dnl Check for ns_msg ptr member
1470 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1471 [#ifdef HAVE_SYS_TYPES_H
1472 #include <sys/types.h>
1473 #endif
1474 #ifdef HAVE_NETINET_IN_H
1475 # include <netinet/in.h>
1476 #endif
1477 #ifdef HAVE_ARPA_NAMESER_H
1478 # include <arpa/nameser.h>
1479 #endif])
1480
1481 dnl Check for the external timezone variables timezone and daylight
1482 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1483                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1484 if test "$ac_cv_have_timezone" = "yes"
1485 then
1486     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1487 fi
1488 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1489                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1490 if test "$ac_cv_have_daylight" = "yes"
1491 then
1492     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1493 fi
1494
1495 dnl *** check for the need to define platform-specific symbols
1496
1497 case $host_cpu in
1498   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1499   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1500   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1501   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1502   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1503 esac
1504
1505 case $host_vendor in
1506   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1507 esac
1508
1509 dnl **** Generate output files ****
1510
1511 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1512 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1513 ["### Dependencies:\\
1514 \\
1515 .INIT: Makefile\\
1516 .BEGIN: Makefile\\
1517 Makefile: dummy\\
1518         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1519 \\
1520 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1521 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1522 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1523 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1524 ["### Dependencies:
1525
1526 .INIT: Makefile
1527 .BEGIN: Makefile
1528 Makefile: dummy
1529         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1530
1531 \$(OBJS): \$(IDL_GEN_HEADERS)
1532 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1533 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1534 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1535
1536 AH_TOP([#define __WINE_CONFIG_H])
1537
1538 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1539
1540 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1541 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1542 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1543 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1544 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1545 WINE_CONFIG_EXTRA_DIR(include/wine)
1546
1547 MAKE_RULES=Make.rules
1548 AC_SUBST_FILE(MAKE_RULES)
1549
1550 MAKE_DLL_RULES=dlls/Makedll.rules
1551 AC_SUBST_FILE(MAKE_DLL_RULES)
1552
1553 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1554 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1555
1556 MAKE_TEST_RULES=dlls/Maketest.rules
1557 AC_SUBST_FILE(MAKE_TEST_RULES)
1558
1559 MAKE_PROG_RULES=programs/Makeprog.rules
1560 AC_SUBST_FILE(MAKE_PROG_RULES)
1561
1562 AC_CONFIG_FILES([Make.rules])
1563 AC_CONFIG_FILES([dlls/Makedll.rules])
1564 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1565 AC_CONFIG_FILES([dlls/Maketest.rules])
1566 AC_CONFIG_FILES([programs/Makeprog.rules])
1567 AC_CONFIG_FILES([Makefile])
1568 AC_CONFIG_FILES([dlls/Makefile])
1569 AC_CONFIG_FILES([dlls/acledit/Makefile])
1570 AC_CONFIG_FILES([dlls/activeds/Makefile])
1571 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1572 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1573 AC_CONFIG_FILES([dlls/advpack/Makefile])
1574 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1575 AC_CONFIG_FILES([dlls/amstream/Makefile])
1576 AC_CONFIG_FILES([dlls/atl/Makefile])
1577 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1578 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1579 AC_CONFIG_FILES([dlls/browseui/Makefile])
1580 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1581 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1582 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1583 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1584 AC_CONFIG_FILES([dlls/cards/Makefile])
1585 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1586 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1587 AC_CONFIG_FILES([dlls/comcat/Makefile])
1588 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1589 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1590 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1591 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1592 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1593 AC_CONFIG_FILES([dlls/compstui/Makefile])
1594 AC_CONFIG_FILES([dlls/credui/Makefile])
1595 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1596 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1597 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1598 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1599 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1600 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1601 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1602 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1603 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1604 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1605 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1606 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1607 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1608 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1609 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1610 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1611 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1612 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1613 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1614 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1615 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1616 AC_CONFIG_FILES([dlls/devenum/Makefile])
1617 AC_CONFIG_FILES([dlls/dinput/Makefile])
1618 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1619 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1620 AC_CONFIG_FILES([dlls/dmband/Makefile])
1621 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1622 AC_CONFIG_FILES([dlls/dmime/Makefile])
1623 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1624 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1625 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1626 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1627 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1628 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1629 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1630 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1631 AC_CONFIG_FILES([dlls/dplay/Makefile])
1632 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1633 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1634 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1635 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1636 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1637 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1638 AC_CONFIG_FILES([dlls/dsound/Makefile])
1639 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1640 AC_CONFIG_FILES([dlls/dswave/Makefile])
1641 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1642 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1643 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1644 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1645 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1646 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1647 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1648 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1649 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1650 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1651 AC_CONFIG_FILES([dlls/glu32/Makefile])
1652 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1653 AC_CONFIG_FILES([dlls/hal/Makefile])
1654 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1655 AC_CONFIG_FILES([dlls/hid/Makefile])
1656 AC_CONFIG_FILES([dlls/hlink/Makefile])
1657 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1658 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1659 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1660 AC_CONFIG_FILES([dlls/icmp/Makefile])
1661 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1662 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1663 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1664 AC_CONFIG_FILES([dlls/imm32/Makefile])
1665 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1666 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1667 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1668 AC_CONFIG_FILES([dlls/inseng/Makefile])
1669 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1670 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1671 AC_CONFIG_FILES([dlls/itss/Makefile])
1672 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1673 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1674 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1675 AC_CONFIG_FILES([dlls/localspl/Makefile])
1676 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1677 AC_CONFIG_FILES([dlls/localui/Makefile])
1678 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1679 AC_CONFIG_FILES([dlls/lz32/Makefile])
1680 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1681 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1682 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1683 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1684 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1685 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1686 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1687 AC_CONFIG_FILES([dlls/midimap/Makefile])
1688 AC_CONFIG_FILES([dlls/mlang/Makefile])
1689 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1690 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1691 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1692 AC_CONFIG_FILES([dlls/mpr/Makefile])
1693 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1694 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1695 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1696 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1697 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1698 AC_CONFIG_FILES([dlls/mscms/Makefile])
1699 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1700 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1701 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1702 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1703 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1704 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1705 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1706 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1707 AC_CONFIG_FILES([dlls/msi/Makefile])
1708 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1709 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1710 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1711 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1712 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1713 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1714 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1715 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1716 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1717 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1718 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1719 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1720 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1721 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1722 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1723 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1724 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1725 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1726 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1727 AC_CONFIG_FILES([dlls/newdev/Makefile])
1728 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1729 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1730 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1731 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1732 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1733 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1734 AC_CONFIG_FILES([dlls/objsel/Makefile])
1735 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1736 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1737 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1738 AC_CONFIG_FILES([dlls/ole32/Makefile])
1739 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1740 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1741 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1742 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1743 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1744 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1745 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1746 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1747 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1748 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1749 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1750 AC_CONFIG_FILES([dlls/pdh/Makefile])
1751 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1752 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1753 AC_CONFIG_FILES([dlls/printui/Makefile])
1754 AC_CONFIG_FILES([dlls/psapi/Makefile])
1755 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1756 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1757 AC_CONFIG_FILES([dlls/qcap/Makefile])
1758 AC_CONFIG_FILES([dlls/quartz/Makefile])
1759 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1760 AC_CONFIG_FILES([dlls/query/Makefile])
1761 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1762 AC_CONFIG_FILES([dlls/resutils/Makefile])
1763 AC_CONFIG_FILES([dlls/riched20/Makefile])
1764 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1765 AC_CONFIG_FILES([dlls/riched32/Makefile])
1766 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1767 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1768 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1769 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1770 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1771 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1772 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1773 AC_CONFIG_FILES([dlls/schannel/Makefile])
1774 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1775 AC_CONFIG_FILES([dlls/secur32/Makefile])
1776 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1777 AC_CONFIG_FILES([dlls/security/Makefile])
1778 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1779 AC_CONFIG_FILES([dlls/serialui/Makefile])
1780 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1781 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1782 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1783 AC_CONFIG_FILES([dlls/sfc/Makefile])
1784 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1785 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1786 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1787 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1788 AC_CONFIG_FILES([dlls/shell32/Makefile])
1789 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1790 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1791 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1792 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1793 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1794 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1795 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1796 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1797 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1798 AC_CONFIG_FILES([dlls/sti/Makefile])
1799 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1800 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1801 AC_CONFIG_FILES([dlls/sxs/Makefile])
1802 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1803 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1804 AC_CONFIG_FILES([dlls/unicows/Makefile])
1805 AC_CONFIG_FILES([dlls/url/Makefile])
1806 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1807 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1808 AC_CONFIG_FILES([dlls/user32/Makefile])
1809 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1810 AC_CONFIG_FILES([dlls/userenv/Makefile])
1811 AC_CONFIG_FILES([dlls/usp10/Makefile])
1812 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1813 AC_CONFIG_FILES([dlls/uuid/Makefile])
1814 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1815 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1816 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1817 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1818 AC_CONFIG_FILES([dlls/version/Makefile])
1819 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1820 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1821 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1822 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1823 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1824 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1825 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1826 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1827 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1828 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1829 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1830 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1831 AC_CONFIG_FILES([dlls/winedos/Makefile])
1832 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1833 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1834 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1835 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1836 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1837 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1838 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1839 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1840 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1841 AC_CONFIG_FILES([dlls/wing32/Makefile])
1842 AC_CONFIG_FILES([dlls/winhttp/Makefile])
1843 AC_CONFIG_FILES([dlls/wininet/Makefile])
1844 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1845 AC_CONFIG_FILES([dlls/winmm/Makefile])
1846 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1847 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1848 AC_CONFIG_FILES([dlls/winscard/Makefile])
1849 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1850 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1851 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1852 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1853 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1854 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1855 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1856 AC_CONFIG_FILES([dlls/wow32/Makefile])
1857 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1858 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1859 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1860 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1861 AC_CONFIG_FILES([documentation/Makefile])
1862 AC_CONFIG_FILES([fonts/Makefile])
1863 AC_CONFIG_FILES([include/Makefile])
1864 AC_CONFIG_FILES([libs/Makefile])
1865 AC_CONFIG_FILES([libs/port/Makefile])
1866 AC_CONFIG_FILES([libs/wine/Makefile])
1867 AC_CONFIG_FILES([libs/wpp/Makefile])
1868 AC_CONFIG_FILES([loader/Makefile])
1869 AC_CONFIG_FILES([programs/Makefile])
1870 AC_CONFIG_FILES([programs/clock/Makefile])
1871 AC_CONFIG_FILES([programs/cmd/Makefile])
1872 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1873 AC_CONFIG_FILES([programs/control/Makefile])
1874 AC_CONFIG_FILES([programs/eject/Makefile])
1875 AC_CONFIG_FILES([programs/expand/Makefile])
1876 AC_CONFIG_FILES([programs/explorer/Makefile])
1877 AC_CONFIG_FILES([programs/hh/Makefile])
1878 AC_CONFIG_FILES([programs/icinfo/Makefile])
1879 AC_CONFIG_FILES([programs/iexplore/Makefile])
1880 AC_CONFIG_FILES([programs/msiexec/Makefile])
1881 AC_CONFIG_FILES([programs/net/Makefile])
1882 AC_CONFIG_FILES([programs/notepad/Makefile])
1883 AC_CONFIG_FILES([programs/oleview/Makefile])
1884 AC_CONFIG_FILES([programs/progman/Makefile])
1885 AC_CONFIG_FILES([programs/regedit/Makefile])
1886 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1887 AC_CONFIG_FILES([programs/rpcss/Makefile])
1888 AC_CONFIG_FILES([programs/rundll32/Makefile])
1889 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1890 AC_CONFIG_FILES([programs/start/Makefile])
1891 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1892 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1893 AC_CONFIG_FILES([programs/view/Makefile])
1894 AC_CONFIG_FILES([programs/wineboot/Makefile])
1895 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1896 AC_CONFIG_FILES([programs/winecfg/Makefile])
1897 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1898 AC_CONFIG_FILES([programs/winedbg/Makefile])
1899 AC_CONFIG_FILES([programs/winedevice/Makefile])
1900 AC_CONFIG_FILES([programs/winefile/Makefile])
1901 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1902 AC_CONFIG_FILES([programs/winemine/Makefile])
1903 AC_CONFIG_FILES([programs/winepath/Makefile])
1904 AC_CONFIG_FILES([programs/winetest/Makefile])
1905 AC_CONFIG_FILES([programs/winevdm/Makefile])
1906 AC_CONFIG_FILES([programs/winhelp/Makefile])
1907 AC_CONFIG_FILES([programs/winver/Makefile])
1908 AC_CONFIG_FILES([programs/wordpad/Makefile])
1909 AC_CONFIG_FILES([programs/write/Makefile])
1910 AC_CONFIG_FILES([programs/xcopy/Makefile])
1911 AC_CONFIG_FILES([server/Makefile])
1912 AC_CONFIG_FILES([tools/Makefile])
1913 AC_CONFIG_FILES([tools/widl/Makefile])
1914 AC_CONFIG_FILES([tools/winebuild/Makefile])
1915 AC_CONFIG_FILES([tools/winedump/Makefile])
1916 AC_CONFIG_FILES([tools/winegcc/Makefile])
1917 AC_CONFIG_FILES([tools/wmc/Makefile])
1918 AC_CONFIG_FILES([tools/wrc/Makefile])
1919
1920 AC_OUTPUT
1921
1922 if test "$no_create" = "yes"
1923 then
1924   exit 0
1925 fi
1926
1927 WINE_PRINT_MESSAGES
1928
1929 echo
1930 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1931 echo
1932
1933 dnl Local Variables:
1934 dnl comment-start: "dnl "
1935 dnl comment-end: ""
1936 dnl comment-start-skip: "\\bdnl\\b\\s *"
1937 dnl compile-command: "autoreconf --warnings=all"
1938 dnl End: