configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  19             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  20 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  21             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  22 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  23             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  24 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  25             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  26 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  27             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  28 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]),
  29             [if test "x$withval" = "xno"; then ac_cv_header_cups_cups_h=no; fi])
  30 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  31             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  32 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  33 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  34             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  35 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  36 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  37 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  38             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  39 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  40             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  41 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  42             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  43 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  45 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  46 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  47             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  48 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  49             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  50 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  51             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  52 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  53 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  54             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  55 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  56             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  57 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  58             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  59 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  61 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  62 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  63             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  64 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  65             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  66 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  67             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  68 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  69             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  70 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  71 AC_ARG_WITH(xvidmode,  AS_HELP_STRING([--without-xvidmode],[do not use XFree video mode extension]),
  72             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; fi])
  73
  74 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  75 AC_ARG_ENABLE(tests, AC_HELP_STRING([--disable-tests],[do not build the testsuites]))
  76
  77 AC_CANONICAL_HOST
  78 case $host in
  79   x86_64*linux*)
  80     if test "x$enable_win64" != "xyes"
  81     then
  82       test -n "$CC" || CC="gcc -m32"
  83       test -n "$CXX"|| CXX="g++ -m32"
  84       test -n "$LD" || LD="ld -m elf_i386"
  85       test -n "$AS" || AS="as --32"
  86       host_cpu="i386"
  87     fi
  88     ;;
  89 esac
  90
  91 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  92 case $host_cpu in
  93   *i[[3456789]]86*)
  94     if test "x$enable_win16" != "xno"
  95     then
  96       enable_win16="yes"
  97     fi
  98     ;;
  99 esac
 100
 101 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
 102 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
 103 if test "x$enable_win16" != "xyes"
 104 then
 105   WIN16_FILES=""
 106   WIN16_INSTALL=""
 107 fi
 108
 109 dnl enable_tests is yes by default, but in some cases it's better to disable the testsuite
 110 if test "x$enable_tests" == "xno"
 111 then
 112   AC_SUBST(TESTSUBDIRS,"")
 113   AC_SUBST(WINETEST,"")
 114 else
 115   AC_SUBST(TESTSUBDIRS,"\$(TESTSUBDIRS)")
 116   AC_SUBST(WINETEST,"winetest")
 117 fi
 118
 119 dnl check for out of tree build with unclean source tree
 120 case "$srcdir" in
 121  .) ;;
 122  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 123       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 124 You need to run 'make distclean' in the source tree first.])
 125     fi ;;
 126 esac
 127
 128 dnl **** Check for some programs ****
 129
 130 AC_PROG_MAKE_SET
 131 AC_PROG_CC
 132 AC_PROG_CXX
 133 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 134 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 135
 136 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 137   [if test -z "$with_wine_tools"; then
 138      if test "$cross_compiling" = "yes"; then
 139        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 140      else
 141        wine_cv_toolsdir="\$(TOPOBJDIR)"
 142      fi
 143    elif test -d "$with_wine_tools/tools/winebuild"; then
 144      case $with_wine_tools in
 145        /*) wine_cv_toolsdir="$with_wine_tools" ;;
 146        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
 147      esac
 148    else
 149      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
 150    fi])
 151 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 152
 153 AC_PATH_XTRA
 154
 155 dnl Check for flex
 156 AC_CHECK_PROGS(FLEX,flex,none)
 157 if test "$FLEX" = "none"
 158 then
 159   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 160 fi
 161
 162 dnl Check for bison
 163 AC_CHECK_PROGS(BISON,bison,none)
 164 if test "$BISON" = "none"
 165 then
 166   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 167 fi
 168
 169 AC_CHECK_TOOLS(AS,[gas as],as)
 170 AC_CHECK_TOOL(LD,ld,ld)
 171 AC_CHECK_TOOL(AR,ar,ar)
 172 AC_PROG_RANLIB
 173 AC_CHECK_TOOL(STRIP,strip,strip)
 174 AC_CHECK_TOOL(WINDRES,windres,false)
 175 AC_PROG_LN_S
 176 WINE_PROG_LN
 177 AC_PROG_EGREP
 178 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 179 AC_PROG_INSTALL
 180 dnl Prepend src dir to install path dir if it's a relative path
 181 case "$INSTALL" in
 182   [[\\/$]]* | ?:[[\\/]]* ) ;;
 183   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 184 esac
 185
 186 dnl Check for lint
 187 AC_CHECK_PROGS(LINT, lclint lint)
 188 if test "$LINT" = "lint"
 189 then
 190   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 191   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 192 fi
 193 AC_SUBST(LINT)
 194 AC_SUBST(LINTFLAGS)
 195
 196 dnl Check for various programs
 197 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 198 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 199
 200 case $host_cpu in
 201   *i[[3456789]]86*)
 202     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 203     ;;
 204 esac
 205
 206 dnl **** Check for some libraries ****
 207
 208 dnl Check for -li386 for NetBSD and OpenBSD
 209 AC_CHECK_LIB(i386,i386_set_ldt)
 210 dnl Check for -lossaudio for NetBSD
 211 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 212 dnl Check for -lpthread
 213 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 214
 215 AC_SUBST(XLIB,"")
 216 AC_SUBST(XFILES,"")
 217 AC_SUBST(OPENGLFILES,"")
 218 AC_SUBST(GLU32FILES,"")
 219 AC_SUBST(OPENGL_LIBS,"")
 220 AC_SUBST(QUARTZFILES,"")
 221
 222 dnl **** Check for header files ****
 223
 224 AC_CHECK_HEADERS(\
 225         AudioUnit/AudioUnit.h \
 226         Carbon/Carbon.h \
 227         CoreAudio/CoreAudio.h \
 228         DiskArbitration/DiskArbitration.h \
 229         IOKit/IOKitLib.h \
 230         alsa/asoundlib.h \
 231         arpa/inet.h \
 232         arpa/nameser.h \
 233         asm/types.h \
 234         capi20.h \
 235         cups/cups.h \
 236         curses.h \
 237         direct.h \
 238         dlfcn.h \
 239         elf.h \
 240         float.h \
 241         fontconfig/fontconfig.h \
 242         getopt.h \
 243         ieeefp.h \
 244         io.h \
 245         jack/jack.h \
 246         jpeglib.h \
 247         lber.h \
 248         lcms.h \
 249         lcms/lcms.h \
 250         ldap.h \
 251         libaudioio.h \
 252         link.h \
 253         linux/cdrom.h \
 254         linux/compiler.h \
 255         linux/hdreg.h \
 256         linux/input.h \
 257         linux/ioctl.h \
 258         linux/joystick.h \
 259         linux/major.h \
 260         linux/param.h \
 261         linux/serial.h \
 262         linux/ucdrom.h \
 263         mach/mach.h \
 264         mach/machine.h \
 265         machine/cpu.h \
 266         machine/limits.h \
 267         machine/soundcard.h \
 268         mntent.h \
 269         ncurses.h \
 270         netdb.h \
 271         netinet/in.h \
 272         netinet/in_systm.h \
 273         netinet/tcp.h \
 274         netinet/tcp_fsm.h \
 275         openssl/err.h \
 276         openssl/ssl.h \
 277         png.h \
 278         poll.h \
 279         process.h \
 280         pthread.h \
 281         pwd.h \
 282         regex.h \
 283         sched.h \
 284         scsi/scsi.h \
 285         scsi/scsi_ioctl.h \
 286         scsi/sg.h \
 287         soundcard.h \
 288         stdint.h \
 289         strings.h \
 290         sys/asoundlib.h \
 291         sys/cdio.h \
 292         sys/elf32.h \
 293         sys/epoll.h \
 294         sys/errno.h \
 295         sys/event.h \
 296         sys/exec_elf.h \
 297         sys/filio.h \
 298         sys/ioctl.h \
 299         sys/ipc.h \
 300         sys/limits.h \
 301         sys/link.h \
 302         sys/lwp.h \
 303         sys/mman.h \
 304         sys/modem.h \
 305         sys/msg.h \
 306         sys/mtio.h \
 307         sys/param.h \
 308         sys/poll.h \
 309         sys/prctl.h \
 310         sys/ptrace.h \
 311         sys/reg.h \
 312         sys/resource.h \
 313         sys/scsiio.h \
 314         sys/shm.h \
 315         sys/signal.h \
 316         sys/socket.h \
 317         sys/socketvar.h \
 318         sys/sockio.h \
 319         sys/soundcard.h \
 320         sys/statvfs.h \
 321         sys/strtio.h \
 322         sys/syscall.h \
 323         sys/sysctl.h \
 324         sys/time.h \
 325         sys/times.h \
 326         sys/uio.h \
 327         sys/un.h \
 328         sys/vm86.h \
 329         sys/wait.h \
 330         syscall.h \
 331         termios.h \
 332         unistd.h \
 333         utime.h \
 334         valgrind/memcheck.h
 335 )
 336 AC_HEADER_STAT()
 337
 338 dnl **** Checks for headers that depend on other ones ****
 339
 340 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 341     [#include <sys/types.h>
 342      #if HAVE_SYS_PARAM_H
 343      # include <sys/param.h>
 344      #endif])
 345
 346 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 347     [#include <sys/types.h>
 348      #if HAVE_SYS_SOCKET_H
 349      # include <sys/socket.h>
 350      #endif
 351      #if HAVE_SYS_SOCKETVAR_H
 352      # include <sys/socketvar.h>
 353      #endif
 354      #if HAVE_NETINET_IN_H
 355      # include <netinet/in.h>
 356      #endif])
 357
 358 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 359     [#include <sys/types.h>
 360      #if HAVE_SYS_SOCKET_H
 361      # include <sys/socket.h>
 362      #endif
 363      #if HAVE_SYS_SOCKETVAR_H
 364      # include <sys/socketvar.h>
 365      #endif
 366      #if HAVE_NETINET_IN_H
 367      # include <netinet/in.h>
 368      #endif
 369      #ifdef HAVE_NETINET_TCP_H
 370      # include <netinet/tcp.h>
 371      #endif])
 372
 373 AC_CHECK_HEADERS([linux/ipx.h],,,
 374     [#include <sys/types.h>
 375      #ifdef HAVE_ASM_TYPES_H
 376      # include <asm/types.h>
 377      #endif
 378      #if HAVE_SYS_SOCKET_H
 379      # include <sys/socket.h>
 380      #endif])
 381
 382 AC_CHECK_HEADERS([resolv.h],,,
 383     [#include <sys/types.h>
 384      #if HAVE_SYS_SOCKET_H
 385      # include <sys/socket.h>
 386      #endif
 387      #if HAVE_NETINET_IN_H
 388      # include <netinet/in.h>
 389      #endif
 390      #if HAVE_ARPA_NAMESER_H
 391      # include <arpa/nameser.h>
 392      #endif])
 393
 394 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 395
 396 AC_CHECK_HEADERS([sys/thr.h],,,
 397 [#include <sys/types.h>
 398 #if HAVE_UCONTEXT_H
 399 #include <ucontext.h>
 400 #endif])
 401
 402 AC_CHECK_HEADERS([pthread_np.h],,,
 403 [#ifdef HAVE_PTHREAD_H
 404 #include <pthread.h>
 405 #endif])
 406
 407 AC_CHECK_HEADERS([linux/videodev.h],,,
 408 [#ifdef HAVE_SYS_TIME_H
 409 #include <sys/time.h>
 410 #endif
 411 #include <sys/types.h>
 412 #ifdef HAVE_ASM_TYPES_H
 413 #include <asm/types.h>
 414 #endif])
 415
 416 dnl Check for broken kernel header that doesn't define __user
 417 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 418
 419 dnl **** Check for working dll ****
 420
 421 AC_SUBST(DLLEXT,"")
 422 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 423 AC_SUBST(LDSHARED,"")
 424 AC_SUBST(LDDLLFLAGS,"")
 425 AC_SUBST(LIBEXT,"so")
 426 AC_SUBST(IMPLIBEXT,"def")
 427 AC_SUBST(LDRPATH_INSTALL,"")
 428 AC_SUBST(LDRPATH_LOCAL,"")
 429 WINE_PATH_LDD
 430
 431 case $host_os in
 432   cygwin*|mingw32*)
 433     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 434     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 435     AC_CHECK_TOOL(MINGWAR,ar,false)
 436     if test "$DLLWRAP" = "false"; then
 437       LIBEXT="a"
 438     else
 439       dnl FIXME - check whether dllwrap works correctly...
 440       LIBEXT="dll"
 441     fi
 442     IMPLIBEXT="a"
 443     dnl We can't build 16-bit NE dlls
 444     WIN16_FILES=""
 445     WIN16_INSTALL=""
 446     ;;
 447   darwin*|macosx*)
 448     DLLEXT=".so"
 449     LIBEXT="dylib"
 450     DLLFLAGS="$DLLFLAGS -fPIC"
 451     LDDLLFLAGS="-bundle -multiply_defined suppress"
 452     LIBWINE_LDFLAGS="-multiply_defined suppress"
 453     LDSHARED="\$(CC) -dynamiclib"
 454     STRIP="$STRIP -x"
 455     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 456     dnl declare needed frameworks
 457     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 458     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 459     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 460     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 461     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 462     then
 463         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 464         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 465     fi
 466     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 467     then
 468         dnl CoreServices needed by AudioUnit
 469         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 470     fi
 471     case $host_cpu in
 472       *powerpc*)
 473         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 474         ;;
 475     esac
 476     dnl Enable quartz driver on Mac OS X
 477     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 478     then
 479         AC_SUBST(CARBONLIB,"-framework Carbon")
 480         QUARTZFILES='$(QUARTZFILES)'
 481     fi
 482     ;;
 483   *)
 484     DLLFLAGS="$DLLFLAGS -fPIC"
 485     DLLEXT=".so"
 486     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 487         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 488                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 489     if test "$ac_cv_c_dll_gnuelf" = "yes"
 490     then
 491       LDSHARED="\$(CC) -shared"
 492       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 493       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 494                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 495                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 496                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 497
 498       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 499
 500       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 501                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 502
 503       echo '{ global: *; };' >conftest.map
 504       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 505                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 506       rm -f conftest.map
 507
 508       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 509                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 510
 511       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 512                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 513                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 514           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 515                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 516                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 517
 518       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 519                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 520
 521       case $host_cpu in
 522         *i[[3456789]]86* | x86_64)
 523           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 524                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 525           ;;
 526       esac
 527
 528     else
 529       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 530           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 531                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 532       if test "$ac_cv_c_dll_unixware" = "yes"
 533       then
 534         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 535         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 536
 537       else
 538         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 539           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 540         if test "$ac_cv_c_dll_hpux" = "yes"
 541         then
 542           LIBEXT="sl"
 543           DLLEXT=".sl"
 544           LDDLLFLAGS="-shared -fPIC"
 545           LDSHARED="\$(CC) -shared"
 546         fi
 547       fi
 548     fi
 549
 550     dnl Check for cross compiler to build test programs
 551     AC_SUBST(CROSSTEST,"")
 552     if test "$cross_compiling" = "no"
 553     then
 554       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 555       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 556       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 557       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 558       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 559     fi
 560     ;;
 561 esac
 562
 563 if test "$LIBEXT" = "a"; then
 564   AC_MSG_ERROR(
 565 [could not find a way to build shared libraries.
 566 It is currently not possible to build Wine without shared library
 567 (.so) support to allow transparent switch between .so and .dll files.
 568 If you are using Linux, you will need a newer binutils.]
 569 )
 570 fi
 571
 572 dnl **** Check for X11 ****
 573
 574 if test "$have_x" = "yes"
 575 then
 576     XLIB="-lXext -lX11"
 577     ac_save_CPPFLAGS="$CPPFLAGS"
 578     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 579
 580     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 581     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 582
 583     dnl *** All of the following tests require X11/Xlib.h
 584     AC_CHECK_HEADERS([X11/Xlib.h \
 585                       X11/XKBlib.h \
 586                       X11/Xutil.h \
 587                       X11/Xcursor/Xcursor.h \
 588                       X11/extensions/shape.h \
 589                       X11/extensions/XInput.h \
 590                       X11/extensions/XShm.h \
 591                       X11/extensions/Xcomposite.h \
 592                       X11/extensions/Xinerama.h \
 593                       X11/extensions/Xrandr.h \
 594                       X11/extensions/Xrender.h \
 595                       X11/extensions/xf86vmode.h],,,
 596 [#ifdef HAVE_X11_XLIB_H
 597 # include <X11/Xlib.h>
 598 #endif
 599 #ifdef HAVE_X11_XUTIL_H
 600 # include <X11/Xutil.h>
 601 #endif])
 602
 603         dnl *** Check for X keyboard extension
 604         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 605         then
 606               AC_CHECK_LIB(X11, XkbQueryExtension,
 607               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 608               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 609         fi
 610
 611         dnl *** Check for X cursor
 612         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 613         then
 614             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 615         fi
 616         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 617                          [libxcursor development files not found, the Xcursor extension won't be supported.])
 618
 619         dnl *** Check for X input extension
 620         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 621         then
 622             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 623         fi
 624         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 625                          [libxi development files not found, the Xinput extension won't be supported.])
 626
 627         dnl *** Check for X Shm extension
 628         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 629         then
 630               AC_CHECK_LIB(Xext, XShmQueryExtension,
 631               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 632               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 633         fi
 634         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 635                          [XShm development files not found, X Shared Memory won't be supported.])
 636
 637         dnl *** Check for X shape extension
 638         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 639         then
 640               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 641               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 642               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 643         fi
 644         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 645                          [XShape development files not found, XShape won't be supported.])
 646
 647         dnl *** Check for XFree86 VMODE extension
 648         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 649         then
 650                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 651                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 652                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 653                   ],,
 654                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 655         fi
 656         WINE_NOTICE_WITH(xvidmode,[test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],
 657                          [libxxf86vm development files not found, XFree86 Vidmode won't be supported.])
 658
 659         dnl *** Check for Transform functions in Xrender
 660         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 661         then
 662             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 663               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 664                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 665                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 666                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 667
 668         fi
 669         WINE_NOTICE_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 670                          [libxrender development files not found, XRender won't be supported.])
 671
 672         dnl *** Check for X RandR extension
 673         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 674         then
 675                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 676 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 677                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 678         fi
 679         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 680                          [libxrandr development files not found, XRandr won't be supported.])
 681
 682         dnl *** Check for Xinerama extension
 683         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 684         then
 685                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 686 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 687                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 688         fi
 689         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 690                          [libxinerama development files not found, multi-monitor setups won't be supported.])
 691
 692         dnl *** Check for X Composite extension
 693         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 694         then
 695             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 696         fi
 697         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
 698                          [libxcomposite development files not found, Xcomposite won't be supported.])
 699
 700     dnl *** End of X11/Xlib.h check
 701
 702     dnl Check for the presence of OpenGL
 703     opengl_msg=""
 704     if test "x$with_opengl" != "xno"
 705     then
 706         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 707 [#ifdef HAVE_GL_GLX_H
 708 # include <GL/glx.h>
 709 #endif])
 710         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 711         then
 712             dnl Check for some problems due to old Mesa versions
 713             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 714               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 715                 [wine_cv_opengl_header_version_OK="yes"],
 716                 [wine_cv_opengl_header_version_OK="no"]))
 717
 718             if test "$wine_cv_opengl_header_version_OK" = "yes"
 719             then
 720                 dnl Check for the presence of the library
 721                 WINE_CHECK_SONAME(GL,glXCreateContext,
 722                              [OPENGL_LIBS="-lGL"
 723                              OPENGLFILES='$(OPENGLFILES)'
 724                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 725                              [WINE_CHECK_SONAME(GL,glXCreateContext,
 726                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
 727                                     OPENGLFILES='$(OPENGLFILES)'
 728                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 729                                     [if test -f /usr/X11R6/lib/libGL.a
 730                                     then
 731                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
 732 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
 733                                     else
 734                                         opengl_msg="No OpenGL library found on this system."
 735                                     fi],
 736                                     $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
 737                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 738
 739                 dnl Check for GLU32 library.
 740                 AC_CHECK_LIB(GLU,gluLookAt,
 741                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 742                              GLU32FILES='$(GLU32FILES)']
 743                              ,,
 744                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 745              else
 746                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
 747              fi
 748          else
 749              opengl_msg="OpenGL development headers not found."
 750          fi
 751     fi
 752     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
 753 OpenGL and Direct3D won't be supported.])
 754
 755     dnl **** Check for NAS ****
 756     AC_SUBST(NASLIBS,"")
 757     AC_CHECK_HEADERS(audio/audiolib.h,
 758          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 759           AC_CHECK_LIB(audio,AuCreateFlow,
 760                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 761                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 762                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 763                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 764                           [$X_LIBS])
 765                        ],,
 766                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 767
 768     CPPFLAGS="$ac_save_CPPFLAGS"
 769     XFILES='$(XFILES)'
 770 else
 771     XLIB=""
 772     X_CFLAGS=""
 773     X_LIBS=""
 774 fi
 775 WINE_WARNING_WITH(x,[test "x$XLIB" = "x"],[X development files not found. Wine will be built
 776 without X support, which probably isn't what you want. You will need to install
 777 development packages of Xlib/Xfree86 at the very least.])
 778
 779 dnl **** Check for libxml2 ****
 780
 781 AC_SUBST(XML2LIBS,"")
 782 AC_SUBST(XML2INCL,"")
 783 AC_SUBST(XSLTLIBS,"")
 784 AC_SUBST(XSLTINCL,"")
 785 if test "x$with_xml" != "xno"
 786 then
 787     ac_save_CPPFLAGS="$CPPFLAGS"
 788     if test "$PKG_CONFIG" != "false"
 789     then
 790         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 791         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 792     else
 793         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 794         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 795     fi
 796     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 797     AC_CHECK_HEADERS(libxml/parser.h,
 798             [AC_CHECK_LIB(xml2, xmlParseMemory,
 799                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 800                  XML2LIBS="$ac_xml_libs"
 801                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 802              AC_CHECK_LIB(xml2, xmlReadMemory,
 803                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 804              AC_CHECK_LIB(xml2, xmlNewDocPI,
 805                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 806         ])
 807     CPPFLAGS="$ac_save_CPPFLAGS"
 808 fi
 809 WINE_NOTICE_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
 810                  [libxml2 development files not found, XML won't be supported.])
 811
 812 if test "x$with_xslt" != "xno"
 813 then
 814     if test "$PKG_CONFIG" != "false"
 815     then
 816         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 817         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 818     else
 819         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 820         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 821     fi
 822     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 823     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 824             [AC_CHECK_LIB(xslt, xsltCompilePattern,
 825                 [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 826                  XSLTLIBS="$ac_xslt_libs"
 827                  XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 828             ],,
 829     [#ifdef HAVE_LIBXSLT_PATTERN_H
 830 # include <libxslt/pattern.h>
 831 #endif])
 832     CPPFLAGS="$ac_save_CPPFLAGS"
 833 fi
 834 WINE_NOTICE_WITH(xslt,[test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],
 835                  [libxslt development files not found, xslt won't be supported.])
 836
 837 dnl **** Check for libhal ****
 838 AC_SUBST(HALINCL,"")
 839 if test "x$with_hal" != "xno" -a "$PKG_CONFIG" != "false"
 840 then
 841     ac_save_CPPFLAGS="$CPPFLAGS"
 842     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 843     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 844     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 845     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 846     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 847     then
 848         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 849           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 850             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 851     fi
 852     CPPFLAGS="$ac_save_CPPFLAGS"
 853 fi
 854 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x"],
 855                  [libhal development files not found, no dynamic device support.])
 856
 857 dnl **** Check which curses lib to use ***
 858 CURSESLIBS=""
 859 if test "$ac_cv_header_ncurses_h" = "yes"
 860 then
 861     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 862 elif test "$ac_cv_header_curses_h" = "yes"
 863 then
 864     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 865 fi
 866 ac_save_LIBS="$LIBS"
 867 LIBS="$LIBS $CURSESLIBS"
 868 AC_CHECK_FUNCS(mousemask)
 869 LIBS="$ac_save_LIBS"
 870 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
 871                  [lib(n)curses development files not found, curses won't be supported.])
 872
 873 dnl **** Check for SANE ****
 874 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 875 if test "$sane_devel" != "no" -a "x$with_sane" != "xno"
 876 then
 877     ac_sane_incl="`$sane_devel --cflags`"
 878     ac_save_CPPFLAGS="$CPPFLAGS"
 879     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 880     AC_CHECK_HEADER(sane/sane.h,
 881         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 882     CPPFLAGS="$ac_save_CPPFLAGS"
 883 fi
 884 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
 885                  [libsane development files not found, scanners won't be supported.])
 886
 887 dnl **** Check for libgphoto2 ****
 888 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 889 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 890 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no" -a "x$with_gphoto" != "xno"
 891 then
 892     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 893     ac_gphoto2_libs=""
 894     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 895     do
 896       case "$i" in
 897         -L/usr/lib|-L/usr/lib64) ;;
 898         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 899       esac
 900     done
 901     ac_save_CPPFLAGS="$CPPFLAGS"
 902     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 903     AC_CHECK_HEADER(gphoto2-camera.h,
 904                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 905                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 906                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 907                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 908                                   [$GPHOTO2LIBS])])
 909     CPPFLAGS="$ac_save_CPPFLAGS"
 910 fi
 911 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
 912                  [libgphoto2 development files not found, digital cameras won't be supported.])
 913
 914
 915 dnl **** Check for resolver library ***
 916 AC_SUBST(RESOLVLIBS,"")
 917 if test "$ac_cv_header_resolv_h" = "yes"
 918 then
 919     AC_CHECK_LIB(resolv, res_query,
 920         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 921          RESOLVLIBS="-lresolv"])
 922 fi
 923
 924 dnl **** Check for LittleCMS ***
 925 AC_SUBST(LCMSLIBS,"")
 926 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 927 then
 928     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 929         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 930          LCMSLIBS="-llcms"])
 931 fi
 932 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
 933                  [liblcms development files not found, Color Management won't be supported.])
 934
 935 dnl **** Check for OpenLDAP ***
 936 AC_SUBST(LDAPLIBS,"")
 937 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 938 then
 939     AC_CHECK_LIB(ldap_r, ldap_initialize,
 940         [AC_CHECK_LIB(lber, ber_init,
 941             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 942              LDAPLIBS="-lldap_r -llber"],,
 943              [$LIBPTHREAD])],,
 944              [$LIBPTHREAD])
 945     WINE_CHECK_LIB_FUNCS(\
 946         ldap_count_references \
 947         ldap_first_reference \
 948         ldap_next_reference \
 949         ldap_parse_reference \
 950         ldap_parse_sort_control \
 951         ldap_parse_sortresponse_control \
 952         ldap_parse_vlv_control \
 953         ldap_parse_vlvresponse_control,
 954         [$LDAPLIBS $LIBPTHREAD])
 955 fi
 956 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
 957                  [libldap (OpenLDAP) development files not found, LDAP won't be supported.])
 958
 959 dnl **** Check for FreeType 2 ****
 960 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 961 if test "$ft_devel" != "false"
 962 then
 963     ac_freetype_libs=`$ft_devel --libs`
 964     ac_freetype_incl=`$ft_devel --cflags`
 965     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 966     if test "$ft_lib" = "yes"
 967     then
 968         ac_save_CPPFLAGS="$CPPFLAGS"
 969         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 970         AC_CHECK_HEADERS(ft2build.h \
 971                          freetype/freetype.h \
 972                          freetype/ftglyph.h \
 973                          freetype/fttypes.h \
 974                          freetype/tttables.h \
 975                          freetype/ftnames.h \
 976                          freetype/ftsnames.h \
 977                          freetype/ttnameid.h \
 978                          freetype/ftoutln.h \
 979                          freetype/ftwinfnt.h \
 980                          freetype/ftmodapi.h \
 981                          freetype/internal/sfnt.h,,,
 982                          [#if HAVE_FT2BUILD_H
 983                           #include <ft2build.h>
 984                           #endif])
 985         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 986                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 987           [Define if you have the <freetype/fttrigon.h> header file.])
 988                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 989         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 990         ac_save_CFLAGS="$CFLAGS"
 991         CFLAGS="$CFLAGS $ac_freetype_libs"
 992         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 993         CFLAGS="$ac_save_CFLAGS"
 994         CPPFLAGS="$ac_save_CPPFLAGS"
 995         dnl Check that we have at least freetype/freetype.h
 996         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 997         then
 998             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 999             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1000             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1001         fi
1002     fi
1003 fi
1004
1005 dnl Only build the fonts dir if we have both freetype and fontforge
1006 if test "$FONTFORGE" = "false"
1007 then
1008     WINE_WARNING([FontForge is missing.
1009 Fonts will not be built. Dialog text may be invisible or unaligned.])
1010 elif test "x$FREETYPELIBS" = "x"
1011 then
1012     WINE_WARNING([FreeType development files not found.
1013 Fonts will not be built. Dialog text may be invisible or unaligned.])
1014 else
1015   AC_SUBST(FONTSSUBDIRS,"fonts")
1016 fi
1017
1018 dnl **** Check for parport (currently Linux only) ****
1019 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1020  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1021     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1022 if test "$ac_cv_c_ppdev" = "yes"
1023 then
1024     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1025 fi
1026
1027 dnl **** Check for va_copy ****
1028 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
1029  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
1030     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
1031  )
1032 if test "$ac_cv_c_va_copy" = "yes"
1033 then
1034     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
1035 fi
1036 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
1037  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
1038     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
1039  )
1040 if test "$ac_cv_c___va_copy" = "yes"
1041 then
1042     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
1043 fi
1044
1045 dnl **** Check for sigsetjmp ****
1046 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
1047  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
1048     sigsetjmp( buf, 1 );
1049     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
1050  )
1051 if test "$ac_cv_c_sigsetjmp" = "yes"
1052 then
1053     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
1054 fi
1055
1056 dnl **** Check for pthread_rwlock_t ****
1057 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
1058 #include <pthread.h>])
1059
1060 dnl **** Check for pthread functions ****
1061 WINE_CHECK_LIB_FUNCS(\
1062         pthread_attr_get_np \
1063         pthread_getattr_np \
1064         pthread_get_stackaddr_np \
1065         pthread_get_stacksize_np,
1066         [$LIBPTHREAD])
1067
1068 dnl **** Check for EsounD ****
1069 AC_PATH_PROG(ESDCONFIG, esd-config)
1070 if test "x$with_esd" != xno -a "x$ESDCONFIG" != x -a "x$ESDCONFIG" != x'"$ESDCONFIG"';
1071 then
1072     ESD_CFLAGS=""
1073     for i in `$ESDCONFIG --cflags`
1074     do
1075       case "$i" in
1076         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
1077       esac
1078     done
1079     ESD_LIBS=`$ESDCONFIG --libs`
1080     save_CFLAGS="$CFLAGS"
1081     CFLAGS="$CFLAGS $ESD_CFLAGS"
1082     AC_CHECK_LIB(esd,esd_open_sound,
1083         [AC_SUBST(ESDLIBS, $ESD_LIBS)
1084          AC_SUBST(ESDINCL, $ESD_CFLAGS)
1085          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
1086     CFLAGS="$save_CFLAGS"
1087 fi
1088
1089 dnl **** Check for ALSA 1.x ****
1090 AC_SUBST(ALSALIBS,"")
1091 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1092 then
1093     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1094         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1095 #include <alsa/asoundlib.h>
1096 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1097 #include <sys/asoundlib.h>
1098 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1099                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1100                          ALSALIBS="-lasound"],[])])
1101 fi
1102
1103 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1104 AC_SUBST(AUDIOIOLIBS,"")
1105 if test "$ac_cv_header_libaudioio_h" = "yes"
1106 then
1107     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1108                   [AUDIOIOLIBS="-laudioio"
1109                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1110 fi
1111
1112 dnl **** Check for capi4linux ****
1113
1114 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1115 then
1116     WINE_CHECK_SONAME(capi20,capi20_register)
1117 fi
1118 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1119                  [libcapi20 development files not found, ISDN won't be supported.])
1120
1121 dnl **** Check for cups ****
1122 if test "$ac_cv_header_cups_cups_h" = "yes"
1123 then
1124     WINE_CHECK_SONAME(cups,cupsGetDefault)
1125 fi
1126 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1127                  [libcups development files not found, CUPS won't be supported.])
1128
1129 dnl **** Check for jack ****
1130 if test "$ac_cv_header_jack_jack_h" = "yes"
1131 then
1132     WINE_CHECK_SONAME(jack,jack_client_new)
1133 fi
1134
1135 dnl **** Check for fontconfig ****
1136 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1137 then
1138     WINE_CHECK_SONAME(fontconfig,FcInit)
1139 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1140 then
1141     dnl fontconfig is in the X directory on Mac OS X
1142     ac_save_CPPFLAGS="$CPPFLAGS"
1143     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1144     $as_unset ac_cv_header_fontconfig_fontconfig_h
1145     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1146     CPPFLAGS="$ac_save_CPPFLAGS"
1147     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1148     then
1149         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1150         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1151     fi
1152 fi
1153 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1154                  [fontconfig development files not found, fontconfig won't be supported.])
1155
1156 dnl **** Check for SSL ****
1157 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1158 then
1159     WINE_CHECK_SONAME(ssl,SSL_library_init)
1160     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1161 fi
1162 WINE_NOTICE_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x"],
1163                  [OpenSSL development files not found, SSL won't be supported.])
1164
1165 dnl **** Check for libjpeg ****
1166 if test "$ac_cv_header_jpeglib_h" = "yes"
1167 then
1168     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1169 fi
1170 WINE_NOTICE_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1171                  [libjpeg development files not found, JPEG won't be supported.])
1172
1173 dnl **** Check for libpng ****
1174 if test "$ac_cv_header_png_h" = "yes"
1175 then
1176     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1177 fi
1178 WINE_NOTICE_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1179                  [libpng development files not found, PNG won't be supported.])
1180
1181 dnl **** Check for libodbc ****
1182 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1183
1184 dnl **** Check for any sound system ****
1185 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1186         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1187         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1188         "$ac_cv_header_soundcard_h" != "yes" -a \
1189         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1190 then
1191     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1192 fi
1193
1194 dnl **** Check for gcc specific options ****
1195
1196 AC_SUBST(EXTRACFLAGS,"")
1197 if test "x${GCC}" = "xyes"
1198 then
1199   EXTRACFLAGS="-Wall -pipe"
1200
1201   dnl Check for strength-reduce bug
1202   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1203                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1204 [[static int Array[[3]];
1205   unsigned int B = 3;
1206   int i;
1207   for(i=0; i<B; i++) Array[[i]] = i - 3;
1208   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1209   L[[i]] = 4;
1210   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1211     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1212   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1213   then
1214     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1215   fi
1216
1217   dnl Check for some compiler flags
1218
1219   WINE_TRY_CFLAGS([-fshort-wchar],
1220                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1221                              [Specifies the compiler flag that forces a short wchar_t])])
1222   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1223   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1224   WINE_TRY_CFLAGS([-Wwrite-strings])
1225   WINE_TRY_CFLAGS([-Wtype-limits])
1226
1227   dnl Check for noisy string.h
1228   saved_CFLAGS="$CFLAGS"
1229   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1230   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1231       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1232   CFLAGS="$saved_CFLAGS"
1233   if test "$ac_cv_c_string_h_warnings" = "no"
1234   then
1235     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1236   fi
1237
1238   AC_SUBST(BUILTINFLAG,"")
1239   saved_CFLAGS="$CFLAGS"
1240   CFLAGS="$CFLAGS -Werror"
1241   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1242       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1243   CFLAGS="$saved_CFLAGS"
1244   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1245   then
1246     BUILTINFLAG="-fno-builtin"
1247   fi
1248 fi
1249
1250 dnl **** Check how to define a function in assembly code ****
1251
1252 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1253   WINE_TRY_ASM_LINK(
1254       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1255       ac_cv_asm_func_def=".def",
1256     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1257       ac_cv_asm_func_def=".type @function",
1258     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1259       ac_cv_asm_func_def=".type 2",
1260       ac_cv_asm_func_def="unknown")])]))
1261
1262 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1263 case "$ac_cv_asm_func_def" in
1264   ".def")
1265      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1266   ".type @function")
1267      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1268   ".type 2")
1269      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1270   *)
1271      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1272 esac
1273
1274 dnl **** Check for underscore on external symbols ****
1275
1276 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1277     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1278                       [extern int ac_test;],
1279                       [if (ac_test) return 1],
1280                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1281
1282 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1283 if test "$ac_cv_c_extern_prefix" = "yes"
1284 then
1285   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1286 else
1287   AC_DEFINE([__ASM_NAME(name)], [name])
1288 fi
1289
1290 dnl **** Platform-specific checks ****
1291
1292 AC_SUBST(LDPATH,"")
1293 case $build_os in
1294   cygwin*|mingw32*)
1295     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1296     ;;
1297   darwin*|macosx*)
1298     ;;
1299   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1300     if test -z "$LDRPATH_LOCAL"
1301     then
1302       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1303     fi
1304     ;;
1305   *)
1306     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1307     ;;
1308 esac
1309
1310 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1311 case $host_os in
1312   mingw32*)
1313     AC_SUBST(CRTLIBS,"-lmsvcrt")
1314     AC_SUBST(SOCKETLIBS,"-lws2_32")
1315     ;;
1316 esac
1317
1318 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1319 case $host_cpu in
1320   *i[[3456789]]86*)
1321     case $host_os in
1322       linux* | k*bsd*-gnu)
1323         AC_SUBST(MAIN_BINARY,"wine-glibc")
1324         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1325       freebsd*)
1326         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1327         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1328     esac
1329     ;;
1330 esac
1331
1332 dnl **** Check for functions ****
1333
1334 AC_CHECK_FUNCS(\
1335         _pclose \
1336         _popen \
1337         _snprintf \
1338         _spawnvp \
1339         _strdup \
1340         _stricmp \
1341         _strnicmp \
1342         _vsnprintf \
1343         asctime_r \
1344         chsize \
1345         clone \
1346         dlopen \
1347         epoll_create \
1348         ffs \
1349         finite \
1350         fork \
1351         fpclass \
1352         fstatfs \
1353         fstatvfs \
1354         ftruncate \
1355         futimes \
1356         futimesat \
1357         getdirentries \
1358         getopt_long \
1359         getpagesize \
1360         getpwuid \
1361         gettid \
1362         gettimeofday \
1363         getuid \
1364         inet_pton \
1365         kqueue \
1366         lstat \
1367         memmove \
1368         mmap \
1369         pclose \
1370         poll \
1371         popen \
1372         prctl \
1373         pread \
1374         pwrite \
1375         readlink \
1376         rfork \
1377         sched_yield \
1378         select \
1379         setproctitle \
1380         setrlimit \
1381         settimeofday \
1382         sigaltstack \
1383         sigprocmask \
1384         snprintf \
1385         spawnvp \
1386         statfs \
1387         statvfs \
1388         strcasecmp \
1389         strdup \
1390         strerror \
1391         strncasecmp \
1392         strtold \
1393         tcgetattr \
1394         thr_kill2 \
1395         timegm \
1396         usleep \
1397         vsnprintf \
1398         wait4 \
1399         waitpid \
1400 )
1401
1402 dnl Check for -ldl
1403 if test "$ac_cv_func_dlopen" = no
1404 then
1405     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1406 fi
1407 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1408
1409 dnl Check for -lpoll for Mac OS X/Darwin
1410 if test "$ac_cv_func_poll" = no
1411 then
1412     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1413 fi
1414
1415 dnl Check for -lnsl for Solaris
1416 AC_SEARCH_LIBS(gethostbyname, nsl)
1417
1418 dnl Check for -lsocket for Solaris
1419 AC_SEARCH_LIBS(connect, socket)
1420
1421 dnl Check for -lresolv for Solaris
1422 AC_SEARCH_LIBS(inet_aton, resolv)
1423
1424 dnl **** Check for functions which may rely on -lsocket on Solaris.
1425 AC_CHECK_FUNCS(\
1426         getaddrinfo \
1427         getnameinfo \
1428         getnetbyname \
1429         getprotobyname \
1430         getprotobynumber \
1431         getservbyport \
1432         inet_network \
1433         sendmsg \
1434 )
1435
1436 dnl **** Check for types ****
1437
1438 AC_C_CONST
1439 AC_C_INLINE
1440 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1441 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1442 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1443
1444 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1445 [#ifdef HAVE_LINUX_INPUT_H
1446 #include <linux/input.h>
1447 #endif])
1448
1449 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1450                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1451 if test "$wine_cv_have_sigaddset" = "yes"
1452 then
1453   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1454 fi
1455
1456
1457 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1458         wine_cv_linux_gethostbyname_r_6,
1459         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1460     char *name=0;
1461     struct hostent he;
1462     struct hostent *result;
1463     char *buf=0;
1464     int bufsize=0;
1465     int res,errnr;
1466     char *addr=0;
1467     int addrlen=0;
1468     int addrtype=0;
1469     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1470     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1471     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1472         ])
1473    )
1474    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1475    then
1476       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1477                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1478    fi
1479
1480 if test "$ac_cv_header_linux_joystick_h" = "yes"
1481 then
1482    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1483         wine_cv_linux_joystick_22_api,
1484         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1485         #include <sys/ioctl.h>
1486         #include <sys/types.h>
1487         #include <linux/joystick.h>
1488
1489         struct js_event blub;
1490         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1491         #error "no 2.2 header"
1492         #endif
1493         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1494    )
1495    if test "$wine_cv_linux_joystick_22_api" = "yes"
1496    then
1497       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1498                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1499    fi
1500 fi
1501
1502 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1503
1504 dnl Check for statfs members
1505 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1506 [#include <sys/types.h>
1507 #ifdef HAVE_SYS_PARAM_H
1508 # include <sys/param.h>
1509 #endif
1510 #ifdef HAVE_SYS_MOUNT_H
1511 # include <sys/mount.h>
1512 #endif
1513 #ifdef HAVE_SYS_VFS_H
1514 # include <sys/vfs.h>
1515 #endif
1516 #ifdef HAVE_SYS_STATFS_H
1517 # include <sys/statfs.h>
1518 #endif])
1519
1520 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1521 [#ifdef HAVE_SYS_STATVFS_H
1522 #include <sys/statvfs.h>
1523 #endif])
1524
1525 dnl Check for socket structure members
1526 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1527 [#include <sys/types.h>
1528 #ifdef HAVE_SYS_SOCKET_H
1529 # include <sys/socket.h>
1530 #endif
1531 #ifdef HAVE_SYS_UN_H
1532 # include <sys/un.h>
1533 #endif])
1534
1535 dnl Check for scsireq_t and sg_io_hdr_t members
1536 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1537 [#include <sys/types.h>
1538 #ifdef HAVE_SCSI_SG_H
1539 #include <scsi/sg.h>
1540 #endif])
1541
1542 dnl Check for siginfo_t members
1543 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1544
1545 dnl Check for struct mtget members
1546 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1547 [#include <sys/types.h>
1548 #ifdef HAVE_SYS_MTIO_H
1549 #include <sys/mtio.h>
1550 #endif])
1551
1552 dnl Check for struct option
1553 AC_CHECK_MEMBERS([struct option.name],,,
1554 [#ifdef HAVE_GETOPT_H
1555 #include <getopt.h>
1556 #endif])
1557
1558 dnl Check for stat.st_blocks
1559 AC_CHECK_MEMBERS([struct stat.st_blocks])
1560
1561 dnl Check for sin6_scope_id
1562 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1563 [#ifdef HAVE_SYS_TYPES_H
1564 #include <sys/types.h>
1565 #endif
1566 #ifdef HAVE_NETINET_IN_H
1567 #include <netinet/in.h>
1568 #endif])
1569
1570 dnl Check for ns_msg ptr member
1571 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1572 [#ifdef HAVE_SYS_TYPES_H
1573 #include <sys/types.h>
1574 #endif
1575 #ifdef HAVE_NETINET_IN_H
1576 # include <netinet/in.h>
1577 #endif
1578 #ifdef HAVE_ARPA_NAMESER_H
1579 # include <arpa/nameser.h>
1580 #endif])
1581
1582 dnl Check for the external timezone variables timezone and daylight
1583 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1584                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1585 if test "$ac_cv_have_timezone" = "yes"
1586 then
1587     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1588 fi
1589 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1590                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1591 if test "$ac_cv_have_daylight" = "yes"
1592 then
1593     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1594 fi
1595
1596 dnl *** check for the need to define platform-specific symbols
1597
1598 case $host_cpu in
1599   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1600   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1601   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1602   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1603   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1604 esac
1605
1606 case $host_vendor in
1607   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1608 esac
1609
1610 dnl **** Generate output files ****
1611
1612 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1613 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1614 ["### Dependencies:\\
1615 \\
1616 .INIT: Makefile\\
1617 .BEGIN: Makefile\\
1618 Makefile: dummy\\
1619         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1620 \\
1621 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1622 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1623 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1624 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1625 ["### Dependencies:
1626
1627 .INIT: Makefile
1628 .BEGIN: Makefile
1629 Makefile: dummy
1630         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1631
1632 \$(OBJS): \$(IDL_GEN_HEADERS)
1633 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1634 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1635 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1636
1637 AH_TOP([#define __WINE_CONFIG_H])
1638
1639 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1640
1641 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1642 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1643 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1644 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1645 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1646 WINE_CONFIG_EXTRA_DIR(include/wine)
1647
1648 MAKE_RULES=Make.rules
1649 AC_SUBST_FILE(MAKE_RULES)
1650
1651 MAKE_DLL_RULES=dlls/Makedll.rules
1652 AC_SUBST_FILE(MAKE_DLL_RULES)
1653
1654 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1655 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1656
1657 MAKE_TEST_RULES=dlls/Maketest.rules
1658 AC_SUBST_FILE(MAKE_TEST_RULES)
1659
1660 MAKE_PROG_RULES=programs/Makeprog.rules
1661 AC_SUBST_FILE(MAKE_PROG_RULES)
1662
1663 AC_CONFIG_FILES([Make.rules])
1664 AC_CONFIG_FILES([dlls/Makedll.rules])
1665 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1666 AC_CONFIG_FILES([dlls/Maketest.rules])
1667 AC_CONFIG_FILES([programs/Makeprog.rules])
1668 AC_CONFIG_FILES([Makefile])
1669 AC_CONFIG_FILES([dlls/Makefile])
1670 AC_CONFIG_FILES([dlls/acledit/Makefile])
1671 AC_CONFIG_FILES([dlls/activeds/Makefile])
1672 AC_CONFIG_FILES([dlls/actxprxy/Makefile])
1673 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1674 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1675 AC_CONFIG_FILES([dlls/advpack/Makefile])
1676 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1677 AC_CONFIG_FILES([dlls/amstream/Makefile])
1678 AC_CONFIG_FILES([dlls/atl/Makefile])
1679 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1680 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1681 AC_CONFIG_FILES([dlls/browseui/Makefile])
1682 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1683 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1684 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1685 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1686 AC_CONFIG_FILES([dlls/cards/Makefile])
1687 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1688 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1689 AC_CONFIG_FILES([dlls/comcat/Makefile])
1690 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1691 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1692 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1693 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1694 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1695 AC_CONFIG_FILES([dlls/compstui/Makefile])
1696 AC_CONFIG_FILES([dlls/credui/Makefile])
1697 AC_CONFIG_FILES([dlls/credui/tests/Makefile])
1698 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1699 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1700 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1701 AC_CONFIG_FILES([dlls/cryptdlg/Makefile])
1702 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1703 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1704 AC_CONFIG_FILES([dlls/cryptnet/tests/Makefile])
1705 AC_CONFIG_FILES([dlls/ctapi32/Makefile])
1706 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1707 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1708 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1709 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1710 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1711 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1712 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1713 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1714 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1715 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1716 AC_CONFIG_FILES([dlls/d3dx8/tests/Makefile])
1717 AC_CONFIG_FILES([dlls/d3dx9_24/Makefile])
1718 AC_CONFIG_FILES([dlls/d3dx9_25/Makefile])
1719 AC_CONFIG_FILES([dlls/d3dx9_26/Makefile])
1720 AC_CONFIG_FILES([dlls/d3dx9_27/Makefile])
1721 AC_CONFIG_FILES([dlls/d3dx9_28/Makefile])
1722 AC_CONFIG_FILES([dlls/d3dx9_29/Makefile])
1723 AC_CONFIG_FILES([dlls/d3dx9_30/Makefile])
1724 AC_CONFIG_FILES([dlls/d3dx9_31/Makefile])
1725 AC_CONFIG_FILES([dlls/d3dx9_32/Makefile])
1726 AC_CONFIG_FILES([dlls/d3dx9_33/Makefile])
1727 AC_CONFIG_FILES([dlls/d3dx9_34/Makefile])
1728 AC_CONFIG_FILES([dlls/d3dx9_35/Makefile])
1729 AC_CONFIG_FILES([dlls/d3dx9_36/Makefile])
1730 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1731 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1732 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1733 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1734 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1735 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1736 AC_CONFIG_FILES([dlls/devenum/Makefile])
1737 AC_CONFIG_FILES([dlls/dinput/Makefile])
1738 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1739 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1740 AC_CONFIG_FILES([dlls/dmband/Makefile])
1741 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1742 AC_CONFIG_FILES([dlls/dmime/Makefile])
1743 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1744 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1745 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1746 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1747 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1748 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1749 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1750 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1751 AC_CONFIG_FILES([dlls/dplay/Makefile])
1752 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1753 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1754 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1755 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1756 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1757 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1758 AC_CONFIG_FILES([dlls/dsound/Makefile])
1759 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1760 AC_CONFIG_FILES([dlls/dssenh/Makefile])
1761 AC_CONFIG_FILES([dlls/dswave/Makefile])
1762 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1763 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1764 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1765 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1766 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1767 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1768 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1769 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1770 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1771 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1772 AC_CONFIG_FILES([dlls/glu32/Makefile])
1773 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1774 AC_CONFIG_FILES([dlls/gpkcsp/Makefile])
1775 AC_CONFIG_FILES([dlls/hal/Makefile])
1776 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1777 AC_CONFIG_FILES([dlls/hid/Makefile])
1778 AC_CONFIG_FILES([dlls/hlink/Makefile])
1779 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1780 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1781 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1782 AC_CONFIG_FILES([dlls/icmp/Makefile])
1783 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1784 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1785 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1786 AC_CONFIG_FILES([dlls/imm32/Makefile])
1787 AC_CONFIG_FILES([dlls/imm32/tests/Makefile])
1788 AC_CONFIG_FILES([dlls/inetcomm/Makefile])
1789 AC_CONFIG_FILES([dlls/inetcomm/tests/Makefile])
1790 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1791 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1792 AC_CONFIG_FILES([dlls/initpki/Makefile])
1793 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1794 AC_CONFIG_FILES([dlls/inseng/Makefile])
1795 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1796 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1797 AC_CONFIG_FILES([dlls/itircl/Makefile])
1798 AC_CONFIG_FILES([dlls/itss/Makefile])
1799 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1800 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1801 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1802 AC_CONFIG_FILES([dlls/localspl/Makefile])
1803 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1804 AC_CONFIG_FILES([dlls/localui/Makefile])
1805 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1806 AC_CONFIG_FILES([dlls/lz32/Makefile])
1807 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1808 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1809 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1810 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1811 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1812 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1813 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1814 AC_CONFIG_FILES([dlls/midimap/Makefile])
1815 AC_CONFIG_FILES([dlls/mlang/Makefile])
1816 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1817 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1818 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1819 AC_CONFIG_FILES([dlls/mountmgr.sys/Makefile])
1820 AC_CONFIG_FILES([dlls/mpr/Makefile])
1821 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1822 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1823 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1824 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1825 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1826 AC_CONFIG_FILES([dlls/mscat32/Makefile])
1827 AC_CONFIG_FILES([dlls/mscms/Makefile])
1828 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1829 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1830 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1831 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1832 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1833 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1834 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1835 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1836 AC_CONFIG_FILES([dlls/msi/Makefile])
1837 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1838 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1839 AC_CONFIG_FILES([dlls/msimtf/Makefile])
1840 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1841 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1842 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1843 AC_CONFIG_FILES([dlls/mssip32/Makefile])
1844 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1845 AC_CONFIG_FILES([dlls/msvcr71/Makefile])
1846 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1847 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1848 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1849 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1850 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1851 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1852 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1853 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1854 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1855 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1856 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1857 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1858 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1859 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1860 AC_CONFIG_FILES([dlls/newdev/Makefile])
1861 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1862 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1863 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1864 AC_CONFIG_FILES([dlls/ntdsapi/tests/Makefile])
1865 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1866 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1867 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1868 AC_CONFIG_FILES([dlls/objsel/Makefile])
1869 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1870 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1871 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1872 AC_CONFIG_FILES([dlls/ole32/Makefile])
1873 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1874 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1875 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1876 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1877 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1878 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1879 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1880 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1881 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1882 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1883 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1884 AC_CONFIG_FILES([dlls/pdh/Makefile])
1885 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1886 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1887 AC_CONFIG_FILES([dlls/printui/Makefile])
1888 AC_CONFIG_FILES([dlls/propsys/Makefile])
1889 AC_CONFIG_FILES([dlls/psapi/Makefile])
1890 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1891 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1892 AC_CONFIG_FILES([dlls/qcap/Makefile])
1893 AC_CONFIG_FILES([dlls/qedit/Makefile])
1894 AC_CONFIG_FILES([dlls/qedit/tests/Makefile])
1895 AC_CONFIG_FILES([dlls/qmgr/Makefile])
1896 AC_CONFIG_FILES([dlls/qmgr/tests/Makefile])
1897 AC_CONFIG_FILES([dlls/qmgrprxy/Makefile])
1898 AC_CONFIG_FILES([dlls/quartz/Makefile])
1899 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1900 AC_CONFIG_FILES([dlls/query/Makefile])
1901 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1902 AC_CONFIG_FILES([dlls/resutils/Makefile])
1903 AC_CONFIG_FILES([dlls/riched20/Makefile])
1904 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1905 AC_CONFIG_FILES([dlls/riched32/Makefile])
1906 AC_CONFIG_FILES([dlls/riched32/tests/Makefile])
1907 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1908 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1909 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1910 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1911 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1912 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1913 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1914 AC_CONFIG_FILES([dlls/sccbase/Makefile])
1915 AC_CONFIG_FILES([dlls/schannel/Makefile])
1916 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1917 AC_CONFIG_FILES([dlls/secur32/Makefile])
1918 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1919 AC_CONFIG_FILES([dlls/security/Makefile])
1920 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1921 AC_CONFIG_FILES([dlls/serialui/Makefile])
1922 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1923 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1924 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1925 AC_CONFIG_FILES([dlls/sfc/Makefile])
1926 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1927 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1928 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1929 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1930 AC_CONFIG_FILES([dlls/shell32/Makefile])
1931 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1932 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1933 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1934 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1935 AC_CONFIG_FILES([dlls/slbcsp/Makefile])
1936 AC_CONFIG_FILES([dlls/slc/Makefile])
1937 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1938 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1939 AC_CONFIG_FILES([dlls/softpub/Makefile])
1940 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1941 AC_CONFIG_FILES([dlls/spoolss/tests/Makefile])
1942 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1943 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1944 AC_CONFIG_FILES([dlls/sti/Makefile])
1945 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1946 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1947 AC_CONFIG_FILES([dlls/sxs/Makefile])
1948 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1949 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1950 AC_CONFIG_FILES([dlls/unicows/Makefile])
1951 AC_CONFIG_FILES([dlls/url/Makefile])
1952 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1953 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1954 AC_CONFIG_FILES([dlls/user32/Makefile])
1955 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1956 AC_CONFIG_FILES([dlls/userenv/Makefile])
1957 AC_CONFIG_FILES([dlls/usp10/Makefile])
1958 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1959 AC_CONFIG_FILES([dlls/uuid/Makefile])
1960 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1961 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1962 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1963 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1964 AC_CONFIG_FILES([dlls/version/Makefile])
1965 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1966 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1967 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1968 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1969 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1970 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1971 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1972 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1973 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1974 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1975 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1976 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1977 AC_CONFIG_FILES([dlls/winedos/Makefile])
1978 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1979 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1980 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1981 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1982 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1983 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1984 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1985 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1986 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1987 AC_CONFIG_FILES([dlls/wing32/Makefile])
1988 AC_CONFIG_FILES([dlls/winhttp/Makefile])
1989 AC_CONFIG_FILES([dlls/wininet/Makefile])
1990 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1991 AC_CONFIG_FILES([dlls/winmm/Makefile])
1992 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1993 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1994 AC_CONFIG_FILES([dlls/winscard/Makefile])
1995 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1996 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1997 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1998 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1999 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
2000 AC_CONFIG_FILES([dlls/wldap32/Makefile])
2001 AC_CONFIG_FILES([dlls/wmi/Makefile])
2002 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
2003 AC_CONFIG_FILES([dlls/wow32/Makefile])
2004 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
2005 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
2006 AC_CONFIG_FILES([dlls/wsock32/Makefile])
2007 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
2008 AC_CONFIG_FILES([documentation/Makefile])
2009 AC_CONFIG_FILES([fonts/Makefile])
2010 AC_CONFIG_FILES([include/Makefile])
2011 AC_CONFIG_FILES([libs/Makefile])
2012 AC_CONFIG_FILES([libs/port/Makefile])
2013 AC_CONFIG_FILES([libs/wine/Makefile])
2014 AC_CONFIG_FILES([libs/wpp/Makefile])
2015 AC_CONFIG_FILES([loader/Makefile])
2016 AC_CONFIG_FILES([programs/Makefile])
2017 AC_CONFIG_FILES([programs/clock/Makefile])
2018 AC_CONFIG_FILES([programs/cmd/Makefile])
2019 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
2020 AC_CONFIG_FILES([programs/control/Makefile])
2021 AC_CONFIG_FILES([programs/eject/Makefile])
2022 AC_CONFIG_FILES([programs/expand/Makefile])
2023 AC_CONFIG_FILES([programs/explorer/Makefile])
2024 AC_CONFIG_FILES([programs/hh/Makefile])
2025 AC_CONFIG_FILES([programs/icinfo/Makefile])
2026 AC_CONFIG_FILES([programs/iexplore/Makefile])
2027 AC_CONFIG_FILES([programs/msiexec/Makefile])
2028 AC_CONFIG_FILES([programs/net/Makefile])
2029 AC_CONFIG_FILES([programs/notepad/Makefile])
2030 AC_CONFIG_FILES([programs/oleview/Makefile])
2031 AC_CONFIG_FILES([programs/progman/Makefile])
2032 AC_CONFIG_FILES([programs/regedit/Makefile])
2033 AC_CONFIG_FILES([programs/regsvr32/Makefile])
2034 AC_CONFIG_FILES([programs/rpcss/Makefile])
2035 AC_CONFIG_FILES([programs/rundll32/Makefile])
2036 AC_CONFIG_FILES([programs/secedit/Makefile])
2037 AC_CONFIG_FILES([programs/spoolsv/Makefile])
2038 AC_CONFIG_FILES([programs/start/Makefile])
2039 AC_CONFIG_FILES([programs/svchost/Makefile])
2040 AC_CONFIG_FILES([programs/taskmgr/Makefile])
2041 AC_CONFIG_FILES([programs/uninstaller/Makefile])
2042 AC_CONFIG_FILES([programs/view/Makefile])
2043 AC_CONFIG_FILES([programs/wineboot/Makefile])
2044 AC_CONFIG_FILES([programs/winebrowser/Makefile])
2045 AC_CONFIG_FILES([programs/winecfg/Makefile])
2046 AC_CONFIG_FILES([programs/wineconsole/Makefile])
2047 AC_CONFIG_FILES([programs/winedbg/Makefile])
2048 AC_CONFIG_FILES([programs/winedevice/Makefile])
2049 AC_CONFIG_FILES([programs/winefile/Makefile])
2050 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
2051 AC_CONFIG_FILES([programs/winemine/Makefile])
2052 AC_CONFIG_FILES([programs/winepath/Makefile])
2053 AC_CONFIG_FILES([programs/winetest/Makefile])
2054 AC_CONFIG_FILES([programs/winevdm/Makefile])
2055 AC_CONFIG_FILES([programs/winhelp/Makefile])
2056 AC_CONFIG_FILES([programs/winver/Makefile])
2057 AC_CONFIG_FILES([programs/wordpad/Makefile])
2058 AC_CONFIG_FILES([programs/write/Makefile])
2059 AC_CONFIG_FILES([programs/xcopy/Makefile])
2060 AC_CONFIG_FILES([server/Makefile])
2061 AC_CONFIG_FILES([tools/Makefile])
2062 AC_CONFIG_FILES([tools/widl/Makefile])
2063 AC_CONFIG_FILES([tools/winebuild/Makefile])
2064 AC_CONFIG_FILES([tools/winedump/Makefile])
2065 AC_CONFIG_FILES([tools/winegcc/Makefile])
2066 AC_CONFIG_FILES([tools/wmc/Makefile])
2067 AC_CONFIG_FILES([tools/wrc/Makefile])
2068
2069 AC_OUTPUT
2070
2071 if test "$no_create" = "yes"
2072 then
2073   exit 0
2074 fi
2075
2076 WINE_PRINT_MESSAGES
2077
2078 echo "
2079 $as_me: Finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine.
2080 " >&AS_MESSAGE_FD
2081
2082 dnl Local Variables:
2083 dnl comment-start: "dnl "
2084 dnl comment-end: ""
2085 dnl comment-start-skip: "\\bdnl\\b\\s *"
2086 dnl compile-command: "autoreconf --warnings=all"
2087 dnl End: