configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$LD" || LD="ld -m elf_i386"
  28       test -n "$AS" || AS="as --32"
  29       host_cpu="i386"
  30     fi
  31     ;;
  32 esac
  33
  34 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  35 case $host_cpu in
  36   *i[[3456789]]86*)
  37     if test "x$enable_win16" != "xno"
  38     then
  39       enable_win16="yes"
  40     fi
  41     ;;
  42 esac
  43
  44 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  45 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  46 if test "x$enable_win16" != "xyes"
  47 then
  48   WIN16_FILES=""
  49   WIN16_INSTALL=""
  50 fi
  51
  52 dnl check for out of tree build with unclean source tree
  53 case "$srcdir" in
  54  .) ;;
  55  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  56       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  57 You need to run 'make distclean' in the source tree first.])
  58     fi ;;
  59 esac
  60
  61 dnl **** Check for some programs ****
  62
  63 AC_PROG_MAKE_SET
  64 AC_PROG_CC
  65 AC_PROG_CXX
  66 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  67 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  68
  69 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  70   [if test -z "$with_wine_tools"; then
  71      if test "$cross_compiling" = "yes"; then
  72        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  73      else
  74        wine_cv_toolsdir="\$(TOPOBJDIR)"
  75      fi
  76    elif test -d "$with_wine_tools/tools/winebuild"; then
  77      case $with_wine_tools in
  78        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  79        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  80      esac
  81    else
  82      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  83    fi])
  84 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  85
  86 AC_PATH_XTRA
  87
  88 dnl Check for flex
  89 AC_CHECK_PROGS(FLEX,flex,none)
  90 if test "$FLEX" = "none"
  91 then
  92   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  93 fi
  94
  95 dnl Check for bison
  96 AC_CHECK_PROGS(BISON,bison,none)
  97 if test "$BISON" = "none"
  98 then
  99   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 100 fi
 101
 102 AC_CHECK_TOOLS(AS,[gas as],as)
 103 AC_CHECK_TOOL(LD,ld,ld)
 104 AC_CHECK_TOOL(AR,ar,ar)
 105 AC_PROG_RANLIB
 106 AC_CHECK_TOOL(STRIP,strip,strip)
 107 AC_CHECK_TOOL(WINDRES,windres,false)
 108 AC_PROG_LN_S
 109 WINE_PROG_LN
 110 AC_PROG_EGREP
 111 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 112 AC_PROG_INSTALL
 113 dnl Prepend src dir to install path dir if it's a relative path
 114 case "$INSTALL" in
 115   [[\\/$]]* | ?:[[\\/]]* ) ;;
 116   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 117 esac
 118
 119 dnl Check for lint
 120 AC_CHECK_PROGS(LINT, lclint lint)
 121 if test "$LINT" = "lint"
 122 then
 123   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 124   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 125 fi
 126 AC_SUBST(LINT)
 127 AC_SUBST(LINTFLAGS)
 128
 129 dnl Check for various programs
 130 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 131 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 132
 133 case $host_cpu in
 134   *i[[3456789]]86*)
 135     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 136     ;;
 137 esac
 138
 139 dnl **** Check for some libraries ****
 140
 141 dnl Check for -li386 for NetBSD and OpenBSD
 142 AC_CHECK_LIB(i386,i386_set_ldt)
 143 dnl Check for -lossaudio for NetBSD
 144 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpthread
 148 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 149
 150 AC_SUBST(XLIB,"")
 151 AC_SUBST(XFILES,"")
 152 AC_SUBST(OPENGLFILES,"")
 153 AC_SUBST(GLU32FILES,"")
 154 AC_SUBST(OPENGL_LIBS,"")
 155 AC_SUBST(QUARTZFILES,"")
 156
 157 dnl **** Check for header files ****
 158
 159 AC_CHECK_HEADERS(\
 160         AudioUnit/AudioUnit.h \
 161         Carbon/Carbon.h \
 162         CoreAudio/CoreAudio.h \
 163         DiskArbitration/DiskArbitration.h \
 164         IOKit/IOKitLib.h \
 165         alsa/asoundlib.h \
 166         arpa/inet.h \
 167         arpa/nameser.h \
 168         asm/types.h \
 169         capi20.h \
 170         cups/cups.h \
 171         curses.h \
 172         direct.h \
 173         dlfcn.h \
 174         elf.h \
 175         float.h \
 176         fontconfig/fontconfig.h \
 177         getopt.h \
 178         ieeefp.h \
 179         io.h \
 180         jack/jack.h \
 181         jpeglib.h \
 182         lber.h \
 183         lcms.h \
 184         lcms/lcms.h \
 185         ldap.h \
 186         libaudioio.h \
 187         link.h \
 188         linux/cdrom.h \
 189         linux/compiler.h \
 190         linux/hdreg.h \
 191         linux/input.h \
 192         linux/ioctl.h \
 193         linux/joystick.h \
 194         linux/major.h \
 195         linux/param.h \
 196         linux/serial.h \
 197         linux/ucdrom.h \
 198         mach/mach.h \
 199         mach/machine.h \
 200         machine/cpu.h \
 201         machine/limits.h \
 202         machine/soundcard.h \
 203         mntent.h \
 204         ncurses.h \
 205         netdb.h \
 206         netinet/in.h \
 207         netinet/in_systm.h \
 208         netinet/tcp.h \
 209         netinet/tcp_fsm.h \
 210         openssl/err.h \
 211         openssl/ssl.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/sockio.h \
 252         sys/soundcard.h \
 253         sys/statvfs.h \
 254         sys/strtio.h \
 255         sys/syscall.h \
 256         sys/sysctl.h \
 257         sys/time.h \
 258         sys/times.h \
 259         sys/uio.h \
 260         sys/un.h \
 261         sys/vm86.h \
 262         sys/wait.h \
 263         syscall.h \
 264         termios.h \
 265         unicode/ubidi.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif])
 285
 286 AC_CHECK_HEADERS([linux/ipx.h],,,
 287     [#include <sys/types.h>
 288      #ifdef HAVE_ASM_TYPES_H
 289      # include <asm/types.h>
 290      #endif
 291      #if HAVE_SYS_SOCKET_H
 292      # include <sys/socket.h>
 293      #endif])
 294
 295 AC_CHECK_HEADERS([resolv.h],,,
 296     [#include <sys/types.h>
 297      #if HAVE_SYS_SOCKET_H
 298      # include <sys/socket.h>
 299      #endif
 300      #if HAVE_NETINET_IN_H
 301      # include <netinet/in.h>
 302      #endif
 303      #if HAVE_ARPA_NAMESER_H
 304      # include <arpa/nameser.h>
 305      #endif])
 306
 307 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 308
 309 AC_CHECK_HEADERS([pthread_np.h],,,
 310 [#ifdef HAVE_PTHREAD_H
 311 #include <pthread.h>
 312 #endif])
 313
 314 AC_CHECK_HEADERS([linux/videodev.h],,,
 315 [#ifdef HAVE_SYS_TIME_H
 316 #include <sys/time.h>
 317 #endif
 318 #include <sys/types.h>
 319 #ifdef HAVE_ASM_TYPES_H
 320 #include <asm/types.h>
 321 #endif])
 322
 323 dnl Check for broken kernel header that doesn't define __user
 324 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 325
 326 dnl **** Check for X11 ****
 327
 328 if test "$have_x" = "yes"
 329 then
 330     XLIB="-lXext -lX11"
 331     ac_save_CPPFLAGS="$CPPFLAGS"
 332     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 333
 334     dnl *** All of the following tests require X11/Xlib.h
 335     AC_CHECK_HEADERS([X11/Xlib.h \
 336                       X11/XKBlib.h \
 337                       X11/Xutil.h \
 338                       X11/Xcursor/Xcursor.h \
 339                       X11/extensions/shape.h \
 340                       X11/extensions/XInput.h \
 341                       X11/extensions/XShm.h \
 342                       X11/extensions/Xinerama.h \
 343                       X11/extensions/Xrandr.h \
 344                       X11/extensions/Xrender.h \
 345                       X11/extensions/xf86vmode.h],,,
 346 [#ifdef HAVE_X11_XLIB_H
 347 # include <X11/Xlib.h>
 348 #endif
 349 #ifdef HAVE_X11_XUTIL_H
 350 # include <X11/Xutil.h>
 351 #endif])
 352
 353         dnl *** Check for X keyboard extension
 354         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 355         then
 356               AC_CHECK_LIB(X11, XkbQueryExtension,
 357               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 358               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 359         fi
 360
 361         dnl *** Check for X Shm extension
 362         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 363         then
 364               AC_CHECK_LIB(Xext, XShmQueryExtension,
 365               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 366               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 367         fi
 368
 369         dnl *** Check for X shape extension
 370         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 371         then
 372               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 373               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 374               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 375         fi
 376
 377         dnl *** Check for XFree86 VMODE extension
 378         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 379         then
 380                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 381                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 382                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 383                   ],,
 384                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 385         fi
 386
 387         dnl *** Check for X RandR extension
 388         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 389         then
 390                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 391 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 392                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 393         fi
 394
 395         dnl *** Check for Transform functions in Xrender
 396         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 397         then
 398               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 399                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 400                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 401                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 402         fi
 403
 404         dnl *** Check for Xinerama extension
 405         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 406         then
 407                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 408 #include <X11/extensions/Xinerama.h>],[static typeof(XineramaQueryScreens) * func;],
 409                   [AC_DEFINE(HAVE_LIBXINERAMA, 1, [Define if you have the Xinerama library])])
 410         fi
 411
 412     dnl *** End of X11/Xlib.h check
 413
 414     dnl Check for the presence of OpenGL
 415     if test "x$with_opengl" != "xno"
 416     then
 417         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 418 [#ifdef HAVE_GL_GLX_H
 419 # include <GL/glx.h>
 420 #endif])
 421         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 422         then
 423             dnl Check for some problems due to old Mesa versions
 424             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 425               AC_TRY_COMPILE(
 426                 [#include <GL/gl.h>],
 427                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 428                 [wine_cv_opengl_header_version_OK="yes"],
 429                 [wine_cv_opengl_header_version_OK="no"]
 430               )
 431             )
 432
 433             if test "$wine_cv_opengl_header_version_OK" = "yes"
 434             then
 435                 dnl Check for the presence of the library
 436                 AC_CHECK_LIB(GL,glXCreateContext,
 437                              [OPENGL_LIBS="-lGL"
 438                              OPENGLFILES='$(OPENGLFILES)'
 439                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])]
 440                              ,,
 441                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 442
 443                 dnl Check for GLU32 library.
 444                 AC_CHECK_LIB(GLU,gluLookAt,
 445                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 446                              GLU32FILES='$(GLU32FILES)']
 447                              ,,
 448                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 449                 )
 450              fi
 451          else
 452              wine_cv_opengl_headers_found="no"
 453          fi
 454     fi
 455     dnl **** Check for NAS ****
 456     AC_SUBST(NASLIBS,"")
 457     AC_CHECK_HEADERS(audio/audiolib.h,
 458          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 459           AC_CHECK_LIB(audio,AuCreateFlow,
 460                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 461                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 462                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 463                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 464                           [$X_LIBS])
 465                        ],,
 466                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 467
 468     CPPFLAGS="$ac_save_CPPFLAGS"
 469     XFILES='$(XFILES)'
 470 else
 471     XLIB=""
 472     X_CFLAGS=""
 473     X_LIBS=""
 474 fi
 475
 476 dnl **** Check for libxml2 ****
 477
 478 AC_SUBST(XML2LIBS,"")
 479 AC_SUBST(XML2INCL,"")
 480 AC_SUBST(XSLTLIBS,"")
 481 AC_SUBST(XSLTINCL,"")
 482 if test "$PKG_CONFIG" != "false"
 483 then
 484     ac_save_CPPFLAGS="$CPPFLAGS"
 485     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 486     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 487     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 488     AC_CHECK_HEADERS(libxml/parser.h,
 489         [AC_CHECK_LIB(xml2, xmlParseMemory,
 490             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 491              XML2LIBS="$ac_xml_libs"
 492              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 493          AC_CHECK_LIB(xml2, xmlReadMemory,
 494             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 495          AC_CHECK_LIB(xml2, xmlNewDocPI,
 496             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 497         ])
 498     CPPFLAGS="$ac_save_CPPFLAGS"
 499     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 500     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 501     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 502     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 503         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 504             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 505              XSLTLIBS="$ac_xslt_libs"
 506              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 507         ],,
 508 [#ifdef HAVE_LIBXSLT_PATTERN_H
 509 # include <libxslt/pattern.h>
 510 #endif])
 511     CPPFLAGS="$ac_save_CPPFLAGS"
 512 fi
 513
 514 dnl **** Check for libhal ****
 515 AC_SUBST(HALINCL,"")
 516 if test "$PKG_CONFIG" != "false"
 517 then
 518     ac_save_CPPFLAGS="$CPPFLAGS"
 519     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 520     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 521     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 522     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 523     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 524     then
 525         AC_CHECK_LIB(hal, libhal_ctx_new,
 526           [AC_CHECK_LIB(dbus-1, dbus_connection_close,
 527             [AC_DEFINE(HAVE_LIBHAL, 1, [Define if you have the hal library])
 528              HALINCL="$ac_hal_cflags"],,$ac_hal_libs)])
 529     fi
 530     CPPFLAGS="$ac_save_CPPFLAGS"
 531 fi
 532
 533 dnl **** Check which curses lib to use ***
 534 CURSESLIBS=""
 535 if test "$ac_cv_header_ncurses_h" = "yes"
 536 then
 537     AC_CHECK_LIB(ncurses,waddch,[CURSESLIBS="-lncurses"])
 538 elif test "$ac_cv_header_curses_h" = "yes"
 539 then
 540     AC_CHECK_LIB(curses,waddch,[CURSESLIBS="-lcurses"])
 541 fi
 542 ac_save_LIBS="$LIBS"
 543 LIBS="$LIBS $CURSESLIBS"
 544 AC_CHECK_FUNCS(mousemask)
 545 LIBS="$ac_save_LIBS"
 546
 547 dnl **** Check for SANE ****
 548 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 549 AC_SUBST(SANEINCL,"")
 550 if test "$sane_devel" != "no"
 551 then
 552     SANEINCL="`$sane_devel --cflags`"
 553     ac_save_CPPFLAGS="$CPPFLAGS"
 554     CPPFLAGS="$CPPFLAGS $SANEINCL"
 555     AC_CHECK_HEADER(sane/sane.h,
 556                     [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 557                     [SANEINCL=""])
 558     CPPFLAGS="$ac_save_CPPFLAGS"
 559 fi
 560
 561 dnl **** Check for libgphoto2 ****
 562 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 563 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 564 AC_SUBST(GPHOTO2LIBS,"")
 565 AC_SUBST(GPHOTO2INCL,"")
 566 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 567 then
 568     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 569     GPHOTO2LIBS=""
 570     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 571     do
 572       case "$i" in
 573         -L/usr/lib|-L/usr/lib64) ;;
 574         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 575       esac
 576     done
 577     ac_save_CPPFLAGS="$CPPFLAGS"
 578     ac_save_LIBS="$LIBS"
 579     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 580     LIBS="$LIBS $GPHOTO2LIBS"
 581     AC_CHECK_HEADER(gphoto2-camera.h,
 582                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 583                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 584                                   [GPHOTO2LIBS=""
 585                                   GPHOTO2INCL=""])],
 586                     [GPHOTO2LIBS=""
 587                     GPHOTO2INCL=""])
 588     LIBS="$ac_save_LIBS"
 589     CPPFLAGS="$ac_save_CPPFLAGS"
 590 fi
 591
 592 dnl **** Check for the ICU library ****
 593 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 594 then
 595     saved_libs="$LIBS"
 596     for i in ${ICU_LIB_DIR-/usr/lib}/libsicu ${ICU_LIB_DIR-/usr/lib}/libicu
 597     do
 598         TEST_ICUUC_LIB="${ICUUC_LIB-${i}uc.a}"
 599         TEST_ICUDATA_LIB="${ICUDATA_LIB-${i}data.a}"
 600         AC_MSG_CHECKING(whether can link with ICU libraries $TEST_ICUUC_LIB and $TEST_ICUDATA_LIB)
 601         LIBS="$saved_libs $TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s"
 602         AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 603                     [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 604                      AC_SUBST(ICULIBS,"$TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s")
 605                      AC_MSG_RESULT(yes)],
 606                     [AC_MSG_RESULT(no)])
 607     done
 608     LIBS="$saved_libs"
 609 fi
 610
 611 dnl **** Check for resolver library ***
 612 AC_SUBST(RESOLVLIBS,"")
 613 if test "$ac_cv_header_resolv_h" = "yes"
 614 then
 615     AC_CHECK_LIB(resolv, res_query,
 616         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 617          RESOLVLIBS="-lresolv"])
 618 fi
 619
 620 dnl **** Check for LittleCMS ***
 621 AC_SUBST(LCMSLIBS,"")
 622 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 623 then
 624     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 625         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 626          LCMSLIBS="-llcms"])
 627 fi
 628
 629 dnl **** Check for OpenLDAP ***
 630 AC_SUBST(LDAPLIBS,"")
 631 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 632 then
 633     AC_CHECK_LIB(ldap_r, ldap_initialize,
 634         [AC_CHECK_LIB(lber, ber_init,
 635             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 636              LDAPLIBS="-lldap_r -llber"],,
 637              [$LIBPTHREAD])],,
 638              [$LIBPTHREAD])
 639     WINE_CHECK_LIB_FUNCS(\
 640         ldap_count_references \
 641         ldap_first_reference \
 642         ldap_next_reference \
 643         ldap_parse_reference,
 644         [$LDAPLIBS $LIBPTHREAD])
 645 fi
 646
 647 dnl **** Check for FreeType 2 ****
 648 AC_SUBST(FREETYPELIBS,"")
 649 AC_SUBST(FREETYPEINCL,"")
 650 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 651 if test "$ft_devel" = "no"
 652 then
 653     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 654     if test "$ft_devel2" = "freetype2-config"
 655     then
 656         ft_devel=$ft_devel2
 657     fi
 658 fi
 659
 660 if test "$ft_devel" = "no"
 661 then
 662     wine_cv_msg_freetype=yes
 663 else
 664     FREETYPELIBS=`$ft_devel --libs`
 665     FREETYPEINCL=`$ft_devel --cflags`
 666     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 667     if test "$ft_lib" = "no"
 668     then
 669         wine_cv_msg_freetype=yes
 670         FREETYPELIBS=""
 671         FREETYPEINCL=""
 672     else
 673         ac_save_CPPFLAGS="$CPPFLAGS"
 674         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 675         AC_CHECK_HEADERS(ft2build.h \
 676                          freetype/freetype.h \
 677                          freetype/ftglyph.h \
 678                          freetype/tttables.h \
 679                          freetype/ftnames.h \
 680                          freetype/ftsnames.h \
 681                          freetype/ttnameid.h \
 682                          freetype/ftoutln.h \
 683                          freetype/ftwinfnt.h \
 684                          freetype/ftmodapi.h \
 685                          freetype/internal/sfnt.h,,,
 686                          [#if HAVE_FT2BUILD_H
 687                           #include <ft2build.h>
 688                           #endif])
 689         AC_TRY_CPP([#include <ft2build.h>
 690                     #include <freetype/fttrigon.h>],
 691                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 692           [Define if you have the <freetype/fttrigon.h> header file.])
 693                     wine_cv_fttrigon=yes],
 694                     wine_cv_fttrigon=no)
 695         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 696         ac_save_CFLAGS="$CFLAGS"
 697         CFLAGS="$CFLAGS $FREETYPELIBS"
 698         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 699         CFLAGS="$ac_save_CFLAGS"
 700         CPPFLAGS="$ac_save_CPPFLAGS"
 701         dnl Check that we have at least freetype/freetype.h
 702         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 703         then
 704             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 705             wine_cv_msg_freetype=no
 706         else
 707             FREETYPELIBS=""
 708             FREETYPEINCL=""
 709             wine_cv_msg_freetype=yes
 710         fi
 711     fi
 712 fi
 713
 714 dnl Only build the fonts dir if we have both freetype and fontforge
 715 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 716 then
 717   AC_SUBST(FONTSSUBDIRS,"fonts")
 718 fi
 719
 720 dnl **** Check for parport (currently Linux only) ****
 721 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 722  AC_TRY_COMPILE(
 723    [#include <linux/ppdev.h>],
 724    [ioctl (1,PPCLAIM,0)],
 725    [ac_cv_c_ppdev="yes"],
 726    [ac_cv_c_ppdev="no"])
 727  )
 728 if test "$ac_cv_c_ppdev" = "yes"
 729 then
 730     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 731 fi
 732
 733 dnl **** Check for va_copy ****
 734 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 735  AC_TRY_LINK(
 736    [#include <stdarg.h>],
 737    [va_list ap1, ap2;
 738     va_copy(ap1,ap2);
 739    ],
 740    [ac_cv_c_va_copy="yes"],
 741    [ac_cv_c_va_copy="no"])
 742  )
 743 if test "$ac_cv_c_va_copy" = "yes"
 744 then
 745     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 746 fi
 747 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 748  AC_TRY_LINK(
 749    [#include <stdarg.h>],
 750    [va_list ap1, ap2;
 751     __va_copy(ap1,ap2);
 752    ],
 753    [ac_cv_c___va_copy="yes"],
 754    [ac_cv_c___va_copy="no"])
 755  )
 756 if test "$ac_cv_c___va_copy" = "yes"
 757 then
 758     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 759 fi
 760
 761 dnl **** Check for sigsetjmp ****
 762 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 763  AC_TRY_LINK(
 764    [#include <setjmp.h>],
 765    [sigjmp_buf buf;
 766     sigsetjmp( buf, 1 );
 767     siglongjmp( buf, 1 );],
 768    [ac_cv_c_sigsetjmp="yes"],
 769    [ac_cv_c_sigsetjmp="no"])
 770  )
 771 if test "$ac_cv_c_sigsetjmp" = "yes"
 772 then
 773     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 774 fi
 775
 776 dnl **** Check for pthread_rwlock_t ****
 777 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 778 #include <pthread.h>])
 779
 780 dnl **** Check for pthread functions ****
 781 WINE_CHECK_LIB_FUNCS(\
 782         pthread_attr_get_np \
 783         pthread_getattr_np \
 784         pthread_get_stackaddr_np \
 785         pthread_get_stacksize_np,
 786         [$LIBPTHREAD])
 787
 788 dnl **** Check for EsounD ****
 789 AC_PATH_PROG(ESDCONFIG, esd-config)
 790 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 791 then
 792     ESD_CFLAGS=""
 793     for i in `$ESDCONFIG --cflags`
 794     do
 795       case "$i" in
 796         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 797       esac
 798     done
 799     ESD_LIBS=`$ESDCONFIG --libs`
 800     save_CFLAGS="$CFLAGS"
 801     CFLAGS="$CFLAGS $ESD_CFLAGS"
 802     AC_CHECK_LIB(esd,esd_open_sound,
 803         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 804          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 805          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 806     CFLAGS="$save_CFLAGS"
 807 fi
 808
 809 dnl **** Check for ALSA 1.x ****
 810 AC_SUBST(ALSALIBS,"")
 811 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 812 then
 813     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 814         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 815 #include <alsa/asoundlib.h>
 816 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 817 #include <sys/asoundlib.h>
 818 #endif],
 819                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 820                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 821                          ALSALIBS="-lasound"])])
 822 fi
 823
 824 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 825
 826 AC_SUBST(AUDIOIOLIBS,"")
 827 if test "$ac_cv_header_libaudioio_h" = "yes"
 828 then
 829     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 830                   [AUDIOIOLIBS="-laudioio"
 831                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 832 fi
 833
 834 dnl **** Check for capi4linux ****
 835
 836 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 837 then
 838     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 839 fi
 840
 841 dnl **** Check for gcc specific options ****
 842
 843 AC_SUBST(EXTRACFLAGS,"")
 844 if test "x${GCC}" = "xyes"
 845 then
 846   EXTRACFLAGS="-Wall -pipe"
 847
 848   dnl Check for strength-reduce bug
 849   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 850                   AC_TRY_RUN([
 851 int     L[[4]] = {0,1,2,3};
 852 int main(void) {
 853   static int Array[[3]];
 854   unsigned int B = 3;
 855   int i;
 856   for(i=0; i<B; i++) Array[[i]] = i - 3;
 857   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 858   L[[i]] = 4;
 859
 860   exit( Array[[1]] != -2 || L[[2]] != 3);
 861 }],
 862     ac_cv_c_gcc_strength_bug="no",
 863     ac_cv_c_gcc_strength_bug="yes",
 864     ac_cv_c_gcc_strength_bug="yes") )
 865   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 866   then
 867     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 868   fi
 869
 870   dnl Check for some compiler flags
 871
 872   WINE_TRY_CFLAGS([-fshort-wchar],
 873                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
 874                              [Specifies the compiler flag that forces a short wchar_t])])
 875   WINE_TRY_CFLAGS([-fno-strict-aliasing])
 876   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
 877   WINE_TRY_CFLAGS([-Wwrite-strings])
 878
 879   dnl Check for noisy string.h
 880   saved_CFLAGS="$CFLAGS"
 881   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 882   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 883       AC_TRY_COMPILE([#include <string.h>],[],
 884                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 885   CFLAGS="$saved_CFLAGS"
 886   if test "$ac_cv_c_string_h_warnings" = "no"
 887   then
 888     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 889   fi
 890
 891   AC_SUBST(BUILTINFLAG,"")
 892   saved_CFLAGS="$CFLAGS"
 893   CFLAGS="$CFLAGS -Werror"
 894   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 895       AC_TRY_COMPILE([],
 896                      [int iswlower(unsigned short);],
 897                      [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 898   CFLAGS="$saved_CFLAGS"
 899   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 900   then
 901     BUILTINFLAG="-fno-builtin"
 902   fi
 903 fi
 904
 905 dnl **** Check how to define a function in assembly code ****
 906
 907 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 908   WINE_TRY_ASM_LINK(
 909       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 910       ac_cv_asm_func_def=".def",
 911     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 912       ac_cv_asm_func_def=".type @function",
 913     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 914       ac_cv_asm_func_def=".type 2",
 915       ac_cv_asm_func_def="unknown")])]))
 916
 917 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 918 case "$ac_cv_asm_func_def" in
 919   ".def")
 920      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 921   ".type @function")
 922      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 923   ".type 2")
 924      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 925   *)
 926      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 927 esac
 928
 929 dnl **** Check for underscore on external symbols ****
 930
 931 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 932     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 933                       [extern int ac_test;],
 934                       [if (ac_test) return 1],
 935                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 936
 937 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 938 if test "$ac_cv_c_extern_prefix" = "yes"
 939 then
 940   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 941 else
 942   AC_DEFINE([__ASM_NAME(name)], [name])
 943 fi
 944
 945 dnl **** Check for working dll ****
 946
 947 AC_SUBST(DLLEXT,"")
 948 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 949 AC_SUBST(LDSHARED,"")
 950 AC_SUBST(LDDLLFLAGS,"")
 951 AC_SUBST(LIBEXT,"so")
 952 AC_SUBST(IMPLIBEXT,"def")
 953 AC_SUBST(LIBWINE_LDFLAGS,"")
 954
 955 case $host_os in
 956   cygwin*|mingw32*)
 957     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 958     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 959     AC_CHECK_TOOL(MINGWAR,ar,false)
 960     if test "$DLLWRAP" = "false"; then
 961       LIBEXT="a"
 962     else
 963       dnl FIXME - check whether dllwrap works correctly...
 964       LIBEXT="dll"
 965     fi
 966     IMPLIBEXT="a"
 967     dnl We can't build 16-bit NE dlls
 968     WIN16_FILES=""
 969     WIN16_INSTALL=""
 970     ;;
 971   darwin*|macosx*)
 972     DLLEXT=".so"
 973     LIBEXT="dylib"
 974     DLLFLAGS="$DLLFLAGS -fPIC"
 975     LDDLLFLAGS="-bundle -multiply_defined suppress"
 976     LIBWINE_LDFLAGS="-multiply_defined suppress"
 977     LDSHARED="\$(CC) -dynamiclib -install_name @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/\$(DYNAME)"
 978     STRIP="$STRIP -u -r"
 979     dnl declare needed frameworks
 980     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 981     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 982     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 983     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 984     then
 985         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 986         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 987     fi
 988     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 989     then
 990         dnl CoreServices needed by AudioUnit
 991         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices")
 992     fi
 993     case $host_cpu in
 994       *powerpc*)
 995         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 996         ;;
 997     esac
 998     dnl Enable quartz driver on Mac OS X
 999     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
1000     then
1001         AC_SUBST(CARBONLIB,"-framework Carbon")
1002         QUARTZFILES='$(QUARTZFILES)'
1003     fi
1004     ;;
1005   *)
1006     DLLFLAGS="$DLLFLAGS -fPIC"
1007     DLLEXT=".so"
1008     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
1009         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
1010                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
1011     if test "$ac_cv_c_dll_gnuelf" = "yes"
1012     then
1013       LDSHARED="\$(CC) -shared"
1014       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
1015       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
1016                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
1017                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
1018                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
1019
1020       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
1021
1022       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
1023                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
1024
1025       echo '{ global: *; };' >conftest.map
1026       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
1027                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
1028       rm -f conftest.map
1029
1030       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
1031                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
1032
1033       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
1034                       [LIBWINE_LDFLAGS="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])
1035
1036       case $host_cpu in
1037         *i[[3456789]]86* | x86_64)
1038           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1039                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
1040           ;;
1041       esac
1042
1043     else
1044       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1045           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1046                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1047       if test "$ac_cv_c_dll_unixware" = "yes"
1048       then
1049         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1050         LDDLLFLAGS="-Wl,-G,-B,symbolic"
1051
1052       else
1053         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1054           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1055         if test "$ac_cv_c_dll_hpux" = "yes"
1056         then
1057           LIBEXT="sl"
1058           DLLEXT=".sl"
1059           LDDLLFLAGS="-shared -fPIC"
1060           LDSHARED="\$(CC) -shared"
1061         fi
1062       fi
1063     fi
1064
1065     dnl Check for cross compiler to build test programs
1066     AC_SUBST(CROSSTEST,"")
1067     if test "$cross_compiling" = "no"
1068     then
1069       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
1070       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
1071       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
1072       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
1073       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1074     fi
1075     ;;
1076 esac
1077
1078 if test "$LIBEXT" = "a"; then
1079   AC_MSG_ERROR(
1080 [could not find a way to build shared libraries.
1081 It is currently not possible to build Wine without shared library
1082 (.so) support to allow transparent switch between .so and .dll files.
1083 If you are using Linux, you will need a newer binutils.]
1084 )
1085 fi
1086
1087 case $build_os in
1088   cygwin*|mingw32*)
1089     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\"") ;;
1090   darwin*|macosx*)
1091     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$DYLD_LIBRARY_PATH\"") ;;
1092   *)
1093     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\"") ;;
1094 esac
1095
1096 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1097 case $host_os in
1098   mingw32*)
1099     AC_SUBST(CRTLIBS,"-lmsvcrt")
1100     AC_SUBST(SOCKETLIBS,"-lws2_32")
1101     ;;
1102 esac
1103
1104 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1105 case $host_cpu in
1106   *i[[3456789]]86*)
1107     case $host_os in
1108       linux* | k*bsd*-gnu)
1109         AC_SUBST(MAIN_BINARY,"wine-glibc")
1110         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1111     esac
1112     ;;
1113 esac
1114
1115 dnl **** Get the soname for libraries that we load dynamically ****
1116
1117 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1118 then
1119   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1120   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1121   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1122   WINE_GET_SONAME(Xinerama,XineramaQueryScreens,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1123   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1124   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1125   WINE_GET_SONAME(Xcursor,XcursorImageLoadCursor,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1126   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1127   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1128   WINE_GET_SONAME(hal,libhal_ctx_new)
1129   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1130   WINE_GET_SONAME(cups,cupsGetDefault)
1131   WINE_GET_SONAME(jack,jack_client_new)
1132   WINE_GET_SONAME(fontconfig,FcInit)
1133   WINE_GET_SONAME(ssl,SSL_library_init)
1134   WINE_GET_SONAME(crypto,BIO_new_socket)
1135   WINE_GET_SONAME(ncurses,waddch)
1136   WINE_GET_SONAME(curses,waddch)
1137   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1138   WINE_GET_SONAME(capi20,capi20_isinstalled)
1139   WINE_GET_SONAME(sane,sane_init)
1140 fi
1141
1142
1143 dnl **** Check for functions ****
1144
1145 AC_CHECK_FUNCS(\
1146         _pclose \
1147         _popen \
1148         _snprintf \
1149         _spawnvp \
1150         _stricmp \
1151         _strnicmp \
1152         _vsnprintf \
1153         asctime_r \
1154         chsize \
1155         clone \
1156         connect \
1157         dlopen \
1158         epoll_create \
1159         ffs \
1160         finite \
1161         fork \
1162         fpclass \
1163         fstatfs \
1164         fstatvfs \
1165         ftruncate \
1166         futimes \
1167         futimesat \
1168         getaddrinfo \
1169         getdirentries \
1170         gethostbyname \
1171         getnameinfo \
1172         getnetbyname \
1173         getopt_long \
1174         getpagesize \
1175         getprotobyname \
1176         getprotobynumber \
1177         getpwuid \
1178         getservbyport \
1179         gettid \
1180         gettimeofday \
1181         getuid \
1182         inet_aton \
1183         inet_network \
1184         kqueue \
1185         lstat \
1186         memmove \
1187         mmap \
1188         pclose \
1189         poll \
1190         popen \
1191         prctl \
1192         pread \
1193         pwrite \
1194         readlink \
1195         rfork \
1196         sched_yield \
1197         select \
1198         sendmsg \
1199         setrlimit \
1200         settimeofday \
1201         sigaltstack \
1202         sigprocmask \
1203         snprintf \
1204         spawnvp \
1205         statfs \
1206         statvfs \
1207         strcasecmp \
1208         strerror \
1209         strncasecmp \
1210         strtold \
1211         tcgetattr \
1212         timegm \
1213         usleep \
1214         vsnprintf \
1215         wait4 \
1216         waitpid \
1217 )
1218
1219 dnl Check for -ldl
1220 if test "$ac_cv_func_dlopen" = no
1221 then
1222     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1223 fi
1224 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1225
1226 dnl Check for -lpoll for Mac OS X/Darwin
1227 if test "$ac_cv_func_poll" = no
1228 then
1229     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1230 fi
1231
1232 dnl Check for -lnsl for Solaris
1233 if test "$ac_cv_func_gethostbyname" = no
1234 then
1235     AC_CHECK_LIB(nsl,gethostbyname)
1236 fi
1237
1238 dnl Check for -lsocket for Solaris
1239 if test "$ac_cv_func_connect" = no
1240 then
1241     AC_CHECK_LIB(socket,connect)
1242 fi
1243
1244 dnl Check for -lresolv for Solaris
1245 if test "$ac_cv_func_inet_aton" = no
1246 then
1247     AC_CHECK_LIB(resolv,inet_aton)
1248 fi
1249
1250 dnl **** Check for types ****
1251
1252 AC_C_CONST
1253 AC_C_INLINE
1254 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1255 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1256 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1257
1258 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1259 [#ifdef HAVE_LINUX_INPUT_H
1260 #include <linux/input.h>
1261 #endif])
1262
1263 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1264                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1265                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1266 if test "$wine_cv_have_sigaddset" = "yes"
1267 then
1268   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1269 fi
1270
1271
1272 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1273         wine_cv_linux_gethostbyname_r_6,
1274         AC_TRY_LINK([
1275 #include <netdb.h>
1276         ], [
1277     char *name=NULL;
1278     struct hostent he;
1279     struct hostent *result;
1280     char *buf=NULL;
1281     int bufsize=0;
1282     int res,errnr;
1283     char *addr=NULL;
1284     int addrlen=0;
1285     int addrtype=0;
1286     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1287     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1288     ],
1289         wine_cv_linux_gethostbyname_r_6=yes,
1290         wine_cv_linux_gethostbyname_r_6=no
1291         )
1292    )
1293    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1294    then
1295       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1296                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1297    fi
1298
1299 if test "$ac_cv_header_linux_joystick_h" = "yes"
1300 then
1301    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1302         wine_cv_linux_joystick_22_api,
1303         AC_TRY_COMPILE([
1304         #include <sys/ioctl.h>
1305         #include <linux/joystick.h>
1306
1307         struct js_event blub;
1308         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1309         #error "no 2.2 header"
1310         #endif
1311         ],/*empty*/,
1312         wine_cv_linux_joystick_22_api=yes,
1313         wine_cv_linux_joystick_22_api=no,
1314         wine_cv_linux_joystick_22_api=no
1315         )
1316    )
1317    if test "$wine_cv_linux_joystick_22_api" = "yes"
1318    then
1319       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1320                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1321    fi
1322 fi
1323
1324 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1325
1326 dnl Check for statfs members
1327 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1328 [#include <sys/types.h>
1329 #ifdef HAVE_SYS_PARAM_H
1330 # include <sys/param.h>
1331 #endif
1332 #ifdef HAVE_SYS_MOUNT_H
1333 # include <sys/mount.h>
1334 #endif
1335 #ifdef HAVE_SYS_VFS_H
1336 # include <sys/vfs.h>
1337 #endif
1338 #ifdef HAVE_SYS_STATFS_H
1339 # include <sys/statfs.h>
1340 #endif])
1341
1342 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1343 [#ifdef HAVE_SYS_STATVFS_H
1344 #include <sys/statvfs.h>
1345 #endif])
1346
1347 dnl Check for socket structure members
1348 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1349 [#include <sys/types.h>
1350 #ifdef HAVE_SYS_SOCKET_H
1351 # include <sys/socket.h>
1352 #endif
1353 #ifdef HAVE_SYS_UN_H
1354 # include <sys/un.h>
1355 #endif])
1356
1357 dnl Check for scsireq_t and sg_io_hdr_t members
1358 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1359 [#include <sys/types.h>
1360 #ifdef HAVE_SCSI_SG_H
1361 #include <scsi/sg.h>
1362 #endif])
1363
1364 dnl Check for siginfo_t members
1365 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1366
1367 dnl Check for struct mtget members
1368 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1369 [#include <sys/types.h>
1370 #ifdef HAVE_SYS_MTIO_H
1371 #include <sys/mtio.h>
1372 #endif])
1373
1374 dnl Check for struct option
1375 AC_CHECK_MEMBERS([struct option.name],,,
1376 [#ifdef HAVE_GETOPT_H
1377 #include <getopt.h>
1378 #endif])
1379
1380 dnl Check for stat.st_blocks
1381 AC_CHECK_MEMBERS([struct stat.st_blocks])
1382
1383 dnl Check for sin6_scope_id
1384 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1385 [#ifdef HAVE_SYS_TYPES_H
1386 #include <sys/types.h>
1387 #endif
1388 #ifdef HAVE_NETINET_IN_H
1389 #include <netinet/in.h>
1390 #endif])
1391
1392 dnl Check for ns_msg ptr member
1393 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1394 [#ifdef HAVE_SYS_TYPES_H
1395 #include <sys/types.h>
1396 #endif
1397 #ifdef HAVE_NETINET_IN_H
1398 # include <netinet/in.h>
1399 #endif
1400 #ifdef HAVE_ARPA_NAMESER_H
1401 # include <arpa/nameser.h>
1402 #endif])
1403
1404 dnl Check for the external timezone variables timezone and daylight
1405 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1406                AC_TRY_LINK([#include <time.h>],[timezone = 1],
1407                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1408 if test "$ac_cv_have_timezone" = "yes"
1409 then
1410     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1411 fi
1412 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1413                AC_TRY_LINK([#include <time.h>],[daylight = 1],
1414                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1415 if test "$ac_cv_have_daylight" = "yes"
1416 then
1417     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1418 fi
1419
1420 dnl *** check for the need to define platform-specific symbols
1421
1422 case $host_cpu in
1423   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1424   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1425   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1426   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1427   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1428 esac
1429
1430 case $host_vendor in
1431   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1432 esac
1433
1434 dnl **** Generate output files ****
1435
1436 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1437 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1438 ["### Dependencies:\\
1439 \\
1440 .INIT: Makefile\\
1441 .BEGIN: Makefile\\
1442 Makefile: dummy\\
1443         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1444 \\
1445 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1446 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1447 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1448 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1449 ["### Dependencies:
1450
1451 .INIT: Makefile
1452 .BEGIN: Makefile
1453 Makefile: dummy
1454         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1455
1456 \$(OBJS): \$(IDL_GEN_HEADERS)
1457 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1458 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1459 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1460
1461 AH_TOP([#define __WINE_CONFIG_H])
1462
1463 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1464
1465 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1466 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1467 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1468 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1469 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1470 WINE_CONFIG_EXTRA_DIR(include/wine)
1471
1472 MAKE_RULES=Make.rules
1473 AC_SUBST_FILE(MAKE_RULES)
1474
1475 MAKE_DLL_RULES=dlls/Makedll.rules
1476 AC_SUBST_FILE(MAKE_DLL_RULES)
1477
1478 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1479 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1480
1481 MAKE_TEST_RULES=dlls/Maketest.rules
1482 AC_SUBST_FILE(MAKE_TEST_RULES)
1483
1484 MAKE_PROG_RULES=programs/Makeprog.rules
1485 AC_SUBST_FILE(MAKE_PROG_RULES)
1486
1487 AC_CONFIG_FILES([Make.rules])
1488 AC_CONFIG_FILES([dlls/Makedll.rules])
1489 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1490 AC_CONFIG_FILES([dlls/Maketest.rules])
1491 AC_CONFIG_FILES([programs/Makeprog.rules])
1492 AC_CONFIG_FILES([Makefile])
1493 AC_CONFIG_FILES([dlls/Makefile])
1494 AC_CONFIG_FILES([dlls/activeds/Makefile])
1495 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1496 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1497 AC_CONFIG_FILES([dlls/advpack/Makefile])
1498 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1499 AC_CONFIG_FILES([dlls/amstream/Makefile])
1500 AC_CONFIG_FILES([dlls/atl/Makefile])
1501 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1502 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1503 AC_CONFIG_FILES([dlls/browseui/Makefile])
1504 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1505 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1506 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1507 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1508 AC_CONFIG_FILES([dlls/cards/Makefile])
1509 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1510 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1511 AC_CONFIG_FILES([dlls/comcat/Makefile])
1512 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1513 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1514 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1515 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1516 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1517 AC_CONFIG_FILES([dlls/compstui/Makefile])
1518 AC_CONFIG_FILES([dlls/credui/Makefile])
1519 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1520 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1521 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1522 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1523 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1524 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1525 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1526 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1527 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1528 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1529 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1530 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1531 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1532 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1533 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1534 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1535 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1536 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1537 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1538 AC_CONFIG_FILES([dlls/devenum/Makefile])
1539 AC_CONFIG_FILES([dlls/dinput/Makefile])
1540 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1541 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1542 AC_CONFIG_FILES([dlls/dmband/Makefile])
1543 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1544 AC_CONFIG_FILES([dlls/dmime/Makefile])
1545 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1546 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1547 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1548 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1549 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1550 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1551 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1552 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1553 AC_CONFIG_FILES([dlls/dplay/Makefile])
1554 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1555 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1556 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1557 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1558 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1559 AC_CONFIG_FILES([dlls/dsound/Makefile])
1560 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1561 AC_CONFIG_FILES([dlls/dswave/Makefile])
1562 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1563 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1564 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1565 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1566 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1567 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1568 AC_CONFIG_FILES([dlls/glu32/Makefile])
1569 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1570 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1571 AC_CONFIG_FILES([dlls/hid/Makefile])
1572 AC_CONFIG_FILES([dlls/hlink/Makefile])
1573 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1574 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1575 AC_CONFIG_FILES([dlls/icmp/Makefile])
1576 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1577 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1578 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1579 AC_CONFIG_FILES([dlls/imm32/Makefile])
1580 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1581 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1582 AC_CONFIG_FILES([dlls/inseng/Makefile])
1583 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1584 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1585 AC_CONFIG_FILES([dlls/itss/Makefile])
1586 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1587 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1588 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1589 AC_CONFIG_FILES([dlls/localspl/Makefile])
1590 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1591 AC_CONFIG_FILES([dlls/lz32/Makefile])
1592 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1593 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1594 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1595 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1596 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1597 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1598 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1599 AC_CONFIG_FILES([dlls/midimap/Makefile])
1600 AC_CONFIG_FILES([dlls/mlang/Makefile])
1601 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1602 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1603 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1604 AC_CONFIG_FILES([dlls/mpr/Makefile])
1605 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1606 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1607 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1608 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1609 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1610 AC_CONFIG_FILES([dlls/mscms/Makefile])
1611 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1612 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1613 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1614 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1615 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1616 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1617 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1618 AC_CONFIG_FILES([dlls/msi/Makefile])
1619 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1620 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1621 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1622 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1623 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1624 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1625 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1626 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1627 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1628 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1629 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1630 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1631 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1632 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1633 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1634 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1635 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1636 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1637 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1638 AC_CONFIG_FILES([dlls/newdev/Makefile])
1639 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1640 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1641 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1642 AC_CONFIG_FILES([dlls/objsel/Makefile])
1643 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1644 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1645 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1646 AC_CONFIG_FILES([dlls/ole32/Makefile])
1647 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1648 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1649 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1650 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1651 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1652 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1653 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1654 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1655 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1656 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1657 AC_CONFIG_FILES([dlls/psapi/Makefile])
1658 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1659 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1660 AC_CONFIG_FILES([dlls/qcap/Makefile])
1661 AC_CONFIG_FILES([dlls/quartz/Makefile])
1662 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1663 AC_CONFIG_FILES([dlls/query/Makefile])
1664 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1665 AC_CONFIG_FILES([dlls/resutils/Makefile])
1666 AC_CONFIG_FILES([dlls/riched20/Makefile])
1667 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1668 AC_CONFIG_FILES([dlls/riched32/Makefile])
1669 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1670 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1671 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1672 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1673 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1674 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1675 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1676 AC_CONFIG_FILES([dlls/schannel/Makefile])
1677 AC_CONFIG_FILES([dlls/secur32/Makefile])
1678 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1679 AC_CONFIG_FILES([dlls/security/Makefile])
1680 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1681 AC_CONFIG_FILES([dlls/serialui/Makefile])
1682 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1683 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1684 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1685 AC_CONFIG_FILES([dlls/sfc/Makefile])
1686 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1687 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1688 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1689 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1690 AC_CONFIG_FILES([dlls/shell32/Makefile])
1691 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1692 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1693 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1694 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1695 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1696 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1697 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1698 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1699 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1700 AC_CONFIG_FILES([dlls/sti/Makefile])
1701 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1702 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1703 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1704 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1705 AC_CONFIG_FILES([dlls/unicows/Makefile])
1706 AC_CONFIG_FILES([dlls/url/Makefile])
1707 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1708 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1709 AC_CONFIG_FILES([dlls/user32/Makefile])
1710 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1711 AC_CONFIG_FILES([dlls/userenv/Makefile])
1712 AC_CONFIG_FILES([dlls/usp10/Makefile])
1713 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1714 AC_CONFIG_FILES([dlls/uuid/Makefile])
1715 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1716 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1717 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1718 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1719 AC_CONFIG_FILES([dlls/version/Makefile])
1720 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1721 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1722 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1723 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1724 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1725 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1726 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1727 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1728 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1729 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1730 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1731 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1732 AC_CONFIG_FILES([dlls/winedos/Makefile])
1733 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1734 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1735 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1736 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1737 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1738 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1739 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1740 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1741 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1742 AC_CONFIG_FILES([dlls/wing32/Makefile])
1743 AC_CONFIG_FILES([dlls/wininet/Makefile])
1744 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1745 AC_CONFIG_FILES([dlls/winmm/Makefile])
1746 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1747 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1748 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1749 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1750 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1751 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1752 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1753 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1754 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1755 AC_CONFIG_FILES([dlls/wow32/Makefile])
1756 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1757 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1758 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1759 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1760 AC_CONFIG_FILES([documentation/Makefile])
1761 AC_CONFIG_FILES([fonts/Makefile])
1762 AC_CONFIG_FILES([include/Makefile])
1763 AC_CONFIG_FILES([libs/Makefile])
1764 AC_CONFIG_FILES([libs/port/Makefile])
1765 AC_CONFIG_FILES([libs/wine/Makefile])
1766 AC_CONFIG_FILES([libs/wpp/Makefile])
1767 AC_CONFIG_FILES([loader/Makefile])
1768 AC_CONFIG_FILES([programs/Makefile])
1769 AC_CONFIG_FILES([programs/clock/Makefile])
1770 AC_CONFIG_FILES([programs/cmd/Makefile])
1771 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1772 AC_CONFIG_FILES([programs/control/Makefile])
1773 AC_CONFIG_FILES([programs/eject/Makefile])
1774 AC_CONFIG_FILES([programs/expand/Makefile])
1775 AC_CONFIG_FILES([programs/explorer/Makefile])
1776 AC_CONFIG_FILES([programs/hh/Makefile])
1777 AC_CONFIG_FILES([programs/icinfo/Makefile])
1778 AC_CONFIG_FILES([programs/iexplore/Makefile])
1779 AC_CONFIG_FILES([programs/msiexec/Makefile])
1780 AC_CONFIG_FILES([programs/notepad/Makefile])
1781 AC_CONFIG_FILES([programs/oleview/Makefile])
1782 AC_CONFIG_FILES([programs/progman/Makefile])
1783 AC_CONFIG_FILES([programs/regedit/Makefile])
1784 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1785 AC_CONFIG_FILES([programs/rpcss/Makefile])
1786 AC_CONFIG_FILES([programs/rundll32/Makefile])
1787 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1788 AC_CONFIG_FILES([programs/start/Makefile])
1789 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1790 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1791 AC_CONFIG_FILES([programs/view/Makefile])
1792 AC_CONFIG_FILES([programs/wineboot/Makefile])
1793 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1794 AC_CONFIG_FILES([programs/winecfg/Makefile])
1795 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1796 AC_CONFIG_FILES([programs/winedbg/Makefile])
1797 AC_CONFIG_FILES([programs/winefile/Makefile])
1798 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1799 AC_CONFIG_FILES([programs/winemine/Makefile])
1800 AC_CONFIG_FILES([programs/winepath/Makefile])
1801 AC_CONFIG_FILES([programs/winetest/Makefile])
1802 AC_CONFIG_FILES([programs/winevdm/Makefile])
1803 AC_CONFIG_FILES([programs/winhelp/Makefile])
1804 AC_CONFIG_FILES([programs/winver/Makefile])
1805 AC_CONFIG_FILES([programs/wordpad/Makefile])
1806 AC_CONFIG_FILES([programs/xcopy/Makefile])
1807 AC_CONFIG_FILES([server/Makefile])
1808 AC_CONFIG_FILES([tools/Makefile])
1809 AC_CONFIG_FILES([tools/widl/Makefile])
1810 AC_CONFIG_FILES([tools/winebuild/Makefile])
1811 AC_CONFIG_FILES([tools/winedump/Makefile])
1812 AC_CONFIG_FILES([tools/winegcc/Makefile])
1813 AC_CONFIG_FILES([tools/wmc/Makefile])
1814 AC_CONFIG_FILES([tools/wrc/Makefile])
1815
1816 AC_OUTPUT
1817
1818 dnl **** Display messages about additional packages ***
1819
1820 if test "$no_create" = "yes"
1821 then
1822   exit 0
1823 fi
1824
1825 if test "$verbose" = "yes"
1826 then
1827   dnl **** libcapi20-dev devel package ***
1828   if test "$ac_cv_header_capi20_h" != "yes" -o "$ac_cv_header_linux_capi_h" != "yes"
1829   then
1830     echo >&2
1831     AC_MSG_NOTICE([libcapi20 development files not found.])
1832     AC_MSG_NOTICE([Wine will be built without ISDN support. (capi2032.dll)])
1833   fi
1834
1835   dnl **** libcupsys-dev devel package ***
1836   if test "$ac_cv_header_cups_cups_h" != "yes"
1837   then
1838     echo >&2
1839     AC_MSG_NOTICE([libcups development files not found.])
1840     AC_MSG_NOTICE([Wine will be built without CUPS support.])
1841   fi
1842
1843   dnl **** libcurses devel package: see libncurses ***
1844   dnl **** libdbus-1 devel package ***
1845   dnl **** libdbus-1-dev is required for libhal-dev ***
1846
1847   dnl **** libgphoto2 devel package ***
1848   if test "$ac_cv_header_gphoto2_camera_h" != "yes"
1849   then
1850     echo >&2
1851     AC_MSG_NOTICE([libgphoto2 development files not found.])
1852     if test "$ac_cv_header_sane_sane_h" = "yes"
1853     then
1854       AC_MSG_NOTICE([Wine will be built with limited Digital Camera support. (twain_32.dll)])
1855     else
1856       AC_MSG_NOTICE([Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
1857     fi
1858   fi
1859
1860   dnl **** libhal devel package ***
1861   dnl **** libhal-dev depends on libdbus-1-dev ***
1862   if test "$ac_cv_header_hal_libhal_h" != "yes"
1863   then
1864     echo >&2
1865     AC_MSG_NOTICE([libhal development files not found.])
1866     AC_MSG_NOTICE([Wine will be built without dynamic device support. (explorer.exe)])
1867   fi
1868
1869   dnl **** libicu devel package ****
1870   if test "$ac_cv_header_unicode_ubidi_h" != "yes"
1871   then
1872     echo >&2
1873     AC_MSG_NOTICE([libicu development files not found.])
1874     AC_MSG_NOTICE([Wine will be built without bidi (Right to Left) support. (gdi32.dll)])
1875   fi
1876
1877   dnl **** liblcms devel package ****
1878   if test "$ac_cv_header_lcms_h" != "yes" -a "$ac_cv_header_lcms_lcms_h" != "yes"
1879   then
1880     echo >&2
1881     AC_MSG_NOTICE([liblcms development files not found.])
1882     AC_MSG_NOTICE([Wine will be built without Color Management support. (mscms.dll)])
1883   fi
1884
1885   dnl **** libldap devel package ****
1886   if test "$ac_cv_header_ldap_h" != "yes" -o "$ac_cv_header_lber_h" != "yes"
1887   then
1888     echo >&2
1889     AC_MSG_NOTICE([libldap (OpenLDAP) development files not found.])
1890     AC_MSG_NOTICE([Wine will be built without LDAP support. (wldap32.dll)])
1891   fi
1892
1893   dnl **** libncurses / libcurses devel package ***
1894   if test "x$with_curses" != "xno" -a "$ac_cv_header_ncurses_h" != "yes" -a "$ac_cv_header_curses_h" != "yes"
1895   then
1896     echo >&2
1897     AC_MSG_NOTICE([lib(n)curses development files not found.])
1898     AC_MSG_NOTICE([Wine will be built without (n)curses support. (wineconsole.exe)])
1899   fi
1900
1901   dnl **** libsane devel package ***
1902   if test "$ac_cv_header_sane_sane_h" != "yes"
1903   then
1904     echo >&2
1905     AC_MSG_NOTICE([libsane development files not found.])
1906     AC_MSG_NOTICE([Wine will be built without Scanner support. (sane.ds/twain_32.dll)])
1907   fi
1908
1909   dnl **** libX11-dev includes Xlib.h and Xutil.h and depends on ***
1910   dnl **** x11proto-input-dev (extensions/XInput.h) and x11proto-kb-dev (XKBlib.h) ***
1911   if test "$have_x" = "yes"
1912   then
1913     dnl **** libX11 - extension: Xext ***
1914     if test "$ac_cv_header_X11_extensions_shape_h" != "yes" -o "$ac_cv_header_X11_extensions_XShm_h" != "yes"
1915     then
1916       echo >&2
1917       AC_MSG_NOTICE([libxext development files not found.])
1918       AC_MSG_NOTICE([Wine will be built without Shm / Shape support. (winex11.drv)])
1919     fi
1920
1921     dnl **** libX11 - extension: Xrandr ***
1922     if test "$ac_cv_header_X11_extensions_Xrandr_h" != "yes"
1923     then
1924       echo >&2
1925       AC_MSG_NOTICE([libXrandr development files not found.])
1926       AC_MSG_NOTICE([Wine will be built without Xrandr support. (winex11.drv)])
1927     fi
1928
1929     dnl **** libX11 - extension: Xrender ***
1930     if test "$ac_cv_header_X11_extensions_Xrender_h" != "yes"
1931     then
1932       echo >&2
1933       AC_MSG_NOTICE([libXrender development files not found.])
1934       AC_MSG_NOTICE([Wine will be built without Xrender support. (winex11.drv)])
1935     fi
1936
1937     dnl **** libX11 - extension: Xxf86vm ***
1938     if test "$ac_cv_header_X11_extensions_xf86vmode_h" != "yes"
1939     then
1940       echo >&2
1941       AC_MSG_NOTICE([libXxf86vm development files not found.])
1942       AC_MSG_NOTICE([Wine will be built without XFree86-VidMode support. (winex11.drv)])
1943     fi
1944   fi
1945
1946   dnl **** libxml2 devel package ***
1947   if test "$ac_cv_header_libxml_parser_h" != "yes"
1948   then
1949     echo >&2
1950     AC_MSG_NOTICE([libxml2 development files not found.])
1951     AC_MSG_NOTICE([Wine will be built without XML support. (msxml.dll)])
1952   fi
1953
1954   dnl **** libxslt devel package ***
1955   if test "$ac_cv_header_libxslt_pattern_h" != "yes" -o "$ac_cv_header_libxslt_transform_h" != "yes"
1956   then
1957     echo >&2
1958     AC_MSG_NOTICE([libxslt development files not found.])
1959     AC_MSG_NOTICE([Wine will be built without xslt support. (msxml.dll)])
1960   fi
1961 fi
1962
1963
1964 dnl **** Display warnings about important packages ***
1965 if test "$have_x" = "no"
1966 then
1967   echo >&2
1968   AC_MSG_WARN([X development files not found. Wine will be built without])
1969   AC_MSG_WARN([X support, which currently does not work, and probably])
1970   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1971   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1972 fi
1973
1974 if test -z "$OPENGLFILES"
1975 then
1976   echo >&2
1977   AC_MSG_WARN([Wine will be build without OpenGL or Direct3D support])
1978   AC_MSG_WARN([because something is wrong with the OpenGL setup:])
1979   if test "$wine_cv_opengl_headers_found" = "no"
1980   then
1981     AC_MSG_WARN([No OpenGL development headers were found])
1982   fi
1983   if test "$wine_cv_opengl_header_version_OK" = "no"
1984   then
1985     AC_MSG_WARN([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
1986   elif test "$ac_cv_lib_GL_glXCreateContext" = "no"
1987   then
1988      if test -f /usr/X11R6/lib/libGL.a
1989      then
1990         AC_MSG_WARN([/usr/X11R6/lib/libGL.a is present on your system.
1991 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
1992      else
1993         AC_MSG_WARN([No OpenGL library found on this system.])
1994      fi
1995   fi
1996 fi
1997
1998 if test "$wine_cv_msg_freetype" = "yes"
1999 then
2000   echo >&2
2001   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
2002   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
2003   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
2004   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
2005 fi
2006
2007 if test -z "$FONTSSUBDIRS"
2008 then
2009   echo >&2
2010   if test "$FONTFORGE" = "false"
2011   then
2012     AC_MSG_WARN([FontForge is missing.])
2013   else
2014     AC_MSG_WARN([FreeType is missing.])
2015   fi
2016   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
2017 fi
2018
2019 if test -z "$ALSALIBS" -a \
2020         -z "$AUDIOIOLIBS" -a \
2021         -z "$NASLIBS" -a \
2022         -z "$ESD_LIBS" -a \
2023         -z "$ac_cv_lib_soname_jack" -a \
2024         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
2025         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
2026         "$ac_cv_header_soundcard_h" != "yes"
2027 then
2028   echo >&2
2029   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
2030   AC_MSG_WARN([The currently supported sound systems are:])
2031   AC_MSG_WARN([ALSA, EsounD, AudioIO, Jack, NAS and OSS])
2032 fi
2033
2034 echo
2035 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
2036 echo
2037
2038 dnl Local Variables:
2039 dnl comment-start: "dnl "
2040 dnl comment-end: ""
2041 dnl comment-start-skip: "\\bdnl\\b\\s *"
2042 dnl compile-command: "autoconf && autoheader"
2043 dnl End: