aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_PROGRAM(), [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  79 CFLAGS=$ac_wine_try_cflags_saved])
  80 AS_IF([test AS_VAR_GET(ac_var) = yes],
  81       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  82 AS_VAR_POPDEF([ac_var])])
  83
  84 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  85 dnl
  86 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  87 dnl
  88 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  89 [ac_wine_try_cflags_saved=$CFLAGS
  90 CFLAGS="$CFLAGS $1"
  91 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  92 CFLAGS=$ac_wine_try_cflags_saved])
  93
  94 dnl **** Check whether we need to define a symbol on the compiler command line ****
  95 dnl
  96 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  97 dnl
  98 AC_DEFUN([WINE_CHECK_DEFINE],
  99 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 100 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 101     AC_EGREP_CPP(yes,[#ifndef $1
 102 yes
 103 #endif],
 104     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 105 AS_IF([test AS_VAR_GET(ac_var) = yes],
 106       [CFLAGS="$CFLAGS -D$1"
 107   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 108 AS_VAR_POPDEF([ac_var])])
 109
 110 dnl **** Check for functions with some extra libraries ****
 111 dnl
 112 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 113 dnl
 114 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 115 [ac_wine_check_funcs_save_LIBS="$LIBS"
 116 LIBS="$LIBS $2"
 117 AC_CHECK_FUNCS([$1],[$3],[$4])
 118 LIBS="$ac_wine_check_funcs_save_LIBS"])
 119
 120 dnl **** Check for ln ****
 121 dnl
 122 dnl Usage: WINE_PROG_LN
 123 dnl
 124 AC_DEFUN([WINE_PROG_LN],
 125 [AC_MSG_CHECKING([whether ln works])
 126 rm -f conf$$ conf$$.file
 127 echo >conf$$.file
 128 if ln conf$$.file conf$$ 2>/dev/null; then
 129   AC_SUBST(LN,ln)
 130   AC_MSG_RESULT([yes])
 131 else
 132   AC_SUBST(LN,["cp -p"])
 133   AC_MSG_RESULT([no, using $LN])
 134 fi
 135 rm -f conf$$ conf$$.file])
 136
 137 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 138 dnl
 139 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 140 dnl
 141 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 142 [AC_CHECK_PROGS([$1],
 143    m4_foreach([ac_wine_prefix],
 144               [i586-mingw32msvc, i386-mingw32msvc, i686-mingw32, i586-mingw32, i386-mingw32, mingw32, mingw],
 145               [ac_wine_prefix-$2 ]),
 146    [$3],[$4])])
 147
 148
 149 dnl **** Create nonexistent directories from config.status ****
 150 dnl
 151 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 152 dnl
 153 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 154 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || (AC_MSG_NOTICE([creating $1]) && mkdir "$1")])])
 155
 156 dnl **** Add a message to the list displayed at the end ****
 157 dnl
 158 dnl Usage: WINE_NOTICE(notice)
 159 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 160 dnl Usage: WINE_WARNING(warning)
 161 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 162 dnl Usage: WINE_PRINT_MESSAGES
 163 dnl
 164 AC_DEFUN([WINE_NOTICE],[wine_notices="$wine_notices|$1"])
 165 AC_DEFUN([WINE_WARNING],[wine_warnings="$wine_warnings|$1"])
 166
 167 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 168   x)   WINE_NOTICE([$3]) ;;
 169   xno) ;;
 170   *)   AC_MSG_ERROR([$3
 171 This is an error since --with-$1 was requested.]) ;;
 172 esac])])
 173
 174 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 175   x)   WINE_WARNING([$3]) ;;
 176   xno) ;;
 177   *)   AC_MSG_ERROR([$3
 178 This is an error since --with-$1 was requested.]) ;;
 179 esac])])
 180
 181 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 182 IFS="|"
 183 if test "x$wine_notices != "x; then
 184     echo >&AS_MESSAGE_FD
 185     for msg in $wine_notices; do
 186         if test -n "$msg"; then
 187             AC_MSG_NOTICE([$msg])
 188         fi
 189     done
 190 fi
 191 for msg in $wine_warnings; do
 192     if test -n "$msg"; then
 193         echo >&2
 194         AC_MSG_WARN([$msg])
 195     fi
 196 done
 197 IFS="$ac_save_IFS"])
 198
 199 dnl Local Variables:
 200 dnl compile-command: "autoreconf --warnings=all"
 201 dnl End: