aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]]),
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32,w64-mingw32],[x86_64-ac_wine_prefix-$2 ])" ;;
 132   *)
 133     ac_prefix_list="" ;;
 134 esac
 135 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 136
 137
 138 dnl **** Define helper functions for creating config.status files ****
 139 dnl
 140 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 141 dnl
 142 AC_DEFUN([WINE_CONFIG_HELPERS],
 143 [AC_SUBST(ALL_MAKEFILE_DEPENDS,["# Makefile dependencies
 144 Makefile: Makefile.in Make.rules config.status"])
 145 AC_SUBST(ALL_WINETEST_DEPENDS,["# Test binaries"])
 146
 147 AC_SUBST(ALL_MAKERULES,"")
 148 AC_SUBST(ALL_SYMLINKS,"")
 149 AC_SUBST(ALL_DIRS,"")
 150 AC_SUBST(ALL_TOP_DIRS,"")
 151 AC_SUBST(ALL_DLL_DIRS,"")
 152 AC_SUBST(ALL_TEST_BINARIES,"")
 153 AC_SUBST(ALL_PROGRAM_BIN_INSTALL_DIRS,"")
 154
 155 wine_fn_append_file ()
 156 {
 157     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 158 }
 159
 160 wine_fn_append_rule ()
 161 {
 162     AS_VAR_APPEND($[1],"$as_nl$[2]")
 163 }
 164
 165 wine_fn_config_makefile ()
 166 {
 167     ac_dir=$[1]
 168     ac_enable=$[2]
 169     wine_fn_append_file ALL_DIRS $ac_dir
 170     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 171 "$ac_dir/__clean__ $ac_dir/__install__ $ac_dir/__install-dev__ $ac_dir/__install-lib__ $ac_dir/__uninstall__ $ac_dir: $ac_dir/Makefile
 172 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status Make.rules \$(MAKEDEP)
 173         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 174     AS_VAR_IF([$ac_enable],[no],,[case $ac_dir in
 175                  */*) ;;
 176                  *) wine_fn_append_file ALL_TOP_DIRS $ac_dir ;;
 177                esac])
 178 }
 179
 180 wine_fn_config_lib ()
 181 {
 182     ac_name=$[1]
 183     ac_dir=dlls/$ac_name
 184     wine_fn_append_file ALL_DIRS $ac_dir
 185     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 186 "all __builddeps__: $ac_dir
 187 __buildcrossdeps__: $ac_dir/lib$ac_name.cross.a
 188 $ac_dir $ac_dir/lib$ac_name.cross.a: $ac_dir/Makefile tools/widl tools/winebuild tools/winegcc include
 189 $ac_dir/lib$ac_name.cross.a: dummy
 190         @cd $ac_dir && \$(MAKE) lib$ac_name.cross.a
 191 $ac_dir/__clean__: $ac_dir/Makefile
 192 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status dlls/Makeimplib.rules \$(MAKEDEP)
 193         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend
 194 install install-dev:: $ac_dir
 195         @cd $ac_dir && \$(MAKE) install
 196 uninstall:: $ac_dir/Makefile
 197         @cd $ac_dir && \$(MAKE) uninstall"
 198 }
 199
 200 wine_fn_config_dll ()
 201 {
 202     ac_dir=$[1]
 203     ac_enable=$[2]
 204     ac_implib=$[3]
 205     ac_implibsrc=$[4]
 206     ac_file="dlls/$ac_dir/lib$ac_implib"
 207     ac_deps="tools/widl tools/winebuild tools/winegcc include"
 208
 209     wine_fn_append_file ALL_DIRS dlls/$ac_dir
 210     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 211 "dlls/$ac_dir/__clean__: dlls/$ac_dir/Makefile
 212 dlls/$ac_dir/Makefile dlls/$ac_dir/__depend__: dlls/$ac_dir/Makefile.in config.status dlls/Makedll.rules \$(MAKEDEP)
 213         @./config.status --file dlls/$ac_dir/Makefile && cd dlls/$ac_dir && \$(MAKE) depend"
 214
 215     AS_VAR_IF([$ac_enable],[no],
 216               dnl enable_win16 is special in that it disables import libs too
 217               [test "$ac_enable" != enable_win16 || return 0],
 218               [wine_fn_append_file ALL_DLL_DIRS dlls/$ac_dir
 219                wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 220 "all: dlls/$ac_dir
 221 dlls/$ac_dir: dlls/$ac_dir/Makefile __builddeps__
 222 install:: dlls/$ac_dir/Makefile __builddeps__
 223         @cd dlls/$ac_dir && \$(MAKE) install
 224 install-lib:: dlls/$ac_dir/Makefile __builddeps__
 225         @cd dlls/$ac_dir && \$(MAKE) install-lib
 226 uninstall:: dlls/$ac_dir/Makefile
 227         @cd dlls/$ac_dir && \$(MAKE) uninstall"])
 228
 229     if test -n "$ac_implibsrc"
 230     then
 231         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 232 "__builddeps__: $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT
 233 __buildcrossdeps__: $ac_file.cross.a
 234 $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 235 $ac_file.def: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 236         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 237 $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/Makefile dummy
 238         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 239 install-dev:: dlls/$ac_dir/Makefile __builddeps__
 240         @cd dlls/$ac_dir && \$(MAKE) install-dev"
 241     elif test -n "$ac_implib"
 242     then
 243         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 244 "__builddeps__: $ac_file.$IMPLIBEXT
 245 __buildcrossdeps__: $ac_file.cross.a
 246 $ac_file.$IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile $ac_deps
 247         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 248 install-dev:: dlls/$ac_dir/Makefile __builddeps__
 249         @cd dlls/$ac_dir && \$(MAKE) install-dev"
 250
 251         if test "$ac_dir" != "$ac_implib"
 252         then
 253             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 254 "__builddeps__: dlls/lib$ac_implib.$IMPLIBEXT
 255 __buildcrossdeps__: dlls/lib$ac_implib.cross.a
 256 dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 257         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.$IMPLIBEXT \$[@]
 258 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 259         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.cross.a \$[@]
 260 clean::
 261         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 262         fi
 263     fi
 264 }
 265
 266 wine_fn_config_program ()
 267 {
 268     ac_dir=$[1]
 269     ac_enable=$[2]
 270     ac_install=$[3]
 271     wine_fn_append_file ALL_DIRS programs/$ac_dir
 272     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 273 "programs/$ac_dir/__clean__: programs/$ac_dir/Makefile
 274 programs/$ac_dir/Makefile programs/$ac_dir/__depend__: programs/$ac_dir/Makefile.in config.status programs/Makeprog.rules \$(MAKEDEP)
 275         @./config.status --file programs/$ac_dir/Makefile && cd programs/$ac_dir && \$(MAKE) depend"
 276
 277     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 278 "all: programs/$ac_dir
 279 programs/$ac_dir: programs/$ac_dir/Makefile __builddeps__"
 280     if test -n "$ac_install"
 281     then
 282         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 283 "install install-lib:: programs/$ac_dir/Makefile __builddeps__
 284         @cd programs/$ac_dir && \$(MAKE) install
 285 uninstall:: programs/$ac_dir/Makefile
 286         @cd programs/$ac_dir && \$(MAKE) uninstall"
 287         test "$ac_install" != installbin || wine_fn_append_file ALL_PROGRAM_BIN_INSTALL_DIRS programs/$ac_dir
 288     fi])
 289 }
 290
 291 wine_fn_config_test ()
 292 {
 293     ac_dir=$[1]
 294     ac_name=$[2]
 295     wine_fn_append_file ALL_TEST_BINARIES $ac_name.exe
 296     wine_fn_append_rule ALL_WINETEST_DEPENDS \
 297 "$ac_name.exe: \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT
 298         cp \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT \$[@] && \$(STRIP) \$[@]
 299 $ac_name.rc:
 300         echo \"$ac_name.exe TESTRES \\\"$ac_name.exe\\\"\" >\$[@] || (\$(RM) \$[@] && false)
 301 $ac_name.res: $ac_name.rc $ac_name.exe"
 302     wine_fn_append_file ALL_DIRS $ac_dir
 303     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 304 "$ac_dir/__clean__: $ac_dir/Makefile
 305 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status Maketest.rules \$(MAKEDEP)
 306         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 307
 308     AS_VAR_IF([enable_tests],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 309 "all programs/winetest: $ac_dir
 310 $ac_dir: $ac_dir/Makefile __builddeps__
 311 crosstest:: $ac_dir/Makefile __buildcrossdeps__
 312         @cd $ac_dir && \$(MAKE) crosstest
 313 test::
 314         @cd $ac_dir && \$(MAKE) test
 315 testclean::
 316         \$(RM) $ac_dir/*.ok"])
 317 }
 318
 319 wine_fn_config_tool ()
 320 {
 321     ac_dir=$[1]
 322     ac_deps="Make.rules"
 323     if test "$ac_dir" != tools
 324     then
 325         dnl makedep is in tools so tools makefile cannot depend on it
 326         ac_deps="$ac_deps \$(MAKEDEP)"
 327     fi
 328     wine_fn_append_file ALL_DIRS $ac_dir
 329     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 330 "$ac_dir/__clean__: $ac_dir/Makefile
 331 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status $ac_deps
 332         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 333
 334     AS_VAR_IF([enable_tools],[no],,[case $ac_dir in
 335       dnl tools directory has both install-lib and install-dev
 336       tools) wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 337 "install:: $ac_dir
 338         @cd $ac_dir && \$(MAKE) install
 339 install-lib:: $ac_dir
 340         @cd $ac_dir && \$(MAKE) install-lib
 341 install-dev:: $ac_dir
 342         @cd $ac_dir && \$(MAKE) install-dev" ;;
 343       *)     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 344 "install install-dev:: $ac_dir
 345         @cd $ac_dir && \$(MAKE) install" ;;
 346       esac
 347       wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 348 "uninstall:: $ac_dir/Makefile
 349         @cd $ac_dir && \$(MAKE) uninstall
 350 all __tooldeps__: $ac_dir
 351 $ac_dir: $ac_dir/Makefile libs/port"])
 352 }])
 353
 354 dnl **** Define helper function to append a file to a makefile file list ****
 355 dnl
 356 dnl Usage: WINE_APPEND_FILE(var,file)
 357 dnl
 358 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 359
 360 dnl **** Define helper function to append a rule to a makefile command list ****
 361 dnl
 362 dnl Usage: WINE_APPEND_RULE(var,rule)
 363 dnl
 364 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 365
 366 dnl **** Create nonexistent directories from config.status ****
 367 dnl
 368 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 369 dnl
 370 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 371 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 372
 373 dnl **** Create symlinks from config.status ****
 374 dnl
 375 dnl Usage: WINE_CONFIG_SYMLINK(name,target)
 376 dnl
 377 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 378 AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 379 m4_if([$2],,[test "$srcdir" = "." || ])WINE_APPEND_FILE(ALL_SYMLINKS,[$1])])
 380
 381 dnl **** Create a make rules file from config.status ****
 382 dnl
 383 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 384 dnl
 385 AC_DEFUN([WINE_CONFIG_MAKERULES],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 386 WINE_APPEND_FILE(ALL_MAKERULES,[$1])
 387 WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[$1: m4_ifval([$3],[$1.in $3],[$1.in]) config.status])
 388 $2=$1
 389 AC_SUBST_FILE([$2])dnl
 390 AC_CONFIG_FILES([$1])])
 391
 392 dnl **** Create a makefile from config.status ****
 393 dnl
 394 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable)
 395 dnl
 396 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 397 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 398 wine_fn_config_makefile [$1] ac_enable[]dnl
 399 AS_VAR_POPDEF([ac_enable])])
 400
 401 dnl **** Create a dll makefile from config.status ****
 402 dnl
 403 dnl Usage: WINE_CONFIG_DLL(name,enable,implib,implibsrc)
 404 dnl
 405 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 406 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 407 wine_fn_config_dll [$1] ac_enable [$3] m4_ifval([$4],["$4"])dnl
 408 AS_VAR_POPDEF([ac_enable])])
 409
 410 dnl **** Create a program makefile from config.status ****
 411 dnl
 412 dnl Usage: WINE_CONFIG_PROGRAM(name,install,enable)
 413 dnl
 414 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 415 AS_VAR_PUSHDEF([ac_enable],m4_default([$3],[enable_]$1))dnl
 416 wine_fn_config_program [$1] ac_enable [$2]dnl
 417 AS_VAR_POPDEF([ac_enable])])
 418
 419 dnl **** Create a test makefile from config.status ****
 420 dnl
 421 dnl Usage: WINE_CONFIG_TEST(dir)
 422 dnl
 423 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 424 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 425 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 426 wine_fn_config_test $1 ac_name[]ac_suffix[]dnl
 427 m4_popdef([ac_suffix])dnl
 428 m4_popdef([ac_name])])
 429
 430 dnl **** Create a static lib makefile from config.status ****
 431 dnl
 432 dnl Usage: WINE_CONFIG_LIB(name)
 433 dnl
 434 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 435 wine_fn_config_lib $1])
 436
 437 dnl **** Create a tool makefile from config.status ****
 438 dnl
 439 dnl Usage: WINE_CONFIG_TOOL(name)
 440 dnl
 441 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 442 wine_fn_config_tool $1])
 443
 444 dnl **** Add a message to the list displayed at the end ****
 445 dnl
 446 dnl Usage: WINE_NOTICE(notice)
 447 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 448 dnl Usage: WINE_WARNING(warning)
 449 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 450 dnl Usage: WINE_PRINT_MESSAGES
 451 dnl
 452 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 453 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 454
 455 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 456   x)   WINE_NOTICE([$3]) ;;
 457   xno) ;;
 458   *)   AC_MSG_ERROR([$3
 459 This is an error since --with-$1 was requested.]) ;;
 460 esac])])
 461
 462 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 463   x)   WINE_WARNING([$3]) ;;
 464   xno) ;;
 465   *)   AC_MSG_ERROR([$3
 466 This is an error since --with-$1 was requested.]) ;;
 467 esac])])
 468
 469 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 470   xno) ;;
 471   *)   AC_MSG_ERROR([$3
 472 Use the --without-$1 option if you really want this.]) ;;
 473 esac])])
 474
 475 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 476 if test "x$wine_notices != "x; then
 477     echo >&AS_MESSAGE_FD
 478     IFS="|"
 479     for msg in $wine_notices; do
 480         IFS="$ac_save_IFS"
 481         if test -n "$msg"; then
 482             AC_MSG_NOTICE([$msg])
 483         fi
 484     done
 485 fi
 486 IFS="|"
 487 for msg in $wine_warnings; do
 488     IFS="$ac_save_IFS"
 489     if test -n "$msg"; then
 490         echo >&2
 491         AC_MSG_WARN([$msg])
 492     fi
 493 done
 494 IFS="$ac_save_IFS"])
 495
 496 dnl Local Variables:
 497 dnl compile-command: "autoreconf --warnings=all"
 498 dnl End: