configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]),
  18                                ,[AC_SUBST([MAINTAINER_MODE],[\#])])
  19
  20 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  21             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  22 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  23             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  24 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  25             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  26 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  27             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  28 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  29             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  30 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  31 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  32             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  33 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  34 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  36 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  37 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  38 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_GL_glu_h=no; fi])
  40 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  41 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  42             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  43 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  45 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  46             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  47 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  48             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  49 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  50 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  51             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  52 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  54 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  55             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  56 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  57 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  58             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  59 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  61 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  63 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  65 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  66 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  67             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  68 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  69             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  70 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  71             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  72 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  73             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  74 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  75 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
  76             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; fi])
  77
  78 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  79 AC_ARG_ENABLE(tests, AC_HELP_STRING([--disable-tests],[do not build the testsuites]))
  80
  81 AC_CANONICAL_HOST
  82 case $host in
  83   x86_64*linux*)
  84     if test "x$enable_win64" != "xyes"
  85     then
  86       test -n "$CC" || CC="gcc -m32"
  87       test -n "$CXX"|| CXX="g++ -m32"
  88       test -n "$LD" || LD="ld -m elf_i386"
  89       test -n "$AS" || AS="as --32"
  90       host_cpu="i386"
  91     fi
  92     ;;
  93 esac
  94
  95 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  96 case $host_cpu in
  97   *i[[3456789]]86*)
  98     if test "x$enable_win16" != "xno"
  99     then
 100       enable_win16="yes"
 101     fi
 102     ;;
 103 esac
 104
 105 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
 106 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
 107 if test "x$enable_win16" != "xyes"
 108 then
 109   WIN16_FILES=""
 110   WIN16_INSTALL=""
 111 fi
 112
 113 dnl enable_tests is yes by default, but in some cases it's better to disable the testsuite
 114 if test "x$enable_tests" == "xno"
 115 then
 116   AC_SUBST(TESTSUBDIRS,"")
 117   AC_SUBST(WINETEST,"")
 118 else
 119   AC_SUBST(TESTSUBDIRS,"\$(TESTSUBDIRS)")
 120   AC_SUBST(WINETEST,"winetest")
 121 fi
 122
 123 dnl check for out of tree build with unclean source tree
 124 case "$srcdir" in
 125  .) ;;
 126  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 127       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 128 You need to run 'make distclean' in the source tree first.])
 129     fi ;;
 130 esac
 131
 132 dnl **** Check for some programs ****
 133
 134 AC_PROG_MAKE_SET
 135 AC_PROG_CC
 136 AC_PROG_CXX
 137 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 138 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 139
 140 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 141   [if test -z "$with_wine_tools"; then
 142      if test "$cross_compiling" = "yes"; then
 143        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 144      else
 145        wine_cv_toolsdir="\$(TOPOBJDIR)"
 146      fi
 147    elif test -d "$with_wine_tools/tools/winebuild"; then
 148      case $with_wine_tools in
 149        /*) wine_cv_toolsdir="$with_wine_tools" ;;
 150        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
 151      esac
 152    else
 153      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
 154    fi])
 155 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 156
 157 AC_PATH_XTRA
 158
 159 dnl Check for flex
 160 AC_CHECK_PROGS(FLEX,flex,none)
 161 if test "$FLEX" = "none"
 162 then
 163   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 164 fi
 165
 166 dnl Check for bison
 167 AC_CHECK_PROGS(BISON,bison,none)
 168 if test "$BISON" = "none"
 169 then
 170   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 171 fi
 172
 173 AC_CHECK_TOOLS(AS,[gas as],as)
 174 AC_CHECK_TOOLS(LD,[ld gld],ld)
 175 AC_CHECK_TOOLS(NM,[nm gnm],nm)
 176 AC_CHECK_TOOLS(AR,[ar gar],ar)
 177 AC_SUBST(ARFLAGS,rc)
 178 AC_PROG_RANLIB
 179 AC_CHECK_TOOL(STRIP,strip,strip)
 180 AC_CHECK_TOOL(WINDRES,windres,false)
 181 AC_PROG_LN_S
 182 WINE_PROG_LN
 183 AC_PROG_EGREP
 184 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 185 AC_PROG_INSTALL
 186 dnl Prepend src dir to install path dir if it's a relative path
 187 case "$INSTALL" in
 188   [[\\/$]]* | ?:[[\\/]]* ) ;;
 189   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 190 esac
 191
 192 dnl Check for lint
 193 AC_CHECK_PROGS(LINT, lclint lint)
 194 if test "$LINT" = "lint"
 195 then
 196   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 197   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 198 fi
 199 AC_SUBST(LINT)
 200 AC_SUBST(LINTFLAGS)
 201
 202 dnl Check for various programs
 203 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 204 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 205 AC_CHECK_PROGS(RSVG, rsvg, false)
 206 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 207
 208 if test "${enable_maintainer_mode+set}" = set
 209 then
 210   if test "$FONTFORGE" = "false"; then WINE_WARNING([fontforge is missing, fonts can't be rebuilt.]); fi
 211   if test "$RSVG" = "false"; then WINE_WARNING([rsvg is missing, icons can't be rebuilt.]); fi
 212   if test "$ICOTOOL" = "false"; then WINE_WARNING([icotool is missing, icons can't be rebuilt.]); fi
 213 fi
 214
 215 case $host_cpu in
 216   *i[[3456789]]86*)
 217     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 218     ;;
 219 esac
 220
 221 dnl **** Check for some libraries ****
 222
 223 dnl Check for -li386 for NetBSD and OpenBSD
 224 AC_CHECK_LIB(i386,i386_set_ldt)
 225 dnl Check for -lossaudio for NetBSD
 226 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 227 dnl Check for -lpthread
 228 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 229
 230 AC_SUBST(XLIB,"")
 231 AC_SUBST(XFILES,"")
 232 AC_SUBST(OPENGLFILES,"")
 233 AC_SUBST(GLU32FILES,"")
 234 AC_SUBST(OPENGL_LIBS,"")
 235 AC_SUBST(QUARTZFILES,"")
 236
 237 dnl **** Check for header files ****
 238
 239 AC_CHECK_HEADERS(\
 240         AudioUnit/AudioUnit.h \
 241         Carbon/Carbon.h \
 242         CoreAudio/CoreAudio.h \
 243         DiskArbitration/DiskArbitration.h \
 244         IOKit/IOKitLib.h \
 245         alias.h \
 246         alsa/asoundlib.h \
 247         arpa/inet.h \
 248         arpa/nameser.h \
 249         asm/types.h \
 250         capi20.h \
 251         curses.h \
 252         direct.h \
 253         dlfcn.h \
 254         elf.h \
 255         float.h \
 256         fontconfig/fontconfig.h \
 257         getopt.h \
 258         ieeefp.h \
 259         io.h \
 260         jack/jack.h \
 261         jpeglib.h \
 262         lber.h \
 263         lcms.h \
 264         lcms/lcms.h \
 265         ldap.h \
 266         libaudioio.h \
 267         link.h \
 268         linux/cdrom.h \
 269         linux/compiler.h \
 270         linux/hdreg.h \
 271         linux/input.h \
 272         linux/ioctl.h \
 273         linux/joystick.h \
 274         linux/major.h \
 275         linux/param.h \
 276         linux/serial.h \
 277         linux/ucdrom.h \
 278         mach/mach.h \
 279         mach/machine.h \
 280         machine/cpu.h \
 281         machine/limits.h \
 282         machine/soundcard.h \
 283         mntent.h \
 284         ncurses.h \
 285         netdb.h \
 286         netinet/in.h \
 287         netinet/in_systm.h \
 288         netinet/tcp.h \
 289         netinet/tcp_fsm.h \
 290         openssl/err.h \
 291         openssl/ssl.h \
 292         png.h \
 293         poll.h \
 294         process.h \
 295         pthread.h \
 296         pwd.h \
 297         regex.h \
 298         sched.h \
 299         scsi/scsi.h \
 300         scsi/scsi_ioctl.h \
 301         scsi/sg.h \
 302         soundcard.h \
 303         stdint.h \
 304         strings.h \
 305         sys/asoundlib.h \
 306         sys/cdio.h \
 307         sys/elf32.h \
 308         sys/epoll.h \
 309         sys/errno.h \
 310         sys/event.h \
 311         sys/exec_elf.h \
 312         sys/filio.h \
 313         sys/ioctl.h \
 314         sys/ipc.h \
 315         sys/limits.h \
 316         sys/link.h \
 317         sys/lwp.h \
 318         sys/mman.h \
 319         sys/modem.h \
 320         sys/msg.h \
 321         sys/mtio.h \
 322         sys/param.h \
 323         sys/poll.h \
 324         sys/prctl.h \
 325         sys/ptrace.h \
 326         sys/reg.h \
 327         sys/resource.h \
 328         sys/scsiio.h \
 329         sys/shm.h \
 330         sys/signal.h \
 331         sys/socket.h \
 332         sys/socketvar.h \
 333         sys/sockio.h \
 334         sys/soundcard.h \
 335         sys/statvfs.h \
 336         sys/strtio.h \
 337         sys/syscall.h \
 338         sys/sysctl.h \
 339         sys/time.h \
 340         sys/times.h \
 341         sys/uio.h \
 342         sys/un.h \
 343         sys/vm86.h \
 344         sys/wait.h \
 345         syscall.h \
 346         termios.h \
 347         unistd.h \
 348         utime.h \
 349         valgrind/memcheck.h \
 350         valgrind/valgrind.h
 351 )
 352 AC_HEADER_STAT()
 353
 354 dnl **** Checks for headers that depend on other ones ****
 355
 356 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 357     [#include <sys/types.h>
 358      #ifdef HAVE_SYS_PARAM_H
 359      # include <sys/param.h>
 360      #endif])
 361
 362 AC_CHECK_HEADERS(\
 363         netinet/ip.h \
 364         net/if.h \
 365         net/if_arp.h \
 366         net/if_dl.h \
 367         net/if_types.h \
 368         net/route.h \
 369         netinet/if_ether.h \
 370         netinet/in_pcb.h \
 371         netinet/ip_icmp.h \
 372         netinet/ip_var.h \
 373         netinet/udp.h \
 374         netipx/ipx.h \
 375 ,,,[#include <sys/types.h>
 376      #ifdef HAVE_SYS_SOCKET_H
 377      # include <sys/socket.h>
 378      #endif
 379      #ifdef HAVE_SYS_SOCKETVAR_H
 380      # include <sys/socketvar.h>
 381      #endif
 382      #ifdef HAVE_NETINET_IN_H
 383      # include <netinet/in.h>
 384      #endif
 385      #ifdef HAVE_NETINET_IP_H
 386      # include <netinet/ip.h>
 387      #endif])
 388
 389 AC_CHECK_HEADERS([netinet/tcp_var.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_timer.h ],,,
 390     [#include <sys/types.h>
 391      #ifdef HAVE_ALIAS_H
 392      # include <alias.h>
 393      #endif
 394      #ifdef HAVE_SYS_SOCKET_H
 395      # include <sys/socket.h>
 396      #endif
 397      #ifdef HAVE_SYS_SOCKETVAR_H
 398      # include <sys/socketvar.h>
 399      #endif
 400      #ifdef HAVE_NETINET_IN_H
 401      # include <netinet/in.h>
 402      #endif
 403      #ifdef HAVE_NETINET_IP_H
 404      # include <netinet/ip.h>
 405      #endif
 406      #ifdef HAVE_NETINET_IP_VAR_H
 407      # include <netinet/ip_var.h>
 408      #endif
 409      #ifdef HAVE_NETINET_IP_ICMP_H
 410      # include <netinet/ip_icmp.h>
 411      #endif
 412      #ifdef HAVE_NETINET_UDP_H
 413      # include <netinet/udp.h>
 414      #endif
 415      #ifdef HAVE_NETINET_TCP_H
 416      # include <netinet/tcp.h>
 417      #endif])
 418
 419 AC_CHECK_HEADERS([linux/ipx.h],,,
 420     [#include <sys/types.h>
 421      #ifdef HAVE_ASM_TYPES_H
 422      # include <asm/types.h>
 423      #endif
 424      #ifdef HAVE_SYS_SOCKET_H
 425      # include <sys/socket.h>
 426      #endif])
 427
 428 AC_CHECK_HEADERS([resolv.h],,,
 429     [#include <sys/types.h>
 430      #ifdef HAVE_SYS_SOCKET_H
 431      # include <sys/socket.h>
 432      #endif
 433      #ifdef HAVE_NETINET_IN_H
 434      # include <netinet/in.h>
 435      #endif
 436      #ifdef HAVE_ARPA_NAMESER_H
 437      # include <arpa/nameser.h>
 438      #endif])
 439
 440 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 441
 442 AC_CHECK_HEADERS([sys/thr.h],,,
 443 [#include <sys/types.h>
 444 #ifdef HAVE_UCONTEXT_H
 445 #include <ucontext.h>
 446 #endif])
 447
 448 AC_CHECK_HEADERS([pthread_np.h],,,
 449 [#ifdef HAVE_PTHREAD_H
 450 #include <pthread.h>
 451 #endif])
 452
 453 AC_CHECK_HEADERS([linux/videodev.h],,,
 454 [#ifdef HAVE_SYS_TIME_H
 455 #include <sys/time.h>
 456 #endif
 457 #include <sys/types.h>
 458 #ifdef HAVE_ASM_TYPES_H
 459 #include <asm/types.h>
 460 #endif])
 461
 462 dnl Check for broken kernel header that doesn't define __user
 463 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 464
 465 dnl **** Check for working dll ****
 466
 467 AC_SUBST(DLLEXT,"")
 468 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 469 AC_SUBST(LDSHARED,"")
 470 AC_SUBST(LDDLLFLAGS,"")
 471 AC_SUBST(LIBEXT,"so")
 472 AC_SUBST(IMPLIBEXT,"def")
 473 AC_SUBST(LDRPATH_INSTALL,"")
 474 AC_SUBST(LDRPATH_LOCAL,"")
 475 WINE_PATH_LDD
 476
 477 case $host_os in
 478   cygwin*|mingw32*)
 479     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 480     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 481     AC_CHECK_TOOL(MINGWAR,ar,false)
 482     if test "$DLLWRAP" = "false"; then
 483       LIBEXT="a"
 484     else
 485       dnl FIXME - check whether dllwrap works correctly...
 486       LIBEXT="dll"
 487     fi
 488     IMPLIBEXT="a"
 489     dnl We can't build 16-bit NE dlls
 490     WIN16_FILES=""
 491     WIN16_INSTALL=""
 492     ;;
 493   darwin*|macosx*)
 494     DLLEXT=".so"
 495     LIBEXT="dylib"
 496     DLLFLAGS="$DLLFLAGS -fPIC"
 497     LDDLLFLAGS="-bundle -multiply_defined suppress"
 498     LIBWINE_LDFLAGS="-multiply_defined suppress"
 499     LDSHARED="\$(CC) -dynamiclib"
 500     STRIP="$STRIP -x"
 501     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 502     dnl declare needed frameworks
 503     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 504     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 505     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 506     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 507     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 508     then
 509         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 510         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 511     fi
 512     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 513     then
 514         dnl CoreServices needed by AudioUnit
 515         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 516     fi
 517     case $host_cpu in
 518       *powerpc*)
 519         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 520         ;;
 521     esac
 522     dnl Enable quartz driver on Mac OS X
 523     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 524     then
 525         AC_SUBST(CARBONLIB,"-framework Carbon")
 526         QUARTZFILES='$(QUARTZFILES)'
 527     fi
 528     ;;
 529   *)
 530     DLLFLAGS="$DLLFLAGS -fPIC"
 531     DLLEXT=".so"
 532     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 533         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 534                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 535     if test "$ac_cv_c_dll_gnuelf" = "yes"
 536     then
 537       LDSHARED="\$(CC) -shared"
 538       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 539       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 540                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 541                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 542                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 543
 544       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 545
 546       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 547                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 548
 549       echo '{ global: *; };' >conftest.map
 550       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 551                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 552       rm -f conftest.map
 553
 554       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 555                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 556
 557       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 558                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 559                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 560           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 561                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 562                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 563
 564       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 565                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 566
 567       case $host_cpu in
 568         *i[[3456789]]86* | x86_64)
 569           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 570                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 571           ;;
 572       esac
 573
 574     else
 575       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 576           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 577                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 578       if test "$ac_cv_c_dll_unixware" = "yes"
 579       then
 580         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 581         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 582
 583       else
 584         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 585           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 586         if test "$ac_cv_c_dll_hpux" = "yes"
 587         then
 588           LIBEXT="sl"
 589           DLLEXT=".sl"
 590           LDDLLFLAGS="-shared -fPIC"
 591           LDSHARED="\$(CC) -shared"
 592         fi
 593       fi
 594     fi
 595
 596     dnl Check for cross compiler to build test programs
 597     AC_SUBST(CROSSTEST,"")
 598     if test "$cross_compiling" = "no"
 599     then
 600       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 601       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 602       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 603       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 604       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 605     fi
 606     ;;
 607 esac
 608
 609 if test "$LIBEXT" = "a"; then
 610   AC_MSG_ERROR(
 611 [could not find a way to build shared libraries.
 612 It is currently not possible to build Wine without shared library
 613 (.so) support to allow transparent switch between .so and .dll files.
 614 If you are using Linux, you will need a newer binutils.]
 615 )
 616 fi
 617
 618 dnl **** Check for X11 ****
 619
 620 if test "$have_x" = "yes"
 621 then
 622     XLIB="-lXext -lX11"
 623     ac_save_CPPFLAGS="$CPPFLAGS"
 624     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 625
 626     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 627     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 628
 629     dnl *** All of the following tests require X11/Xlib.h
 630     AC_CHECK_HEADERS([X11/Xlib.h \
 631                       X11/XKBlib.h \
 632                       X11/Xutil.h \
 633                       X11/Xcursor/Xcursor.h \
 634                       X11/extensions/shape.h \
 635                       X11/extensions/XInput.h \
 636                       X11/extensions/XShm.h \
 637                       X11/extensions/Xcomposite.h \
 638                       X11/extensions/Xinerama.h \
 639                       X11/extensions/Xrandr.h \
 640                       X11/extensions/Xrender.h \
 641                       X11/extensions/xf86vmode.h],,,
 642 [#ifdef HAVE_X11_XLIB_H
 643 # include <X11/Xlib.h>
 644 #endif
 645 #ifdef HAVE_X11_XUTIL_H
 646 # include <X11/Xutil.h>
 647 #endif])
 648
 649         dnl *** Check for X keyboard extension
 650         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 651         then
 652               AC_CHECK_LIB(X11, XkbQueryExtension,
 653               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 654               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 655         fi
 656
 657         dnl *** Check for X cursor
 658         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 659         then
 660             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 661         fi
 662         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 663                          [libxcursor development files not found, the Xcursor extension won't be supported.])
 664
 665         dnl *** Check for X input extension
 666         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 667         then
 668             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 669         fi
 670         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 671                          [libxi development files not found, the Xinput extension won't be supported.])
 672
 673         dnl *** Check for X Shm extension
 674         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 675         then
 676               AC_CHECK_LIB(Xext, XShmQueryExtension,
 677               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 678               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 679         fi
 680         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 681                          [XShm development files not found, X Shared Memory won't be supported.])
 682
 683         dnl *** Check for X shape extension
 684         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 685         then
 686               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 687               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 688               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 689         fi
 690         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 691                          [XShape development files not found, XShape won't be supported.])
 692
 693         dnl *** Check for XFree86 VMODE extension
 694         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 695         then
 696             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 697         fi
 698         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
 699                          [libXxf86vm development files not found, XFree86 Vidmode won't be supported.])
 700
 701         dnl *** Check for Transform functions in Xrender
 702         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 703         then
 704             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 705               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 706                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 707                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 708                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 709
 710         fi
 711         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 712                          [libxrender development files not found, XRender won't be supported.])
 713
 714         dnl *** Check for X RandR extension
 715         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 716         then
 717                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 718 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 719                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 720         fi
 721         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 722                          [libxrandr development files not found, XRandr won't be supported.])
 723
 724         dnl *** Check for Xinerama extension
 725         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 726         then
 727                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 728 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 729                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 730         fi
 731         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 732                          [libxinerama development files not found, multi-monitor setups won't be supported.])
 733
 734         dnl *** Check for X Composite extension
 735         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 736         then
 737             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 738         fi
 739         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
 740                          [libxcomposite development files not found, Xcomposite won't be supported.])
 741
 742         dnl *** Check for XICCallback struct
 743         AC_CHECK_MEMBERS([XICCallback.callback],,,
 744 [#ifdef HAVE_X11_XLIB_H
 745 #include <X11/Xlib.h>
 746 #endif])
 747
 748     dnl *** End of X11/Xlib.h check
 749
 750     dnl Check for the presence of OpenGL
 751     opengl_msg=""
 752     if test "x$with_opengl" != "xno"
 753     then
 754         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 755 [#ifdef HAVE_GL_GLX_H
 756 # include <GL/glx.h>
 757 #endif])
 758         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 759         then
 760             dnl Check for some problems due to old Mesa versions
 761             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 762               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 763                 [wine_cv_opengl_header_version_OK="yes"],
 764                 [wine_cv_opengl_header_version_OK="no"]))
 765
 766             if test "$wine_cv_opengl_header_version_OK" = "yes"
 767             then
 768                 dnl Check for the presence of the library
 769                 WINE_CHECK_SONAME(GL,glXCreateContext,
 770                              [OPENGL_LIBS="-lGL"
 771                              OPENGLFILES='$(OPENGLFILES)'
 772                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 773                              [WINE_CHECK_SONAME(GL,glXCreateContext,
 774                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
 775                                     OPENGLFILES='$(OPENGLFILES)'
 776                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 777                                     [if test -f /usr/X11R6/lib/libGL.a
 778                                     then
 779                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
 780 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
 781                                     else
 782                                         opengl_msg="No OpenGL library found on this system."
 783                                     fi],
 784                                     $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
 785                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 786                  if test "$ac_cv_header_GL_glu_h" = "yes"
 787                  then
 788                     WINE_CHECK_SONAME(GLU,gluLookAt,[GLU32FILES='$(GLU32FILES)'],,
 789                                       [$OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS])
 790                  fi
 791                  WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_soname_GLU" = "x"],
 792                                  [libGLU development files not found, GLU won't be supported.])
 793              else
 794                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
 795              fi
 796          else
 797              opengl_msg="OpenGL development headers not found."
 798          fi
 799     fi
 800     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
 801 OpenGL and Direct3D won't be supported.])
 802
 803     dnl **** Check for NAS ****
 804     AC_SUBST(NASLIBS,"")
 805     AC_CHECK_HEADERS(audio/audiolib.h,
 806          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 807           AC_CHECK_LIB(audio,AuCreateFlow,
 808                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 809                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 810                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 811                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 812                           [$X_LIBS])
 813                        ],,
 814                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 815
 816     CPPFLAGS="$ac_save_CPPFLAGS"
 817     XFILES='$(XFILES)'
 818 else
 819     XLIB=""
 820     X_CFLAGS=""
 821     X_LIBS=""
 822 fi
 823 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X development files not found. Wine will be built
 824 without X support, which probably isn't what you want. You will need to install
 825 development packages of Xlib/Xfree86 at the very least.])
 826
 827 dnl **** Check for libxml2 ****
 828
 829 AC_SUBST(XML2LIBS,"")
 830 AC_SUBST(XML2INCL,"")
 831 AC_SUBST(XSLTLIBS,"")
 832 AC_SUBST(XSLTINCL,"")
 833 if test "x$with_xml" != "xno"
 834 then
 835     ac_save_CPPFLAGS="$CPPFLAGS"
 836     if test "$PKG_CONFIG" != "false"
 837     then
 838         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 839         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 840     else
 841         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 842         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 843     fi
 844     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 845     AC_CHECK_HEADERS(libxml/parser.h,
 846             [AC_CHECK_LIB(xml2, xmlParseMemory,
 847                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 848                  XML2LIBS="$ac_xml_libs"
 849                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 850              AC_CHECK_LIB(xml2, xmlReadMemory,
 851                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 852              AC_CHECK_LIB(xml2, xmlNewDocPI,
 853                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 854         ])
 855     CPPFLAGS="$ac_save_CPPFLAGS"
 856 fi
 857 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
 858                  [libxml2 development files not found, XML won't be supported.])
 859
 860 if test "x$with_xslt" != "xno"
 861 then
 862     if test "$PKG_CONFIG" != "false"
 863     then
 864         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 865         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 866     else
 867         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 868         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 869     fi
 870     ac_save_CPPFLAGS="$CPPFLAGS"
 871     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 872     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
 873     [#ifdef HAVE_LIBXSLT_PATTERN_H
 874 # include <libxslt/pattern.h>
 875 #endif])
 876     CPPFLAGS="$ac_save_CPPFLAGS"
 877     if test "$ac_cv_header_libxslt_transform_h" = "yes"
 878     then
 879         AC_CHECK_LIB(xslt, xsltCompilePattern,
 880             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 881              XSLTLIBS="$ac_xslt_libs"
 882              XSLTINCL="$ac_xslt_cflags"
 883              ac_save_LIBS="$LIBS"
 884              LIBS="$LIBS $ac_xslt_libs"
 885              AC_CHECK_FUNCS(xsltInit)
 886              LIBS="$ac_save_LIBS"],,$ac_xslt_libs)
 887     fi
 888 fi
 889 WINE_WARNING_WITH(xslt,[test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],
 890                  [libxslt development files not found, xslt won't be supported.])
 891
 892 dnl **** Check for libhal ****
 893 AC_SUBST(HALINCL,"")
 894 if test "x$with_hal" != "xno" -a "$PKG_CONFIG" != "false"
 895 then
 896     ac_save_CPPFLAGS="$CPPFLAGS"
 897     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 898     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 899     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 900     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 901     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 902     then
 903         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 904           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 905             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 906     fi
 907     CPPFLAGS="$ac_save_CPPFLAGS"
 908 fi
 909 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x"],
 910                  [libhal development files not found, no dynamic device support.])
 911
 912 dnl **** Check which curses lib to use ***
 913 CURSESLIBS=""
 914 if test "$ac_cv_header_ncurses_h" = "yes"
 915 then
 916     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 917 elif test "$ac_cv_header_curses_h" = "yes"
 918 then
 919     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 920 fi
 921 ac_save_LIBS="$LIBS"
 922 LIBS="$LIBS $CURSESLIBS"
 923 AC_CHECK_FUNCS(mousemask)
 924 LIBS="$ac_save_LIBS"
 925 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
 926                  [lib(n)curses development files not found, curses won't be supported.])
 927
 928 dnl **** Check for SANE ****
 929 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 930 if test "$sane_devel" != "no" -a "x$with_sane" != "xno"
 931 then
 932     ac_sane_incl="`$sane_devel --cflags`"
 933     ac_sane_libs="`$sane_devel --ldflags`"
 934     ac_save_CPPFLAGS="$CPPFLAGS"
 935     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 936     AC_CHECK_HEADER(sane/sane.h,
 937         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")],,[$ac_sane_libs])])
 938     CPPFLAGS="$ac_save_CPPFLAGS"
 939 fi
 940 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
 941                  [libsane development files not found, scanners won't be supported.])
 942
 943 dnl **** Check for libgphoto2 ****
 944 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 945 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 946 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no" -a "x$with_gphoto" != "xno"
 947 then
 948     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 949     ac_gphoto2_libs=""
 950     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 951     do
 952       case "$i" in
 953         -L/usr/lib|-L/usr/lib64) ;;
 954         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 955       esac
 956     done
 957     ac_save_CPPFLAGS="$CPPFLAGS"
 958     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 959     AC_CHECK_HEADER(gphoto2-camera.h,
 960                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 961                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 962                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 963                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 964                                   [$ac_gphoto2_libs])])
 965     CPPFLAGS="$ac_save_CPPFLAGS"
 966 fi
 967 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
 968                  [libgphoto2 development files not found, digital cameras won't be supported.])
 969
 970
 971 dnl **** Check for resolver library ***
 972 AC_SUBST(RESOLVLIBS,"")
 973 if test "$ac_cv_header_resolv_h" = "yes"
 974 then
 975     AC_CHECK_LIB(resolv, res_query,
 976         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 977          RESOLVLIBS="-lresolv"])
 978 fi
 979
 980 dnl **** Check for LittleCMS ***
 981 AC_SUBST(LCMSLIBS,"")
 982 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 983 then
 984     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 985         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 986          LCMSLIBS="-llcms"])
 987 fi
 988 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
 989                  [liblcms development files not found, Color Management won't be supported.])
 990
 991 dnl **** Check for FreeType 2 ****
 992 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 993 if test "$ft_devel" != "false" -a "x$with_freetype" != "xno"
 994 then
 995     ac_freetype_libs=`$ft_devel --libs`
 996     ac_freetype_incl=`$ft_devel --cflags`
 997     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 998     if test "$ft_lib" = "yes"
 999     then
1000         ac_save_CPPFLAGS="$CPPFLAGS"
1001         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
1002         AC_CHECK_HEADERS(ft2build.h \
1003                          freetype/freetype.h \
1004                          freetype/ftglyph.h \
1005                          freetype/fttypes.h \
1006                          freetype/tttables.h \
1007                          freetype/ftnames.h \
1008                          freetype/ftsnames.h \
1009                          freetype/ttnameid.h \
1010                          freetype/ftoutln.h \
1011                          freetype/ftwinfnt.h \
1012                          freetype/ftmodapi.h \
1013                          freetype/internal/sfnt.h,,,
1014                          [#ifdef HAVE_FT2BUILD_H
1015                           # include <ft2build.h>
1016                           #endif])
1017         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1018                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1019           [Define if you have the <freetype/fttrigon.h> header file.])
1020                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1021         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1022         ac_save_CFLAGS="$CFLAGS"
1023         CFLAGS="$CFLAGS $ac_freetype_libs"
1024         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
1025         CFLAGS="$ac_save_CFLAGS"
1026         CPPFLAGS="$ac_save_CPPFLAGS"
1027         dnl Check that we have at least freetype/freetype.h
1028         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1029         then
1030             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1031             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1032             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1033             AC_SUBST(FONTSSUBDIRS,"fonts")
1034         fi
1035     fi
1036 fi
1037 WINE_ERROR_WITH(freetype,[test "x$FREETYPELIBS" = "x"],[FreeType development files not found.
1038 Fonts will not be built. Dialog text may be invisible or unaligned.])
1039
1040 dnl **** Check for parport (currently Linux only) ****
1041 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1042  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1043     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1044 if test "$ac_cv_c_ppdev" = "yes"
1045 then
1046     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1047 fi
1048
1049 dnl **** Check for va_copy ****
1050 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
1051  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
1052     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
1053  )
1054 if test "$ac_cv_c_va_copy" = "yes"
1055 then
1056     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
1057 fi
1058 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
1059  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
1060     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
1061  )
1062 if test "$ac_cv_c___va_copy" = "yes"
1063 then
1064     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
1065 fi
1066
1067 dnl **** Check for pthread_rwlock_t ****
1068 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
1069 #include <pthread.h>])
1070
1071 dnl **** Check for pthread functions ****
1072 WINE_CHECK_LIB_FUNCS(\
1073         pthread_attr_get_np \
1074         pthread_getattr_np \
1075         pthread_get_stackaddr_np \
1076         pthread_get_stacksize_np,
1077         [$LIBPTHREAD])
1078
1079 dnl **** Check for EsounD ****
1080 AC_PATH_PROG(ESDCONFIG, esd-config)
1081 if test "x$with_esd" != xno -a "x$ESDCONFIG" != x -a "x$ESDCONFIG" != x'"$ESDCONFIG"';
1082 then
1083     ac_esd_incl=""
1084     for i in `$ESDCONFIG --cflags`
1085     do
1086       case "$i" in
1087         -I*) ac_esd_incl="$ac_esd_incl $i";;
1088       esac
1089     done
1090     ac_esd_libs=`$ESDCONFIG --libs`
1091     save_CFLAGS="$CFLAGS"
1092     CFLAGS="$CFLAGS $ac_esd_incl"
1093     AC_CHECK_LIB(esd,esd_open_sound,
1094         [AC_SUBST(ESDINCL, "$ac_esd_incl")
1095          AC_SUBST(ESDLIBS, "$ac_esd_libs")
1096          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])],,
1097         [$ac_esd_libs])
1098     CFLAGS="$save_CFLAGS"
1099 fi
1100
1101 dnl **** Check for ALSA 1.x ****
1102 AC_SUBST(ALSALIBS,"")
1103 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1104 then
1105     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1106         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1107 #include <alsa/asoundlib.h>
1108 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1109 #include <sys/asoundlib.h>
1110 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1111                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1112                          ALSALIBS="-lasound"],[])])
1113 fi
1114
1115 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1116 AC_SUBST(AUDIOIOLIBS,"")
1117 if test "$ac_cv_header_libaudioio_h" = "yes"
1118 then
1119     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1120                   [AUDIOIOLIBS="-laudioio"
1121                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1122 fi
1123
1124 dnl **** Check for capi4linux ****
1125
1126 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1127 then
1128     WINE_CHECK_SONAME(capi20,capi20_register)
1129 fi
1130 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1131                  [libcapi20 development files not found, ISDN won't be supported.])
1132
1133 dnl **** Check for cups ****
1134 AC_SUBST(CUPSINCL,"")
1135 if test "x$with_cups" != "xno"
1136 then
1137     ac_save_CPPFLAGS="$CPPFLAGS"
1138     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1139     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1140     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1141     AC_CHECK_HEADERS(cups/cups.h,
1142             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1143                        [CUPSINCL="$ac_cups_cflags"],,
1144                        [$ac_cups_libs])])
1145     CPPFLAGS="$ac_save_CPPFLAGS"
1146 fi
1147 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1148                  [libcups development files not found, CUPS won't be supported.])
1149
1150 dnl **** Check for jack ****
1151 if test "$ac_cv_header_jack_jack_h" = "yes"
1152 then
1153     WINE_CHECK_SONAME(jack,jack_client_new,,,,[[libjack-*[[0-9.]]*]])
1154 fi
1155
1156 dnl **** Check for fontconfig ****
1157 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1158 then
1159     WINE_CHECK_SONAME(fontconfig,FcInit)
1160 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1161 then
1162     dnl fontconfig is in the X directory on Mac OS X
1163     ac_save_CPPFLAGS="$CPPFLAGS"
1164     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1165     $as_unset ac_cv_header_fontconfig_fontconfig_h
1166     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1167     CPPFLAGS="$ac_save_CPPFLAGS"
1168     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1169     then
1170         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1171         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1172     fi
1173 fi
1174 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1175                  [fontconfig development files not found, fontconfig won't be supported.])
1176
1177 dnl **** Check for SSL ****
1178 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1179 then
1180     WINE_CHECK_SONAME(ssl,SSL_library_init)
1181     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1182 fi
1183 WINE_WARNING_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1184                  [OpenSSL development files not found, SSL won't be supported.])
1185
1186 dnl **** Check for libjpeg ****
1187 if test "$ac_cv_header_jpeglib_h" = "yes"
1188 then
1189     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1190 fi
1191 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1192                  [libjpeg development files not found, JPEG won't be supported.])
1193
1194 dnl **** Check for libpng ****
1195 if test "$ac_cv_header_png_h" = "yes"
1196 then
1197     WINE_CHECK_SONAME(png,png_create_read_struct,,,-lm,[[libpng[[0-9]]*]])
1198 fi
1199 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1200                  [libpng development files not found, PNG won't be supported.])
1201
1202 dnl **** Check for libodbc ****
1203 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1204
1205 dnl **** Check for any sound system ****
1206 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESDLIBS$ac_cv_lib_soname_jack" = "x" -a \
1207         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1208         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1209         "$ac_cv_header_soundcard_h" != "yes" -a \
1210         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1211 then
1212     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1213 fi
1214
1215 dnl **** Check for gcc specific options ****
1216
1217 AC_SUBST(EXTRACFLAGS,"")
1218 if test "x${GCC}" = "xyes"
1219 then
1220   EXTRACFLAGS="-Wall -pipe"
1221
1222   dnl Check for strength-reduce bug
1223   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1224                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1225 [[static int Array[[3]];
1226   unsigned int B = 3;
1227   int i;
1228   for(i=0; i<B; i++) Array[[i]] = i - 3;
1229   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1230   L[[i]] = 4;
1231   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1232     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1233   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1234   then
1235     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1236   fi
1237
1238   dnl Check for some compiler flags
1239
1240   WINE_TRY_CFLAGS([-fshort-wchar],
1241                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1242                              [Specifies the compiler flag that forces a short wchar_t])])
1243   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1244   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1245   WINE_TRY_CFLAGS([-Wwrite-strings])
1246   WINE_TRY_CFLAGS([-Wtype-limits])
1247
1248   dnl Check for noisy string.h
1249   saved_CFLAGS="$CFLAGS"
1250   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1251   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1252       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1253   CFLAGS="$saved_CFLAGS"
1254   if test "$ac_cv_c_string_h_warnings" = "no"
1255   then
1256     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1257   fi
1258
1259   AC_SUBST(BUILTINFLAG,"")
1260   saved_CFLAGS="$CFLAGS"
1261   CFLAGS="$CFLAGS -Werror"
1262   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1263       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1264   CFLAGS="$saved_CFLAGS"
1265   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1266   then
1267     BUILTINFLAG="-fno-builtin"
1268   fi
1269 fi
1270
1271 dnl **** Check how to define a function in assembly code ****
1272
1273 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1274   WINE_TRY_ASM_LINK(
1275       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1276       ac_cv_asm_func_def=".def",
1277     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1278       ac_cv_asm_func_def=".type @function",
1279     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1280       ac_cv_asm_func_def=".type 2",
1281       ac_cv_asm_func_def="unknown")])]))
1282
1283 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1284 case "$ac_cv_asm_func_def" in
1285   ".def")
1286      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1287   ".type @function")
1288      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1289   ".type 2")
1290      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1291   *)
1292      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1293 esac
1294
1295 dnl **** Check for underscore on external symbols ****
1296
1297 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1298     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1299                       [extern int ac_test;],
1300                       [if (ac_test) return 1],
1301                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1302
1303 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1304 if test "$ac_cv_c_extern_prefix" = "yes"
1305 then
1306   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1307 else
1308   AC_DEFINE([__ASM_NAME(name)], [name])
1309 fi
1310
1311 dnl **** Platform-specific checks ****
1312
1313 AC_SUBST(LDPATH,"")
1314 case $build_os in
1315   cygwin*|mingw32*)
1316     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1317     ;;
1318   darwin*|macosx*)
1319     ;;
1320   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1321     if test -z "$LDRPATH_LOCAL"
1322     then
1323       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1324     fi
1325     ;;
1326   *)
1327     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1328     ;;
1329 esac
1330
1331 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1332 case $host_os in
1333   mingw32*)
1334     AC_SUBST(CRTLIBS,"-lmsvcrt")
1335     AC_SUBST(SOCKETLIBS,"-lws2_32")
1336     ;;
1337 esac
1338
1339 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1340 case $host_cpu in
1341   *i[[3456789]]86*)
1342     case $host_os in
1343       linux* | k*bsd*-gnu)
1344         AC_SUBST(MAIN_BINARY,"wine-glibc")
1345         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1346       freebsd*)
1347         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1348         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1349     esac
1350     ;;
1351 esac
1352
1353 dnl **** Check for functions ****
1354
1355 AC_CHECK_FUNCS(\
1356         _pclose \
1357         _popen \
1358         _snprintf \
1359         _spawnvp \
1360         _strdup \
1361         _stricmp \
1362         _strnicmp \
1363         _strtoi64 \
1364         _strtoui64 \
1365         _vsnprintf \
1366         asctime_r \
1367         chsize \
1368         clone \
1369         dlopen \
1370         epoll_create \
1371         ffs \
1372         finite \
1373         fork \
1374         fpclass \
1375         fstatfs \
1376         fstatvfs \
1377         ftruncate \
1378         futimes \
1379         futimesat \
1380         getdirentries \
1381         getopt_long \
1382         getpagesize \
1383         getpwuid \
1384         gettid \
1385         gettimeofday \
1386         getuid \
1387         inet_pton \
1388         kqueue \
1389         lstat \
1390         memmove \
1391         mmap \
1392         pclose \
1393         poll \
1394         popen \
1395         prctl \
1396         pread \
1397         pwrite \
1398         readlink \
1399         rfork \
1400         sched_yield \
1401         select \
1402         setproctitle \
1403         setrlimit \
1404         settimeofday \
1405         sigaltstack \
1406         sigprocmask \
1407         snprintf \
1408         spawnvp \
1409         statfs \
1410         statvfs \
1411         strcasecmp \
1412         strdup \
1413         strerror \
1414         strncasecmp \
1415         strtold \
1416         strtoll \
1417         strtoull \
1418         tcgetattr \
1419         thr_kill2 \
1420         timegm \
1421         usleep \
1422         vsnprintf \
1423         wait4 \
1424         waitpid \
1425 )
1426
1427 dnl Check for -ldl
1428 if test "$ac_cv_func_dlopen" = no
1429 then
1430     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1431 fi
1432 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1433
1434 dnl Check for -lpoll for Mac OS X/Darwin
1435 if test "$ac_cv_func_poll" = no
1436 then
1437     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1438 fi
1439
1440 dnl Check for -lnsl for Solaris
1441 AC_SEARCH_LIBS(gethostbyname, nsl)
1442
1443 dnl Check for -lsocket for Solaris
1444 AC_SEARCH_LIBS(connect, socket)
1445
1446 dnl Check for -lresolv for Solaris
1447 AC_SEARCH_LIBS(inet_aton, resolv)
1448
1449 dnl **** Check for functions which may rely on -lsocket on Solaris.
1450 AC_CHECK_FUNCS(\
1451         getaddrinfo \
1452         getnameinfo \
1453         getnetbyname \
1454         getprotobyname \
1455         getprotobynumber \
1456         getservbyport \
1457         inet_network \
1458         sendmsg \
1459 )
1460
1461 dnl **** Check for OpenLDAP ***
1462 AC_SUBST(LDAPLIBS,"")
1463 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
1464 then
1465     AC_CHECK_TYPE(LDAPSortKey,
1466         [AC_CHECK_LIB(ldap_r, ldap_initialize,
1467             [AC_CHECK_LIB(lber, ber_init,
1468                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
1469                  LDAPLIBS="-lldap_r -llber"],,
1470                  [$LIBPTHREAD])],,
1471                  [$LIBPTHREAD])],,
1472         [#include <ldap.h>])
1473     WINE_CHECK_LIB_FUNCS(\
1474         ldap_count_references \
1475         ldap_first_reference \
1476         ldap_next_reference \
1477         ldap_parse_reference \
1478         ldap_parse_sort_control \
1479         ldap_parse_sortresponse_control \
1480         ldap_parse_vlv_control \
1481         ldap_parse_vlvresponse_control,
1482         [$LDAPLIBS $LIBPTHREAD])
1483 fi
1484 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
1485                  [libldap (OpenLDAP) development files not found, LDAP won't be supported.])
1486
1487 dnl **** Check for types ****
1488
1489 AC_C_CONST
1490 AC_C_INLINE
1491 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1492 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1493 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1494
1495 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1496 [#ifdef HAVE_LINUX_INPUT_H
1497 #include <linux/input.h>
1498 #endif])
1499
1500 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1501                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1502 if test "$wine_cv_have_sigaddset" = "yes"
1503 then
1504   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1505 fi
1506
1507
1508 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1509         wine_cv_linux_gethostbyname_r_6,
1510         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1511     char *name=0;
1512     struct hostent he;
1513     struct hostent *result;
1514     char *buf=0;
1515     int bufsize=0;
1516     int res,errnr;
1517     char *addr=0;
1518     int addrlen=0;
1519     int addrtype=0;
1520     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1521     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1522     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1523         ])
1524    )
1525    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1526    then
1527       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1528                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1529    fi
1530
1531 if test "$ac_cv_header_linux_joystick_h" = "yes"
1532 then
1533    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1534         wine_cv_linux_joystick_22_api,
1535         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1536         #include <sys/ioctl.h>
1537         #include <sys/types.h>
1538         #include <linux/joystick.h>
1539
1540         struct js_event blub;
1541         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1542         #error "no 2.2 header"
1543         #endif
1544         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1545    )
1546    if test "$wine_cv_linux_joystick_22_api" = "yes"
1547    then
1548       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1549                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1550    fi
1551 fi
1552
1553 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1554
1555 dnl Check for statfs members
1556 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1557 [#include <sys/types.h>
1558 #ifdef HAVE_SYS_PARAM_H
1559 # include <sys/param.h>
1560 #endif
1561 #ifdef HAVE_SYS_MOUNT_H
1562 # include <sys/mount.h>
1563 #endif
1564 #ifdef HAVE_SYS_VFS_H
1565 # include <sys/vfs.h>
1566 #endif
1567 #ifdef HAVE_SYS_STATFS_H
1568 # include <sys/statfs.h>
1569 #endif])
1570
1571 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1572 [#ifdef HAVE_SYS_STATVFS_H
1573 #include <sys/statvfs.h>
1574 #endif])
1575
1576 dnl Check for socket structure members
1577 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1578 [#include <sys/types.h>
1579 #ifdef HAVE_SYS_SOCKET_H
1580 # include <sys/socket.h>
1581 #endif
1582 #ifdef HAVE_SYS_UN_H
1583 # include <sys/un.h>
1584 #endif])
1585
1586 dnl Check for scsireq_t and sg_io_hdr_t members
1587 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1588 [#include <sys/types.h>
1589 #ifdef HAVE_SCSI_SG_H
1590 #include <scsi/sg.h>
1591 #endif])
1592
1593 dnl Check for siginfo_t members
1594 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1595
1596 dnl Check for struct mtget members
1597 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1598 [#include <sys/types.h>
1599 #ifdef HAVE_SYS_MTIO_H
1600 #include <sys/mtio.h>
1601 #endif])
1602
1603 dnl Check for struct option
1604 AC_CHECK_MEMBERS([struct option.name],,,
1605 [#ifdef HAVE_GETOPT_H
1606 #include <getopt.h>
1607 #endif])
1608
1609 dnl Check for stat.st_blocks
1610 AC_CHECK_MEMBERS([struct stat.st_blocks])
1611
1612 dnl Check for sin6_scope_id
1613 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1614 [#ifdef HAVE_SYS_TYPES_H
1615 #include <sys/types.h>
1616 #endif
1617 #ifdef HAVE_NETINET_IN_H
1618 #include <netinet/in.h>
1619 #endif])
1620
1621 dnl Check for ns_msg ptr member
1622 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1623 [#ifdef HAVE_SYS_TYPES_H
1624 #include <sys/types.h>
1625 #endif
1626 #ifdef HAVE_NETINET_IN_H
1627 # include <netinet/in.h>
1628 #endif
1629 #ifdef HAVE_ARPA_NAMESER_H
1630 # include <arpa/nameser.h>
1631 #endif])
1632
1633 dnl Check for the external timezone variables timezone and daylight
1634 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1635                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1636 if test "$ac_cv_have_timezone" = "yes"
1637 then
1638     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1639 fi
1640 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1641                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1642 if test "$ac_cv_have_daylight" = "yes"
1643 then
1644     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1645 fi
1646
1647 dnl Check for isinf
1648 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
1649                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
1650 if test "$ac_cv_have_isinf" = "yes"
1651 then
1652     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
1653 fi
1654
1655 dnl *** check for the need to define platform-specific symbols
1656
1657 case $host_cpu in
1658   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1659   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1660   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1661   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1662   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1663 esac
1664
1665 case $host_vendor in
1666   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1667 esac
1668
1669 dnl **** Generate output files ****
1670
1671 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1672 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1673 ["### Dependencies:\\
1674 \\
1675 .INIT: Makefile\\
1676 .BEGIN: Makefile\\
1677 Makefile: dummy\\
1678         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1679 \\
1680 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1681 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1682 \$(RC_SRCS:.rc=.res): \$(IDL_TLB_SRCS:.idl=.tlb)\\
1683 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1684 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1685 ["### Dependencies:
1686
1687 .INIT: Makefile
1688 .BEGIN: Makefile
1689 Makefile: dummy
1690         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1691
1692 \$(OBJS): \$(IDL_GEN_HEADERS)
1693 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1694 \$(RC_SRCS:.rc=.res): \$(IDL_TLB_SRCS:.idl=.tlb)
1695 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1696 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1697
1698 AH_TOP([#define __WINE_CONFIG_H])
1699
1700 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1701
1702 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1703 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1704 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1705 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1706 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1707 WINE_CONFIG_EXTRA_DIR(include/wine)
1708
1709 MAKE_RULES=Make.rules
1710 AC_SUBST_FILE(MAKE_RULES)
1711
1712 MAKE_DLL_RULES=dlls/Makedll.rules
1713 AC_SUBST_FILE(MAKE_DLL_RULES)
1714
1715 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1716 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1717
1718 MAKE_TEST_RULES=dlls/Maketest.rules
1719 AC_SUBST_FILE(MAKE_TEST_RULES)
1720
1721 MAKE_PROG_RULES=programs/Makeprog.rules
1722 AC_SUBST_FILE(MAKE_PROG_RULES)
1723
1724 AC_CONFIG_FILES([Make.rules])
1725 AC_CONFIG_FILES([dlls/Makedll.rules])
1726 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1727 AC_CONFIG_FILES([dlls/Maketest.rules])
1728 AC_CONFIG_FILES([programs/Makeprog.rules])
1729 AC_CONFIG_FILES([Makefile])
1730 AC_CONFIG_FILES([dlls/Makefile])
1731 AC_CONFIG_FILES([dlls/acledit/Makefile])
1732 AC_CONFIG_FILES([dlls/activeds/Makefile])
1733 AC_CONFIG_FILES([dlls/actxprxy/Makefile])
1734 AC_CONFIG_FILES([dlls/adsiid/Makefile])
1735 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1736 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1737 AC_CONFIG_FILES([dlls/advpack/Makefile])
1738 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1739 AC_CONFIG_FILES([dlls/amstream/Makefile])
1740 AC_CONFIG_FILES([dlls/appwiz.cpl/Makefile])
1741 AC_CONFIG_FILES([dlls/atl/Makefile])
1742 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1743 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1744 AC_CONFIG_FILES([dlls/browseui/Makefile])
1745 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1746 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1747 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1748 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1749 AC_CONFIG_FILES([dlls/cards/Makefile])
1750 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1751 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1752 AC_CONFIG_FILES([dlls/comcat/Makefile])
1753 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1754 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1755 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1756 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1757 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1758 AC_CONFIG_FILES([dlls/compstui/Makefile])
1759 AC_CONFIG_FILES([dlls/credui/Makefile])
1760 AC_CONFIG_FILES([dlls/credui/tests/Makefile])
1761 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1762 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1763 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1764 AC_CONFIG_FILES([dlls/cryptdlg/Makefile])
1765 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1766 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1767 AC_CONFIG_FILES([dlls/cryptnet/tests/Makefile])
1768 AC_CONFIG_FILES([dlls/cryptui/Makefile])
1769 AC_CONFIG_FILES([dlls/ctapi32/Makefile])
1770 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1771 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1772 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1773 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1774 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1775 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1776 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1777 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1778 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1779 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1780 AC_CONFIG_FILES([dlls/d3dx8/tests/Makefile])
1781 AC_CONFIG_FILES([dlls/d3dx9_24/Makefile])
1782 AC_CONFIG_FILES([dlls/d3dx9_25/Makefile])
1783 AC_CONFIG_FILES([dlls/d3dx9_26/Makefile])
1784 AC_CONFIG_FILES([dlls/d3dx9_27/Makefile])
1785 AC_CONFIG_FILES([dlls/d3dx9_28/Makefile])
1786 AC_CONFIG_FILES([dlls/d3dx9_29/Makefile])
1787 AC_CONFIG_FILES([dlls/d3dx9_30/Makefile])
1788 AC_CONFIG_FILES([dlls/d3dx9_31/Makefile])
1789 AC_CONFIG_FILES([dlls/d3dx9_32/Makefile])
1790 AC_CONFIG_FILES([dlls/d3dx9_33/Makefile])
1791 AC_CONFIG_FILES([dlls/d3dx9_34/Makefile])
1792 AC_CONFIG_FILES([dlls/d3dx9_35/Makefile])
1793 AC_CONFIG_FILES([dlls/d3dx9_36/Makefile])
1794 AC_CONFIG_FILES([dlls/d3dx9_36/tests/Makefile])
1795 AC_CONFIG_FILES([dlls/d3dx9_37/Makefile])
1796 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1797 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1798 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1799 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1800 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1801 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1802 AC_CONFIG_FILES([dlls/devenum/Makefile])
1803 AC_CONFIG_FILES([dlls/dinput/Makefile])
1804 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1805 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1806 AC_CONFIG_FILES([dlls/dmband/Makefile])
1807 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1808 AC_CONFIG_FILES([dlls/dmime/Makefile])
1809 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1810 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1811 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1812 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1813 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1814 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1815 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1816 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1817 AC_CONFIG_FILES([dlls/dplay/Makefile])
1818 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1819 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1820 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1821 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1822 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1823 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1824 AC_CONFIG_FILES([dlls/dpwsockx/Makefile])
1825 AC_CONFIG_FILES([dlls/dsound/Makefile])
1826 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1827 AC_CONFIG_FILES([dlls/dssenh/Makefile])
1828 AC_CONFIG_FILES([dlls/dswave/Makefile])
1829 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1830 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1831 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1832 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1833 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1834 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1835 AC_CONFIG_FILES([dlls/fusion/Makefile])
1836 AC_CONFIG_FILES([dlls/fusion/tests/Makefile])
1837 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1838 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1839 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1840 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1841 AC_CONFIG_FILES([dlls/glu32/Makefile])
1842 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1843 AC_CONFIG_FILES([dlls/gpkcsp/Makefile])
1844 AC_CONFIG_FILES([dlls/hal/Makefile])
1845 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1846 AC_CONFIG_FILES([dlls/hid/Makefile])
1847 AC_CONFIG_FILES([dlls/hlink/Makefile])
1848 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1849 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1850 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1851 AC_CONFIG_FILES([dlls/icmp/Makefile])
1852 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1853 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1854 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1855 AC_CONFIG_FILES([dlls/imm32/Makefile])
1856 AC_CONFIG_FILES([dlls/imm32/tests/Makefile])
1857 AC_CONFIG_FILES([dlls/inetcomm/Makefile])
1858 AC_CONFIG_FILES([dlls/inetcomm/tests/Makefile])
1859 AC_CONFIG_FILES([dlls/inetmib1/Makefile])
1860 AC_CONFIG_FILES([dlls/inetmib1/tests/Makefile])
1861 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1862 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1863 AC_CONFIG_FILES([dlls/initpki/Makefile])
1864 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1865 AC_CONFIG_FILES([dlls/inseng/Makefile])
1866 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1867 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1868 AC_CONFIG_FILES([dlls/itircl/Makefile])
1869 AC_CONFIG_FILES([dlls/itss/Makefile])
1870 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1871 AC_CONFIG_FILES([dlls/jscript/Makefile])
1872 AC_CONFIG_FILES([dlls/jscript/tests/Makefile])
1873 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1874 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1875 AC_CONFIG_FILES([dlls/localspl/Makefile])
1876 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1877 AC_CONFIG_FILES([dlls/localui/Makefile])
1878 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1879 AC_CONFIG_FILES([dlls/lz32/Makefile])
1880 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1881 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1882 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1883 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1884 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1885 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1886 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1887 AC_CONFIG_FILES([dlls/midimap/Makefile])
1888 AC_CONFIG_FILES([dlls/mlang/Makefile])
1889 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1890 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1891 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1892 AC_CONFIG_FILES([dlls/mountmgr.sys/Makefile])
1893 AC_CONFIG_FILES([dlls/mpr/Makefile])
1894 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1895 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1896 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1897 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1898 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1899 AC_CONFIG_FILES([dlls/mscat32/Makefile])
1900 AC_CONFIG_FILES([dlls/mscms/Makefile])
1901 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1902 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1903 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1904 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1905 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1906 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1907 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1908 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1909 AC_CONFIG_FILES([dlls/msi/Makefile])
1910 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1911 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1912 AC_CONFIG_FILES([dlls/msimtf/Makefile])
1913 AC_CONFIG_FILES([dlls/msisip/Makefile])
1914 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1915 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1916 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1917 AC_CONFIG_FILES([dlls/mssip32/Makefile])
1918 AC_CONFIG_FILES([dlls/mstask/Makefile])
1919 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1920 AC_CONFIG_FILES([dlls/msvcr71/Makefile])
1921 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1922 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1923 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1924 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1925 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1926 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1927 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1928 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1929 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1930 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1931 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1932 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1933 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1934 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1935 AC_CONFIG_FILES([dlls/newdev/Makefile])
1936 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1937 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1938 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1939 AC_CONFIG_FILES([dlls/ntdsapi/tests/Makefile])
1940 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1941 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1942 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1943 AC_CONFIG_FILES([dlls/objsel/Makefile])
1944 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1945 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1946 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1947 AC_CONFIG_FILES([dlls/ole32/Makefile])
1948 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1949 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1950 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1951 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1952 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1953 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1954 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1955 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1956 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1957 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1958 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1959 AC_CONFIG_FILES([dlls/pdh/Makefile])
1960 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1961 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1962 AC_CONFIG_FILES([dlls/printui/Makefile])
1963 AC_CONFIG_FILES([dlls/propsys/Makefile])
1964 AC_CONFIG_FILES([dlls/psapi/Makefile])
1965 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1966 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1967 AC_CONFIG_FILES([dlls/qcap/Makefile])
1968 AC_CONFIG_FILES([dlls/qedit/Makefile])
1969 AC_CONFIG_FILES([dlls/qedit/tests/Makefile])
1970 AC_CONFIG_FILES([dlls/qmgr/Makefile])
1971 AC_CONFIG_FILES([dlls/qmgr/tests/Makefile])
1972 AC_CONFIG_FILES([dlls/qmgrprxy/Makefile])
1973 AC_CONFIG_FILES([dlls/quartz/Makefile])
1974 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1975 AC_CONFIG_FILES([dlls/query/Makefile])
1976 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1977 AC_CONFIG_FILES([dlls/rasapi32/tests/Makefile])
1978 AC_CONFIG_FILES([dlls/resutils/Makefile])
1979 AC_CONFIG_FILES([dlls/riched20/Makefile])
1980 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1981 AC_CONFIG_FILES([dlls/riched32/Makefile])
1982 AC_CONFIG_FILES([dlls/riched32/tests/Makefile])
1983 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1984 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1985 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1986 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1987 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1988 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1989 AC_CONFIG_FILES([dlls/sccbase/Makefile])
1990 AC_CONFIG_FILES([dlls/schannel/Makefile])
1991 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1992 AC_CONFIG_FILES([dlls/secur32/Makefile])
1993 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1994 AC_CONFIG_FILES([dlls/security/Makefile])
1995 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1996 AC_CONFIG_FILES([dlls/serialui/Makefile])
1997 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1998 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1999 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
2000 AC_CONFIG_FILES([dlls/sfc/Makefile])
2001 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
2002 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
2003 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
2004 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
2005 AC_CONFIG_FILES([dlls/shell32/Makefile])
2006 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
2007 AC_CONFIG_FILES([dlls/shfolder/Makefile])
2008 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
2009 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
2010 AC_CONFIG_FILES([dlls/slbcsp/Makefile])
2011 AC_CONFIG_FILES([dlls/slc/Makefile])
2012 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
2013 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
2014 AC_CONFIG_FILES([dlls/softpub/Makefile])
2015 AC_CONFIG_FILES([dlls/spoolss/Makefile])
2016 AC_CONFIG_FILES([dlls/spoolss/tests/Makefile])
2017 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
2018 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
2019 AC_CONFIG_FILES([dlls/sti/Makefile])
2020 AC_CONFIG_FILES([dlls/strmiids/Makefile])
2021 AC_CONFIG_FILES([dlls/svrapi/Makefile])
2022 AC_CONFIG_FILES([dlls/sxs/Makefile])
2023 AC_CONFIG_FILES([dlls/tapi32/Makefile])
2024 AC_CONFIG_FILES([dlls/twain_32/Makefile])
2025 AC_CONFIG_FILES([dlls/unicows/Makefile])
2026 AC_CONFIG_FILES([dlls/url/Makefile])
2027 AC_CONFIG_FILES([dlls/urlmon/Makefile])
2028 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
2029 AC_CONFIG_FILES([dlls/user32/Makefile])
2030 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
2031 AC_CONFIG_FILES([dlls/userenv/Makefile])
2032 AC_CONFIG_FILES([dlls/userenv/tests/Makefile])
2033 AC_CONFIG_FILES([dlls/usp10/Makefile])
2034 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
2035 AC_CONFIG_FILES([dlls/uuid/Makefile])
2036 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
2037 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
2038 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
2039 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
2040 AC_CONFIG_FILES([dlls/version/Makefile])
2041 AC_CONFIG_FILES([dlls/version/tests/Makefile])
2042 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
2043 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
2044 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
2045 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
2046 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
2047 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
2048 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
2049 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
2050 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
2051 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
2052 AC_CONFIG_FILES([dlls/wined3d/Makefile])
2053 AC_CONFIG_FILES([dlls/winedos/Makefile])
2054 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
2055 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
2056 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
2057 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
2058 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
2059 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
2060 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
2061 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
2062 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
2063 AC_CONFIG_FILES([dlls/wing32/Makefile])
2064 AC_CONFIG_FILES([dlls/winhttp/Makefile])
2065 AC_CONFIG_FILES([dlls/winhttp/tests/Makefile])
2066 AC_CONFIG_FILES([dlls/wininet/Makefile])
2067 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
2068 AC_CONFIG_FILES([dlls/winmm/Makefile])
2069 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
2070 AC_CONFIG_FILES([dlls/winnls32/Makefile])
2071 AC_CONFIG_FILES([dlls/winscard/Makefile])
2072 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
2073 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
2074 AC_CONFIG_FILES([dlls/wintab32/Makefile])
2075 AC_CONFIG_FILES([dlls/wintrust/Makefile])
2076 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
2077 AC_CONFIG_FILES([dlls/wldap32/Makefile])
2078 AC_CONFIG_FILES([dlls/wmi/Makefile])
2079 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
2080 AC_CONFIG_FILES([dlls/wow32/Makefile])
2081 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
2082 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
2083 AC_CONFIG_FILES([dlls/wsock32/Makefile])
2084 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
2085 AC_CONFIG_FILES([documentation/Makefile])
2086 AC_CONFIG_FILES([fonts/Makefile])
2087 AC_CONFIG_FILES([include/Makefile])
2088 AC_CONFIG_FILES([libs/Makefile])
2089 AC_CONFIG_FILES([libs/port/Makefile])
2090 AC_CONFIG_FILES([libs/wine/Makefile])
2091 AC_CONFIG_FILES([libs/wpp/Makefile])
2092 AC_CONFIG_FILES([loader/Makefile])
2093 AC_CONFIG_FILES([programs/Makefile])
2094 AC_CONFIG_FILES([programs/clock/Makefile])
2095 AC_CONFIG_FILES([programs/cmd/Makefile])
2096 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
2097 AC_CONFIG_FILES([programs/control/Makefile])
2098 AC_CONFIG_FILES([programs/eject/Makefile])
2099 AC_CONFIG_FILES([programs/expand/Makefile])
2100 AC_CONFIG_FILES([programs/explorer/Makefile])
2101 AC_CONFIG_FILES([programs/hh/Makefile])
2102 AC_CONFIG_FILES([programs/icinfo/Makefile])
2103 AC_CONFIG_FILES([programs/iexplore/Makefile])
2104 AC_CONFIG_FILES([programs/msiexec/Makefile])
2105 AC_CONFIG_FILES([programs/net/Makefile])
2106 AC_CONFIG_FILES([programs/notepad/Makefile])
2107 AC_CONFIG_FILES([programs/oleview/Makefile])
2108 AC_CONFIG_FILES([programs/progman/Makefile])
2109 AC_CONFIG_FILES([programs/reg/Makefile])
2110 AC_CONFIG_FILES([programs/regedit/Makefile])
2111 AC_CONFIG_FILES([programs/regsvr32/Makefile])
2112 AC_CONFIG_FILES([programs/rpcss/Makefile])
2113 AC_CONFIG_FILES([programs/rundll32/Makefile])
2114 AC_CONFIG_FILES([programs/secedit/Makefile])
2115 AC_CONFIG_FILES([programs/services/Makefile])
2116 AC_CONFIG_FILES([programs/spoolsv/Makefile])
2117 AC_CONFIG_FILES([programs/start/Makefile])
2118 AC_CONFIG_FILES([programs/svchost/Makefile])
2119 AC_CONFIG_FILES([programs/taskmgr/Makefile])
2120 AC_CONFIG_FILES([programs/uninstaller/Makefile])
2121 AC_CONFIG_FILES([programs/view/Makefile])
2122 AC_CONFIG_FILES([programs/wineboot/Makefile])
2123 AC_CONFIG_FILES([programs/winebrowser/Makefile])
2124 AC_CONFIG_FILES([programs/winecfg/Makefile])
2125 AC_CONFIG_FILES([programs/wineconsole/Makefile])
2126 AC_CONFIG_FILES([programs/winedbg/Makefile])
2127 AC_CONFIG_FILES([programs/winedevice/Makefile])
2128 AC_CONFIG_FILES([programs/winefile/Makefile])
2129 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
2130 AC_CONFIG_FILES([programs/winemine/Makefile])
2131 AC_CONFIG_FILES([programs/winepath/Makefile])
2132 AC_CONFIG_FILES([programs/winetest/Makefile])
2133 AC_CONFIG_FILES([programs/winevdm/Makefile])
2134 AC_CONFIG_FILES([programs/winhlp32/Makefile])
2135 AC_CONFIG_FILES([programs/winver/Makefile])
2136 AC_CONFIG_FILES([programs/wordpad/Makefile])
2137 AC_CONFIG_FILES([programs/write/Makefile])
2138 AC_CONFIG_FILES([programs/xcopy/Makefile])
2139 AC_CONFIG_FILES([server/Makefile])
2140 AC_CONFIG_FILES([tools/Makefile])
2141 AC_CONFIG_FILES([tools/widl/Makefile])
2142 AC_CONFIG_FILES([tools/winebuild/Makefile])
2143 AC_CONFIG_FILES([tools/winedump/Makefile])
2144 AC_CONFIG_FILES([tools/winegcc/Makefile])
2145 AC_CONFIG_FILES([tools/wmc/Makefile])
2146 AC_CONFIG_FILES([tools/wrc/Makefile])
2147
2148 AC_OUTPUT
2149
2150 if test "$no_create" = "yes"
2151 then
2152   exit 0
2153 fi
2154
2155 WINE_PRINT_MESSAGES
2156
2157 echo "
2158 $as_me: Finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine.
2159 " >&AS_MESSAGE_FD
2160
2161 dnl Local Variables:
2162 dnl comment-start: "dnl "
2163 dnl comment-end: ""
2164 dnl comment-start-skip: "\\bdnl\\b\\s *"
2165 dnl compile-command: "autoreconf --warnings=all"
2166 dnl End: