tools/winapi/winapi.pm

   1 #
   2 # Copyright 1999, 2000, 2001 Patrik Stridvall
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2.1 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  17 #
  18
  19 package winapi;
  20
  21 use strict;
  22
  23 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK);
  24 require Exporter;
  25
  26 @ISA = qw(Exporter);
  27 @EXPORT = qw();
  28 @EXPORT_OK = qw($win16api $win32api @winapis);
  29
  30 use vars qw($win16api $win32api @winapis);
  31
  32 use config qw($current_dir $wine_dir $winapi_dir);
  33 use options qw($options);
  34 use output qw($output);
  35
  36 use vars qw($modules);
  37
  38 sub found_shared_internal_function($$);
  39 sub function_external_calling_convention_in_module($$$);
  40 sub function_internal_module($$);
  41 sub is_function_stub_in_module($$$);
  42 sub new($$$);
  43 sub parse_api_file($$);
  44 sub parse_spec_file($$);
  45
  46 sub import(@) {
  47     $Exporter::ExportLevel++;
  48     Exporter::import(@_);
  49     $Exporter::ExportLevel--;
  50
  51     if (defined($modules) && defined($win16api) && defined($win32api)) {
  52         return;
  53     }
  54
  55     require modules;
  56     import modules qw($modules);
  57
  58     my @spec_files16 = $modules->allowed_spec_files16;
  59     $win16api = 'winapi'->new("win16", \@spec_files16);
  60
  61     my @spec_files32 = $modules->allowed_spec_files32;
  62     $win32api = 'winapi'->new("win32", \@spec_files32);
  63
  64     @winapis = ($win16api, $win32api);
  65
  66     for my $internal_name ($win32api->all_internal_functions) {
  67         my $module16 = $win16api->function_internal_module($internal_name);
  68         my $module32 = $win16api->function_internal_module($internal_name);
  69         if(defined($module16) &&
  70            !$win16api->is_function_stub_in_module($module16, $internal_name) &&
  71            !$win32api->is_function_stub_in_module($module32, $internal_name))
  72         {
  73             $win16api->found_shared_internal_function($internal_name);
  74             $win32api->found_shared_internal_function($internal_name);
  75         }
  76     }
  77 }
  78
  79
  80 sub new($$$) {
  81     my $proto = shift;
  82     my $class = ref($proto) || $proto;
  83     my $self  = {};
  84     bless ($self, $class);
  85
  86     my $name = \${$self->{NAME}};
  87     my $function_forward = \%{$self->{FUNCTION_FORWARD}};
  88     my $function_internal_name = \%{$self->{FUNCTION_INTERNAL_NAME}};
  89     my $function_module = \%{$self->{FUNCTION_MODULE}};
  90
  91     $$name = shift;
  92     my $refspec_files = shift;
  93
  94     foreach my $file (@$refspec_files) {
  95         $self->parse_spec_file("$wine_dir/$file");
  96     }
  97
  98     $self->parse_api_file("$$name.api");
  99
 100     foreach my $module (sort(keys(%$function_forward))) {
 101         foreach my $external_name (sort(keys(%{$$function_forward{$module}}))) {
 102             (my $forward_module, my $forward_external_name) = @{$$function_forward{$module}{$external_name}};
 103             my $forward_internal_name = $$function_internal_name{$forward_external_name};
 104             if(defined($forward_internal_name)) {
 105                 $$function_module{$forward_internal_name} .= " & $module";
 106             }
 107         }
 108     }
 109
 110     return $self;
 111 }
 112
 113 sub win16api() {
 114     return $win16api;
 115 }
 116
 117 sub win32api() {
 118     return $win32api;
 119 }
 120
 121 sub parse_api_file($$) {
 122     my $self = shift;
 123
 124     my $allowed_kind = \%{$self->{ALLOWED_KIND}};
 125     my $allowed_modules = \%{$self->{ALLOWED_MODULES}};
 126     my $allowed_modules_limited = \%{$self->{ALLOWED_MODULES_LIMITED}};
 127     my $allowed_modules_unlimited = \%{$self->{ALLOWED_MODULES_UNLIMITED}};
 128     my $translate_argument = \%{$self->{TRANSLATE_ARGUMENT}};
 129     my $type_format = \%{$self->{TYPE_FORMAT}};
 130
 131     my $file = shift;
 132
 133     my $module;
 134     my $kind;
 135     my $format;
 136     my $forbidden = 0;
 137
 138     $output->lazy_progress("$file");
 139
 140     open(IN, "< $winapi_dir/$file") || die "$winapi_dir/$file: $!\n";
 141     $/ = "\n";
 142     my $linenum=0;
 143     while(<IN>) {
 144         $linenum++;
 145         s/^\s*?(.*?)\s*$/$1/; # remove whitespace at begin and end of line
 146         s/^(.*?)\s*#.*$/$1/;  # remove comments
 147         /^$/ && next;         # skip empty lines
 148
 149         if(/^%%(\S+)$/) {
 150             $module = $1;
 151             $module =~ s/\.dll$//; # FIXME: Kludge
 152         } elsif(!$modules->is_allowed_module($module)) {
 153             # Nothing
 154         } elsif(s/^%(\S+)\s*//) {
 155             $kind = $1;
 156             $format = undef;
 157             $forbidden = 0;
 158
 159             $$allowed_kind{$kind} = 1;
 160             if(/^--forbidden/) {
 161                 $forbidden = 1;
 162             } elsif(/^--format=(\".*?\"|\S*)/) {
 163                 $format = $1;
 164                 $format =~ s/^\"(.*?)\"$/$1/;
 165             }
 166
 167             if(!defined($format)) {
 168                 if($kind eq "long") {
 169                     $format  = "%d|%u|%x|%X|";
 170                     $format .= "%hd|%hu|%hx|%hX|";
 171                     $format .= "%ld|%lu|%lx|%lX|";
 172                     $format .= "%04x|%04X|0x%04x|0x%04X|";
 173                     $format .= "%08x|%08X|0x%08x|0x%08X|";
 174                     $format .= "%08lx|%08lX|0x%08lx|0x%08lX";
 175                 } elsif($kind eq "longlong") {
 176                     $format = "%lld";
 177                 } elsif($kind eq "ptr") {
 178                     $format = "%p";
 179                 } elsif($kind eq "segptr") {
 180                     $format = "%p";
 181                 } elsif($kind eq "str") {
 182                     $format = "%p|%s";
 183                 } elsif($kind eq "wstr") {
 184                     $format = "%p|%s";
 185                 } elsif($kind eq "word") {
 186                     $format  = "%d|%u|%x|%X|";
 187                     $format .= "%hd|%hu|%hx|%hX|";
 188                     $format .= "%04x|%04X|0x%04x|0x%04X";
 189                 } else {
 190                     $format = "<unknown>";
 191                 }
 192             }
 193         } elsif(defined($kind)) {
 194             my $type = $_;
 195             if ($type =~ /\blong\b/)
 196             {
 197                 $output->write("$file:$linenum: type ($type) is not Win64 compatible\n");
 198             }
 199             if(!$forbidden) {
 200                 if(defined($module)) {
 201                     if($$allowed_modules_unlimited{$type}) {
 202                         $output->write("$file:$linenum: type ($type) already specified as an unlimited type\n");
 203                     } elsif(!$$allowed_modules{$type}{$module}) {
 204                         $$allowed_modules{$type}{$module} = 1;
 205                         $$allowed_modules_limited{$type} = 1;
 206                     } else {
 207                         $output->write("$file:$linenum: type ($type) already specified\n");
 208                     }
 209                 } else {
 210                     $$allowed_modules_unlimited{$type} = 1;
 211                 }
 212             } else {
 213                 $$allowed_modules_limited{$type} = 1;
 214             }
 215             if(defined($$translate_argument{$type}) && $$translate_argument{$type} ne $kind) {
 216                 $output->write("$file:$linenum: type ($type) respecified as different kind ($kind != $$translate_argument{$type})\n");
 217             } else {
 218                 $$translate_argument{$type} = $kind;
 219             }
 220
 221             $$type_format{$module}{$type} = $format;
 222         } else {
 223             $output->write("$file:$linenum: file must begin with %<type> statement\n");
 224             exit 1;
 225         }
 226     }
 227     close(IN);
 228 }
 229
 230 sub parse_spec_file($$) {
 231     my $self = shift;
 232
 233     my $function_internal_arguments = \%{$self->{FUNCTION_INTERNAL_ARGUMENTS}};
 234     my $function_external_arguments = \%{$self->{FUNCTION_EXTERNAL_ARGUMENTS}};
 235     my $function_internal_ordinal = \%{$self->{FUNCTION_INTERNAL_ORDINAL}};
 236     my $function_external_ordinal = \%{$self->{FUNCTION_EXTERNAL_ORDINAL}};
 237     my $function_internal_calling_convention = \%{$self->{FUNCTION_INTERNAL_CALLING_CONVENTION}};
 238     my $function_external_calling_convention = \%{$self->{FUNCTION_EXTERNAL_CALLING_CONVENTION}};
 239     my $function_internal_name = \%{$self->{FUNCTION_INTERNAL_NAME}};
 240     my $function_external_name = \%{$self->{FUNCTION_EXTERNAL_NAME}};
 241     my $function_forward = \%{$self->{FUNCTION_FORWARD}};
 242     my $function_internal_module = \%{$self->{FUNCTION_INTERNAL_MODULE}};
 243     my $function_external_module = \%{$self->{FUNCTION_EXTERNAL_MODULE}};
 244     my $function_wine_extension = \%{$self->{FUNCTION_WINE_EXTENSION}};
 245     my $modules = \%{$self->{MODULES}};
 246     my $module_files = \%{$self->{MODULE_FILES}};
 247     my $module_external_calling_convention = \%{$self->{MODULE_EXTERNAL_CALLING_CONVENTION}};
 248
 249     my $file = shift;
 250     $file =~ s%^\./%%;
 251
 252     my %ordinals;
 253     my $module;
 254     my $wine_extension = 0;
 255
 256     $output->lazy_progress("$file");
 257
 258     $module = $file;
 259     $module =~ s/^.*?([^\/]*)\.spec$/$1/;
 260
 261     open(IN, "< $file") || die "$file: $!\n";
 262     $/ = "\n";
 263     my $header = 1;
 264     my $lookahead = 0;
 265     while($lookahead || defined($_ = <IN>)) {
 266         $lookahead = 0;
 267         s/^\s*(.*?)\s*$/$1/;
 268         if(s/^(.*?)\s*\#\s*(.*)\s*$/$1/) {
 269             my $comment = $2;
 270             if ($comment =~ /^Wine/i) { # FIXME: Kludge
 271                 $wine_extension = 1;
 272             }
 273         }
 274         /^$/ && next;
 275
 276         if($header)  {
 277             if(/^\d+|@/) { $header = 0; $lookahead = 1; }
 278             next;
 279         }
 280
 281         my $ordinal;
 282         my $ARCHES="alpha|i386|powerpc|sparc|x86_64";
 283         if(/^(\d+|@)\s+
 284            (pascal|stdcall|cdecl|varargs)\s+
 285            ((?:(?:-arch=(?:$ARCHES)(?:,(?:$ARCHES))*|-noname|-norelay|-i386|-ret16|-ret64|-register|-interrupt|-private)\s+)*)(\S+)\s*\(\s*(.*?)\s*\)\s*(\S*)$/x)
 286         {
 287             my $calling_convention = $2;
 288             my $flags = $3;
 289             my $external_name = $4;
 290             my $arguments = $5;
 291             my $internal_name = $6;
 292
 293             $ordinal = $1;
 294
 295             $flags =~ s/\s+/ /g;
 296
 297             if (!$internal_name)
 298             {
 299                 $internal_name = ($flags =~ /-register/ ? "__regs_" : "") . $external_name;
 300             }
 301
 302             if($flags =~ /-noname/) {
 303                 # $external_name = "@";
 304             }
 305
 306             if($flags =~ /(?:-register|-interrupt)/) {
 307                 if($arguments) { $arguments .= " "; }
 308                 $arguments .= "ptr";
 309                 $calling_convention .= " -register";
 310             }
 311             if($flags =~ /(?:-i386)/) {
 312                 $calling_convention .= " -i386";
 313             }
 314
 315             if ($internal_name =~ /^(.*?)\.(.*?)$/) {
 316                 my $forward_module = lc($1);
 317                 my $forward_name = $2;
 318
 319                 if (0) {
 320                     $calling_convention .= " -forward";
 321                 } else {
 322                     $calling_convention = "forward";
 323                 }
 324
 325                 $$function_forward{$module}{$external_name} = [$forward_module, $forward_name];
 326             }
 327
 328             if($external_name ne "@") {
 329                 $$module_external_calling_convention{$module}{$external_name} = $calling_convention;
 330             } else {
 331                 $$module_external_calling_convention{$module}{"\@$ordinal"} = $calling_convention;
 332             }
 333             if(!$$function_internal_name{$external_name}) {
 334                 $$function_internal_name{$external_name} = $internal_name;
 335             } else {
 336                 $$function_internal_name{$external_name} .= " & $internal_name";
 337             }
 338             if(!$$function_external_name{$internal_name}) {
 339                 $$function_external_name{$internal_name} = $external_name;
 340             } else {
 341                 $$function_external_name{$internal_name} .= " & $external_name";
 342             }
 343             $$function_internal_arguments{$internal_name} = $arguments;
 344             $$function_external_arguments{$external_name} = $arguments;
 345             if(!$$function_internal_ordinal{$internal_name}) {
 346                 $$function_internal_ordinal{$internal_name} = $ordinal;
 347             } else {
 348                 $$function_internal_ordinal{$internal_name} .= " & $ordinal";
 349             }
 350             if(!$$function_external_ordinal{$external_name}) {
 351                 $$function_external_ordinal{$external_name} = $ordinal;
 352             } else {
 353                 $$function_external_ordinal{$external_name} .= " & $ordinal";
 354             }
 355             $$function_internal_calling_convention{$internal_name} = $calling_convention;
 356             $$function_external_calling_convention{$external_name} = $calling_convention;
 357             if(!$$function_internal_module{$internal_name}) {
 358                 $$function_internal_module{$internal_name} = "$module";
 359             } else {
 360                 $$function_internal_module{$internal_name} .= " & $module";
 361             }
 362             if(!$$function_external_module{$external_name}) {
 363                 $$function_external_module{$external_name} = "$module";
 364             } else {
 365                 $$function_external_module{$external_name} .= " & $module";
 366             }
 367             $$function_wine_extension{$module}{$external_name} = $wine_extension;
 368
 369             if(0 && $options->spec_mismatch) {
 370                 if($external_name eq "@") {
 371                     if($internal_name !~ /^\U$module\E_$ordinal$/) {
 372                         $output->write("$file: $external_name: the internal name ($internal_name) mismatch\n");
 373                     }
 374                 } else {
 375                     my $name = $external_name;
 376
 377                     my $name1 = $name;
 378                     $name1 =~ s/^Zw/Nt/;
 379
 380                     my $name2 = $name;
 381                     $name2 =~ s/^(?:_|Rtl|k32|K32)//;
 382
 383                     my $name3 = $name;
 384                     $name3 =~ s/^INT_Int[0-9a-f]{2}Handler$/BUILTIN_DefaultIntHandler/;
 385
 386                     my $name4 = $name;
 387                     $name4 =~ s/^(VxDCall)\d$/$1/;
 388
 389                     # FIXME: This special case is because of a very ugly kludge that should be fixed IMHO
 390                     my $name5 = $name;
 391                     $name5 =~ s/^(.*?16)_(.*?)$/$1_fn$2/;
 392
 393                     if(uc($internal_name) ne uc($external_name) &&
 394                        $internal_name !~ /(\Q$name\E|\Q$name1\E|\Q$name2\E|\Q$name3\E|\Q$name4\E|\Q$name5\E)/)
 395                     {
 396                         $output->write("$file: $external_name: internal name ($internal_name) mismatch\n");
 397                     }
 398                 }
 399             }
 400         } elsif(/^(\d+|@)\s+stub(?:\s+(-arch=(?:$ARCHES)(?:,(?:$ARCHES))*|-noname|-norelay|-i386|-ret16|-ret64|-private))?\s+(\S+)$/) {
 401             $ordinal = $1;
 402
 403             my $flags = $2;
 404             my $external_name = $3;
 405
 406             $flags = "" if !defined($flags);
 407
 408             if($flags =~ /-noname/) {
 409                 # $external_name = "@";
 410             }
 411
 412             my $internal_name = $external_name;
 413
 414             if ($external_name ne "@") {
 415                 $$module_external_calling_convention{$module}{$external_name} = "stub";
 416             } else {
 417                 $$module_external_calling_convention{$module}{"\@$ordinal"} = "stub";
 418             }
 419             if(!$$function_internal_name{$external_name}) {
 420                 $$function_internal_name{$external_name} = $internal_name;
 421             } else {
 422                 $$function_internal_name{$external_name} .= " & $internal_name";
 423             }
 424             if(!$$function_external_name{$internal_name}) {
 425                 $$function_external_name{$internal_name} = $external_name;
 426             } else {
 427                 $$function_external_name{$internal_name} .= " & $external_name";
 428             }
 429             if(!$$function_internal_ordinal{$internal_name}) {
 430                 $$function_internal_ordinal{$internal_name} = $ordinal;
 431             } else {
 432                 $$function_internal_ordinal{$internal_name} .= " & $ordinal";
 433             }
 434             if(!$$function_external_ordinal{$external_name}) {
 435                 $$function_external_ordinal{$external_name} = $ordinal;
 436             } else {
 437                 $$function_external_ordinal{$external_name} .= " & $ordinal";
 438             }
 439             if(!$$function_internal_module{$internal_name}) {
 440                 $$function_internal_module{$internal_name} = "$module";
 441             } else { # if($$function_internal_module{$internal_name} !~ /$module/) {
 442                 $$function_internal_module{$internal_name} .= " & $module";
 443             }
 444             if(!$$function_external_module{$external_name}) {
 445                 $$function_external_module{$external_name} = "$module";
 446             } else { # if($$function_external_module{$external_name} !~ /$module/) {
 447                 $$function_external_module{$external_name} .= " & $module";
 448             }
 449         } elsif(/^(\d+|@)\s+extern(?:\s+(?:-norelay|-i386|-ret16|-ret64))?\s+(\S+)\s*(\S*)$/) {
 450             $ordinal = $1;
 451
 452             my $external_name = $2;
 453             my $internal_name = $3;
 454
 455             $internal_name = $external_name if !$internal_name;
 456
 457             if ($external_name ne "@") {
 458                 $$module_external_calling_convention{$module}{$external_name} = "extern";
 459             } else {
 460                 $$module_external_calling_convention{$module}{"\@$ordinal"} = "extern";
 461             }
 462         } elsif(/^(?:\d+|@)\s+(?:equate|variable)/) {
 463             # ignore
 464         } else {
 465             my $next_line = <IN>;
 466             if(!defined($next_line) || $next_line =~ /^\s*\d|@/) {
 467                 die "$file: $.: syntax error: '$_'\n";
 468             } else {
 469                 $_ .= $next_line;
 470                 $lookahead = 1;
 471             }
 472         }
 473
 474         if(defined($ordinal)) {
 475             if($ordinal ne "@" && $ordinals{$ordinal}) {
 476                 $output->write("$file: ordinal redefined: $_\n");
 477             }
 478             $ordinals{$ordinal}++;
 479         }
 480     }
 481     close(IN);
 482
 483     $$modules{$module}++;
 484
 485     $$module_files{$module} = $file;
 486 }
 487
 488 sub name($) {
 489     my $self = shift;
 490     my $name = \${$self->{NAME}};
 491
 492     return $$name;
 493 }
 494
 495 sub is_allowed_kind($$) {
 496     my $self = shift;
 497     my $allowed_kind = \%{$self->{ALLOWED_KIND}};
 498
 499     my $kind = shift;
 500     if(defined($kind)) {
 501         return $$allowed_kind{$kind};
 502     } else {
 503         return 0;
 504     }
 505
 506 }
 507
 508 sub allow_kind($$) {
 509     my $self = shift;
 510     my $allowed_kind = \%{$self->{ALLOWED_KIND}};
 511
 512     my $kind = shift;
 513
 514     $$allowed_kind{$kind}++;
 515 }
 516
 517 sub is_limited_type($$) {
 518     my $self = shift;
 519     my $allowed_modules_limited = \%{$self->{ALLOWED_MODULES_LIMITED}};
 520
 521     my $type = shift;
 522
 523     return $$allowed_modules_limited{$type};
 524 }
 525
 526 sub is_allowed_type_in_module($$) {
 527     my $self = shift;
 528     my $allowed_modules = \%{$self->{ALLOWED_MODULES}};
 529     my $allowed_modules_limited = \%{$self->{ALLOWED_MODULES_LIMITED}};
 530
 531     my $type = shift;
 532     my @modules = split(/ \& /, shift);
 533
 534     if(!$$allowed_modules_limited{$type}) { return 1; }
 535
 536     foreach my $module (@modules) {
 537         if($$allowed_modules{$type}{$module}) { return 1; }
 538     }
 539
 540     return 0;
 541 }
 542
 543 sub allow_type_in_module($$) {
 544     my $self = shift;
 545     my $allowed_modules = \%{$self->{ALLOWED_MODULES}};
 546
 547     my $type = shift;
 548     my @modules = split(/ \& /, shift);
 549
 550     foreach my $module (@modules) {
 551         $$allowed_modules{$type}{$module}++;
 552     }
 553 }
 554
 555 sub type_used_in_module($$) {
 556     my $self = shift;
 557     my $used_modules = \%{$self->{USED_MODULES}};
 558
 559     my $type = shift;
 560     my @modules = split(/ \& /, shift);
 561
 562     foreach my $module (@modules) {
 563         $$used_modules{$type}{$module} = 1;
 564     }
 565
 566     return ();
 567 }
 568
 569 sub types_not_used($) {
 570     my $self = shift;
 571     my $used_modules = \%{$self->{USED_MODULES}};
 572     my $allowed_modules = \%{$self->{ALLOWED_MODULES}};
 573
 574     my $not_used;
 575     foreach my $type (sort(keys(%$allowed_modules))) {
 576         foreach my $module (sort(keys(%{$$allowed_modules{$type}}))) {
 577             if(!$$used_modules{$type}{$module}) {
 578                 $$not_used{$module}{$type} = 1;
 579             }
 580         }
 581     }
 582     return $not_used;
 583 }
 584
 585 sub types_unlimited_used_in_modules($) {
 586     my $self = shift;
 587
 588     my $used_modules = \%{$self->{USED_MODULES}};
 589     my $allowed_modules = \%{$self->{ALLOWED_MODULES}};
 590     my $allowed_modules_unlimited = \%{$self->{ALLOWED_MODULES_UNLIMITED}};
 591
 592     my $used_types;
 593     foreach my $type (sort(keys(%$allowed_modules_unlimited))) {
 594         my $count = 0;
 595         my @modules = ();
 596         foreach my $module (sort(keys(%{$$used_modules{$type}}))) {
 597             $count++;
 598             push @modules, $module;
 599         }
 600         if($count) {
 601             foreach my $module (@modules) {
 602               $$used_types{$type}{$module} = 1;
 603             }
 604         }
 605     }
 606     return $used_types;
 607 }
 608
 609 sub translate_argument($$) {
 610     my $self = shift;
 611     my $translate_argument = \%{$self->{TRANSLATE_ARGUMENT}};
 612
 613     my $type = shift;
 614
 615     return $$translate_argument{$type};
 616 }
 617
 618 sub declare_argument($$$) {
 619     my $self = shift;
 620     my $translate_argument = \%{$self->{TRANSLATE_ARGUMENT}};
 621
 622     my $type = shift;
 623     my $kind = shift;
 624
 625     $$translate_argument{$type} = $kind;
 626 }
 627
 628 sub all_declared_types($) {
 629     my $self = shift;
 630     my $translate_argument = \%{$self->{TRANSLATE_ARGUMENT}};
 631
 632     return sort(keys(%$translate_argument));
 633 }
 634
 635 sub is_allowed_type_format($$$$) {
 636     my $self = shift;
 637     my $type_format = \%{$self->{TYPE_FORMAT}};
 638
 639     my $module = shift;
 640     my $type = shift;
 641     my $format = shift;
 642
 643     my $formats;
 644
 645     if(defined($module) && defined($type)) {
 646         local $_;
 647         foreach (split(/ & /, $module)) {
 648             if(defined($formats)) {
 649                 $formats .= "|";
 650             } else {
 651                 $formats = "";
 652             }
 653             if(defined($$type_format{$_}{$type})) {
 654                 $formats .= $$type_format{$_}{$type};
 655             }
 656         }
 657     }
 658
 659     if(defined($formats)) {
 660         local $_;
 661         foreach (split(/\|/, $formats)) {
 662             if($_ eq $format) {
 663                 return 1;
 664             }
 665         }
 666     }
 667
 668     return 0;
 669 }
 670
 671 sub all_modules($) {
 672     my $self = shift;
 673     my $modules = \%{$self->{MODULES}};
 674
 675     return sort(keys(%$modules));
 676 }
 677
 678 sub is_module($$) {
 679     my $self = shift;
 680     my $modules = \%{$self->{MODULES}};
 681
 682     my $name = shift;
 683
 684     return $$modules{$name};
 685 }
 686
 687 sub module_file($$) {
 688     my $self = shift;
 689
 690     my $module = shift;
 691
 692     my $module_files = \%{$self->{MODULE_FILES}};
 693
 694     return $$module_files{$module};
 695 }
 696
 697 sub all_internal_functions($) {
 698     my $self = shift;
 699     my $function_internal_calling_convention = \%{$self->{FUNCTION_INTERNAL_CALLING_CONVENTION}};
 700
 701     return sort(keys(%$function_internal_calling_convention));
 702 }
 703
 704 sub all_internal_functions_in_module($$) {
 705     my $self = shift;
 706     my $function_internal_calling_convention = \%{$self->{FUNCTION_INTERNAL_CALLING_CONVENTION}};
 707     my $function_internal_module = \%{$self->{FUNCTION_INTERNAL_MODULE}};
 708
 709     my $module = shift;
 710
 711     my @names;
 712     foreach my $name (keys(%$function_internal_calling_convention)) {
 713         if($$function_internal_module{$name} eq $module) {
 714             push @names, $name;
 715         }
 716     }
 717
 718     return sort(@names);
 719 }
 720
 721 sub all_external_functions($) {
 722     my $self = shift;
 723     my $function_external_name = \%{$self->{FUNCTION_EXTERNAL_NAME}};
 724
 725     return sort(keys(%$function_external_name));
 726 }
 727
 728 sub all_external_functions_in_module($$) {
 729     my $self = shift;
 730     my $function_external_name = \%{$self->{FUNCTION_EXTERNAL_NAME}};
 731     my $function_external_module = \%{$self->{FUNCTION_EXTERNAL_MODULE}};
 732
 733     my $module = shift;
 734
 735     my @names;
 736     foreach my $name (keys(%$function_external_name)) {
 737         if($$function_external_module{$name} eq $module) {
 738             push @names, $name;
 739         }
 740     }
 741
 742     return sort(@names);
 743 }
 744
 745 sub all_functions_in_module($$) {
 746     my $self = shift;
 747     my $module_external_calling_convention = \%{$self->{MODULE_EXTERNAL_CALLING_CONVENTION}};
 748
 749     my $module = shift;
 750
 751     return sort(keys(%{$$module_external_calling_convention{$module}}));
 752 }
 753
 754 sub all_broken_forwards($) {
 755     my $self = shift;
 756     my $function_forward = \%{$self->{FUNCTION_FORWARD}};
 757
 758     my @broken_forwards = ();
 759     foreach my $module (sort(keys(%$function_forward))) {
 760         foreach my $external_name (sort(keys(%{$$function_forward{$module}}))) {
 761             (my $forward_module, my $forward_external_name) = @{$$function_forward{$module}{$external_name}};
 762
 763             my $forward_external_calling_convention =
 764                 $self->function_external_calling_convention_in_module($forward_module, $forward_external_name);
 765
 766             if(!defined($forward_external_calling_convention)) {
 767                 push @broken_forwards, [$module, $external_name, $forward_module, $forward_external_name];
 768             }
 769         }
 770     }
 771     return @broken_forwards;
 772 }
 773
 774
 775 sub function_internal_ordinal($$) {
 776     my $self = shift;
 777     my $function_internal_ordinal = \%{$self->{FUNCTION_INTERNAL_ORDINAL}};
 778
 779     my $name = shift;
 780
 781     return $$function_internal_ordinal{$name};
 782 }
 783
 784 sub function_external_ordinal($$) {
 785     my $self = shift;
 786     my $function_external_ordinal = \%{$self->{FUNCTION_EXTERNAL_ORDINAL}};
 787
 788     my $name = shift;
 789
 790     return $$function_external_ordinal{$name};
 791 }
 792
 793 sub function_internal_calling_convention($$) {
 794     my $self = shift;
 795     my $function_internal_calling_convention = \%{$self->{FUNCTION_INTERNAL_CALLING_CONVENTION}};
 796
 797     my $name = shift;
 798
 799     return $$function_internal_calling_convention{$name};
 800 }
 801
 802 sub function_external_calling_convention($$) {
 803     my $self = shift;
 804     my $function_external_calling_convention = \%{$self->{FUNCTION_EXTERNAL_CALLING_CONVENTION}};
 805
 806     my $name = shift;
 807
 808     return $$function_external_calling_convention{$name};
 809 }
 810
 811 sub function_external_calling_convention_in_module($$$) {
 812     my $self = shift;
 813     my $module_external_calling_convention = \%{$self->{MODULE_EXTERNAL_CALLING_CONVENTION}};
 814
 815     my $module = shift;
 816     my $name = shift;
 817
 818     return $$module_external_calling_convention{$module}{$name};
 819 }
 820
 821 sub function_internal_name($$) {
 822     my $self = shift;
 823     my $function_internal_name = \%{$self->{FUNCTION_INTERNAL_NAME}};
 824
 825     my $name = shift;
 826
 827     return $$function_internal_name{$name};
 828 }
 829
 830 sub function_external_name($$) {
 831     my $self = shift;
 832     my $function_external_name = \%{$self->{FUNCTION_EXTERNAL_NAME}};
 833
 834     my $name = shift;
 835
 836     return $$function_external_name{$name};
 837 }
 838
 839 sub function_forward_final_destination($$$) {
 840     my $self = shift;
 841
 842     my $function_forward = \%{$self->{FUNCTION_FORWARD}};
 843
 844     my $module = shift;
 845     my $name = shift;
 846
 847     my $forward_module = $module;
 848     my $forward_name = $name;
 849     while(defined(my $forward = $$function_forward{$forward_module}{$forward_name})) {
 850         ($forward_module, $forward_name) = @$forward;
 851     }
 852
 853     return ($forward_module, $forward_name);
 854 }
 855
 856 sub is_function($$) {
 857     my $self = shift;
 858     my $function_internal_calling_convention = \%{$self->{FUNCTION_INTERNAL_CALLING_CONVENTION}};
 859
 860     my $name = shift;
 861
 862     return $$function_internal_calling_convention{$name};
 863 }
 864
 865 sub all_shared_internal_functions($$) {
 866     my $self = shift;
 867     my $function_shared = \%{$self->{FUNCTION_SHARED}};
 868
 869     return sort(keys(%$function_shared));
 870 }
 871
 872 sub is_shared_internal_function($$) {
 873     my $self = shift;
 874     my $function_shared = \%{$self->{FUNCTION_SHARED}};
 875
 876     my $name = shift;
 877
 878     return $$function_shared{$name};
 879 }
 880
 881 sub found_shared_internal_function($$) {
 882     my $self = shift;
 883     my $function_shared = \%{$self->{FUNCTION_SHARED}};
 884
 885     my $name = shift;
 886
 887     $$function_shared{$name} = 1;
 888 }
 889
 890 sub function_internal_arguments($$) {
 891     my $self = shift;
 892     my $function_internal_arguments = \%{$self->{FUNCTION_INTERNAL_ARGUMENTS}};
 893
 894     my $name = shift;
 895
 896     return $$function_internal_arguments{$name};
 897 }
 898
 899 sub function_external_arguments($$) {
 900     my $self = shift;
 901     my $function_external_arguments = \%{$self->{FUNCTION_EXTERNAL_ARGUMENTS}};
 902
 903     my $name = shift;
 904
 905     return $$function_external_arguments{$name};
 906 }
 907
 908 sub function_internal_module($$) {
 909     my $self = shift;
 910     my $function_internal_module = \%{$self->{FUNCTION_INTERNAL_MODULE}};
 911
 912     my $name = shift;
 913
 914     return $$function_internal_module{$name};
 915 }
 916
 917 sub function_external_module($$) {
 918     my $self = shift;
 919     my $function_external_module = \%{$self->{FUNCTION_EXTERNAL_MODULE}};
 920
 921     my $name = shift;
 922
 923     return $$function_external_module{$name};
 924 }
 925
 926 sub function_wine_extension($$$) {
 927     my $self = shift;
 928     my $function_wine_extension = \%{$self->{FUNCTION_WINE_EXTENSION}};
 929
 930     my $module = shift;
 931     my $name = shift;
 932
 933     return $$function_wine_extension{$module}{$name};
 934 }
 935
 936 sub is_function_stub($$$) {
 937     my $self = shift;
 938     my $module_external_calling_convention = \%{$self->{MODULE_EXTERNAL_CALLING_CONVENTION}};
 939
 940     my $module = shift;
 941     my $name = shift;
 942
 943     if($$module_external_calling_convention{$module}{$name} eq "stub") {
 944         return 1;
 945     }
 946     return 0;
 947 }
 948
 949 sub is_function_stub_in_module($$$) {
 950     my $self = shift;
 951     my $module_external_calling_convention = \%{$self->{MODULE_EXTERNAL_CALLING_CONVENTION}};
 952
 953     my $module = shift;
 954     my $name = shift;
 955
 956     if(!defined($$module_external_calling_convention{$module}{$name})) {
 957         return 0;
 958     }
 959     return $$module_external_calling_convention{$module}{$name} eq "stub";
 960 }
 961
 962 ########################################################################
 963 # class methods
 964 #
 965
 966 sub _get_all_module_internal_ordinal($$) {
 967     my $winapi = shift;
 968     my $internal_name = shift;
 969
 970     my @entries = ();
 971
 972     my @name = (); {
 973         my $name = $winapi->function_external_name($internal_name);
 974         if(defined($name)) {
 975             @name = split(/ & /, $name);
 976         }
 977     }
 978
 979     my @module = (); {
 980         my $module = $winapi->function_internal_module($internal_name);
 981         if(defined($module)) {
 982             @module = split(/ & /, $module);
 983         }
 984     }
 985
 986     my @ordinal = (); {
 987         my $ordinal = $winapi->function_internal_ordinal($internal_name);
 988         if(defined($ordinal)) {
 989             @ordinal = split(/ & /, $ordinal);
 990         }
 991     }
 992
 993     my $name;
 994     my $module;
 995     my $ordinal;
 996     while(defined($name = shift @name) &&
 997           defined($module = shift @module) &&
 998           defined($ordinal = shift @ordinal))
 999     {
1000         push @entries, [$name, $module, $ordinal];
1001     }
1002
1003     return @entries;
1004 }
1005
1006 sub get_all_module_internal_ordinal16($) {
1007     return _get_all_module_internal_ordinal($win16api, $_[0]);
1008 }
1009
1010 sub get_all_module_internal_ordinal32($) {
1011     return _get_all_module_internal_ordinal($win32api, $_[0]);
1012 }
1013
1014 sub get_all_module_internal_ordinal($) {
1015     my @entries = ();
1016     foreach my $winapi (@winapis) {
1017         push @entries, _get_all_module_internal_ordinal($winapi, $_[0]);
1018     }
1019
1020     return @entries;
1021 }
1022
1023 sub _get_all_module_external_ordinal($$) {
1024     my $winapi = shift;
1025     my $external_name = shift;
1026
1027     my @entries = ();
1028
1029     my @name = (); {
1030         my $name = $winapi->function_internal_name($external_name);
1031         if(defined($name)) {
1032             @name = split(/ & /, $name);
1033         }
1034     }
1035
1036     my @module = (); {
1037         my $module = $winapi->function_external_module($external_name);
1038         if(defined($module)) {
1039             @module = split(/ & /, $module);
1040         }
1041     }
1042
1043     my @ordinal = (); {
1044         my $ordinal = $winapi->function_external_ordinal($external_name);
1045         if(defined($ordinal)) {
1046             @ordinal = split(/ & /, $ordinal);
1047         }
1048     }
1049
1050     my $name;
1051     my $module;
1052     my $ordinal;
1053     while(defined($name = shift @name) &&
1054           defined($module = shift @module) &&
1055           defined($ordinal = shift @ordinal))
1056     {
1057         push @entries, [$name, $module, $ordinal];
1058     }
1059
1060     return @entries;
1061 }
1062
1063 sub get_all_module_external_ordinal16($) {
1064     return _get_all_module_external_ordinal($win16api, $_[0]);
1065 }
1066
1067 sub get_all_module_external_ordinal32($) {
1068     return _get_all_module_external_ordinal($win32api, $_[0]);
1069 }
1070
1071 sub get_all_module_external_ordinal($) {
1072     my @entries = ();
1073     foreach my $winapi (@winapis) {
1074         push @entries, _get_all_module_external_ordinal($winapi, $_[0]);
1075     }
1076
1077     return @entries;
1078 }
1079
1080 1;