tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of server/protocol.def.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (                     # size align format
  26     "int"           => [  4,   4,  "%d" ],
  27     "short int"     => [  2,   2,  "%d" ],
  28     "char"          => [  1,   1,  "%c" ],
  29     "unsigned char" => [  1,   1,  "%02x" ],
  30     "unsigned short"=> [  2,   2,  "%04x" ],
  31     "unsigned int"  => [  4,   4,  "%08x" ],
  32     "data_size_t"   => [  4,   4,  "%u" ],
  33     "obj_handle_t"  => [  4,   4,  "%04x" ],
  34     "atom_t"        => [  4,   4,  "%04x" ],
  35     "user_handle_t" => [  4,   4,  "%08x" ],
  36     "process_id_t"  => [  4,   4,  "%04x" ],
  37     "thread_id_t"   => [  4,   4,  "%04x" ],
  38     "client_ptr_t"  => [  8,   8,  "&dump_uint64" ],
  39     "mod_handle_t"  => [  8,   8,  "&dump_uint64" ],
  40     "lparam_t"      => [  8,   8,  "&dump_uint64" ],
  41     "apc_param_t"   => [  8,   8,  "&dump_uint64" ],
  42     "file_pos_t"    => [  8,   8,  "&dump_uint64" ],
  43     "mem_size_t"    => [  8,   8,  "&dump_uint64" ],
  44     "affinity_t"    => [  8,   8,  "&dump_uint64" ],
  45     "timeout_t"     => [  8,   8,  "&dump_timeout" ],
  46     "rectangle_t"   => [  16,  4,  "&dump_rectangle" ],
  47     "char_info_t"   => [  4,   2,  "&dump_char_info" ],
  48     "apc_call_t"    => [  40,  8,  "&dump_apc_call" ],
  49     "apc_result_t"  => [  40,  8,  "&dump_apc_result" ],
  50     "async_data_t"  => [  40,  8,  "&dump_async_data" ],
  51     "irp_params_t"  => [  32,  8,  "&dump_irp_params" ],
  52     "luid_t"        => [  8,   4,  "&dump_luid" ],
  53     "ioctl_code_t"  => [  4,   4,  "&dump_ioctl_code" ],
  54     "client_cpu_t"  => [  4,   4,  "&dump_client_cpu" ],
  55     "hw_input_t"    => [  32,  8,  "&dump_hw_input" ],
  56 );
  57
  58 my @requests = ();
  59 my %replies = ();
  60 my @asserts = ();
  61
  62 my @trace_lines = ();
  63
  64 my $max_req_size = 64;
  65
  66 my $warnings = scalar(@ARGV) && $ARGV[0] eq "-w";
  67
  68 sub add_padding($$)
  69 {
  70     my ($offset, $padding) = @_;
  71     if ($offset % $padding)
  72     {
  73         my $count = $padding - ($offset % $padding);
  74         print SERVER_PROT "    char __pad_$offset\[$count\];\n";
  75         $offset += $count;
  76     }
  77     return $offset;
  78 }
  79
  80 ### Generate a dumping function
  81
  82 sub DO_DUMP_FUNC($$@)
  83 {
  84     my $name = shift;
  85     my $req = shift;
  86     my $prefix = " ";
  87     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  88     while ($#_ >= 0)
  89     {
  90         my $type = shift;
  91         my $var = shift;
  92         next if $var =~ /^__pad/;
  93         if (defined($formats{$type}))
  94         {
  95             my $fmt = ${$formats{$type}}[2];
  96             if ($fmt =~ /^&(.*)/)
  97             {
  98                 my $func = $1;
  99                 push @trace_lines, "    $func( \"$prefix$var=\", &req->$var );\n";
 100             }
 101             elsif ($fmt =~ /^(%.*)\s+\((.*)\)/)
 102             {
 103                 my ($format, $cast) = ($1, $2);
 104                 push @trace_lines, "    fprintf( stderr, \"$prefix$var=$format\", ($cast)req->$var );\n";
 105             }
 106             else
 107             {
 108                 push @trace_lines, "    fprintf( stderr, \"$prefix$var=$fmt\", req->$var );\n";
 109             }
 110         }
 111         else  # must be some varargs format
 112         {
 113             push @trace_lines, "    " . sprintf($type, "$prefix$var=") . ";\n";
 114         }
 115         $prefix = ", ";
 116     }
 117     push @trace_lines, "}\n\n";
 118 }
 119
 120 ### Parse the request definitions
 121
 122 sub PARSE_REQUESTS()
 123 {
 124     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 125     my $state = 0;
 126     my $offset = 0;
 127     my $name = "";
 128     my @in_struct = ();
 129     my @out_struct = ();
 130
 131     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 132
 133     while (<PROTOCOL>)
 134     {
 135         my ($type, $var);
 136         # strip comments
 137         s!/\*.*\*/!!g;
 138         # strip white space at end of line
 139         s/\s+$//;
 140
 141         if (/^\@HEADER/)
 142         {
 143             die "Misplaced \@HEADER" unless $state == 0;
 144             $state++;
 145             next;
 146         }
 147
 148         # ignore everything while in state 0
 149         next if $state == 0;
 150
 151         if (/^\@REQ\(\s*(\w+)\s*\)/)
 152         {
 153             $name = $1;
 154             die "Misplaced \@REQ" unless $state == 1;
 155             # start a new request
 156             @in_struct = ();
 157             @out_struct = ();
 158             $offset = 12;
 159             print SERVER_PROT "struct ${name}_request\n{\n";
 160             print SERVER_PROT "    struct request_header __header;\n";
 161             $state++;
 162             next;
 163         }
 164
 165         if (/^\@REPLY/)
 166         {
 167             die "Misplaced \@REPLY" unless $state == 2;
 168             $offset = add_padding( $offset, 8 ); # all requests should be 8-byte aligned
 169             die "request $name too large ($offset)" if ($offset > $max_req_size);
 170             push @asserts, "C_ASSERT( sizeof(struct ${name}_request) == $offset );\n";
 171             print SERVER_PROT "};\n";
 172             print SERVER_PROT "struct ${name}_reply\n{\n";
 173             print SERVER_PROT "    struct reply_header __header;\n";
 174             $offset = 8;
 175             $state++;
 176             next;
 177         }
 178
 179         if (/^\@END/)
 180         {
 181             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 182
 183             $offset = add_padding( $offset, 8 ); # all requests should be 8-byte aligned
 184             print SERVER_PROT "};\n";
 185             if ($state == 2)  # build dummy reply struct
 186             {
 187                 die "request $name too large ($offset)" if ($offset > $max_req_size);
 188                 push @asserts, "C_ASSERT( sizeof(struct ${name}_request) == $offset );\n";
 189                 print SERVER_PROT "struct ${name}_reply\n{\n";
 190                 print SERVER_PROT "    struct reply_header __header;\n";
 191                 print SERVER_PROT "};\n";
 192             }
 193             else
 194             {
 195                 die "reply $name too large ($offset)" if ($offset > $max_req_size);
 196                 push @asserts, "C_ASSERT( sizeof(struct ${name}_reply) == $offset );\n";
 197             }
 198             # got a complete request
 199             push @requests, $name;
 200             DO_DUMP_FUNC( $name, "request", @in_struct);
 201             if ($#out_struct >= 0)
 202             {
 203                 $replies{$name} = 1;
 204                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 205             }
 206             $state = 1;
 207             next;
 208         }
 209
 210         if ($state != 1)
 211         {
 212             # skip empty lines (but keep them in output file)
 213             if (/^$/)
 214             {
 215                 print SERVER_PROT "\n";
 216                 next;
 217             }
 218
 219             if (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 220             {
 221                 $var = $1;
 222                 $type = "dump_varargs_" . $2 . "( \"%s\", min(cur_size,req->" . $3 . ") )";
 223                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 224             }
 225             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 226             {
 227                 $var = $1;
 228                 $type = "dump_varargs_" . $2 . "( \"%s\", cur_size )";
 229                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 230             }
 231             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 232             {
 233                 $type = $1;
 234                 $var = $3;
 235                 die "Unrecognized type $type" unless defined($formats{$type});
 236                 my @fmt = @{$formats{$type}};
 237                 if ($offset & ($fmt[1] - 1))
 238                 {
 239                     my $count = $fmt[1] - ($offset & ($fmt[1] - 1));
 240                     print "protocol.def:$.: warning: $name $offset $type $var needs padding\n" if $warnings;
 241                     print SERVER_PROT "    char __pad_$offset\[$count\];\n";
 242                     $offset += $count;
 243                 }
 244                 if ($state == 2)
 245                 {
 246                     push @asserts, "C_ASSERT( FIELD_OFFSET(struct ${name}_request, $var) == $offset );\n";
 247                 }
 248                 else
 249                 {
 250                     push @asserts, "C_ASSERT( FIELD_OFFSET(struct ${name}_reply, $var) == $offset );\n";
 251                 }
 252                 $offset += $fmt[0];
 253             }
 254             else
 255             {
 256                 die "Unrecognized syntax $_";
 257             }
 258             if ($state == 2) { push @in_struct, $type, $var; }
 259             if ($state == 3) { push @out_struct, $type, $var; }
 260         }
 261
 262         # Pass it through into the output file
 263         print SERVER_PROT $_ . "\n";
 264     }
 265     close PROTOCOL;
 266 }
 267
 268 ### Retrieve the server protocol version from the existing server_protocol.h file
 269
 270 sub GET_PROTOCOL_VERSION()
 271 {
 272     my $protocol = 0;
 273     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 274     while (<SERVER_PROT>)
 275     {
 276         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 277     }
 278     close SERVER_PROT;
 279     return $protocol;
 280 }
 281
 282 ### Retrieve the list of status and errors used in the server
 283
 284 sub GET_ERROR_NAMES()
 285 {
 286     my %errors = ();
 287     foreach my $f (glob "server/*.c")
 288     {
 289         next if $f eq "server/trace.c";
 290         open FILE, $f or die "Can't open $f";
 291         while (<FILE>)
 292         {
 293             while (/\bSTATUS_(\w+)/g)
 294             {
 295                 $errors{$1} = "STATUS_$1" unless ($1 eq "SUCCESS" || $1 eq "WAIT_0");
 296             }
 297             while (/\bset_win32_error\s*\(\s*(\w+)\s*\)/g)
 298             {
 299                 $errors{$1} = "0xc0010000 | $1";
 300             }
 301             while (/\breturn\s+(WSA\w+)/g)
 302             {
 303                 $errors{$1} = "0xc0010000 | $1";
 304             }
 305         }
 306         close FILE;
 307     }
 308     return %errors;
 309 }
 310
 311 # update a file if changed
 312 sub update_file($)
 313 {
 314     my $file = shift;
 315     my $ret = !(-f $file) || system "cmp $file $file.new >/dev/null";
 316     if (!$ret)
 317     {
 318         unlink "$file.new";
 319     }
 320     else
 321     {
 322         rename "$file.new", "$file";
 323         print "$file updated\n";
 324     }
 325     return $ret;
 326 }
 327
 328 # replace some lines in a file between two markers
 329 sub replace_in_file($$$@)
 330 {
 331     my $file = shift;
 332     my $start = shift;
 333     my $end = shift;
 334
 335     open NEW_FILE, ">$file.new" or die "cannot create $file.new";
 336
 337     if (defined($start))
 338     {
 339         open OLD_FILE, "$file" or die "cannot open $file";
 340         while (<OLD_FILE>)
 341         {
 342             print NEW_FILE $_;
 343             last if /$start/;
 344         }
 345     }
 346
 347     print NEW_FILE "\n", @_, "\n";
 348
 349     if (defined($end))
 350     {
 351         my $skip=1;
 352         while (<OLD_FILE>)
 353         {
 354             $skip = 0 if /$end/;
 355             print NEW_FILE $_ unless $skip;
 356         }
 357     }
 358
 359     close OLD_FILE if defined($start);
 360     close NEW_FILE;
 361     return update_file($file);
 362 }
 363
 364 ### Main
 365
 366 # Get the server protocol version
 367 my $protocol = GET_PROTOCOL_VERSION();
 368
 369 my %errors = GET_ERROR_NAMES();
 370
 371 ### Create server_protocol.h and print header
 372
 373 open SERVER_PROT, ">include/wine/server_protocol.h.new" or die "Cannot create include/wine/server_protocol.h.new";
 374 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 375 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 376 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 377 print SERVER_PROT " */\n\n";
 378 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 379 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 380
 381 ### Parse requests to find request/reply structure definitions
 382
 383 PARSE_REQUESTS();
 384
 385 ### Build the request list and structures
 386
 387 print SERVER_PROT "\n\nenum request\n{\n";
 388 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 389 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 390
 391 print SERVER_PROT "union generic_request\n{\n";
 392 print SERVER_PROT "    struct request_max_size max_size;\n";
 393 print SERVER_PROT "    struct request_header request_header;\n";
 394 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 395 print SERVER_PROT "};\n";
 396
 397 print SERVER_PROT "union generic_reply\n{\n";
 398 print SERVER_PROT "    struct request_max_size max_size;\n";
 399 print SERVER_PROT "    struct reply_header reply_header;\n";
 400 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 401 print SERVER_PROT "};\n\n";
 402
 403 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol + 1;
 404 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 405 close SERVER_PROT;
 406 update_file( "include/wine/server_protocol.h" );
 407
 408 ### Output the dumping function tables
 409
 410 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 411 foreach my $req (@requests)
 412 {
 413     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 414 }
 415 push @trace_lines, "};\n\n";
 416
 417 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 418 foreach my $req (@requests)
 419 {
 420     push @trace_lines, "    ", $replies{$req} ? "(dump_func)dump_${req}_reply,\n" : "NULL,\n";
 421 }
 422 push @trace_lines, "};\n\n";
 423
 424 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 425 foreach my $req (@requests)
 426 {
 427     push @trace_lines, "    \"$req\",\n";
 428 }
 429 push @trace_lines, "};\n\n";
 430
 431 push @trace_lines, "static const struct\n{\n";
 432 push @trace_lines, "    const char  *name;\n";
 433 push @trace_lines, "    unsigned int value;\n";
 434 push @trace_lines, "} status_names[] =\n{\n";
 435
 436 foreach my $err (sort keys %errors)
 437 {
 438     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 439 }
 440 push @trace_lines, "    { NULL, 0 }\n";
 441 push @trace_lines, "};\n";
 442
 443 replace_in_file( "server/trace.c",
 444                  "### make_requests begin ###",
 445                  "### make_requests end ###",
 446                  @trace_lines );
 447
 448 ### Output the request handlers list
 449
 450 my @request_lines = ();
 451
 452 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 453 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 454 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 455 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 456 foreach my $req (@requests)
 457 {
 458     push @request_lines, "    (req_handler)req_$req,\n";
 459 }
 460 push @request_lines, "};\n\n";
 461
 462 foreach my $type (sort keys %formats)
 463 {
 464     my $size = ${$formats{$type}}[0];
 465     push @request_lines, "C_ASSERT( sizeof($type) == $size );\n";
 466 }
 467 push @request_lines, @asserts;
 468 push @request_lines, "\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 469
 470 replace_in_file( "server/request.h",
 471                  "### make_requests begin ###",
 472                  "### make_requests end ###",
 473                  @request_lines );