aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_GET_SONAME(LIBRARY, FUNCTION, [OTHER_LIBRARIES])
  34 dnl
  35 AC_DEFUN([WINE_GET_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])
  37 AC_CACHE_CHECK([for -l$1 soname], ac_cv_lib_soname_$1,
  38 [ac_get_soname_save_LIBS=$LIBS
  39 LIBS="-l$1 $3 $LIBS"
  40   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  41   [ac_cv_lib_soname_$1=`$ac_cv_path_LDD conftest$ac_exeext | grep lib$1\\.so | sed 's/^[[       ]]*\([[^        ]]*\)[[         ]]*=>.*$/\1/'`
  42   if test "x$ac_cv_lib_soname_$1" = "x"
  43   then
  44      ac_cv_lib_soname_$1="lib$1.so"
  45   fi],
  46   [ac_cv_lib_soname_$1="lib$1.so"])
  47   LIBS=$ac_get_soname_save_LIBS])
  48 if test "x$ac_cv_lib_soname_$1" != xNONE
  49 then AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),"$ac_cv_lib_soname_$1",
  50                         [Define to the soname of the lib$1 library.])dnl
  51 fi])
  52
  53 dnl **** Check for reentrant libc ****
  54 dnl
  55 dnl Usage: WINE_CHECK_ERRNO(errno-name,[action-if-yes,[action-if-no]])
  56 dnl
  57 dnl For cross-compiling we blindly assume that libc is reentrant. This is
  58 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
  59 dnl
  60 AC_DEFUN([WINE_CHECK_ERRNO],
  61 [AC_CACHE_CHECK([for reentrant libc: $1],[wine_cv_libc_r_$1],
  62   [AC_TRY_RUN([int myerrno = 0;
  63 int *$1(){return &myerrno;}
  64 main(){close(333); close(333); exit(!myerrno);}],
  65   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
  66   wine_cv_libc_r_$1=yes)])
  67 AS_IF([test "$wine_cv_libc_r_$1" = "yes"],[$2],[$3])])
  68
  69 dnl **** Link C code with an assembly file ****
  70 dnl
  71 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  72 dnl
  73 AC_DEFUN([WINE_TRY_ASM_LINK],
  74 [AC_TRY_LINK([void ac_asm(void) { asm([$1]); }
  75 [$2]],[$3],[$4],[$5])])
  76
  77 dnl **** Check if we can link an empty program with special CFLAGS ****
  78 dnl
  79 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  80 dnl
  81 AC_DEFUN([WINE_TRY_CFLAGS],
  82 [ac_wine_try_cflags_saved=$CFLAGS
  83 CFLAGS="$CFLAGS $1"
  84 AC_TRY_LINK([],[],[$2],[$3])
  85 CFLAGS=$ac_wine_try_cflags_saved])
  86
  87 dnl **** Check whether we need to define a symbol on the compiler command line ****
  88 dnl
  89 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  90 dnl
  91 AC_DEFUN([WINE_CHECK_DEFINE],
  92 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
  93 AC_CACHE_CHECK([whether we need to define $1],ac_var,
  94     AC_EGREP_CPP(yes,[#ifndef $1
  95 yes
  96 #endif],
  97     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
  98 AS_IF([test AS_VAR_GET(ac_var) = yes],
  99       [CFLAGS="$CFLAGS -D$1"
 100   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 101 AS_VAR_POPDEF([ac_var])])
 102
 103 dnl **** Check for ln ****
 104 dnl
 105 dnl Usage: WINE_PROG_LN
 106 dnl
 107 AC_DEFUN([WINE_PROG_LN],
 108 [AC_MSG_CHECKING([whether ln works])
 109 rm -f conf$$ conf$$.file
 110 echo >conf$$.file
 111 if ln conf$$.file conf$$ 2>/dev/null; then
 112   AC_SUBST(LN,ln)
 113   AC_MSG_RESULT([yes])
 114 else
 115   AC_SUBST(LN,["cp -p"])
 116   AC_MSG_RESULT([no, using $LN])
 117 fi
 118 rm -f conf$$ conf$$.file])
 119
 120 dnl **** Create non-existent directories from config.status ****
 121 dnl
 122 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 123 dnl
 124 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 125 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || (AC_MSG_NOTICE([creating $1]) && mkdir "$1")])])