debugger/dbg.y

   1 %{
   2 /*
   3  * Parser for command lines in the Wine debugger
   4  *
   5  * Copyright 1993 Eric Youngdale
   6  * Copyright 1995 Morten Welinder
   7  * Copyright 2000 Eric Pouech
   8  *
   9  * This library is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public
  11  * License as published by the Free Software Foundation; either
  12  * version 2.1 of the License, or (at your option) any later version.
  13  *
  14  * This library is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with this library; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24 #include "config.h"
  25
  26 #include <stdio.h>
  27 #include <stdlib.h>
  28 #include <string.h>
  29 #include <signal.h>
  30 #include <unistd.h>
  31
  32 #include "wine/exception.h"
  33 #include "debugger.h"
  34 #include "expr.h"
  35 #include "msvcrt/excpt.h"
  36
  37 static void mode_command(int);
  38 int yylex(void);
  39 int yyerror(char *);
  40
  41 %}
  42
  43 %union
  44 {
  45     DBG_VALUE        value;
  46     char *           string;
  47     int              integer;
  48     struct list_id   listing;
  49     struct expr *    expression;
  50     struct datatype* type;
  51 }
  52
  53 %token tCONT tPASS tSTEP tLIST tNEXT tQUIT tHELP tBACKTRACE tINFO tWALK tUP tDOWN
  54 %token tENABLE tDISABLE tBREAK tWATCH tDELETE tSET tMODE tPRINT tEXAM tABORT tVM86
  55 %token tCLASS tMAPS tMODULE tSTACK tSEGMENTS tREGS tWND tQUEUE tLOCAL tEXCEPTION
  56 %token tPROCESS tTHREAD tMODREF tEOL tEOF
  57 %token tFRAME tSHARE tCOND tDISPLAY tUNDISPLAY tDISASSEMBLE
  58 %token tSTEPI tNEXTI tFINISH tSHOW tDIR tWHATIS tSOURCE
  59 %token <string> tPATH
  60 %token <string> tIDENTIFIER tSTRING tDEBUGSTR tINTVAR
  61 %token <integer> tNUM tFORMAT
  62 %token tSYMBOLFILE tRUN tATTACH tDETACH tNOPROCESS
  63
  64 %token tCHAR tSHORT tINT tLONG tFLOAT tDOUBLE tUNSIGNED tSIGNED
  65 %token tSTRUCT tUNION tENUM
  66
  67 /* %left ',' */
  68 /* %left '=' OP_OR_EQUAL OP_XOR_EQUAL OP_AND_EQUAL OP_SHL_EQUAL \
  69          OP_SHR_EQUAL OP_PLUS_EQUAL OP_MINUS_EQUAL \
  70          OP_TIMES_EQUAL OP_DIVIDE_EQUAL OP_MODULO_EQUAL */
  71 /* %left OP_COND */ /* ... ? ... : ... */
  72 %left OP_LOR
  73 %left OP_LAND
  74 %left '|'
  75 %left '^'
  76 %left '&'
  77 %left OP_EQ OP_NE
  78 %left '<' '>' OP_LE OP_GE
  79 %left OP_SHL OP_SHR
  80 %left '+' '-'
  81 %left '*' '/' '%'
  82 %left OP_SIGN '!' '~' OP_DEREF /* OP_INC OP_DEC OP_ADDR */
  83 %left '.' '[' OP_DRF
  84 %nonassoc ':'
  85
  86 %type <expression> expr lval lvalue
  87 %type <type> type_expr
  88 %type <value> expr_addr lval_addr
  89 %type <integer> expr_value
  90 %type <string> pathname identifier
  91
  92 %type <listing> list_arg
  93
  94 %%
  95
  96 input: line
  97     | input line
  98     ;
  99
 100 line: command
 101     | tEOL
 102     | tEOF                      { return 1; }
 103     | error tEOL                { yyerrok; }
 104     ;
 105
 106 command:
 107       tQUIT tEOL                { /*DEBUG_Quit();*/ return 1; }
 108     | tHELP tEOL                { DEBUG_Help(); }
 109     | tHELP tINFO tEOL          { DEBUG_HelpInfo(); }
 110     | tPASS tEOL                { DEBUG_WaitNextException(DBG_EXCEPTION_NOT_HANDLED, 0, 0); }
 111     | tCONT tEOL                { DEBUG_WaitNextException(DBG_CONTINUE, 1,  EXEC_CONT); }
 112     | tCONT tNUM tEOL           { DEBUG_WaitNextException(DBG_CONTINUE, $2, EXEC_CONT); }
 113     | tSTEP tEOL                { DEBUG_WaitNextException(DBG_CONTINUE, 1,  EXEC_STEP_INSTR); }
 114     | tSTEP tNUM tEOL           { DEBUG_WaitNextException(DBG_CONTINUE, $2, EXEC_STEP_INSTR); }
 115     | tNEXT tEOL                { DEBUG_WaitNextException(DBG_CONTINUE, 1,  EXEC_STEP_OVER); }
 116     | tNEXT tNUM tEOL           { DEBUG_WaitNextException(DBG_CONTINUE, $2, EXEC_STEP_OVER); }
 117     | tSTEPI tEOL               { DEBUG_WaitNextException(DBG_CONTINUE, 1,  EXEC_STEPI_INSTR); }
 118     | tSTEPI tNUM tEOL          { DEBUG_WaitNextException(DBG_CONTINUE, $2, EXEC_STEPI_INSTR); }
 119     | tNEXTI tEOL               { DEBUG_WaitNextException(DBG_CONTINUE, 1,  EXEC_STEPI_OVER); }
 120     | tNEXTI tNUM tEOL          { DEBUG_WaitNextException(DBG_CONTINUE, $2, EXEC_STEPI_OVER); }
 121     | tFINISH tEOL              { DEBUG_WaitNextException(DBG_CONTINUE, 0,  EXEC_FINISH); }
 122     | tABORT tEOL               { kill(getpid(), SIGABRT); }
 123     | tMODE tNUM tEOL           { mode_command($2); }
 124     | tMODE tVM86 tEOL          { DEBUG_CurrThread->dbg_mode = MODE_VM86; }
 125     | tENABLE tNUM tEOL         { DEBUG_EnableBreakpoint( $2, TRUE ); }
 126     | tDISABLE tNUM tEOL        { DEBUG_EnableBreakpoint( $2, FALSE ); }
 127     | tDELETE tBREAK tNUM tEOL  { DEBUG_DelBreakpoint( $3 ); }
 128     | tBACKTRACE tEOL           { DEBUG_BackTrace(DEBUG_CurrTid, TRUE); }
 129     | tBACKTRACE tNUM tEOL      { DEBUG_BackTrace($2, TRUE); }
 130     | tUP tEOL                  { DEBUG_SetFrame( curr_frame + 1 );  }
 131     | tUP tNUM tEOL             { DEBUG_SetFrame( curr_frame + $2 ); }
 132     | tDOWN tEOL                { DEBUG_SetFrame( curr_frame - 1 );  }
 133     | tDOWN tNUM tEOL           { DEBUG_SetFrame( curr_frame - $2 ); }
 134     | tFRAME tNUM tEOL          { DEBUG_SetFrame( $2 ); }
 135     | tSHOW tDIR tEOL           { DEBUG_ShowDir(); }
 136     | tDIR pathname tEOL        { DEBUG_AddPath( $2 ); }
 137     | tDIR tEOL                 { DEBUG_NukePath(); }
 138     | tDISPLAY tEOL             { DEBUG_InfoDisplay(); }
 139     | tDISPLAY expr tEOL        { DEBUG_AddDisplay($2, 1, 0); }
 140     | tDISPLAY tFORMAT expr tEOL{ DEBUG_AddDisplay($3, $2 >> 8, $2 & 0xff); }
 141     | tDELETE tDISPLAY tNUM tEOL{ DEBUG_DelDisplay( $3 ); }
 142     | tDELETE tDISPLAY tEOL     { DEBUG_DelDisplay( -1 ); }
 143     | tUNDISPLAY tNUM tEOL      { DEBUG_DelDisplay( $2 ); }
 144     | tUNDISPLAY tEOL           { DEBUG_DelDisplay( -1 ); }
 145     | tCOND tNUM tEOL           { DEBUG_AddBPCondition($2, NULL); }
 146     | tCOND tNUM expr tEOL      { DEBUG_AddBPCondition($2, $3); }
 147     | tSOURCE pathname tEOL     { DEBUG_Parser($2); }
 148     | tSYMBOLFILE pathname tEOL { DEBUG_ReadSymbolTable($2, 0); }
 149     | tSYMBOLFILE pathname tNUM tEOL    { DEBUG_ReadSymbolTable($2, $3); }
 150     | tWHATIS expr_addr tEOL    { DEBUG_PrintType(&$2); DEBUG_FreeExprMem(); }
 151     | tATTACH tNUM tEOL         { DEBUG_Attach($2, FALSE); }
 152     | tDETACH tEOL              { return DEBUG_Detach(); /* FIXME: we shouldn't return, but since we cannot simply clean the symbol table, exit debugger for now */ }
 153     | list_command
 154     | disassemble_command
 155     | set_command
 156     | x_command
 157     | print_command
 158     | break_command
 159     | watch_command
 160     | info_command
 161     | walk_command
 162     | run_command
 163     | noprocess_state
 164     ;
 165
 166 set_command:
 167       tSET lval_addr '=' expr_value tEOL { DEBUG_WriteMemory(&$2, $4); DEBUG_FreeExprMem(); }
 168     | tSET '+' tIDENTIFIER tEOL {DEBUG_DbgChannel(TRUE, NULL, $3);}
 169     | tSET '-' tIDENTIFIER tEOL {DEBUG_DbgChannel(FALSE, NULL, $3);}
 170     | tSET tIDENTIFIER '+' tIDENTIFIER tEOL {DEBUG_DbgChannel(TRUE, $2, $4);}
 171     | tSET tIDENTIFIER '-' tIDENTIFIER tEOL {DEBUG_DbgChannel(FALSE, $2, $4);}
 172     ;
 173
 174 pathname:
 175       tIDENTIFIER              { $$ = $1; }
 176     | tPATH                    { $$ = $1; }
 177     ;
 178
 179 disassemble_command:
 180       tDISASSEMBLE tEOL              { DEBUG_Disassemble( NULL, NULL, 10 ); }
 181     | tDISASSEMBLE expr_addr tEOL    { DEBUG_Disassemble( & $2, NULL, 10 ); }
 182     | tDISASSEMBLE expr_addr ',' expr_addr tEOL { DEBUG_Disassemble( & $2, & $4, 0 ); }
 183     ;
 184
 185 list_command:
 186       tLIST tEOL               { DEBUG_List( NULL, NULL, 10 ); }
 187     | tLIST '-' tEOL           { DEBUG_List( NULL, NULL, -10 ); }
 188     | tLIST list_arg tEOL      { DEBUG_List( & $2, NULL, 10 ); }
 189     | tLIST ',' list_arg tEOL  { DEBUG_List( NULL, & $3, -10 ); }
 190     | tLIST list_arg ',' list_arg tEOL { DEBUG_List( & $2, & $4, 0 ); }
 191     ;
 192
 193 list_arg:
 194       tNUM                     { $$.sourcefile = NULL; $$.line = $1; }
 195     | pathname ':' tNUM        { $$.sourcefile = $1; $$.line = $3; }
 196     | tIDENTIFIER              { DEBUG_GetFuncInfo( & $$, NULL, $1); }
 197     | pathname ':' tIDENTIFIER { DEBUG_GetFuncInfo( & $$, $1, $3); }
 198     | '*' expr_addr            { DEBUG_FindNearestSymbol( & $2.addr, FALSE, NULL, 0, & $$ );
 199                                  DEBUG_FreeExprMem(); }
 200     ;
 201
 202 x_command:
 203       tEXAM expr_addr tEOL     { DEBUG_ExamineMemory( &$2, 1, 'x'); DEBUG_FreeExprMem(); }
 204     | tEXAM tFORMAT expr_addr tEOL  { DEBUG_ExamineMemory( &$3, $2>>8, $2&0xff );
 205                                       DEBUG_FreeExprMem(); }
 206     ;
 207
 208 print_command:
 209       tPRINT expr_addr tEOL    { DEBUG_Print( &$2, 1, 0, 0 ); DEBUG_FreeExprMem(); }
 210     | tPRINT tFORMAT expr_addr tEOL { DEBUG_Print( &$3, $2 >> 8, $2 & 0xff, 0 );
 211                                       DEBUG_FreeExprMem(); }
 212     ;
 213
 214 break_command:
 215       tBREAK '*' expr_addr tEOL{ DEBUG_AddBreakpointFromValue( &$3 ); DEBUG_FreeExprMem(); }
 216     | tBREAK identifier tEOL   { DEBUG_AddBreakpointFromId($2, -1); }
 217     | tBREAK identifier ':' tNUM tEOL  { DEBUG_AddBreakpointFromId($2, $4); }
 218     | tBREAK tNUM tEOL         { DEBUG_AddBreakpointFromLineno($2); }
 219     | tBREAK tEOL              { DEBUG_AddBreakpointFromLineno(-1); }
 220     ;
 221
 222 watch_command:
 223       tWATCH '*' expr_addr tEOL { DEBUG_AddWatchpoint( &$3, 1 ); DEBUG_FreeExprMem(); }
 224     | tWATCH identifier tEOL    { DEBUG_AddWatchpointFromId($2); }
 225     ;
 226
 227 info_command:
 228       tINFO tBREAK tEOL         { DEBUG_InfoBreakpoints(); }
 229     | tINFO tCLASS tSTRING tEOL { DEBUG_InfoClass( $3 ); }
 230     | tINFO tSHARE tEOL         { DEBUG_InfoShare(); }
 231     | tINFO tMODULE expr_value tEOL   { DEBUG_DumpModule( $3 ); DEBUG_FreeExprMem(); }
 232     | tINFO tQUEUE expr_value tEOL    { DEBUG_DumpQueue( $3 ); DEBUG_FreeExprMem(); }
 233     | tINFO tREGS tEOL          { DEBUG_InfoRegisters(&DEBUG_context); }
 234     | tINFO tSEGMENTS expr_value tEOL { DEBUG_InfoSegments( $3, 1 ); DEBUG_FreeExprMem(); }
 235     | tINFO tSEGMENTS tEOL      { DEBUG_InfoSegments( 0, -1 ); }
 236     | tINFO tSTACK tEOL         { DEBUG_InfoStack(); }
 237     | tINFO tMAPS tEOL          { DEBUG_InfoVirtual(); }
 238     | tINFO tWND expr_value tEOL{ DEBUG_InfoWindow( (HWND)$3 ); DEBUG_FreeExprMem(); }
 239     | tINFO tLOCAL tEOL         { DEBUG_InfoLocals(); }
 240     | tINFO tDISPLAY tEOL       { DEBUG_InfoDisplay(); }
 241     ;
 242
 243 walk_command:
 244       tWALK tCLASS tEOL         { DEBUG_WalkClasses(); }
 245     | tWALK tMODULE tEOL        { DEBUG_WalkModules(); }
 246     | tWALK tQUEUE tEOL         { DEBUG_WalkQueues(); }
 247     | tWALK tWND tEOL           { DEBUG_WalkWindows( 0, 0 ); }
 248     | tWALK tWND tNUM tEOL      { DEBUG_WalkWindows( (HWND)$3, 0 ); }
 249     | tWALK tPROCESS tEOL       { DEBUG_WalkProcess(); }
 250     | tWALK tTHREAD tEOL        { DEBUG_WalkThreads(); }
 251     | tWALK tEXCEPTION tEOL           { DEBUG_WalkExceptions(DEBUG_CurrTid); }
 252     | tWALK tEXCEPTION tNUM tEOL      { DEBUG_WalkExceptions($3); }
 253     | tWALK tMODREF expr_value tEOL   { DEBUG_WalkModref( $3 ); DEBUG_FreeExprMem(); }
 254     ;
 255
 256 run_command:
 257       tRUN tEOL                 { DEBUG_Run(NULL); }
 258     | tRUN tSTRING tEOL         { DEBUG_Run($2); }
 259     ;
 260
 261 noprocess_state:
 262       tNOPROCESS tEOL           {} /* <CR> shall not barf anything */
 263     | tNOPROCESS tSTRING tEOL   { DEBUG_Printf(DBG_CHN_MESG, "No process loaded, cannot execute '%s'\n", $2); }
 264     ;
 265
 266 type_expr:
 267       type_expr '*'             { $$ = $1 ? DEBUG_FindOrMakePointerType($1) : NULL; }
 268     | tINT                      { $$ = DEBUG_GetBasicType(DT_BASIC_INT); }
 269     | tCHAR                     { $$ = DEBUG_GetBasicType(DT_BASIC_CHAR); }
 270     | tLONG tINT                { $$ = DEBUG_GetBasicType(DT_BASIC_LONGINT); }
 271     | tUNSIGNED tINT            { $$ = DEBUG_GetBasicType(DT_BASIC_UINT); }
 272     | tLONG tUNSIGNED tINT      { $$ = DEBUG_GetBasicType(DT_BASIC_ULONGINT); }
 273     | tLONG tLONG tINT          { $$ = DEBUG_GetBasicType(DT_BASIC_LONGLONGINT); }
 274     | tLONG tLONG tUNSIGNED tINT{ $$ = DEBUG_GetBasicType(DT_BASIC_ULONGLONGINT); }
 275     | tSHORT tINT               { $$ = DEBUG_GetBasicType(DT_BASIC_SHORTINT); }
 276     | tSHORT tUNSIGNED tINT     { $$ = DEBUG_GetBasicType(DT_BASIC_USHORTINT); }
 277     | tSIGNED tCHAR             { $$ = DEBUG_GetBasicType(DT_BASIC_SCHAR); }
 278     | tUNSIGNED tCHAR           { $$ = DEBUG_GetBasicType(DT_BASIC_UCHAR); }
 279     | tFLOAT                    { $$ = DEBUG_GetBasicType(DT_BASIC_FLOAT); }
 280     | tDOUBLE                   { $$ = DEBUG_GetBasicType(DT_BASIC_DOUBLE); }
 281     | tLONG tDOUBLE             { $$ = DEBUG_GetBasicType(DT_BASIC_LONGDOUBLE); }
 282     | tSTRUCT tIDENTIFIER       { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 283     | tUNION tIDENTIFIER        { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 284     | tENUM tIDENTIFIER         { $$ = DEBUG_TypeCast(DT_ENUM, $2); }
 285     ;
 286
 287 expr_addr: expr                 { $$ = DEBUG_EvalExpr($1); }
 288     ;
 289
 290 expr_value: expr                { DBG_VALUE value = DEBUG_EvalExpr($1);
 291                                   /* expr_value is typed as an integer */
 292                                   $$ = DEBUG_ReadMemory(&value); }
 293     ;
 294
 295 /*
 296  * The expr rule builds an expression tree.  When we are done, we call
 297  * EvalExpr to evaluate the value of the expression.  The advantage of
 298  * the two-step approach is that it is possible to save expressions for
 299  * use in 'display' commands, and in conditional watchpoints.
 300  */
 301 expr:
 302       tNUM                       { $$ = DEBUG_ConstExpr($1); }
 303     | tSTRING                    { $$ = DEBUG_StringExpr($1); }
 304     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 305     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 306     | expr OP_DRF tIDENTIFIER    { $$ = DEBUG_StructPExpr($1, $3); }
 307     | expr '.' tIDENTIFIER       { $$ = DEBUG_StructExpr($1, $3); }
 308     | tIDENTIFIER '(' ')'        { $$ = DEBUG_CallExpr($1, 0); }
 309     | tIDENTIFIER '(' expr ')'   { $$ = DEBUG_CallExpr($1, 1, $3); }
 310     | tIDENTIFIER '(' expr ',' expr ')'  { $$ = DEBUG_CallExpr($1, 2, $3, $5); }
 311     | tIDENTIFIER '(' expr ',' expr ',' expr ')'         { $$ = DEBUG_CallExpr($1, 3, $3, $5, $7); }
 312     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ')'        { $$ = DEBUG_CallExpr($1, 4, $3, $5, $7, $9); }
 313     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ',' expr ')'       { $$ = DEBUG_CallExpr($1, 5, $3, $5, $7, $9, $11); }
 314     | expr '[' expr ']'          { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 315     | expr ':' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SEG, $1, $3); }
 316     | expr OP_LOR expr           { $$ = DEBUG_BinopExpr(EXP_OP_LOR, $1, $3); }
 317     | expr OP_LAND expr          { $$ = DEBUG_BinopExpr(EXP_OP_LAND, $1, $3); }
 318     | expr '|' expr              { $$ = DEBUG_BinopExpr(EXP_OP_OR, $1, $3); }
 319     | expr '&' expr              { $$ = DEBUG_BinopExpr(EXP_OP_AND, $1, $3); }
 320     | expr '^' expr              { $$ = DEBUG_BinopExpr(EXP_OP_XOR, $1, $3); }
 321     | expr OP_EQ expr            { $$ = DEBUG_BinopExpr(EXP_OP_EQ, $1, $3); }
 322     | expr '>' expr              { $$ = DEBUG_BinopExpr(EXP_OP_GT, $1, $3); }
 323     | expr '<' expr              { $$ = DEBUG_BinopExpr(EXP_OP_LT, $1, $3); }
 324     | expr OP_GE expr            { $$ = DEBUG_BinopExpr(EXP_OP_GE, $1, $3); }
 325     | expr OP_LE expr            { $$ = DEBUG_BinopExpr(EXP_OP_LE, $1, $3); }
 326     | expr OP_NE expr            { $$ = DEBUG_BinopExpr(EXP_OP_NE, $1, $3); }
 327     | expr OP_SHL expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHL, $1, $3); }
 328     | expr OP_SHR expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHR, $1, $3); }
 329     | expr '+' expr              { $$ = DEBUG_BinopExpr(EXP_OP_ADD, $1, $3); }
 330     | expr '-' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SUB, $1, $3); }
 331     | expr '*' expr              { $$ = DEBUG_BinopExpr(EXP_OP_MUL, $1, $3); }
 332     | expr '/' expr              { $$ = DEBUG_BinopExpr(EXP_OP_DIV, $1, $3); }
 333     | expr '%' expr              { $$ = DEBUG_BinopExpr(EXP_OP_REM, $1, $3); }
 334     | '-' expr %prec OP_SIGN     { $$ = DEBUG_UnopExpr(EXP_OP_NEG, $2); }
 335     | '+' expr %prec OP_SIGN     { $$ = $2; }
 336     | '!' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_NOT, $2); }
 337     | '~' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_LNOT, $2); }
 338     | '(' expr ')'               { $$ = $2; }
 339     | '*' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_DEREF, $2); }
 340     | '&' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_ADDR, $2); }
 341     | '(' type_expr ')' expr %prec OP_DEREF { $$ = DEBUG_TypeCastExpr($2, $4); }
 342     ;
 343
 344 /*
 345  * The lvalue rule builds an expression tree.  This is a limited form
 346  * of expression that is suitable to be used as an lvalue.
 347  */
 348 lval_addr: lval                  { $$ = DEBUG_EvalExpr($1); }
 349     ;
 350
 351 lval: lvalue                     { $$ = $1; }
 352     | '*' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_FORCE_DEREF, $2); }
 353     ;
 354
 355 lvalue: tNUM                     { $$ = DEBUG_ConstExpr($1); }
 356     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 357     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 358     | lvalue OP_DRF tIDENTIFIER  { $$ = DEBUG_StructPExpr($1, $3); }
 359     | lvalue '.' tIDENTIFIER     { $$ = DEBUG_StructExpr($1, $3); }
 360     | lvalue '[' expr ']'        { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 361     ;
 362
 363 identifier: tIDENTIFIER          { $$ = $1; }
 364     | identifier '.' tIDENTIFIER { char* ptr = DBG_alloc(strlen($1) + 1 + strlen($3)+ 1);
 365                                    sprintf(ptr, "%s.%s", $1, $3); $$ = DEBUG_MakeSymbol(ptr);
 366                                    DBG_free(ptr); }
 367     | identifier ':' ':' tIDENTIFIER { char* ptr = DBG_alloc(strlen($1) + 2 + strlen($4) + 1);
 368                                    sprintf(ptr, "%s::%s", $1, $4); $$ = DEBUG_MakeSymbol(ptr);
 369                                    DBG_free(ptr); }
 370     ;
 371
 372 %%
 373
 374 static void mode_command(int newmode)
 375 {
 376     switch(newmode)
 377     {
 378     case 16: DEBUG_CurrThread->dbg_mode = MODE_16; break;
 379     case 32: DEBUG_CurrThread->dbg_mode = MODE_32; break;
 380     default: DEBUG_Printf(DBG_CHN_MESG,"Invalid mode (use 16, 32 or vm86)\n");
 381     }
 382 }
 383
 384 void DEBUG_Exit(DWORD ec)
 385 {
 386    ExitProcess(ec);
 387 }
 388
 389 static WINE_EXCEPTION_FILTER(wine_dbg_cmd)
 390 {
 391    DEBUG_Printf(DBG_CHN_MESG, "\nwine_dbg_cmd: ");
 392    switch (GetExceptionCode()) {
 393    case DEBUG_STATUS_INTERNAL_ERROR:
 394       DEBUG_Printf(DBG_CHN_MESG, "WineDbg internal error\n");
 395       break;
 396    case DEBUG_STATUS_NO_SYMBOL:
 397       DEBUG_Printf(DBG_CHN_MESG, "Undefined symbol\n");
 398       break;
 399    case DEBUG_STATUS_DIV_BY_ZERO:
 400       DEBUG_Printf(DBG_CHN_MESG, "Division by zero\n");
 401       break;
 402    case DEBUG_STATUS_BAD_TYPE:
 403       DEBUG_Printf(DBG_CHN_MESG, "No type or type mismatch\n");
 404       break;
 405    case DEBUG_STATUS_NO_FIELD:
 406       DEBUG_Printf(DBG_CHN_MESG, "No such field in structure or union\n");
 407       break;
 408    default:
 409       DEBUG_Printf(DBG_CHN_MESG, "Exception %lx\n", GetExceptionCode());
 410       DEBUG_ExternalDebugger();
 411       break;
 412    }
 413
 414    return EXCEPTION_EXECUTE_HANDLER;
 415 }
 416
 417 static  void set_default_channels(void)
 418 {
 419     DEBUG_hParserOutput = GetStdHandle(STD_OUTPUT_HANDLE);
 420     DEBUG_hParserInput  = GetStdHandle(STD_INPUT_HANDLE);
 421 }
 422
 423 /***********************************************************************
 424  *           DEBUG_Parser
 425  *
 426  * Debugger editline parser
 427  */
 428 void    DEBUG_Parser(LPCSTR filename)
 429 {
 430     BOOL                ret_ok;
 431 #ifdef YYDEBUG
 432     yydebug = 0;
 433 #endif
 434
 435     ret_ok = FALSE;
 436
 437     if (filename)
 438     {
 439         DEBUG_hParserOutput = 0;
 440         DEBUG_hParserInput  = CreateFile(filename, GENERIC_READ, FILE_SHARE_READ, NULL, OPEN_EXISTING, 0L, 0);
 441         if (DEBUG_hParserInput == INVALID_HANDLE_VALUE)
 442         {
 443             set_default_channels();
 444             return;
 445         }
 446     }
 447     else
 448         set_default_channels();
 449
 450     do
 451     {
 452        __TRY
 453            {
 454           ret_ok = TRUE;
 455           yyparse();
 456        }
 457        __EXCEPT(wine_dbg_cmd)
 458        {
 459           ret_ok = FALSE;
 460        }
 461        __ENDTRY;
 462        DEBUG_FlushSymbols();
 463     } while (!ret_ok);
 464
 465     if (filename)
 466         CloseHandle(DEBUG_hParserInput);
 467     set_default_channels();
 468 }
 469
 470 int yyerror(char* s)
 471 {
 472    DEBUG_Printf(DBG_CHN_MESG, "%s\n", s);
 473    return 0;
 474 }