aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]]),
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32,w64-mingw32],[x86_64-ac_wine_prefix-$2 ])" ;;
 132   *)
 133     ac_prefix_list="" ;;
 134 esac
 135 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 136
 137
 138 dnl **** Define helper functions for creating config.status files ****
 139 dnl
 140 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 141 dnl
 142 AC_DEFUN([WINE_CONFIG_HELPERS],
 143 [AC_SUBST(ALL_MAKEFILE_DEPENDS,["# Makefile dependencies
 144 Makefile: Makefile.in Make.rules config.status"])
 145 AC_SUBST(ALL_WINETEST_DEPENDS,["# Test binaries"])
 146
 147 AC_SUBST(ALL_MAKERULES,"")
 148 AC_SUBST(ALL_SYMLINKS,"")
 149 AC_SUBST(ALL_DIRS,"")
 150 AC_SUBST(ALL_TOP_DIRS,"")
 151 AC_SUBST(ALL_DLL_DIRS,"")
 152 AC_SUBST(ALL_TOOL_DIRS,"")
 153 AC_SUBST(ALL_STATICLIB_DIRS,"")
 154 AC_SUBST(ALL_STATIC_LIBS,"")
 155 AC_SUBST(ALL_IMPORT_LIBS,"")
 156 AC_SUBST(ALL_INSTALL_DIRS,"")
 157 AC_SUBST(ALL_TEST_DIRS,"")
 158 AC_SUBST(ALL_TEST_BINARIES,"")
 159 AC_SUBST(ALL_PROGRAM_DIRS,"")
 160 AC_SUBST(ALL_PROGRAM_BIN_INSTALL_DIRS,"")
 161
 162 wine_fn_append_file ()
 163 {
 164     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 165 }
 166
 167 wine_fn_append_rule ()
 168 {
 169     AS_VAR_APPEND($[1],"$as_nl$[2]")
 170 }
 171
 172 wine_fn_config_makefile ()
 173 {
 174     ac_dir=$[1]
 175     ac_enable=$[2]
 176     wine_fn_append_file ALL_DIRS $ac_dir
 177     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 178 "$ac_dir/__clean__ $ac_dir/__install__ $ac_dir/__install-dev__ $ac_dir/__install-lib__ $ac_dir/__uninstall__ $ac_dir: $ac_dir/Makefile
 179 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status Make.rules \$(MAKEDEP)
 180         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 181     AS_VAR_IF([$ac_enable],[no],,[case $ac_dir in
 182                  */*) ;;
 183                  *) wine_fn_append_file ALL_TOP_DIRS $ac_dir ;;
 184                esac])
 185 }
 186
 187 wine_fn_config_lib ()
 188 {
 189     ac_name=$[1]
 190     ac_dir=dlls/$ac_name
 191     wine_fn_append_file ALL_DIRS $ac_dir
 192     wine_fn_append_file ALL_STATICLIB_DIRS $ac_dir
 193     wine_fn_append_file ALL_STATIC_LIBS $ac_dir/lib$ac_name.a
 194     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 195 "$ac_dir/__install__ $ac_dir/__install-dev__: $ac_dir
 196 $ac_dir $ac_dir/lib$ac_name.cross.a: tools/widl tools/winebuild tools/winegcc include
 197 $ac_dir/lib$ac_name.cross.a: $ac_dir/Makefile dummy
 198         @cd $ac_dir && \$(MAKE) lib$ac_name.cross.a
 199 $ac_dir/__clean__ $ac_dir/__install-lib__ $ac_dir/__uninstall__ $ac_dir: $ac_dir/Makefile
 200 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status dlls/Makeimplib.rules \$(MAKEDEP)
 201         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 202 }
 203
 204 wine_fn_config_dll ()
 205 {
 206     ac_dir=$[1]
 207     ac_enable=$[2]
 208     ac_implib=$[3]
 209     ac_implibsrc=$[4]
 210     ac_file="dlls/$ac_dir/lib$ac_implib"
 211     ac_deps="tools/widl tools/winebuild tools/winegcc include"
 212
 213     wine_fn_append_file ALL_DIRS dlls/$ac_dir
 214     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 215 "dlls/$ac_dir dlls/$ac_dir/__install__ dlls/$ac_dir/__install-lib__ dlls/$ac_dir/__install-dev__: __builddeps__ dlls/$ac_dir/Makefile
 216 dlls/$ac_dir/__clean__ dlls/$ac_dir/__uninstall__ dlls/$ac_dir: dlls/$ac_dir/Makefile
 217 dlls/$ac_dir/Makefile dlls/$ac_dir/__depend__: dlls/$ac_dir/Makefile.in config.status dlls/Makedll.rules \$(MAKEDEP)
 218         @./config.status --file dlls/$ac_dir/Makefile && cd dlls/$ac_dir && \$(MAKE) depend"
 219     AS_VAR_IF([$ac_enable],[no],
 220               dnl enable_win16 is special in that it disables import libs too
 221               [test "$ac_enable" != enable_win16 || return 0],
 222               [wine_fn_append_file ALL_DLL_DIRS dlls/$ac_dir])
 223
 224     if test -n "$ac_implibsrc"
 225     then
 226         wine_fn_append_file ALL_IMPORT_LIBS $ac_file.$IMPLIBEXT
 227         wine_fn_append_file ALL_IMPORT_LIBS $ac_file.$STATIC_IMPLIBEXT
 228         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 229 "$ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 230 $ac_file.def: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 231         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`
 232 $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/Makefile dummy
 233         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`"
 234     elif test -n "$ac_implib"
 235     then
 236         wine_fn_append_file ALL_IMPORT_LIBS $ac_file.$IMPLIBEXT
 237         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 238 "$ac_file.$IMPLIBEXT $ac_file.cross.a: $ac_deps
 239 $ac_file.$IMPLIBEXT $ac_file.cross.a: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 240         @cd dlls/$ac_dir && \$(MAKE) \`basename \$[@]\`"
 241
 242         if test "$ac_dir" != "$ac_implib"
 243         then
 244             wine_fn_append_file ALL_IMPORT_LIBS dlls/lib$ac_implib.$IMPLIBEXT
 245             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 246 "dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 247         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.$IMPLIBEXT \$[@]
 248 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 249         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.cross.a \$[@]
 250 clean::
 251         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 252         fi
 253     fi
 254 }
 255
 256 wine_fn_config_program ()
 257 {
 258     ac_dir=$[1]
 259     ac_enable=$[2]
 260     ac_install=$[3]
 261     wine_fn_append_file ALL_DIRS programs/$ac_dir
 262     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 263 "programs/$ac_dir programs/$ac_dir/__install__ programs/$ac_dir/__install-lib__: __builddeps__ programs/$ac_dir/Makefile
 264 programs/$ac_dir/__clean__ programs/$ac_dir/__install-dev__ programs/$ac_dir/__uninstall__ programs/$ac_dir: programs/$ac_dir/Makefile
 265 programs/$ac_dir/Makefile programs/$ac_dir/__depend__: programs/$ac_dir/Makefile.in config.status programs/Makeprog.rules \$(MAKEDEP)
 266         @./config.status --file programs/$ac_dir/Makefile && cd programs/$ac_dir && \$(MAKE) depend"
 267     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_file ALL_PROGRAM_DIRS programs/$ac_dir
 268               case $ac_install in
 269                installbin) wine_fn_append_file ALL_INSTALL_DIRS programs/$ac_dir
 270                            wine_fn_append_file ALL_PROGRAM_BIN_INSTALL_DIRS programs/$ac_dir ;;
 271                install) wine_fn_append_file ALL_INSTALL_DIRS programs/$ac_dir ;;
 272               esac])
 273 }
 274
 275 wine_fn_config_test ()
 276 {
 277     ac_dir=$[1]
 278     ac_name=$[2]
 279     wine_fn_append_file ALL_TEST_BINARIES $ac_name.exe
 280     wine_fn_append_rule ALL_WINETEST_DEPENDS \
 281 "$ac_name.exe: \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT
 282         cp \$(TOPOBJDIR)/$ac_dir/$ac_name.exe$DLLEXT \$[@] && \$(STRIP) \$[@]
 283 $ac_name.rc:
 284         echo \"$ac_name.exe TESTRES \\\"$ac_name.exe\\\"\" >\$[@] || (\$(RM) \$[@] && false)
 285 $ac_name.res: $ac_name.rc $ac_name.exe"
 286     wine_fn_append_file ALL_DIRS $ac_dir
 287     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 288 "$ac_dir: __builddeps__
 289 $ac_dir/__crosstest__: __buildcrossdeps__
 290 $ac_dir/__clean__ $ac_dir/__crosstest__ $ac_dir: $ac_dir/Makefile
 291 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status Maketest.rules \$(MAKEDEP)
 292         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 293     AS_VAR_IF([enable_tests],[no],,[wine_fn_append_file ALL_TEST_DIRS $ac_dir])
 294 }
 295
 296 wine_fn_config_tool ()
 297 {
 298     ac_dir=$[1]
 299     ac_deps="Make.rules"
 300     if test "$ac_dir" != tools
 301     then
 302         dnl makedep is in tools so tools makefile cannot depend on it
 303         ac_deps="$ac_deps \$(MAKEDEP)"
 304     fi
 305     wine_fn_append_file ALL_DIRS $ac_dir
 306     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 307 "$ac_dir/__clean__ $ac_dir/__install__ $ac_dir/__install-dev__ $ac_dir/__install-lib__ $ac_dir/__uninstall__ $ac_dir: $ac_dir/Makefile
 308 $ac_dir/Makefile $ac_dir/__depend__: $ac_dir/Makefile.in config.status $ac_deps
 309         @./config.status --file $ac_dir/Makefile && cd $ac_dir && \$(MAKE) depend"
 310     AS_VAR_IF([enable_tools],[no],,[wine_fn_append_file ALL_TOOL_DIRS $ac_dir])
 311 }])
 312
 313 dnl **** Define helper function to append a file to a makefile file list ****
 314 dnl
 315 dnl Usage: WINE_APPEND_FILE(var,file)
 316 dnl
 317 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 318
 319 dnl **** Define helper function to append a rule to a makefile command list ****
 320 dnl
 321 dnl Usage: WINE_APPEND_RULE(var,rule)
 322 dnl
 323 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 324
 325 dnl **** Create nonexistent directories from config.status ****
 326 dnl
 327 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 328 dnl
 329 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 330 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 331
 332 dnl **** Create symlinks from config.status ****
 333 dnl
 334 dnl Usage: WINE_CONFIG_SYMLINK(name,target)
 335 dnl
 336 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 337 AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 338 m4_if([$2],,[test "$srcdir" = "." || ])WINE_APPEND_FILE(ALL_SYMLINKS,[$1])])
 339
 340 dnl **** Create a make rules file from config.status ****
 341 dnl
 342 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 343 dnl
 344 AC_DEFUN([WINE_CONFIG_MAKERULES],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 345 WINE_APPEND_FILE(ALL_MAKERULES,[$1])
 346 WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[$1: m4_ifval([$3],[$1.in $3],[$1.in]) config.status])
 347 $2=$1
 348 AC_SUBST_FILE([$2])dnl
 349 AC_CONFIG_FILES([$1])])
 350
 351 dnl **** Create a makefile from config.status ****
 352 dnl
 353 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable)
 354 dnl
 355 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 356 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 357 wine_fn_config_makefile [$1] ac_enable[]dnl
 358 AS_VAR_POPDEF([ac_enable])])
 359
 360 dnl **** Create a dll makefile from config.status ****
 361 dnl
 362 dnl Usage: WINE_CONFIG_DLL(name,enable,implib,implibsrc)
 363 dnl
 364 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 365 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 366 wine_fn_config_dll [$1] ac_enable [$3] m4_ifval([$4],["$4"])dnl
 367 AS_VAR_POPDEF([ac_enable])])
 368
 369 dnl **** Create a program makefile from config.status ****
 370 dnl
 371 dnl Usage: WINE_CONFIG_PROGRAM(name,install,enable)
 372 dnl
 373 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 374 AS_VAR_PUSHDEF([ac_enable],m4_default([$3],[enable_]$1))dnl
 375 wine_fn_config_program [$1] ac_enable [$2]dnl
 376 AS_VAR_POPDEF([ac_enable])])
 377
 378 dnl **** Create a test makefile from config.status ****
 379 dnl
 380 dnl Usage: WINE_CONFIG_TEST(dir)
 381 dnl
 382 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 383 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 384 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 385 wine_fn_config_test $1 ac_name[]ac_suffix[]dnl
 386 m4_popdef([ac_suffix])dnl
 387 m4_popdef([ac_name])])
 388
 389 dnl **** Create a static lib makefile from config.status ****
 390 dnl
 391 dnl Usage: WINE_CONFIG_LIB(name)
 392 dnl
 393 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 394 wine_fn_config_lib $1])
 395
 396 dnl **** Create a tool makefile from config.status ****
 397 dnl
 398 dnl Usage: WINE_CONFIG_TOOL(name)
 399 dnl
 400 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 401 wine_fn_config_tool $1])
 402
 403 dnl **** Add a message to the list displayed at the end ****
 404 dnl
 405 dnl Usage: WINE_NOTICE(notice)
 406 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 407 dnl Usage: WINE_WARNING(warning)
 408 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 409 dnl Usage: WINE_PRINT_MESSAGES
 410 dnl
 411 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 412 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 413
 414 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 415   x)   WINE_NOTICE([$3]) ;;
 416   xno) ;;
 417   *)   AC_MSG_ERROR([$3
 418 This is an error since --with-$1 was requested.]) ;;
 419 esac])])
 420
 421 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 422   x)   WINE_WARNING([$3]) ;;
 423   xno) ;;
 424   *)   AC_MSG_ERROR([$3
 425 This is an error since --with-$1 was requested.]) ;;
 426 esac])])
 427
 428 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 429   xno) ;;
 430   *)   AC_MSG_ERROR([$3
 431 Use the --without-$1 option if you really want this.]) ;;
 432 esac])])
 433
 434 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 435 if test "x$wine_notices != "x; then
 436     echo >&AS_MESSAGE_FD
 437     IFS="|"
 438     for msg in $wine_notices; do
 439         IFS="$ac_save_IFS"
 440         if test -n "$msg"; then
 441             AC_MSG_NOTICE([$msg])
 442         fi
 443     done
 444 fi
 445 IFS="|"
 446 for msg in $wine_warnings; do
 447     IFS="$ac_save_IFS"
 448     if test -n "$msg"; then
 449         echo >&2
 450         AC_MSG_WARN([$msg])
 451     fi
 452 done
 453 IFS="$ac_save_IFS"])
 454
 455 dnl Local Variables:
 456 dnl compile-command: "autoreconf --warnings=all"
 457 dnl End: