configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  19
  20 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  21 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  23
  24 AC_SUBST(DLLDEFS,"")
  25 if test "x$enable_debug" = "xno"
  26 then
  27   DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
  28 fi
  29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  30 then
  31   DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
  32 fi
  33
  34 AC_CANONICAL_HOST
  35 case $host in
  36   x86_64*linux*)
  37     if test "x$enable_win64" != "xyes"
  38     then
  39       test -n "$CC" || CC="gcc -m32"
  40       test -n "$LD" || LD="ld -m elf_i386"
  41       test -n "$AS" || AS="as --32"
  42       host_cpu="i386"
  43     fi
  44     ;;
  45 esac
  46
  47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  48 case $host_cpu in
  49   *i[[3456789]]86*)
  50     if test "x$enable_win16" != "xno"
  51     then
  52       enable_win16="yes"
  53     fi
  54     ;;
  55 esac
  56
  57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  59 if test "x$enable_win16" != "xyes"
  60 then
  61   WIN16_FILES=""
  62   WIN16_INSTALL=""
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CXX
  70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  72
  73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  74   [if test -z "$with_wine_tools"; then
  75      if test "$cross_compiling" = "yes"; then
  76        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  77      else
  78        wine_cv_toolsdir="\$(TOPOBJDIR)"
  79      fi
  80    elif test -d "$with_wine_tools/tools/winebuild"; then
  81      case $with_wine_tools in
  82        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  83        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  84      esac
  85    else
  86      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  87    fi])
  88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  89
  90 AC_PATH_XTRA
  91 AC_PROG_LEX
  92
  93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  94 dnl **** without one present.
  95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  96 if test "$XLEX" = "none"
  97 then
  98   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  99 fi
 100
 101 dnl Check for bison
 102 AC_CHECK_PROGS(BISON,bison,none)
 103 if test "$BISON" = "none"
 104 then
 105   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 106 fi
 107
 108 AC_CHECK_TOOLS(AS,[gas as],as)
 109 AC_CHECK_TOOL(LD,ld,ld)
 110 AC_CHECK_TOOL(AR,ar,ar)
 111 AC_PROG_RANLIB
 112 AC_CHECK_TOOL(STRIP,strip,strip)
 113 AC_CHECK_TOOL(WINDRES,windres,false)
 114 AC_PROG_LN_S
 115 WINE_PROG_LN
 116 AC_PROG_EGREP
 117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 118 AC_PROG_INSTALL
 119 dnl Prepend src dir to install path dir if it's a relative path
 120 case "$INSTALL" in
 121   [[\\/$]]* | ?:[[\\/]]* ) ;;
 122   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 123 esac
 124
 125 dnl Check for lint
 126 AC_CHECK_PROGS(LINT, lclint lint)
 127 if test "$LINT" = "lint"
 128 then
 129   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 130   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 131 fi
 132 AC_SUBST(LINT)
 133 AC_SUBST(LINTFLAGS)
 134
 135 dnl Check for various programs
 136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 137 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 138
 139 case $host_cpu in
 140   *i[[3456789]]86*)
 141     AC_CHECK_PROGS(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 142     ;;
 143 esac
 144
 145 dnl **** Check for some libraries ****
 146
 147 dnl Check for -li386 for NetBSD and OpenBSD
 148 AC_CHECK_LIB(i386,i386_set_ldt)
 149 dnl Check for -lossaudio for NetBSD
 150 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 151 dnl Check for -lnsl for Solaris
 152 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 153 dnl Check for -lsocket for Solaris
 154 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 155 dnl Check for -lresolv for Solaris
 156 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 157 dnl Check for -lxpg4 for FreeBSD
 158 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 159 dnl Check for -lpoll for Mac OS X/Darwin
 160 AC_CHECK_LIB(poll,poll)
 161 dnl Check for -lresolv for Mac OS X/Darwin
 162 AC_CHECK_LIB(resolv,res_9_init)
 163 dnl Check for -lpthread
 164 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 165
 166 AC_SUBST(XLIB,"")
 167 AC_SUBST(XFILES,"")
 168 AC_SUBST(OPENGLFILES,"")
 169 AC_SUBST(GLU32FILES,"")
 170 AC_SUBST(OPENGL_LIBS,"")
 171
 172 dnl **** Check for header files ****
 173
 174 AC_CHECK_HEADERS(\
 175         IOKit/IOKitLib.h \
 176         alsa/asoundlib.h \
 177         arpa/inet.h \
 178         arpa/nameser.h \
 179         asm/types.h \
 180         capi20.h \
 181         cups/cups.h \
 182         curses.h \
 183         direct.h \
 184         dlfcn.h \
 185         elf.h \
 186         float.h \
 187         fontconfig/fontconfig.h \
 188         getopt.h \
 189         gif_lib.h \
 190         ieeefp.h \
 191         io.h \
 192         jack/jack.h \
 193         jpeglib.h \
 194         lber.h \
 195         lcms.h \
 196         lcms/lcms.h \
 197         ldap.h \
 198         libaudioio.h \
 199         link.h \
 200         linux/capi.h \
 201         linux/cdrom.h \
 202         linux/compiler.h \
 203         linux/hdreg.h \
 204         linux/input.h \
 205         linux/ioctl.h \
 206         linux/joystick.h \
 207         linux/major.h \
 208         linux/param.h \
 209         linux/serial.h \
 210         linux/ucdrom.h \
 211         mach/machine.h \
 212         machine/cpu.h \
 213         machine/limits.h \
 214         machine/soundcard.h \
 215         mntent.h \
 216         ncurses.h \
 217         netdb.h \
 218         netinet/in.h \
 219         netinet/in_systm.h \
 220         netinet/tcp.h \
 221         netinet/tcp_fsm.h \
 222         openssl/ssl.h \
 223         poll.h \
 224         process.h \
 225         pthread.h \
 226         pwd.h \
 227         regex.h \
 228         sched.h \
 229         scsi/scsi.h \
 230         scsi/scsi_ioctl.h \
 231         scsi/sg.h \
 232         soundcard.h \
 233         stdint.h \
 234         strings.h \
 235         sys/asoundlib.h \
 236         sys/cdio.h \
 237         sys/elf32.h \
 238         sys/epoll.h \
 239         sys/errno.h \
 240         sys/exec_elf.h \
 241         sys/filio.h \
 242         sys/ioctl.h \
 243         sys/ipc.h \
 244         sys/link.h \
 245         sys/lwp.h \
 246         sys/mman.h \
 247         sys/modem.h \
 248         sys/msg.h \
 249         sys/param.h \
 250         sys/poll.h \
 251         sys/ptrace.h \
 252         sys/reg.h \
 253         sys/scsiio.h \
 254         sys/shm.h \
 255         sys/signal.h \
 256         sys/socket.h \
 257         sys/sockio.h \
 258         sys/soundcard.h \
 259         sys/statvfs.h \
 260         sys/strtio.h \
 261         sys/syscall.h \
 262         sys/sysctl.h \
 263         sys/time.h \
 264         sys/times.h \
 265         sys/uio.h \
 266         sys/un.h \
 267         sys/vm86.h \
 268         sys/wait.h \
 269         syscall.h \
 270         termios.h \
 271         unicode/ubidi.h \
 272         unistd.h \
 273         utime.h \
 274         valgrind/memcheck.h
 275 )
 276 AC_HEADER_STAT()
 277
 278 dnl **** Check for X11 ****
 279
 280 if test "$have_x" = "yes"
 281 then
 282     XLIB="-lXext -lX11"
 283     ac_save_CPPFLAGS="$CPPFLAGS"
 284     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 285
 286     dnl *** All of the following tests require X11/Xlib.h
 287     AC_CHECK_HEADERS([X11/Xlib.h \
 288                       X11/XKBlib.h \
 289                       X11/Xutil.h \
 290                       X11/extensions/shape.h \
 291                       X11/extensions/XInput.h \
 292                       X11/extensions/XShm.h \
 293                       X11/extensions/Xrandr.h \
 294                       X11/extensions/Xrender.h \
 295                       X11/extensions/xf86dga.h \
 296                       X11/extensions/xf86vmode.h],,,
 297 [#ifdef HAVE_X11_XLIB_H
 298 # include <X11/Xlib.h>
 299 #endif
 300 #ifdef HAVE_X11_XUTIL_H
 301 # include <X11/Xutil.h>
 302 #endif])
 303
 304         dnl *** Check for X keyboard extension
 305         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 306         then
 307               AC_CHECK_LIB(X11, XkbQueryExtension,
 308               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 309               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 310         fi
 311
 312         dnl *** Check for X Shm extension
 313         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 314         then
 315               AC_CHECK_LIB(Xext, XShmQueryExtension,
 316               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 317               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 318         fi
 319
 320         dnl *** Check for X shape extension
 321         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 322         then
 323               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 324               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 325               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 326         fi
 327
 328         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 329         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 330         then
 331               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 332                 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 333                             [Define if you have the Xxf86dga library version 2])
 334                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 335                 ],,
 336                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 337         fi
 338
 339         dnl *** Check for XFree86 VMODE extension
 340         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 341         then
 342                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 343                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 344                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 345                   ],,
 346                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 347         fi
 348
 349         dnl *** Check for X RandR extension
 350         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 351         then
 352                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 353 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 354                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 355         fi
 356
 357         dnl *** Check for Transform functions in Xrender
 358         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 359         then
 360               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 361                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 362                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 363                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 364         fi
 365     dnl *** End of X11/Xlib.h check
 366
 367     dnl Check for the presence of OpenGL
 368     if test "x$with_opengl" != "xno"
 369     then
 370         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h,,,
 371 [#ifdef HAVE_GL_GLX_H
 372 # include <GL/glx.h>
 373 #endif])
 374         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 375         then
 376             dnl Check for some problems due to old Mesa versions
 377             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 378               AC_TRY_COMPILE(
 379                 [#include <GL/gl.h>],
 380                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 381                 [wine_cv_opengl_version_OK="yes"],
 382                 [wine_cv_opengl_version_OK="no"]
 383               )
 384             )
 385
 386             if test "$wine_cv_opengl_version_OK" = "yes"
 387             then
 388                 dnl Check for the presence of the library
 389                 AC_CHECK_LIB(GL,glXCreateContext,
 390                              OPENGL_LIBS="-lGL"
 391                              ,,
 392                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 393
 394                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 395                 then
 396                         OPENGLFILES='$(OPENGLFILES)'
 397                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 398                 else
 399                     if test -f /usr/X11R6/lib/libGL.a
 400                     then
 401                        AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 402 This prevents linking to OpenGL. Delete the file and restart configure.])
 403                     fi
 404                 fi
 405
 406                 dnl Check for GLU32 library.
 407                 AC_CHECK_LIB(GLU,gluLookAt,
 408                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 409                              GLU32FILES='$(GLU32FILES)']
 410                              ,,
 411                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 412                 )
 413              fi
 414
 415              dnl Check for glut32 library.
 416              AC_CHECK_LIB(glut,glutMainLoop,
 417                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 418                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 419                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 420          fi
 421     fi
 422
 423     dnl **** Check for NAS ****
 424     AC_SUBST(NASLIBS,"")
 425     AC_CHECK_HEADERS(audio/audiolib.h,
 426          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 427           AC_CHECK_LIB(audio,AuCreateFlow,
 428                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 429                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 430                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 431
 432     CPPFLAGS="$ac_save_CPPFLAGS"
 433     XFILES='$(XFILES)'
 434 else
 435     XLIB=""
 436     X_CFLAGS=""
 437     X_LIBS=""
 438 fi
 439
 440 dnl **** Check for libxml2 ****
 441
 442 AC_SUBST(XML2LIBS,"")
 443 AC_SUBST(XML2INCL,"")
 444 if test "$PKG_CONFIG" != "false"
 445 then
 446     ac_save_CPPFLAGS="$CPPFLAGS"
 447     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0`"
 448     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0`"
 449     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 450     AC_CHECK_HEADERS(libxml/parser.h,
 451         [AC_CHECK_LIB(xml2, xmlParseMemory,
 452             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 453              XML2LIBS="$ac_xml_libs"
 454              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)])
 455     CPPFLAGS="$ac_save_CPPFLAGS"
 456 fi
 457
 458 dnl **** Check which curses lib to use ***
 459 CURSESLIBS=""
 460 if test "x$with_curses" != "xno"
 461 then
 462     if test "$ac_cv_header_ncurses_h" = "yes"
 463     then
 464         AC_CHECK_LIB(ncurses,waddch,
 465             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 466              CURSESLIBS="-lncurses"])
 467     elif test "$ac_cv_header_curses_h" = "yes"
 468     then
 469         AC_CHECK_LIB(curses,waddch,
 470             [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 471              CURSESLIBS="-lcurses"])
 472     fi
 473 fi
 474 AC_SUBST(CURSESLIBS)
 475
 476 dnl **** Check for SANE ****
 477 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 478 AC_SUBST(SANELIBS,"")
 479 AC_SUBST(SANEINCL,"")
 480 if test "$sane_devel" != "no"
 481 then
 482     SANELIBS="`$sane_devel --libs`"
 483     SANEINCL="`$sane_devel --cflags`"
 484     ac_save_CPPFLAGS="$CPPFLAGS"
 485     ac_save_LIBS="$LIBS"
 486     CPPFLAGS="$CPPFLAGS $SANEINCL"
 487     LIBS="$LIBS $SANELIBS"
 488     AC_CHECK_HEADER(sane/sane.h,
 489                     [AC_CHECK_LIB(sane,sane_open,
 490                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 491                                   [SANELIBS=""
 492                                   SANEINCL=""])],
 493                     [SANELIBS=""
 494                     SANEINCL=""])
 495     LIBS="$ac_save_LIBS"
 496     CPPFLAGS="$ac_save_CPPFLAGS"
 497 fi
 498
 499 dnl **** Check for the ICU library ****
 500 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 501 then
 502     saved_libs="$LIBS"
 503     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 504     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 505     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 506     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 507     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 508     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 509                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 510                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 511                  AC_MSG_RESULT(yes)],
 512                 [AC_MSG_RESULT(no)])
 513     LIBS="$saved_libs"
 514 fi
 515
 516 dnl **** Check for LittleCMS ***
 517 AC_SUBST(LCMSLIBS,"")
 518 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 519 then
 520     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 521         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 522          LCMSLIBS="-llcms"])
 523 fi
 524
 525 dnl **** Check for OpenLDAP ***
 526 AC_SUBST(LDAPLIBS,"")
 527 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 528 then
 529     AC_CHECK_LIB(ldap, ldap_init,
 530         [AC_CHECK_LIB(lber, ber_init,
 531             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 532              LDAPLIBS="-lldap -llber"])])
 533 fi
 534
 535 dnl **** Check for FreeType 2 ****
 536 AC_SUBST(FREETYPELIBS,"")
 537 AC_SUBST(FREETYPEINCL,"")
 538 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 539 if test "$ft_lib" = "no"
 540 then
 541     wine_cv_msg_freetype=no
 542 else
 543     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 544     if test "$ft_devel" = "no"
 545     then
 546         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 547         if test "$ft_devel2" = "freetype2-config"
 548         then
 549                 ft_devel=$ft_devel2
 550         fi
 551     fi
 552     if test "$ft_devel" = "no"
 553     then
 554         wine_cv_msg_freetype=yes
 555     else
 556         FREETYPELIBS=`$ft_devel --libs`
 557         FREETYPEINCL=`$ft_devel --cflags`
 558         ac_save_CPPFLAGS="$CPPFLAGS"
 559         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 560         AC_CHECK_HEADERS(ft2build.h \
 561                          freetype/freetype.h \
 562                          freetype/ftglyph.h \
 563                          freetype/tttables.h \
 564                          freetype/ftnames.h \
 565                          freetype/ftsnames.h \
 566                          freetype/ttnameid.h \
 567                          freetype/ftoutln.h \
 568                          freetype/ftwinfnt.h \
 569                          freetype/internal/sfnt.h,,,
 570                          [#if HAVE_FT2BUILD_H
 571                           #include <ft2build.h>
 572                           #endif])
 573         AC_TRY_CPP([#include <ft2build.h>
 574                     #include <freetype/fttrigon.h>],
 575                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 576           [Define if you have the <freetype/fttrigon.h> header file.])
 577                     wine_cv_fttrigon=yes],
 578                     wine_cv_fttrigon=no)
 579         CPPFLAGS="$ac_save_CPPFLAGS"
 580         dnl Check that we have at least freetype/freetype.h
 581         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 582         then
 583             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 584             wine_cv_msg_freetype=no
 585         else
 586             FREETYPELIBS=""
 587             FREETYPEINCL=""
 588             wine_cv_msg_freetype=yes
 589         fi
 590     fi
 591 fi
 592
 593 dnl Only build the fonts dir if we have both freetype and fontforge
 594 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 595 then
 596   AC_SUBST(FONTSSUBDIRS,"fonts")
 597 fi
 598
 599 dnl **** Check for parport (currently Linux only) ****
 600 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 601  AC_TRY_COMPILE(
 602    [#include <linux/ppdev.h>],
 603    [ioctl (1,PPCLAIM,0)],
 604    [ac_cv_c_ppdev="yes"],
 605    [ac_cv_c_ppdev="no"])
 606  )
 607 if test "$ac_cv_c_ppdev" = "yes"
 608 then
 609     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 610 fi
 611
 612 dnl **** Check for va_copy ****
 613 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 614  AC_TRY_LINK(
 615    [#include <stdarg.h>],
 616    [va_list ap1, ap2;
 617     va_copy(ap1,ap2);
 618    ],
 619    [ac_cv_c_va_copy="yes"],
 620    [ac_cv_c_va_copy="no"])
 621  )
 622 if test "$ac_cv_c_va_copy" = "yes"
 623 then
 624     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 625 fi
 626 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 627  AC_TRY_LINK(
 628    [#include <stdarg.h>],
 629    [va_list ap1, ap2;
 630     __va_copy(ap1,ap2);
 631    ],
 632    [ac_cv_c___va_copy="yes"],
 633    [ac_cv_c___va_copy="no"])
 634  )
 635 if test "$ac_cv_c___va_copy" = "yes"
 636 then
 637     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 638 fi
 639
 640 dnl **** Check for sigsetjmp ****
 641 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 642  AC_TRY_LINK(
 643    [#include <setjmp.h>],
 644    [sigjmp_buf buf;
 645     sigsetjmp( buf, 1 );
 646     siglongjmp( buf, 1 );],
 647    [ac_cv_c_sigsetjmp="yes"],
 648    [ac_cv_c_sigsetjmp="no"])
 649  )
 650 if test "$ac_cv_c_sigsetjmp" = "yes"
 651 then
 652     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 653 fi
 654
 655 dnl **** Check for pthread_rwlock_t ****
 656 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 657 #include <pthread.h>])
 658
 659 dnl **** Check for pthread functions ****
 660 ac_save_LIBS="$LIBS"
 661 LIBS="$LIBS $LIBPTHREAD"
 662 AC_CHECK_FUNCS(\
 663         pthread_getattr_np \
 664         pthread_get_stackaddr_np \
 665         pthread_get_stacksize_np \
 666 )
 667 LIBS="$ac_save_LIBS"
 668
 669 dnl **** Check for aRts Sound Server ****
 670 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 671 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 672 then
 673     ARTSC_CFLAGS=""
 674     for i in `$ARTSCCONFIG --cflags`
 675     do
 676       case "$i" in
 677         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 678       esac
 679     done
 680     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 681     save_CFLAGS="$CFLAGS"
 682     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 683     AC_CHECK_LIB(artsc,arts_init,
 684         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 685             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 686             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 687             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
 688             $ARTSC_LIBS)
 689     CFLAGS="$save_CFLAGS"
 690 fi
 691
 692 dnl **** Check for EsounD ****
 693 AC_PATH_PROG(ESDCONFIG, esd-config)
 694 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 695 then
 696     ESD_CFLAGS=""
 697     for i in `$ESDCONFIG --cflags`
 698     do
 699       case "$i" in
 700         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 701       esac
 702     done
 703     ESD_LIBS=`$ESDCONFIG --libs`
 704     save_CFLAGS="$CFLAGS"
 705     CFLAGS="$CFLAGS $ESD_CFLAGS"
 706     AC_CHECK_LIB(esd,esd_open_sound,
 707         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 708          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 709          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 710     CFLAGS="$save_CFLAGS"
 711 fi
 712
 713 dnl **** Check for ALSA 1.x ****
 714 AC_SUBST(ALSALIBS,"")
 715 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 716 then
 717     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 718         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 719 #include <alsa/asoundlib.h>
 720 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 721 #include <sys/asoundlib.h>
 722 #endif],
 723                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 724                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 725                          ALSALIBS="-lasound"])])
 726 fi
 727
 728 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 729
 730 AC_SUBST(AUDIOIOLIBS,"")
 731 if test "$ac_cv_header_libaudioio_h" = "yes"
 732 then
 733     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 734                   [AUDIOIOLIBS="-laudioio"
 735                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 736 fi
 737
 738 dnl **** Check for capi4linux ****
 739
 740 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 741 then
 742     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 743 fi
 744
 745 dnl **** Check for gcc specific options ****
 746
 747 AC_SUBST(EXTRACFLAGS,"")
 748 if test "x${GCC}" = "xyes"
 749 then
 750   EXTRACFLAGS="-Wall -pipe"
 751
 752   dnl Check for strength-reduce bug
 753   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 754                   AC_TRY_RUN([
 755 int     L[[4]] = {0,1,2,3};
 756 int main(void) {
 757   static int Array[[3]];
 758   unsigned int B = 3;
 759   int i;
 760   for(i=0; i<B; i++) Array[[i]] = i - 3;
 761   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 762   L[[i]] = 4;
 763
 764   exit( Array[[1]] != -2 || L[[2]] != 3);
 765 }],
 766     ac_cv_c_gcc_strength_bug="no",
 767     ac_cv_c_gcc_strength_bug="yes",
 768     ac_cv_c_gcc_strength_bug="yes") )
 769   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 770   then
 771     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 772   fi
 773
 774   dnl Check for -fshort-wchar
 775   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 776       [WINE_TRY_CFLAGS([-fshort-wchar],
 777                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 778   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 779   then
 780       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 781   fi
 782
 783   dnl Check for -mpreferred-stack-boundary
 784   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 785       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 786                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 787   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 788   then
 789     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 790   fi
 791
 792   dnl Check for -fno-strict-aliasing
 793   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 794       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 795                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 796   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 797   then
 798     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 799   fi
 800
 801   dnl Check for -gstabs+ option
 802   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 803       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 804   if test "$ac_cv_c_gcc_gstabs" = "yes"
 805   then
 806     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 807   fi
 808
 809   dnl Check for noisy string.h
 810   saved_CFLAGS="$CFLAGS"
 811   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 812   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 813       AC_TRY_COMPILE([#include <string.h>],[],
 814                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 815   CFLAGS="$saved_CFLAGS"
 816   if test "$ac_cv_c_string_h_warnings" = "no"
 817   then
 818     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 819   fi
 820
 821   AC_SUBST(BUILTINFLAG,"")
 822   saved_CFLAGS="$CFLAGS"
 823   CFLAGS="$CFLAGS -Werror"
 824   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 825       AC_TRY_COMPILE([],
 826                      [int iswlower(unsigned short);],
 827                      [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 828   CFLAGS="$saved_CFLAGS"
 829   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 830   then
 831     BUILTINFLAG=""
 832     for builtin in \
 833       iswalnum iswalpha iswcntrl iswdigit iswgraph iswlower \
 834       iswprint iswpunct iswspace iswupper iswxdigit towlower towupper
 835     do
 836       BUILTINFLAG="$BUILTINFLAG -fno-builtin-$builtin"
 837     done
 838   fi
 839 fi
 840
 841 dnl **** Check how to define a function in assembly code ****
 842
 843 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 844   WINE_TRY_ASM_LINK(
 845       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 846       ac_cv_asm_func_def=".def",
 847     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 848       ac_cv_asm_func_def=".type @function",
 849     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 850       ac_cv_asm_func_def=".type 2",
 851       ac_cv_asm_func_def="unknown")])]))
 852
 853 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 854 case "$ac_cv_asm_func_def" in
 855   ".def")
 856      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 857   ".type @function")
 858      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 859   ".type 2")
 860      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 861   *)
 862      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 863 esac
 864
 865 dnl **** Check for underscore on external symbols ****
 866
 867 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 868     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 869                       [extern int ac_test;],
 870                       [if (ac_test) return 1],
 871                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 872
 873 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 874 if test "$ac_cv_c_extern_prefix" = "yes"
 875 then
 876   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 877 else
 878   AC_DEFINE([__ASM_NAME(name)], [name])
 879 fi
 880
 881 dnl **** Check for working dll ****
 882
 883 AC_SUBST(DLLEXT,"")
 884 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 885 AC_SUBST(DLLIBS,"")
 886 AC_SUBST(LDSHARED,"")
 887 AC_SUBST(LDDLLFLAGS,"")
 888 AC_SUBST(LIBEXT,"so")
 889 AC_SUBST(IMPLIBEXT,"def")
 890
 891 case $host_os in
 892   cygwin*|mingw32*)
 893     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 894     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 895     if test "$DLLWRAP" = "false"; then
 896       LIBEXT="a"
 897     else
 898       dnl FIXME - check whether dllwrap works correctly...
 899       LIBEXT="dll"
 900     fi
 901     IMPLIBEXT="a"
 902     dnl We can't build 16-bit NE dlls
 903     WIN16_FILES=""
 904     WIN16_INSTALL=""
 905     ;;
 906   *)
 907     if test "$ac_cv_header_dlfcn_h" = "yes"
 908     then
 909         AC_CHECK_FUNCS(dlopen,,
 910             [AC_CHECK_LIB(dl,dlopen,
 911                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 912                           DLLIBS="-ldl"],
 913                          [LIBEXT="a"])])
 914     else
 915         LIBEXT="a"
 916     fi
 917
 918     if test "$LIBEXT" = "so"
 919     then
 920       DLLFLAGS="$DLLFLAGS -fPIC"
 921       DLLEXT=".so"
 922       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 923           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 924                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 925       if test "$ac_cv_c_dll_gnuelf" = "yes"
 926       then
 927         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 928         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 929         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 930           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 931                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 932         if test "$ac_cv_c_dll_zdefs" = "yes"
 933         then
 934           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 935         fi
 936
 937         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 938           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 939                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 940         if test "$ac_cv_c_dll_init_fini" = "yes"
 941         then
 942           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 943         fi
 944
 945         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 946           [echo '{ global: *; };' >conftest.map
 947            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 948                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 949            rm -f conftest.map])
 950         if test "$ac_cv_c_ld_version_scripts" = "yes"
 951         then
 952           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 953         fi
 954
 955         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 956           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 957                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 958         if test "$ac_cv_c_export_dynamic" = "yes"
 959         then
 960           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 961         fi
 962
 963         case $host_cpu in
 964           *i[[3456789]]86*)
 965             AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
 966               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 967                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 968             if test "$ac_cv_ld_reloc_exec" = "yes"
 969             then
 970               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
 971             fi
 972             ;;
 973         esac
 974
 975       else
 976         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 977             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 978                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 979         if test "$ac_cv_c_dll_unixware" = "yes"
 980         then
 981           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 982           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 983
 984         else
 985           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 986             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 987           if test "$ac_cv_c_dll_macho" = "yes"
 988           then
 989             LIBEXT="dylib"
 990             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
 991             LDSHARED="\$(CC) -dynamiclib"
 992             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 993             STRIP="$STRIP -u -r"
 994             dnl Relocate wine executable
 995             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
 996             dnl Relocate libwine.dyld too
 997             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
 998             dnl declare needed frameworks
 999             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1000             AC_SUBST(IOKITLIB,"-framework IOKit")
1001             dnl using IOKit imply we use CoreFoundation too
1002             IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1003           else
1004             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1005               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1006             if test "$ac_cv_c_dll_hpux" = "yes"
1007             then
1008               LIBEXT="sl"
1009               DLLEXT=".sl"
1010               LDDLLFLAGS="-shared -fPIC"
1011               LDSHARED="\$(CC) -shared"
1012             fi
1013           fi
1014         fi
1015       fi
1016     fi
1017
1018     dnl Check for cross compiler to build test programs
1019     AC_SUBST(CROSSTEST,"")
1020     if test "$cross_compiling" = "no"
1021     then
1022       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1023       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1024       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1025       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1026     fi
1027     ;;
1028 esac
1029
1030 if test "$LIBEXT" = "a"; then
1031   AC_MSG_ERROR(
1032 [could not find a way to build shared libraries.
1033 It is currently not possible to build Wine without shared library
1034 (.so) support to allow transparent switch between .so and .dll files.
1035 If you are using Linux, you will need a newer binutils.]
1036 )
1037 fi
1038
1039 case $build_os in
1040   cygwin*|mingw32*)
1041     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1042   darwin*|macosx*)
1043     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1044   *)
1045     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1046 esac
1047
1048 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1049 case $host_os in
1050   mingw32*)
1051     AC_SUBST(CRTLIBS,"-lmsvcrt")
1052     AC_SUBST(SOCKETLIBS,"-lws2_32")
1053     ;;
1054 esac
1055
1056 case $host_os in
1057   linux*)
1058     case $host_cpu in
1059       *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1060       *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1061     esac
1062     AC_SUBST(MAIN_BINARY,"wine-glibc")
1063     ;;
1064   darwin*)
1065     AC_SUBST(WINE_BINARIES,"wine-pthread")
1066     AC_SUBST(MAIN_BINARY,"wine-pthread")
1067     ;;
1068   *)
1069     AC_SUBST(WINE_BINARIES,"wine-kthread")
1070     AC_SUBST(MAIN_BINARY,"wine-kthread")
1071     ;;
1072 esac
1073
1074 dnl **** Get the soname for libraries that we load dynamically ****
1075
1076 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1077 then
1078   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1079   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1080   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1081   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1082   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1083   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1084   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1085   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1086   WINE_GET_SONAME(cups,cupsGetDefault)
1087   WINE_GET_SONAME(jack,jack_client_new)
1088   WINE_GET_SONAME(fontconfig,FcInit)
1089   WINE_GET_SONAME(ssl,SSL_library_init)
1090   WINE_GET_SONAME(crypto,BIO_new_socket)
1091   WINE_GET_SONAME(ncurses,waddch)
1092   WINE_GET_SONAME(curses,waddch)
1093   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1094   WINE_GET_SONAME(ungif,DGifOpen)
1095   WINE_GET_SONAME(gif,DGifOpen)
1096   WINE_GET_SONAME(capi20,capi20_isinstalled)
1097 fi
1098
1099
1100 dnl **** Check for functions ****
1101
1102 AC_CHECK_FUNCS(\
1103         _lwp_create \
1104         _lwp_self \
1105         _pclose \
1106         _popen \
1107         _snprintf \
1108         _spawnvp \
1109         _stricmp \
1110         _strnicmp \
1111         _vsnprintf \
1112         chsize \
1113         clone \
1114         epoll_create \
1115         ffs \
1116         finite \
1117         fork \
1118         fpclass \
1119         fstatfs \
1120         fstatvfs \
1121         ftruncate \
1122         futimes \
1123         futimesat \
1124         getnetbyname \
1125         getopt_long \
1126         getpagesize \
1127         getprotobyname \
1128         getprotobynumber \
1129         getpwuid \
1130         getservbyport \
1131         gettid \
1132         gettimeofday \
1133         getuid \
1134         inet_network \
1135         lstat \
1136         memmove \
1137         mmap \
1138         pclose \
1139         popen \
1140         pread \
1141         pwrite \
1142         readlink \
1143         rfork \
1144         sched_yield \
1145         select \
1146         sendmsg \
1147         settimeofday \
1148         sigaltstack \
1149         sigprocmask \
1150         snprintf \
1151         spawnvp \
1152         statfs \
1153         statvfs \
1154         strcasecmp \
1155         strerror \
1156         strncasecmp \
1157         tcgetattr \
1158         timegm \
1159         usleep \
1160         vsnprintf \
1161         wait4 \
1162         waitpid \
1163 )
1164
1165 dnl **** Checks for headers that depend on other ones ****
1166
1167 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
1168     [#include <sys/types.h>
1169      #if HAVE_SYS_PARAM_H
1170      # include <sys/param.h>
1171      #endif])
1172
1173 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
1174     [#include <sys/types.h>
1175      #if HAVE_SYS_SOCKET_H
1176      # include <sys/socket.h>
1177      #endif])
1178
1179 AC_CHECK_HEADERS([resolv.h],,,
1180     [#include <sys/types.h>
1181      #if HAVE_SYS_SOCKET_H
1182      # include <sys/socket.h>
1183      #endif
1184      #if HAVE_NETINET_IN_H
1185      # include <netinet/in.h>
1186      #endif
1187      #if HAVE_ARPA_NAMESER_H
1188      # include <arpa/nameser.h>
1189      #endif])
1190
1191 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1192
1193 AC_CHECK_HEADERS([linux/ipx.h linux/videodev.h],,,
1194 [#ifdef HAVE_SYS_TIME_H
1195 #include <sys/time.h>
1196 #endif
1197 #include <sys/types.h>
1198 #ifdef HAVE_ASM_TYPES_H
1199 #include <asm/types.h>
1200 #endif])
1201
1202 dnl **** Check for types ****
1203
1204 AC_C_CONST
1205 AC_C_INLINE
1206 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1207 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1208 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1209
1210 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1211 [#ifdef HAVE_LINUX_INPUT_H
1212 #include <linux/input.h>
1213 #endif])
1214
1215 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1216                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1217                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1218 if test "$wine_cv_have_sigaddset" = "yes"
1219 then
1220   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1221 fi
1222
1223
1224 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1225         wine_cv_linux_gethostbyname_r_6,
1226         AC_TRY_LINK([
1227 #include <netdb.h>
1228         ], [
1229     char *name=NULL;
1230     struct hostent he;
1231     struct hostent *result;
1232     char *buf=NULL;
1233     int bufsize=0;
1234     int res,errnr;
1235     char *addr=NULL;
1236     int addrlen=0;
1237     int addrtype=0;
1238     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1239     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1240     ],
1241         wine_cv_linux_gethostbyname_r_6=yes,
1242         wine_cv_linux_gethostbyname_r_6=no
1243         )
1244    )
1245    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1246    then
1247       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1248                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1249    fi
1250
1251 if test "$ac_cv_header_linux_joystick_h" = "yes"
1252 then
1253    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1254         wine_cv_linux_joystick_22_api,
1255         AC_TRY_COMPILE([
1256         #include <sys/ioctl.h>
1257         #include <linux/joystick.h>
1258
1259         struct js_event blub;
1260         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1261         #error "no 2.2 header"
1262         #endif
1263         ],/*empty*/,
1264         wine_cv_linux_joystick_22_api=yes,
1265         wine_cv_linux_joystick_22_api=no,
1266         wine_cv_linux_joystick_22_api=no
1267         )
1268    )
1269    if test "$wine_cv_linux_joystick_22_api" = "yes"
1270    then
1271       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1272                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1273    fi
1274 fi
1275
1276 dnl **** statfs checks ****
1277
1278 if test "$ac_cv_header_sys_vfs_h" = "yes"
1279 then
1280     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1281                     wine_cv_sys_vfs_has_statfs,
1282         AC_TRY_COMPILE([
1283         #include <sys/types.h>
1284         #ifdef HAVE_SYS_PARAM_H
1285         # include <sys/param.h>
1286         #endif
1287         #include <sys/vfs.h>
1288         ],[
1289                 struct statfs stfs;
1290
1291                 memset(&stfs,0,sizeof(stfs));
1292         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1293         )
1294     )
1295     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1296     then
1297       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1298                 [Define if the struct statfs is defined by <sys/vfs.h>])
1299     fi
1300 fi
1301
1302 if test "$ac_cv_header_sys_statfs_h" = "yes"
1303 then
1304     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1305                     wine_cv_sys_statfs_has_statfs,
1306         AC_TRY_COMPILE([
1307         #include <sys/types.h>
1308         #ifdef HAVE_SYS_PARAM_H
1309         # include <sys/param.h>
1310         #endif
1311         #include <sys/statfs.h>
1312         ],[
1313                 struct statfs stfs;
1314         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1315         )
1316     )
1317     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1318     then
1319       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1320                 [Define if the struct statfs is defined by <sys/statfs.h>])
1321     fi
1322 fi
1323
1324 if test "$ac_cv_header_sys_mount_h" = "yes"
1325 then
1326     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1327                     wine_cv_sys_mount_has_statfs,
1328         AC_TRY_COMPILE([
1329         #include <sys/types.h>
1330         #ifdef HAVE_SYS_PARAM_H
1331         # include <sys/param.h>
1332         #endif
1333         #include <sys/mount.h>
1334         ],[
1335                 struct statfs stfs;
1336         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1337         )
1338     )
1339     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1340     then
1341       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1342                 [Define if the struct statfs is defined by <sys/mount.h>])
1343     fi
1344 fi
1345
1346 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1347
1348 dnl Check for statfs members
1349 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1350 [#include <sys/types.h>
1351 #ifdef HAVE_SYS_PARAM_H
1352 # include <sys/param.h>
1353 #endif
1354 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1355 # include <sys/mount.h>
1356 #else
1357 # ifdef STATFS_DEFINED_BY_SYS_VFS
1358 #  include <sys/vfs.h>
1359 # else
1360 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1361 #   include <sys/statfs.h>
1362 #  endif
1363 # endif
1364 #endif])
1365
1366 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1367 [#ifdef HAVE_SYS_STATVFS_H
1368 #include <sys/statvfs.h>
1369 #endif])
1370
1371 dnl Check for socket structure members
1372 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1373 [#include <sys/types.h>
1374 #ifdef HAVE_SYS_SOCKET_H
1375 # include <sys/socket.h>
1376 #endif
1377 #ifdef HAVE_SYS_UN_H
1378 # include <sys/un.h>
1379 #endif])
1380
1381 dnl Check for scsireq_t and sg_io_hdr_t members
1382 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1383 [#include <sys/types.h>
1384 #ifdef HAVE_SCSI_SG_H
1385 #include <scsi/sg.h>
1386 #endif])
1387
1388 dnl Check for siginfo_t members
1389 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1390
1391 dnl Check for struct option
1392 AC_CHECK_MEMBERS([struct option.name],,,
1393 [#ifdef HAVE_GETOPT_H
1394 #include <getopt.h>
1395 #endif])
1396
1397 dnl Check for stat.st_blocks
1398 AC_CHECK_MEMBERS([struct stat.st_blocks])
1399
1400 dnl Check for the external timezone variables timezone and daylight
1401 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1402                AC_TRY_LINK([#include <time.h>],[timezone;],
1403                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1404 if test "$ac_cv_have_timezone" = "yes"
1405 then
1406     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1407 fi
1408 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1409                AC_TRY_LINK([#include <time.h>],[daylight;],
1410                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1411 if test "$ac_cv_have_daylight" = "yes"
1412 then
1413     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1414 fi
1415
1416 dnl *** check for the need to define platform-specific symbols
1417
1418 case $host_cpu in
1419   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1420   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1421   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1422   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1423 esac
1424
1425 case $host_vendor in
1426   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1427 esac
1428
1429 dnl **** Generate output files ****
1430
1431 AH_TOP([#define __WINE_CONFIG_H])
1432
1433 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1434 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1435 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1436 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1437 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1438 WINE_CONFIG_EXTRA_DIR(include/wine)
1439
1440 MAKE_RULES=Make.rules
1441 AC_SUBST_FILE(MAKE_RULES)
1442
1443 MAKE_DLL_RULES=dlls/Makedll.rules
1444 AC_SUBST_FILE(MAKE_DLL_RULES)
1445
1446 MAKE_TEST_RULES=dlls/Maketest.rules
1447 AC_SUBST_FILE(MAKE_TEST_RULES)
1448
1449 MAKE_LIB_RULES=libs/Makelib.rules
1450 AC_SUBST_FILE(MAKE_LIB_RULES)
1451
1452 MAKE_PROG_RULES=programs/Makeprog.rules
1453 AC_SUBST_FILE(MAKE_PROG_RULES)
1454
1455 AC_CONFIG_FILES([
1456 Make.rules
1457 dlls/Makedll.rules
1458 dlls/Maketest.rules
1459 libs/Makelib.rules
1460 programs/Makeprog.rules
1461 Makefile
1462 dlls/Makefile
1463 dlls/activeds/Makefile
1464 dlls/advapi32/Makefile
1465 dlls/advapi32/tests/Makefile
1466 dlls/advpack/Makefile
1467 dlls/advpack/tests/Makefile
1468 dlls/amstream/Makefile
1469 dlls/atl/Makefile
1470 dlls/avicap32/Makefile
1471 dlls/avifil32/Makefile
1472 dlls/cabinet/Makefile
1473 dlls/capi2032/Makefile
1474 dlls/cards/Makefile
1475 dlls/cfgmgr32/Makefile
1476 dlls/comcat/Makefile
1477 dlls/comctl32/Makefile
1478 dlls/comctl32/tests/Makefile
1479 dlls/commdlg/Makefile
1480 dlls/crtdll/Makefile
1481 dlls/crypt32/Makefile
1482 dlls/crypt32/tests/Makefile
1483 dlls/cryptdll/Makefile
1484 dlls/ctl3d/Makefile
1485 dlls/d3d8/Makefile
1486 dlls/d3d9/Makefile
1487 dlls/d3dim/Makefile
1488 dlls/d3drm/Makefile
1489 dlls/d3dx8/Makefile
1490 dlls/d3dxof/Makefile
1491 dlls/dbghelp/Makefile
1492 dlls/dciman32/Makefile
1493 dlls/ddraw/Makefile
1494 dlls/ddraw/tests/Makefile
1495 dlls/devenum/Makefile
1496 dlls/dinput/Makefile
1497 dlls/dinput/tests/Makefile
1498 dlls/dinput8/Makefile
1499 dlls/dmband/Makefile
1500 dlls/dmcompos/Makefile
1501 dlls/dmime/Makefile
1502 dlls/dmloader/Makefile
1503 dlls/dmscript/Makefile
1504 dlls/dmstyle/Makefile
1505 dlls/dmsynth/Makefile
1506 dlls/dmusic/Makefile
1507 dlls/dmusic32/Makefile
1508 dlls/dplay/Makefile
1509 dlls/dplayx/Makefile
1510 dlls/dpnet/Makefile
1511 dlls/dpnhpast/Makefile
1512 dlls/dsound/Makefile
1513 dlls/dsound/tests/Makefile
1514 dlls/dswave/Makefile
1515 dlls/dxdiagn/Makefile
1516 dlls/dxerr8/Makefile
1517 dlls/dxerr9/Makefile
1518 dlls/dxguid/Makefile
1519 dlls/gdi/Makefile
1520 dlls/gdi/tests/Makefile
1521 dlls/glu32/Makefile
1522 dlls/glut32/Makefile
1523 dlls/hhctrl.ocx/Makefile
1524 dlls/iccvid/Makefile
1525 dlls/icmp/Makefile
1526 dlls/ifsmgr.vxd/Makefile
1527 dlls/imagehlp/Makefile
1528 dlls/imm32/Makefile
1529 dlls/iphlpapi/Makefile
1530 dlls/iphlpapi/tests/Makefile
1531 dlls/itss/Makefile
1532 dlls/kernel/Makefile
1533 dlls/kernel/tests/Makefile
1534 dlls/lzexpand/Makefile
1535 dlls/lzexpand/tests/Makefile
1536 dlls/mapi32/Makefile
1537 dlls/mapi32/tests/Makefile
1538 dlls/midimap/Makefile
1539 dlls/mlang/Makefile
1540 dlls/mlang/tests/Makefile
1541 dlls/mmdevldr.vxd/Makefile
1542 dlls/monodebg.vxd/Makefile
1543 dlls/mpr/Makefile
1544 dlls/msacm/Makefile
1545 dlls/msacm/imaadp32/Makefile
1546 dlls/msacm/msadp32/Makefile
1547 dlls/msacm/msg711/Makefile
1548 dlls/msacm/winemp3/Makefile
1549 dlls/msacm/tests/Makefile
1550 dlls/mscms/Makefile
1551 dlls/mscms/tests/Makefile
1552 dlls/msdmo/Makefile
1553 dlls/mshtml/Makefile
1554 dlls/mshtml/tests/Makefile
1555 dlls/msi/Makefile
1556 dlls/msi/tests/Makefile
1557 dlls/msimg32/Makefile
1558 dlls/msisys/Makefile
1559 dlls/msnet32/Makefile
1560 dlls/msrle32/Makefile
1561 dlls/msvcrt/Makefile
1562 dlls/msvcrt/tests/Makefile
1563 dlls/msvcrt20/Makefile
1564 dlls/msvcrt40/Makefile
1565 dlls/msvcrtd/Makefile
1566 dlls/msvcrtd/tests/Makefile
1567 dlls/msvidc32/Makefile
1568 dlls/msvideo/Makefile
1569 dlls/mswsock/Makefile
1570 dlls/msxml3/Makefile
1571 dlls/netapi32/Makefile
1572 dlls/netapi32/tests/Makefile
1573 dlls/newdev/Makefile
1574 dlls/ntdll/Makefile
1575 dlls/ntdll/tests/Makefile
1576 dlls/objsel/Makefile
1577 dlls/odbc32/Makefile
1578 dlls/odbccp32/Makefile
1579 dlls/ole32/Makefile
1580 dlls/ole32/tests/Makefile
1581 dlls/oleacc/Makefile
1582 dlls/oleaut32/Makefile
1583 dlls/oleaut32/tests/Makefile
1584 dlls/olecli/Makefile
1585 dlls/oledlg/Makefile
1586 dlls/olepro32/Makefile
1587 dlls/olesvr/Makefile
1588 dlls/opengl32/Makefile
1589 dlls/powrprof/Makefile
1590 dlls/psapi/Makefile
1591 dlls/psapi/tests/Makefile
1592 dlls/qcap/Makefile
1593 dlls/quartz/Makefile
1594 dlls/quartz/tests/Makefile
1595 dlls/rasapi32/Makefile
1596 dlls/riched20/Makefile
1597 dlls/richedit/Makefile
1598 dlls/rpcrt4/Makefile
1599 dlls/rpcrt4/tests/Makefile
1600 dlls/rsabase/Makefile
1601 dlls/rsabase/tests/Makefile
1602 dlls/rsaenh/Makefile
1603 dlls/rsaenh/tests/Makefile
1604 dlls/secur32/Makefile
1605 dlls/secur32/tests/Makefile
1606 dlls/sensapi/Makefile
1607 dlls/serialui/Makefile
1608 dlls/setupapi/Makefile
1609 dlls/shdocvw/Makefile
1610 dlls/shell32/Makefile
1611 dlls/shell32/tests/Makefile
1612 dlls/shfolder/Makefile
1613 dlls/shlwapi/Makefile
1614 dlls/shlwapi/tests/Makefile
1615 dlls/snmpapi/Makefile
1616 dlls/stdole2.tlb/Makefile
1617 dlls/stdole32.tlb/Makefile
1618 dlls/sti/Makefile
1619 dlls/strmiids/Makefile
1620 dlls/tapi32/Makefile
1621 dlls/ttydrv/Makefile
1622 dlls/twain/Makefile
1623 dlls/unicows/Makefile
1624 dlls/url/Makefile
1625 dlls/urlmon/Makefile
1626 dlls/urlmon/tests/Makefile
1627 dlls/user/Makefile
1628 dlls/user/tests/Makefile
1629 dlls/usp10/Makefile
1630 dlls/uuid/Makefile
1631 dlls/uxtheme/Makefile
1632 dlls/vdhcp.vxd/Makefile
1633 dlls/vdmdbg/Makefile
1634 dlls/version/Makefile
1635 dlls/version/tests/Makefile
1636 dlls/vmm.vxd/Makefile
1637 dlls/vnbt.vxd/Makefile
1638 dlls/vnetbios.vxd/Makefile
1639 dlls/vtdapi.vxd/Makefile
1640 dlls/vwin32.vxd/Makefile
1641 dlls/win32s/Makefile
1642 dlls/winaspi/Makefile
1643 dlls/wined3d/Makefile
1644 dlls/winedos/Makefile
1645 dlls/wineps/Makefile
1646 dlls/wininet/Makefile
1647 dlls/wininet/tests/Makefile
1648 dlls/winmm/Makefile
1649 dlls/winmm/joystick/Makefile
1650 dlls/winmm/mcianim/Makefile
1651 dlls/winmm/mciavi/Makefile
1652 dlls/mcicda/Makefile
1653 dlls/winmm/mciseq/Makefile
1654 dlls/winmm/mciwave/Makefile
1655 dlls/winmm/tests/Makefile
1656 dlls/winmm/wavemap/Makefile
1657 dlls/winmm/winealsa/Makefile
1658 dlls/winmm/winearts/Makefile
1659 dlls/winmm/wineaudioio/Makefile
1660 dlls/winmm/wineesd/Makefile
1661 dlls/winmm/winejack/Makefile
1662 dlls/winmm/winenas/Makefile
1663 dlls/winmm/wineoss/Makefile
1664 dlls/winnls/Makefile
1665 dlls/winsock/Makefile
1666 dlls/winsock/tests/Makefile
1667 dlls/winspool/Makefile
1668 dlls/winspool/tests/Makefile
1669 dlls/wintab32/Makefile
1670 dlls/wintrust/Makefile
1671 dlls/wldap32/Makefile
1672 dlls/wow32/Makefile
1673 dlls/wsock32/Makefile
1674 dlls/wtsapi32/Makefile
1675 dlls/x11drv/Makefile
1676 documentation/Makefile
1677 fonts/Makefile
1678 include/Makefile
1679 libs/Makefile
1680 libs/port/Makefile
1681 libs/unicode/Makefile
1682 libs/wine/Makefile
1683 libs/wpp/Makefile
1684 loader/Makefile
1685 programs/Makefile
1686 programs/avitools/Makefile
1687 programs/clock/Makefile
1688 programs/cmdlgtst/Makefile
1689 programs/control/Makefile
1690 programs/expand/Makefile
1691 programs/hh/Makefile
1692 programs/msiexec/Makefile
1693 programs/notepad/Makefile
1694 programs/progman/Makefile
1695 programs/regedit/Makefile
1696 programs/regsvr32/Makefile
1697 programs/rpcss/Makefile
1698 programs/rundll32/Makefile
1699 programs/start/Makefile
1700 programs/taskmgr/Makefile
1701 programs/uninstaller/Makefile
1702 programs/view/Makefile
1703 programs/wcmd/Makefile
1704 programs/wineboot/Makefile
1705 programs/winebrowser/Makefile
1706 programs/winecfg/Makefile
1707 programs/wineconsole/Makefile
1708 programs/winedbg/Makefile
1709 programs/winefile/Makefile
1710 programs/winemenubuilder/Makefile
1711 programs/winemine/Makefile
1712 programs/winepath/Makefile
1713 programs/winetest/Makefile
1714 programs/winevdm/Makefile
1715 programs/winhelp/Makefile
1716 programs/winver/Makefile
1717 server/Makefile
1718 tools/Makefile
1719 tools/widl/Makefile
1720 tools/winapi/Makefile
1721 tools/winebuild/Makefile
1722 tools/winedump/Makefile
1723 tools/winegcc/Makefile
1724 tools/wmc/Makefile
1725 tools/wrc/Makefile])
1726
1727 AC_OUTPUT
1728
1729 if test "$have_x" = "no"
1730 then
1731   echo
1732   echo "*** Warning: X development files not found. Wine will be built without"
1733   echo "*** X support, which currently does not work, and would probably not be"
1734   echo "*** what you want anyway. You will need to install devel packages of"
1735   echo "*** Xlib/Xfree86 at the very least."
1736 fi
1737
1738 if test "$wine_cv_opengl_version_OK" = "no"
1739 then
1740   echo
1741   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1742   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1743 fi
1744
1745 if test "$wine_cv_msg_freetype" = "yes"
1746 then
1747   echo
1748   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1749   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1750   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1751   echo "*** enable Wine to use TrueType fonts."
1752 fi
1753
1754 if test -z "$ALSALIBS" -a \
1755         -z "$ARTSC_LIBS" -a \
1756         -z "$AUDIOIOLIBS" -a \
1757         -z "$NASLIBS" -a \
1758         -z "$ESD_LIBS" -a \
1759         -z "$ac_cv_lib_soname_jack" -a \
1760         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1761         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1762         "$ac_cv_header_soundcard_h" != "yes"
1763 then
1764     echo "*** No sound system was found. Windows applications will be silent."
1765     echo "*** The currently supported sound systems are:"
1766     echo "*** ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS"
1767 fi
1768
1769 echo
1770 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1771 echo
1772
1773 dnl Local Variables:
1774 dnl comment-start: "dnl "
1775 dnl comment-end: ""
1776 dnl comment-start-skip: "\\bdnl\\b\\s *"
1777 dnl compile-command: "autoconf"
1778 dnl End: