configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 dnl Ported to autoconf 2.5x by bero@redhat.com
   5 AC_REVISION([configure.in 1.00])
   6 AC_INIT(controls/edit.c)
   7 AC_CONFIG_HEADER(include/config.h)
   8 AC_CONFIG_AUX_DIR(tools)
   9
  10 dnl **** Command-line arguments ****
  11
  12 dnl Default values
  13 LIBEXT=so       # library type .so or .a
  14 TRACE_MSGS=yes  # the TRACE() macro
  15 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  16 CURSES=yes
  17 OPENGL=normal
  18
  19 AC_ARG_ENABLE(debug,
  20 [  --disable-debug         compile out all debugging messages],
  21 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  22
  23 AC_ARG_ENABLE(opengl,
  24 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe via pthread],
  25 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  26
  27 AC_ARG_ENABLE(trace,
  28 [  --disable-trace         compile out TRACE messages],
  29 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  30
  31 AC_ARG_WITH(curses,
  32 [  --without-curses        do not use curses],
  33 [if test "$withval" = "no"; then CURSES="no"; fi])
  34
  35 AC_ARG_WITH(reentrant-x,
  36 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  37
  38 AC_SUBST(OPTIONS)
  39
  40 if test "$DEBUG_MSGS" = "no"
  41 then
  42     OPTIONS="$OPTIONS -DNO_DEBUG_MSGS"
  43 fi
  44
  45 if test "$TRACE_MSGS" = "no" -o "$DEBUG_MSGS" = "no"
  46 then
  47     OPTIONS="$OPTIONS -DNO_TRACE_MSGS"
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_PROG_RANLIB
  66 AC_PROG_INSTALL
  67 AC_PROG_LN_S
  68 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  69 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  70 AC_CYGWIN
  71 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  72
  73 dnl Check for lint
  74 AC_CHECK_PROGS(LINT, lclint lint)
  75 if test "$LINT" = "lint"
  76 then
  77   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  78   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  79 fi
  80 AC_SUBST(LINT)
  81 AC_SUBST(LINTFLAGS)
  82
  83 if test "$CYGWIN" = "yes"
  84 then
  85     LDCOMBINE="ld -r --enable-stdcall-fixup"
  86 else
  87     LDCOMBINE="ld -r"
  88 fi
  89 AC_SUBST(LDCOMBINE)
  90
  91 dnl **** Check for some libraries ****
  92
  93 dnl Check for -lm
  94 AC_CHECK_LIB(m,sqrt)
  95 dnl Check for -li386 for NetBSD and OpenBSD
  96 AC_CHECK_LIB(i386,i386_set_ldt)
  97 dnl Check for -lossaudio for NetBSD
  98 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  99 dnl Check for -lw for Solaris
 100 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 101 dnl Check for -lnsl for Solaris
 102 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 103 dnl Check for -lsocket for Solaris
 104 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 105 dnl Check for -lxpg4 for FreeBSD
 106 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 107 dnl Check for -lmmap for OS/2
 108 AC_CHECK_LIB(mmap,mmap)
 109
 110 dnl Check for openpty
 111 UTILLIBS=""
 112 AC_SUBST(UTILLIBS)
 113 AC_CHECK_FUNCS(openpty,,
 114         [AC_CHECK_LIB(util,openpty,
 115                 [AC_DEFINE(HAVE_OPENPTY)
 116                 UTILLIBS="-lutil"]
 117         )])
 118
 119 DLLIBS=""
 120 AC_SUBST(DLLIBS)
 121 AC_CHECK_HEADERS(dlfcn.h,
 122     [AC_CHECK_FUNCS(dlopen,,
 123         [AC_CHECK_LIB(dl,dlopen,
 124                      [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 125                      DLLIBS="-ldl"],
 126                      LIBEXT="a")]
 127         )],
 128         LIBEXT="a"
 129     )
 130
 131 JPEGLIB=""
 132 AC_SUBST(JPEGLIB)
 133 AC_CHECK_HEADERS(jpeglib.h,
 134     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 135         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 136         JPEGLIB="-ljpeg"
 137     )
 138 )
 139
 140
 141 AC_SUBST(XLIB)
 142 AC_SUBST(XFILES)
 143 XFILES=""
 144 AC_SUBST(OPENGLFILES)
 145 OPENGLFILES=""
 146 AC_SUBST(GLU32FILES)
 147 GLU32FILES=""
 148 if test "$have_x" = "yes"
 149 then
 150     XLIB="-lXext -lX11"
 151     ac_save_CPPFLAGS="$CPPFLAGS"
 152     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 153
 154     dnl *** All of the following tests require X11/Xlib.h
 155     AC_CHECK_HEADERS(X11/Xlib.h,
 156       [
 157         dnl *** Check for X keyboard extension
 158         AC_CHECK_HEADERS(X11/XKBlib.h,
 159             [ dnl *** If X11/XKBlib.h exists...
 160               AC_CHECK_LIB(X11, XkbQueryExtension,
 161               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 162               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 163             ],
 164             AC_MSG_WARN([XKB extension not found!!])
 165         )
 166
 167         dnl *** Check for X Shm extension
 168         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 169             [ dnl *** If X11/extensions/XShm.h exists...
 170               AC_CHECK_LIB(Xext, XShmQueryExtension,
 171               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 172               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 173             ],
 174             AC_MSG_WARN([Xshm extension not found!!])
 175         )
 176
 177         dnl *** Check for X shape extension
 178         AC_CHECK_HEADERS(X11/extensions/shape.h,
 179             [ dnl *** If X11/extensions/shape.h exists...
 180               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 181               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 182               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 183             ],
 184             AC_MSG_WARN([XShape extension not found!!])
 185         )
 186
 187         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 188         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 189             [ dnl *** If X11/extensions/xf86dga.h exists, check
 190               dnl *** for XDGAQueryExtension()...
 191               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 192                 [ dnl *** If found...
 193                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 194                             [Define if you have the Xxf86dga library version 2])
 195                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 196                ],
 197                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 198                   dnl *** instead (DGA 2.0 not found)...
 199                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 200                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 201                                 [Define if you have the Xxf86dga library version 1])
 202                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 203                     ],,
 204                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 205                   )
 206                 ],
 207                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 208               )
 209             ],
 210             AC_MSG_WARN([DGA extension not found!!])
 211         )
 212
 213         dnl *** Check for XFree86 VMODE extension
 214         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 215             [ dnl *** If X11/extensions/xf86vmode.h exists...
 216                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 217                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 218                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 219                   ],,
 220                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 221                 )
 222             ],
 223             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 224         )
 225
 226         dnl *** Check for XVideo extension supporting XvImages
 227         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 228             [ dnl *** If X11/extensions/Xvlib.h exists...
 229                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 230                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 231                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 232                   ],,
 233                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 234                 )
 235             ],
 236             AC_MSG_WARN([XVideo extension not found !!])
 237         )
 238
 239         dnl *** Check for XRender extension
 240         AC_CHECK_HEADERS(X11/extensions/Xrender.h,
 241             [ dnl *** If X11/extensions/Xrender.h exists...
 242                 AC_CHECK_LIB(Xrender, XRenderQueryExtension,
 243                   [ AC_DEFINE(HAVE_LIBXRENDER, 1, [Define if you have the XRender extension library])
 244                      X_PRE_LIBS="$X_PRE_LIBS -lXrender"
 245                   ],,
 246                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 247                 )
 248             ],
 249             AC_MSG_WARN([XRender extension not found !!])
 250         )
 251
 252       ]
 253     ) dnl *** End of X11/Xlib.h check
 254
 255     dnl Check for the presence of OpenGL
 256     if test $OPENGL = "yes" -o $OPENGL = "normal"
 257     then
 258         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 259         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 260         then
 261             dnl Check for some problems due to old Mesa versions
 262             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 263               AC_TRY_COMPILE(
 264                 [#include <GL/gl.h>],
 265                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 266                 [wine_cv_opengl_version_OK="yes"],
 267                 [wine_cv_opengl_version_OK="no"]
 268               )
 269             )
 270
 271             dnl Check for the thread-safety of the OpenGL library
 272             AC_CACHE_CHECK([for thread-safe OpenGL version],
 273                            wine_cv_opengl_version_threadsafe,
 274               [saved_libs=$LIBS
 275                LIBS="$X_LIBS -lGL"
 276                AC_TRY_LINK([],[pthread_getspecific();],
 277                               [wine_cv_opengl_version_threadsafe="yes"],
 278                               [wine_cv_opengl_version_threadsafe="no"])
 279                LIBS=$saved_libs]
 280             )
 281
 282             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 283             then
 284                 dnl Check for the presence of the library
 285                 AC_CHECK_LIB(GL,glXCreateContext,
 286                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 287                              ,,
 288                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 289
 290                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 291                 then
 292
 293                         OPENGLFILES='$(OPENGLFILES)'
 294                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 295
 296                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 297                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 298                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 299                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 300
 301                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 302                         then
 303                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 304                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 305                                                   #ifdef HAVE_GL_GLEXT_H
 306                                                   # include <GL/glext.h>
 307                                                   #endif
 308                                                   ],
 309                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 310                                                  [wine_cv_extension_prototypes="yes"],
 311                                                  [wine_cv_extension_prototypes="no"]
 312                                   )]
 313                                 )
 314                                 if test $wine_cv_extension_prototypes = "yes"
 315                                 then
 316                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 317                                               [Define if the OpenGL headers define extension typedefs])
 318                                 fi
 319                         fi
 320
 321                 fi
 322                 dnl Check for GLU32 library.
 323                 AC_CHECK_LIB(GLU,gluLookAt,
 324                              [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
 325                              GLU32FILES='$(GLU32FILES)']
 326                              ,,
 327                              $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 328                 )
 329              fi
 330          fi
 331     fi
 332
 333     CPPFLAGS="$ac_save_CPPFLAGS"
 334     XFILES='$(XFILES)'
 335 else
 336     XLIB=""
 337     X_CFLAGS=""
 338     X_LIBS=""
 339 fi
 340
 341 dnl **** Check which curses lib to use ***
 342 CURSESLIBS=""
 343 if test "$CURSES" = "yes"
 344 then
 345     AC_CHECK_HEADERS(ncurses.h,
 346         [AC_CHECK_LIB(ncurses,waddch,
 347             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 348              CURSESLIBS="-lncurses"],
 349              [AC_CHECK_HEADERS(curses.h,
 350                  [AC_CHECK_LIB(curses,waddch,
 351                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 352                       CURSESLIBS="-lcurses"])])])])
 353     saved_libs="$LIBS"
 354     LIBS="$CURSESLIBS $LIBS"
 355     AC_CHECK_FUNCS(getbkgd resizeterm)
 356     LIBS="$saved_libs"
 357 fi
 358 AC_SUBST(CURSESLIBS)
 359
 360 CUPSLIBS=""
 361 dnl **** Check for CUPS ****
 362 wine_cv_warn_cups_h=no
 363 AC_CHECK_LIB(cups,cupsGetPPD,
 364         [AC_CHECK_HEADER(cups/cups.h,
 365             [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
 366             CUPSLIBS="-lcups"],
 367             wine_cv_warn_cups_h=yes)]
 368 )
 369 AC_SUBST(CUPSLIBS)
 370
 371 dnl **** Check for FreeType 2 ****
 372 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 373 if test "$ft_lib" = "no"
 374 then
 375     FREETYPELIBS=""
 376     FREETYPEINCL=""
 377     wine_cv_msg_freetype=no
 378 else
 379     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 380     if test "$ft_devel" = "no"
 381     then
 382         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 383         if test "$ft_devel2" = "freetype2-config"
 384         then
 385                 ft_devel=$ft_devel2
 386         fi
 387     fi
 388     if test "$ft_devel" = "no"
 389     then
 390         FREETYPELIBS=""
 391         FREETYPEINCL=""
 392         wine_cv_msg_freetype=yes
 393     else
 394         AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 395         FREETYPELIBS=`$ft_devel --libs`
 396         FREETYPEINCL=`$ft_devel --cflags`
 397         ac_save_CPPFLAGS="$CPPFLAGS"
 398         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 399         AC_CHECK_HEADERS(freetype/freetype.h \
 400                          freetype/ftglyph.h \
 401                          freetype/tttables.h \
 402                          freetype/ftnames.h \
 403                          freetype/ftsnames.h \
 404                          freetype/ttnameid.h \
 405                          freetype/ftoutln.h \
 406                          freetype/internal/sfnt.h)
 407         CPPFLAGS="$ac_save_CPPFLAGS"
 408         wine_cv_msg_freetype=no
 409     fi
 410 fi
 411 AC_SUBST(FREETYPELIBS)
 412 AC_SUBST(FREETYPEINCL)
 413
 414 dnl **** Check for parport (currently Linux only) ****
 415 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 416  AC_TRY_COMPILE(
 417    [#include <linux/ppdev.h>],
 418    [ioctl (1,PPCLAIM,0)],
 419    [ac_cv_c_ppdev="yes"],
 420    [ac_cv_c_ppdev="no"])
 421  )
 422 if test "$ac_cv_c_ppdev" = "yes"
 423 then
 424     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 425 fi
 426
 427 dnl **** Check for IPX (currently Linux only) ****
 428 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
 429  AC_TRY_COMPILE(
 430    [#include <sys/socket.h>
 431     #include <netipx/ipx.h>],
 432    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 433    [ac_cv_c_ipx_gnu="yes"],
 434    [ac_cv_c_ipx_gnu="no"])
 435  )
 436 if test "$ac_cv_c_ipx_gnu" = "yes"
 437 then
 438     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
 439 fi
 440
 441 if test "$ac_cv_c_ipx_gnu" = "no"
 442 then
 443  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
 444   AC_TRY_COMPILE(
 445     [#include <sys/socket.h>
 446      #include <asm/types.h>
 447      #include <linux/ipx.h>],
 448     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 449     [ac_cv_c_ipx_linux="yes"],
 450     [ac_cv_c_ipx_linux="no"])
 451   )
 452   if test "$ac_cv_c_ipx_linux" = "yes"
 453   then
 454       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
 455   fi
 456 fi
 457
 458 dnl **** Check for Open Sound System ****
 459 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 460
 461 AC_CACHE_CHECK([for Open Sound System],
 462         ac_cv_c_opensoundsystem,
 463         AC_TRY_COMPILE([
 464         #if defined(HAVE_SYS_SOUNDCARD_H)
 465                 #include <sys/soundcard.h>
 466         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 467                 #include <machine/soundcard.h>
 468         #elif defined(HAVE_SOUNDCARD_H)
 469                 #include <soundcard.h>
 470         #endif
 471         ],[
 472
 473 /* check for one of the Open Sound System specific SNDCTL_ defines */
 474 #if !defined(SNDCTL_DSP_STEREO)
 475 #error No open sound system
 476 #endif
 477 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 478
 479 if test "$ac_cv_c_opensoundsystem" = "yes"
 480 then
 481     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 482 fi
 483
 484 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 485         ac_cv_c_opensoundsystem_midi,
 486         AC_TRY_COMPILE([
 487         #if defined(HAVE_SYS_SOUNDCARD_H)
 488                 #include <sys/soundcard.h>
 489         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 490                 #include <machine/soundcard.h>
 491         #elif defined(HAVE_SOUNDCARD_H)
 492                 #include <soundcard.h>
 493         #endif
 494         ],[
 495
 496 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 497 #if !defined(SNDCTL_SEQ_SYNC)
 498 #error No open sound system MIDI interface
 499 #endif
 500 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 501
 502 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 503 then
 504     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 505 fi
 506
 507 dnl **** If ln -s doesn't work, use cp instead ****
 508 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 509
 510 dnl **** Check for broken glibc mmap64 ****
 511
 512 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 513         AC_TRY_RUN([
 514                 #define _FILE_OFFSET_BITS 64
 515                 #include <stdio.h>
 516                 #include <unistd.h>
 517                 #include <fcntl.h>
 518                 #include <sys/mman.h>
 519                 #include <errno.h>
 520
 521                 int main(int argc,char **argv) {
 522                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 523                         if (fd == -1) exit(1);
 524
 525                         unlink("conftest.map");
 526
 527                         write(fd,"test",4);
 528
 529                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 530                             (errno == EINVAL)
 531                         ) {
 532                                 exit(1);
 533                         }
 534                         close(fd);
 535                         fprintf(stderr,"success!\n");
 536                         exit(0);
 537                 }
 538
 539         ],
 540     ac_cv_mmap64_works="yes",
 541     ac_cv_mmap64_works="no",
 542     ac_cv_mmap64_works="no") )
 543
 544 if test "$ac_cv_mmap64_works" = "yes"
 545 then
 546     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 547 fi
 548
 549 dnl **** Check for gcc strength-reduce bug ****
 550
 551 if test "x${GCC}" = "xyes"
 552 then
 553   CFLAGS="$CFLAGS -Wall"
 554   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 555                   AC_TRY_RUN([
 556 int     L[[4]] = {0,1,2,3};
 557 int main(void) {
 558   static int Array[[3]];
 559   unsigned int B = 3;
 560   int i;
 561   for(i=0; i<B; i++) Array[[i]] = i - 3;
 562   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 563   L[[i]] = 4;
 564
 565   exit( Array[[1]] != -2 || L[[2]] != 3);
 566 }],
 567     ac_cv_c_gcc_strength_bug="no",
 568     ac_cv_c_gcc_strength_bug="yes",
 569     ac_cv_c_gcc_strength_bug="yes") )
 570   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 571   then
 572     CFLAGS="$CFLAGS -fno-strength-reduce"
 573   fi
 574
 575   dnl Check for -mpreferred-stack-boundary
 576   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support],
 577                  ac_cv_c_gcc_stack_boundary,
 578   [saved_cflags=$CFLAGS
 579   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 580   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 581   CFLAGS=$saved_cflags
 582   ])
 583   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 584   then
 585     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 586   fi
 587 fi
 588
 589 dnl **** Check if we need to place .type inside a .def directive ****
 590
 591 AC_CACHE_CHECK([whether .type must sit inside a .def directive],
 592                ac_cv_c_type_in_def,
 593 [saved_libs=$LIBS
 594 LIBS="conftest_asm.s $LIBS"
 595 cat > conftest_asm.s <<EOF
 596         .globl _ac_test
 597         .def _ac_test; .scl 2; .type 32; .endef
 598 _ac_test:
 599         .long 0
 600 EOF
 601 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 602 LIBS=$saved_libs])
 603 if test "$ac_cv_c_type_in_def" = "yes"
 604 then
 605   AC_DEFINE(NEED_TYPE_IN_DEF, 1, [Define if .type asm directive must be inside a .def directive])
 606 fi
 607
 608 dnl **** Check for underscore on external symbols ****
 609
 610 AC_CACHE_CHECK([whether external symbols need an underscore prefix],
 611                ac_cv_c_extern_prefix,
 612 [saved_libs=$LIBS
 613 LIBS="conftest_asm.s $LIBS"
 614 cat > conftest_asm.s <<EOF
 615         .globl _ac_test
 616 _ac_test:
 617         .long 0
 618 EOF
 619 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 620             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 621 LIBS=$saved_libs])
 622 if test "$ac_cv_c_extern_prefix" = "yes"
 623 then
 624   AC_DEFINE(NEED_UNDERSCORE_PREFIX, 1,
 625             [Define if symbols declared in assembly code need an underscore prefix])
 626 fi
 627
 628 dnl **** Check for .string in assembler ****
 629
 630 AC_CACHE_CHECK([whether assembler accepts .string],
 631                ac_cv_c_asm_string,
 632 [saved_libs=$LIBS
 633 LIBS="conftest_asm.s $LIBS"
 634 cat > conftest_asm.s <<EOF
 635         .string "test"
 636 EOF
 637 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 638 LIBS=$saved_libs])
 639 if test "$ac_cv_c_asm_string" = "yes"
 640 then
 641   AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
 642 fi
 643
 644 dnl **** Check for working dll ****
 645
 646 LDSHARED=""
 647 LDDLLFLAGS=""
 648 if test "$LIBEXT" = "so"
 649 then
 650   AC_CACHE_CHECK([whether we can build a GNU style ELF dll],
 651                  ac_cv_c_dll_gnuelf,
 652   [saved_cflags=$CFLAGS
 653   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 654   AC_TRY_LINK(,[return 1],ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")
 655   CFLAGS=$saved_cflags
 656   ])
 657   if test "$ac_cv_c_dll_gnuelf" = "yes"
 658   then
 659     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 660     LDDLLFLAGS="-Wl,-Bsymbolic"
 661   else
 662     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 663                  ac_cv_c_dll_unixware,
 664     [saved_cflags=$CFLAGS
 665     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 666     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 667     CFLAGS=$saved_cflags
 668     ])
 669     if test "$ac_cv_c_dll_unixware" = "yes"
 670     then
 671       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 672       LDDLLFLAGS="-Wl,-B,symbolic"
 673     fi
 674   fi
 675   if test "$ac_cv_c_dll_gnuelf" = "no" -a "$ac_cv_c_dll_unixware" = "no"
 676   then
 677     LIBEXT="a"
 678     if test "$DLLWRAP" = "dllwrap"; then
 679       dnl FIXME - check whether dllwrap works correctly...
 680       if test "$CYGWIN" = "yes"; then
 681         echo "*** use dllwrap for building shared library."
 682         LIBEXT="dll"
 683       fi
 684     fi
 685   fi
 686 fi
 687
 688 if test "$LIBEXT" = "a"; then
 689   echo "*** It is currently not possible to build WINE without shared"
 690   echo "*** library (.so) support to allow transparent switch between .so"
 691   echo "*** and .dll files."
 692   echo "*** If you are using Linux, you will need a newer binutils."
 693   exit 1
 694 fi
 695
 696 DLLFLAGS=""
 697 LDPATH=""
 698
 699 if test "$LIBEXT" = "so"; then
 700     DLLFLAGS="-fPIC"
 701     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 702 elif test "$LIBEXT" = "dll"; then
 703     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 704     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 705 fi
 706
 707 AC_SUBST(DLLFLAGS)
 708 AC_SUBST(LDSHARED)
 709 AC_SUBST(LDDLLFLAGS)
 710 AC_SUBST(LIBEXT)
 711 AC_SUBST(LDPATH)
 712
 713 dnl **** Check for reentrant libc ****
 714 dnl
 715 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 716 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 717
 718 AC_DEFUN([WINE_CHECK_ERRNO],
 719 [
 720   AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
 721   [AC_TRY_RUN([int myerrno = 0;
 722 char buf[256];
 723 int *$1(){return &myerrno;}
 724 main(){connect(0,buf,255); exit(!myerrno);}],
 725   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
 726   wine_cv_libc_r_$1=yes )
 727 ])
 728 if test "$wine_cv_libc_r_$1" = "yes"
 729 then
 730     wine_cv_libc_reentrant=$1
 731 fi
 732 ])
 733
 734 wine_cv_libc_reentrant=no
 735 dnl Linux style errno location
 736 WINE_CHECK_ERRNO(__errno_location)
 737 dnl FreeBSD style errno location
 738 WINE_CHECK_ERRNO(__error)
 739 dnl Solaris style errno location
 740 WINE_CHECK_ERRNO(___errno)
 741 dnl UnixWare style errno location
 742 WINE_CHECK_ERRNO(__thr_errno)
 743 dnl NetBSD style errno location
 744 WINE_CHECK_ERRNO(__errno)
 745
 746 if test "$wine_cv_libc_reentrant" != "no"
 747 then
 748   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
 749                      [Define to the name of the function returning errno for reentrant libc])
 750 fi
 751
 752 dnl **** Check for reentrant X libraries ****
 753 dnl
 754 dnl This may fail to determine whether X libraries are reentrant if
 755 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 756 dnl is possible with the --without-reentrant-x option.
 757
 758 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 759 then
 760 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
 761   [ if test "x$with_reentrant_x" = "xno"
 762     then
 763         wine_cv_x_reentrant=no
 764     else
 765         libX11_check=none
 766         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 767             if test -r $dir/libX11.so; then
 768                 libX11_check="-D $dir/libX11.so"
 769                 break 1
 770             fi
 771             if test -r $dir/libX11.a; then
 772                 libX11_check="$dir/libX11.a"
 773                 break 1
 774             fi
 775         done
 776         if test "$libX11_check" != "none"; then
 777             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 778             then
 779                 wine_cv_x_reentrant=yes
 780             else
 781                 wine_cv_x_reentrant=no
 782             fi
 783         else
 784             wine_cv_x_reentrant=unknown
 785         fi
 786     fi ] )
 787 else
 788     wine_cv_x_reentrant=no
 789 fi
 790 if test "$wine_cv_x_reentrant" = "no"
 791 then
 792   AC_DEFINE(NO_REENTRANT_X11, 1,
 793             [Define if X libraries are not reentrant (compiled without -D_REENTRANT)])
 794 fi
 795
 796
 797 dnl **** Check for functions ****
 798
 799 AC_FUNC_ALLOCA()
 800 AC_CHECK_FUNCS(\
 801         __libc_fork \
 802         _lwp_create \
 803         clone \
 804         ecvt \
 805         finite \
 806         fpclass \
 807         ftruncate64 \
 808         getnetbyaddr \
 809         getnetbyname \
 810         getpagesize \
 811         getprotobyname \
 812         getprotobynumber \
 813         getrlimit \
 814         getservbyport \
 815         getsockopt \
 816         inet_network \
 817         lseek64 \
 818         lstat \
 819         memmove \
 820         mmap \
 821         pread \
 822         pwrite \
 823         rfork \
 824         select \
 825         sendmsg \
 826         settimeofday \
 827         sigaltstack \
 828         statfs \
 829         strcasecmp \
 830         strerror \
 831         strncasecmp \
 832         tcgetattr \
 833         timegm \
 834         usleep \
 835         vfscanf \
 836         wait4 \
 837         waitpid \
 838 )
 839
 840 dnl **** Check for header files ****
 841
 842 AC_CHECK_HEADERS(\
 843         arpa/inet.h \
 844         arpa/nameser.h \
 845         elf.h \
 846         float.h \
 847         ieeefp.h \
 848         libio.h \
 849         libutil.h \
 850         link.h \
 851         linux/cdrom.h \
 852         linux/input.h \
 853         linux/joystick.h \
 854         linux/ucdrom.h \
 855         net/if.h \
 856         netdb.h \
 857         netinet/in.h \
 858         netinet/in_systm.h \
 859         netinet/ip.h \
 860         netinet/tcp.h \
 861         pty.h \
 862         resolv.h \
 863         sched.h \
 864         socket.h \
 865         stdint.h \
 866         strings.h \
 867         sys/cdio.h \
 868         sys/errno.h \
 869         sys/file.h \
 870         sys/filio.h \
 871         sys/ipc.h \
 872         sys/link.h \
 873         sys/lwp.h \
 874         sys/mman.h \
 875         sys/modem.h \
 876         sys/mount.h \
 877         sys/msg.h \
 878         sys/param.h \
 879         sys/ptrace.h \
 880         sys/reg.h \
 881         sys/signal.h \
 882         sys/shm.h \
 883         sys/socket.h \
 884         sys/sockio.h \
 885         sys/statfs.h \
 886         sys/strtio.h \
 887         sys/syscall.h \
 888         sys/user.h \
 889         sys/wait.h \
 890         sys/v86.h \
 891         sys/v86intr.h \
 892         sys/vfs.h \
 893         sys/vm86.h \
 894         syscall.h \
 895         ucontext.h \
 896 )
 897 AC_HEADER_STAT()
 898
 899 dnl **** Check for types ****
 900
 901 AC_C_CONST()
 902 AC_C_INLINE()
 903 AC_TYPE_SIZE_T()
 904 AC_CHECK_SIZEOF(long long,0)
 905
 906 AC_CACHE_CHECK([whether linux/input.h is for real],
 907         wine_cv_linux_input_h,
 908         AC_TRY_COMPILE([
 909             #include <linux/input.h>
 910         ] , [
 911             int foo = EVIOCGBIT(EV_ABS,42);
 912             int bar = BTN_PINKIE;
 913             int fortytwo = 42;
 914         ],
 915         wine_cv_linux_input_h=yes,
 916         wine_cv_linux_input_h=no,
 917         no
 918         )
 919     )
 920     if test "$wine_cv_linux_input_h" = "yes"
 921     then
 922         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
 923                   [Define if we have linux/input.h AND it contains the INPUT event API])
 924     fi
 925
 926
 927 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
 928         wine_cv_linux_gethostbyname_r_6,
 929         AC_TRY_COMPILE([
 930 #include <netdb.h>
 931         ], [
 932     char *name=NULL;
 933     struct hostent he;
 934     struct hostent *result;
 935     char *buf=NULL;
 936     int bufsize=0;
 937     int res,errnr;
 938     char *addr=NULL;
 939     int addrlen=0;
 940     int addrtype=0;
 941     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 942     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 943     ],
 944         wine_cv_linux_gethostbyname_r_6=yes,
 945         wine_cv_linux_gethostbyname_r_6=no
 946         )
 947    )
 948    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 949    then
 950       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
 951                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
 952    fi
 953
 954 if test "$ac_cv_header_linux_joystick_h" = "yes"
 955 then
 956    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
 957         wine_cv_linux_joystick_22_api,
 958         AC_TRY_COMPILE([
 959         #include <sys/ioctl.h>
 960         #include <linux/joystick.h>
 961
 962         struct js_event blub;
 963         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 964         #error "no 2.2 header"
 965         #endif
 966         ],/*empty*/,
 967         wine_cv_linux_joystick_22_api=yes,
 968         wine_cv_linux_joystick_22_api=no,
 969         wine_cv_linux_joystick_22_api=no
 970         )
 971    )
 972    if test "$wine_cv_linux_joystick_22_api" = "yes"
 973    then
 974       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
 975                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
 976    fi
 977 fi
 978
 979 dnl **** statfs checks ****
 980
 981 if test "$ac_cv_header_sys_vfs_h" = "yes"
 982 then
 983     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
 984                     wine_cv_sys_vfs_has_statfs,
 985         AC_TRY_COMPILE([
 986         #include <sys/types.h>
 987         #ifdef HAVE_SYS_PARAM_H
 988         # include <sys/param.h>
 989         #endif
 990         #include <sys/vfs.h>
 991         ],[
 992                 struct statfs stfs;
 993
 994                 memset(&stfs,0,sizeof(stfs));
 995         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 996         )
 997     )
 998     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 999     then
1000       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1001                 [Define if the struct statfs is defined by <sys/vfs.h>])
1002     fi
1003 fi
1004
1005 if test "$ac_cv_header_sys_statfs_h" = "yes"
1006 then
1007     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1008                     wine_cv_sys_statfs_has_statfs,
1009         AC_TRY_COMPILE([
1010         #include <sys/types.h>
1011         #ifdef HAVE_SYS_PARAM_H
1012         # include <sys/param.h>
1013         #endif
1014         #include <sys/statfs.h>
1015         ],[
1016                 struct statfs stfs;
1017         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1018         )
1019     )
1020     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1021     then
1022       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1023                 [Define if the struct statfs is defined by <sys/statfs.h>])
1024     fi
1025 fi
1026
1027 if test "$ac_cv_header_sys_mount_h" = "yes"
1028 then
1029     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1030                     wine_cv_sys_mount_has_statfs,
1031         AC_TRY_COMPILE([
1032         #include <sys/types.h>
1033         #ifdef HAVE_SYS_PARAM_H
1034         # include <sys/param.h>
1035         #endif
1036         #include <sys/mount.h>
1037         ],[
1038                 struct statfs stfs;
1039         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1040         )
1041     )
1042     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1043     then
1044       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1045                 [Define if the struct statfs is defined by <sys/mount.h>])
1046     fi
1047 fi
1048
1049 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1050
1051 AC_CACHE_CHECK( [for statfs.f_bfree], wine_cv_statfs_bfree,
1052   [ if test "x$statfs_bfree" = "xno"
1053     then
1054         wine_cv_statfs_bfree=no
1055     else
1056         AC_TRY_COMPILE([
1057         #include <sys/types.h>
1058         #ifdef HAVE_SYS_PARAM_H
1059         # include <sys/param.h>
1060         #endif
1061         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1062         # include <sys/mount.h>
1063         #else
1064         # ifdef STATFS_DEFINED_BY_SYS_VFS
1065         #  include <sys/vfs.h>
1066         # else
1067         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1068         #   include <sys/statfs.h>
1069         #  endif
1070         # endif
1071         #endif
1072         ],[
1073                 struct statfs stfs;
1074
1075                 stfs.f_bfree++;
1076         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1077         )
1078     fi ] )
1079 if test "$wine_cv_statfs_bfree" = "yes"
1080 then
1081   AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])
1082 fi
1083
1084 AC_CACHE_CHECK( [for statfs.f_bavail], wine_cv_statfs_bavail,
1085   [ if test "x$statfs_bavail" = "xno"
1086     then
1087         wine_cv_statfs_bavail=no
1088     else
1089         AC_TRY_COMPILE([
1090         #include <sys/types.h>
1091         #ifdef HAVE_SYS_PARAM_H
1092         # include <sys/param.h>
1093         #endif
1094         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1095         # include <sys/mount.h>
1096         #else
1097         # ifdef STATFS_DEFINED_BY_SYS_VFS
1098         #  include <sys/vfs.h>
1099         # else
1100         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1101         #   include <sys/statfs.h>
1102         #  endif
1103         # endif
1104         #endif
1105         ],[
1106                 struct statfs stfs;
1107
1108                 stfs.f_bavail++;
1109         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1110         )
1111     fi ] )
1112 if test "$wine_cv_statfs_bavail" = "yes"
1113 then
1114   AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])
1115 fi
1116
1117 dnl *** check for file descriptor passing with msg_accrights
1118
1119 AC_CACHE_CHECK([for msg_accrights in struct msghdr], ac_cv_c_msg_accrights,
1120  AC_TRY_COMPILE([#include <sys/types.h>
1121 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1122                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1123 if test "$ac_cv_c_msg_accrights" = "yes"
1124 then
1125     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])
1126 fi
1127
1128 dnl *** Check for the sa_len member in struct sockaddr
1129
1130 AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_c_sockaddr_sa_len,
1131  AC_TRY_COMPILE([#include <sys/types.h>
1132 #include <sys/socket.h>
1133 ], [static struct sockaddr addr; addr.sa_len = 1],
1134                 ac_cv_c_sockaddr_sa_len="yes", ac_cv_c_sockaddr_sa_len="no"))
1135 if test "$ac_cv_c_sockaddr_sa_len" = "yes"
1136 then
1137     AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])
1138 fi
1139
1140 dnl *** Check for the sun_len member in struct sockaddr_un
1141
1142 AC_CACHE_CHECK([for sun_len in struct sockaddr_un], ac_cv_c_sockaddr_sun_len,
1143  AC_TRY_COMPILE([#include <sys/types.h>
1144 #include <sys/socket.h>
1145 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1146                 ac_cv_c_sockaddr_sun_len="yes", ac_cv_c_sockaddr_sun_len="no"))
1147 if test "$ac_cv_c_sockaddr_sun_len" = "yes"
1148 then
1149     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])
1150 fi
1151
1152 dnl *** check for the need to define __i386__
1153
1154 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1155  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1156 yes
1157 #endif],
1158  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1159 if test "$ac_cv_cpp_def_i386" = "yes"
1160 then
1161     CFLAGS="$CFLAGS -D__i386__"
1162     LINTFLAGS="$LINTFLAGS -D__i386__"
1163 fi
1164
1165 dnl $GCC is set by autoconf
1166 GCC_NO_BUILTIN=""
1167 if test "$GCC" = "yes"
1168 then
1169     GCC_NO_BUILTIN="-fno-builtin"
1170 fi
1171 AC_SUBST(GCC_NO_BUILTIN)
1172
1173 dnl **** Generate output files ****
1174
1175 AC_DEFINE(__WINE_CONFIG_H, 1,
1176           [This must always be defined to allow checking for config.h inclusion])
1177
1178 AC_OUTPUT_COMMANDS([
1179 extra_subdirs="\
1180 dlls/ddraw/d3ddevice \
1181 dlls/ddraw/dclipper \
1182 dlls/ddraw/ddraw \
1183 dlls/ddraw/direct3d \
1184 dlls/ddraw/dpalette \
1185 dlls/ddraw/dsurface \
1186 dlls/dinput/joystick \
1187 dlls/dinput/keyboard \
1188 dlls/dinput/mouse \
1189 dlls/kernel/messages \
1190 dlls/user/dde \
1191 dlls/user/resources \
1192 dlls/wineps/data \
1193 "
1194 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1195
1196 MAKE_RULES=Make.rules
1197 AC_SUBST_FILE(MAKE_RULES)
1198
1199 MAKE_DLL_RULES=dlls/Makedll.rules
1200 AC_SUBST_FILE(MAKE_DLL_RULES)
1201
1202 MAKE_PROG_RULES=programs/Makeprog.rules
1203 AC_SUBST_FILE(MAKE_PROG_RULES)
1204
1205 AC_OUTPUT([
1206 Make.rules
1207 dlls/Makedll.rules
1208 programs/Makeprog.rules
1209 Makefile
1210 console/Makefile
1211 controls/Makefile
1212 debugger/Makefile
1213 dlls/Makefile
1214 dlls/advapi32/Makefile
1215 dlls/avicap32/Makefile
1216 dlls/avifil32/Makefile
1217 dlls/comctl32/Makefile
1218 dlls/commdlg/Makefile
1219 dlls/crtdll/Makefile
1220 dlls/dciman32/Makefile
1221 dlls/ddraw/Makefile
1222 dlls/devenum/Makefile
1223 dlls/dinput/Makefile
1224 dlls/dplay/Makefile
1225 dlls/dplayx/Makefile
1226 dlls/dsound/Makefile
1227 dlls/gdi/Makefile
1228 dlls/glu32/Makefile
1229 dlls/icmp/Makefile
1230 dlls/imagehlp/Makefile
1231 dlls/imm32/Makefile
1232 dlls/kernel/Makefile
1233 dlls/lzexpand/Makefile
1234 dlls/mapi32/Makefile
1235 dlls/mpr/Makefile
1236 dlls/msacm/Makefile
1237 dlls/msdmo/Makefile
1238 dlls/msimg32/Makefile
1239 dlls/msnet32/Makefile
1240 dlls/msrle32/Makefile
1241 dlls/msvcrt/Makefile
1242 dlls/msvideo/Makefile
1243 dlls/netapi32/Makefile
1244 dlls/ntdll/Makefile
1245 dlls/odbc32/Makefile
1246 dlls/ole32/Makefile
1247 dlls/oleaut32/Makefile
1248 dlls/olecli/Makefile
1249 dlls/oledlg/Makefile
1250 dlls/olepro32/Makefile
1251 dlls/olesvr/Makefile
1252 dlls/opengl32/Makefile
1253 dlls/psapi/Makefile
1254 dlls/qcap/Makefile
1255 dlls/quartz/Makefile
1256 dlls/rasapi32/Makefile
1257 dlls/richedit/Makefile
1258 dlls/rpcrt4/Makefile
1259 dlls/serialui/Makefile
1260 dlls/setupapi/Makefile
1261 dlls/shdocvw/Makefile
1262 dlls/shell32/Makefile
1263 dlls/shfolder/Makefile
1264 dlls/shlwapi/Makefile
1265 dlls/sti/Makefile
1266 dlls/tapi32/Makefile
1267 dlls/ttydrv/Makefile
1268 dlls/url/Makefile
1269 dlls/urlmon/Makefile
1270 dlls/user/Makefile
1271 dlls/version/Makefile
1272 dlls/win32s/Makefile
1273 dlls/winaspi/Makefile
1274 dlls/winedos/Makefile
1275 dlls/wineps/Makefile
1276 dlls/wininet/Makefile
1277 dlls/winmm/Makefile
1278 dlls/winmm/joystick/Makefile
1279 dlls/winmm/mcianim/Makefile
1280 dlls/winmm/mciavi/Makefile
1281 dlls/winmm/mcicda/Makefile
1282 dlls/winmm/mciseq/Makefile
1283 dlls/winmm/mciwave/Makefile
1284 dlls/winmm/midimap/Makefile
1285 dlls/winmm/wavemap/Makefile
1286 dlls/winmm/wineoss/Makefile
1287 dlls/winnls/Makefile
1288 dlls/winsock/Makefile
1289 dlls/winspool/Makefile
1290 dlls/wintrust/Makefile
1291 dlls/wow32/Makefile
1292 dlls/wsock32/Makefile
1293 dlls/x11drv/Makefile
1294 documentation/Makefile
1295 documentation/wine.conf.man
1296 documentation/wine.man
1297 files/Makefile
1298 graphics/Makefile
1299 graphics/enhmetafiledrv/Makefile
1300 graphics/metafiledrv/Makefile
1301 graphics/win16drv/Makefile
1302 graphics/x11drv/Makefile
1303 if1632/Makefile
1304 include/Makefile
1305 library/Makefile
1306 libtest/Makefile
1307 loader/Makefile
1308 loader/ne/Makefile
1309 memory/Makefile
1310 misc/Makefile
1311 miscemu/Makefile
1312 msdos/Makefile
1313 objects/Makefile
1314 ole/Makefile
1315 programs/Makefile
1316 programs/avitools/Makefile
1317 programs/clock/Makefile
1318 programs/cmdlgtst/Makefile
1319 programs/control/Makefile
1320 programs/notepad/Makefile
1321 programs/osversioncheck/Makefile
1322 programs/progman/Makefile
1323 programs/regapi/Makefile
1324 programs/regtest/Makefile
1325 programs/uninstaller/Makefile
1326 programs/view/Makefile
1327 programs/wcmd/Makefile
1328 programs/wineconsole/Makefile
1329 programs/winemine/Makefile
1330 programs/winetest/Makefile
1331 programs/winhelp/Makefile
1332 programs/winver/Makefile
1333 relay32/Makefile
1334 scheduler/Makefile
1335 server/Makefile
1336 tools/Makefile
1337 tools/winapi/Makefile
1338 tools/winebuild/Makefile
1339 tools/winedump/Makefile
1340 tools/winelauncher
1341 tools/wmc/Makefile
1342 tools/wrc/Makefile
1343 tsx11/Makefile
1344 unicode/Makefile
1345 win32/Makefile
1346 windows/Makefile
1347 windows/x11drv/Makefile ])
1348
1349 if test "$have_x" = "no"
1350 then
1351   echo
1352   echo "*** Warning: X development files not found. Wine will be built without"
1353   echo "*** X support, which currently does not work, and would probably not be"
1354   echo "*** what you want anyway. You will need to install devel packages of"
1355   echo "*** Xlib/Xfree86 at the very least."
1356 fi
1357
1358 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1359 then
1360   echo
1361   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1362   echo "*** terminal resize support. Consider upgrading ncurses."
1363 fi
1364
1365 if test "$wine_cv_libc_reentrant" = "no"
1366 then
1367   echo
1368   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1369   echo "*** thread support. Consider upgrading libc to a more recent"
1370   echo "*** reentrant version of libc."
1371 fi
1372
1373 if test "$wine_cv_opengl_version_OK" = "no"
1374 then
1375   echo
1376   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1377   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1378 fi
1379
1380 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1381 then
1382   echo
1383   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1384   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1385   echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1386   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1387 fi
1388
1389 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1390 then
1391   echo
1392   echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1393   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1394   echo "*** support before reporting bugs."
1395 fi
1396
1397 if test "$wine_cv_warn_cups_h" = "yes"
1398 then
1399   echo
1400   echo "*** Note: You have cups runtime libraries, but no development"
1401   echo "*** libraries. Install the cups-devel package or whichever package"
1402   echo "*** contains cups.h to enable CUPS support in WINE."
1403 fi
1404
1405 if test "$wine_cv_msg_freetype" = "yes"
1406 then
1407   echo
1408   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1409   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1410   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1411   echo "*** enable Wine to use TrueType fonts."
1412 fi
1413
1414 echo
1415 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1416 echo
1417
1418 dnl Local Variables:
1419 dnl comment-start: "dnl "
1420 dnl comment-end: ""
1421 dnl comment-start-skip: "\\bdnl\\b\\s *"
1422 dnl compile-command: "autoconf"
1423 dnl End: