configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]),
  18                                ,[AC_SUBST([MAINTAINER_MODE],[\#])])
  19
  20 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  21             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  22 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  23             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  24 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  25             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  26 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  27             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  28 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  29             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  30 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]),
  31             [if test "x$withval" = "xno"; then ac_cv_header_cups_cups_h=no; fi])
  32 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  33             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  34 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  35 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  36             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  37 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  38 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  39 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  40             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  41 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  42             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  43 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  45 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  46             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  47 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  48 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  49             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  50 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  51             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  52 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  54 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  55 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  56             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  57 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  58             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  59 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  61 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  63 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  64 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  65             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  66 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  67             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  68 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  69             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  70 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  71             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  72 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  73 AC_ARG_WITH(xvidmode,  AS_HELP_STRING([--without-xvidmode],[do not use XFree video mode extension]),
  74             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; fi])
  75
  76 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  77 AC_ARG_ENABLE(tests, AC_HELP_STRING([--disable-tests],[do not build the testsuites]))
  78
  79 AC_CANONICAL_HOST
  80 case $host in
  81   x86_64*linux*)
  82     if test "x$enable_win64" != "xyes"
  83     then
  84       test -n "$CC" || CC="gcc -m32"
  85       test -n "$CXX"|| CXX="g++ -m32"
  86       test -n "$LD" || LD="ld -m elf_i386"
  87       test -n "$AS" || AS="as --32"
  88       host_cpu="i386"
  89     fi
  90     ;;
  91 esac
  92
  93 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  94 case $host_cpu in
  95   *i[[3456789]]86*)
  96     if test "x$enable_win16" != "xno"
  97     then
  98       enable_win16="yes"
  99     fi
 100     ;;
 101 esac
 102
 103 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
 104 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
 105 if test "x$enable_win16" != "xyes"
 106 then
 107   WIN16_FILES=""
 108   WIN16_INSTALL=""
 109 fi
 110
 111 dnl enable_tests is yes by default, but in some cases it's better to disable the testsuite
 112 if test "x$enable_tests" == "xno"
 113 then
 114   AC_SUBST(TESTSUBDIRS,"")
 115   AC_SUBST(WINETEST,"")
 116 else
 117   AC_SUBST(TESTSUBDIRS,"\$(TESTSUBDIRS)")
 118   AC_SUBST(WINETEST,"winetest")
 119 fi
 120
 121 dnl check for out of tree build with unclean source tree
 122 case "$srcdir" in
 123  .) ;;
 124  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 125       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 126 You need to run 'make distclean' in the source tree first.])
 127     fi ;;
 128 esac
 129
 130 dnl **** Check for some programs ****
 131
 132 AC_PROG_MAKE_SET
 133 AC_PROG_CC
 134 AC_PROG_CXX
 135 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 136 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 137
 138 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 139   [if test -z "$with_wine_tools"; then
 140      if test "$cross_compiling" = "yes"; then
 141        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 142      else
 143        wine_cv_toolsdir="\$(TOPOBJDIR)"
 144      fi
 145    elif test -d "$with_wine_tools/tools/winebuild"; then
 146      case $with_wine_tools in
 147        /*) wine_cv_toolsdir="$with_wine_tools" ;;
 148        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
 149      esac
 150    else
 151      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
 152    fi])
 153 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 154
 155 AC_PATH_XTRA
 156
 157 dnl Check for flex
 158 AC_CHECK_PROGS(FLEX,flex,none)
 159 if test "$FLEX" = "none"
 160 then
 161   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 162 fi
 163
 164 dnl Check for bison
 165 AC_CHECK_PROGS(BISON,bison,none)
 166 if test "$BISON" = "none"
 167 then
 168   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 169 fi
 170
 171 AC_CHECK_TOOLS(AS,[gas as],as)
 172 AC_CHECK_TOOL(LD,ld,ld)
 173 AC_CHECK_TOOL(AR,ar,ar)
 174 AC_SUBST(ARFLAGS,rc)
 175 AC_PROG_RANLIB
 176 AC_CHECK_TOOL(STRIP,strip,strip)
 177 AC_CHECK_TOOL(WINDRES,windres,false)
 178 AC_PROG_LN_S
 179 WINE_PROG_LN
 180 AC_PROG_EGREP
 181 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 182 AC_PROG_INSTALL
 183 dnl Prepend src dir to install path dir if it's a relative path
 184 case "$INSTALL" in
 185   [[\\/$]]* | ?:[[\\/]]* ) ;;
 186   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 187 esac
 188
 189 dnl Check for lint
 190 AC_CHECK_PROGS(LINT, lclint lint)
 191 if test "$LINT" = "lint"
 192 then
 193   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 194   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 195 fi
 196 AC_SUBST(LINT)
 197 AC_SUBST(LINTFLAGS)
 198
 199 dnl Check for various programs
 200 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 201 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 202 AC_CHECK_PROGS(RSVG, rsvg, false)
 203 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 204
 205 if test "${enable_maintainer_mode+set}" = set
 206 then
 207   if test "$FONTFORGE" = "false"; then WINE_WARNING([fontforge is missing, fonts can't be rebuilt.]); fi
 208   if test "$RSVG" = "false"; then WINE_WARNING([rsvg is missing, icons can't be rebuilt.]); fi
 209   if test "$ICOTOOL" = "false"; then WINE_WARNING([icotool is missing, icons can't be rebuilt.]); fi
 210 fi
 211
 212 case $host_cpu in
 213   *i[[3456789]]86*)
 214     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 215     ;;
 216 esac
 217
 218 dnl **** Check for some libraries ****
 219
 220 dnl Check for -li386 for NetBSD and OpenBSD
 221 AC_CHECK_LIB(i386,i386_set_ldt)
 222 dnl Check for -lossaudio for NetBSD
 223 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 224 dnl Check for -lpthread
 225 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 226
 227 AC_SUBST(XLIB,"")
 228 AC_SUBST(XFILES,"")
 229 AC_SUBST(OPENGLFILES,"")
 230 AC_SUBST(GLU32FILES,"")
 231 AC_SUBST(OPENGL_LIBS,"")
 232 AC_SUBST(QUARTZFILES,"")
 233
 234 dnl **** Check for header files ****
 235
 236 AC_CHECK_HEADERS(\
 237         AudioUnit/AudioUnit.h \
 238         Carbon/Carbon.h \
 239         CoreAudio/CoreAudio.h \
 240         DiskArbitration/DiskArbitration.h \
 241         IOKit/IOKitLib.h \
 242         alsa/asoundlib.h \
 243         arpa/inet.h \
 244         arpa/nameser.h \
 245         asm/types.h \
 246         capi20.h \
 247         cups/cups.h \
 248         curses.h \
 249         direct.h \
 250         dlfcn.h \
 251         elf.h \
 252         float.h \
 253         fontconfig/fontconfig.h \
 254         getopt.h \
 255         ieeefp.h \
 256         io.h \
 257         jack/jack.h \
 258         jpeglib.h \
 259         lber.h \
 260         lcms.h \
 261         lcms/lcms.h \
 262         ldap.h \
 263         libaudioio.h \
 264         link.h \
 265         linux/cdrom.h \
 266         linux/compiler.h \
 267         linux/hdreg.h \
 268         linux/input.h \
 269         linux/ioctl.h \
 270         linux/joystick.h \
 271         linux/major.h \
 272         linux/param.h \
 273         linux/serial.h \
 274         linux/ucdrom.h \
 275         mach/mach.h \
 276         mach/machine.h \
 277         machine/cpu.h \
 278         machine/limits.h \
 279         machine/soundcard.h \
 280         mntent.h \
 281         ncurses.h \
 282         netdb.h \
 283         netinet/in.h \
 284         netinet/in_systm.h \
 285         netinet/tcp.h \
 286         netinet/tcp_fsm.h \
 287         openssl/err.h \
 288         openssl/ssl.h \
 289         png.h \
 290         poll.h \
 291         process.h \
 292         pthread.h \
 293         pwd.h \
 294         regex.h \
 295         sched.h \
 296         scsi/scsi.h \
 297         scsi/scsi_ioctl.h \
 298         scsi/sg.h \
 299         soundcard.h \
 300         stdint.h \
 301         strings.h \
 302         sys/asoundlib.h \
 303         sys/cdio.h \
 304         sys/elf32.h \
 305         sys/epoll.h \
 306         sys/errno.h \
 307         sys/event.h \
 308         sys/exec_elf.h \
 309         sys/filio.h \
 310         sys/ioctl.h \
 311         sys/ipc.h \
 312         sys/limits.h \
 313         sys/link.h \
 314         sys/lwp.h \
 315         sys/mman.h \
 316         sys/modem.h \
 317         sys/msg.h \
 318         sys/mtio.h \
 319         sys/param.h \
 320         sys/poll.h \
 321         sys/prctl.h \
 322         sys/ptrace.h \
 323         sys/reg.h \
 324         sys/resource.h \
 325         sys/scsiio.h \
 326         sys/shm.h \
 327         sys/signal.h \
 328         sys/socket.h \
 329         sys/socketvar.h \
 330         sys/sockio.h \
 331         sys/soundcard.h \
 332         sys/statvfs.h \
 333         sys/strtio.h \
 334         sys/syscall.h \
 335         sys/sysctl.h \
 336         sys/time.h \
 337         sys/times.h \
 338         sys/uio.h \
 339         sys/un.h \
 340         sys/vm86.h \
 341         sys/wait.h \
 342         syscall.h \
 343         termios.h \
 344         unistd.h \
 345         utime.h \
 346         valgrind/memcheck.h
 347 )
 348 AC_HEADER_STAT()
 349
 350 dnl **** Checks for headers that depend on other ones ****
 351
 352 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 353     [#include <sys/types.h>
 354      #ifdef HAVE_SYS_PARAM_H
 355      # include <sys/param.h>
 356      #endif])
 357
 358 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 359     [#include <sys/types.h>
 360      #ifdef HAVE_SYS_SOCKET_H
 361      # include <sys/socket.h>
 362      #endif
 363      #ifdef HAVE_SYS_SOCKETVAR_H
 364      # include <sys/socketvar.h>
 365      #endif
 366      #ifdef HAVE_NETINET_IN_H
 367      # include <netinet/in.h>
 368      #endif])
 369
 370 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 371     [#include <sys/types.h>
 372      #ifdef HAVE_SYS_SOCKET_H
 373      # include <sys/socket.h>
 374      #endif
 375      #ifdef HAVE_SYS_SOCKETVAR_H
 376      # include <sys/socketvar.h>
 377      #endif
 378      #ifdef HAVE_NETINET_IN_H
 379      # include <netinet/in.h>
 380      #endif
 381      #ifdef HAVE_NETINET_TCP_H
 382      # include <netinet/tcp.h>
 383      #endif])
 384
 385 AC_CHECK_HEADERS([linux/ipx.h],,,
 386     [#include <sys/types.h>
 387      #ifdef HAVE_ASM_TYPES_H
 388      # include <asm/types.h>
 389      #endif
 390      #ifdef HAVE_SYS_SOCKET_H
 391      # include <sys/socket.h>
 392      #endif])
 393
 394 AC_CHECK_HEADERS([resolv.h],,,
 395     [#include <sys/types.h>
 396      #ifdef HAVE_SYS_SOCKET_H
 397      # include <sys/socket.h>
 398      #endif
 399      #ifdef HAVE_NETINET_IN_H
 400      # include <netinet/in.h>
 401      #endif
 402      #ifdef HAVE_ARPA_NAMESER_H
 403      # include <arpa/nameser.h>
 404      #endif])
 405
 406 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 407
 408 AC_CHECK_HEADERS([sys/thr.h],,,
 409 [#include <sys/types.h>
 410 #ifdef HAVE_UCONTEXT_H
 411 #include <ucontext.h>
 412 #endif])
 413
 414 AC_CHECK_HEADERS([pthread_np.h],,,
 415 [#ifdef HAVE_PTHREAD_H
 416 #include <pthread.h>
 417 #endif])
 418
 419 AC_CHECK_HEADERS([linux/videodev.h],,,
 420 [#ifdef HAVE_SYS_TIME_H
 421 #include <sys/time.h>
 422 #endif
 423 #include <sys/types.h>
 424 #ifdef HAVE_ASM_TYPES_H
 425 #include <asm/types.h>
 426 #endif])
 427
 428 dnl Check for broken kernel header that doesn't define __user
 429 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 430
 431 dnl **** Check for working dll ****
 432
 433 AC_SUBST(DLLEXT,"")
 434 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 435 AC_SUBST(LDSHARED,"")
 436 AC_SUBST(LDDLLFLAGS,"")
 437 AC_SUBST(LIBEXT,"so")
 438 AC_SUBST(IMPLIBEXT,"def")
 439 AC_SUBST(LDRPATH_INSTALL,"")
 440 AC_SUBST(LDRPATH_LOCAL,"")
 441 WINE_PATH_LDD
 442
 443 case $host_os in
 444   cygwin*|mingw32*)
 445     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 446     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 447     AC_CHECK_TOOL(MINGWAR,ar,false)
 448     if test "$DLLWRAP" = "false"; then
 449       LIBEXT="a"
 450     else
 451       dnl FIXME - check whether dllwrap works correctly...
 452       LIBEXT="dll"
 453     fi
 454     IMPLIBEXT="a"
 455     dnl We can't build 16-bit NE dlls
 456     WIN16_FILES=""
 457     WIN16_INSTALL=""
 458     ;;
 459   darwin*|macosx*)
 460     DLLEXT=".so"
 461     LIBEXT="dylib"
 462     DLLFLAGS="$DLLFLAGS -fPIC"
 463     LDDLLFLAGS="-bundle -multiply_defined suppress"
 464     LIBWINE_LDFLAGS="-multiply_defined suppress"
 465     LDSHARED="\$(CC) -dynamiclib"
 466     STRIP="$STRIP -x"
 467     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 468     dnl declare needed frameworks
 469     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 470     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 471     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 472     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 473     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 474     then
 475         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 476         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 477     fi
 478     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 479     then
 480         dnl CoreServices needed by AudioUnit
 481         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 482     fi
 483     case $host_cpu in
 484       *powerpc*)
 485         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 486         ;;
 487     esac
 488     dnl Enable quartz driver on Mac OS X
 489     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 490     then
 491         AC_SUBST(CARBONLIB,"-framework Carbon")
 492         QUARTZFILES='$(QUARTZFILES)'
 493     fi
 494     ;;
 495   *)
 496     DLLFLAGS="$DLLFLAGS -fPIC"
 497     DLLEXT=".so"
 498     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 499         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 500                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 501     if test "$ac_cv_c_dll_gnuelf" = "yes"
 502     then
 503       LDSHARED="\$(CC) -shared"
 504       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 505       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 506                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 507                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 508                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 509
 510       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 511
 512       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 513                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 514
 515       echo '{ global: *; };' >conftest.map
 516       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 517                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 518       rm -f conftest.map
 519
 520       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 521                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 522
 523       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 524                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 525                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 526           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 527                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 528                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 529
 530       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 531                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 532
 533       case $host_cpu in
 534         *i[[3456789]]86* | x86_64)
 535           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 536                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 537           ;;
 538       esac
 539
 540     else
 541       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 542           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 543                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 544       if test "$ac_cv_c_dll_unixware" = "yes"
 545       then
 546         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 547         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 548
 549       else
 550         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 551           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 552         if test "$ac_cv_c_dll_hpux" = "yes"
 553         then
 554           LIBEXT="sl"
 555           DLLEXT=".sl"
 556           LDDLLFLAGS="-shared -fPIC"
 557           LDSHARED="\$(CC) -shared"
 558         fi
 559       fi
 560     fi
 561
 562     dnl Check for cross compiler to build test programs
 563     AC_SUBST(CROSSTEST,"")
 564     if test "$cross_compiling" = "no"
 565     then
 566       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 567       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 568       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 569       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 570       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 571     fi
 572     ;;
 573 esac
 574
 575 if test "$LIBEXT" = "a"; then
 576   AC_MSG_ERROR(
 577 [could not find a way to build shared libraries.
 578 It is currently not possible to build Wine without shared library
 579 (.so) support to allow transparent switch between .so and .dll files.
 580 If you are using Linux, you will need a newer binutils.]
 581 )
 582 fi
 583
 584 dnl **** Check for X11 ****
 585
 586 if test "$have_x" = "yes"
 587 then
 588     XLIB="-lXext -lX11"
 589     ac_save_CPPFLAGS="$CPPFLAGS"
 590     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 591
 592     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 593     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 594
 595     dnl *** All of the following tests require X11/Xlib.h
 596     AC_CHECK_HEADERS([X11/Xlib.h \
 597                       X11/XKBlib.h \
 598                       X11/Xutil.h \
 599                       X11/Xcursor/Xcursor.h \
 600                       X11/extensions/shape.h \
 601                       X11/extensions/XInput.h \
 602                       X11/extensions/XShm.h \
 603                       X11/extensions/Xcomposite.h \
 604                       X11/extensions/Xinerama.h \
 605                       X11/extensions/Xrandr.h \
 606                       X11/extensions/Xrender.h \
 607                       X11/extensions/xf86vmode.h],,,
 608 [#ifdef HAVE_X11_XLIB_H
 609 # include <X11/Xlib.h>
 610 #endif
 611 #ifdef HAVE_X11_XUTIL_H
 612 # include <X11/Xutil.h>
 613 #endif])
 614
 615         dnl *** Check for X keyboard extension
 616         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 617         then
 618               AC_CHECK_LIB(X11, XkbQueryExtension,
 619               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 620               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 621         fi
 622
 623         dnl *** Check for X cursor
 624         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 625         then
 626             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 627         fi
 628         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 629                          [libxcursor development files not found, the Xcursor extension won't be supported.])
 630
 631         dnl *** Check for X input extension
 632         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 633         then
 634             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 635         fi
 636         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 637                          [libxi development files not found, the Xinput extension won't be supported.])
 638
 639         dnl *** Check for X Shm extension
 640         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 641         then
 642               AC_CHECK_LIB(Xext, XShmQueryExtension,
 643               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 644               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 645         fi
 646         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 647                          [XShm development files not found, X Shared Memory won't be supported.])
 648
 649         dnl *** Check for X shape extension
 650         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 651         then
 652               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 653               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 654               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 655         fi
 656         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 657                          [XShape development files not found, XShape won't be supported.])
 658
 659         dnl *** Check for XFree86 VMODE extension
 660         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 661         then
 662                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 663                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 664                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 665                   ],,
 666                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 667         fi
 668         WINE_NOTICE_WITH(xvidmode,[test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],
 669                          [libXxf86vm development files not found, XFree86 Vidmode won't be supported.])
 670
 671         dnl *** Check for Transform functions in Xrender
 672         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 673         then
 674             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 675               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 676                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 677                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 678                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 679
 680         fi
 681         WINE_NOTICE_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 682                          [libxrender development files not found, XRender won't be supported.])
 683
 684         dnl *** Check for X RandR extension
 685         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 686         then
 687                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 688 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 689                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 690         fi
 691         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 692                          [libxrandr development files not found, XRandr won't be supported.])
 693
 694         dnl *** Check for Xinerama extension
 695         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 696         then
 697                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 698 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 699                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 700         fi
 701         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 702                          [libxinerama development files not found, multi-monitor setups won't be supported.])
 703
 704         dnl *** Check for X Composite extension
 705         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 706         then
 707             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 708         fi
 709         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
 710                          [libxcomposite development files not found, Xcomposite won't be supported.])
 711
 712         dnl *** Check for XICCallback struct
 713         AC_CHECK_MEMBERS([XICCallback.callback],,,
 714 [#ifdef HAVE_X11_XLIB_H
 715 #include <X11/Xlib.h>
 716 #endif])
 717
 718     dnl *** End of X11/Xlib.h check
 719
 720     dnl Check for the presence of OpenGL
 721     opengl_msg=""
 722     if test "x$with_opengl" != "xno"
 723     then
 724         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 725 [#ifdef HAVE_GL_GLX_H
 726 # include <GL/glx.h>
 727 #endif])
 728         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 729         then
 730             dnl Check for some problems due to old Mesa versions
 731             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 732               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 733                 [wine_cv_opengl_header_version_OK="yes"],
 734                 [wine_cv_opengl_header_version_OK="no"]))
 735
 736             if test "$wine_cv_opengl_header_version_OK" = "yes"
 737             then
 738                 dnl Check for the presence of the library
 739                 WINE_CHECK_SONAME(GL,glXCreateContext,
 740                              [OPENGL_LIBS="-lGL"
 741                              OPENGLFILES='$(OPENGLFILES)'
 742                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 743                              [WINE_CHECK_SONAME(GL,glXCreateContext,
 744                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
 745                                     OPENGLFILES='$(OPENGLFILES)'
 746                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 747                                     [if test -f /usr/X11R6/lib/libGL.a
 748                                     then
 749                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
 750 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
 751                                     else
 752                                         opengl_msg="No OpenGL library found on this system."
 753                                     fi],
 754                                     $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
 755                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 756
 757                 dnl Check for GLU32 library.
 758                 AC_CHECK_LIB(GLU,gluLookAt,
 759                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 760                              GLU32FILES='$(GLU32FILES)']
 761                              ,,
 762                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 763              else
 764                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
 765              fi
 766          else
 767              opengl_msg="OpenGL development headers not found."
 768          fi
 769     fi
 770     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
 771 OpenGL and Direct3D won't be supported.])
 772
 773     dnl **** Check for NAS ****
 774     AC_SUBST(NASLIBS,"")
 775     AC_CHECK_HEADERS(audio/audiolib.h,
 776          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 777           AC_CHECK_LIB(audio,AuCreateFlow,
 778                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 779                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 780                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 781                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 782                           [$X_LIBS])
 783                        ],,
 784                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 785
 786     CPPFLAGS="$ac_save_CPPFLAGS"
 787     XFILES='$(XFILES)'
 788 else
 789     XLIB=""
 790     X_CFLAGS=""
 791     X_LIBS=""
 792 fi
 793 WINE_WARNING_WITH(x,[test "x$XLIB" = "x"],[X development files not found. Wine will be built
 794 without X support, which probably isn't what you want. You will need to install
 795 development packages of Xlib/Xfree86 at the very least.])
 796
 797 dnl **** Check for libxml2 ****
 798
 799 AC_SUBST(XML2LIBS,"")
 800 AC_SUBST(XML2INCL,"")
 801 AC_SUBST(XSLTLIBS,"")
 802 AC_SUBST(XSLTINCL,"")
 803 if test "x$with_xml" != "xno"
 804 then
 805     ac_save_CPPFLAGS="$CPPFLAGS"
 806     if test "$PKG_CONFIG" != "false"
 807     then
 808         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 809         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 810     else
 811         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 812         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 813     fi
 814     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 815     AC_CHECK_HEADERS(libxml/parser.h,
 816             [AC_CHECK_LIB(xml2, xmlParseMemory,
 817                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 818                  XML2LIBS="$ac_xml_libs"
 819                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 820              AC_CHECK_LIB(xml2, xmlReadMemory,
 821                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 822              AC_CHECK_LIB(xml2, xmlNewDocPI,
 823                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 824         ])
 825     CPPFLAGS="$ac_save_CPPFLAGS"
 826 fi
 827 WINE_NOTICE_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
 828                  [libxml2 development files not found, XML won't be supported.])
 829
 830 if test "x$with_xslt" != "xno"
 831 then
 832     if test "$PKG_CONFIG" != "false"
 833     then
 834         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 835         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 836     else
 837         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 838         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 839     fi
 840     ac_save_CPPFLAGS="$CPPFLAGS"
 841     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 842     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
 843     [#ifdef HAVE_LIBXSLT_PATTERN_H
 844 # include <libxslt/pattern.h>
 845 #endif])
 846     CPPFLAGS="$ac_save_CPPFLAGS"
 847     if test "$ac_cv_header_libxslt_transform_h" = "yes"
 848     then
 849         AC_CHECK_LIB(xslt, xsltCompilePattern,
 850             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 851              XSLTLIBS="$ac_xslt_libs"
 852              XSLTINCL="$ac_xslt_cflags"
 853              ac_save_LIBS="$LIBS"
 854              LIBS="$LIBS $ac_xslt_libs"
 855              AC_CHECK_FUNCS(xsltInit)
 856              LIBS="$ac_save_LIBS"],,$ac_xslt_libs)
 857     fi
 858 fi
 859 WINE_NOTICE_WITH(xslt,[test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],
 860                  [libxslt development files not found, xslt won't be supported.])
 861
 862 dnl **** Check for libhal ****
 863 AC_SUBST(HALINCL,"")
 864 if test "x$with_hal" != "xno" -a "$PKG_CONFIG" != "false"
 865 then
 866     ac_save_CPPFLAGS="$CPPFLAGS"
 867     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 868     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 869     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 870     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 871     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 872     then
 873         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 874           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 875             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 876     fi
 877     CPPFLAGS="$ac_save_CPPFLAGS"
 878 fi
 879 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x"],
 880                  [libhal development files not found, no dynamic device support.])
 881
 882 dnl **** Check which curses lib to use ***
 883 CURSESLIBS=""
 884 if test "$ac_cv_header_ncurses_h" = "yes"
 885 then
 886     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 887 elif test "$ac_cv_header_curses_h" = "yes"
 888 then
 889     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 890 fi
 891 ac_save_LIBS="$LIBS"
 892 LIBS="$LIBS $CURSESLIBS"
 893 AC_CHECK_FUNCS(mousemask)
 894 LIBS="$ac_save_LIBS"
 895 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
 896                  [lib(n)curses development files not found, curses won't be supported.])
 897
 898 dnl **** Check for SANE ****
 899 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 900 if test "$sane_devel" != "no" -a "x$with_sane" != "xno"
 901 then
 902     ac_sane_incl="`$sane_devel --cflags`"
 903     ac_save_CPPFLAGS="$CPPFLAGS"
 904     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 905     AC_CHECK_HEADER(sane/sane.h,
 906         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 907     CPPFLAGS="$ac_save_CPPFLAGS"
 908 fi
 909 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
 910                  [libsane development files not found, scanners won't be supported.])
 911
 912 dnl **** Check for libgphoto2 ****
 913 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 914 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 915 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no" -a "x$with_gphoto" != "xno"
 916 then
 917     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 918     ac_gphoto2_libs=""
 919     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 920     do
 921       case "$i" in
 922         -L/usr/lib|-L/usr/lib64) ;;
 923         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 924       esac
 925     done
 926     ac_save_CPPFLAGS="$CPPFLAGS"
 927     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 928     AC_CHECK_HEADER(gphoto2-camera.h,
 929                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 930                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 931                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 932                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 933                                   [$GPHOTO2LIBS])])
 934     CPPFLAGS="$ac_save_CPPFLAGS"
 935 fi
 936 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
 937                  [libgphoto2 development files not found, digital cameras won't be supported.])
 938
 939
 940 dnl **** Check for resolver library ***
 941 AC_SUBST(RESOLVLIBS,"")
 942 if test "$ac_cv_header_resolv_h" = "yes"
 943 then
 944     AC_CHECK_LIB(resolv, res_query,
 945         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 946          RESOLVLIBS="-lresolv"])
 947 fi
 948
 949 dnl **** Check for LittleCMS ***
 950 AC_SUBST(LCMSLIBS,"")
 951 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 952 then
 953     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 954         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 955          LCMSLIBS="-llcms"])
 956 fi
 957 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
 958                  [liblcms development files not found, Color Management won't be supported.])
 959
 960 dnl **** Check for OpenLDAP ***
 961 AC_SUBST(LDAPLIBS,"")
 962 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 963 then
 964     AC_CHECK_LIB(ldap_r, ldap_initialize,
 965         [AC_CHECK_LIB(lber, ber_init,
 966             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 967              LDAPLIBS="-lldap_r -llber"],,
 968              [$LIBPTHREAD])],,
 969              [$LIBPTHREAD])
 970     WINE_CHECK_LIB_FUNCS(\
 971         ldap_count_references \
 972         ldap_first_reference \
 973         ldap_next_reference \
 974         ldap_parse_reference \
 975         ldap_parse_sort_control \
 976         ldap_parse_sortresponse_control \
 977         ldap_parse_vlv_control \
 978         ldap_parse_vlvresponse_control,
 979         [$LDAPLIBS $LIBPTHREAD])
 980 fi
 981 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
 982                  [libldap (OpenLDAP) development files not found, LDAP won't be supported.])
 983
 984 dnl **** Check for FreeType 2 ****
 985 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 986 if test "$ft_devel" != "false"
 987 then
 988     ac_freetype_libs=`$ft_devel --libs`
 989     ac_freetype_incl=`$ft_devel --cflags`
 990     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 991     if test "$ft_lib" = "yes"
 992     then
 993         ac_save_CPPFLAGS="$CPPFLAGS"
 994         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 995         AC_CHECK_HEADERS(ft2build.h \
 996                          freetype/freetype.h \
 997                          freetype/ftglyph.h \
 998                          freetype/fttypes.h \
 999                          freetype/tttables.h \
1000                          freetype/ftnames.h \
1001                          freetype/ftsnames.h \
1002                          freetype/ttnameid.h \
1003                          freetype/ftoutln.h \
1004                          freetype/ftwinfnt.h \
1005                          freetype/ftmodapi.h \
1006                          freetype/internal/sfnt.h,,,
1007                          [#ifdef HAVE_FT2BUILD_H
1008                           # include <ft2build.h>
1009                           #endif])
1010         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1011                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1012           [Define if you have the <freetype/fttrigon.h> header file.])
1013                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1014         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1015         ac_save_CFLAGS="$CFLAGS"
1016         CFLAGS="$CFLAGS $ac_freetype_libs"
1017         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
1018         CFLAGS="$ac_save_CFLAGS"
1019         CPPFLAGS="$ac_save_CPPFLAGS"
1020         dnl Check that we have at least freetype/freetype.h
1021         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1022         then
1023             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1024             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1025             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1026         fi
1027     fi
1028 fi
1029
1030 dnl Only build the fonts dir if we have freetype
1031 if test "x$FREETYPELIBS" = "x"
1032 then
1033     WINE_WARNING([FreeType development files not found.
1034 Fonts will not be built. Dialog text may be invisible or unaligned.])
1035 else
1036   AC_SUBST(FONTSSUBDIRS,"fonts")
1037 fi
1038
1039 dnl **** Check for parport (currently Linux only) ****
1040 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1041  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1042     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1043 if test "$ac_cv_c_ppdev" = "yes"
1044 then
1045     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1046 fi
1047
1048 dnl **** Check for va_copy ****
1049 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
1050  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
1051     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
1052  )
1053 if test "$ac_cv_c_va_copy" = "yes"
1054 then
1055     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
1056 fi
1057 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
1058  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
1059     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
1060  )
1061 if test "$ac_cv_c___va_copy" = "yes"
1062 then
1063     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
1064 fi
1065
1066 dnl **** Check for sigsetjmp ****
1067 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
1068  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
1069     sigsetjmp( buf, 1 );
1070     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
1071  )
1072 if test "$ac_cv_c_sigsetjmp" = "yes"
1073 then
1074     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
1075 fi
1076
1077 dnl **** Check for pthread_rwlock_t ****
1078 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
1079 #include <pthread.h>])
1080
1081 dnl **** Check for pthread functions ****
1082 WINE_CHECK_LIB_FUNCS(\
1083         pthread_attr_get_np \
1084         pthread_getattr_np \
1085         pthread_get_stackaddr_np \
1086         pthread_get_stacksize_np,
1087         [$LIBPTHREAD])
1088
1089 dnl **** Check for EsounD ****
1090 AC_PATH_PROG(ESDCONFIG, esd-config)
1091 if test "x$with_esd" != xno -a "x$ESDCONFIG" != x -a "x$ESDCONFIG" != x'"$ESDCONFIG"';
1092 then
1093     ESD_CFLAGS=""
1094     for i in `$ESDCONFIG --cflags`
1095     do
1096       case "$i" in
1097         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
1098       esac
1099     done
1100     ESD_LIBS=`$ESDCONFIG --libs`
1101     save_CFLAGS="$CFLAGS"
1102     CFLAGS="$CFLAGS $ESD_CFLAGS"
1103     AC_CHECK_LIB(esd,esd_open_sound,
1104         [AC_SUBST(ESDLIBS, $ESD_LIBS)
1105          AC_SUBST(ESDINCL, $ESD_CFLAGS)
1106          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
1107     CFLAGS="$save_CFLAGS"
1108 fi
1109
1110 dnl **** Check for ALSA 1.x ****
1111 AC_SUBST(ALSALIBS,"")
1112 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1113 then
1114     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1115         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1116 #include <alsa/asoundlib.h>
1117 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1118 #include <sys/asoundlib.h>
1119 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1120                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1121                          ALSALIBS="-lasound"],[])])
1122 fi
1123
1124 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1125 AC_SUBST(AUDIOIOLIBS,"")
1126 if test "$ac_cv_header_libaudioio_h" = "yes"
1127 then
1128     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1129                   [AUDIOIOLIBS="-laudioio"
1130                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1131 fi
1132
1133 dnl **** Check for capi4linux ****
1134
1135 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1136 then
1137     WINE_CHECK_SONAME(capi20,capi20_register)
1138 fi
1139 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1140                  [libcapi20 development files not found, ISDN won't be supported.])
1141
1142 dnl **** Check for cups ****
1143 if test "$ac_cv_header_cups_cups_h" = "yes"
1144 then
1145     WINE_CHECK_SONAME(cups,cupsGetDefault)
1146 fi
1147 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1148                  [libcups development files not found, CUPS won't be supported.])
1149
1150 dnl **** Check for jack ****
1151 if test "$ac_cv_header_jack_jack_h" = "yes"
1152 then
1153     WINE_CHECK_SONAME(jack,jack_client_new)
1154 fi
1155
1156 dnl **** Check for fontconfig ****
1157 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1158 then
1159     WINE_CHECK_SONAME(fontconfig,FcInit)
1160 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1161 then
1162     dnl fontconfig is in the X directory on Mac OS X
1163     ac_save_CPPFLAGS="$CPPFLAGS"
1164     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1165     $as_unset ac_cv_header_fontconfig_fontconfig_h
1166     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1167     CPPFLAGS="$ac_save_CPPFLAGS"
1168     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1169     then
1170         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1171         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1172     fi
1173 fi
1174 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1175                  [fontconfig development files not found, fontconfig won't be supported.])
1176
1177 dnl **** Check for SSL ****
1178 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1179 then
1180     WINE_CHECK_SONAME(ssl,SSL_library_init)
1181     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1182 fi
1183 WINE_NOTICE_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x"],
1184                  [OpenSSL development files not found, SSL won't be supported.])
1185
1186 dnl **** Check for libjpeg ****
1187 if test "$ac_cv_header_jpeglib_h" = "yes"
1188 then
1189     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1190 fi
1191 WINE_NOTICE_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1192                  [libjpeg development files not found, JPEG won't be supported.])
1193
1194 dnl **** Check for libpng ****
1195 if test "$ac_cv_header_png_h" = "yes"
1196 then
1197     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1198 fi
1199 WINE_NOTICE_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1200                  [libpng development files not found, PNG won't be supported.])
1201
1202 dnl **** Check for libodbc ****
1203 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1204
1205 dnl **** Check for any sound system ****
1206 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1207         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1208         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1209         "$ac_cv_header_soundcard_h" != "yes" -a \
1210         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1211 then
1212     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1213 fi
1214
1215 dnl **** Check for gcc specific options ****
1216
1217 AC_SUBST(EXTRACFLAGS,"")
1218 if test "x${GCC}" = "xyes"
1219 then
1220   EXTRACFLAGS="-Wall -pipe"
1221
1222   dnl Check for strength-reduce bug
1223   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1224                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1225 [[static int Array[[3]];
1226   unsigned int B = 3;
1227   int i;
1228   for(i=0; i<B; i++) Array[[i]] = i - 3;
1229   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1230   L[[i]] = 4;
1231   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1232     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1233   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1234   then
1235     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1236   fi
1237
1238   dnl Check for some compiler flags
1239
1240   WINE_TRY_CFLAGS([-fshort-wchar],
1241                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1242                              [Specifies the compiler flag that forces a short wchar_t])])
1243   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1244   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1245   WINE_TRY_CFLAGS([-Wwrite-strings])
1246   WINE_TRY_CFLAGS([-Wtype-limits])
1247
1248   dnl Check for noisy string.h
1249   saved_CFLAGS="$CFLAGS"
1250   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1251   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1252       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1253   CFLAGS="$saved_CFLAGS"
1254   if test "$ac_cv_c_string_h_warnings" = "no"
1255   then
1256     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1257   fi
1258
1259   AC_SUBST(BUILTINFLAG,"")
1260   saved_CFLAGS="$CFLAGS"
1261   CFLAGS="$CFLAGS -Werror"
1262   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1263       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1264   CFLAGS="$saved_CFLAGS"
1265   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1266   then
1267     BUILTINFLAG="-fno-builtin"
1268   fi
1269 fi
1270
1271 dnl **** Check how to define a function in assembly code ****
1272
1273 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1274   WINE_TRY_ASM_LINK(
1275       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1276       ac_cv_asm_func_def=".def",
1277     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1278       ac_cv_asm_func_def=".type @function",
1279     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1280       ac_cv_asm_func_def=".type 2",
1281       ac_cv_asm_func_def="unknown")])]))
1282
1283 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1284 case "$ac_cv_asm_func_def" in
1285   ".def")
1286      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1287   ".type @function")
1288      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1289   ".type 2")
1290      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1291   *)
1292      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1293 esac
1294
1295 dnl **** Check for underscore on external symbols ****
1296
1297 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1298     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1299                       [extern int ac_test;],
1300                       [if (ac_test) return 1],
1301                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1302
1303 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1304 if test "$ac_cv_c_extern_prefix" = "yes"
1305 then
1306   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1307 else
1308   AC_DEFINE([__ASM_NAME(name)], [name])
1309 fi
1310
1311 dnl **** Platform-specific checks ****
1312
1313 AC_SUBST(LDPATH,"")
1314 case $build_os in
1315   cygwin*|mingw32*)
1316     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1317     ;;
1318   darwin*|macosx*)
1319     ;;
1320   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1321     if test -z "$LDRPATH_LOCAL"
1322     then
1323       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1324     fi
1325     ;;
1326   *)
1327     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1328     ;;
1329 esac
1330
1331 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1332 case $host_os in
1333   mingw32*)
1334     AC_SUBST(CRTLIBS,"-lmsvcrt")
1335     AC_SUBST(SOCKETLIBS,"-lws2_32")
1336     ;;
1337 esac
1338
1339 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1340 case $host_cpu in
1341   *i[[3456789]]86*)
1342     case $host_os in
1343       linux* | k*bsd*-gnu)
1344         AC_SUBST(MAIN_BINARY,"wine-glibc")
1345         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1346       freebsd*)
1347         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1348         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1349     esac
1350     ;;
1351 esac
1352
1353 dnl **** Check for functions ****
1354
1355 AC_CHECK_FUNCS(\
1356         _pclose \
1357         _popen \
1358         _snprintf \
1359         _spawnvp \
1360         _strdup \
1361         _stricmp \
1362         _strnicmp \
1363         _strtoi64 \
1364         _strtoui64 \
1365         _vsnprintf \
1366         asctime_r \
1367         chsize \
1368         clone \
1369         dlopen \
1370         epoll_create \
1371         ffs \
1372         finite \
1373         fork \
1374         fpclass \
1375         fstatfs \
1376         fstatvfs \
1377         ftruncate \
1378         futimes \
1379         futimesat \
1380         getdirentries \
1381         getopt_long \
1382         getpagesize \
1383         getpwuid \
1384         gettid \
1385         gettimeofday \
1386         getuid \
1387         inet_pton \
1388         kqueue \
1389         lstat \
1390         memmove \
1391         mmap \
1392         pclose \
1393         poll \
1394         popen \
1395         prctl \
1396         pread \
1397         pwrite \
1398         readlink \
1399         rfork \
1400         sched_yield \
1401         select \
1402         setproctitle \
1403         setrlimit \
1404         settimeofday \
1405         sigaltstack \
1406         sigprocmask \
1407         snprintf \
1408         spawnvp \
1409         statfs \
1410         statvfs \
1411         strcasecmp \
1412         strdup \
1413         strerror \
1414         strncasecmp \
1415         strtold \
1416         strtoll \
1417         strtoull \
1418         tcgetattr \
1419         thr_kill2 \
1420         timegm \
1421         usleep \
1422         vsnprintf \
1423         wait4 \
1424         waitpid \
1425 )
1426
1427 dnl Check for -ldl
1428 if test "$ac_cv_func_dlopen" = no
1429 then
1430     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1431 fi
1432 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1433
1434 dnl Check for -lpoll for Mac OS X/Darwin
1435 if test "$ac_cv_func_poll" = no
1436 then
1437     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1438 fi
1439
1440 dnl Check for -lnsl for Solaris
1441 AC_SEARCH_LIBS(gethostbyname, nsl)
1442
1443 dnl Check for -lsocket for Solaris
1444 AC_SEARCH_LIBS(connect, socket)
1445
1446 dnl Check for -lresolv for Solaris
1447 AC_SEARCH_LIBS(inet_aton, resolv)
1448
1449 dnl **** Check for functions which may rely on -lsocket on Solaris.
1450 AC_CHECK_FUNCS(\
1451         getaddrinfo \
1452         getnameinfo \
1453         getnetbyname \
1454         getprotobyname \
1455         getprotobynumber \
1456         getservbyport \
1457         inet_network \
1458         sendmsg \
1459 )
1460
1461 dnl **** Check for types ****
1462
1463 AC_C_CONST
1464 AC_C_INLINE
1465 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1466 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1467 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1468
1469 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1470 [#ifdef HAVE_LINUX_INPUT_H
1471 #include <linux/input.h>
1472 #endif])
1473
1474 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1475                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1476 if test "$wine_cv_have_sigaddset" = "yes"
1477 then
1478   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1479 fi
1480
1481
1482 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1483         wine_cv_linux_gethostbyname_r_6,
1484         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1485     char *name=0;
1486     struct hostent he;
1487     struct hostent *result;
1488     char *buf=0;
1489     int bufsize=0;
1490     int res,errnr;
1491     char *addr=0;
1492     int addrlen=0;
1493     int addrtype=0;
1494     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1495     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1496     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1497         ])
1498    )
1499    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1500    then
1501       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1502                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1503    fi
1504
1505 if test "$ac_cv_header_linux_joystick_h" = "yes"
1506 then
1507    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1508         wine_cv_linux_joystick_22_api,
1509         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1510         #include <sys/ioctl.h>
1511         #include <sys/types.h>
1512         #include <linux/joystick.h>
1513
1514         struct js_event blub;
1515         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1516         #error "no 2.2 header"
1517         #endif
1518         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1519    )
1520    if test "$wine_cv_linux_joystick_22_api" = "yes"
1521    then
1522       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1523                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1524    fi
1525 fi
1526
1527 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1528
1529 dnl Check for statfs members
1530 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1531 [#include <sys/types.h>
1532 #ifdef HAVE_SYS_PARAM_H
1533 # include <sys/param.h>
1534 #endif
1535 #ifdef HAVE_SYS_MOUNT_H
1536 # include <sys/mount.h>
1537 #endif
1538 #ifdef HAVE_SYS_VFS_H
1539 # include <sys/vfs.h>
1540 #endif
1541 #ifdef HAVE_SYS_STATFS_H
1542 # include <sys/statfs.h>
1543 #endif])
1544
1545 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1546 [#ifdef HAVE_SYS_STATVFS_H
1547 #include <sys/statvfs.h>
1548 #endif])
1549
1550 dnl Check for socket structure members
1551 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1552 [#include <sys/types.h>
1553 #ifdef HAVE_SYS_SOCKET_H
1554 # include <sys/socket.h>
1555 #endif
1556 #ifdef HAVE_SYS_UN_H
1557 # include <sys/un.h>
1558 #endif])
1559
1560 dnl Check for scsireq_t and sg_io_hdr_t members
1561 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1562 [#include <sys/types.h>
1563 #ifdef HAVE_SCSI_SG_H
1564 #include <scsi/sg.h>
1565 #endif])
1566
1567 dnl Check for siginfo_t members
1568 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1569
1570 dnl Check for struct mtget members
1571 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1572 [#include <sys/types.h>
1573 #ifdef HAVE_SYS_MTIO_H
1574 #include <sys/mtio.h>
1575 #endif])
1576
1577 dnl Check for struct option
1578 AC_CHECK_MEMBERS([struct option.name],,,
1579 [#ifdef HAVE_GETOPT_H
1580 #include <getopt.h>
1581 #endif])
1582
1583 dnl Check for stat.st_blocks
1584 AC_CHECK_MEMBERS([struct stat.st_blocks])
1585
1586 dnl Check for sin6_scope_id
1587 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1588 [#ifdef HAVE_SYS_TYPES_H
1589 #include <sys/types.h>
1590 #endif
1591 #ifdef HAVE_NETINET_IN_H
1592 #include <netinet/in.h>
1593 #endif])
1594
1595 dnl Check for ns_msg ptr member
1596 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1597 [#ifdef HAVE_SYS_TYPES_H
1598 #include <sys/types.h>
1599 #endif
1600 #ifdef HAVE_NETINET_IN_H
1601 # include <netinet/in.h>
1602 #endif
1603 #ifdef HAVE_ARPA_NAMESER_H
1604 # include <arpa/nameser.h>
1605 #endif])
1606
1607 dnl Check for the external timezone variables timezone and daylight
1608 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1609                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1610 if test "$ac_cv_have_timezone" = "yes"
1611 then
1612     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1613 fi
1614 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1615                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1616 if test "$ac_cv_have_daylight" = "yes"
1617 then
1618     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1619 fi
1620
1621 dnl *** check for the need to define platform-specific symbols
1622
1623 case $host_cpu in
1624   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1625   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1626   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1627   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1628   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1629 esac
1630
1631 case $host_vendor in
1632   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1633 esac
1634
1635 dnl **** Generate output files ****
1636
1637 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1638 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1639 ["### Dependencies:\\
1640 \\
1641 .INIT: Makefile\\
1642 .BEGIN: Makefile\\
1643 Makefile: dummy\\
1644         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1645 \\
1646 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1647 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1648 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1649 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1650 ["### Dependencies:
1651
1652 .INIT: Makefile
1653 .BEGIN: Makefile
1654 Makefile: dummy
1655         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1656
1657 \$(OBJS): \$(IDL_GEN_HEADERS)
1658 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1659 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1660 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1661
1662 AH_TOP([#define __WINE_CONFIG_H])
1663
1664 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1665
1666 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1667 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1668 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1669 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1670 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1671 WINE_CONFIG_EXTRA_DIR(include/wine)
1672
1673 MAKE_RULES=Make.rules
1674 AC_SUBST_FILE(MAKE_RULES)
1675
1676 MAKE_DLL_RULES=dlls/Makedll.rules
1677 AC_SUBST_FILE(MAKE_DLL_RULES)
1678
1679 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1680 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1681
1682 MAKE_TEST_RULES=dlls/Maketest.rules
1683 AC_SUBST_FILE(MAKE_TEST_RULES)
1684
1685 MAKE_PROG_RULES=programs/Makeprog.rules
1686 AC_SUBST_FILE(MAKE_PROG_RULES)
1687
1688 AC_CONFIG_FILES([Make.rules])
1689 AC_CONFIG_FILES([dlls/Makedll.rules])
1690 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1691 AC_CONFIG_FILES([dlls/Maketest.rules])
1692 AC_CONFIG_FILES([programs/Makeprog.rules])
1693 AC_CONFIG_FILES([Makefile])
1694 AC_CONFIG_FILES([dlls/Makefile])
1695 AC_CONFIG_FILES([dlls/acledit/Makefile])
1696 AC_CONFIG_FILES([dlls/activeds/Makefile])
1697 AC_CONFIG_FILES([dlls/actxprxy/Makefile])
1698 AC_CONFIG_FILES([dlls/adsiid/Makefile])
1699 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1700 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1701 AC_CONFIG_FILES([dlls/advpack/Makefile])
1702 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1703 AC_CONFIG_FILES([dlls/amstream/Makefile])
1704 AC_CONFIG_FILES([dlls/atl/Makefile])
1705 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1706 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1707 AC_CONFIG_FILES([dlls/browseui/Makefile])
1708 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1709 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1710 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1711 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1712 AC_CONFIG_FILES([dlls/cards/Makefile])
1713 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1714 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1715 AC_CONFIG_FILES([dlls/comcat/Makefile])
1716 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1717 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1718 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1719 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1720 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1721 AC_CONFIG_FILES([dlls/compstui/Makefile])
1722 AC_CONFIG_FILES([dlls/credui/Makefile])
1723 AC_CONFIG_FILES([dlls/credui/tests/Makefile])
1724 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1725 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1726 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1727 AC_CONFIG_FILES([dlls/cryptdlg/Makefile])
1728 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1729 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1730 AC_CONFIG_FILES([dlls/cryptnet/tests/Makefile])
1731 AC_CONFIG_FILES([dlls/cryptui/Makefile])
1732 AC_CONFIG_FILES([dlls/ctapi32/Makefile])
1733 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1734 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1735 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1736 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1737 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1738 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1739 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1740 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1741 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1742 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1743 AC_CONFIG_FILES([dlls/d3dx8/tests/Makefile])
1744 AC_CONFIG_FILES([dlls/d3dx9_24/Makefile])
1745 AC_CONFIG_FILES([dlls/d3dx9_25/Makefile])
1746 AC_CONFIG_FILES([dlls/d3dx9_26/Makefile])
1747 AC_CONFIG_FILES([dlls/d3dx9_27/Makefile])
1748 AC_CONFIG_FILES([dlls/d3dx9_28/Makefile])
1749 AC_CONFIG_FILES([dlls/d3dx9_29/Makefile])
1750 AC_CONFIG_FILES([dlls/d3dx9_30/Makefile])
1751 AC_CONFIG_FILES([dlls/d3dx9_31/Makefile])
1752 AC_CONFIG_FILES([dlls/d3dx9_32/Makefile])
1753 AC_CONFIG_FILES([dlls/d3dx9_33/Makefile])
1754 AC_CONFIG_FILES([dlls/d3dx9_34/Makefile])
1755 AC_CONFIG_FILES([dlls/d3dx9_35/Makefile])
1756 AC_CONFIG_FILES([dlls/d3dx9_36/Makefile])
1757 AC_CONFIG_FILES([dlls/d3dx9_36/tests/Makefile])
1758 AC_CONFIG_FILES([dlls/d3dx9_37/Makefile])
1759 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1760 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1761 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1762 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1763 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1764 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1765 AC_CONFIG_FILES([dlls/devenum/Makefile])
1766 AC_CONFIG_FILES([dlls/dinput/Makefile])
1767 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1768 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1769 AC_CONFIG_FILES([dlls/dmband/Makefile])
1770 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1771 AC_CONFIG_FILES([dlls/dmime/Makefile])
1772 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1773 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1774 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1775 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1776 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1777 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1778 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1779 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1780 AC_CONFIG_FILES([dlls/dplay/Makefile])
1781 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1782 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1783 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1784 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1785 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1786 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1787 AC_CONFIG_FILES([dlls/dsound/Makefile])
1788 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1789 AC_CONFIG_FILES([dlls/dssenh/Makefile])
1790 AC_CONFIG_FILES([dlls/dswave/Makefile])
1791 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1792 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1793 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1794 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1795 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1796 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1797 AC_CONFIG_FILES([dlls/fusion/Makefile])
1798 AC_CONFIG_FILES([dlls/fusion/tests/Makefile])
1799 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1800 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1801 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1802 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1803 AC_CONFIG_FILES([dlls/glu32/Makefile])
1804 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1805 AC_CONFIG_FILES([dlls/gpkcsp/Makefile])
1806 AC_CONFIG_FILES([dlls/hal/Makefile])
1807 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1808 AC_CONFIG_FILES([dlls/hid/Makefile])
1809 AC_CONFIG_FILES([dlls/hlink/Makefile])
1810 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1811 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1812 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1813 AC_CONFIG_FILES([dlls/icmp/Makefile])
1814 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1815 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1816 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1817 AC_CONFIG_FILES([dlls/imm32/Makefile])
1818 AC_CONFIG_FILES([dlls/imm32/tests/Makefile])
1819 AC_CONFIG_FILES([dlls/inetcomm/Makefile])
1820 AC_CONFIG_FILES([dlls/inetcomm/tests/Makefile])
1821 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1822 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1823 AC_CONFIG_FILES([dlls/initpki/Makefile])
1824 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1825 AC_CONFIG_FILES([dlls/inseng/Makefile])
1826 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1827 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1828 AC_CONFIG_FILES([dlls/itircl/Makefile])
1829 AC_CONFIG_FILES([dlls/itss/Makefile])
1830 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1831 AC_CONFIG_FILES([dlls/jscript/Makefile])
1832 AC_CONFIG_FILES([dlls/jscript/tests/Makefile])
1833 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1834 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1835 AC_CONFIG_FILES([dlls/localspl/Makefile])
1836 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1837 AC_CONFIG_FILES([dlls/localui/Makefile])
1838 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1839 AC_CONFIG_FILES([dlls/lz32/Makefile])
1840 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1841 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1842 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1843 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1844 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1845 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1846 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1847 AC_CONFIG_FILES([dlls/midimap/Makefile])
1848 AC_CONFIG_FILES([dlls/mlang/Makefile])
1849 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1850 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1851 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1852 AC_CONFIG_FILES([dlls/mountmgr.sys/Makefile])
1853 AC_CONFIG_FILES([dlls/mpr/Makefile])
1854 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1855 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1856 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1857 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1858 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1859 AC_CONFIG_FILES([dlls/mscat32/Makefile])
1860 AC_CONFIG_FILES([dlls/mscms/Makefile])
1861 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1862 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1863 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1864 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1865 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1866 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1867 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1868 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1869 AC_CONFIG_FILES([dlls/msi/Makefile])
1870 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1871 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1872 AC_CONFIG_FILES([dlls/msimtf/Makefile])
1873 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1874 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1875 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1876 AC_CONFIG_FILES([dlls/mssip32/Makefile])
1877 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1878 AC_CONFIG_FILES([dlls/msvcr71/Makefile])
1879 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1880 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1881 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1882 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1883 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1884 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1885 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1886 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1887 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1888 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1889 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1890 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1891 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1892 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1893 AC_CONFIG_FILES([dlls/newdev/Makefile])
1894 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1895 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1896 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1897 AC_CONFIG_FILES([dlls/ntdsapi/tests/Makefile])
1898 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1899 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1900 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1901 AC_CONFIG_FILES([dlls/objsel/Makefile])
1902 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1903 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1904 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1905 AC_CONFIG_FILES([dlls/ole32/Makefile])
1906 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1907 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1908 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1909 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1910 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1911 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1912 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1913 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1914 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1915 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1916 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1917 AC_CONFIG_FILES([dlls/pdh/Makefile])
1918 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1919 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1920 AC_CONFIG_FILES([dlls/printui/Makefile])
1921 AC_CONFIG_FILES([dlls/propsys/Makefile])
1922 AC_CONFIG_FILES([dlls/psapi/Makefile])
1923 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1924 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1925 AC_CONFIG_FILES([dlls/qcap/Makefile])
1926 AC_CONFIG_FILES([dlls/qedit/Makefile])
1927 AC_CONFIG_FILES([dlls/qedit/tests/Makefile])
1928 AC_CONFIG_FILES([dlls/qmgr/Makefile])
1929 AC_CONFIG_FILES([dlls/qmgr/tests/Makefile])
1930 AC_CONFIG_FILES([dlls/qmgrprxy/Makefile])
1931 AC_CONFIG_FILES([dlls/quartz/Makefile])
1932 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1933 AC_CONFIG_FILES([dlls/query/Makefile])
1934 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1935 AC_CONFIG_FILES([dlls/resutils/Makefile])
1936 AC_CONFIG_FILES([dlls/riched20/Makefile])
1937 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1938 AC_CONFIG_FILES([dlls/riched32/Makefile])
1939 AC_CONFIG_FILES([dlls/riched32/tests/Makefile])
1940 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1941 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1942 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1943 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1944 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1945 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1946 AC_CONFIG_FILES([dlls/sccbase/Makefile])
1947 AC_CONFIG_FILES([dlls/schannel/Makefile])
1948 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1949 AC_CONFIG_FILES([dlls/secur32/Makefile])
1950 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1951 AC_CONFIG_FILES([dlls/security/Makefile])
1952 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1953 AC_CONFIG_FILES([dlls/serialui/Makefile])
1954 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1955 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1956 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1957 AC_CONFIG_FILES([dlls/sfc/Makefile])
1958 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1959 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1960 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1961 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1962 AC_CONFIG_FILES([dlls/shell32/Makefile])
1963 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1964 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1965 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1966 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1967 AC_CONFIG_FILES([dlls/slbcsp/Makefile])
1968 AC_CONFIG_FILES([dlls/slc/Makefile])
1969 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1970 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1971 AC_CONFIG_FILES([dlls/softpub/Makefile])
1972 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1973 AC_CONFIG_FILES([dlls/spoolss/tests/Makefile])
1974 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1975 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1976 AC_CONFIG_FILES([dlls/sti/Makefile])
1977 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1978 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1979 AC_CONFIG_FILES([dlls/sxs/Makefile])
1980 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1981 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1982 AC_CONFIG_FILES([dlls/unicows/Makefile])
1983 AC_CONFIG_FILES([dlls/url/Makefile])
1984 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1985 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1986 AC_CONFIG_FILES([dlls/user32/Makefile])
1987 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1988 AC_CONFIG_FILES([dlls/userenv/Makefile])
1989 AC_CONFIG_FILES([dlls/usp10/Makefile])
1990 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1991 AC_CONFIG_FILES([dlls/uuid/Makefile])
1992 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1993 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1994 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1995 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1996 AC_CONFIG_FILES([dlls/version/Makefile])
1997 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1998 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1999 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
2000 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
2001 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
2002 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
2003 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
2004 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
2005 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
2006 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
2007 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
2008 AC_CONFIG_FILES([dlls/wined3d/Makefile])
2009 AC_CONFIG_FILES([dlls/winedos/Makefile])
2010 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
2011 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
2012 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
2013 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
2014 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
2015 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
2016 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
2017 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
2018 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
2019 AC_CONFIG_FILES([dlls/wing32/Makefile])
2020 AC_CONFIG_FILES([dlls/winhttp/Makefile])
2021 AC_CONFIG_FILES([dlls/wininet/Makefile])
2022 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
2023 AC_CONFIG_FILES([dlls/winmm/Makefile])
2024 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
2025 AC_CONFIG_FILES([dlls/winnls32/Makefile])
2026 AC_CONFIG_FILES([dlls/winscard/Makefile])
2027 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
2028 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
2029 AC_CONFIG_FILES([dlls/wintab32/Makefile])
2030 AC_CONFIG_FILES([dlls/wintrust/Makefile])
2031 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
2032 AC_CONFIG_FILES([dlls/wldap32/Makefile])
2033 AC_CONFIG_FILES([dlls/wmi/Makefile])
2034 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
2035 AC_CONFIG_FILES([dlls/wow32/Makefile])
2036 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
2037 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
2038 AC_CONFIG_FILES([dlls/wsock32/Makefile])
2039 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
2040 AC_CONFIG_FILES([documentation/Makefile])
2041 AC_CONFIG_FILES([fonts/Makefile])
2042 AC_CONFIG_FILES([include/Makefile])
2043 AC_CONFIG_FILES([libs/Makefile])
2044 AC_CONFIG_FILES([libs/port/Makefile])
2045 AC_CONFIG_FILES([libs/wine/Makefile])
2046 AC_CONFIG_FILES([libs/wpp/Makefile])
2047 AC_CONFIG_FILES([loader/Makefile])
2048 AC_CONFIG_FILES([programs/Makefile])
2049 AC_CONFIG_FILES([programs/clock/Makefile])
2050 AC_CONFIG_FILES([programs/cmd/Makefile])
2051 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
2052 AC_CONFIG_FILES([programs/control/Makefile])
2053 AC_CONFIG_FILES([programs/eject/Makefile])
2054 AC_CONFIG_FILES([programs/expand/Makefile])
2055 AC_CONFIG_FILES([programs/explorer/Makefile])
2056 AC_CONFIG_FILES([programs/hh/Makefile])
2057 AC_CONFIG_FILES([programs/icinfo/Makefile])
2058 AC_CONFIG_FILES([programs/iexplore/Makefile])
2059 AC_CONFIG_FILES([programs/msiexec/Makefile])
2060 AC_CONFIG_FILES([programs/net/Makefile])
2061 AC_CONFIG_FILES([programs/notepad/Makefile])
2062 AC_CONFIG_FILES([programs/oleview/Makefile])
2063 AC_CONFIG_FILES([programs/progman/Makefile])
2064 AC_CONFIG_FILES([programs/reg/Makefile])
2065 AC_CONFIG_FILES([programs/regedit/Makefile])
2066 AC_CONFIG_FILES([programs/regsvr32/Makefile])
2067 AC_CONFIG_FILES([programs/rpcss/Makefile])
2068 AC_CONFIG_FILES([programs/rundll32/Makefile])
2069 AC_CONFIG_FILES([programs/secedit/Makefile])
2070 AC_CONFIG_FILES([programs/services/Makefile])
2071 AC_CONFIG_FILES([programs/spoolsv/Makefile])
2072 AC_CONFIG_FILES([programs/start/Makefile])
2073 AC_CONFIG_FILES([programs/svchost/Makefile])
2074 AC_CONFIG_FILES([programs/taskmgr/Makefile])
2075 AC_CONFIG_FILES([programs/uninstaller/Makefile])
2076 AC_CONFIG_FILES([programs/view/Makefile])
2077 AC_CONFIG_FILES([programs/wineboot/Makefile])
2078 AC_CONFIG_FILES([programs/winebrowser/Makefile])
2079 AC_CONFIG_FILES([programs/winecfg/Makefile])
2080 AC_CONFIG_FILES([programs/wineconsole/Makefile])
2081 AC_CONFIG_FILES([programs/winedbg/Makefile])
2082 AC_CONFIG_FILES([programs/winedevice/Makefile])
2083 AC_CONFIG_FILES([programs/winefile/Makefile])
2084 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
2085 AC_CONFIG_FILES([programs/winemine/Makefile])
2086 AC_CONFIG_FILES([programs/winepath/Makefile])
2087 AC_CONFIG_FILES([programs/winetest/Makefile])
2088 AC_CONFIG_FILES([programs/winevdm/Makefile])
2089 AC_CONFIG_FILES([programs/winhelp/Makefile])
2090 AC_CONFIG_FILES([programs/winver/Makefile])
2091 AC_CONFIG_FILES([programs/wordpad/Makefile])
2092 AC_CONFIG_FILES([programs/write/Makefile])
2093 AC_CONFIG_FILES([programs/xcopy/Makefile])
2094 AC_CONFIG_FILES([server/Makefile])
2095 AC_CONFIG_FILES([tools/Makefile])
2096 AC_CONFIG_FILES([tools/widl/Makefile])
2097 AC_CONFIG_FILES([tools/winebuild/Makefile])
2098 AC_CONFIG_FILES([tools/winedump/Makefile])
2099 AC_CONFIG_FILES([tools/winegcc/Makefile])
2100 AC_CONFIG_FILES([tools/wmc/Makefile])
2101 AC_CONFIG_FILES([tools/wrc/Makefile])
2102
2103 AC_OUTPUT
2104
2105 if test "$no_create" = "yes"
2106 then
2107   exit 0
2108 fi
2109
2110 WINE_PRINT_MESSAGES
2111
2112 echo "
2113 $as_me: Finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine.
2114 " >&AS_MESSAGE_FD
2115
2116 dnl Local Variables:
2117 dnl comment-start: "dnl "
2118 dnl comment-end: ""
2119 dnl comment-start-skip: "\\bdnl\\b\\s *"
2120 dnl compile-command: "autoreconf --warnings=all"
2121 dnl End: