aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_SOURCE([int main(int argc, char *argv[]) { return 0; }]),
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32,w64-mingw32],[x86_64-ac_wine_prefix-$2 ])" ;;
 132   *)
 133     ac_prefix_list="" ;;
 134 esac
 135 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 136
 137
 138 dnl **** Define helper functions for creating config.status files ****
 139 dnl
 140 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 141 dnl
 142 AC_DEFUN([WINE_CONFIG_HELPERS],
 143 [wine_fn_append_file ()
 144 {
 145     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 146 }
 147 wine_fn_append_rule ()
 148 {
 149     AS_VAR_APPEND($[1],"$as_nl$[2]")
 150 }])
 151
 152 dnl **** Define helper function to append a file to a makefile file list ****
 153 dnl
 154 dnl Usage: WINE_APPEND_FILE(var,file)
 155 dnl
 156 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 157
 158 dnl **** Define helper function to append a rule to a makefile command list ****
 159 dnl
 160 dnl Usage: WINE_APPEND_RULE(var,rule)
 161 dnl
 162 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 163
 164 dnl **** Create nonexistent directories from config.status ****
 165 dnl
 166 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 167 dnl
 168 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 169 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 170
 171 dnl **** Create symlinks from config.status ****
 172 dnl
 173 dnl Usage: WINE_CONFIG_SYMLINK(name,target)
 174 dnl
 175 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 176 AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 177 m4_if([$2],,[test "$srcdir" = "." || ])WINE_APPEND_FILE(ALL_SYMLINKS,[$1])])
 178
 179 dnl **** Create a make rules file from config.status ****
 180 dnl
 181 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 182 dnl
 183 AC_DEFUN([WINE_CONFIG_MAKERULES],
 184 [WINE_APPEND_FILE(ALL_MAKERULES,[$1])
 185 WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[$1: m4_ifval([$3],[$1.in $3],[$1.in]) config.status])
 186 $2=$1
 187 AC_SUBST_FILE([$2])dnl
 188 AC_CONFIG_FILES([$1])])
 189
 190 dnl **** Create a makefile from config.status ****
 191 dnl
 192 dnl Usage: WINE_CONFIG_MAKEFILE(file,deps,var,enable)
 193 dnl
 194 AC_DEFUN([WINE_CONFIG_MAKEFILE],
 195 [m4_pushdef([ac_dir],m4_bpatsubst([$1],[^\(\(.*\)/\)?Makefile$],[\2]))dnl
 196 m4_pushdef([ac_name],m4_bpatsubst(ac_dir,[.*/\(.*\)$],[\1]))dnl
 197 m4_ifval(ac_dir,WINE_APPEND_FILE(ALL_DIRS,ac_dir))
 198 AS_VAR_PUSHDEF([ac_enable],m4_default([$4],[enable_]ac_name))dnl
 199 m4_ifval([$3],[test "x$ac_enable" != xno]m4_foreach([ac_var],[$3],[ && WINE_APPEND_FILE(ac_var,ac_dir)]))
 200 AS_VAR_POPDEF([ac_enable])dnl
 201 WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[m4_ifval(ac_dir,[\$(RECURSE_TARGETS:%=ac_dir/%) ac_dir: $1 \$(MAKEDEP)
 202 ])[$1: ]m4_ifval([$2],[$1.in $2],[$1.in]) config.status])
 203 AC_CONFIG_FILES([$1])dnl
 204 m4_popdef([ac_dir])dnl
 205 m4_popdef([ac_name])])
 206
 207 dnl **** Create a dll makefile from config.status ****
 208 dnl
 209 dnl Usage: WINE_CONFIG_DLL(name,enable,implib,implibsrc)
 210 dnl
 211 AC_DEFUN([WINE_CONFIG_DLL],
 212 [m4_pushdef([ac_implib],m4_ifval([$3],[dlls/$1/lib$3.$IMPLIBEXT]))dnl
 213 m4_pushdef([ac_crosslib],m4_ifval([$3],[dlls/$1/lib$3.cross.a]))dnl
 214 m4_pushdef([ac_staticlib],m4_ifval([$4],[dlls/$1/lib$3.$STATIC_IMPLIBEXT]))dnl
 215 m4_pushdef([ac_symlink],m4_if([$1],[$3],,[dlls/lib$3.$IMPLIBEXT]))dnl
 216 m4_ifval(ac_implib,[m4_ifval([$2],[test "x$[$2]" != xno && ])WINE_APPEND_FILE(ALL_IMPORT_LIBS,ac_implib)dnl
 217 m4_ifval(ac_symlink,[ && WINE_APPEND_FILE(ALL_IMPORT_LIBS,ac_symlink)])dnl
 218 m4_ifval(ac_staticlib,[ && WINE_APPEND_FILE(ALL_IMPORT_LIBS,ac_staticlib)])
 219 ])WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,
 220 [m4_ifval(ac_implib,[ac_implib m4_ifval(ac_staticlib,[ac_staticlib ])ac_crosslib: tools/widl tools/winebuild tools/winegcc include
 221 m4_ifval(ac_symlink,[ac_symlink: ac_implib
 222         \$(RM) \$[@] && \$(LN_S) $1/lib$3.$IMPLIBEXT \$[@]
 223 dlls/lib$3.cross.a: ac_crosslib
 224         \$(RM) \$[@] && \$(LN_S) $1/lib$3.cross.a \$[@]
 225 clean::
 226         \$(RM) ac_symlink
 227 ])m4_ifval(ac_staticlib,[dlls/$1/lib$3.def: dlls/$1/$1.spec dlls/$1/Makefile
 228         @cd dlls/$1 && \$(MAKE) \`basename \$[@]\`
 229 ac_staticlib ac_crosslib: dlls/$1/Makefile dummy
 230         @cd dlls/$1 && \$(MAKE) \`basename \$[@]\`],
 231 [ac_implib ac_crosslib: dlls/$1/$1.spec dlls/$1/Makefile
 232         @cd dlls/$1 && \$(MAKE) \`basename \$[@]\`])
 233 ])dlls/$1 dlls/$1/__install__ dlls/$1/__install-lib__ dlls/$1/__install-dev__: __builddeps__])
 234 WINE_CONFIG_MAKEFILE([dlls/$1/Makefile],[dlls/Makedll.rules],[ALL_DLL_DIRS],[$2])dnl
 235 m4_popdef([ac_implib])dnl
 236 m4_popdef([ac_crosslib])dnl
 237 m4_popdef([ac_staticlib])dnl
 238 m4_popdef([ac_symlink])])
 239
 240 dnl **** Create a program makefile from config.status ****
 241 dnl
 242 dnl Usage: WINE_CONFIG_PROGRAM(name,var,enable)
 243 dnl
 244 AC_DEFUN([WINE_CONFIG_PROGRAM],
 245 [WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[programs/$1 programs/$1/__install__ programs/$1/__install-lib__: __builddeps__])
 246 WINE_CONFIG_MAKEFILE([programs/$1/Makefile],[programs/Makeprog.rules],[$2],[$3])])
 247
 248 dnl **** Create a test makefile from config.status ****
 249 dnl
 250 dnl Usage: WINE_CONFIG_TEST(dir)
 251 dnl
 252 AC_DEFUN([WINE_CONFIG_TEST],
 253 [m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 254 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])]ac_suffix)dnl
 255 WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[$1: __builddeps__
 256 $1/__crosstest__: __buildcrossdeps__])
 257 WINE_APPEND_FILE(ALL_TEST_BINARIES,[ac_name.exe])
 258 WINE_APPEND_RULE(ALL_WINETEST_DEPENDS,
 259 [ac_name.exe: \$(TOPOBJDIR)/$1/ac_name.exe$DLLEXT
 260         cp \$(TOPOBJDIR)/$1/ac_name.exe$DLLEXT \$[@] && \$(STRIP) \$[@]
 261 ac_name.rc:
 262         echo \"ac_name.exe TESTRES \\\"ac_name.exe\\\"\" >\$[@] || (\$(RM) \$[@] && false)
 263 ac_name.res: ac_name.rc ac_name.exe])
 264 WINE_CONFIG_MAKEFILE([$1/Makefile],[Maketest.rules],[ALL_TEST_DIRS],[enable_tests])dnl
 265 m4_popdef([ac_suffix])dnl
 266 m4_popdef([ac_name])])
 267
 268 dnl **** Create a static lib makefile from config.status ****
 269 dnl
 270 dnl Usage: WINE_CONFIG_LIB(name)
 271 dnl
 272 AC_DEFUN([WINE_CONFIG_LIB],
 273 [WINE_APPEND_FILE(ALL_STATIC_LIBS,[dlls/$1/lib$1.a])
 274 WINE_APPEND_RULE(ALL_MAKEFILE_DEPENDS,[dlls/$1: tools/widl tools/winebuild tools/winegcc include
 275 dlls/$1/__install__ dlls/$1/__install-dev__: dlls/$1
 276 dlls/$1/lib$1.cross.a: dlls/$1/Makefile tools/widl tools/winebuild tools/winegcc include dummy
 277         @cd dlls/$1 && \$(MAKE) \`basename \$[@]\`])
 278 WINE_CONFIG_MAKEFILE([dlls/$1/Makefile],[dlls/Makeimplib.rules],[ALL_STATICLIB_DIRS])])
 279
 280 dnl **** Add a message to the list displayed at the end ****
 281 dnl
 282 dnl Usage: WINE_NOTICE(notice)
 283 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 284 dnl Usage: WINE_WARNING(warning)
 285 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 286 dnl Usage: WINE_PRINT_MESSAGES
 287 dnl
 288 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 289 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 290
 291 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 292   x)   WINE_NOTICE([$3]) ;;
 293   xno) ;;
 294   *)   AC_MSG_ERROR([$3
 295 This is an error since --with-$1 was requested.]) ;;
 296 esac])])
 297
 298 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 299   x)   WINE_WARNING([$3]) ;;
 300   xno) ;;
 301   *)   AC_MSG_ERROR([$3
 302 This is an error since --with-$1 was requested.]) ;;
 303 esac])])
 304
 305 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 306   xno) ;;
 307   *)   AC_MSG_ERROR([$3
 308 Use the --without-$1 option if you really want this.]) ;;
 309 esac])])
 310
 311 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 312 if test "x$wine_notices != "x; then
 313     echo >&AS_MESSAGE_FD
 314     IFS="|"
 315     for msg in $wine_notices; do
 316         IFS="$ac_save_IFS"
 317         if test -n "$msg"; then
 318             AC_MSG_NOTICE([$msg])
 319         fi
 320     done
 321 fi
 322 IFS="|"
 323 for msg in $wine_warnings; do
 324     IFS="$ac_save_IFS"
 325     if test -n "$msg"; then
 326         echo >&2
 327         AC_MSG_WARN([$msg])
 328     fi
 329 done
 330 IFS="$ac_save_IFS"])
 331
 332 dnl Local Variables:
 333 dnl compile-command: "autoreconf --warnings=all"
 334 dnl End: