configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20 AC_ARG_ENABLE(tests, AC_HELP_STRING([--disable-tests],[do not build the testsuites]))
  21
  22 AC_CANONICAL_HOST
  23 case $host in
  24   x86_64*linux*)
  25     if test "x$enable_win64" != "xyes"
  26     then
  27       test -n "$CC" || CC="gcc -m32"
  28       test -n "$CXX"|| CXX="g++ -m32"
  29       test -n "$LD" || LD="ld -m elf_i386"
  30       test -n "$AS" || AS="as --32"
  31       host_cpu="i386"
  32     fi
  33     ;;
  34 esac
  35
  36 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  37 case $host_cpu in
  38   *i[[3456789]]86*)
  39     if test "x$enable_win16" != "xno"
  40     then
  41       enable_win16="yes"
  42     fi
  43     ;;
  44 esac
  45
  46 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  47 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  48 if test "x$enable_win16" != "xyes"
  49 then
  50   WIN16_FILES=""
  51   WIN16_INSTALL=""
  52 fi
  53
  54 dnl enable_tests is yes by default, but in some cases it's better to disable the testsuite
  55 if test "x$enable_tests" == "xno"
  56 then
  57   AC_SUBST(TESTSUBDIRS,"")
  58   AC_SUBST(WINETEST,"")
  59 else
  60   AC_SUBST(TESTSUBDIRS,"\$(TESTSUBDIRS)")
  61   AC_SUBST(WINETEST,"winetest")
  62 fi
  63
  64 dnl check for out of tree build with unclean source tree
  65 case "$srcdir" in
  66  .) ;;
  67  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  68       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  69 You need to run 'make distclean' in the source tree first.])
  70     fi ;;
  71 esac
  72
  73 dnl **** Check for some programs ****
  74
  75 AC_PROG_MAKE_SET
  76 AC_PROG_CC
  77 AC_PROG_CXX
  78 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  79 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  80
  81 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  82   [if test -z "$with_wine_tools"; then
  83      if test "$cross_compiling" = "yes"; then
  84        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  85      else
  86        wine_cv_toolsdir="\$(TOPOBJDIR)"
  87      fi
  88    elif test -d "$with_wine_tools/tools/winebuild"; then
  89      case $with_wine_tools in
  90        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  91        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  92      esac
  93    else
  94      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  95    fi])
  96 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  97
  98 AC_PATH_XTRA
  99
 100 dnl Check for flex
 101 AC_CHECK_PROGS(FLEX,flex,none)
 102 if test "$FLEX" = "none"
 103 then
 104   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 105 fi
 106
 107 dnl Check for bison
 108 AC_CHECK_PROGS(BISON,bison,none)
 109 if test "$BISON" = "none"
 110 then
 111   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 112 fi
 113
 114 AC_CHECK_TOOLS(AS,[gas as],as)
 115 AC_CHECK_TOOL(LD,ld,ld)
 116 AC_CHECK_TOOL(AR,ar,ar)
 117 AC_PROG_RANLIB
 118 AC_CHECK_TOOL(STRIP,strip,strip)
 119 AC_CHECK_TOOL(WINDRES,windres,false)
 120 AC_PROG_LN_S
 121 WINE_PROG_LN
 122 AC_PROG_EGREP
 123 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 124 AC_PROG_INSTALL
 125 dnl Prepend src dir to install path dir if it's a relative path
 126 case "$INSTALL" in
 127   [[\\/$]]* | ?:[[\\/]]* ) ;;
 128   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 129 esac
 130
 131 dnl Check for lint
 132 AC_CHECK_PROGS(LINT, lclint lint)
 133 if test "$LINT" = "lint"
 134 then
 135   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 136   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 137 fi
 138 AC_SUBST(LINT)
 139 AC_SUBST(LINTFLAGS)
 140
 141 dnl Check for various programs
 142 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 143 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 144
 145 case $host_cpu in
 146   *i[[3456789]]86*)
 147     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 148     ;;
 149 esac
 150
 151 dnl **** Check for some libraries ****
 152
 153 dnl Check for -li386 for NetBSD and OpenBSD
 154 AC_CHECK_LIB(i386,i386_set_ldt)
 155 dnl Check for -lossaudio for NetBSD
 156 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 157 dnl Check for -lpthread
 158 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 159
 160 AC_SUBST(XLIB,"")
 161 AC_SUBST(XFILES,"")
 162 AC_SUBST(OPENGLFILES,"")
 163 AC_SUBST(GLU32FILES,"")
 164 AC_SUBST(OPENGL_LIBS,"")
 165 AC_SUBST(QUARTZFILES,"")
 166
 167 dnl **** Check for header files ****
 168
 169 AC_CHECK_HEADERS(\
 170         AudioUnit/AudioUnit.h \
 171         Carbon/Carbon.h \
 172         CoreAudio/CoreAudio.h \
 173         DiskArbitration/DiskArbitration.h \
 174         IOKit/IOKitLib.h \
 175         alsa/asoundlib.h \
 176         arpa/inet.h \
 177         arpa/nameser.h \
 178         asm/types.h \
 179         capi20.h \
 180         cups/cups.h \
 181         curses.h \
 182         direct.h \
 183         dlfcn.h \
 184         elf.h \
 185         float.h \
 186         fontconfig/fontconfig.h \
 187         getopt.h \
 188         ieeefp.h \
 189         io.h \
 190         jack/jack.h \
 191         jpeglib.h \
 192         lber.h \
 193         lcms.h \
 194         lcms/lcms.h \
 195         ldap.h \
 196         libaudioio.h \
 197         link.h \
 198         linux/cdrom.h \
 199         linux/compiler.h \
 200         linux/hdreg.h \
 201         linux/input.h \
 202         linux/ioctl.h \
 203         linux/joystick.h \
 204         linux/major.h \
 205         linux/param.h \
 206         linux/serial.h \
 207         linux/ucdrom.h \
 208         mach/mach.h \
 209         mach/machine.h \
 210         machine/cpu.h \
 211         machine/limits.h \
 212         machine/soundcard.h \
 213         mntent.h \
 214         ncurses.h \
 215         netdb.h \
 216         netinet/in.h \
 217         netinet/in_systm.h \
 218         netinet/tcp.h \
 219         netinet/tcp_fsm.h \
 220         openssl/err.h \
 221         openssl/ssl.h \
 222         png.h \
 223         poll.h \
 224         process.h \
 225         pthread.h \
 226         pwd.h \
 227         regex.h \
 228         sched.h \
 229         scsi/scsi.h \
 230         scsi/scsi_ioctl.h \
 231         scsi/sg.h \
 232         soundcard.h \
 233         stdint.h \
 234         strings.h \
 235         sys/asoundlib.h \
 236         sys/cdio.h \
 237         sys/elf32.h \
 238         sys/epoll.h \
 239         sys/errno.h \
 240         sys/event.h \
 241         sys/exec_elf.h \
 242         sys/filio.h \
 243         sys/ioctl.h \
 244         sys/ipc.h \
 245         sys/limits.h \
 246         sys/link.h \
 247         sys/lwp.h \
 248         sys/mman.h \
 249         sys/modem.h \
 250         sys/msg.h \
 251         sys/mtio.h \
 252         sys/param.h \
 253         sys/poll.h \
 254         sys/prctl.h \
 255         sys/ptrace.h \
 256         sys/reg.h \
 257         sys/resource.h \
 258         sys/scsiio.h \
 259         sys/shm.h \
 260         sys/signal.h \
 261         sys/socket.h \
 262         sys/socketvar.h \
 263         sys/sockio.h \
 264         sys/soundcard.h \
 265         sys/statvfs.h \
 266         sys/strtio.h \
 267         sys/syscall.h \
 268         sys/sysctl.h \
 269         sys/time.h \
 270         sys/times.h \
 271         sys/uio.h \
 272         sys/un.h \
 273         sys/vm86.h \
 274         sys/wait.h \
 275         syscall.h \
 276         termios.h \
 277         unistd.h \
 278         utime.h \
 279         valgrind/memcheck.h
 280 )
 281 AC_HEADER_STAT()
 282
 283 dnl **** Checks for headers that depend on other ones ****
 284
 285 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 286     [#include <sys/types.h>
 287      #if HAVE_SYS_PARAM_H
 288      # include <sys/param.h>
 289      #endif])
 290
 291 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 292     [#include <sys/types.h>
 293      #if HAVE_SYS_SOCKET_H
 294      # include <sys/socket.h>
 295      #endif])
 296      #if HAVE_SYS_SOCKETVAR_H
 297      # include <sys/socketvar.h>
 298      #endif
 299
 300 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 301     [#include <sys/types.h>
 302      #if HAVE_SYS_SOCKET_H
 303      # include <sys/socket.h>
 304      #endif
 305      #if HAVE_SYS_SOCKETVAR_H
 306      # include <sys/socketvar.h>
 307      #endif
 308      #if HAVE_NETINET_IN_H
 309      # include <netinet/in.h>
 310      #endif
 311      #ifdef HAVE_NETINET_TCP_H
 312      # include <netinet/tcp.h>
 313      #endif])
 314
 315 AC_CHECK_HEADERS([linux/ipx.h],,,
 316     [#include <sys/types.h>
 317      #ifdef HAVE_ASM_TYPES_H
 318      # include <asm/types.h>
 319      #endif
 320      #if HAVE_SYS_SOCKET_H
 321      # include <sys/socket.h>
 322      #endif])
 323
 324 AC_CHECK_HEADERS([resolv.h],,,
 325     [#include <sys/types.h>
 326      #if HAVE_SYS_SOCKET_H
 327      # include <sys/socket.h>
 328      #endif
 329      #if HAVE_NETINET_IN_H
 330      # include <netinet/in.h>
 331      #endif
 332      #if HAVE_ARPA_NAMESER_H
 333      # include <arpa/nameser.h>
 334      #endif])
 335
 336 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 337
 338 AC_CHECK_HEADERS([sys/thr.h],,,
 339 [#include <sys/types.h>
 340 #if HAVE_UCONTEXT_H
 341 #include <ucontext.h>
 342 #endif])
 343
 344 AC_CHECK_HEADERS([pthread_np.h],,,
 345 [#ifdef HAVE_PTHREAD_H
 346 #include <pthread.h>
 347 #endif])
 348
 349 AC_CHECK_HEADERS([linux/videodev.h],,,
 350 [#ifdef HAVE_SYS_TIME_H
 351 #include <sys/time.h>
 352 #endif
 353 #include <sys/types.h>
 354 #ifdef HAVE_ASM_TYPES_H
 355 #include <asm/types.h>
 356 #endif])
 357
 358 dnl Check for broken kernel header that doesn't define __user
 359 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 360
 361 dnl **** Check for working dll ****
 362
 363 AC_SUBST(DLLEXT,"")
 364 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 365 AC_SUBST(LDSHARED,"")
 366 AC_SUBST(LDDLLFLAGS,"")
 367 AC_SUBST(LIBEXT,"so")
 368 AC_SUBST(IMPLIBEXT,"def")
 369 AC_SUBST(LDRPATH_INSTALL,"")
 370 AC_SUBST(LDRPATH_LOCAL,"")
 371 WINE_PATH_LDD
 372
 373 case $host_os in
 374   cygwin*|mingw32*)
 375     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 376     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 377     AC_CHECK_TOOL(MINGWAR,ar,false)
 378     if test "$DLLWRAP" = "false"; then
 379       LIBEXT="a"
 380     else
 381       dnl FIXME - check whether dllwrap works correctly...
 382       LIBEXT="dll"
 383     fi
 384     IMPLIBEXT="a"
 385     dnl We can't build 16-bit NE dlls
 386     WIN16_FILES=""
 387     WIN16_INSTALL=""
 388     ;;
 389   darwin*|macosx*)
 390     DLLEXT=".so"
 391     LIBEXT="dylib"
 392     DLLFLAGS="$DLLFLAGS -fPIC"
 393     LDDLLFLAGS="-bundle -multiply_defined suppress"
 394     LIBWINE_LDFLAGS="-multiply_defined suppress"
 395     LDSHARED="\$(CC) -dynamiclib"
 396     STRIP="$STRIP -x"
 397     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 398     dnl declare needed frameworks
 399     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 400     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 401     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 402     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 403     then
 404         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 405         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 406     fi
 407     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 408     then
 409         dnl CoreServices needed by AudioUnit
 410         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 411     fi
 412     case $host_cpu in
 413       *powerpc*)
 414         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 415         ;;
 416     esac
 417     dnl Enable quartz driver on Mac OS X
 418     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 419     then
 420         AC_SUBST(CARBONLIB,"-framework Carbon")
 421         QUARTZFILES='$(QUARTZFILES)'
 422     fi
 423     ;;
 424   *)
 425     DLLFLAGS="$DLLFLAGS -fPIC"
 426     DLLEXT=".so"
 427     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 428         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 429                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 430     if test "$ac_cv_c_dll_gnuelf" = "yes"
 431     then
 432       LDSHARED="\$(CC) -shared"
 433       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 434       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 435                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 436                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 437                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 438
 439       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 440
 441       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 442                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 443
 444       echo '{ global: *; };' >conftest.map
 445       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 446                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 447       rm -f conftest.map
 448
 449       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 450                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 451
 452       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 453                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 454                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 455           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 456                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 457                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 458
 459       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 460                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 461
 462       case $host_cpu in
 463         *i[[3456789]]86* | x86_64)
 464           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 465                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 466           ;;
 467       esac
 468
 469     else
 470       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 471           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 472                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 473       if test "$ac_cv_c_dll_unixware" = "yes"
 474       then
 475         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 476         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 477
 478       else
 479         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 480           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 481         if test "$ac_cv_c_dll_hpux" = "yes"
 482         then
 483           LIBEXT="sl"
 484           DLLEXT=".sl"
 485           LDDLLFLAGS="-shared -fPIC"
 486           LDSHARED="\$(CC) -shared"
 487         fi
 488       fi
 489     fi
 490
 491     dnl Check for cross compiler to build test programs
 492     AC_SUBST(CROSSTEST,"")
 493     if test "$cross_compiling" = "no"
 494     then
 495       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 496       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 497       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 498       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 499       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 500     fi
 501     ;;
 502 esac
 503
 504 if test "$LIBEXT" = "a"; then
 505   AC_MSG_ERROR(
 506 [could not find a way to build shared libraries.
 507 It is currently not possible to build Wine without shared library
 508 (.so) support to allow transparent switch between .so and .dll files.
 509 If you are using Linux, you will need a newer binutils.]
 510 )
 511 fi
 512
 513 dnl **** Check for X11 ****
 514
 515 if test "$have_x" = "yes"
 516 then
 517     XLIB="-lXext -lX11"
 518     ac_save_CPPFLAGS="$CPPFLAGS"
 519     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 520
 521     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 522     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 523
 524     dnl *** All of the following tests require X11/Xlib.h
 525     AC_CHECK_HEADERS([X11/Xlib.h \
 526                       X11/XKBlib.h \
 527                       X11/Xutil.h \
 528                       X11/Xcursor/Xcursor.h \
 529                       X11/extensions/shape.h \
 530                       X11/extensions/XInput.h \
 531                       X11/extensions/XShm.h \
 532                       X11/extensions/Xcomposite.h \
 533                       X11/extensions/Xinerama.h \
 534                       X11/extensions/Xrandr.h \
 535                       X11/extensions/Xrender.h \
 536                       X11/extensions/xf86vmode.h],,,
 537 [#ifdef HAVE_X11_XLIB_H
 538 # include <X11/Xlib.h>
 539 #endif
 540 #ifdef HAVE_X11_XUTIL_H
 541 # include <X11/Xutil.h>
 542 #endif])
 543
 544         dnl *** Check for X keyboard extension
 545         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 546         then
 547               AC_CHECK_LIB(X11, XkbQueryExtension,
 548               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 549               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 550         fi
 551
 552         dnl *** Check for X cursor
 553         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 554         then
 555             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 556         fi
 557
 558         dnl *** Check for X input extension
 559         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 560         then
 561             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 562         fi
 563
 564         dnl *** Check for X Shm extension
 565         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 566         then
 567               AC_CHECK_LIB(Xext, XShmQueryExtension,
 568               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 569               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 570         fi
 571         WINE_NOTICE_IF([test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],[XShm development files not found.
 572 Wine will be built without XShm support. (winex11.drv)])
 573
 574         dnl *** Check for X shape extension
 575         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 576         then
 577               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 578               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 579               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 580         fi
 581         WINE_NOTICE_IF([test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],[XShape development files not found.
 582 Wine will be built without XShape support. (winex11.drv)])
 583
 584         dnl *** Check for XFree86 VMODE extension
 585         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 586         then
 587                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 588                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 589                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 590                   ],,
 591                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 592         fi
 593         WINE_NOTICE_IF([test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],[Xxf86vm development files not found.
 594 Wine will be built without XF86 Vidmode support. (winex11.drv)])
 595
 596         dnl *** Check for Transform functions in Xrender
 597         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 598         then
 599             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 600               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 601                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 602                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 603                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 604
 605         fi
 606         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xrender" = "x"],[XRender development files not found.
 607 Wine will be built without XRender support. (winex11.drv)])
 608
 609         dnl *** Check for X RandR extension
 610         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 611         then
 612                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 613 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 614                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 615         fi
 616         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xrandr" = "x"],[XRandr development files not found.
 617 Wine will be built without XRandr support. (winex11.drv)])
 618
 619         dnl *** Check for Xinerama extension
 620         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 621         then
 622                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 623 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 624                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 625         fi
 626         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xinerama" = "x"],[Xinerama development files not found.
 627 Wine will be built without Xinerama support. (winex11.drv)])
 628
 629         dnl *** Check for X Composite extension
 630         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 631         then
 632             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 633         fi
 634         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xcomposite" = "x"],[XComposite development files not found.
 635 Wine will be built without XComposite support. (winex11.drv)])
 636
 637     dnl *** End of X11/Xlib.h check
 638
 639     dnl Check for the presence of OpenGL
 640     if test "x$with_opengl" != "xno"
 641     then
 642         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 643 [#ifdef HAVE_GL_GLX_H
 644 # include <GL/glx.h>
 645 #endif])
 646         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 647         then
 648             dnl Check for some problems due to old Mesa versions
 649             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 650               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 651                 [wine_cv_opengl_header_version_OK="yes"],
 652                 [wine_cv_opengl_header_version_OK="no"]))
 653
 654             if test "$wine_cv_opengl_header_version_OK" = "yes"
 655             then
 656                 dnl Check for the presence of the library
 657                 WINE_CHECK_SONAME(GL,glXCreateContext,
 658                              [OPENGL_LIBS="-lGL"
 659                              OPENGLFILES='$(OPENGLFILES)'
 660                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 661                              [if test -f /usr/X11R6/lib/libGL.a
 662                               then
 663                                   WINE_WARNING([/usr/X11R6/lib/libGL.a is present on your system.
 664 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
 665                               else
 666                                   WINE_WARNING([No OpenGL library found on this system.
 667 Wine will be build without OpenGL or Direct3D support.])
 668                               fi],
 669                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 670
 671                 dnl Check for GLU32 library.
 672                 AC_CHECK_LIB(GLU,gluLookAt,
 673                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 674                              GLU32FILES='$(GLU32FILES)']
 675                              ,,
 676                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 677              else
 678                  WINE_WARNING([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).
 679 Wine will be build without OpenGL or Direct3D support.])
 680              fi
 681          else
 682              WINE_WARNING([OpenGL development headers not found.
 683 Wine will be build without OpenGL or Direct3D support.])
 684          fi
 685     fi
 686
 687     dnl **** Check for NAS ****
 688     AC_SUBST(NASLIBS,"")
 689     AC_CHECK_HEADERS(audio/audiolib.h,
 690          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 691           AC_CHECK_LIB(audio,AuCreateFlow,
 692                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 693                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 694                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 695                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 696                           [$X_LIBS])
 697                        ],,
 698                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 699
 700     CPPFLAGS="$ac_save_CPPFLAGS"
 701     XFILES='$(XFILES)'
 702 else
 703     XLIB=""
 704     X_CFLAGS=""
 705     X_LIBS=""
 706     WINE_WARNING([X development files not found. Wine will be built
 707 without X support, which probably isn't what you want. You will need to install
 708 development packages of Xlib/Xfree86 at the very least.])
 709 fi
 710
 711 dnl **** Check for libxml2 ****
 712
 713 AC_SUBST(XML2LIBS,"")
 714 AC_SUBST(XML2INCL,"")
 715 AC_SUBST(XSLTLIBS,"")
 716 AC_SUBST(XSLTINCL,"")
 717 ac_save_CPPFLAGS="$CPPFLAGS"
 718 if test "$PKG_CONFIG" != "false"
 719 then
 720     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 721     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 722 else
 723     ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 724     ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 725 fi
 726 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 727 AC_CHECK_HEADERS(libxml/parser.h,
 728         [AC_CHECK_LIB(xml2, xmlParseMemory,
 729             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 730              XML2LIBS="$ac_xml_libs"
 731              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 732          AC_CHECK_LIB(xml2, xmlReadMemory,
 733             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 734          AC_CHECK_LIB(xml2, xmlNewDocPI,
 735             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 736     ])
 737 CPPFLAGS="$ac_save_CPPFLAGS"
 738 WINE_NOTICE_IF([test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],[libxml2 development files not found.
 739 Wine will be built without XML support. (msxml.dll)])
 740
 741 if test "$PKG_CONFIG" != "false"
 742 then
 743     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 744     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 745 else
 746     ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 747     ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 748 fi
 749 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 750 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 751         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 752             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 753              XSLTLIBS="$ac_xslt_libs"
 754              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 755         ],,
 756 [#ifdef HAVE_LIBXSLT_PATTERN_H
 757 # include <libxslt/pattern.h>
 758 #endif])
 759 CPPFLAGS="$ac_save_CPPFLAGS"
 760 WINE_NOTICE_IF([test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],[libxslt development files not found.
 761 Wine will be built without xslt support. (msxml.dll)])
 762
 763 dnl **** Check for libhal ****
 764 AC_SUBST(HALINCL,"")
 765 if test "$PKG_CONFIG" != "false"
 766 then
 767     ac_save_CPPFLAGS="$CPPFLAGS"
 768     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 769     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 770     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 771     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 772     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 773     then
 774         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 775           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 776             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 777     fi
 778     CPPFLAGS="$ac_save_CPPFLAGS"
 779 fi
 780 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_hal" = "x"],[libhal development files not found.
 781 Wine will be built without dynamic device support. (explorer.exe)])
 782
 783 dnl **** Check which curses lib to use ***
 784 CURSESLIBS=""
 785 if test "$ac_cv_header_ncurses_h" = "yes"
 786 then
 787     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 788 elif test "$ac_cv_header_curses_h" = "yes"
 789 then
 790     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 791 fi
 792 ac_save_LIBS="$LIBS"
 793 LIBS="$LIBS $CURSESLIBS"
 794 AC_CHECK_FUNCS(mousemask)
 795 LIBS="$ac_save_LIBS"
 796 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],[lib(n)curses development files not found.
 797 Wine will be built without (n)curses support. (wineconsole.exe)])
 798
 799 dnl **** Check for SANE ****
 800 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 801 if test "$sane_devel" != "no"
 802 then
 803     ac_sane_incl="`$sane_devel --cflags`"
 804     ac_save_CPPFLAGS="$CPPFLAGS"
 805     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 806     AC_CHECK_HEADER(sane/sane.h,
 807         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 808     CPPFLAGS="$ac_save_CPPFLAGS"
 809 fi
 810 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_sane" = "x"],[libsane development files not found.
 811 Wine will be built without scanner support. (sane.ds/twain_32.dll)])
 812
 813 dnl **** Check for libgphoto2 ****
 814 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 815 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 816 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 817 then
 818     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 819     ac_gphoto2_libs=""
 820     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 821     do
 822       case "$i" in
 823         -L/usr/lib|-L/usr/lib64) ;;
 824         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 825       esac
 826     done
 827     ac_save_CPPFLAGS="$CPPFLAGS"
 828     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 829     AC_CHECK_HEADER(gphoto2-camera.h,
 830                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 831                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 832                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 833                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 834                                   [$GPHOTO2LIBS])])
 835     CPPFLAGS="$ac_save_CPPFLAGS"
 836 fi
 837 WINE_NOTICE_IF([test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],[libgphoto2 development files not found.
 838 Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
 839
 840
 841 dnl **** Check for resolver library ***
 842 AC_SUBST(RESOLVLIBS,"")
 843 if test "$ac_cv_header_resolv_h" = "yes"
 844 then
 845     AC_CHECK_LIB(resolv, res_query,
 846         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 847          RESOLVLIBS="-lresolv"])
 848 fi
 849
 850 dnl **** Check for LittleCMS ***
 851 AC_SUBST(LCMSLIBS,"")
 852 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 853 then
 854     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 855         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 856          LCMSLIBS="-llcms"])
 857 fi
 858 WINE_NOTICE_IF([test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],[liblcms development files not found.
 859 Wine will be built without Color Management support. (mscms.dll)])
 860
 861 dnl **** Check for OpenLDAP ***
 862 AC_SUBST(LDAPLIBS,"")
 863 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 864 then
 865     AC_CHECK_LIB(ldap_r, ldap_initialize,
 866         [AC_CHECK_LIB(lber, ber_init,
 867             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 868              LDAPLIBS="-lldap_r -llber"],,
 869              [$LIBPTHREAD])],,
 870              [$LIBPTHREAD])
 871     WINE_CHECK_LIB_FUNCS(\
 872         ldap_count_references \
 873         ldap_first_reference \
 874         ldap_next_reference \
 875         ldap_parse_reference,
 876         [$LDAPLIBS $LIBPTHREAD])
 877 fi
 878 WINE_NOTICE_IF([test "x$LDAPLIBS" = "x"],[libldap (OpenLDAP) development files not found.
 879 Wine will be built without LDAP support. (wldap32.dll)])
 880
 881 dnl **** Check for FreeType 2 ****
 882 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 883 if test "$ft_devel" != "false"
 884 then
 885     ac_freetype_libs=`$ft_devel --libs`
 886     ac_freetype_incl=`$ft_devel --cflags`
 887     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 888     if test "$ft_lib" = "yes"
 889     then
 890         ac_save_CPPFLAGS="$CPPFLAGS"
 891         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 892         AC_CHECK_HEADERS(ft2build.h \
 893                          freetype/freetype.h \
 894                          freetype/ftglyph.h \
 895                          freetype/fttypes.h \
 896                          freetype/tttables.h \
 897                          freetype/ftnames.h \
 898                          freetype/ftsnames.h \
 899                          freetype/ttnameid.h \
 900                          freetype/ftoutln.h \
 901                          freetype/ftwinfnt.h \
 902                          freetype/ftmodapi.h \
 903                          freetype/internal/sfnt.h,,,
 904                          [#if HAVE_FT2BUILD_H
 905                           #include <ft2build.h>
 906                           #endif])
 907         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 908                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 909           [Define if you have the <freetype/fttrigon.h> header file.])
 910                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 911         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 912         ac_save_CFLAGS="$CFLAGS"
 913         CFLAGS="$CFLAGS $ac_freetype_libs"
 914         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 915         CFLAGS="$ac_save_CFLAGS"
 916         CPPFLAGS="$ac_save_CPPFLAGS"
 917         dnl Check that we have at least freetype/freetype.h
 918         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 919         then
 920             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 921             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
 922             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
 923         fi
 924     fi
 925 fi
 926
 927 dnl Only build the fonts dir if we have both freetype and fontforge
 928 if test "$FONTFORGE" = "false"
 929 then
 930     WINE_WARNING([FontForge is missing.
 931 Fonts will not be built. Dialog text may be invisible or unaligned.])
 932 elif test "x$FREETYPELIBS" = "x"
 933 then
 934     WINE_WARNING([FreeType development files not found.
 935 Fonts will not be built. Dialog text may be invisible or unaligned.])
 936 else
 937   AC_SUBST(FONTSSUBDIRS,"fonts")
 938 fi
 939
 940 dnl **** Check for parport (currently Linux only) ****
 941 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 942  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
 943     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
 944 if test "$ac_cv_c_ppdev" = "yes"
 945 then
 946     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 947 fi
 948
 949 dnl **** Check for va_copy ****
 950 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 951  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
 952     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
 953  )
 954 if test "$ac_cv_c_va_copy" = "yes"
 955 then
 956     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 957 fi
 958 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 959  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
 960     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
 961  )
 962 if test "$ac_cv_c___va_copy" = "yes"
 963 then
 964     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 965 fi
 966
 967 dnl **** Check for sigsetjmp ****
 968 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 969  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
 970     sigsetjmp( buf, 1 );
 971     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
 972  )
 973 if test "$ac_cv_c_sigsetjmp" = "yes"
 974 then
 975     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 976 fi
 977
 978 dnl **** Check for pthread_rwlock_t ****
 979 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 980 #include <pthread.h>])
 981
 982 dnl **** Check for pthread functions ****
 983 WINE_CHECK_LIB_FUNCS(\
 984         pthread_attr_get_np \
 985         pthread_getattr_np \
 986         pthread_get_stackaddr_np \
 987         pthread_get_stacksize_np,
 988         [$LIBPTHREAD])
 989
 990 dnl **** Check for EsounD ****
 991 AC_PATH_PROG(ESDCONFIG, esd-config)
 992 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 993 then
 994     ESD_CFLAGS=""
 995     for i in `$ESDCONFIG --cflags`
 996     do
 997       case "$i" in
 998         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 999       esac
1000     done
1001     ESD_LIBS=`$ESDCONFIG --libs`
1002     save_CFLAGS="$CFLAGS"
1003     CFLAGS="$CFLAGS $ESD_CFLAGS"
1004     AC_CHECK_LIB(esd,esd_open_sound,
1005         [AC_SUBST(ESDLIBS, $ESD_LIBS)
1006          AC_SUBST(ESDINCL, $ESD_CFLAGS)
1007          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
1008     CFLAGS="$save_CFLAGS"
1009 fi
1010
1011 dnl **** Check for ALSA 1.x ****
1012 AC_SUBST(ALSALIBS,"")
1013 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1014 then
1015     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1016         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1017 #include <alsa/asoundlib.h>
1018 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1019 #include <sys/asoundlib.h>
1020 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1021                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1022                          ALSALIBS="-lasound"],[])])
1023 fi
1024
1025 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1026 AC_SUBST(AUDIOIOLIBS,"")
1027 if test "$ac_cv_header_libaudioio_h" = "yes"
1028 then
1029     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1030                   [AUDIOIOLIBS="-laudioio"
1031                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1032 fi
1033
1034 dnl **** Check for capi4linux ****
1035
1036 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1037 then
1038     WINE_CHECK_SONAME(capi20,capi20_register)
1039 fi
1040 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_capi20" = "x"],[libcapi20 development files not found.
1041 Wine will be built without ISDN support. (capi2032.dll)])
1042
1043 dnl **** Check for cups ****
1044 if test "$ac_cv_header_cups_cups_h" = "yes"
1045 then
1046     WINE_CHECK_SONAME(cups,cupsGetDefault)
1047 fi
1048 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_cups" = "x"],[libcups development files not found.
1049 Wine will be built without CUPS support.])
1050
1051 dnl **** Check for jack ****
1052 if test "$ac_cv_header_jack_jack_h" = "yes"
1053 then
1054     WINE_CHECK_SONAME(jack,jack_client_new)
1055 fi
1056
1057 dnl **** Check for fontconfig ****
1058 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1059 then
1060     WINE_CHECK_SONAME(fontconfig,FcInit)
1061 fi
1062 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_fontconfig" = "x"],[fontconfig development files not found.
1063 Wine will be built without fontconfig support.])
1064
1065 dnl **** Check for SSL ****
1066 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1067 then
1068     WINE_CHECK_SONAME(ssl,SSL_library_init)
1069     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1070 fi
1071 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_ssl" = "x"],[OpenSSL development files not found.
1072 Wine will be built without SSL support. (wininet.dll)])
1073
1074 dnl **** Check for libjpeg ****
1075 if test "$ac_cv_header_jpeglib_h" = "yes"
1076 then
1077     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1078 fi
1079 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_jpeg" = "x"],[libjpeg development files not found.
1080 Wine will be built without JPEG support. (oleaut32.dll)])
1081
1082 dnl **** Check for libpng ****
1083 if test "$ac_cv_header_png_h" = "yes"
1084 then
1085     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1086 fi
1087 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_png" = "x"],[libpng development files not found.
1088 Wine will be built without PNG support. (oleaut32.dll)])
1089
1090 dnl **** Check for any sound system ****
1091 WINE_WARNING_IF([test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1092                  "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1093                  "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1094                  "$ac_cv_header_soundcard_h" != "yes"],
1095 [No sound system was found. Windows applications will be silent.])
1096
1097 dnl **** Check for gcc specific options ****
1098
1099 AC_SUBST(EXTRACFLAGS,"")
1100 if test "x${GCC}" = "xyes"
1101 then
1102   EXTRACFLAGS="-Wall -pipe"
1103
1104   dnl Check for strength-reduce bug
1105   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1106                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1107 [[static int Array[[3]];
1108   unsigned int B = 3;
1109   int i;
1110   for(i=0; i<B; i++) Array[[i]] = i - 3;
1111   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1112   L[[i]] = 4;
1113   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1114     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1115   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1116   then
1117     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1118   fi
1119
1120   dnl Check for some compiler flags
1121
1122   WINE_TRY_CFLAGS([-fshort-wchar],
1123                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1124                              [Specifies the compiler flag that forces a short wchar_t])])
1125   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1126   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1127   WINE_TRY_CFLAGS([-Wwrite-strings])
1128
1129   dnl Check for noisy string.h
1130   saved_CFLAGS="$CFLAGS"
1131   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1132   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1133       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1134   CFLAGS="$saved_CFLAGS"
1135   if test "$ac_cv_c_string_h_warnings" = "no"
1136   then
1137     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1138   fi
1139
1140   AC_SUBST(BUILTINFLAG,"")
1141   saved_CFLAGS="$CFLAGS"
1142   CFLAGS="$CFLAGS -Werror"
1143   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1144       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1145   CFLAGS="$saved_CFLAGS"
1146   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1147   then
1148     BUILTINFLAG="-fno-builtin"
1149   fi
1150 fi
1151
1152 dnl **** Check how to define a function in assembly code ****
1153
1154 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1155   WINE_TRY_ASM_LINK(
1156       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1157       ac_cv_asm_func_def=".def",
1158     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1159       ac_cv_asm_func_def=".type @function",
1160     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1161       ac_cv_asm_func_def=".type 2",
1162       ac_cv_asm_func_def="unknown")])]))
1163
1164 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1165 case "$ac_cv_asm_func_def" in
1166   ".def")
1167      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1168   ".type @function")
1169      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1170   ".type 2")
1171      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1172   *)
1173      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1174 esac
1175
1176 dnl **** Check for underscore on external symbols ****
1177
1178 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1179     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1180                       [extern int ac_test;],
1181                       [if (ac_test) return 1],
1182                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1183
1184 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1185 if test "$ac_cv_c_extern_prefix" = "yes"
1186 then
1187   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1188 else
1189   AC_DEFINE([__ASM_NAME(name)], [name])
1190 fi
1191
1192 dnl **** Platform-specific checks ****
1193
1194 AC_SUBST(LDPATH,"")
1195 case $build_os in
1196   cygwin*|mingw32*)
1197     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1198     ;;
1199   darwin*|macosx*)
1200     ;;
1201   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1202     if test -z "$LDRPATH_LOCAL"
1203     then
1204       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1205     fi
1206     ;;
1207   *)
1208     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1209     ;;
1210 esac
1211
1212 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1213 case $host_os in
1214   mingw32*)
1215     AC_SUBST(CRTLIBS,"-lmsvcrt")
1216     AC_SUBST(SOCKETLIBS,"-lws2_32")
1217     ;;
1218 esac
1219
1220 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1221 case $host_cpu in
1222   *i[[3456789]]86*)
1223     case $host_os in
1224       linux* | k*bsd*-gnu)
1225         AC_SUBST(MAIN_BINARY,"wine-glibc")
1226         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1227       freebsd*)
1228         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1229         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1230     esac
1231     ;;
1232 esac
1233
1234 dnl **** Check for functions ****
1235
1236 AC_CHECK_FUNCS(\
1237         _pclose \
1238         _popen \
1239         _snprintf \
1240         _spawnvp \
1241         _stricmp \
1242         _strnicmp \
1243         _vsnprintf \
1244         asctime_r \
1245         chsize \
1246         clone \
1247         dlopen \
1248         epoll_create \
1249         ffs \
1250         finite \
1251         fork \
1252         fpclass \
1253         fstatfs \
1254         fstatvfs \
1255         ftruncate \
1256         futimes \
1257         futimesat \
1258         getdirentries \
1259         getopt_long \
1260         getpagesize \
1261         getpwuid \
1262         gettid \
1263         gettimeofday \
1264         getuid \
1265         inet_pton \
1266         kqueue \
1267         lstat \
1268         memmove \
1269         mmap \
1270         pclose \
1271         poll \
1272         popen \
1273         prctl \
1274         pread \
1275         pwrite \
1276         readlink \
1277         rfork \
1278         sched_yield \
1279         select \
1280         setrlimit \
1281         settimeofday \
1282         sigaltstack \
1283         sigprocmask \
1284         snprintf \
1285         spawnvp \
1286         statfs \
1287         statvfs \
1288         strcasecmp \
1289         strerror \
1290         strncasecmp \
1291         strtold \
1292         tcgetattr \
1293         thr_kill2 \
1294         timegm \
1295         usleep \
1296         vsnprintf \
1297         wait4 \
1298         waitpid \
1299 )
1300
1301 dnl Check for -ldl
1302 if test "$ac_cv_func_dlopen" = no
1303 then
1304     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1305 fi
1306 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1307
1308 dnl Check for -lpoll for Mac OS X/Darwin
1309 if test "$ac_cv_func_poll" = no
1310 then
1311     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1312 fi
1313
1314 dnl Check for -lnsl for Solaris
1315 AC_SEARCH_LIBS(gethostbyname, nsl)
1316
1317 dnl Check for -lsocket for Solaris
1318 AC_SEARCH_LIBS(connect, socket)
1319
1320 dnl Check for -lresolv for Solaris
1321 AC_SEARCH_LIBS(inet_aton, resolv)
1322
1323 dnl **** Check for functions which may rely on -lsocket on Solaris.
1324 AC_CHECK_FUNCS(\
1325         getaddrinfo \
1326         getnameinfo \
1327         getnetbyname \
1328         getprotobyname \
1329         getprotobynumber \
1330         getservbyport \
1331         inet_network \
1332         sendmsg \
1333 )
1334
1335 dnl **** Check for types ****
1336
1337 AC_C_CONST
1338 AC_C_INLINE
1339 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1340 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1341 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1342
1343 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1344 [#ifdef HAVE_LINUX_INPUT_H
1345 #include <linux/input.h>
1346 #endif])
1347
1348 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1349                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1350 if test "$wine_cv_have_sigaddset" = "yes"
1351 then
1352   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1353 fi
1354
1355
1356 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1357         wine_cv_linux_gethostbyname_r_6,
1358         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1359     char *name=NULL;
1360     struct hostent he;
1361     struct hostent *result;
1362     char *buf=NULL;
1363     int bufsize=0;
1364     int res,errnr;
1365     char *addr=NULL;
1366     int addrlen=0;
1367     int addrtype=0;
1368     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1369     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1370     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1371         ])
1372    )
1373    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1374    then
1375       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1376                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1377    fi
1378
1379 if test "$ac_cv_header_linux_joystick_h" = "yes"
1380 then
1381    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1382         wine_cv_linux_joystick_22_api,
1383         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1384         #include <sys/ioctl.h>
1385         #include <sys/types.h>
1386         #include <linux/joystick.h>
1387
1388         struct js_event blub;
1389         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1390         #error "no 2.2 header"
1391         #endif
1392         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1393    )
1394    if test "$wine_cv_linux_joystick_22_api" = "yes"
1395    then
1396       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1397                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1398    fi
1399 fi
1400
1401 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1402
1403 dnl Check for statfs members
1404 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1405 [#include <sys/types.h>
1406 #ifdef HAVE_SYS_PARAM_H
1407 # include <sys/param.h>
1408 #endif
1409 #ifdef HAVE_SYS_MOUNT_H
1410 # include <sys/mount.h>
1411 #endif
1412 #ifdef HAVE_SYS_VFS_H
1413 # include <sys/vfs.h>
1414 #endif
1415 #ifdef HAVE_SYS_STATFS_H
1416 # include <sys/statfs.h>
1417 #endif])
1418
1419 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1420 [#ifdef HAVE_SYS_STATVFS_H
1421 #include <sys/statvfs.h>
1422 #endif])
1423
1424 dnl Check for socket structure members
1425 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1426 [#include <sys/types.h>
1427 #ifdef HAVE_SYS_SOCKET_H
1428 # include <sys/socket.h>
1429 #endif
1430 #ifdef HAVE_SYS_UN_H
1431 # include <sys/un.h>
1432 #endif])
1433
1434 dnl Check for scsireq_t and sg_io_hdr_t members
1435 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1436 [#include <sys/types.h>
1437 #ifdef HAVE_SCSI_SG_H
1438 #include <scsi/sg.h>
1439 #endif])
1440
1441 dnl Check for siginfo_t members
1442 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1443
1444 dnl Check for struct mtget members
1445 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1446 [#include <sys/types.h>
1447 #ifdef HAVE_SYS_MTIO_H
1448 #include <sys/mtio.h>
1449 #endif])
1450
1451 dnl Check for struct option
1452 AC_CHECK_MEMBERS([struct option.name],,,
1453 [#ifdef HAVE_GETOPT_H
1454 #include <getopt.h>
1455 #endif])
1456
1457 dnl Check for stat.st_blocks
1458 AC_CHECK_MEMBERS([struct stat.st_blocks])
1459
1460 dnl Check for sin6_scope_id
1461 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1462 [#ifdef HAVE_SYS_TYPES_H
1463 #include <sys/types.h>
1464 #endif
1465 #ifdef HAVE_NETINET_IN_H
1466 #include <netinet/in.h>
1467 #endif])
1468
1469 dnl Check for ns_msg ptr member
1470 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1471 [#ifdef HAVE_SYS_TYPES_H
1472 #include <sys/types.h>
1473 #endif
1474 #ifdef HAVE_NETINET_IN_H
1475 # include <netinet/in.h>
1476 #endif
1477 #ifdef HAVE_ARPA_NAMESER_H
1478 # include <arpa/nameser.h>
1479 #endif])
1480
1481 dnl Check for the external timezone variables timezone and daylight
1482 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1483                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1484 if test "$ac_cv_have_timezone" = "yes"
1485 then
1486     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1487 fi
1488 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1489                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1490 if test "$ac_cv_have_daylight" = "yes"
1491 then
1492     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1493 fi
1494
1495 dnl *** check for the need to define platform-specific symbols
1496
1497 case $host_cpu in
1498   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1499   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1500   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1501   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1502   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1503 esac
1504
1505 case $host_vendor in
1506   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1507 esac
1508
1509 dnl **** Generate output files ****
1510
1511 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1512 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1513 ["### Dependencies:\\
1514 \\
1515 .INIT: Makefile\\
1516 .BEGIN: Makefile\\
1517 Makefile: dummy\\
1518         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1519 \\
1520 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1521 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1522 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1523 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1524 ["### Dependencies:
1525
1526 .INIT: Makefile
1527 .BEGIN: Makefile
1528 Makefile: dummy
1529         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1530
1531 \$(OBJS): \$(IDL_GEN_HEADERS)
1532 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1533 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1534 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1535
1536 AH_TOP([#define __WINE_CONFIG_H])
1537
1538 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1539
1540 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1541 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1542 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1543 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1544 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1545 WINE_CONFIG_EXTRA_DIR(include/wine)
1546
1547 MAKE_RULES=Make.rules
1548 AC_SUBST_FILE(MAKE_RULES)
1549
1550 MAKE_DLL_RULES=dlls/Makedll.rules
1551 AC_SUBST_FILE(MAKE_DLL_RULES)
1552
1553 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1554 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1555
1556 MAKE_TEST_RULES=dlls/Maketest.rules
1557 AC_SUBST_FILE(MAKE_TEST_RULES)
1558
1559 MAKE_PROG_RULES=programs/Makeprog.rules
1560 AC_SUBST_FILE(MAKE_PROG_RULES)
1561
1562 AC_CONFIG_FILES([Make.rules])
1563 AC_CONFIG_FILES([dlls/Makedll.rules])
1564 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1565 AC_CONFIG_FILES([dlls/Maketest.rules])
1566 AC_CONFIG_FILES([programs/Makeprog.rules])
1567 AC_CONFIG_FILES([Makefile])
1568 AC_CONFIG_FILES([dlls/Makefile])
1569 AC_CONFIG_FILES([dlls/acledit/Makefile])
1570 AC_CONFIG_FILES([dlls/activeds/Makefile])
1571 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1572 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1573 AC_CONFIG_FILES([dlls/advpack/Makefile])
1574 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1575 AC_CONFIG_FILES([dlls/amstream/Makefile])
1576 AC_CONFIG_FILES([dlls/atl/Makefile])
1577 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1578 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1579 AC_CONFIG_FILES([dlls/browseui/Makefile])
1580 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1581 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1582 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1583 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1584 AC_CONFIG_FILES([dlls/cards/Makefile])
1585 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1586 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1587 AC_CONFIG_FILES([dlls/comcat/Makefile])
1588 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1589 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1590 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1591 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1592 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1593 AC_CONFIG_FILES([dlls/compstui/Makefile])
1594 AC_CONFIG_FILES([dlls/credui/Makefile])
1595 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1596 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1597 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1598 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1599 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1600 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1601 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1602 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1603 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1604 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1605 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1606 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1607 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1608 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1609 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1610 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1611 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1612 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1613 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1614 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1615 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1616 AC_CONFIG_FILES([dlls/devenum/Makefile])
1617 AC_CONFIG_FILES([dlls/dinput/Makefile])
1618 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1619 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1620 AC_CONFIG_FILES([dlls/dmband/Makefile])
1621 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1622 AC_CONFIG_FILES([dlls/dmime/Makefile])
1623 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1624 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1625 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1626 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1627 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1628 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1629 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1630 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1631 AC_CONFIG_FILES([dlls/dplay/Makefile])
1632 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1633 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1634 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1635 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1636 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1637 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1638 AC_CONFIG_FILES([dlls/dsound/Makefile])
1639 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1640 AC_CONFIG_FILES([dlls/dswave/Makefile])
1641 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1642 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1643 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1644 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1645 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1646 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1647 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1648 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1649 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1650 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1651 AC_CONFIG_FILES([dlls/glu32/Makefile])
1652 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1653 AC_CONFIG_FILES([dlls/hal/Makefile])
1654 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1655 AC_CONFIG_FILES([dlls/hid/Makefile])
1656 AC_CONFIG_FILES([dlls/hlink/Makefile])
1657 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1658 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1659 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1660 AC_CONFIG_FILES([dlls/icmp/Makefile])
1661 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1662 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1663 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1664 AC_CONFIG_FILES([dlls/imm32/Makefile])
1665 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1666 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1667 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1668 AC_CONFIG_FILES([dlls/inseng/Makefile])
1669 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1670 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1671 AC_CONFIG_FILES([dlls/itss/Makefile])
1672 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1673 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1674 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1675 AC_CONFIG_FILES([dlls/localspl/Makefile])
1676 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1677 AC_CONFIG_FILES([dlls/localui/Makefile])
1678 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1679 AC_CONFIG_FILES([dlls/lz32/Makefile])
1680 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1681 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1682 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1683 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1684 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1685 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1686 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1687 AC_CONFIG_FILES([dlls/midimap/Makefile])
1688 AC_CONFIG_FILES([dlls/mlang/Makefile])
1689 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1690 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1691 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1692 AC_CONFIG_FILES([dlls/mpr/Makefile])
1693 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1694 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1695 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1696 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1697 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1698 AC_CONFIG_FILES([dlls/mscms/Makefile])
1699 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1700 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1701 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1702 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1703 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1704 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1705 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1706 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1707 AC_CONFIG_FILES([dlls/msi/Makefile])
1708 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1709 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1710 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1711 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1712 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1713 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1714 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1715 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1716 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1717 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1718 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1719 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1720 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1721 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1722 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1723 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1724 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1725 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1726 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1727 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1728 AC_CONFIG_FILES([dlls/newdev/Makefile])
1729 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1730 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1731 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1732 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1733 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1734 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1735 AC_CONFIG_FILES([dlls/objsel/Makefile])
1736 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1737 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1738 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1739 AC_CONFIG_FILES([dlls/ole32/Makefile])
1740 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1741 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1742 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1743 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1744 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1745 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1746 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1747 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1748 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1749 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1750 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1751 AC_CONFIG_FILES([dlls/pdh/Makefile])
1752 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1753 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1754 AC_CONFIG_FILES([dlls/printui/Makefile])
1755 AC_CONFIG_FILES([dlls/psapi/Makefile])
1756 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1757 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1758 AC_CONFIG_FILES([dlls/qcap/Makefile])
1759 AC_CONFIG_FILES([dlls/quartz/Makefile])
1760 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1761 AC_CONFIG_FILES([dlls/query/Makefile])
1762 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1763 AC_CONFIG_FILES([dlls/resutils/Makefile])
1764 AC_CONFIG_FILES([dlls/riched20/Makefile])
1765 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1766 AC_CONFIG_FILES([dlls/riched32/Makefile])
1767 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1768 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1769 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1770 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1771 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1772 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1773 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1774 AC_CONFIG_FILES([dlls/schannel/Makefile])
1775 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1776 AC_CONFIG_FILES([dlls/secur32/Makefile])
1777 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1778 AC_CONFIG_FILES([dlls/security/Makefile])
1779 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1780 AC_CONFIG_FILES([dlls/serialui/Makefile])
1781 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1782 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1783 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1784 AC_CONFIG_FILES([dlls/sfc/Makefile])
1785 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1786 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1787 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1788 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1789 AC_CONFIG_FILES([dlls/shell32/Makefile])
1790 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1791 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1792 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1793 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1794 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1795 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1796 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1797 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1798 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1799 AC_CONFIG_FILES([dlls/sti/Makefile])
1800 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1801 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1802 AC_CONFIG_FILES([dlls/sxs/Makefile])
1803 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1804 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1805 AC_CONFIG_FILES([dlls/unicows/Makefile])
1806 AC_CONFIG_FILES([dlls/url/Makefile])
1807 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1808 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1809 AC_CONFIG_FILES([dlls/user32/Makefile])
1810 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1811 AC_CONFIG_FILES([dlls/userenv/Makefile])
1812 AC_CONFIG_FILES([dlls/usp10/Makefile])
1813 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1814 AC_CONFIG_FILES([dlls/uuid/Makefile])
1815 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1816 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1817 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1818 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1819 AC_CONFIG_FILES([dlls/version/Makefile])
1820 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1821 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1822 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1823 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1824 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1825 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1826 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1827 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1828 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1829 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1830 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1831 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1832 AC_CONFIG_FILES([dlls/winedos/Makefile])
1833 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1834 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1835 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1836 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1837 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1838 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1839 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1840 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1841 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1842 AC_CONFIG_FILES([dlls/wing32/Makefile])
1843 AC_CONFIG_FILES([dlls/winhttp/Makefile])
1844 AC_CONFIG_FILES([dlls/wininet/Makefile])
1845 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1846 AC_CONFIG_FILES([dlls/winmm/Makefile])
1847 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1848 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1849 AC_CONFIG_FILES([dlls/winscard/Makefile])
1850 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1851 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1852 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1853 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1854 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1855 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1856 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1857 AC_CONFIG_FILES([dlls/wow32/Makefile])
1858 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1859 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1860 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1861 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1862 AC_CONFIG_FILES([documentation/Makefile])
1863 AC_CONFIG_FILES([fonts/Makefile])
1864 AC_CONFIG_FILES([include/Makefile])
1865 AC_CONFIG_FILES([libs/Makefile])
1866 AC_CONFIG_FILES([libs/port/Makefile])
1867 AC_CONFIG_FILES([libs/wine/Makefile])
1868 AC_CONFIG_FILES([libs/wpp/Makefile])
1869 AC_CONFIG_FILES([loader/Makefile])
1870 AC_CONFIG_FILES([programs/Makefile])
1871 AC_CONFIG_FILES([programs/clock/Makefile])
1872 AC_CONFIG_FILES([programs/cmd/Makefile])
1873 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1874 AC_CONFIG_FILES([programs/control/Makefile])
1875 AC_CONFIG_FILES([programs/eject/Makefile])
1876 AC_CONFIG_FILES([programs/expand/Makefile])
1877 AC_CONFIG_FILES([programs/explorer/Makefile])
1878 AC_CONFIG_FILES([programs/hh/Makefile])
1879 AC_CONFIG_FILES([programs/icinfo/Makefile])
1880 AC_CONFIG_FILES([programs/iexplore/Makefile])
1881 AC_CONFIG_FILES([programs/msiexec/Makefile])
1882 AC_CONFIG_FILES([programs/net/Makefile])
1883 AC_CONFIG_FILES([programs/notepad/Makefile])
1884 AC_CONFIG_FILES([programs/oleview/Makefile])
1885 AC_CONFIG_FILES([programs/progman/Makefile])
1886 AC_CONFIG_FILES([programs/regedit/Makefile])
1887 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1888 AC_CONFIG_FILES([programs/rpcss/Makefile])
1889 AC_CONFIG_FILES([programs/rundll32/Makefile])
1890 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1891 AC_CONFIG_FILES([programs/start/Makefile])
1892 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1893 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1894 AC_CONFIG_FILES([programs/view/Makefile])
1895 AC_CONFIG_FILES([programs/wineboot/Makefile])
1896 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1897 AC_CONFIG_FILES([programs/winecfg/Makefile])
1898 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1899 AC_CONFIG_FILES([programs/winedbg/Makefile])
1900 AC_CONFIG_FILES([programs/winedevice/Makefile])
1901 AC_CONFIG_FILES([programs/winefile/Makefile])
1902 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1903 AC_CONFIG_FILES([programs/winemine/Makefile])
1904 AC_CONFIG_FILES([programs/winepath/Makefile])
1905 AC_CONFIG_FILES([programs/winetest/Makefile])
1906 AC_CONFIG_FILES([programs/winevdm/Makefile])
1907 AC_CONFIG_FILES([programs/winhelp/Makefile])
1908 AC_CONFIG_FILES([programs/winver/Makefile])
1909 AC_CONFIG_FILES([programs/wordpad/Makefile])
1910 AC_CONFIG_FILES([programs/write/Makefile])
1911 AC_CONFIG_FILES([programs/xcopy/Makefile])
1912 AC_CONFIG_FILES([server/Makefile])
1913 AC_CONFIG_FILES([tools/Makefile])
1914 AC_CONFIG_FILES([tools/widl/Makefile])
1915 AC_CONFIG_FILES([tools/winebuild/Makefile])
1916 AC_CONFIG_FILES([tools/winedump/Makefile])
1917 AC_CONFIG_FILES([tools/winegcc/Makefile])
1918 AC_CONFIG_FILES([tools/wmc/Makefile])
1919 AC_CONFIG_FILES([tools/wrc/Makefile])
1920
1921 AC_OUTPUT
1922
1923 if test "$no_create" = "yes"
1924 then
1925   exit 0
1926 fi
1927
1928 WINE_PRINT_MESSAGES
1929
1930 echo
1931 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1932 echo
1933
1934 dnl Local Variables:
1935 dnl comment-start: "dnl "
1936 dnl comment-end: ""
1937 dnl comment-start-skip: "\\bdnl\\b\\s *"
1938 dnl compile-command: "autoreconf --warnings=all"
1939 dnl End: