configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(debug,
  19 [  --disable-debug         compile out all debugging messages],
  20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  21
  22 AC_ARG_ENABLE(opengl,
  23 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe via pthread],
  24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  25
  26 AC_ARG_ENABLE(trace,
  27 [  --disable-trace         compile out TRACE messages],
  28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  29
  30 AC_ARG_WITH(curses,
  31 [  --without-curses        do not use curses],
  32 [if test "$withval" = "no"; then CURSES="no"; fi])
  33
  34 AC_ARG_WITH(reentrant-x,
  35 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  36
  37 AC_SUBST(OPTIONS)
  38
  39 if test "$DEBUG_MSGS" = "no"
  40 then
  41     AC_DEFINE(NO_DEBUG_MSGS)
  42     AC_DEFINE(NO_TRACE_MSGS)
  43 else
  44     if test "$TRACE_MSGS" = "no"
  45     then
  46         AC_DEFINE(NO_TRACE_MSGS)
  47     fi
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_DECL_YYTEXT
  66 AC_PROG_RANLIB
  67 AC_PROG_INSTALL
  68 AC_PROG_LN_S
  69 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  70 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  71 AC_CYGWIN
  72 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  73
  74 dnl Check for lint
  75 AC_CHECK_PROGS(LINT, lclint lint)
  76 if test "$LINT" = "lint"
  77 then
  78   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  79   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  80 fi
  81 AC_SUBST(LINT)
  82 AC_SUBST(LINTFLAGS)
  83
  84 if test "$CYGWIN" = "yes"
  85 then
  86     LDCOMBINE="ld -r --enable-stdcall-fixup"
  87 else
  88     LDCOMBINE="ld -r"
  89 fi
  90 AC_SUBST(LDCOMBINE)
  91
  92 dnl **** Check for some libraries ****
  93
  94 dnl Check for -lm for BeOS
  95 AC_CHECK_LIB(m,sqrt)
  96 dnl Check for -li386 for NetBSD and OpenBSD
  97 AC_CHECK_LIB(i386,i386_set_ldt)
  98 dnl Check for -lossaudio for NetBSD
  99 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 100 dnl Check for -lw for Solaris
 101 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 102 dnl Check for -lnsl for Solaris
 103 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 104 dnl Check for -lsocket for Solaris
 105 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 106 dnl Check for -lxpg4 for FreeBSD
 107 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 108 dnl Check for -lmmap for OS/2
 109 AC_CHECK_LIB(mmap,mmap)
 110 dnl Check for openpty
 111 AC_CHECK_FUNCS(openpty,,
 112         AC_CHECK_LIB(util,openpty,
 113                 AC_DEFINE(HAVE_OPENPTY)
 114                 LIBS="$LIBS -lutil"
 115         ))
 116
 117 AC_CHECK_HEADERS(dlfcn.h,
 118         AC_CHECK_FUNCS(dlopen,
 119                 AC_DEFINE(HAVE_DL_API),
 120                 AC_CHECK_LIB(dl,dlopen,
 121                         AC_DEFINE(HAVE_DL_API)
 122                         LIBS="$LIBS -ldl",
 123                         LIBEXT="a"
 124                 )
 125         ),
 126         LIBEXT="a"
 127 )
 128 AC_SUBST(XLIB)
 129 AC_SUBST(X_DLLS)
 130 X_DLLS=""
 131 AC_SUBST(XFILES)
 132 XFILES=""
 133 AC_SUBST(OPENGLFILES)
 134 OPENGLFILES=""
 135 AC_SUBST(OPENGL32_DLL)
 136 OPENGL32_DLL=""
 137 if test "$have_x" = "yes"
 138 then
 139     XLIB="-lXext -lX11"
 140     ac_save_CPPFLAGS="$CPPFLAGS"
 141     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 142
 143     dnl *** Check for -lXpm
 144     AC_CHECK_HEADERS(X11/xpm.h,
 145       [ dnl *** If X11/xpm.h exists...
 146         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 147           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 148           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 149         )
 150       ],
 151       [ dnl *** If X11/xpm.h does not exist...
 152         dnl NOTE: autoconf does not allow commas inside the third
 153         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 154         dnl       magic it does.
 155         echo "Redhat            :       xpm xpm-devel"
 156         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 157         echo "SuSE              :       xpm"
 158         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 159         echo
 160         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 161         echo "the directory /contrib/libraries."
 162         echo
 163         exit 1
 164       ]
 165     )
 166
 167     dnl *** All three of the following tests require X11/Xlib.h
 168     AC_CHECK_HEADERS(X11/Xlib.h,
 169       [
 170         dnl *** Check for X keyboard extension
 171         AC_CHECK_HEADERS(X11/XKBlib.h,
 172             [ dnl *** If X11/XKBlib.h exists...
 173               AC_CHECK_LIB(X11, XkbQueryExtension,
 174               AC_DEFINE(HAVE_XKB),,
 175               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 176             ],
 177             AC_MSG_WARN([XKB extension not found!!])
 178         )
 179
 180         dnl *** Check for X Shm extension
 181         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 182             [ dnl *** If X11/extensions/XShm.h exists...
 183               AC_CHECK_LIB(Xext, XShmQueryExtension,
 184               AC_DEFINE(HAVE_LIBXXSHM),,
 185               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 186             ],
 187             AC_MSG_WARN([Xshm extension not found!!])
 188         )
 189
 190         dnl *** Check for X shape extension
 191         AC_CHECK_HEADERS(X11/extensions/shape.h,
 192             [ dnl *** If X11/extensions/shape.h exists...
 193               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 194               AC_DEFINE(HAVE_LIBXSHAPE),,
 195               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 196             ],
 197             AC_MSG_WARN([XShape extension not found!!])
 198         )
 199
 200         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 201         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 202             [ dnl *** If X11/extensions/xf86dga.h exists, check
 203               dnl *** for XDGAQueryExtension()...
 204               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 205                 [ dnl *** If found...
 206                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 207                   AC_DEFINE(HAVE_LIBXXF86DGA)
 208                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 209                ],
 210                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 211                   dnl *** instead (DGA 2.0 not found)...
 212                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 213                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 214                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 215                     ],,
 216                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 217                   )
 218                 ],
 219                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 220               )
 221             ],
 222             AC_MSG_WARN([DGA extension not found!!])
 223         )
 224
 225         dnl *** Check for XFree86 VMODE extension
 226         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 227             [ dnl *** If X11/extensions/xf86vmode.h exists...
 228                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 229                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 230                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 231                   ],,
 232                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 233                 )
 234             ],
 235             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 236         )
 237
 238         dnl *** Check for XVideo extension supporting XvImages
 239         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 240             [ dnl *** If X11/extensions/Xvlib.h exists...
 241                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 242                   [ AC_DEFINE(HAVE_XVIDEO)
 243                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 244                   ],,
 245                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 246                 )
 247             ],
 248             AC_MSG_WARN([XVideo extension not found !!])
 249         )
 250
 251       ]
 252     ) dnl *** End of X11/Xlib.h check
 253
 254     dnl Check for the presence of OpenGL
 255     if test $OPENGL = "yes" -o $OPENGL = "normal"
 256     then
 257         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 258         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 259         then
 260             dnl Check for some problems due to old Mesa versions
 261             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 262               AC_TRY_COMPILE(
 263                 [#include <GL/gl.h>],
 264                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 265                 [wine_cv_opengl_version_OK="yes"],
 266                 [wine_cv_opengl_version_OK="no"]
 267               )
 268             )
 269
 270             dnl Check for the thread-safety of the OpenGL library
 271             AC_CACHE_CHECK("for thread-safe OpenGL version",
 272                            wine_cv_opengl_version_threadsafe,
 273               [saved_libs=$LIBS
 274                LIBS="$X_LIBS -lGL"
 275                AC_TRY_LINK([],[pthread_getspecific();],
 276                               [wine_cv_opengl_version_threadsafe="yes"],
 277                               [wine_cv_opengl_version_threadsafe="no"])
 278                LIBS=$saved_libs]
 279             )
 280
 281             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 282             then
 283                 dnl Check for the presence of the library
 284                 AC_CHECK_LIB(GL,glXCreateContext,
 285                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 286                              ,,
 287                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 288
 289                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 290                 then
 291
 292                         OPENGLFILES='$(OPENGLFILES)'
 293                         AC_DEFINE(HAVE_OPENGL)
 294
 295                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 296
 297                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 298                         then
 299                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 300                                   AC_TRY_COMPILE([#include <GL/gl.h>
 301                                                   #ifdef HAVE_GL_GLEXT_H
 302                                                   # include <GL/glext.h>
 303                                                   #endif
 304                                                   ],
 305                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 306                                                  [wine_cv_extension_prototypes="yes"],
 307                                                  [wine_cv_extension_prototypes="no"]
 308                                   )
 309                                 )
 310                                 if test $wine_cv_extension_prototypes = "yes"
 311                                 then
 312                                         AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 313                                 fi
 314
 315                                 OPENGL32_DLL=opengl32
 316                         fi
 317
 318                         AC_CHECK_HEADERS(GL/osmesa.h,
 319                             [ dnl *** If GL/osmesa.h exists...
 320                                 AC_CHECK_LIB(GL, OSMesaCreateContext,
 321                                   AC_DEFINE(HAVE_OSMESA),
 322                                   AC_CHECK_LIB(OSMesa, OSMesaCreateContext,
 323                                   [ AC_DEFINE(HAVE_OSMESA)
 324                                     X_PRE_LIBS="$X_PRE_LIBS -lOSMesa"
 325                                   ],,-lGL $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS),
 326                                   $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 327                                 )
 328                             ]
 329                         )
 330                 fi
 331              fi
 332          fi
 333     fi
 334
 335     CPPFLAGS="$ac_save_CPPFLAGS"
 336     X_DLLS='$(X_DLLS)'
 337     XFILES='$(XFILES)'
 338 else
 339     XLIB=""
 340     X_CFLAGS=""
 341     X_LIBS=""
 342 fi
 343
 344 dnl **** Check which curses lib to use ***
 345 if test "$CURSES" = "yes"
 346 then
 347     AC_CHECK_HEADERS(ncurses.h)
 348     if test "$ac_cv_header_ncurses_h" = "yes"
 349     then
 350         AC_CHECK_LIB(ncurses,waddch)
 351     fi
 352     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 353     then
 354         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 355         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 356     else
 357         AC_CHECK_HEADERS(curses.h)
 358         if test "$ac_cv_header_curses_h" = "yes"
 359         then
 360             AC_CHECK_LIB(curses,waddch)
 361             if test "$ac_cv_lib_curses_waddch" = "yes"
 362             then
 363                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 364                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 365             fi
 366         fi
 367     fi
 368 fi
 369
 370 CUPSLIBS=""
 371 dnl **** Check for CUPS ****
 372 wine_cv_warn_cups_h=no
 373 AC_CHECK_LIB(cups,cupsGetPPD,
 374         AC_CHECK_HEADER(cups/cups.h,
 375             AC_DEFINE(HAVE_CUPS)
 376             CUPSLIBS="-lcups",
 377             wine_cv_warn_cups_h=yes)
 378 )
 379 AC_SUBST(CUPSLIBS)
 380
 381 dnl **** Check for IPX (currently Linux only) ****
 382 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 383  AC_TRY_COMPILE(
 384    [#include <sys/socket.h>
 385     #include <netipx/ipx.h>],
 386    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 387    [ac_cv_c_ipx_gnu="yes"],
 388    [ac_cv_c_ipx_gnu="no"])
 389  )
 390 if test "$ac_cv_c_ipx_gnu" = "yes"
 391 then
 392     AC_DEFINE(HAVE_IPX_GNU)
 393 fi
 394
 395 if test "$ac_cv_c_ipx_gnu" = "no"
 396 then
 397  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 398   AC_TRY_COMPILE(
 399     [#include <sys/socket.h>
 400      #include <asm/types.h>
 401      #include <linux/ipx.h>],
 402     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 403     [ac_cv_c_ipx_linux="yes"],
 404     [ac_cv_c_ipx_linux="no"])
 405   )
 406   if test "$ac_cv_c_ipx_linux" = "yes"
 407   then
 408       AC_DEFINE(HAVE_IPX_LINUX)
 409   fi
 410 fi
 411
 412 dnl **** Check for Open Sound System ****
 413 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 414
 415 AC_CACHE_CHECK("for Open Sound System",
 416         ac_cv_c_opensoundsystem,
 417         AC_TRY_COMPILE([
 418         #if defined(HAVE_SYS_SOUNDCARD_H)
 419                 #include <sys/soundcard.h>
 420         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 421                 #include <machine/soundcard.h>
 422         #elif defined(HAVE_SOUNDCARD_H)
 423                 #include <soundcard.h>
 424         #endif
 425         ],[
 426
 427 /* check for one of the Open Sound System specific SNDCTL_ defines */
 428 #if !defined(SNDCTL_DSP_STEREO)
 429 #error No open sound system
 430 #endif
 431 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 432
 433 if test "$ac_cv_c_opensoundsystem" = "yes"
 434 then
 435     AC_DEFINE(HAVE_OSS)
 436 fi
 437
 438 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 439         ac_cv_c_opensoundsystem_midi,
 440         AC_TRY_COMPILE([
 441         #if defined(HAVE_SYS_SOUNDCARD_H)
 442                 #include <sys/soundcard.h>
 443         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 444                 #include <machine/soundcard.h>
 445         #elif defined(HAVE_SOUNDCARD_H)
 446                 #include <soundcard.h>
 447         #endif
 448         ],[
 449
 450 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 451 #if !defined(SNDCTL_SEQ_SYNC)
 452 #error No open sound system MIDI interface
 453 #endif
 454 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 455
 456 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 457 then
 458     AC_DEFINE(HAVE_OSS_MIDI)
 459 fi
 460
 461 dnl **** If ln -s doesn't work, use cp instead ****
 462 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 463
 464 dnl **** Check for gcc strength-reduce bug ****
 465
 466 if test "x${GCC}" = "xyes"
 467 then
 468   CFLAGS="$CFLAGS -Wall"
 469   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 470                   AC_TRY_RUN([
 471 int     L[[4]] = {0,1,2,3};
 472 int main(void) {
 473   static int Array[[3]];
 474   unsigned int B = 3;
 475   int i;
 476   for(i=0; i<B; i++) Array[[i]] = i - 3;
 477   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 478   L[[i]] = 4;
 479
 480   exit( Array[[1]] != -2 || L[[2]] != 3);
 481 }],
 482     ac_cv_c_gcc_strength_bug="no",
 483     ac_cv_c_gcc_strength_bug="yes",
 484     ac_cv_c_gcc_strength_bug="yes") )
 485   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 486   then
 487     CFLAGS="$CFLAGS -fno-strength-reduce"
 488   fi
 489
 490   dnl Check for -mpreferred-stack-boundary
 491   AC_CACHE_CHECK("for gcc -mpreferred-stack-boundary=2 support",
 492                  ac_cv_c_gcc_stack_boundary,
 493   [saved_cflags=$CFLAGS
 494   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 495   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 496   CFLAGS=$saved_cflags
 497   ])
 498   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 499   then
 500     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 501   fi
 502 fi
 503
 504 dnl **** Check if we need to place .type inside a .def directive ****
 505
 506 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
 507                ac_cv_c_type_in_def,
 508 [saved_libs=$LIBS
 509 LIBS="conftest_asm.s $LIBS"
 510 cat > conftest_asm.s <<EOF
 511         .globl _ac_test
 512         .def _ac_test; .scl 2; .type 32; .endef
 513 _ac_test:
 514         .long 0
 515 EOF
 516 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 517 LIBS=$saved_libs])
 518 if test "$ac_cv_c_type_in_def" = "yes"
 519 then
 520   AC_DEFINE(NEED_TYPE_IN_DEF)
 521 fi
 522
 523 dnl **** Check for underscore on external symbols ****
 524
 525 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 526                ac_cv_c_extern_prefix,
 527 [saved_libs=$LIBS
 528 LIBS="conftest_asm.s $LIBS"
 529 cat > conftest_asm.s <<EOF
 530         .globl _ac_test
 531 _ac_test:
 532         .long 0
 533 EOF
 534 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 535             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 536 LIBS=$saved_libs])
 537 if test "$ac_cv_c_extern_prefix" = "yes"
 538 then
 539   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 540 fi
 541
 542 dnl **** Check for .string in assembler ****
 543
 544 AC_CACHE_CHECK("whether assembler accepts .string",
 545                ac_cv_c_asm_string,
 546 [saved_libs=$LIBS
 547 LIBS="conftest_asm.s $LIBS"
 548 cat > conftest_asm.s <<EOF
 549         .string "test"
 550 EOF
 551 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 552 LIBS=$saved_libs])
 553 if test "$ac_cv_c_asm_string" = "yes"
 554 then
 555   AC_DEFINE(HAVE_ASM_STRING)
 556 fi
 557
 558 dnl **** Check for working dll ****
 559
 560 LDSHARED=""
 561 LDDLLFLAGS=""
 562 if test "$LIBEXT" = "so"
 563 then
 564   AC_CACHE_CHECK("whether we can build a Linux dll",
 565                  ac_cv_c_dll_linux,
 566   [saved_cflags=$CFLAGS
 567   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 568   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 569   CFLAGS=$saved_cflags
 570   ])
 571   if test "$ac_cv_c_dll_linux" = "yes"
 572   then
 573     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%) -Wl,-rpath,\$(libdir)"
 574     LDDLLFLAGS="-Wl,-Bsymbolic"
 575   else
 576     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 577                  ac_cv_c_dll_unixware,
 578     [saved_cflags=$CFLAGS
 579     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 580     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 581     CFLAGS=$saved_cflags
 582     ])
 583     if test "$ac_cv_c_dll_unixware" = "yes"
 584     then
 585       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,\$(libdir)/%)"
 586       LDDLLFLAGS="-Wl,-B,symbolic"
 587     else
 588       AC_CACHE_CHECK("whether we can build a NetBSD dll",
 589                    ac_cv_c_dll_netbsd,
 590       [saved_cflags=$CFLAGS
 591       CFLAGS="$CFLAGS -fPIC -Wl,-Bshareable,-Bforcearchive"
 592       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 593       CFLAGS=$saved_cflags
 594       ])
 595       if test "$ac_cv_c_dll_netbsd" = "yes"
 596       then
 597         LDSHARED="\$(CC) -Wl,-Bshareable,-Bforcearchive"
 598         LDDLLFLAGS="" #FIXME
 599       fi
 600     fi
 601   fi
 602   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 603   then
 604     LIBEXT="a"
 605     if test "$DLLWRAP" = "dllwrap"; then
 606       dnl FIXME - check whether dllwrap works correctly...
 607       if test "$CYGWIN" = "yes"; then
 608         echo "*** use dllwrap for building shared library."
 609         LIBEXT="dll"
 610       fi
 611     fi
 612   fi
 613 fi
 614
 615 if test "$LIBEXT" = "a"; then
 616   echo "*** It is currently not possible to build WINE without shared"
 617   echo "*** library (.so) support to allow transparent switch between .so"
 618   echo "*** and .dll files."
 619   echo "*** If you are using Linux, you will need a newer binutils."
 620   exit 1
 621 fi
 622
 623 DLLFLAGS=""
 624 LDPATH=""
 625
 626 if test "$LIBEXT" = "so"; then
 627     DLLFLAGS="-fPIC"
 628     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 629     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 630 elif test "$LIBEXT" = "dll"; then
 631     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 632     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 633     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 634 else
 635     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) \$(LIBWINE) \$(LIBUNICODE) \$(X_LIBS) \$(XLIB)"
 636     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 637                    ac_cv_c_whole_archive,
 638             [saved_cflags=$CFLAGS
 639             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 640             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 641             CFLAGS=$saved_cflags
 642             ])
 643     if test "$ac_cv_c_whole_archive" = "yes"
 644     then
 645         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 646     else
 647         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 648                        ac_cv_c_allextract,
 649                 [saved_cflags=$CFLAGS
 650                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 651                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 652                 CFLAGS=$saved_cflags
 653                 ])
 654         if test "$ac_cv_c_allextract" = "yes"
 655         then
 656             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 657         fi
 658     fi
 659 fi
 660
 661 AC_SUBST(DLL_LINK)
 662 AC_SUBST(DLLFLAGS)
 663 AC_SUBST(LDSHARED)
 664 AC_SUBST(LDDLLFLAGS)
 665 AC_SUBST(LIBEXT)
 666 AC_SUBST(LDPATH)
 667
 668 dnl **** Check for reentrant libc ****
 669 dnl
 670 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 671 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 672
 673 AC_DEFUN(WINE_CHECK_ERRNO,
 674 [
 675   AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
 676   [AC_TRY_RUN([int myerrno = 0;
 677 char buf[256];
 678 int *$1(){return &myerrno;}
 679 main(){connect(0,buf,255); exit(!myerrno);}],
 680   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
 681   wine_cv_libc_r_$1=yes )
 682 ])
 683 if test "$wine_cv_libc_r_$1" = "yes"
 684 then
 685     wine_cv_libc_reentrant=$1
 686 fi
 687 ])
 688
 689 wine_cv_libc_reentrant=no
 690 dnl Linux style errno location
 691 WINE_CHECK_ERRNO(__errno_location)
 692 dnl FreeBSD style errno location
 693 WINE_CHECK_ERRNO(__error)
 694 dnl Solaris style errno location
 695 WINE_CHECK_ERRNO(___errno)
 696 dnl UnixWare style errno location
 697 WINE_CHECK_ERRNO(__thr_errno)
 698
 699 if test "$wine_cv_libc_reentrant" != "no"
 700 then
 701   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant)
 702 fi
 703
 704 dnl **** Check for reentrant X libraries ****
 705 dnl
 706 dnl This may fail to determine whether X libraries are reentrant if
 707 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 708 dnl is possible with the --without-reentrant-x option.
 709
 710 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 711 then
 712 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 713   [ if test "x$with_reentrant_x" = "xno"
 714     then
 715         wine_cv_x_reentrant=no
 716     else
 717         libX11_check=none
 718         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 719             if test -r $dir/libX11.so; then
 720                 libX11_check="-D $dir/libX11.so"
 721                 break 1
 722             fi
 723             if test -r $dir/libX11.a; then
 724                 libX11_check="$dir/libX11.a"
 725                 break 1
 726             fi
 727         done
 728         if test "$libX11_check" != "none"; then
 729             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 730             then
 731                 wine_cv_x_reentrant=yes
 732             else
 733                 wine_cv_x_reentrant=no
 734             fi
 735         else
 736             wine_cv_x_reentrant=unknown
 737         fi
 738     fi ] )
 739 else
 740     wine_cv_x_reentrant=no
 741 fi
 742 if test "$wine_cv_x_reentrant" = "no"
 743 then
 744   AC_DEFINE(NO_REENTRANT_X11)
 745 fi
 746
 747
 748 dnl **** Check for functions ****
 749
 750 AC_FUNC_ALLOCA()
 751 AC_CHECK_FUNCS(\
 752         __libc_fork \
 753         _lwp_create \
 754         clone \
 755         ecvt \
 756         finite \
 757         fpclass \
 758         getnetbyaddr \
 759         getnetbyname \
 760         getpagesize \
 761         getprotobyname \
 762         getprotobynumber \
 763         getrlimit \
 764         getservbyport \
 765         getsockopt \
 766         inet_network \
 767         lstat \
 768         memmove \
 769         mmap \
 770         rfork \
 771         select \
 772         sendmsg \
 773         settimeofday \
 774         sigaltstack \
 775         statfs \
 776         strcasecmp \
 777         strerror \
 778         strncasecmp \
 779         tcgetattr \
 780         timegm \
 781         usleep \
 782         vfscanf \
 783         wait4 \
 784         waitpid \
 785 )
 786
 787 dnl **** Check for header files ****
 788
 789 AC_CHECK_HEADERS(\
 790         arpa/inet.h \
 791         arpa/nameser.h \
 792         elf.h \
 793         float.h \
 794         ieeefp.h \
 795         libio.h \
 796         libutil.h \
 797         link.h \
 798         linux/cdrom.h \
 799         linux/input.h \
 800         linux/joystick.h \
 801         linux/ucdrom.h \
 802         net/if.h \
 803         netdb.h \
 804         netinet/in.h \
 805         netinet/in_systm.h \
 806         netinet/ip.h \
 807         netinet/tcp.h \
 808         pty.h \
 809         resolv.h \
 810         sched.h \
 811         socket.h \
 812         strings.h \
 813         sys/cdio.h \
 814         sys/errno.h \
 815         sys/file.h \
 816         sys/filio.h \
 817         sys/ipc.h \
 818         sys/lwp.h \
 819         sys/mman.h \
 820         sys/modem.h \
 821         sys/mount.h \
 822         sys/msg.h \
 823         sys/param.h \
 824         sys/ptrace.h \
 825         sys/reg.h \
 826         sys/signal.h \
 827         sys/shm.h \
 828         sys/socket.h \
 829         sys/sockio.h \
 830         sys/statfs.h \
 831         sys/strtio.h \
 832         sys/syscall.h \
 833         sys/user.h \
 834         sys/wait.h \
 835         sys/v86.h \
 836         sys/v86intr.h \
 837         sys/vfs.h \
 838         sys/vm86.h \
 839         syscall.h \
 840         ucontext.h \
 841 )
 842 AC_HEADER_STAT()
 843
 844 dnl **** Check for types ****
 845
 846 AC_C_CONST()
 847 AC_C_INLINE()
 848 AC_TYPE_SIZE_T()
 849 AC_CHECK_SIZEOF(long long,0)
 850
 851 AC_CACHE_CHECK("whether linux/input.h is for real",
 852         wine_cv_linux_input_h,
 853         AC_TRY_COMPILE([
 854             #include <linux/input.h>
 855         ] , [
 856             int foo = EVIOCGBIT(EV_ABS,42);
 857             int bar = BTN_PINKIE;
 858             int fortytwo = 42;
 859         ],
 860         wine_cv_linux_input_h=yes,
 861         wine_cv_linux_input_h=no,
 862         no
 863         )
 864     )
 865     if test "$wine_cv_linux_input_h" = "yes"
 866     then
 867         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H)
 868     fi
 869
 870
 871 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
 872         wine_cv_linux_gethostbyname_r_6,
 873         AC_TRY_COMPILE([
 874 #include <netdb.h>
 875         ], [
 876     char *name=NULL;
 877     struct hostent he;
 878     struct hostent *result;
 879     char *buf=NULL;
 880     int bufsize=0;
 881     int res,errnr;
 882     char *addr=NULL;
 883     int addrlen=0;
 884     int addrtype=0;
 885     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 886     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 887     ],
 888         wine_cv_linux_gethostbyname_r_6=yes,
 889         wine_cv_linux_gethostbyname_r_6=no
 890         )
 891    )
 892    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 893    then
 894       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6)
 895    fi
 896
 897 if test "$ac_cv_header_linux_joystick_h" = "yes"
 898 then
 899    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 900         wine_cv_linux_joystick_22_api,
 901         AC_TRY_COMPILE([
 902         #include <sys/ioctl.h>
 903         #include <linux/joystick.h>
 904
 905         struct js_event blub;
 906         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 907         #error "no 2.2 header"
 908         #endif
 909         ],/*empty*/,
 910         wine_cv_linux_joystick_22_api=yes,
 911         wine_cv_linux_joystick_22_api=no,
 912         wine_cv_linux_joystick_22_api=no
 913         )
 914    )
 915    if test "$wine_cv_linux_joystick_22_api" = "yes"
 916    then
 917       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 918    fi
 919 fi
 920
 921 dnl **** statfs checks ****
 922
 923 if test "$ac_cv_header_sys_vfs_h" = "yes"
 924 then
 925     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 926                     wine_cv_sys_vfs_has_statfs,
 927         AC_TRY_COMPILE([
 928         #include <sys/types.h>
 929         #ifdef HAVE_SYS_PARAM_H
 930         # include <sys/param.h>
 931         #endif
 932         #include <sys/vfs.h>
 933         ],[
 934                 struct statfs stfs;
 935
 936                 memset(&stfs,0,sizeof(stfs));
 937         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 938         )
 939     )
 940     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 941     then
 942       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 943     fi
 944 fi
 945
 946 if test "$ac_cv_header_sys_statfs_h" = "yes"
 947 then
 948     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 949                     wine_cv_sys_statfs_has_statfs,
 950         AC_TRY_COMPILE([
 951         #include <sys/types.h>
 952         #ifdef HAVE_SYS_PARAM_H
 953         # include <sys/param.h>
 954         #endif
 955         #include <sys/statfs.h>
 956         ],[
 957                 struct statfs stfs;
 958         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 959         )
 960     )
 961     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 962     then
 963       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 964     fi
 965 fi
 966
 967 if test "$ac_cv_header_sys_mount_h" = "yes"
 968 then
 969     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 970                     wine_cv_sys_mount_has_statfs,
 971         AC_TRY_COMPILE([
 972         #include <sys/types.h>
 973         #ifdef HAVE_SYS_PARAM_H
 974         # include <sys/param.h>
 975         #endif
 976         #include <sys/mount.h>
 977         ],[
 978                 struct statfs stfs;
 979         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 980         )
 981     )
 982     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 983     then
 984       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 985     fi
 986 fi
 987
 988 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 989
 990 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 991   [ if test "x$statfs_bfree" = "xno"
 992     then
 993         wine_cv_statfs_bfree=no
 994     else
 995         AC_TRY_COMPILE([
 996         #include <sys/types.h>
 997         #ifdef HAVE_SYS_PARAM_H
 998         # include <sys/param.h>
 999         #endif
1000         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1001         # include <sys/mount.h>
1002         #else
1003         # ifdef STATFS_DEFINED_BY_SYS_VFS
1004         #  include <sys/vfs.h>
1005         # else
1006         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1007         #   include <sys/statfs.h>
1008         #  endif
1009         # endif
1010         #endif
1011         ],[
1012                 struct statfs stfs;
1013
1014                 stfs.f_bfree++;
1015         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1016         )
1017     fi ] )
1018 if test "$wine_cv_statfs_bfree" = "yes"
1019 then
1020   AC_DEFINE(STATFS_HAS_BFREE)
1021 fi
1022
1023 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
1024   [ if test "x$statfs_bavail" = "xno"
1025     then
1026         wine_cv_statfs_bavail=no
1027     else
1028         AC_TRY_COMPILE([
1029         #include <sys/types.h>
1030         #ifdef HAVE_SYS_PARAM_H
1031         # include <sys/param.h>
1032         #endif
1033         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1034         # include <sys/mount.h>
1035         #else
1036         # ifdef STATFS_DEFINED_BY_SYS_VFS
1037         #  include <sys/vfs.h>
1038         # else
1039         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1040         #   include <sys/statfs.h>
1041         #  endif
1042         # endif
1043         #endif
1044         ],[
1045                 struct statfs stfs;
1046
1047                 stfs.f_bavail++;
1048         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1049         )
1050     fi ] )
1051 if test "$wine_cv_statfs_bavail" = "yes"
1052 then
1053   AC_DEFINE(STATFS_HAS_BAVAIL)
1054 fi
1055
1056 dnl *** check for file descriptor passing with msg_accrights
1057
1058 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1059  AC_TRY_COMPILE([#include <sys/types.h>
1060 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1061                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1062 if test "$ac_cv_c_msg_accrights" = "yes"
1063 then
1064     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
1065 fi
1066
1067 dnl *** Check for the sun_len member in struct sockaddr_un
1068
1069 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
1070  AC_TRY_COMPILE([#include <sys/types.h>
1071 #include <sys/socket.h>
1072 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1073                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
1074 if test "$ac_cv_c_sun_len" = "yes"
1075 then
1076     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
1077 fi
1078
1079 dnl *** check for the need to define __i386__
1080
1081 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1082  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1083 yes
1084 #endif],
1085  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1086 if test "$ac_cv_cpp_def_i386" = "yes"
1087 then
1088     CFLAGS="$CFLAGS -D__i386__"
1089     LINTFLAGS="$LINTFLAGS -D__i386__"
1090 fi
1091
1092 dnl $GCC is set by autoconf
1093 GCC_NO_BUILTIN=""
1094 if test "$GCC" = "yes"
1095 then
1096     GCC_NO_BUILTIN="-fno-builtin"
1097 fi
1098 AC_SUBST(GCC_NO_BUILTIN)
1099
1100 dnl **** Generate output files ****
1101
1102 AC_OUTPUT_COMMANDS([
1103 extra_subdirs="\
1104 dlls/ddraw/d3ddevice \
1105 dlls/ddraw/dclipper \
1106 dlls/ddraw/ddraw \
1107 dlls/ddraw/direct3d \
1108 dlls/ddraw/dpalette \
1109 dlls/ddraw/dsurface \
1110 dlls/dinput/joystick \
1111 dlls/dinput/keyboard \
1112 dlls/dinput/mouse \
1113 dlls/kernel/messages \
1114 dlls/user/resources \
1115 "
1116 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1117
1118 MAKE_RULES=Make.rules
1119 AC_SUBST_FILE(MAKE_RULES)
1120
1121 MAKE_DLL_RULES=dlls/Makedll.rules
1122 AC_SUBST_FILE(MAKE_DLL_RULES)
1123
1124 MAKE_PROG_RULES=programs/Makeprog.rules
1125 AC_SUBST_FILE(MAKE_PROG_RULES)
1126
1127 AC_OUTPUT([
1128 Make.rules
1129 dlls/Makedll.rules
1130 programs/Makeprog.rules
1131 Makefile
1132 console/Makefile
1133 controls/Makefile
1134 debugger/Makefile
1135 dlls/Makefile
1136 dlls/advapi32/Makefile
1137 dlls/avifil32/Makefile
1138 dlls/comctl32/Makefile
1139 dlls/commdlg/Makefile
1140 dlls/crtdll/Makefile
1141 dlls/dciman32/Makefile
1142 dlls/ddraw/Makefile
1143 dlls/dinput/Makefile
1144 dlls/dplay/Makefile
1145 dlls/dplayx/Makefile
1146 dlls/dsound/Makefile
1147 dlls/gdi/Makefile
1148 dlls/icmp/Makefile
1149 dlls/imagehlp/Makefile
1150 dlls/imm32/Makefile
1151 dlls/kernel/Makefile
1152 dlls/lzexpand/Makefile
1153 dlls/mpr/Makefile
1154 dlls/msacm/Makefile
1155 dlls/msnet32/Makefile
1156 dlls/msvcrt/Makefile
1157 dlls/msvideo/Makefile
1158 dlls/ntdll/Makefile
1159 dlls/odbc32/Makefile
1160 dlls/ole32/Makefile
1161 dlls/oleaut32/Makefile
1162 dlls/olecli/Makefile
1163 dlls/oledlg/Makefile
1164 dlls/olepro32/Makefile
1165 dlls/olesvr/Makefile
1166 dlls/opengl32/Makefile
1167 dlls/psapi/Makefile
1168 dlls/rasapi32/Makefile
1169 dlls/richedit/Makefile
1170 dlls/rpcrt4/Makefile
1171 dlls/serialui/Makefile
1172 dlls/setupapi/Makefile
1173 dlls/shdocvw/Makefile
1174 dlls/shell32/Makefile
1175 dlls/shfolder/Makefile
1176 dlls/shlwapi/Makefile
1177 dlls/tapi32/Makefile
1178 dlls/ttydrv/Makefile
1179 dlls/urlmon/Makefile
1180 dlls/user/Makefile
1181 dlls/version/Makefile
1182 dlls/win32s/Makefile
1183 dlls/winaspi/Makefile
1184 dlls/winedos/Makefile
1185 dlls/wineps/Makefile
1186 dlls/wininet/Makefile
1187 dlls/winmm/Makefile
1188 dlls/winmm/joystick/Makefile
1189 dlls/winmm/mcianim/Makefile
1190 dlls/winmm/mciavi/Makefile
1191 dlls/winmm/mcicda/Makefile
1192 dlls/winmm/mciseq/Makefile
1193 dlls/winmm/mciwave/Makefile
1194 dlls/winmm/midimap/Makefile
1195 dlls/winmm/wavemap/Makefile
1196 dlls/winmm/wineoss/Makefile
1197 dlls/winnls/Makefile
1198 dlls/winsock/Makefile
1199 dlls/winspool/Makefile
1200 dlls/wintrust/Makefile
1201 dlls/wow32/Makefile
1202 dlls/wsock32/Makefile
1203 dlls/x11drv/Makefile
1204 documentation/Makefile
1205 documentation/wine.conf.man
1206 documentation/wine.man
1207 files/Makefile
1208 graphics/Makefile
1209 graphics/enhmetafiledrv/Makefile
1210 graphics/metafiledrv/Makefile
1211 graphics/win16drv/Makefile
1212 graphics/x11drv/Makefile
1213 if1632/Makefile
1214 include/Makefile
1215 library/Makefile
1216 libtest/Makefile
1217 loader/Makefile
1218 loader/dos/Makefile
1219 loader/ne/Makefile
1220 memory/Makefile
1221 misc/Makefile
1222 miscemu/Makefile
1223 msdos/Makefile
1224 objects/Makefile
1225 ole/Makefile
1226 programs/Makefile
1227 programs/avitools/Makefile
1228 programs/clock/Makefile
1229 programs/cmdlgtst/Makefile
1230 programs/control/Makefile
1231 programs/notepad/Makefile
1232 programs/osversioncheck/Makefile
1233 programs/progman/Makefile
1234 programs/regapi/Makefile
1235 programs/regtest/Makefile
1236 programs/uninstaller/Makefile
1237 programs/view/Makefile
1238 programs/wcmd/Makefile
1239 programs/winemine/Makefile
1240 programs/winetest/Makefile
1241 programs/winhelp/Makefile
1242 programs/winver/Makefile
1243 relay32/Makefile
1244 scheduler/Makefile
1245 server/Makefile
1246 tools/Makefile
1247 tools/cvdump/Makefile
1248 tools/specmaker/Makefile
1249 tools/winebuild/Makefile
1250 tools/winelauncher
1251 tools/wmc/Makefile
1252 tools/wrc/Makefile
1253 tsx11/Makefile
1254 unicode/Makefile
1255 win32/Makefile
1256 windows/Makefile
1257 windows/x11drv/Makefile ])
1258
1259 if test "$have_x" = "no"
1260 then
1261   echo
1262   echo "*** Warning: X development files not found. Wine will be built without"
1263   echo "*** X support, which currently does not work, and would probably not be"
1264   echo "*** what you want anyway. You will need to install devel packages of"
1265   echo "*** Xlib/Xfree86 and Xpm at the very least."
1266 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1267 then
1268   echo
1269   echo "*** Warning: Xpm development files not found. Wine will be built without"
1270   echo "*** Xpm support, which currently does not work. You will need to install"
1271   echo "*** devel packages of Xpm."
1272 fi
1273
1274 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1275 then
1276   echo
1277   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1278   echo "*** terminal resize support. Consider upgrading ncurses."
1279 fi
1280
1281 if test "$wine_cv_libc_reentrant" = "no"
1282 then
1283   echo
1284   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1285   echo "*** thread support. Consider upgrading libc to a more recent"
1286   echo "*** reentrant version of libc."
1287 fi
1288
1289 if test "$wine_cv_opengl_version_OK" = "no"
1290 then
1291   echo
1292   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1293   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1294 fi
1295
1296 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1297 then
1298   echo
1299   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1300   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1301   echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1302   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1303 fi
1304
1305 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1306 then
1307   echo
1308   echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1309   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1310   echo "*** support before reporting bugs."
1311 fi
1312
1313 if test "$wine_cv_warn_cups_h" = "yes"
1314 then
1315   echo
1316   echo "*** Note: You have cups runtime libraries, but no development"
1317   echo "*** libraries. Install the cups-devel package or whichever package"
1318   echo "*** contains cups.h to enable CUPS support in WINE."
1319 fi
1320
1321 echo
1322 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1323 echo
1324
1325 dnl Local Variables:
1326 dnl comment-start: "dnl "
1327 dnl comment-end: ""
1328 dnl comment-start-skip: "\\bdnl\\b\\s *"
1329 dnl compile-command: "autoconf"
1330 dnl End: